configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [0])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [9])
   6 m4_define([folks_micro_version], [1])
   7 m4_define([folks_nano_version], [1])
   8
   9 # If library source has changed since last release, increment revision
  10 # If public symbols have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If public symbols have been added since last release, increment age
  13 # If public symbols have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [38])
  15 m4_define([folks_lt_revision], [1])
  16 m4_define([folks_lt_age], [13])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-xz no-define
  46                   no-dist-gzip tar-ustar -Wno-portability color-tests])
  47 AM_MAINTAINER_MODE([enable])
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54 GLIB_GSETTINGS
  55
  56 AC_SUBST([CFLAGS])
  57 AC_SUBST([CPPFLAGS])
  58 AC_SUBST([LDFLAGS])
  59
  60 LT_CURRENT=folks_lt_current
  61 LT_REVISION=folks_lt_revision
  62 LT_AGE=folks_lt_age
  63 AC_SUBST([LT_CURRENT])
  64 AC_SUBST([LT_REVISION])
  65 AC_SUBST([LT_AGE])
  66
  67 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  68 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  69
  70 API_VERSION=0.6
  71 AC_SUBST([API_VERSION])
  72
  73 AC_ARG_ENABLE(tracker-backend,
  74         AC_HELP_STRING([--enable-tracker-backend],
  75                        [ build the Tracker backend]),
  76         enable_tracker_backend=$enableval,
  77         enable_tracker_backend=no )
  78
  79 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  80
  81 AS_IF([test "x$enable_tracker_backend" = "xyes"], [
  82         AC_DEFINE(HAVE_TRACKER, [1],
  83                   [Define as 1 if you have the Tracker backend])
  84 ], [
  85         AC_DEFINE(HAVE_TRACKER, [0],
  86                   [Define as 1 if you have the Tracker backend])
  87 ])
  88
  89 AC_ARG_ENABLE(eds-backend,
  90         AC_HELP_STRING([--enable-eds-backend],
  91                        [ build the E-D-S backend]),
  92         enable_eds_backend=$enableval,
  93         enable_eds_backend=yes )
  94
  95 AS_IF([test "x$enable_eds_backend" = "xyes"], [
  96         AC_DEFINE(HAVE_EDS, [1], [Define as 1 if you have the eds backend])
  97 ], [
  98         AC_DEFINE(HAVE_EDS, [0], [Define as 1 if you have the eds backend])
  99 ])
 100
 101 AM_CONDITIONAL([ENABLE_EDS], [test "x$enable_eds_backend" = "xyes"])
 102
 103 AC_ARG_ENABLE(ofono-backend,
 104         AC_HELP_STRING([--enable-ofono-backend],
 105                        [ build the ofono backend]),
 106         enable_ofono_backend=$enableval,
 107         enable_ofono_backend=yes )
 108
 109 AS_IF([test "x$enable_ofono_backend" = "xyes"], [
 110         AC_DEFINE(HAVE_OFONO, [1], [Define as 1 if you have the ofono backend])
 111 ], [
 112         AC_DEFINE(HAVE_OFONO, [0], [Define as 1 if you have the ofono backend])
 113 ])
 114
 115 AM_CONDITIONAL([ENABLE_OFONO], [test "x$enable_ofono_backend" = "xyes"])
 116
 117 AC_ARG_ENABLE(telepathy-backend,
 118         AC_HELP_STRING([--enable-telepathy-backend],
 119                        [ build the Telepathy backend]),
 120         enable_telepathy_backend=$enableval,
 121         enable_telepathy_backend=yes )
 122
 123 AS_IF([test "x$enable_telepathy_backend" = "xyes"], [
 124         AC_DEFINE(HAVE_TELEPATHY, [1], [Define as 1 if you have the Telepathy backend])
 125 ], [
 126         AC_DEFINE(HAVE_TELEPATHY, [0], [Define as 1 if you have the Telepathy backend])
 127 ])
 128
 129 AM_CONDITIONAL([ENABLE_TELEPATHY], [test "x$enable_telepathy_backend" = "xyes"])
 130
 131 # Automatically check the dependencies for the libsocialweb backend
 132 SW_CLIENT_REQUIRED=0.25.20
 133 AC_ARG_ENABLE(libsocialweb-backend,
 134         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
 135                        [build the Libsocialweb backend (default: auto)]),
 136         enable_libsocialweb_backend=$enableval,
 137         enable_libsocialweb_backend=auto )
 138
 139 # this may be overwritten farther down
 140 AC_DEFINE(HAVE_LIBSOCIALWEB, [0],
 141           [Define as 1 if you have the libsocialweb backend])
 142 AS_IF([test "x$enable_libsocialweb_backend" != "xno"], [
 143   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
 144       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
 145   AS_IF([test "x$have_libsocialweb_backend" = "xyes" -a \
 146           "x$enable_vala" = "xyes"], [
 147     VALA_CHECK_PACKAGES([telepathy-glib
 148                          gio-2.0
 149                          gee-0.8
 150                          libsocialweb-client],
 151         ,
 152         have_libsocialweb_backend="no")
 153   ])
 154
 155   AS_IF([test "x$have_libsocialweb_backend" = "xyes"], [
 156     AC_DEFINE(HAVE_LIBSOCIALWEB, [1],
 157               [Define if you have the libsocialweb backend])
 158   ])
 159 ], [
 160    have_libsocialweb_backend=no
 161 ])
 162
 163 AS_IF([test "x$enable_libsocialweb_backend" = "xyes" -a \
 164   "x$have_libsocialweb_backend" != "xyes"], [
 165     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 166 ])
 167
 168 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 169         [test "x$have_libsocialweb_backend" = "xyes"])
 170
 171 # -----------------------------------------------------------
 172 # Dependencies
 173 # -----------------------------------------------------------
 174
 175 GLIB_REQUIRED=2.32.0
 176 VALA_REQUIRED=0.17.6
 177 VALADOC_REQUIRED=0.3.1
 178 TRACKER_SPARQL_MAJOR=0.16
 179 TRACKER_SPARQL_REQUIRED=0.15.2
 180 EBOOK_REQUIRED=3.7.90
 181 EDATASERVER_REQUIRED=3.5.3.1
 182 ZEITGEIST_REQUIRED=0.3.14
 183 GEE_REQUIRED=0.8.4
 184
 185 AC_SUBST([TRACKER_SPARQL_MAJOR])
 186
 187 PKG_CHECK_MODULES([GLIB],
 188                   [glib-2.0 >= $GLIB_REQUIRED
 189                    gobject-2.0 >= $GLIB_REQUIRED])
 190 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 191 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 192 # FIXME: get rid of this when our dependencies stop using dbus-1 (GNOME#696177)
 193 PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1 dbus-1])
 194
 195 PKG_CHECK_MODULES([GEE], [gee-0.8 >= $GEE_REQUIRED])
 196
 197 TP_GLIB_REQUIRED=0.19.0
 198 AS_IF([test x$enable_telepathy_backend = xyes], [
 199         PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
 200         PKG_CHECK_MODULES([ZEITGEIST], [zeitgeist-1.0 >= $ZEITGEIST_REQUIRED],
 201                            have_zeitgeist="yes",have_zeitgeist="no")])
 202 AS_IF([test "x$have_zeitgeist" == "xyes"], [
 203    ZEITGEIST_VALAFLAGS="-D HAVE_ZEITGEIST"
 204    AC_SUBST([ZEITGEIST_VALAFLAGS])
 205    ZEITGEIST_PKG="--pkg zeitgeist-1.0"
 206    AC_SUBST([ZEITGEIST_PKG])
 207 ])
 208
 209 # Ignore post 0.20 deprecations
 210 TP_GLIB_CFLAGS="$TP_GLIB_CFLAGS -DTP_VERSION_MIN_REQUIRED=TP_VERSION_0_20"
 211 # Prevent post 0.20 APIs
 212 TP_GLIB_CFLAGS="$TP_GLIB_CFLAGS -DTP_VERSION_MAX_ALLOWED=TP_VERSION_0_20"
 213
 214 AS_IF([test x$enable_tracker_backend = xyes], [
 215         PKG_CHECK_MODULES([TRACKER_SPARQL],
 216                           [tracker-sparql-$TRACKER_SPARQL_MAJOR >= \
 217                            $TRACKER_SPARQL_REQUIRED])
 218 ])
 219
 220 AS_IF([test x$enable_eds_backend = xyes], [
 221         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED
 222                                     libebook-contacts-1.2 >= $EBOOK_REQUIRED])
 223         PKG_CHECK_MODULES([EDATASERVER], [libedataserver-1.2 >= $EDATASERVER_REQUIRED])
 224 ])
 225
 226 AS_IF([test x$enable_ofono_backend = xyes], [
 227         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED])
 228 ])
 229
 230 #
 231 # Vala building options -- allows tarball builds without installing Vala
 232 #
 233 AC_ARG_ENABLE([vala],
 234               AS_HELP_STRING([--enable-vala],
 235                              [Enable building from the Vala sources]),
 236               [enable_vala=$enableval],
 237               [enable_vala=no])
 238
 239 # will be re-set as necessary below
 240 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 241 sd=${srcdir}/
 242
 243 # Force Vala for non-release builds
 244 m4_if(folks_released, [1], [],
 245     [
 246         enable_vala=yes
 247         echo "Vala compiler required for non-release builds; requiring Vala..."
 248     ])
 249
 250 # Force Vala if generated source is missing or outdated
 251 AS_IF([test \
 252         ! -e ${sd}tools/folks_import_vala.stamp -o \
 253         ! -e ${sd}tests/folks/abstract_field_details_vala.stamp -o \
 254         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 255         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 256         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 257         ! -e ${sd}tests/lib/folks-test.vapi -o \
 258         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 259         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 260         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 261         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 262         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 263         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 264         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 265         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 266         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 267         ! -e ${sd}backends/key-file/key_file_la_vala.stamp -o \
 268         ! -e ${sd}backends/telepathy/telepathy_la_vala.stamp \
 269                 -o \
 270         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 271         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 272         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 273         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 274         ! -e ${sd}folks/folks-internal.h -o \
 275         ! -e ${sd}folks/folks-internal.vapi -o \
 276         ! -e ${sd}folks/libfolks_internal_la_vala.stamp -o \
 277         ! -e ${sd}folks/folks.vapi -o \
 278         ! -e ${sd}folks/libfolks_la_vala.stamp \
 279       ], [
 280         enable_vala=yes
 281         echo "Vala source needs to be re-compiled; requiring Vala..."
 282 ])
 283
 284 AS_IF([test "x$enable_vala" = "xyes"], [
 285         AM_PROG_VALAC([$VALA_REQUIRED])
 286         AS_IF([test "x$VALAC" = "x"], [
 287               AC_MSG_ERROR([Vala requested but valac is not installed])
 288         ])
 289
 290         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 291         AS_IF([test "x$VAPIGEN" = "x"], [
 292               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 293         ])
 294
 295         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 296         # automatically
 297         AM_VALAFLAGS="--target-glib=2.24"
 298         AC_SUBST([AM_VALAFLAGS])
 299         AC_SUBST([VAPIGENFLAGS])
 300         AC_SUBST([VAPIDIR])
 301
 302         VALA_CHECK_PACKAGES([gio-2.0
 303                              gee-0.8])
 304
 305         AS_IF([test x$enable_telepathy_backend = xyes], [
 306           VALA_CHECK_PACKAGES([telepathy-glib])
 307           AS_IF([test "x$have_zeitgeist" == "xyes"], [
 308               VALA_CHECK_PACKAGES([zeitgeist-1.0])
 309           ])
 310         ])
 311
 312         AS_IF([test x$enable_tracker_backend = xyes], [
 313           VALA_CHECK_PACKAGES([tracker-sparql-$TRACKER_SPARQL_MAJOR])
 314         ])
 315
 316         AS_IF([test x$enable_eds_backend = xyes], [
 317           VALA_CHECK_PACKAGES([libebook-1.2 libebook-contacts-1.2 libedataserver-1.2 libxml-2.0])
 318         ])
 319
 320         AS_IF([test x$enable_ofono_backend = xyes], [
 321           VALA_CHECK_PACKAGES([libebook-1.2])
 322         ])
 323 ])
 324
 325 # this will set HAVE_INTROSPECTION
 326 GOBJECT_INTROSPECTION_REQUIRE([1.30])
 327
 328 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 329
 330 # Various functions that we need (used in C code generated from Vala)
 331 AC_CHECK_FUNCS([memset])
 332 AC_CHECK_FUNCS([strstr])
 333
 334 AM_CONDITIONAL([NOT_RELEASE], [test "x$folks_released" = "x0"])
 335
 336 # -----------------------------------------------------------
 337 # Backends
 338 # -----------------------------------------------------------
 339
 340 FOLKS_MODULE_VERSION=folks_module_version
 341 AC_SUBST([FOLKS_MODULE_VERSION])
 342 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 343
 344 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 345 AC_SUBST([BACKEND_DIR])
 346
 347 # -----------------------------------------------------------
 348 # Tools
 349 # -----------------------------------------------------------
 350
 351 AC_ARG_ENABLE([import-tool],
 352               AS_HELP_STRING([--enable-import-tool],
 353                              [Enable building the meta-contact import tool]),
 354               [enable_import_tool=$enableval with_import_tool=$enableval],
 355               [enable_import_tool=maybe with_import_tool=no])
 356 AS_IF([test "$enable_import_tool" != "no"],
 357       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 358                          [with_import_tool=yes], [with_import_tool=no])])
 359 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 360       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 361 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 362
 363 # Readline's required for the folks-inspect program
 364 AC_ARG_ENABLE([inspect-tool],
 365               AS_HELP_STRING([--enable-inspect-tool],
 366                              [Enable building the data inspection tool]),
 367               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 368               [enable_inspect_tool=maybe with_inspect_tool=no])
 369 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 370       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 371                      using --enable-vala])])
 372 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 373       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 374                       --enable-vala])])
 375 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 376       [AC_CHECK_LIB([readline], [main],
 377                     [with_inspect_tool=yes], [with_inspect_tool=no],
 378                     [-lncurses])])
 379 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 380        "x$enable_vala" = "xyes"],
 381       [VALA_CHECK_PACKAGES([readline])
 382        LIBREADLINE="-lreadline -lncurses"
 383        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 384        AC_SUBST([LIBREADLINE])])
 385 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 386       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 387 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 388
 389 # -----------------------------------------------------------
 390 # Tests
 391 # -----------------------------------------------------------
 392
 393 AC_ARG_ENABLE([tests],
 394               AS_HELP_STRING([--enable-tests],[Enable building of tests]),
 395               [enable_tests=$enableval], [enable_tests=yes])
 396 AM_CONDITIONAL([ENABLE_TESTS], [test x$enable_tests = xyes])
 397
 398 # -----------------------------------------------------------
 399 # Documentation
 400 # -----------------------------------------------------------
 401
 402 AC_ARG_ENABLE([docs],
 403               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 404               [enable_docs=$enableval], [enable_docs=no])
 405 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 406
 407 have_valadoc=no
 408 AS_IF([test x$enable_docs = xyes], [
 409   # make sure the library is new enough and the program exists
 410   PKG_CHECK_MODULES([VALADOC], [valadoc-1.0 >= $VALADOC_REQUIRED])
 411   AC_PATH_PROG([VALADOC], [valadoc], [:])
 412   AS_IF([test "$VALADOC" != :], have_valadoc=yes)
 413 ])
 414 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 415
 416 AS_IF([test "x$enable_docs" = "xyes" -a "x$have_valadoc" != "xyes"], [
 417     AC_MSG_ERROR([Doc building requested but valadoc not installed.])
 418 ])
 419
 420 # -----------------------------------------------------------
 421 # Gettext
 422 # -----------------------------------------------------------
 423
 424 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 425 AC_SUBST(GETTEXT_PACKAGE)
 426 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 427 IT_PROG_INTLTOOL([0.50.0])
 428
 429 # -----------------------------------------------------------
 430 # Error flags
 431 # -----------------------------------------------------------
 432
 433 # Disable GLib deprecation warnings for now (#670196); GValueArray is deprecated
 434 # but we need it for dbus-glib. Porting to GDBus will solve this (#653198)
 435 AC_DEFINE(GLIB_DISABLE_DEPRECATION_WARNINGS, 1, [Build with GLib deprecated])
 436
 437 AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
 438 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 439
 440 AC_ARG_ENABLE([debug],
 441               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 442               [enable_debug=$enableval], [enable_debug=yes])
 443
 444 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 445 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 446                  [wno_missing_field_initializers=yes],
 447                  [wno_missing_field_initializers=no])
 448 AS_COMPILER_FLAG([-Wno-unused-parameter],
 449                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 450 AS_COMPILER_FLAG([-Wstrict-prototypes], [wstrict_prototypes=yes],
 451                  [wstrict_prototypes=no])
 452 AS_COMPILER_FLAG([-Wmissing-prototypes], [wmissing_prototypes=yes],
 453                  [wmissing_prototypes=no])
 454 AS_COMPILER_FLAG([-Wimplicit-function-declaration],
 455                  [wimplicit_function_declaration=yes],
 456                  [wimplicit_function_declaration=no])
 457 AS_COMPILER_FLAG([-Wpointer-arith], [wpointer_arith=yes], [wpointer_arith=no])
 458 AS_COMPILER_FLAG([-Winit-self], [winit_self=yes], [winit_self=no])
 459 AS_COMPILER_FLAG([-Wformat=2], [wformat=yes], [wformat=no])
 460 AS_COMPILER_FLAG([-Wmissing-include-dirs], [wmissing_include_dirs=yes],
 461                  [wmissing_include_dirs=no])
 462 AS_COMPILER_FLAG([-Waggregate-return], [waggregate_return=yes],
 463                  [waggregate_return=no])
 464 AS_COMPILER_FLAG([-Wdeclaration-after-statement],
 465                  [wdeclaration_after_statement=yes],
 466                  [wdeclaration_after_statement=no])
 467
 468 m4_if(folks_released, [1], [],
 469     [
 470         # Iff we support -Werror, then use it with all our compiler warnings.
 471         if test x$werror = xyes; then
 472             flag="-Werror="
 473         else
 474             flag="-W"
 475         fi
 476
 477         if test x$wextra = xyes -a \
 478             x$wno_missing_field_initializers = xyes -a \
 479             x$wno_unused_parameter = xyes -a x$wstrict_prototypes = xyes -a \
 480             x$wmissing_prototypes = xyes -a \
 481             x$wimplicit_function_declaration = xyes -a x$wpointer_arith = xyes \
 482             -a x$winit_self = xyes -a x$wformat = xyes -a \
 483             x$wmissing_include_dirs = xyes -a x$waggregate_return = xyes -a \
 484             x$wdeclaration_after_statement = xyes; then
 485             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra \
 486                 -Wno-missing-field-initializers \
 487                 -Wno-unused-parameter ${flag}strict-prototypes \
 488                 ${flag}missing-prototypes ${flag}implicit-function-declaration \
 489                 ${flag}pointer-arith ${flag}init-self ${flag}format=2 \
 490                 ${flag}missing-include-dirs ${flag}aggregate-return \
 491                 ${flag}declaration-after-statement"
 492         fi
 493     ])
 494
 495 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
 496 AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
 497 AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
 498 AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 499                                           -Wmissing-prototypes"])
 500 AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS \
 501                                             -Wmissing-declarations"])
 502 AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 503                                          -Wstrict-prototypes"])
 504
 505 AC_SUBST([ERROR_CFLAGS])
 506
 507 # -----------------------------------------------------------
 508 # Code coverage flags
 509 # -----------------------------------------------------------
 510
 511 AC_ARG_ENABLE([code-coverage],
 512               AS_HELP_STRING([--enable-code-coverage],
 513                              [compile with code coverage code]),
 514               [enable_code_coverage=$enableval], [enable_code_coverage=no])
 515
 516 # Only enable code coverage if this isn't a release.
 517 m4_if(folks_released, [1], [],
 518     [
 519         if test "x$GCC" = "xyes"; then
 520             if test "x$enable_code_coverage" = "xyes"; then
 521                 CODE_COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage -O0 -ggdb"
 522                 CODE_COVERAGE_LDFLAGS="-lgcov"
 523             fi
 524         fi
 525     ])
 526
 527 AC_SUBST([CODE_COVERAGE_CFLAGS])
 528 AC_SUBST([CODE_COVERAGE_LDFLAGS])
 529
 530 # Vala-related flags
 531 AC_ARG_ENABLE([fatal-warnings],
 532               AS_HELP_STRING([--disable-fatal-warnings],
 533                              [Make warnings from valac and g-ir-scanner non-fatal]),
 534               [enable_fatal_warnings=$enableval], [enable_fatal_warnings=yes])
 535 AS_IF([test "x$enable_vala" = "xyes" && test "x$enable_fatal_warnings" = "xyes"],
 536       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 537                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 538        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 539
 540 # Disable -g if we're building with code coverage enabled, since Vala's
 541 # insertion of #line directives into .c files confuses lcov. For the moment,
 542 # we'll have to do with looking at code coverage of the generated C files only.
 543 # We set the debug flags in CODE_COVERAGE_CFLAGS instead in that case.
 544 m4_if(folks_released, [1], [],
 545     [
 546         if test "x$enable_code_coverage" != "xyes" -o "x$GCC" != "xyes"; then
 547             ERROR_VALAFLAGS="$ERROR_VALAFLAGS -g"
 548         fi
 549     ])
 550
 551 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 552 AC_SUBST([ERROR_VALAFLAGS])
 553
 554 # -----------------------------------------------------------
 555 # Profiling
 556 # -----------------------------------------------------------
 557
 558 AC_ARG_ENABLE([profiling],
 559               AS_HELP_STRING([--enable-profiling],
 560                              [Enable building profiling points]),
 561               [enable_profiling=$enableval],
 562               [enable_profiling=no])
 563 AM_CONDITIONAL([ENABLE_PROFILING], [test "$enable_profiling" = "yes"])
 564
 565 # -----------------------------------------------------------
 566 # Final output
 567 # -----------------------------------------------------------
 568
 569 AC_CONFIG_FILES([
 570     backends/telepathy/lib/folks-telepathy.pc
 571     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 572     backends/tracker/lib/folks-tracker.deps
 573     backends/tracker/lib/folks-tracker.pc
 574     backends/tracker/lib/folks-tracker-uninstalled.pc
 575     backends/eds/lib/folks-eds.pc
 576     backends/eds/lib/folks-eds-uninstalled.pc
 577     folks/folks.pc
 578     folks/folks-uninstalled.pc
 579     folks/org.freedesktop.folks.gschema.xml
 580     Makefile
 581     backends/Makefile
 582     backends/key-file/Makefile
 583     backends/libsocialweb/Makefile
 584     backends/libsocialweb/lib/Makefile
 585     backends/libsocialweb/lib/folks-libsocialweb.pc
 586     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 587     backends/telepathy/Makefile
 588     backends/telepathy/lib/Makefile
 589     backends/tracker/Makefile
 590     backends/tracker/lib/Makefile
 591     backends/eds/Makefile
 592     backends/eds/lib/Makefile
 593     backends/ofono/Makefile
 594     folks/Makefile
 595     docs/Makefile
 596     po/Makefile.in
 597     tests/Makefile
 598     tests/data/Makefile
 599     tests/eds/Makefile
 600     tests/folks/Makefile
 601     tests/key-file/Makefile
 602     tests/libsocialweb/Makefile
 603     tests/telepathy/Makefile
 604     tests/tracker/Makefile
 605     tests/lib/Makefile
 606     tests/lib/folks-test-uninstalled.pc
 607     tests/lib/eds/Makefile
 608     tests/lib/key-file/Makefile
 609     tests/lib/libsocialweb/Makefile
 610     tests/lib/telepathy/Makefile
 611     tests/lib/tracker/Makefile
 612     tests/lib/telepathy/contactlist/Makefile
 613     tests/tools/Makefile
 614     tools/Makefile
 615     tools/inspect/Makefile
 616 ])
 617
 618 AC_OUTPUT
 619
 620 echo "
 621 Configure summary:
 622
 623         Vala........................:  ${enable_vala}
 624         Vala Compiler...............:  ${VALAC}
 625         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS} ${CODE_COVERAGE_CFLAGS}
 626         Linker Flags................:  ${LDFLAGS} ${CODE_COVERAGE_LDFLAGS}
 627         Prefix......................:  ${prefix}
 628         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 629         Documentation...............:  ${have_valadoc}
 630         Import tool.................:  ${with_import_tool}
 631         Inspector tool..............:  ${with_inspect_tool}
 632         Telepathy backend...........:  ${enable_telepathy_backend}
 633         Tracker backend.............:  ${enable_tracker_backend}
 634         Libsocialweb backend........:  ${have_libsocialweb_backend}
 635         E-D-S backend...............:  ${enable_eds_backend}
 636         Ofono backend...............:  ${enable_ofono_backend}
 637         Zeitgeist support...........:  ${have_zeitgeist}
 638         Build tests.................:  ${enable_tests}
 639 "