configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.21.2,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.28.1
  56 GSTPB_REQ=0.10.28.1
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 dnl *** checks for platform ***
  92
  93 dnl * hardware/architecture *
  94
  95 dnl common/m4/gst-arch.m4
  96 dnl check CPU type
  97 AG_GST_ARCH
  98
  99 dnl Determine endianness
 100 AC_C_BIGENDIAN
 101
 102 dnl *** checks for programs ***
 103
 104 dnl find a compiler
 105 AC_PROG_CC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl determine c++ preprocessor
 113 dnl FIXME: do we need this ?
 114 AC_PROG_CXXCPP
 115
 116 AS_PROG_OBJC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 dnl check if the compiler supports do while(0) macros
 125 AG_GST_CHECK_DOWHILE_MACROS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for gconftool-2
 131 dnl this macro defines an am conditional, so it needs to be run always
 132 AM_GCONF_SOURCE_2
 133
 134 dnl check for documentation tools
 135 GTK_DOC_CHECK([1.3])
 136 AS_PATH_PYTHON([2.1])
 137 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 138
 139 dnl *** checks for libraries ***
 140
 141 dnl check for libm, for sin()
 142 AC_CHECK_LIBM
 143 AC_SUBST(LIBM)
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/rtp/gstasteriskh263.c
 154 AC_CHECK_HEADERS([netinet/in.h])
 155 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 156 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 157
 158 dnl used in gst/udp
 159 AC_CHECK_HEADERS([sys/time.h])
 160
 161 dnl *** checks for types/defines ***
 162
 163 dnl Check for FIONREAD ioctl declaration.  This check is needed
 164 dnl for the UDP plugin to build on Solaris
 165 GST_CHECK_FIONREAD
 166
 167 dnl *** checks for structures ***
 168
 169 dnl *** checks for compiler characteristics ***
 170
 171 dnl check if we have GCC inline-asm
 172 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 173 if test x$HAVE_GCC_ASM = xyes ; then
 174   AC_DEFINE(HAVE_GCC_ASM, 1,
 175     [Define if compiler supports gcc inline assembly])
 176 fi
 177 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 178
 179 dnl *** checks for library functions ***
 180
 181 LIBS_SAVE=$LIBS
 182 LIBS="$LIBS $LIBM"
 183 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 184 LIBS=$LIBS_SAVE
 185
 186 dnl Check whether isinf() is defined by math.h
 187 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 189 if test "$ac_cv_have_isinf" = "yes"
 190 then
 191     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 192 fi
 193
 194 dnl Check for mmap (needed by electricfence plugin)
 195 AC_FUNC_MMAP
 196 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 197
 198 dnl Check for mmap (needed by electricfence plugin)
 199
 200 AC_CHECK_TYPE([struct ip_mreqn], [
 201               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 202               [#include <netinet/in.h>])
 203
 204 dnl *** checks for dependency libraries ***
 205
 206 dnl GLib is required
 207 AG_GST_GLIB_CHECK([2.18])
 208
 209 dnl liboil is required
 210 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 211 if test "x$HAVE_LIBOIL" != "xyes"; then
 212   AC_ERROR([liboil-0.3.8 or later is required])
 213 fi
 214
 215 dnl checks for gstreamer
 216 dnl uninstalled is selected preferentially -- see pkg-config(1)
 217 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 222 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 223
 224 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 225 if test -z $GST_TOOLS_DIR; then
 226   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 227 fi
 228 AC_SUBST(GST_TOOLS_DIR)
 229
 230 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 231 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 232
 233 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 234
 235 dnl Check for documentation xrefs
 236 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 237 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 238 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 239 AC_SUBST(GLIB_PREFIX)
 240 AC_SUBST(GST_PREFIX)
 241 AC_SUBST(GSTPB_PREFIX)
 242
 243 dnl GTK is optional and used in examples
 244 if test "x$BUILD_EXAMPLES" = "xyes"; then
 245   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, HAVE_GTK=yes, HAVE_GTK=no)
 246   AC_SUBST(GTK_LIBS)
 247   AC_SUBST(GTK_CFLAGS)
 248 fi
 249 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 250
 251 dnl should we install schemas ?
 252 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 253 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 254   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 255   if test x$GCONFTOOL = xno; then
 256     AC_MSG_WARN(Not installing GConf schemas)
 257     HAVE_GCONFTOOL="no"
 258   else
 259     HAVE_GCONFTOOL="yes"
 260   fi
 261   AC_SUBST(HAVE_GCONFTOOL)
 262 ])
 263
 264 dnl *** set variables based on configure arguments ***
 265
 266 dnl set license and copyright notice
 267 GST_LICENSE="LGPL"
 268 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 269 AC_SUBST(GST_LICENSE)
 270
 271 dnl set location of plugin directory
 272 AG_GST_SET_PLUGINDIR
 273
 274 dnl define an ERROR_CFLAGS Makefile variable
 275 dnl -Wundef: too many broken headers
 276 dnl -Waggregate-return: causes problems with ObjC code like in osxvideosink
 277 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 278         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 279         -Wwrite-strings -Wold-style-definition -Wcast-align
 280         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 281         -Wnested-externs ])
 282
 283 dnl define an ERROR_CXXFLAGS Makefile variable
 284 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 285         -Wmissing-declarations -Wredundant-decls
 286         -Wwrite-strings -Wcast-align
 287         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 288
 289 dnl define correct level for debugging messages
 290 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 291
 292 dnl used in examples
 293 AG_GST_DEFAULT_ELEMENTS
 294
 295 dnl *** plug-ins to include ***
 296
 297 dnl these are all the gst plug-ins, compilable without additional libs
 298 dnl videofilter is at the top because others depend on it
 299 AG_GST_CHECK_PLUGIN(videofilter)
 300 AG_GST_CHECK_PLUGIN(alpha)
 301 AG_GST_CHECK_PLUGIN(apetag)
 302 AG_GST_CHECK_PLUGIN(audiofx)
 303 AG_GST_CHECK_PLUGIN(auparse)
 304 AG_GST_CHECK_PLUGIN(autodetect)
 305 AG_GST_CHECK_PLUGIN(avi)
 306 AG_GST_CHECK_PLUGIN(cutter)
 307 AG_GST_CHECK_PLUGIN(debugutils)
 308 AG_GST_CHECK_PLUGIN(deinterlace)
 309 AG_GST_CHECK_PLUGIN(effectv)
 310 AG_GST_CHECK_PLUGIN(equalizer)
 311 AG_GST_CHECK_PLUGIN(flv)
 312 AG_GST_CHECK_PLUGIN(id3demux)
 313 AG_GST_CHECK_PLUGIN(icydemux)
 314 AG_GST_CHECK_PLUGIN(interleave)
 315 AG_GST_CHECK_PLUGIN(flx)
 316 AG_GST_CHECK_PLUGIN(goom)
 317 AG_GST_CHECK_PLUGIN(goom2k1)
 318 AG_GST_CHECK_PLUGIN(law)
 319 AG_GST_CHECK_PLUGIN(level)
 320 AG_GST_CHECK_PLUGIN(matroska)
 321 AG_GST_CHECK_PLUGIN(monoscope)
 322 AG_GST_CHECK_PLUGIN(multifile)
 323 AG_GST_CHECK_PLUGIN(multipart)
 324 AG_GST_CHECK_PLUGIN(qtdemux)
 325 AG_GST_CHECK_PLUGIN(replaygain)
 326 AG_GST_CHECK_PLUGIN(rtp)
 327 AG_GST_CHECK_PLUGIN(rtpmanager)
 328 AG_GST_CHECK_PLUGIN(rtsp)
 329 AG_GST_CHECK_PLUGIN(shapewipe)
 330 AG_GST_CHECK_PLUGIN(smpte)
 331 AG_GST_CHECK_PLUGIN(spectrum)
 332 AG_GST_CHECK_PLUGIN(udp)
 333 AG_GST_CHECK_PLUGIN(videobox)
 334 AG_GST_CHECK_PLUGIN(videocrop)
 335 AG_GST_CHECK_PLUGIN(videomixer)
 336 AG_GST_CHECK_PLUGIN(wavenc)
 337 AG_GST_CHECK_PLUGIN(wavparse)
 338 AG_GST_CHECK_PLUGIN(y4m)
 339
 340 dnl *** checks for socket and nsl libraries ***
 341 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 342
 343 dnl disable gst plugins we might not be able to build on this
 344 dnl platform: udp and rtsp (ugly but minimally invasive)
 345 dnl FIXME: maybe move to sys
 346 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 347 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 348
 349 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 350   AG_GST_DISABLE_PLUGIN(udp)
 351   AG_GST_DISABLE_PLUGIN(rtsp)
 352 fi
 353
 354 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 355   WIN32_LIBS="-lws2_32"
 356   AC_SUBST(WIN32_LIBS)
 357 fi
 358
 359 dnl disable experimental plug-ins
 360 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 361   AG_GST_DISABLE_PLUGIN(monoscope)
 362 fi
 363
 364 dnl *** sys plug-ins ***
 365
 366 echo
 367 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 368 echo
 369
 370 dnl DirectSound
 371 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 372 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 373   HAVE_DIRECTSOUND="no"
 374   save_CFLAGS="$CFLAGS"
 375   save_LDFLAGS="$LDFLAGS"
 376   save_LIBS="$LIBS"
 377   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 378   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 379   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 380   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 381   AC_LINK_IFELSE([
 382 #include <windows.h>
 383 #include <dxerr9.h>
 384 #include <dsound.h>
 385
 386 int main ()
 387 {
 388   DXGetErrorString9 (0);
 389   DirectSoundCreate(NULL, NULL, NULL);
 390
 391   return 0;
 392 }
 393 ],
 394     [HAVE_DIRECTSOUND="yes"],
 395     [HAVE_DIRECTSOUND="no"])
 396   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 397   CFLAGS=$save_CFLAGS
 398   LDFLAGS=$save_LDFLAGS
 399   LIBS=$save_LIBS
 400
 401   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 402     dnl this is much more than we want
 403     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 404     AC_SUBST(DIRECTSOUND_CFLAGS)
 405     AC_SUBST(DIRECTSOUND_LDFLAGS)
 406     AC_SUBST(DIRECTSOUND_LIBS)
 407   fi
 408   AC_SUBST(HAVE_DIRECTSOUND)
 409 ])
 410
 411 dnl *** OSS audio *** (Linux, *BSD)
 412 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 413 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 414  HAVE_OSS="yes"
 415 dnl Linux and newer BSD versions :
 416  AC_CHECK_HEADER(sys/soundcard.h, [
 417    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 418    ] , [
 419 dnl Some old BSD versions and also newer OpenBSD versions :
 420    AC_CHECK_HEADER(soundcard.h, [
 421      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 422      ], [
 423   dnl Some old BSD versions :
 424      AC_CHECK_HEADER(machine/soundcard.h, [
 425        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 426          [Define if OSS includes are in /machine/])
 427        ], [
 428        HAVE_OSS="no"
 429      ])
 430    ])
 431  ])
 432 ])
 433
 434 dnl *** Sun Audio ***
 435 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 436 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 437   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 438 ])
 439
 440 dnl *** OSX Audio ***
 441 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 442 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 443   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 444 ])
 445
 446 dnl *** OS X video ***
 447 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 448 HAVE_OSX_VIDEO="no"
 449 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 450   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 451 ])
 452 dnl in case header OpenGL/gl.h is found on other platforms
 453 case "$host" in
 454   *-*darwin*)
 455     dnl do nothing
 456     ;;
 457   *)
 458     HAVE_OSX_VIDEO="no"
 459     ;;
 460 esac
 461
 462
 463 dnl *** Video 4 Linux 2 ***
 464 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 465 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 466 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 467 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 468   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 469   AC_TRY_COMPILE([
 470 #include <sys/types.h>
 471 #ifdef __sun /* Solaris */
 472 #include <sys/types.h>
 473 #include <sys/videodev2.h>
 474 #else /* Linux */
 475 #include <linux/types.h>
 476 #define _LINUX_TIME_H
 477 #define __user
 478 #include <linux/videodev2.h>
 479 #endif
 480 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 481 #error too early v4l2 version or no v4l2 at all
 482 #endif
 483     ], [
 484 return 0;
 485     ], [
 486       HAVE_GST_V4L2="yes"
 487       AC_MSG_RESULT(yes)
 488     ], [
 489       HAVE_GST_V4L2="no"
 490       AC_MSG_RESULT(no)
 491
 492       HAVE_VIDEODEV=no
 493       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 494       [
 495         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 496       ])
 497
 498       if test "x$HAVE_VIDEODEV" = "xyes"; then
 499         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 500         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 501       else
 502         AC_MSG_WARN([video4linux2 was not found])
 503       fi
 504     ])
 505
 506   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 507     dnl check for missing v4l2_buffer declaration (see #135919)
 508     MISSING_DECL=0
 509     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 510     AC_TRY_COMPILE([
 511 #include <sys/types.h>
 512 #ifdef __sun /* Solaris */
 513 #include <sys/types.h>
 514 #include <sys/videodev2.h>
 515 #else /* Linux */
 516 #include <linux/types.h>
 517 #define _LINUX_TIME_H
 518 #define __user
 519 #include <linux/videodev2.h>
 520 #endif
 521     ],[
 522 struct v4l2_buffer buf;
 523 buf.index = 0;
 524 return 0;
 525     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 526     if [ test x$MISSING_DECL = x1 ]; then
 527       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 528     fi
 529
 530     dnl check for XOverlay libraries
 531     AG_GST_CHECK_XV
 532   fi
 533 ])
 534
 535 # Optional gudev for device probing
 536 AC_ARG_WITH([gudev],
 537   AC_HELP_STRING([--with-gudev],
 538     [device detection with gudev]),
 539   [],
 540   [with_gudev=check])
 541 if test x$HAVE_GST_V4L2 = xyes; then
 542   if test x$with_gudev != xno; then
 543       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 544           [ have_gudev=yes
 545             AC_DEFINE(HAVE_GUDEV, 1,
 546                [Whether gudev is available for device detection])
 547             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 548           ], [
 549           have_gudev=no
 550           ])
 551   else
 552     have_gudev=no
 553   fi
 554 fi
 555 AC_SUBST(GUDEV_CFLAGS)
 556 AC_SUBST(GUDEV_LIBS)
 557
 558 # Make libv4l2 non-automagic
 559 AC_ARG_WITH([libv4l2],
 560   AC_HELP_STRING([--with-libv4l2],
 561     [support video buffer conversion using libv4l2]),
 562   [],
 563   [with_libv4l2=check])
 564 if test x$HAVE_GST_V4L2 = xyes; then
 565   if test x$with_libv4l2 != xno; then
 566       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 567           [ have_libv4l2=yes
 568             AC_DEFINE(HAVE_LIBV4L2, 1,
 569                 [Whether libv4l2 is available for video buffer conversion])
 570           ], [
 571           have_libv4l2=no
 572           ])
 573   else
 574     have_libv4l2=no
 575   fi
 576 fi
 577
 578 dnl Check for X11
 579 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 580 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 581                   [ximagesrc], [
 582   AC_PATH_XTRA
 583
 584   dnl now try to find the HEADER
 585   ac_cflags_save="$CFLAGS"
 586   ac_cppflags_save="$CPPFLAGS"
 587   CFLAGS="$CFLAGS $X_CFLAGS"
 588   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 589   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 590
 591   if test "x$HAVE_X" = "xno"
 592   then
 593     AC_MSG_NOTICE([cannot find X11 development files])
 594   else
 595     dnl this is much more than we want
 596     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 597     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 598     dnl it does not add the libs; therefore we add them here
 599     X_LIBS="$X_LIBS -lX11"
 600     AC_SUBST(X_CFLAGS)
 601     AC_SUBST(X_LIBS)
 602
 603     dnl check for Xfixes
 604     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 605     if test "x$HAVE_XFIXES" = "xyes"
 606     then
 607         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 608     fi
 609     AC_SUBST(XFIXES_LIBS)
 610     AC_SUBST(XFIXES_CFLAGS)
 611
 612     dnl check for Xdamage
 613     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 614     if test "x$HAVE_XDAMAGE" = "xyes"
 615     then
 616         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 617     fi
 618     AC_SUBST(XDAMAGE_LIBS)
 619     AC_SUBST(XDAMAGE_CFLAGS)
 620   fi
 621   AC_SUBST(HAVE_X)
 622   CFLAGS="$ac_cflags_save"
 623   CPPFLAGS="$ac_cppflags_save"
 624 ])
 625
 626 dnl FIXME: this should be rolled into the test above, it's just an additional
 627 dnl feature of the ximagesrc plug-in
 628 dnl This is the same as in gst-plugins-base
 629 dnl check for X Shm
 630 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 631 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 632   if test x$HAVE_X = xyes; then
 633     AC_CHECK_LIB(Xext, XShmAttach,
 634                  HAVE_XSHM="yes", HAVE_XSHM="no",
 635                  $X_LIBS)
 636     if test "x$HAVE_XSHM" = "xyes"; then
 637       XSHM_LIBS="-lXext"
 638     else
 639       dnl On AIX, it is in XextSam instead, but we still need -lXext
 640       AC_CHECK_LIB(XextSam, XShmAttach,
 641                    HAVE_XSHM="yes", HAVE_XSHM="no",
 642                    $X_LIBS)
 643       if test "x$HAVE_XSHM" = "xyes"; then
 644         XSHM_LIBS="-lXext -lXextSam"
 645       fi
 646     fi
 647   fi
 648 ], ,[
 649   AC_SUBST(HAVE_XSHM)
 650   AC_SUBST(XSHM_LIBS)
 651 ])
 652
 653 dnl for V4L2, we also need to know if we have XVIDEO
 654 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 655 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 656                   [], [
 657   AG_GST_CHECK_XV
 658 ])
 659
 660 dnl *** ext plug-ins ***
 661 dnl keep this list sorted alphabetically !
 662
 663 if test "x$BUILD_EXTERNAL" = "xyes"; then
 664
 665 echo
 666 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 667 echo
 668
 669 dnl *** aalib ***
 670 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 671 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 672   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 673   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 674 ])
 675
 676 dnl *** annodex ***
 677 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 678 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 679   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 680 ])
 681
 682 dnl *** cairo ***
 683 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 684 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 685   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 686 ])
 687
 688 dnl **** ESound ****
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 690 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 691   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 692   if test $HAVE_ESD = no
 693   then
 694     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 695     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 696   fi
 697 ])
 698
 699 dnl *** FLAC ***
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 701 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 702   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 703 ])
 704
 705 dnl *** GConf ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 707 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 708   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 709 ])
 710
 711 dnl *** GDK pixbuf ***
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 713 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 714   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 715 ])
 716
 717 dnl *** HAL ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 719 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 720   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 721 ])
 722
 723 dnl *** jpeg ***
 724 dnl FIXME: we could use header checks here as well IMO
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 726 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 727   AC_ARG_WITH(jpeg-mmx,
 728     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 729   OLD_LIBS="$LIBS"
 730   if test x$with_jpeg_mmx != x; then
 731     LIBS="$LIBS -L$with_jpeg_mmx"
 732   fi
 733   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 734   JPEG_LIBS="$LIBS -ljpeg-mmx"
 735   LIBS="$OLD_LIBS"
 736   if test x$HAVE_JPEG != xyes; then
 737     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 738     JPEG_LIBS="-ljpeg"
 739   fi
 740   AC_SUBST(JPEG_LIBS)
 741 ])
 742
 743 dnl *** libcaca ***
 744 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 745 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 746   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 747   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 748   if test "x$HAVE_LIBCACA" != "xyes"; then
 749     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 750     dnl see if it compilation works too, might not if we are cross-compiling
 751     if test "x$HAVE_LIBCACA" = "xyes"; then
 752       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 753                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 754     fi
 755   fi
 756 ])
 757
 758 dnl *** libdv ***
 759 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 760 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 761   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 762 ])
 763
 764 dnl *** libpng ***
 765 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 766 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 767   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 768 ])
 769
 770 dnl *** pulseaudio ***
 771 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 772 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 773   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 774   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 775   if test x$HAVE_PULSE_0_9_11 = xyes; then
 776     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 777   fi
 778   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 779   if test x$HAVE_PULSE_0_9_12 = xyes; then
 780     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 781   fi
 782   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 783   if test x$HAVE_PULSE_0_9_13 = xyes; then
 784     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 785   fi
 786   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 787   if test x$HAVE_PULSE_0_9_15 = xyes; then
 788     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 789   fi
 790   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 791   if test x$HAVE_PULSE_0_9_20 = xyes; then
 792     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 793   fi
 794 ])
 795
 796 dnl *** dv1394 ***
 797 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 798 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 799   dnl first test for libraw1394 >= 1.2.1
 800   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 801   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 802   dnl now see how far we got
 803   if test x$HAVE_RAW1394 = xyes && \
 804      test x$HAVE_LIBIEC61883 = xyes; then
 805        AG_GST_CHECK_LIBHEADER(AVC1394,
 806         avc1394, avc1394_send_command, $RAW1394_LIBS,
 807         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 808        AG_GST_CHECK_LIBHEADER(ROM1394,
 809         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 810         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 811        if test x$HAVE_AVC1394 = xyes && \
 812           test x$HAVE_AVC1394 = xyes && \
 813           test x$HAVE_ROM1394 = xyes; then
 814           HAVE_DV1394=yes
 815           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 816           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 817           AC_SUBST(DV1394_CFLAGS)
 818           AC_SUBST(DV1394_LIBS)
 819         fi
 820   else
 821        if test x$HAVE_RAW1394 = xno; then
 822           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 823           AG_GST_CHECK_LIBHEADER(AVC1394,
 824            avc1394, avc1394_send_command, $RAW1394_LIBS,
 825            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 826           AG_GST_CHECK_LIBHEADER(ROM1394,
 827            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 828            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 829           if test x$HAVE_RAW1394 = xyes && \
 830              test x$HAVE_AVC1394 = xyes && \
 831              test x$HAVE_ROM1394 = xyes; then
 832              HAVE_DV1394=yes
 833              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 834              DV1394_CFLAGS="$RAW1394_CFLAGS"
 835              if test x$HAVE_LIBIEC61883 = xyes; then
 836                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 837                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 838              fi
 839              AC_SUBST(DV1394_CFLAGS)
 840              AC_SUBST(DV1394_LIBS)
 841            fi
 842          fi
 843   fi
 844 ])
 845
 846 dnl *** shout2 ***
 847 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 848 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 849   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 850   if test $HAVE_SHOUT2 = no
 851   then
 852     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 853     AC_SUBST(SHOUT2_CFLAGS)
 854     AC_SUBST(SHOUT2_LIBS)
 855   fi
 856 ])
 857
 858 dnl *** soup ***
 859 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 860 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 861   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 862     HAVE_SOUP="yes"
 863     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 864   ],[
 865     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 866       HAVE_SOUP="no"
 867       AC_MSG_RESULT(no)
 868     ])
 869   ])
 870   AC_SUBST(SOUP_CFLAGS)
 871   AC_SUBST(SOUP_LIBS)
 872 ])
 873
 874 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 875 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 876 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 877 dnl   speex_jitter.h is 1.1.x only
 878 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 879 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 880   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 881   if test $HAVE_SPEEX = no
 882   then
 883     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 884       AC_CHECK_HEADER(speex/speex_jitter.h, [
 885         dnl speex 1.1.x :
 886         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 887           dnl speex 1.1.5 or + :
 888           HAVE_SPEEX="yes"
 889           SPEEX_LIBS="-lspeex"
 890           AC_SUBST(SPEEX_CFLAGS)
 891           AC_SUBST(SPEEX_LIBS)
 892         ],[
 893           HAVE_SPEEX="no"
 894         ])
 895       ],[
 896         dnl speex 1.0.x :
 897           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 898             dnl speex 1.0.4
 899             HAVE_SPEEX="yes"
 900             SPEEX_LIBS="-lspeex"
 901             AC_SUBST(SPEEX_CFLAGS)
 902             AC_SUBST(SPEEX_LIBS)
 903
 904             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 905               [defined if speex 1.0.x API detected])
 906         ],[
 907             HAVE_SPEEX="no"
 908             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 909         ], [
 910 #include <speex/speex.h>
 911         ])
 912       ])
 913     ])
 914   fi
 915 ])
 916
 917 dnl *** taglib ***
 918 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 919 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 920   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 921   if test "x$HAVE_CXX" != "xyes"; then
 922     USE_TAGLIB=false
 923     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 924   else
 925     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 926     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 927         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 928       ], [
 929         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 930     ])
 931     AC_SUBST(TAGLIB_CXXFLAGS)
 932   fi
 933 ])
 934
 935 dnl *** wavpack ***
 936 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 937 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 938   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 939     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 940       HAVE_WAVPACK=yes
 941       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 942     ],[
 943       HAVE_WAVPACK=no
 944       AC_MSG_RESULT(no)
 945     ])
 946   ])
 947   AC_SUBST(WAVPACK_CFLAGS)
 948   AC_SUBST(WAVPACK_LIBS)
 949 ])
 950
 951 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 952 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 953 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 954   AG_GST_CHECK_LIBHEADER(ZLIB,
 955     z, uncompress,, zlib.h, [
 956     HAVE_ZLIB="yes"
 957     ZLIB_LIBS="-lz"
 958     AC_SUBST(ZLIB_LIBS)
 959   ])
 960 ])
 961
 962 dnl *** matroska prefers to have bz2 ***
 963 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 964 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 965   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 966   AC_SUBST(BZ2_LIBS)
 967 ])
 968
 969 else
 970
 971 dnl not building plugins with external dependencies,
 972 dnl but we still need to set the conditionals
 973 AM_CONDITIONAL(USE_AALIB, false)
 974 AM_CONDITIONAL(USE_ANNODEX, false)
 975 AM_CONDITIONAL(USE_BZ2, false)
 976 AM_CONDITIONAL(USE_CAIRO, false)
 977 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 978 AM_CONDITIONAL(USE_DV1394, false)
 979 AM_CONDITIONAL(USE_ESD, false)
 980 AM_CONDITIONAL(USE_FLAC, false)
 981 AM_CONDITIONAL(USE_GCONF, false)
 982 AM_CONDITIONAL(USE_GCONFTOOL, false)
 983 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 984 AM_CONDITIONAL(USE_GST_V4L2, false)
 985 AM_CONDITIONAL(USE_HAL, false)
 986 AM_CONDITIONAL(USE_JPEG, false)
 987 AM_CONDITIONAL(USE_LIBCACA, false)
 988 AM_CONDITIONAL(USE_LIBDV, false)
 989 AM_CONDITIONAL(USE_LIBPNG, false)
 990 AM_CONDITIONAL(USE_OSS, false)
 991 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 992 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 993 AM_CONDITIONAL(USE_PULSE, false)
 994 AM_CONDITIONAL(USE_SHOUT2, false)
 995 AM_CONDITIONAL(USE_SOUP, false)
 996 AM_CONDITIONAL(USE_SPEEX, false)
 997 AM_CONDITIONAL(USE_SUNAUDIO, false)
 998 AM_CONDITIONAL(USE_TAGLIB, false)
 999 AM_CONDITIONAL(USE_WAVPACK, false)
1000 AM_CONDITIONAL(USE_X, false)
1001 AM_CONDITIONAL(USE_XSHM, false)
1002 AM_CONDITIONAL(USE_XVIDEO, false)
1003 AM_CONDITIONAL(USE_ZLIB, false)
1004
1005 fi dnl of EXT plugins
1006
1007 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1008
1009 dnl Overview:
1010 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1011 dnl GST_*:              flags shared by all built objects
1012 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1013 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1014 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1015 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1016
1017 dnl GST_OPTION_CFLAGS
1018 if test "x$USE_DEBUG" = xyes; then
1019    PROFILE_CFLAGS="-g"
1020 fi
1021 AC_SUBST(PROFILE_CFLAGS)
1022
1023 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1024   dnl Define _only_ for git (not pre-releases or releases)
1025   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1026 else
1027   DEPRECATED_CFLAGS=""
1028 fi
1029 AC_SUBST(DEPRECATED_CFLAGS)
1030
1031 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1032 dnl at make time with e.g. make ERROR_CFLAGS=""
1033 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1034 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1035 AC_SUBST(GST_OPTION_CFLAGS)
1036 AC_SUBST(GST_OPTION_CXXFLAGS)
1037
1038 dnl our libraries need to be versioned correctly
1039 AC_SUBST(GST_LT_LDFLAGS)
1040
1041 dnl FIXME: do we want to rename to GST_ALL_* ?
1042 dnl prefer internal headers to already installed ones
1043 dnl also add builddir include for enumtypes and marshal
1044 dnl add ERROR_CFLAGS, but overridable
1045 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1046 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1047 AC_SUBST(GST_CFLAGS)
1048 AC_SUBST(GST_CXXFLAGS)
1049 AC_SUBST(GST_LIBS)
1050
1051 dnl LDFLAGS really should only contain flags, not libs - they get added before
1052 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1053 GST_ALL_LDFLAGS="-no-undefined"
1054 AC_SUBST(GST_ALL_LDFLAGS)
1055
1056 dnl this really should only contain flags, not libs - they get added before
1057 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1058 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1059 AC_SUBST(GST_PLUGIN_LDFLAGS)
1060
1061 dnl *** output files ***
1062
1063 dnl keep this alphabetic per directory, please
1064 AC_CONFIG_FILES(
1065 Makefile
1066 gst/Makefile
1067 gst/alpha/Makefile
1068 gst/apetag/Makefile
1069 gst/audiofx/Makefile
1070 gst/auparse/Makefile
1071 gst/autodetect/Makefile
1072 gst/avi/Makefile
1073 gst/cutter/Makefile
1074 gst/deinterlace/Makefile
1075 gst/debugutils/Makefile
1076 gst/effectv/Makefile
1077 gst/equalizer/Makefile
1078 gst/flv/Makefile
1079 gst/id3demux/Makefile
1080 gst/icydemux/Makefile
1081 gst/interleave/Makefile
1082 gst/goom/Makefile
1083 gst/goom2k1/Makefile
1084 gst/law/Makefile
1085 gst/level/Makefile
1086 gst/matroska/Makefile
1087 gst/monoscope/Makefile
1088 gst/multifile/Makefile
1089 gst/multipart/Makefile
1090 gst/qtdemux/Makefile
1091 gst/replaygain/Makefile
1092 gst/rtp/Makefile
1093 gst/rtpmanager/Makefile
1094 gst/rtsp/Makefile
1095 gst/shapewipe/Makefile
1096 gst/smpte/Makefile
1097 gst/spectrum/Makefile
1098 gst/udp/Makefile
1099 gst/videobox/Makefile
1100 gst/videocrop/Makefile
1101 gst/videofilter/Makefile
1102 gst/videomixer/Makefile
1103 gst/wavenc/Makefile
1104 gst/wavparse/Makefile
1105 gst/flx/Makefile
1106 gst/y4m/Makefile
1107 ext/jpeg/Makefile
1108 ext/Makefile
1109 ext/aalib/Makefile
1110 ext/annodex/Makefile
1111 ext/cairo/Makefile
1112 ext/dv/Makefile
1113 ext/esd/Makefile
1114 ext/flac/Makefile
1115 ext/gconf/Makefile
1116 ext/gdk_pixbuf/Makefile
1117 ext/hal/Makefile
1118 ext/libcaca/Makefile
1119 ext/libpng/Makefile
1120 ext/pulse/Makefile
1121 ext/raw1394/Makefile
1122 ext/shout2/Makefile
1123 ext/soup/Makefile
1124 ext/speex/Makefile
1125 ext/taglib/Makefile
1126 ext/wavpack/Makefile
1127 sys/Makefile
1128 sys/directsound/Makefile
1129 sys/oss/Makefile
1130 sys/sunaudio/Makefile
1131 sys/osxaudio/Makefile
1132 sys/osxvideo/Makefile
1133 sys/v4l2/Makefile
1134 sys/waveform/Makefile
1135 sys/ximage/Makefile
1136 po/Makefile.in
1137 tests/Makefile
1138 tests/check/Makefile
1139 tests/examples/Makefile
1140 tests/examples/audiofx/Makefile
1141 tests/examples/equalizer/Makefile
1142 tests/examples/level/Makefile
1143 tests/examples/rtp/Makefile
1144 tests/examples/shapewipe/Makefile
1145 tests/examples/spectrum/Makefile
1146 tests/examples/v4l2/Makefile
1147 tests/files/Makefile
1148 tests/icles/Makefile
1149 gconf/Makefile
1150 gconf/gstreamer.schemas
1151 common/Makefile
1152 common/m4/Makefile
1153 m4/Makefile
1154 docs/Makefile
1155 docs/plugins/Makefile
1156 docs/version.entities
1157 pkgconfig/Makefile
1158 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1159 gst-plugins-good.spec
1160 )
1161
1162 dnl Create the config.h file for Visual Studio builds
1163 dnl Beware of spaces and /'s in some of the shell variable contents.
1164 sed \
1165     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1166     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1167     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1168     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1169     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1170     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1171     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1172     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1173     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1174     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1175     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1176     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1177     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1178     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1179     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1180     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1181     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1182     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1183     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1184     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1185     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1186     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1187     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1188     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1189     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1190     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1191     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1192     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1193     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1194     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1195     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1196     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1197     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1198     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1199     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1200     config.h.in >win32/common/config.h-new
1201
1202 AC_OUTPUT
1203
1204 AG_GST_OUTPUT_PLUGINS