configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32 m4_include([config/cloog.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_PREREQ(2.64)
  36 AC_DISABLE_OPTION_CHECKING
  37
  38 progname=$0
  39 # if PWD already has a value, it is probably wrong.
  40 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  41
  42 # Export original configure arguments for use by sub-configures.
  43 # Quote arguments with shell meta charatcers.
  44 TOPLEVEL_CONFIGURE_ARGUMENTS=
  45 set -- "$progname" "$@"
  46 for ac_arg
  47 do
  48   case "$ac_arg" in
  49   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  50     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  51     # if the argument is of the form -foo=baz, quote the baz part only
  52     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  53   *) ;;
  54   esac
  55   # Add the quoted argument to the list.
  56   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  57 done
  58 if test "$silent" = yes; then
  59   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  60 fi
  61 # Remove the initial space we just introduced and, as these will be
  62 # expanded by make, quote '$'.
  63 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  64 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  65
  66 # Find the build, host, and target systems.
  67 ACX_NONCANONICAL_BUILD
  68 ACX_NONCANONICAL_HOST
  69 ACX_NONCANONICAL_TARGET
  70
  71 dnl Autoconf 2.5x and later will set a default program prefix if
  72 dnl --target was used, even if it was the same as --host.  Disable
  73 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  74 dnl to take effect.
  75 test "$host_noncanonical" = "$target_noncanonical" &&
  76   test "$program_prefix$program_suffix$program_transform_name" = \
  77     NONENONEs,x,x, &&
  78   program_transform_name=s,y,y,
  79
  80 AC_CANONICAL_SYSTEM
  81 AC_ARG_PROGRAM
  82
  83 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  84 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  85
  86 # Get 'install' or 'install-sh' and its variants.
  87 AC_PROG_INSTALL
  88 ACX_PROG_LN
  89 AC_PROG_LN_S
  90 AC_PROG_SED
  91 AC_PROG_AWK
  92
  93 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  94
  95 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  96 # a relative path.
  97 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  98   INSTALL="${srcpwd}/install-sh -c"
  99 fi
 100
 101 # Set srcdir to "." if that's what it is.
 102 # This is important for multilib support.
 103 pwd=`${PWDCMD-pwd}`
 104 if test "${pwd}" = "${srcpwd}" ; then
 105   srcdir=.
 106 fi
 107
 108 topsrcdir=$srcpwd
 109
 110 extra_host_args=
 111
 112 ### To add a new directory to the tree, first choose whether it is a target
 113 ### or a host dependent tool.  Then put it into the appropriate list
 114 ### (library or tools, host or target), doing a dependency sort.
 115
 116 # Subdirs will be configured in the order listed in build_configdirs,
 117 # configdirs, or target_configdirs; see the serialization section below.
 118
 119 # Dependency sorting is only needed when *configuration* must be done in
 120 # a particular order.  In all cases a dependency should be specified in
 121 # the Makefile, whether or not it's implicitly specified here.
 122
 123 # Double entries in build_configdirs, configdirs, or target_configdirs may
 124 # cause circular dependencies and break everything horribly.
 125
 126 # these library is used by various programs built for the build
 127 # environment
 128 #
 129 build_libs="build-libiberty"
 130
 131 # these tools are built for the build environment
 132 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 133
 134 # these libraries are used by various programs built for the host environment
 135 #
 136 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc isl cloog libelf libiconv"
 137
 138 # these tools are built for the host environment
 139 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 140 # know that we are building the simulator.
 141 # binutils, gas and ld appear in that order because it makes sense to run
 142 # "make check" in that particular order.
 143 # If --enable-gold is used, "gold" may replace "ld".
 144 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 145
 146 # libgcj represents the runtime libraries only used by gcj.
 147 libgcj="target-libffi \
 148         target-zlib \
 149         target-libjava"
 150
 151 # these libraries are built for the target environment, and are built after
 152 # the host libraries and the host tools (which may be a cross compiler)
 153 # Note that libiberty is not a target library.
 154 target_libraries="target-libgcc \
 155                 target-libgloss \
 156                 target-newlib \
 157                 target-libgomp \
 158                 target-libatomic \
 159                 target-libitm \
 160                 target-libstdc++-v3 \
 161                 target-libmudflap \
 162                 target-libssp \
 163                 target-libquadmath \
 164                 target-libgfortran \
 165                 target-boehm-gc \
 166                 ${libgcj} \
 167                 target-libobjc \
 168                 target-libada \
 169                 target-libgo"
 170
 171 # these tools are built using the target libraries, and are intended to
 172 # run only in the target environment
 173 #
 174 # note: any program that *uses* libraries that are in the "target_libraries"
 175 # list belongs in this list.
 176 #
 177 target_tools="target-rda"
 178
 179 ################################################################################
 180
 181 ## All tools belong in one of the four categories, and are assigned above
 182 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 183 ## is important because configure will choke if they ever get through.
 184 ## ${configdirs} is directories we build using the host tools.
 185 ## ${target_configdirs} is directories we build using the target tools.
 186 configdirs=`echo ${host_libs} ${host_tools}`
 187 target_configdirs=`echo ${target_libraries} ${target_tools}`
 188 build_configdirs=`echo ${build_libs} ${build_tools}`
 189
 190 m4_divert_text([PARSE_ARGS],
 191 [case $srcdir in
 192   *" "*)
 193 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 194     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 195 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 196     ;;
 197 esac
 198 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 199 ])
 200
 201 ################################################################################
 202
 203 srcname="gnu development package"
 204
 205 # This gets set non-empty for some net releases of packages.
 206 appdirs=""
 207
 208 # Define is_cross_compiler to save on calls to 'test'.
 209 is_cross_compiler=
 210 if test x"${host}" = x"${target}" ; then
 211   is_cross_compiler=no
 212 else
 213   is_cross_compiler=yes
 214 fi
 215
 216 # Find the build and target subdir names.
 217 GCC_TOPLEV_SUBDIRS
 218 # Be sure to cover against remnants of an in-tree build.
 219 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 220   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 221 Use a pristine source tree when building in a separate tree])
 222 fi
 223
 224 # Skipdirs are removed silently.
 225 skipdirs=
 226 # Noconfigdirs are removed loudly.
 227 noconfigdirs=""
 228
 229 use_gnu_ld=
 230 # Make sure we don't let GNU ld be added if we didn't want it.
 231 if test x$with_gnu_ld = xno ; then
 232   use_gnu_ld=no
 233   noconfigdirs="$noconfigdirs ld gold"
 234 fi
 235
 236 use_gnu_as=
 237 # Make sure we don't let GNU as be added if we didn't want it.
 238 if test x$with_gnu_as = xno ; then
 239   use_gnu_as=no
 240   noconfigdirs="$noconfigdirs gas"
 241 fi
 242
 243 use_included_zlib=
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 # Handle --enable-gold, --enable-ld.
 287 # --disable-gold [--enable-ld]
 288 #     Build only ld.  Default option.
 289 # --enable-gold [--enable-ld]
 290 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 291 #     as "ld.bfd" and "ld".
 292 # --enable-gold=default [--enable-ld]
 293 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 294 #     install ld as "ld.bfd".
 295 # --enable-gold[=default] --disable-ld
 296 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 297 # --enable-gold --enable-ld=default
 298 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 299 #     and ld.bfd).
 300 #     In other words, ld is default
 301 # --enable-gold=default --enable-ld=default
 302 #     Error.
 303
 304 default_ld=
 305 AC_ARG_ENABLE(gold,
 306 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 307                 [build gold @<:@ARG={default,yes,no}@:>@])],
 308 ENABLE_GOLD=$enableval,
 309 ENABLE_GOLD=no)
 310 case "${ENABLE_GOLD}" in
 311   yes|default)
 312     # Check for ELF target.
 313     is_elf=no
 314     case "${target}" in
 315       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 316       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 317       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 318       | *-*-solaris2* | *-*-nto*)
 319         case "${target}" in
 320           *-*-linux*aout* | *-*-linux*oldld*)
 321             ;;
 322           *)
 323             is_elf=yes
 324             ;;
 325         esac
 326     esac
 327
 328     if test "$is_elf" = "yes"; then
 329       # Check for target supported by gold.
 330       case "${target}" in
 331         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 332           configdirs="$configdirs gold"
 333           if test x${ENABLE_GOLD} = xdefault; then
 334             default_ld=gold
 335           fi
 336           ENABLE_GOLD=yes
 337           ;;
 338       esac
 339     fi
 340     ;;
 341   no)
 342     ;;
 343   *)
 344     AC_MSG_ERROR([invalid --enable-gold argument])
 345     ;;
 346 esac
 347
 348 AC_ARG_ENABLE(ld,
 349 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 350                 [build ld @<:@ARG={default,yes,no}@:>@])],
 351 ENABLE_LD=$enableval,
 352 ENABLE_LD=yes)
 353
 354 case "${ENABLE_LD}" in
 355   default)
 356     if test x${default_ld} != x; then
 357       AC_MSG_ERROR([either gold or ld can be the default ld])
 358     fi
 359     ;;
 360   yes)
 361     ;;
 362   no)
 363     if test x${ENABLE_GOLD} != xyes; then
 364       AC_MSG_WARN([neither ld nor gold are enabled])
 365     fi
 366     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 367     ;;
 368   *)
 369     AC_MSG_ERROR([invalid --enable-ld argument])
 370     ;;
 371 esac
 372
 373 # Configure extra directories which are host specific
 374
 375 case "${host}" in
 376   *-cygwin*)
 377     configdirs="$configdirs libtermcap" ;;
 378 esac
 379
 380 # A target can indicate whether a language isn't supported for some reason.
 381 # Only spaces may be used in this macro; not newlines or tabs.
 382 unsupported_languages=
 383
 384 # Remove more programs from consideration, based on the host or
 385 # target this usually means that a port of the program doesn't
 386 # exist yet.
 387
 388 case "${host}" in
 389   i[[3456789]]86-*-msdosdjgpp*)
 390     noconfigdirs="$noconfigdirs tcl tk itcl"
 391     ;;
 392 esac
 393
 394
 395 AC_ARG_ENABLE(libquadmath,
 396 AS_HELP_STRING([--disable-libquadmath],
 397   [do not build libquadmath directory]),
 398 ENABLE_LIBQUADMATH=$enableval,
 399 ENABLE_LIBQUADMATH=yes)
 400 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 401   noconfigdirs="$noconfigdirs target-libquadmath"
 402 fi
 403
 404
 405 AC_ARG_ENABLE(libquadmath-support,
 406 AS_HELP_STRING([--disable-libquadmath-support],
 407   [disable libquadmath support for Fortran]),
 408 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 409 ENABLE_LIBQUADMATH_SUPPORT=yes)
 410 enable_libquadmath_support=
 411 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 412   enable_libquadmath_support=no
 413 fi
 414
 415
 416 AC_ARG_ENABLE(libada,
 417 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 418 ENABLE_LIBADA=$enableval,
 419 ENABLE_LIBADA=yes)
 420 if test "${ENABLE_LIBADA}" != "yes" ; then
 421   noconfigdirs="$noconfigdirs gnattools"
 422 fi
 423
 424 AC_ARG_ENABLE(libssp,
 425 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 426 ENABLE_LIBSSP=$enableval,
 427 ENABLE_LIBSSP=yes)
 428
 429 # Save it here so that, even in case of --enable-libgcj, if the Java
 430 # front-end isn't enabled, we still get libgcj disabled.
 431 libgcj_saved=$libgcj
 432 case $enable_libgcj in
 433 yes)
 434   # If we reset it here, it won't get added to noconfigdirs in the
 435   # target-specific build rules, so it will be forcibly enabled
 436   # (unless the Java language itself isn't enabled).
 437   libgcj=
 438   ;;
 439 no)
 440   # Make sure we get it printed in the list of not supported target libs.
 441   # Don't disable libffi, though, other languages use it.
 442   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 443   # Clear libgcj_saved so that even if java is enabled libffi won't be
 444   # built.
 445   libgcj_saved=
 446   ;;
 447 esac
 448
 449 AC_ARG_ENABLE(static-libjava,
 450 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 451                 [build static libjava @<:@default=no@:>@])],
 452 ENABLE_STATIC_LIBJAVA=$enableval,
 453 ENABLE_STATIC_LIBJAVA=no)
 454 enable_static_libjava=
 455 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 456   enable_static_libjava=yes
 457 fi
 458
 459 if test x$enable_static_libjava != xyes ; then
 460   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 461 fi
 462 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 463
 464 # Disable libmudflap on some systems.
 465 if test x$enable_libmudflap = x ; then
 466     case "${target}" in
 467     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 468         # Enable libmudflap by default in GNU and friends.
 469         ;;
 470     *-*-freebsd*)
 471         # Enable libmudflap by default in FreeBSD.
 472         ;;
 473     *)
 474         # Disable it by default everywhere else.
 475         noconfigdirs="$noconfigdirs target-libmudflap"
 476         ;;
 477     esac
 478 fi
 479
 480 # Disable libgomp on non POSIX hosted systems.
 481 if test x$enable_libgomp = x ; then
 482     # Enable libgomp by default on hosted POSIX systems.
 483     case "${target}" in
 484     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 485         ;;
 486     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 487         ;;
 488     *-*-solaris2* | *-*-hpux11*)
 489         ;;
 490     *-*-darwin* | *-*-aix*)
 491         ;;
 492     *)
 493         noconfigdirs="$noconfigdirs target-libgomp"
 494         ;;
 495     esac
 496 fi
 497
 498 # Disable libatomic on unsupported systems.
 499 if test -d ${srcdir}/libatomic; then
 500     if test x$enable_libatomic = x; then
 501         AC_MSG_CHECKING([for libatomic support])
 502         if (srcdir=${srcdir}/libatomic; \
 503                 . ${srcdir}/configure.tgt; \
 504                 test -n "$UNSUPPORTED")
 505         then
 506             AC_MSG_RESULT([no])
 507             noconfigdirs="$noconfigdirs target-libatomic"
 508         else
 509             AC_MSG_RESULT([yes])
 510         fi
 511     fi
 512 fi
 513
 514 # Disable libitm on unsupported systems.
 515 if test -d ${srcdir}/libitm; then
 516     if test x$enable_libitm = x; then
 517         AC_MSG_CHECKING([for libitm support])
 518         if (srcdir=${srcdir}/libitm; \
 519                 . ${srcdir}/configure.tgt; \
 520                 test -n "$UNSUPPORTED")
 521         then
 522             AC_MSG_RESULT([no])
 523             noconfigdirs="$noconfigdirs target-libitm"
 524         else
 525             AC_MSG_RESULT([yes])
 526         fi
 527     fi
 528 fi
 529
 530 # Disable libquadmath for some systems.
 531 case "${target}" in
 532   # libquadmath is unused on AIX and libquadmath build process use of
 533   # LD_LIBRARY_PATH can break AIX bootstrap.
 534   powerpc-*-aix* | rs6000-*-aix*)
 535     noconfigdirs="$noconfigdirs target-libquadmath"
 536     ;;
 537 esac
 538
 539 # Disable libssp for some systems.
 540 case "${target}" in
 541   avr-*-*)
 542     # No hosted I/O support.
 543     noconfigdirs="$noconfigdirs target-libssp"
 544     ;;
 545   powerpc-*-aix* | rs6000-*-aix*)
 546     noconfigdirs="$noconfigdirs target-libssp"
 547     ;;
 548   rl78-*-*)
 549     # libssp uses a misaligned load to trigger a fault, but the RL78
 550     # doesn't fault for those - instead, it gives a build-time error
 551     # for explicit misaligned loads.
 552     noconfigdirs="$noconfigdirs target-libssp"
 553     ;;
 554 esac
 555
 556 # Disable libstdc++-v3 for some systems.
 557 case "${target}" in
 558   *-*-vxworks*)
 559     # VxWorks uses the Dinkumware C++ library.
 560     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 561     ;;
 562   arm*-wince-pe*)
 563     # the C++ libraries don't build on top of CE's C libraries
 564     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 565     ;;
 566   avr-*-*)
 567     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 568     ;;
 569 esac
 570
 571 # Disable Fortran for some systems.
 572 case "${target}" in
 573   mmix-*-*)
 574     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 575     unsupported_languages="$unsupported_languages fortran"
 576     ;;
 577 esac
 578
 579 # Disable Java if libffi is not supported.
 580 case "${target}" in
 581   alpha*-*-*)
 582     ;;
 583   arm*-*-*)
 584     ;;
 585   cris-*-*)
 586     ;;
 587   frv-*-*)
 588     ;;
 589   hppa*-*-linux*)
 590     ;;
 591   hppa*-*-hpux*)
 592     ;;
 593   i?86-*-*)
 594     ;;
 595   ia64*-*-*)
 596     ;;
 597   m32r*-*-*)
 598     ;;
 599   m68k-*-*)
 600     ;;
 601   mips*-*-rtems*)
 602     ;;
 603   mips*-*-linux*)
 604     ;;
 605   powerpc*-*-linux*)
 606     ;;
 607   powerpc-*-darwin*)
 608     ;;
 609   powerpc-*-aix* | rs6000-*-aix*)
 610     ;;
 611   powerpc-*-freebsd*)
 612     ;;
 613   powerpc64-*-freebsd*)
 614     ;;
 615   powerpc*-*-rtems*)
 616     ;;
 617   s390-*-* | s390x-*-*)
 618     ;;
 619   sh-*-* | sh[[34]]*-*-*)
 620     ;;
 621   sh64-*-* | sh5*-*-*)
 622     ;;
 623   sparc*-*-*)
 624     ;;
 625   x86_64-*-*)
 626     ;;
 627   *-*-*)
 628     unsupported_languages="$unsupported_languages java"
 629     ;;
 630 esac
 631
 632 # Disable Java, libgcj or related libraries for some systems.
 633 case "${target}" in
 634   powerpc-*-darwin*)
 635     ;;
 636   i[[3456789]]86-*-darwin*)
 637     ;;
 638   x86_64-*-darwin[[912]]*)
 639     ;;
 640   *-*-darwin*)
 641     noconfigdirs="$noconfigdirs ${libgcj}"
 642     ;;
 643   *-*-netware*)
 644     noconfigdirs="$noconfigdirs ${libgcj}"
 645     ;;
 646   *-*-rtems*)
 647     noconfigdirs="$noconfigdirs ${libgcj}"
 648     ;;
 649   *-*-tpf*)
 650     noconfigdirs="$noconfigdirs ${libgcj}"
 651     ;;
 652   *-*-uclinux*)
 653     noconfigdirs="$noconfigdirs ${libgcj}"
 654     ;;
 655   *-*-vxworks*)
 656     noconfigdirs="$noconfigdirs ${libgcj}"
 657     ;;
 658   alpha*-*-*vms*)
 659     noconfigdirs="$noconfigdirs ${libgcj}"
 660     ;;
 661   arm-wince-pe)
 662     noconfigdirs="$noconfigdirs ${libgcj}"
 663     ;;
 664   arm*-*-symbianelf*)
 665     noconfigdirs="$noconfigdirs ${libgcj}"
 666     ;;
 667   bfin-*-*)
 668     noconfigdirs="$noconfigdirs target-boehm-gc"
 669     ;;
 670   cris-*-* | crisv32-*-*)
 671     unsupported_languages="$unsupported_languages java"
 672     case "${target}" in
 673       *-*-linux*)
 674         ;;
 675       *) # See PR46792 regarding target-libffi.
 676         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 677     esac
 678     ;;
 679   hppa*64*-*-linux*)
 680     # In this case, it's because the hppa64-linux target is for
 681     # the kernel only at this point and has no libc, and thus no
 682     # headers, crt*.o, etc., all of which are needed by these.
 683     unsupported_languages="$unsupported_languages java"
 684     ;;
 685   hppa*64*-*-hpux*)
 686     noconfigdirs="$noconfigdirs ${libgcj}"
 687     ;;
 688   hppa*-hp-hpux11*)
 689     ;;
 690   hppa*-*-hpux*)
 691     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 692     # build on HP-UX 10.20.
 693     noconfigdirs="$noconfigdirs ${libgcj}"
 694     ;;
 695   ia64*-*-*vms*)
 696     noconfigdirs="$noconfigdirs ${libgcj}"
 697     ;;
 698   i[[3456789]]86-w64-mingw*)
 699     noconfigdirs="$noconfigdirs ${libgcj}"
 700     ;;
 701   i[[3456789]]86-*-mingw*)
 702     noconfigdirs="$noconfigdirs ${libgcj}"
 703     ;;
 704   x86_64-*-mingw*)
 705     noconfigdirs="$noconfigdirs ${libgcj}"
 706     ;;
 707   mmix-*-*)
 708     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 709     ;;
 710   powerpc-*-aix*)
 711     # copied from rs6000-*-* entry
 712     noconfigdirs="$noconfigdirs ${libgcj}"
 713     ;;
 714   rs6000-*-aix*)
 715     noconfigdirs="$noconfigdirs ${libgcj}"
 716     ;;
 717   *-*-lynxos*)
 718     noconfigdirs="$noconfigdirs ${libgcj}"
 719     ;;
 720 esac
 721
 722 # Default libgloss CPU subdirectory.
 723 libgloss_dir="$target_cpu"
 724
 725 case "${target}" in
 726   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 727     libgloss_dir=wince
 728     ;;
 729   arm*-*-*)
 730     libgloss_dir=arm
 731     ;;
 732   cris-*-* | crisv32-*-*)
 733     libgloss_dir=cris
 734     ;;
 735   hppa*-*-*)
 736     libgloss_dir=pa
 737     ;;
 738   i[[3456789]]86-*-*)
 739     libgloss_dir=i386
 740     ;;
 741   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 742     libgloss_dir=m68hc11
 743     ;;
 744   m68*-*-* | fido-*-*)
 745     libgloss_dir=m68k
 746     ;;
 747   mips*-*-*)
 748     libgloss_dir=mips
 749     ;;
 750   powerpc*-*-*)
 751     libgloss_dir=rs6000
 752     ;;
 753   sparc*-*-*)
 754     libgloss_dir=sparc
 755     ;;
 756 esac
 757
 758 # Disable newlib and libgloss for various target OSes.
 759 case "${target}" in
 760   alpha*-dec-osf*)
 761     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 762     ;;
 763   i[[3456789]]86-*-linux*)
 764     # This section makes it possible to build newlib natively on linux.
 765     # If we are using a cross compiler then don't configure newlib.
 766     if test x${is_cross_compiler} != xno ; then
 767       noconfigdirs="$noconfigdirs target-newlib"
 768     fi
 769     noconfigdirs="$noconfigdirs target-libgloss"
 770     # If we are not using a cross compiler, do configure newlib.
 771     # Note however, that newlib will only be configured in this situation
 772     # if the --with-newlib option has been given, because otherwise
 773     # 'target-newlib' will appear in skipdirs.
 774     ;;
 775   i[[3456789]]86-*-rdos*)
 776     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 777     ;;
 778   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 779     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 780     ;;
 781   sparc-*-sunos4*)
 782     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 783     ;;
 784   *-*-aix*)
 785     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 786     ;;
 787   *-*-beos*)
 788     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 789     ;;
 790   *-*-chorusos)
 791     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 792     ;;
 793   *-*-dragonfly*)
 794     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 795     ;;
 796   *-*-freebsd*)
 797     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 798     ;;
 799   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 800     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 801     ;;
 802   *-*-lynxos*)
 803     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 804     ;;
 805   *-*-mingw*)
 806     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 807     ;;
 808   *-*-netbsd*)
 809     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 810     ;;
 811   *-*-netware*)
 812     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 813     ;;
 814   *-*-tpf*)
 815     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 816     ;;
 817   *-*-uclinux*)
 818     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 819     ;;
 820   *-*-vxworks*)
 821     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 822     ;;
 823 esac
 824
 825 case "${target}" in
 826   *-*-chorusos)
 827     ;;
 828   powerpc-*-darwin*)
 829     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 830     noconfigdirs="$noconfigdirs sim target-rda"
 831     ;;
 832   i[[3456789]]86-*-darwin*)
 833     noconfigdirs="$noconfigdirs ld gprof"
 834     noconfigdirs="$noconfigdirs sim target-rda"
 835     ;;
 836   x86_64-*-darwin[[912]]*)
 837     noconfigdirs="$noconfigdirs ld gas gprof"
 838     noconfigdirs="$noconfigdirs sim target-rda"
 839     ;;
 840   *-*-darwin*)
 841     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 842     noconfigdirs="$noconfigdirs sim target-rda"
 843     ;;
 844   *-*-dragonfly*)
 845     ;;
 846   *-*-freebsd*)
 847     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 848         && test -f /usr/local/include/gmp.h; then
 849       with_gmp=/usr/local
 850     fi
 851     ;;
 852   *-*-kaos*)
 853     # Remove unsupported stuff on all kaOS configurations.
 854     noconfigdirs="$noconfigdirs target-libgloss"
 855     ;;
 856   *-*-netbsd*)
 857     ;;
 858   *-*-netware*)
 859     ;;
 860   *-*-rtems*)
 861     noconfigdirs="$noconfigdirs target-libgloss"
 862     ;;
 863     # The tpf target doesn't support gdb yet.
 864   *-*-tpf*)
 865     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 866     ;;
 867   *-*-uclinux*)
 868     noconfigdirs="$noconfigdirs target-rda"
 869     ;;
 870   *-*-vxworks*)
 871     ;;
 872   alpha*-dec-osf*)
 873     # ld works, but does not support shared libraries.
 874     # gas doesn't generate exception information.
 875     noconfigdirs="$noconfigdirs gas ld"
 876     ;;
 877   alpha*-*-*vms*)
 878     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 879     ;;
 880   alpha*-*-*)
 881     # newlib is not 64 bit ready
 882     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 883     ;;
 884   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 885     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 886     ;;
 887   arc-*-*)
 888     noconfigdirs="$noconfigdirs target-libgloss"
 889     ;;
 890   arm-*-pe*)
 891     noconfigdirs="$noconfigdirs target-libgloss"
 892     ;;
 893   arm-*-riscix*)
 894     noconfigdirs="$noconfigdirs ld target-libgloss"
 895     ;;
 896   c4x-*-* | tic4x-*-*)
 897     noconfigdirs="$noconfigdirs target-libgloss"
 898     ;;
 899   tic54x-*-*)
 900     noconfigdirs="$noconfigdirs target-libgloss gdb"
 901     ;;
 902   d10v-*-*)
 903     noconfigdirs="$noconfigdirs target-libgloss"
 904     ;;
 905   d30v-*-*)
 906     noconfigdirs="$noconfigdirs gdb"
 907     ;;
 908   fr30-*-elf*)
 909     noconfigdirs="$noconfigdirs gdb"
 910     ;;
 911   moxie-*-*)
 912     noconfigdirs="$noconfigdirs gprof"
 913     ;;
 914   h8300*-*-*)
 915     noconfigdirs="$noconfigdirs target-libgloss"
 916     ;;
 917   h8500-*-*)
 918     noconfigdirs="$noconfigdirs target-libgloss"
 919     ;;
 920   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 921     ;;
 922   hppa*64*-*-linux*)
 923     ;;
 924   hppa*-*-linux*)
 925     ;;
 926   hppa*-*-*elf* | \
 927   hppa*-*-lites* | \
 928   hppa*-*-openbsd* | \
 929   hppa*64*-*-*)
 930     ;;
 931   hppa*-hp-hpux11*)
 932     noconfigdirs="$noconfigdirs ld"
 933     ;;
 934   hppa*-*-pro*)
 935     ;;
 936   hppa*-*-*)
 937     noconfigdirs="$noconfigdirs ld"
 938     ;;
 939   i960-*-*)
 940     noconfigdirs="$noconfigdirs gdb"
 941     ;;
 942   ia64*-*-elf*)
 943     # No gdb support yet.
 944     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 945     ;;
 946   ia64*-**-hpux*)
 947     # No ld support yet.
 948     noconfigdirs="$noconfigdirs libgui itcl ld"
 949     ;;
 950   ia64*-*-*vms*)
 951     # No ld support yet.
 952     noconfigdirs="$noconfigdirs libgui itcl ld"
 953     ;;
 954   i[[3456789]]86-w64-mingw*)
 955     ;;
 956   i[[3456789]]86-*-mingw*)
 957     target_configdirs="$target_configdirs target-winsup"
 958     ;;
 959   *-*-cygwin*)
 960     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 961     noconfigdirs="$noconfigdirs target-libgloss"
 962     # always build newlib if winsup directory is present.
 963     if test -d "$srcdir/winsup/cygwin"; then
 964       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 965     elif test -d "$srcdir/newlib"; then
 966       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 967     fi
 968     ;;
 969   i[[3456789]]86-*-pe)
 970     noconfigdirs="$noconfigdirs target-libgloss"
 971     ;;
 972   i[[3456789]]86-*-sco3.2v5*)
 973     # The linker does not yet know about weak symbols in COFF,
 974     # and is not configured to handle mixed ELF and COFF.
 975     noconfigdirs="$noconfigdirs ld target-libgloss"
 976     ;;
 977   i[[3456789]]86-*-sco*)
 978     noconfigdirs="$noconfigdirs gprof target-libgloss"
 979     ;;
 980   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 981     noconfigdirs="$noconfigdirs target-libgloss"
 982     ;;
 983   i[[3456789]]86-*-sysv4*)
 984     noconfigdirs="$noconfigdirs target-libgloss"
 985     ;;
 986   i[[3456789]]86-*-beos*)
 987     noconfigdirs="$noconfigdirs gdb"
 988     ;;
 989   i[[3456789]]86-*-rdos*)
 990     noconfigdirs="$noconfigdirs gdb"
 991     ;;
 992   mmix-*-*)
 993     noconfigdirs="$noconfigdirs gdb"
 994     ;;
 995   mt-*-*)
 996     noconfigdirs="$noconfigdirs sim"
 997     ;;
 998   powerpc-*-aix*)
 999     # copied from rs6000-*-* entry
1000     noconfigdirs="$noconfigdirs gprof"
1001     ;;
1002   powerpc*-*-winnt* | powerpc*-*-pe*)
1003     target_configdirs="$target_configdirs target-winsup"
1004     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1005     # always build newlib.
1006     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1007     ;;
1008     # This is temporary until we can link against shared libraries
1009   powerpcle-*-solaris*)
1010     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1011     ;;
1012   powerpc-*-beos*)
1013     noconfigdirs="$noconfigdirs gdb"
1014     ;;
1015   rs6000-*-lynxos*)
1016     noconfigdirs="$noconfigdirs gprof"
1017     ;;
1018   rs6000-*-aix*)
1019     noconfigdirs="$noconfigdirs gprof"
1020     ;;
1021   rs6000-*-*)
1022     noconfigdirs="$noconfigdirs gprof"
1023     ;;
1024   m68k-apollo-*)
1025     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1026     ;;
1027   microblaze*)
1028     noconfigdirs="$noconfigdirs gprof"
1029     ;;
1030   mips*-sde-elf*)
1031     if test x$with_newlib = xyes; then
1032       noconfigdirs="$noconfigdirs gprof"
1033     fi
1034     ;;
1035   mips*-*-irix5*)
1036     noconfigdirs="$noconfigdirs gprof target-libgloss"
1037     ;;
1038   mips*-*-irix6*)
1039     noconfigdirs="$noconfigdirs gprof target-libgloss"
1040     ;;
1041   mips*-*-bsd*)
1042     noconfigdirs="$noconfigdirs gprof target-libgloss"
1043     ;;
1044   mips*-*-linux*)
1045     ;;
1046   mips*-*-*)
1047     noconfigdirs="$noconfigdirs gprof"
1048     ;;
1049   sh-*-* | sh64-*-*)
1050     case "${target}" in
1051       sh*-*-elf)
1052          ;;
1053       *)
1054          noconfigdirs="$noconfigdirs target-libgloss" ;;
1055     esac
1056     ;;
1057   sparc-*-sunos4*)
1058     if test x${is_cross_compiler} = xno ; then
1059            use_gnu_ld=no
1060     fi
1061     ;;
1062   tic6x-*-*)
1063     noconfigdirs="$noconfigdirs sim"
1064     ;;
1065   tilepro-*-* | tilegx-*-*)
1066     noconfigdirs="$noconfigdirs sim"
1067     ;;
1068   v810-*-*)
1069     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1070     ;;
1071   vax-*-*)
1072     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1073     ;;
1074 esac
1075
1076 # If we aren't building newlib, then don't build libgloss, since libgloss
1077 # depends upon some newlib header files.
1078 case "${noconfigdirs}" in
1079   *target-libgloss*) ;;
1080   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1081 esac
1082
1083 # Work in distributions that contain no compiler tools, like Autoconf.
1084 host_makefile_frag=/dev/null
1085 if test -d ${srcdir}/config ; then
1086 case "${host}" in
1087   i[[3456789]]86-*-msdosdjgpp*)
1088     host_makefile_frag="config/mh-djgpp"
1089     ;;
1090   *-cygwin*)
1091     ACX_CHECK_CYGWIN_CAT_WORKS
1092     host_makefile_frag="config/mh-cygwin"
1093     ;;
1094   *-mingw*)
1095     host_makefile_frag="config/mh-mingw"
1096     ;;
1097   hppa*-hp-hpux10*)
1098     host_makefile_frag="config/mh-pa-hpux10"
1099     ;;
1100   hppa*-hp-hpux*)
1101     host_makefile_frag="config/mh-pa"
1102     ;;
1103   hppa*-*)
1104     host_makefile_frag="config/mh-pa"
1105     ;;
1106   *-*-darwin*)
1107     host_makefile_frag="config/mh-darwin"
1108     ;;
1109   powerpc-*-aix*)
1110     host_makefile_frag="config/mh-ppc-aix"
1111     ;;
1112   rs6000-*-aix*)
1113     host_makefile_frag="config/mh-ppc-aix"
1114     ;;
1115 esac
1116 fi
1117
1118 if test "${build}" != "${host}" ; then
1119   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1120   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1121   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1122   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1123   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1124   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1125   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1126   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1127   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1128   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1129   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1130   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1131   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1132 else
1133   AR_FOR_BUILD="\$(AR)"
1134   AS_FOR_BUILD="\$(AS)"
1135   CC_FOR_BUILD="\$(CC)"
1136   CXX_FOR_BUILD="\$(CXX)"
1137   GCJ_FOR_BUILD="\$(GCJ)"
1138   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1139   GOC_FOR_BUILD="\$(GOC)"
1140   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1141   LD_FOR_BUILD="\$(LD)"
1142   NM_FOR_BUILD="\$(NM)"
1143   RANLIB_FOR_BUILD="\$(RANLIB)"
1144   WINDRES_FOR_BUILD="\$(WINDRES)"
1145   WINDMC_FOR_BUILD="\$(WINDMC)"
1146 fi
1147
1148 AC_PROG_CC
1149 AC_PROG_CXX
1150
1151 # We must set the default linker to the linker used by gcc for the correct
1152 # operation of libtool.  If LD is not defined and we are using gcc, try to
1153 # set the LD default to the ld used by gcc.
1154 if test -z "$LD"; then
1155   if test "$GCC" = yes; then
1156     case $build in
1157     *-*-mingw*)
1158       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1159     *)
1160       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1161     esac
1162     case $gcc_prog_ld in
1163     # Accept absolute paths.
1164     [[\\/]* | [A-Za-z]:[\\/]*)]
1165       LD="$gcc_prog_ld" ;;
1166     esac
1167   fi
1168 fi
1169
1170 ACX_PROG_GNAT
1171 ACX_PROG_CMP_IGNORE_INITIAL
1172
1173 AC_ARG_ENABLE([bootstrap],
1174 [AS_HELP_STRING([--enable-bootstrap],
1175                 [enable bootstrapping @<:@yes if native build@:>@])],,
1176 enable_bootstrap=default)
1177
1178 # Issue errors and warnings for invalid/strange bootstrap combinations.
1179 if test -r $srcdir/gcc/configure; then
1180   have_compiler=yes
1181 else
1182   have_compiler=no
1183 fi
1184
1185 case "$have_compiler:$host:$target:$enable_bootstrap" in
1186   *:*:*:no) ;;
1187
1188   # Default behavior.  Enable bootstrap if we have a compiler
1189   # and we are in a native configuration.
1190   yes:$build:$build:default)
1191     enable_bootstrap=yes ;;
1192
1193   *:*:*:default)
1194     enable_bootstrap=no ;;
1195
1196   # We have a compiler and we are in a native configuration, bootstrap is ok
1197   yes:$build:$build:yes)
1198     ;;
1199
1200   # Other configurations, but we have a compiler.  Assume the user knows
1201   # what he's doing.
1202   yes:*:*:yes)
1203     AC_MSG_WARN([trying to bootstrap a cross compiler])
1204     ;;
1205
1206   # No compiler: if they passed --enable-bootstrap explicitly, fail
1207   no:*:*:yes)
1208     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1209
1210   # Fail if wrong command line
1211   *)
1212     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1213     ;;
1214 esac
1215
1216 # Used for setting $lt_cv_objdir
1217 _LT_CHECK_OBJDIR
1218
1219 # Check for GMP, MPFR and MPC
1220 gmplibs="-lmpc -lmpfr -lgmp"
1221 gmpinc=
1222 have_gmp=no
1223
1224 # Specify a location for mpc
1225 # check for this first so it ends up on the link line before mpfr.
1226 AC_ARG_WITH(mpc,
1227 [AS_HELP_STRING([--with-mpc=PATH],
1228                 [specify prefix directory for installed MPC package.
1229                  Equivalent to --with-mpc-include=PATH/include
1230                  plus --with-mpc-lib=PATH/lib])])
1231 AC_ARG_WITH(mpc-include,
1232 [AS_HELP_STRING([--with-mpc-include=PATH],
1233                 [specify directory for installed MPC include files])])
1234 AC_ARG_WITH(mpc-lib,
1235 [AS_HELP_STRING([--with-mpc-lib=PATH],
1236                 [specify directory for the installed MPC library])])
1237
1238 if test "x$with_mpc" != x; then
1239   gmplibs="-L$with_mpc/lib $gmplibs"
1240   gmpinc="-I$with_mpc/include $gmpinc"
1241 fi
1242 if test "x$with_mpc_include" != x; then
1243   gmpinc="-I$with_mpc_include $gmpinc"
1244 fi
1245 if test "x$with_mpc_lib" != x; then
1246   gmplibs="-L$with_mpc_lib $gmplibs"
1247 fi
1248 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1249   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1250   gmpinc='-I$$s/mpc/src '"$gmpinc"
1251   # Do not test the mpc version.  Assume that it is sufficient, since
1252   # it is in the source tree, and the library has not been built yet
1253   # but it would be included on the link line in the version check below
1254   # hence making the test fail.
1255   have_gmp=yes
1256 fi
1257
1258 # Specify a location for mpfr
1259 # check for this first so it ends up on the link line before gmp.
1260 AC_ARG_WITH(mpfr-dir,
1261 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1262 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1263 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1264
1265 AC_ARG_WITH(mpfr,
1266 [AS_HELP_STRING([--with-mpfr=PATH],
1267                 [specify prefix directory for installed MPFR package.
1268                  Equivalent to --with-mpfr-include=PATH/include
1269                  plus --with-mpfr-lib=PATH/lib])])
1270 AC_ARG_WITH(mpfr-include,
1271 [AS_HELP_STRING([--with-mpfr-include=PATH],
1272                 [specify directory for installed MPFR include files])])
1273 AC_ARG_WITH(mpfr-lib,
1274 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1275                 [specify directory for the installed MPFR library])])
1276
1277 if test "x$with_mpfr" != x; then
1278   gmplibs="-L$with_mpfr/lib $gmplibs"
1279   gmpinc="-I$with_mpfr/include $gmpinc"
1280 fi
1281 if test "x$with_mpfr_include" != x; then
1282   gmpinc="-I$with_mpfr_include $gmpinc"
1283 fi
1284 if test "x$with_mpfr_lib" != x; then
1285   gmplibs="-L$with_mpfr_lib $gmplibs"
1286 fi
1287 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1288   # MPFR v3.1.0 moved the sources into a src sub-directory.
1289   if test -d ${srcdir}/mpfr/src; then
1290     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1291     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1292     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1293   else
1294     gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1295     gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1296     extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1297   fi
1298   # Do not test the mpfr version.  Assume that it is sufficient, since
1299   # it is in the source tree, and the library has not been built yet
1300   # but it would be included on the link line in the version check below
1301   # hence making the test fail.
1302   have_gmp=yes
1303 fi
1304
1305 # Specify a location for gmp
1306 AC_ARG_WITH(gmp-dir,
1307 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1308 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1309 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1310
1311 AC_ARG_WITH(gmp,
1312 [AS_HELP_STRING([--with-gmp=PATH],
1313                 [specify prefix directory for the installed GMP package.
1314                  Equivalent to --with-gmp-include=PATH/include
1315                  plus --with-gmp-lib=PATH/lib])])
1316 AC_ARG_WITH(gmp-include,
1317 [AS_HELP_STRING([--with-gmp-include=PATH],
1318                 [specify directory for installed GMP include files])])
1319 AC_ARG_WITH(gmp-lib,
1320 [AS_HELP_STRING([--with-gmp-lib=PATH],
1321                 [specify directory for the installed GMP library])])
1322
1323
1324 if test "x$with_gmp" != x; then
1325   gmplibs="-L$with_gmp/lib $gmplibs"
1326   gmpinc="-I$with_gmp/include $gmpinc"
1327 fi
1328 if test "x$with_gmp_include" != x; then
1329   gmpinc="-I$with_gmp_include $gmpinc"
1330 fi
1331 if test "x$with_gmp_lib" != x; then
1332   gmplibs="-L$with_gmp_lib $gmplibs"
1333 fi
1334 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1335   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1336   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1337   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1338   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1339   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1340   # Do not test the gmp version.  Assume that it is sufficient, since
1341   # it is in the source tree, and the library has not been built yet
1342   # but it would be included on the link line in the version check below
1343   # hence making the test fail.
1344   have_gmp=yes
1345 fi
1346
1347 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1348   have_gmp=yes
1349   saved_CFLAGS="$CFLAGS"
1350   CFLAGS="$CFLAGS $gmpinc"
1351   # Check for the recommended and required versions of GMP.
1352   AC_MSG_CHECKING([for the correct version of gmp.h])
1353   AC_TRY_COMPILE([#include "gmp.h"],[
1354   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1355   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1356   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1357   choke me
1358   #endif
1359   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1360   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1361   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1362   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1363   choke me
1364   #endif
1365   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1366    [AC_MSG_RESULT([no]); have_gmp=no])
1367
1368   # If we have GMP, check the MPFR version.
1369   if test x"$have_gmp" = xyes; then
1370     # Check for the recommended and required versions of MPFR.
1371     AC_MSG_CHECKING([for the correct version of mpfr.h])
1372     AC_TRY_COMPILE([#include <gmp.h>
1373     #include <mpfr.h>],[
1374     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1375     choke me
1376     #endif
1377     ], [AC_TRY_COMPILE([#include <gmp.h>
1378     #include <mpfr.h>],[
1379     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1380     choke me
1381     #endif
1382     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1383      [AC_MSG_RESULT([no]); have_gmp=no])
1384   fi
1385
1386   # Check for the MPC header version.
1387   if test x"$have_gmp" = xyes ; then
1388     # Check for the recommended and required versions of MPC.
1389     AC_MSG_CHECKING([for the correct version of mpc.h])
1390     AC_TRY_COMPILE([#include <mpc.h>],[
1391     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1392     choke me
1393     #endif
1394     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1395     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1396     choke me
1397     #endif
1398     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1399      [AC_MSG_RESULT([no]); have_gmp=no])
1400   fi
1401
1402   # Now check the MPFR library.
1403   if test x"$have_gmp" = xyes; then
1404     saved_LIBS="$LIBS"
1405     LIBS="$LIBS $gmplibs"
1406     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1407     AC_TRY_LINK([#include <mpc.h>],[
1408     mpfr_t n;
1409     mpfr_t x;
1410     mpc_t c;
1411     int t;
1412     mpfr_init (n);
1413     mpfr_init (x);
1414     mpfr_atan2 (n, n, x, GMP_RNDN);
1415     mpfr_erfc (n, x, GMP_RNDN);
1416     mpfr_subnormalize (x, t, GMP_RNDN);
1417     mpfr_clear(n);
1418     mpfr_clear(x);
1419     mpc_init2 (c, 53);
1420     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1421     mpc_cosh (c, c, MPC_RNDNN);
1422     mpc_pow (c, c, c, MPC_RNDNN);
1423     mpc_acosh (c, c, MPC_RNDNN);
1424     mpc_clear (c);
1425     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1426     LIBS="$saved_LIBS"
1427   fi
1428
1429   CFLAGS="$saved_CFLAGS"
1430
1431 # The library versions listed in the error message below should match
1432 # the HARD-minimums enforced above.
1433   if test x$have_gmp != xyes; then
1434     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1435 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1436 their locations.  Source code for these libraries can be found at
1437 their respective hosting sites as well as at
1438 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1439 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1440 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1441 make sure that you have installed both the libraries and the header
1442 files.  They may be located in separate packages.])
1443   fi
1444 fi
1445
1446 # Flags needed for both GMP, MPFR and/or MPC.
1447 AC_SUBST(gmplibs)
1448 AC_SUBST(gmpinc)
1449 AC_SUBST(extra_mpfr_configure_flags)
1450 AC_SUBST(extra_mpc_gmp_configure_flags)
1451 AC_SUBST(extra_mpc_mpfr_configure_flags)
1452 AC_SUBST(extra_isl_gmp_configure_flags)
1453
1454 # Allow host libstdc++ to be specified for static linking with PPL.
1455 AC_ARG_WITH(host-libstdcxx,
1456 [AS_HELP_STRING([--with-host-libstdcxx=L],
1457                 [use linker arguments L to link with libstdc++
1458                  when linking with PPL])])
1459
1460 case $with_host_libstdcxx in
1461   no|yes)
1462     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1463     ;;
1464 esac
1465
1466 # Linker flags to use for stage1 or when not boostrapping.
1467 AC_ARG_WITH(stage1-ldflags,
1468 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1469 [if test "$withval" = "no" -o "$withval" = "yes"; then
1470    stage1_ldflags=
1471  else
1472    stage1_ldflags=$withval
1473  fi],
1474 [stage1_ldflags=])
1475 AC_SUBST(stage1_ldflags)
1476
1477 # Libraries to use for stage1 or when not bootstrapping.
1478 AC_ARG_WITH(stage1-libs,
1479 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1480 [if test "$withval" = "no" -o "$withval" = "yes"; then
1481    stage1_libs=
1482  else
1483    stage1_libs=$withval
1484  fi],
1485 [stage1_libs=$with_host_libstdcxx])
1486 AC_SUBST(stage1_libs)
1487
1488 # Libraries to use for stage2 and later builds.  This defaults to the
1489 # argument passed to --with-host-libstdcxx.
1490 AC_ARG_WITH(boot-libs,
1491 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1492 [if test "$withval" = "no" -o "$withval" = "yes"; then
1493    poststage1_libs=
1494  else
1495    poststage1_libs=$withval
1496  fi],
1497 [poststage1_libs=$with_host_libstdcxx])
1498 AC_SUBST(poststage1_libs)
1499
1500 # Linker flags to use for stage2 and later builds.
1501 AC_ARG_WITH(boot-ldflags,
1502 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1503                 [linker flags for stage2 and later])],
1504 [if test "$withval" = "no" -o "$withval" = "yes"; then
1505    poststage1_ldflags=
1506  else
1507    poststage1_ldflags=$withval
1508  fi],
1509 [poststage1_ldflags=
1510  # In stages 2 and 3, default to linking libstdc++ and libgcc
1511  # statically.  But if the user explicitly specified the libraries to
1512  # use, trust that they are doing what they want.
1513  if test "$poststage1_libs" = ""; then
1514    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1515  fi])
1516 AC_SUBST(poststage1_ldflags)
1517
1518 # Check for ISL
1519 dnl Provide configure switches and initialize islinc & isllibs
1520 dnl with user input.
1521 ISL_INIT_FLAGS
1522 if test "x$with_isl" != "xno"; then
1523   dnl The minimal version of ISL required for Graphite.
1524   ISL_CHECK_VERSION(0,10)
1525
1526   dnl Only execute fail-action, if ISL has been requested.
1527   ISL_IF_FAILED([
1528     AC_MSG_ERROR([Unable to find a usable ISL.  See config.log for details.])])
1529 fi
1530
1531 # Check for CLOOG
1532 dnl Provide configure switches and initialize clooginc & clooglibs
1533 dnl with user input.
1534 CLOOG_INIT_FLAGS
1535 if test "x$isllibs" = x && test "x$islinc" = x; then
1536   clooglibs=
1537   clooginc=
1538 elif test "x$with_cloog" != "xno"; then
1539   dnl The minimal version of CLooG required for Graphite.
1540   dnl
1541   dnl If we use CLooG-Legacy, the provided version information is
1542   dnl ignored.
1543   CLOOG_CHECK_VERSION(0,17,0)
1544
1545   dnl Only execute fail-action, if CLooG has been requested.
1546   CLOOG_IF_FAILED([
1547     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1548 fi
1549
1550 # If either the ISL or the CLooG check failed, disable builds of in-tree
1551 # variants of both
1552 if test "x$clooglibs" = x && test "x$clooginc" = x; then
1553   noconfigdirs="$noconfigdirs cloog isl"
1554 fi
1555
1556 # Check for LTO support.
1557 AC_ARG_ENABLE(lto,
1558 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1559 enable_lto=$enableval,
1560 enable_lto=yes; default_enable_lto=yes)
1561
1562 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1563   build_lto_plugin=yes
1564 ],[if test x"$default_enable_lto" = x"yes" ; then
1565     case $target in
1566       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1567       # On other non-ELF platforms, LTO has yet to be validated.
1568       *) enable_lto=no ;;
1569     esac
1570   else
1571   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1572   # It would also be nice to check the binutils support, but we don't
1573   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1574   # warn during gcc/ subconfigure; unless you're bootstrapping with
1575   # -flto it won't be needed until after installation anyway.
1576     case $target in
1577       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1578       *) if test x"$enable_lto" = x"yes"; then
1579         AC_MSG_ERROR([LTO support is not enabled for this target.])
1580         fi
1581       ;;
1582     esac
1583   fi
1584   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1585   # Build it unless LTO was explicitly disabled.
1586   case $target in
1587     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1588     *) ;;
1589   esac
1590 ])
1591
1592
1593 # By default, C and C++ are the only stage 1 languages.
1594 stage1_languages=,c,
1595
1596 # Target libraries that we bootstrap.
1597 bootstrap_target_libs=,target-libgcc,
1598
1599 # Figure out what language subdirectories are present.
1600 # Look if the user specified --enable-languages="..."; if not, use
1601 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1602 # go away some day.
1603 # NB:  embedded tabs in this IF block -- do not untabify
1604 if test -d ${srcdir}/gcc; then
1605   if test x"${enable_languages+set}" != xset; then
1606     if test x"${LANGUAGES+set}" = xset; then
1607       enable_languages="${LANGUAGES}"
1608         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1609     else
1610       enable_languages=all
1611     fi
1612   else
1613     if test x"${enable_languages}" = x ||
1614        test x"${enable_languages}" = xyes;
1615        then
1616       echo configure.in: --enable-languages needs at least one language argument 1>&2
1617       exit 1
1618     fi
1619   fi
1620   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1621
1622   # 'f95' is the old name for the 'fortran' language. We issue a warning
1623   # and make the substitution.
1624   case ,${enable_languages}, in
1625     *,f95,*)
1626       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1627       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1628       ;;
1629   esac
1630
1631   # If bootstrapping, C++ must be enabled.
1632   case ",$enable_languages,:$enable_bootstrap" in
1633     *,c++,*:*) ;;
1634     *:yes)
1635       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1636         enable_languages="${enable_languages},c++"
1637       else
1638         AC_MSG_ERROR([bootstrapping requires c++ sources])
1639       fi
1640       ;;
1641   esac
1642
1643   # First scan to see if an enabled language requires some other language.
1644   # We assume that a given config-lang.in will list all the language
1645   # front ends it requires, even if some are required indirectly.
1646   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1647     case ${lang_frag} in
1648       ..) ;;
1649       # The odd quoting in the next line works around
1650       # an apparent bug in bash 1.12 on linux.
1651       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1652       *)
1653         # From the config-lang.in, get $language, $lang_requires, and
1654         # $lang_requires_boot_languages.
1655         language=
1656         lang_requires=
1657         lang_requires_boot_languages=
1658         . ${lang_frag}
1659         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1660           case ,${enable_languages}, in
1661             *,$other,*) ;;
1662             *,all,*) ;;
1663             *,$language,*)
1664               echo " \`$other' language required by \`$language'; enabling" 1>&2
1665               enable_languages="${enable_languages},${other}"
1666               ;;
1667           esac
1668         done
1669         for other in ${lang_requires_boot_languages} ; do
1670           if test "$other" != "c"; then
1671             case ,${enable_stage1_languages}, in
1672               *,$other,*) ;;
1673               *,all,*) ;;
1674               *)
1675                 case ,${enable_languages}, in
1676                   *,$language,*)
1677                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1678                     enable_stage1_languages="$enable_stage1_languages,${other}"
1679                     ;;
1680                 esac
1681                 ;;
1682             esac
1683           fi
1684         done
1685         ;;
1686     esac
1687   done
1688
1689   new_enable_languages=,c,
1690
1691   # If LTO is enabled, add the LTO front end.
1692   extra_host_libiberty_configure_flags=
1693   if test "$enable_lto" = "yes" ; then
1694     case ,${enable_languages}, in
1695       *,lto,*) ;;
1696       *) enable_languages="${enable_languages},lto" ;;
1697     esac
1698     if test "${build_lto_plugin}" = "yes" ; then
1699       configdirs="$configdirs lto-plugin"
1700       extra_host_libiberty_configure_flags=--enable-shared
1701     fi
1702   fi
1703   AC_SUBST(extra_host_libiberty_configure_flags)
1704
1705   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1706   potential_languages=,c,
1707
1708   enabled_target_libs=
1709   disabled_target_libs=
1710
1711   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1712     case ${lang_frag} in
1713       ..) ;;
1714       # The odd quoting in the next line works around
1715       # an apparent bug in bash 1.12 on linux.
1716       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1717       *)
1718         # From the config-lang.in, get $language, $target_libs,
1719         # $lang_dirs, $boot_language, and $build_by_default
1720         language=
1721         target_libs=
1722         lang_dirs=
1723         subdir_requires=
1724         boot_language=no
1725         build_by_default=yes
1726         . ${lang_frag}
1727         if test x${language} = x; then
1728           echo "${lang_frag} doesn't set \$language." 1>&2
1729           exit 1
1730         fi
1731
1732         if test "$language" = "c++"; then
1733           boot_language=yes
1734         fi
1735
1736         case ,${enable_languages}, in
1737           *,${language},*)
1738             # Language was explicitly selected; include it
1739             # unless it is C, which is enabled by default.
1740             if test "$language" != "c"; then
1741               add_this_lang=yes
1742             fi
1743             ;;
1744           *,all,*)
1745             # 'all' was selected, select it if it is a default language
1746             add_this_lang=${build_by_default}
1747             ;;
1748           *)
1749             add_this_lang=no
1750             ;;
1751         esac
1752
1753         # Disable languages that need other directories if these aren't available.
1754         for i in $subdir_requires; do
1755           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1756           case ,${enable_languages}, in
1757             *,${language},*)
1758               # Specifically requested language; tell them.
1759               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1760               ;;
1761             *)
1762               # Silently disable.
1763               add_this_lang=unsupported
1764               ;;
1765           esac
1766         done
1767
1768         # Disable Ada if no preexisting GNAT is available.
1769         case ,${enable_languages},:${language}:${have_gnat} in
1770           *,${language},*:ada:no)
1771             # Specifically requested language; tell them.
1772             AC_MSG_ERROR([GNAT is required to build $language])
1773             ;;
1774           *:ada:no)
1775             # Silently disable.
1776             add_this_lang=unsupported
1777             ;;
1778         esac
1779
1780         # Disable a language that is unsupported by the target.
1781         case " $unsupported_languages " in
1782           *" $language "*)
1783             add_this_lang=unsupported
1784             ;;
1785         esac
1786
1787         case $add_this_lang in
1788           unsupported)
1789             # Remove language-dependent dirs.
1790             disabled_target_libs="$disabled_target_libs $target_libs"
1791             noconfigdirs="$noconfigdirs $lang_dirs"
1792             ;;
1793           no)
1794             # Remove language-dependent dirs; still show language as supported.
1795             disabled_target_libs="$disabled_target_libs $target_libs"
1796             noconfigdirs="$noconfigdirs $lang_dirs"
1797             potential_languages="${potential_languages}${language},"
1798             ;;
1799           yes)
1800             new_enable_languages="${new_enable_languages}${language},"
1801             potential_languages="${potential_languages}${language},"
1802             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1803             enabled_target_libs="$enabled_target_libs $target_libs"
1804             case "${boot_language}:,$enable_stage1_languages," in
1805               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1806                 # Add to (comma-separated) list of stage 1 languages.
1807                 case ",$stage1_languages," in
1808                   *,$language,* | ,yes, | ,all,) ;;
1809                   *) stage1_languages="${stage1_languages}${language}," ;;
1810                 esac
1811                 # We need to bootstrap any supporting libraries.
1812                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1813                 ;;
1814             esac
1815             ;;
1816         esac
1817         ;;
1818     esac
1819   done
1820
1821   # Add target libraries which are only needed for disabled languages
1822   # to noconfigdirs.
1823   if test -n "$disabled_target_libs"; then
1824     for dir in $disabled_target_libs; do
1825       case " $enabled_target_libs " in
1826       *" ${dir} "*) ;;
1827       *) noconfigdirs="$noconfigdirs $dir" ;;
1828       esac
1829     done
1830   fi
1831
1832   AC_ARG_ENABLE(stage1-languages,
1833   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1834                   [choose additional languages to build during
1835                   stage1.  Mostly useful for compiler development])],
1836   [case ,${enable_stage1_languages}, in
1837     ,no,|,,)
1838       # Set it to something that will have no effect in the loop below
1839       enable_stage1_languages=c ;;
1840     ,yes,)
1841       enable_stage1_languages=`echo $new_enable_languages | \
1842         sed -e "s/^,//" -e "s/,$//" ` ;;
1843     *,all,*)
1844       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1845         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1846   esac
1847
1848   # Add "good" languages from enable_stage1_languages to stage1_languages,
1849   # while "bad" languages go in missing_languages.  Leave no duplicates.
1850   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1851     case $potential_languages in
1852       *,$i,*)
1853         case $stage1_languages in
1854           *,$i,*) ;;
1855           *) stage1_languages="$stage1_languages$i," ;;
1856         esac ;;
1857       *)
1858         case $missing_languages in
1859           *,$i,*) ;;
1860           *) missing_languages="$missing_languages$i," ;;
1861         esac ;;
1862      esac
1863   done])
1864
1865   # Remove leading/trailing commas that were added for simplicity
1866   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1867   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1868   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1869   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1870
1871   if test "x$missing_languages" != x; then
1872     AC_MSG_ERROR([
1873 The following requested languages could not be built: ${missing_languages}
1874 Supported languages are: ${potential_languages}])
1875   fi
1876   if test "x$new_enable_languages" != "x$enable_languages"; then
1877     echo The following languages will be built: ${new_enable_languages}
1878     enable_languages="$new_enable_languages"
1879   fi
1880
1881   AC_SUBST(stage1_languages)
1882   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1883 fi
1884
1885 # Handle --disable-<component> generically.
1886 for dir in $configdirs $build_configdirs $target_configdirs ; do
1887   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1888   varname=`echo $dirname | sed -e s/+/_/g`
1889   if eval test x\${enable_${varname}} "=" xno ; then
1890     noconfigdirs="$noconfigdirs $dir"
1891   fi
1892 done
1893
1894 # Check for Boehm's garbage collector
1895 AC_ARG_ENABLE(objc-gc,
1896 [AS_HELP_STRING([--enable-objc-gc],
1897                 [enable use of Boehm's garbage collector with the
1898                  GNU Objective-C runtime])],
1899 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1900   *,objc,*:*:yes:*target-boehm-gc*)
1901     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1902     ;;
1903 esac])
1904
1905 # Make sure we only build Boehm's garbage collector if required.
1906 case ,${enable_languages},:${enable_objc_gc} in
1907   *,objc,*:yes)
1908     # Keep target-boehm-gc if requested for Objective-C.
1909     ;;
1910   *)
1911     # Otherwise remove target-boehm-gc depending on target-libjava.
1912     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1913       noconfigdirs="$noconfigdirs target-boehm-gc"
1914     fi
1915     ;;
1916 esac
1917
1918 # Disable libitm if we're not building C++
1919 case ,${enable_languages}, in
1920   *,c++,*) ;;
1921   *)
1922     noconfigdirs="$noconfigdirs target-libitm"
1923     ;;
1924 esac
1925
1926 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1927 # $build_configdirs and $target_configdirs.
1928 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1929
1930 notsupp=""
1931 for dir in . $skipdirs $noconfigdirs ; do
1932   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1933   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1934     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1935     if test -r $srcdir/$dirname/configure ; then
1936       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1937         true
1938       else
1939         notsupp="$notsupp $dir"
1940       fi
1941     fi
1942   fi
1943   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1944     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1945     if test -r $srcdir/$dirname/configure ; then
1946       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1947         true
1948       else
1949         notsupp="$notsupp $dir"
1950       fi
1951     fi
1952   fi
1953   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1954     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
1955     if test -r $srcdir/$dirname/configure ; then
1956       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1957         true
1958       else
1959         notsupp="$notsupp $dir"
1960       fi
1961     fi
1962   fi
1963 done
1964
1965 # Quietly strip out all directories which aren't configurable in this tree.
1966 # This relies on all configurable subdirectories being autoconfiscated, which
1967 # is now the case.
1968 build_configdirs_all="$build_configdirs"
1969 build_configdirs=
1970 for i in ${build_configdirs_all} ; do
1971   j=`echo $i | sed -e s/build-//g`
1972   if test -f ${srcdir}/$j/configure ; then
1973     build_configdirs="${build_configdirs} $i"
1974   fi
1975 done
1976
1977 configdirs_all="$configdirs"
1978 configdirs=
1979 for i in ${configdirs_all} ; do
1980   if test -f ${srcdir}/$i/configure ; then
1981     configdirs="${configdirs} $i"
1982   fi
1983 done
1984
1985 target_configdirs_all="$target_configdirs"
1986 target_configdirs=
1987 for i in ${target_configdirs_all} ; do
1988   j=`echo $i | sed -e s/target-//g`
1989   if test -f ${srcdir}/$j/configure ; then
1990     target_configdirs="${target_configdirs} $i"
1991   fi
1992 done
1993
1994 # Produce a warning message for the subdirs we can't configure.
1995 # This isn't especially interesting in the Cygnus tree, but in the individual
1996 # FSF releases, it's important to let people know when their machine isn't
1997 # supported by the one or two programs in a package.
1998
1999 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2000   # If $appdirs is non-empty, at least one of those directories must still
2001   # be configured, or we error out.  (E.g., if the gas release supports a
2002   # specified target in some subdirs but not the gas subdir, we shouldn't
2003   # pretend that all is well.)
2004   if test -n "$appdirs" ; then
2005     for dir in $appdirs ; do
2006       if test -r $dir/Makefile.in ; then
2007         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2008           appdirs=""
2009           break
2010         fi
2011         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2012           appdirs=""
2013           break
2014         fi
2015       fi
2016     done
2017     if test -n "$appdirs" ; then
2018       echo "*** This configuration is not supported by this package." 1>&2
2019       exit 1
2020     fi
2021   fi
2022   # Okay, some application will build, or we don't care to check.  Still
2023   # notify of subdirs not getting built.
2024   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2025   echo "    ${notsupp}" 1>&2
2026   echo "    (Any other directories should still work fine.)" 1>&2
2027 fi
2028
2029 case "$host" in
2030   *msdosdjgpp*)
2031     enable_gdbtk=no ;;
2032 esac
2033
2034 # To find our prefix, in gcc_cv_tool_prefix.
2035 ACX_TOOL_DIRS
2036
2037 copy_dirs=
2038
2039 AC_ARG_WITH([build-sysroot],
2040   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2041                   [use sysroot as the system root during the build])],
2042   [if test x"$withval" != x ; then
2043      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2044    fi],
2045   [SYSROOT_CFLAGS_FOR_TARGET=])
2046 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2047
2048 AC_ARG_WITH([debug-prefix-map],
2049   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2050                   [map A to B, C to D ... in debug information])],
2051   [if test x"$withval" != x; then
2052      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2053      for debug_map in $withval; do
2054        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2055      done
2056    fi],
2057   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2058 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2059
2060 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2061 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2062 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2063 # We want to ensure that TARGET libraries (which we know are built with
2064 # gcc) are built with "-O2 -g", so include those options when setting
2065 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2066 if test "x$CFLAGS_FOR_TARGET" = x; then
2067   CFLAGS_FOR_TARGET=$CFLAGS
2068   case " $CFLAGS " in
2069     *" -O2 "*) ;;
2070     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2071   esac
2072   case " $CFLAGS " in
2073     *" -g "* | *" -g3 "*) ;;
2074     *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2075   esac
2076 fi
2077 AC_SUBST(CFLAGS_FOR_TARGET)
2078
2079 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2080   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2081   case " $CXXFLAGS " in
2082     *" -O2 "*) ;;
2083     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2084   esac
2085   case " $CXXFLAGS " in
2086     *" -g "* | *" -g3 "*) ;;
2087     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2088   esac
2089 fi
2090 AC_SUBST(CXXFLAGS_FOR_TARGET)
2091
2092 AC_SUBST(LDFLAGS_FOR_TARGET)
2093
2094 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2095 # the named directory are copied to $(tooldir)/sys-include.
2096 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2097   if test x${is_cross_compiler} = xno ; then
2098     echo 1>&2 '***' --with-headers is only supported when cross compiling
2099     exit 1
2100   fi
2101   if test x"${with_headers}" != xyes ; then
2102     x=${gcc_cv_tool_prefix}
2103     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2104   fi
2105 fi
2106
2107 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2108 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2109 # are permitted.
2110 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2111   if test x${is_cross_compiler} = xno ; then
2112     echo 1>&2 '***' --with-libs is only supported when cross compiling
2113     exit 1
2114   fi
2115   if test x"${with_libs}" != xyes ; then
2116     # Copy the libraries in reverse order, so that files in the first named
2117     # library override files in subsequent libraries.
2118     x=${gcc_cv_tool_prefix}
2119     for l in ${with_libs}; do
2120       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2121     done
2122   fi
2123 fi
2124
2125 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2126 #
2127 # This is done by determining whether or not the appropriate directory
2128 # is available, and by checking whether or not specific configurations
2129 # have requested that this magic not happen.
2130 #
2131 # The command line options always override the explicit settings in
2132 # configure.in, and the settings in configure.in override this magic.
2133 #
2134 # If the default for a toolchain is to use GNU as and ld, and you don't
2135 # want to do that, then you should use the --without-gnu-as and
2136 # --without-gnu-ld options for the configure script.  Similarly, if
2137 # the default is to use the included zlib and you don't want to do that,
2138 # you should use the --with-system-zlib option for the configure script.
2139
2140 if test x${use_gnu_as} = x &&
2141    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2142   with_gnu_as=yes
2143   extra_host_args="$extra_host_args --with-gnu-as"
2144 fi
2145
2146 if test x${use_gnu_ld} = x &&
2147    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2148   with_gnu_ld=yes
2149   extra_host_args="$extra_host_args --with-gnu-ld"
2150 fi
2151
2152 if test x${use_included_zlib} = x &&
2153    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2154   :
2155 else
2156   with_system_zlib=yes
2157   extra_host_args="$extra_host_args --with-system-zlib"
2158 fi
2159
2160 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2161 # can detect this case.
2162
2163 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2164   with_newlib=yes
2165   extra_host_args="$extra_host_args --with-newlib"
2166 fi
2167
2168 # Handle ${copy_dirs}
2169 set fnord ${copy_dirs}
2170 shift
2171 while test $# != 0 ; do
2172   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2173     :
2174   else
2175     echo Copying $1 to $2
2176
2177     # Use the install script to create the directory and all required
2178     # parent directories.
2179     if test -d $2 ; then
2180       :
2181     else
2182       echo >config.temp
2183       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2184     fi
2185
2186     # Copy the directory, assuming we have tar.
2187     # FIXME: Should we use B in the second tar?  Not all systems support it.
2188     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2189
2190     # It is the responsibility of the user to correctly adjust all
2191     # symlinks.  If somebody can figure out how to handle them correctly
2192     # here, feel free to add the code.
2193
2194     echo $1 > $2/COPIED
2195   fi
2196   shift; shift
2197 done
2198
2199 # Determine a target-dependent exec_prefix that the installed
2200 # gcc will search in.  Keep this list sorted by triplet, with
2201 # the *-*-osname triplets last.
2202 md_exec_prefix=
2203 case "${target}" in
2204   i[[34567]]86-pc-msdosdjgpp*)
2205     md_exec_prefix=/dev/env/DJDIR/bin
2206     ;;
2207   *-*-hpux* | \
2208   *-*-nto-qnx* | \
2209   *-*-solaris2*)
2210     md_exec_prefix=/usr/ccs/bin
2211     ;;
2212 esac
2213
2214 extra_arflags_for_target=
2215 extra_nmflags_for_target=
2216 extra_ranlibflags_for_target=
2217 target_makefile_frag=/dev/null
2218 case "${target}" in
2219   spu-*-*)
2220     target_makefile_frag="config/mt-spu"
2221     ;;
2222   mips*-sde-elf*)
2223     target_makefile_frag="config/mt-sde"
2224     ;;
2225   mipsisa*-*-elfoabi*)
2226     target_makefile_frag="config/mt-mips-elfoabi"
2227     ;;
2228   mips*-*-*linux* | mips*-*-gnu*)
2229     target_makefile_frag="config/mt-mips-gnu"
2230     ;;
2231   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2232     target_makefile_frag="config/mt-gnu"
2233     ;;
2234   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2235     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2236     # commands to handle both 32-bit and 64-bit objects.  These flags are
2237     # harmless if we're using GNU nm or ar.
2238     extra_arflags_for_target=" -X32_64"
2239     extra_nmflags_for_target=" -B -X32_64"
2240     ;;
2241 esac
2242
2243 alphaieee_frag=/dev/null
2244 case $target in
2245   alpha*-*-*)
2246     # This just makes sure to use the -mieee option to build target libs.
2247     # This should probably be set individually by each library.
2248     alphaieee_frag="config/mt-alphaieee"
2249     ;;
2250 esac
2251
2252 # If --enable-target-optspace always use -Os instead of -O2 to build
2253 # the target libraries, similarly if it is not specified, use -Os
2254 # on selected platforms.
2255 ospace_frag=/dev/null
2256 case "${enable_target_optspace}:${target}" in
2257   yes:*)
2258     ospace_frag="config/mt-ospace"
2259     ;;
2260   :d30v-*)
2261     ospace_frag="config/mt-d30v"
2262     ;;
2263   :m32r-* | :d10v-* | :fr30-*)
2264     ospace_frag="config/mt-ospace"
2265     ;;
2266   no:* | :*)
2267     ;;
2268   *)
2269     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2270     ;;
2271 esac
2272
2273 # Some systems (e.g., one of the i386-aix systems the gas testers are
2274 # using) don't handle "\$" correctly, so don't use it here.
2275 tooldir='${exec_prefix}'/${target_noncanonical}
2276 build_tooldir=${tooldir}
2277
2278 # Create a .gdbinit file which runs the one in srcdir
2279 # and tells GDB to look there for source files.
2280
2281 if test -r ${srcdir}/.gdbinit ; then
2282   case ${srcdir} in
2283     .) ;;
2284     *) cat > ./.gdbinit <<EOF
2285 # ${NO_EDIT}
2286 dir ${srcdir}
2287 dir .
2288 source ${srcdir}/.gdbinit
2289 EOF
2290     ;;
2291   esac
2292 fi
2293
2294 # Make sure that the compiler is able to generate an executable.  If it
2295 # can't, we are probably in trouble.  We don't care whether we can run the
2296 # executable--we might be using a cross compiler--we only care whether it
2297 # can be created.  At this point the main configure script has set CC.
2298 we_are_ok=no
2299 echo "int main () { return 0; }" > conftest.c
2300 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2301 if test $? = 0 ; then
2302   if test -s conftest || test -s conftest.exe ; then
2303     we_are_ok=yes
2304   fi
2305 fi
2306 case $we_are_ok in
2307   no)
2308     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2309     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2310     rm -f conftest*
2311     exit 1
2312     ;;
2313 esac
2314 rm -f conftest*
2315
2316 # Decide which environment variable is used to find dynamic libraries.
2317 case "${host}" in
2318   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2319   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2320   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2321   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2322 esac
2323
2324 # On systems where the dynamic library environment variable is PATH,
2325 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2326 # built executables to PATH.
2327 if test "$RPATH_ENVVAR" = PATH; then
2328   GCC_SHLIB_SUBDIR=/shlib
2329 else
2330   GCC_SHLIB_SUBDIR=
2331 fi
2332
2333 # Record target_configdirs and the configure arguments for target and
2334 # build configuration in Makefile.
2335 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2336 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2337
2338 # If we are building libgomp, bootstrap it.
2339 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2340   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2341 fi
2342
2343 # Determine whether gdb needs tk/tcl or not.
2344 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2345 # and in that case we want gdb to be built without tk.  Ugh!
2346 # In fact I believe gdb is the *only* package directly dependent on tk,
2347 # so we should be able to put the 'maybe's in unconditionally and
2348 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2349 # 100% sure that that's safe though.
2350
2351 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2352 case "$enable_gdbtk" in
2353   no)
2354     GDB_TK="" ;;
2355   yes)
2356     GDB_TK="${gdb_tk}" ;;
2357   *)
2358     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2359     # distro.  Eventually someone will fix this and move Insight, nee
2360     # gdbtk to a separate directory.
2361     if test -d ${srcdir}/gdb/gdbtk ; then
2362       GDB_TK="${gdb_tk}"
2363     else
2364       GDB_TK=""
2365     fi
2366     ;;
2367 esac
2368 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2369 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2370
2371 # Strip out unwanted targets.
2372
2373 # While at that, we remove Makefiles if we were started for recursive
2374 # configuration, so that the top-level Makefile reconfigures them,
2375 # like we used to do when configure itself was recursive.
2376
2377 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2378 # but now we're fixing up the Makefile ourselves with the additional
2379 # commands passed to AC_CONFIG_FILES.  Use separate variables
2380 # extrasub-{build,host,target} not because there is any reason to split
2381 # the substitutions up that way, but only to remain below the limit of
2382 # 99 commands in a script, for HP-UX sed.
2383 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2384
2385 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2386   yes:yes:*\ gold\ *:*,c++,*) ;;
2387   yes:yes:*\ gold\ *:*)
2388     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2389     ;;
2390 esac
2391
2392 # Adjust the toplevel makefile according to whether bootstrap was selected.
2393 case $enable_bootstrap in
2394   yes)
2395     bootstrap_suffix=bootstrap
2396     BUILD_CONFIG=bootstrap-debug
2397     ;;
2398   no)
2399     bootstrap_suffix=no-bootstrap
2400     BUILD_CONFIG=
2401     ;;
2402 esac
2403
2404 AC_MSG_CHECKING(for default BUILD_CONFIG)
2405
2406 AC_ARG_WITH([build-config],
2407   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2408                   [use config/NAME.mk build configuration])],
2409   [case $with_build_config in
2410    yes) with_build_config= ;;
2411    no) with_build_config= BUILD_CONFIG= ;;
2412    esac])
2413
2414 if test "x${with_build_config}" != x; then
2415   BUILD_CONFIG=$with_build_config
2416 else
2417   case $BUILD_CONFIG in
2418   bootstrap-debug)
2419     if echo "int f (void) { return 0; }" > conftest.c &&
2420        ${CC} -c conftest.c &&
2421        mv conftest.o conftest.o.g0 &&
2422        ${CC} -c -g conftest.c &&
2423        mv conftest.o conftest.o.g &&
2424        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2425       :
2426     else
2427       BUILD_CONFIG=
2428     fi
2429     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2430     ;;
2431   esac
2432 fi
2433 AC_MSG_RESULT($BUILD_CONFIG)
2434 AC_SUBST(BUILD_CONFIG)
2435
2436 extrasub_build=
2437 for module in ${build_configdirs} ; do
2438   if test -z "${no_recursion}" \
2439      && test -f ${build_subdir}/${module}/Makefile; then
2440     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2441     rm -f ${build_subdir}/${module}/Makefile
2442   fi
2443   extrasub_build="$extrasub_build
2444 /^@if build-$module\$/d
2445 /^@endif build-$module\$/d
2446 /^@if build-$module-$bootstrap_suffix\$/d
2447 /^@endif build-$module-$bootstrap_suffix\$/d"
2448 done
2449 extrasub_host=
2450 for module in ${configdirs} ; do
2451   if test -z "${no_recursion}"; then
2452     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2453       if test -f ${file}; then
2454         echo 1>&2 "*** removing ${file} to force reconfigure"
2455         rm -f ${file}
2456       fi
2457     done
2458   fi
2459   extrasub_host="$extrasub_host
2460 /^@if $module\$/d
2461 /^@endif $module\$/d
2462 /^@if $module-$bootstrap_suffix\$/d
2463 /^@endif $module-$bootstrap_suffix\$/d"
2464 done
2465 extrasub_target=
2466 for module in ${target_configdirs} ; do
2467   if test -z "${no_recursion}" \
2468      && test -f ${target_subdir}/${module}/Makefile; then
2469     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2470     rm -f ${target_subdir}/${module}/Makefile
2471   fi
2472
2473   # We only bootstrap target libraries listed in bootstrap_target_libs.
2474   case $bootstrap_target_libs in
2475     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2476     *) target_bootstrap_suffix=no-bootstrap ;;
2477   esac
2478
2479   extrasub_target="$extrasub_target
2480 /^@if target-$module\$/d
2481 /^@endif target-$module\$/d
2482 /^@if target-$module-$target_bootstrap_suffix\$/d
2483 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2484 done
2485
2486 # Do the final fixup along with target modules.
2487 extrasub_target="$extrasub_target
2488 /^@if /,/^@endif /d"
2489
2490 # Create the serialization dependencies.  This uses a temporary file.
2491
2492 AC_ARG_ENABLE([serial-configure],
2493 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2494                 [force sequential configuration of
2495                  sub-packages for the host, target or build
2496                  machine, or all sub-packages])])
2497
2498 case ${enable_serial_configure} in
2499   yes)
2500     enable_serial_build_configure=yes
2501     enable_serial_host_configure=yes
2502     enable_serial_target_configure=yes
2503     ;;
2504 esac
2505
2506 # These force 'configure's to be done one at a time, to avoid problems
2507 # with contention over a shared config.cache.
2508 rm -f serdep.tmp
2509 echo '# serdep.tmp' > serdep.tmp
2510 olditem=
2511 test "x${enable_serial_build_configure}" = xyes &&
2512 for item in ${build_configdirs} ; do
2513   case ${olditem} in
2514     "") ;;
2515     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2516   esac
2517   olditem=${item}
2518 done
2519 olditem=
2520 test "x${enable_serial_host_configure}" = xyes &&
2521 for item in ${configdirs} ; do
2522   case ${olditem} in
2523     "") ;;
2524     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2525   esac
2526   olditem=${item}
2527 done
2528 olditem=
2529 test "x${enable_serial_target_configure}" = xyes &&
2530 for item in ${target_configdirs} ; do
2531   case ${olditem} in
2532     "") ;;
2533     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2534   esac
2535   olditem=${item}
2536 done
2537 serialization_dependencies=serdep.tmp
2538 AC_SUBST_FILE(serialization_dependencies)
2539
2540 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2541 # target, nonopt, and variable assignments.  These are the ones we
2542 # might not want to pass down to subconfigures.  The exception being
2543 # --cache-file=/dev/null, which is used to turn off the use of cache
2544 # files altogether, and which should be passed on to subconfigures.
2545 # Also strip program-prefix, program-suffix, and program-transform-name,
2546 # so that we can pass down a consistent program-transform-name.
2547 baseargs=
2548 tbaseargs=
2549 keep_next=no
2550 skip_next=no
2551 eval "set -- $ac_configure_args"
2552 for ac_arg
2553 do
2554   if test X"$skip_next" = X"yes"; then
2555     skip_next=no
2556     continue
2557   fi
2558   if test X"$keep_next" = X"yes"; then
2559     case $ac_arg in
2560       *\'*)
2561         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2562     esac
2563     baseargs="$baseargs '$ac_arg'"
2564     tbaseargs="$tbaseargs '$ac_arg'"
2565     keep_next=no
2566     continue
2567   fi
2568
2569   # Handle separated arguments.  Based on the logic generated by
2570   # autoconf 2.59.
2571   case $ac_arg in
2572     *=* | --config-cache | -C | -disable-* | --disable-* \
2573       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2574       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2575       | -with-* | --with-* | -without-* | --without-* | --x)
2576       separate_arg=no
2577       ;;
2578     -*)
2579       separate_arg=yes
2580       ;;
2581     *)
2582       separate_arg=no
2583       ;;
2584   esac
2585
2586   skip_targ=no
2587   case $ac_arg in
2588 changequote(,)
2589   --with-* | --without-*)
2590     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2591
2592     case $libopt in
2593     *[-_]include)
2594       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2595       ;;
2596     *[-_]lib)
2597       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2598       ;;
2599     *)
2600       lib=$libopt
2601       ;;
2602     esac
2603 changequote([,])
2604
2605     case $lib in
2606     mpc | mpfr | gmp | cloog)
2607       # If we're processing --with-$lib, --with-$lib-include or
2608       # --with-$lib-lib, for one of the libs above, and target is
2609       # different from host, don't pass the current argument to any
2610       # target library's configure.
2611       if test x$is_cross_compiler = xyes; then
2612         skip_targ=yes
2613       fi
2614       ;;
2615     esac
2616     ;;
2617   esac
2618
2619   case "$ac_arg" in
2620     --cache-file=/dev/null | \
2621     -cache-file=/dev/null )
2622       # Handled here to avoid the test to skip args below.
2623       baseargs="$baseargs '$ac_arg'"
2624       tbaseargs="$tbaseargs '$ac_arg'"
2625       # Assert: $separate_arg should always be no.
2626       keep_next=$separate_arg
2627       ;;
2628     --no*)
2629       continue
2630       ;;
2631     --c* | \
2632     --sr* | \
2633     --ho* | \
2634     --bu* | \
2635     --t* | \
2636     --program-* | \
2637     -cache_file* | \
2638     -srcdir* | \
2639     -host* | \
2640     -build* | \
2641     -target* | \
2642     -program-prefix* | \
2643     -program-suffix* | \
2644     -program-transform-name* )
2645       skip_next=$separate_arg
2646       continue
2647       ;;
2648     -*)
2649       # An option.  Add it.
2650       case $ac_arg in
2651         *\'*)
2652           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2653       esac
2654       baseargs="$baseargs '$ac_arg'"
2655       if test X"$skip_targ" = Xno; then
2656         tbaseargs="$tbaseargs '$ac_arg'"
2657       fi
2658       keep_next=$separate_arg
2659       ;;
2660     *)
2661       # Either a variable assignment, or a nonopt (triplet).  Don't
2662       # pass it down; let the Makefile handle this.
2663       continue
2664       ;;
2665   esac
2666 done
2667 # Remove the initial space we just introduced and, as these will be
2668 # expanded by make, quote '$'.
2669 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2670
2671 # Add in --program-transform-name, after --program-prefix and
2672 # --program-suffix have been applied to it.  Autoconf has already
2673 # doubled dollar signs and backslashes in program_transform_name; we want
2674 # the backslashes un-doubled, and then the entire thing wrapped in single
2675 # quotes, because this will be expanded first by make and then by the shell.
2676 # Also, because we want to override the logic in subdir configure scripts to
2677 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2678 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2679 ${program_transform_name}
2680 EOF_SED
2681 gcc_transform_name=`cat conftestsed.out`
2682 rm -f conftestsed.out
2683 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2684 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2685 if test "$silent" = yes; then
2686   baseargs="$baseargs --silent"
2687   tbaseargs="$tbaseargs --silent"
2688 fi
2689 baseargs="$baseargs --disable-option-checking"
2690 tbaseargs="$tbaseargs --disable-option-checking"
2691
2692 # Record and document user additions to sub configure arguments.
2693 AC_ARG_VAR([build_configargs],
2694            [additional configure arguments for build directories])
2695 AC_ARG_VAR([host_configargs],
2696            [additional configure arguments for host directories])
2697 AC_ARG_VAR([target_configargs],
2698            [additional configure arguments for target directories])
2699
2700 # For the build-side libraries, we just need to pretend we're native,
2701 # and not use the same cache file.  Multilibs are neither needed nor
2702 # desired.
2703 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2704
2705 # For host modules, accept cache file option, or specification as blank.
2706 case "${cache_file}" in
2707 "") # empty
2708   cache_file_option="" ;;
2709 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2710   cache_file_option="--cache-file=${cache_file}" ;;
2711 *) # relative path
2712   cache_file_option="--cache-file=../${cache_file}" ;;
2713 esac
2714
2715 # Host dirs don't like to share a cache file either, horribly enough.
2716 # This seems to be due to autoconf 2.5x stupidity.
2717 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2718
2719 target_configargs="$target_configargs ${tbaseargs}"
2720
2721 # Passing a --with-cross-host argument lets the target libraries know
2722 # whether they are being built with a cross-compiler or being built
2723 # native.  However, it would be better to use other mechanisms to make the
2724 # sorts of decisions they want to make on this basis.  Please consider
2725 # this option to be deprecated.  FIXME.
2726 if test x${is_cross_compiler} = xyes ; then
2727   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2728 fi
2729
2730 # Default to --enable-multilib.
2731 if test x${enable_multilib} = x ; then
2732   target_configargs="--enable-multilib ${target_configargs}"
2733 fi
2734
2735 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2736 # changed from the earlier setting of with_newlib.
2737 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2738   target_configargs="--with-newlib ${target_configargs}"
2739 fi
2740
2741 # Different target subdirs use different values of certain variables
2742 # (notably CXX).  Worse, multilibs use *lots* of different values.
2743 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2744 # it doesn't automatically accept command-line overrides of them.
2745 # This means it's not safe for target subdirs to share a cache file,
2746 # which is disgusting, but there you have it.  Hopefully this can be
2747 # fixed in future.  It's still worthwhile to use a cache file for each
2748 # directory.  I think.
2749
2750 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2751 # We need to pass --target, as newer autoconf's requires consistency
2752 # for target_alias and gcc doesn't manage it consistently.
2753 target_configargs="--cache-file=./config.cache ${target_configargs}"
2754
2755 FLAGS_FOR_TARGET=
2756 case " $target_configdirs " in
2757  *" newlib "*)
2758   case " $target_configargs " in
2759   *" --with-newlib "*)
2760    case "$target" in
2761     *-cygwin*)
2762       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2763       ;;
2764    esac
2765
2766    # If we're not building GCC, don't discard standard headers.
2767    if test -d ${srcdir}/gcc; then
2768      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2769
2770      if test "${build}" != "${host}"; then
2771        # On Canadian crosses, CC_FOR_TARGET will have already been set
2772        # by `configure', so we won't have an opportunity to add -Bgcc/
2773        # to it.  This is right: we don't want to search that directory
2774        # for binaries, but we want the header files in there, so add
2775        # them explicitly.
2776        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2777
2778        # Someone might think of using the pre-installed headers on
2779        # Canadian crosses, in case the installed compiler is not fully
2780        # compatible with the compiler being built.  In this case, it
2781        # would be better to flag an error than risking having
2782        # incompatible object files being constructed.  We can't
2783        # guarantee that an error will be flagged, but let's hope the
2784        # compiler will do it, when presented with incompatible header
2785        # files.
2786      fi
2787    fi
2788
2789    case "${target}-${is_cross_compiler}" in
2790    i[[3456789]]86-*-linux*-no)
2791       # Here host == target, so we don't need to build gcc,
2792       # so we don't want to discard standard headers.
2793       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2794       ;;
2795    *)
2796       # If we're building newlib, use its generic headers last, but search
2797       # for any libc-related directories first (so make it the last -B
2798       # switch).
2799       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2800
2801       # If we're building libgloss, find the startup file, simulator library
2802       # and linker script.
2803       case " $target_configdirs " in
2804         *" libgloss "*)
2805         # Look for startup file, simulator library and maybe linker script.
2806         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2807         # Look for libnosys.a in case the target needs it.
2808         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2809         # Most targets have the linker script in the source directory.
2810         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2811         ;;
2812       esac
2813       ;;
2814    esac
2815    ;;
2816   esac
2817   ;;
2818 esac
2819
2820 case "$target" in
2821   x86_64-*mingw* | *-w64-mingw*)
2822   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2823   # however, use a symlink named 'mingw' in ${prefix} .
2824     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2825     ;;
2826   *-mingw*)
2827   # MinGW can't be handled as Cygwin above since it does not use newlib.
2828     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2829     ;;
2830 esac
2831
2832 # Allow the user to override the flags for
2833 # our build compiler if desired.
2834 if test x"${build}" = x"${host}" ; then
2835   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2836   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2837   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2838 fi
2839
2840 # On Canadian crosses, we'll be searching the right directories for
2841 # the previously-installed cross compiler, so don't bother to add
2842 # flags for directories within the install tree of the compiler
2843 # being built; programs in there won't even run.
2844 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2845   # Search for pre-installed headers if nothing else fits.
2846   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2847 fi
2848
2849 if test "x${use_gnu_ld}" = x &&
2850    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2851   # Arrange for us to find uninstalled linker scripts.
2852   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2853 fi
2854
2855 # Search for other target-specific linker scripts and such.
2856 case "${target}" in
2857   mep*)
2858     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2859     ;;
2860 esac
2861
2862 # Makefile fragments.
2863 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2864 do
2865   eval fragval=\$$frag
2866   if test $fragval != /dev/null; then
2867     eval $frag=${srcdir}/$fragval
2868   fi
2869 done
2870 AC_SUBST_FILE(host_makefile_frag)
2871 AC_SUBST_FILE(target_makefile_frag)
2872 AC_SUBST_FILE(alphaieee_frag)
2873 AC_SUBST_FILE(ospace_frag)
2874
2875 # Miscellanea: directories, flags, etc.
2876 AC_SUBST(RPATH_ENVVAR)
2877 AC_SUBST(GCC_SHLIB_SUBDIR)
2878 AC_SUBST(tooldir)
2879 AC_SUBST(build_tooldir)
2880 AC_SUBST(CONFIGURE_GDB_TK)
2881 AC_SUBST(GDB_TK)
2882 AC_SUBST(INSTALL_GDB_TK)
2883
2884 # Build module lists & subconfigure args.
2885 AC_SUBST(build_configargs)
2886 AC_SUBST(build_configdirs)
2887
2888 # Host module lists & subconfigure args.
2889 AC_SUBST(host_configargs)
2890 AC_SUBST(configdirs)
2891 AC_SUBST(target_configdirs)
2892
2893 # Target module lists & subconfigure args.
2894 AC_SUBST(target_configargs)
2895
2896
2897 # Build tools.
2898 AC_SUBST(AR_FOR_BUILD)
2899 AC_SUBST(AS_FOR_BUILD)
2900 AC_SUBST(CC_FOR_BUILD)
2901 AC_SUBST(CFLAGS_FOR_BUILD)
2902 AC_SUBST(CXXFLAGS_FOR_BUILD)
2903 AC_SUBST(CXX_FOR_BUILD)
2904 AC_SUBST(DLLTOOL_FOR_BUILD)
2905 AC_SUBST(GCJ_FOR_BUILD)
2906 AC_SUBST(GFORTRAN_FOR_BUILD)
2907 AC_SUBST(GOC_FOR_BUILD)
2908 AC_SUBST(LDFLAGS_FOR_BUILD)
2909 AC_SUBST(LD_FOR_BUILD)
2910 AC_SUBST(NM_FOR_BUILD)
2911 AC_SUBST(RANLIB_FOR_BUILD)
2912 AC_SUBST(WINDMC_FOR_BUILD)
2913 AC_SUBST(WINDRES_FOR_BUILD)
2914
2915 # Generate default definitions for YACC, M4, LEX and other programs that run
2916 # on the build machine.  These are used if the Makefile can't locate these
2917 # programs in objdir.
2918 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2919
2920 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2921 case " $build_configdirs " in
2922   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2923 esac
2924
2925 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2926 case " $build_configdirs " in
2927   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2928 esac
2929
2930 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
2931 case " $build_configdirs " in
2932   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
2933 esac
2934
2935 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
2936 case " $build_configdirs " in
2937   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2938   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
2939 esac
2940
2941 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
2942 case " $build_configdirs " in
2943   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2944 esac
2945
2946 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
2947 case " $build_configdirs " in
2948   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
2949   *)
2950 changequote(,)
2951     # For an installed makeinfo, we require it to be from texinfo 4.7 or
2952     # higher, else we use the "missing" dummy.
2953     if ${MAKEINFO} --version \
2954        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
2955       :
2956     else
2957       MAKEINFO="$MISSING makeinfo"
2958     fi
2959     ;;
2960 changequote([,])
2961 esac
2962
2963 # FIXME: expect and dejagnu may become build tools?
2964
2965 AC_CHECK_PROGS(EXPECT, expect, expect)
2966 case " $configdirs " in
2967   *" expect "*)
2968     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
2969     ;;
2970 esac
2971
2972 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
2973 case " $configdirs " in
2974   *" dejagnu "*)
2975     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
2976     ;;
2977 esac
2978
2979
2980 # Host tools.
2981 NCN_STRICT_CHECK_TOOLS(AR, ar)
2982 NCN_STRICT_CHECK_TOOLS(AS, as)
2983 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
2984 NCN_STRICT_CHECK_TOOLS(LD, ld)
2985 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
2986 NCN_STRICT_CHECK_TOOLS(NM, nm)
2987 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
2988 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
2989 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
2990 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
2991 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
2992 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
2993 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
2994 AC_SUBST(CC)
2995 AC_SUBST(CXX)
2996 AC_SUBST(CFLAGS)
2997 AC_SUBST(CXXFLAGS)
2998
2999 # Target tools.
3000 AC_ARG_WITH([build-time-tools],
3001   [AS_HELP_STRING([--with-build-time-tools=PATH],
3002                   [use given path to find target tools during the build])],
3003   [case x"$withval" in
3004      x/*) ;;
3005      *)
3006        with_build_time_tools=
3007        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3008        ;;
3009    esac],
3010   [with_build_time_tools=])
3011
3012 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3013 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3014 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3015 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3016 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3017 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3018
3019 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3020 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3021 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3022 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3023 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3024 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3025 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3026 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3027 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3028 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3029 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3030 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3031
3032 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3033
3034 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3035 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3036 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3037 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3038 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3039                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3040                 c++)
3041 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3042                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3043                 c++)
3044 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3045 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3046 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3047                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3048 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3049                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3050 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3051                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3052 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3053 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3054 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3055 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3056 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3057 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3058 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3059 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3060 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3061
3062 AC_SUBST(FLAGS_FOR_TARGET)
3063 AC_SUBST(RAW_CXX_FOR_TARGET)
3064
3065 # Certain tools may need extra flags.
3066 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3067 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3068 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3069
3070 # When building target libraries, except in a Canadian cross, we use
3071 # the same toolchain as the compiler we just built.
3072 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3073 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3074 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3075 if test $host = $build; then
3076   case " $configdirs " in
3077     *" gcc "*)
3078       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3079       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3080       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3081       ;;
3082   esac
3083 fi
3084
3085 AC_SUBST(COMPILER_AS_FOR_TARGET)
3086 AC_SUBST(COMPILER_LD_FOR_TARGET)
3087 AC_SUBST(COMPILER_NM_FOR_TARGET)
3088
3089 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3090 AC_ARG_ENABLE(maintainer-mode,
3091 [AS_HELP_STRING([--enable-maintainer-mode],
3092                 [enable make rules and dependencies not useful
3093                  (and sometimes confusing) to the casual installer])],
3094       USE_MAINTAINER_MODE=$enableval,
3095       USE_MAINTAINER_MODE=no)
3096 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3097 AC_SUBST(MAINTAINER_MODE_TRUE)
3098 AC_SUBST(MAINTAINER_MODE_FALSE)
3099 if test "$USE_MAINTAINER_MODE" = yes; then
3100   MAINTAINER_MODE_TRUE=
3101   MAINTAINER_MODE_FALSE='#'
3102 else
3103   MAINTAINER_MODE_TRUE='#'
3104   MAINTAINER_MODE_FALSE=
3105 fi
3106 MAINT=$MAINTAINER_MODE_TRUE
3107 AC_SUBST(MAINT)dnl
3108
3109 # ---------------------
3110 # GCC bootstrap support
3111 # ---------------------
3112
3113 # Stage specific cflags for build.
3114 stage1_cflags="-g"
3115 case $build in
3116   vax-*-*)
3117     case ${GCC} in
3118       yes) stage1_cflags="-g -Wa,-J" ;;
3119       *) stage1_cflags="-g -J" ;;
3120     esac ;;
3121 esac
3122
3123 AC_SUBST(stage1_cflags)
3124
3125 # Enable --enable-checking in stage1 of the compiler.
3126 AC_ARG_ENABLE(stage1-checking,
3127 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3128                 [choose additional checking for stage1 of the compiler])],
3129 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3130 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3131   stage1_checking=--enable-checking=yes,types
3132 else
3133   stage1_checking=--enable-checking=$enable_checking,types
3134 fi])
3135 AC_SUBST(stage1_checking)
3136
3137 # Enable -Werror in bootstrap stage2 and later.
3138 AC_ARG_ENABLE(werror,
3139 [AS_HELP_STRING([--enable-werror],
3140                 [enable -Werror in bootstrap stage2 and later])], [],
3141 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3142   enable_werror=yes
3143 else
3144   enable_werror=no
3145 fi])
3146 case ${enable_werror} in
3147   yes) stage2_werror_flag="--enable-werror-always" ;;
3148   *) stage2_werror_flag="" ;;
3149 esac
3150 AC_SUBST(stage2_werror_flag)
3151
3152 # Specify what files to not compare during bootstrap.
3153
3154 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3155 case "$target" in
3156   hppa*64*-*-hpux*) ;;
3157   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3158   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3159 esac
3160 AC_SUBST(compare_exclusions)
3161
3162 AC_CONFIG_FILES([Makefile],
3163   [sed "$extrasub_build" Makefile |
3164    sed "$extrasub_host" |
3165    sed "$extrasub_target" > mf$$
3166    mv -f mf$$ Makefile],
3167   [extrasub_build="$extrasub_build"
3168    extrasub_host="$extrasub_host"
3169    extrasub_target="$extrasub_target"])
3170 AC_OUTPUT