configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Configure input file for elfutils.                     -*-autoconf-*-
   3 dnl
   4 dnl Copyright (C) 1996-2017 Red Hat, Inc.
   5 dnl
   6 dnl This file is part of elfutils.
   7 dnl
   8 dnl  This file is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 3 of the License, or
  11 dnl  (at your option) any later version.
  12 dnl
  13 dnl  elfutils is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl  GNU General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 AC_INIT([elfutils],[0.170],[https://sourceware.org/bugzilla],[elfutils],[http://elfutils.org/])
  21
  22 dnl Workaround for older autoconf < 2.64
  23 m4_ifndef([AC_PACKAGE_URL],
  24          [AC_DEFINE([PACKAGE_URL], ["http://elfutils.org/"],
  25                     [Define to home page for this package])
  26           AC_SUBST([PACKAGE_URL], ["http://elfutils.org/"])])
  27
  28 # We want eu- as default program prefix if none was given by the user.
  29 # But if the user explicitly provided --program-prefix="" then pretend
  30 # it wasn't set at all (NONE). We want to test this really early before
  31 # configure has a chance to use the value.
  32
  33 if test "x$program_prefix" = "xNONE"; then
  34   AC_MSG_NOTICE([No --program-prefix given, using "eu-"])
  35   program_prefix="eu-"
  36 elif test "x$program_prefix" = "x"; then
  37   AC_MSG_NOTICE([Using no program-prefix])
  38   program_prefix=NONE
  39 fi
  40
  41 AC_CONFIG_AUX_DIR([config])
  42 AC_CONFIG_FILES([config/Makefile])
  43
  44 AC_COPYRIGHT([Copyright (C) 1996-2017 The elfutils developers.])
  45 AC_PREREQ(2.63)                 dnl Minimum Autoconf version required.
  46
  47 dnl We use GNU make extensions; automake 1.10 defaults to -Wportability.
  48 AM_INIT_AUTOMAKE([gnits 1.11 -Wno-portability dist-bzip2 no-dist-gzip parallel-tests])
  49 AM_MAINTAINER_MODE
  50
  51 AM_SILENT_RULES([yes])
  52
  53 AC_CONFIG_SRCDIR([libelf/libelf.h])
  54 AC_CONFIG_FILES([Makefile])
  55 AC_CONFIG_HEADERS([config.h])
  56
  57 AC_CONFIG_MACRO_DIR([m4])
  58 AC_CONFIG_FILES([m4/Makefile])
  59
  60 dnl The RPM spec file.  We substitute a few values in the file.
  61 AC_CONFIG_FILES([elfutils.spec:config/elfutils.spec.in])
  62
  63
  64 AC_CANONICAL_HOST
  65
  66 AC_ARG_ENABLE(deterministic-archives,
  67 [AS_HELP_STRING([--enable-deterministic-archives],
  68                 [ar and ranlib default to -D behavior])], [
  69 if test "${enableval}" = no; then
  70   default_ar_deterministic=false
  71 else
  72   default_ar_deterministic=true
  73 fi], [default_ar_deterministic=false])
  74 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  75                    [Should ar and ranlib use -D behavior by default?])
  76
  77 AC_ARG_ENABLE([thread-safety],
  78 AS_HELP_STRING([--enable-thread-safety],
  79                [enable thread safety of libraries EXPERIMENTAL]),
  80                use_locks=$enableval, use_locks=no)
  81 AM_CONDITIONAL(USE_LOCKS, test "$use_locks" = yes)
  82 AS_IF([test "$use_locks" = yes], [AC_DEFINE(USE_LOCKS)])
  83 AS_IF([test "$use_locks" = yes],
  84       [AC_MSG_WARN([thread-safety is EXPERIMENTAL tests might fail.])])
  85
  86 AH_TEMPLATE([USE_LOCKS], [Defined if libraries should be thread-safe.])
  87
  88 AC_PROG_CC
  89 AC_PROG_RANLIB
  90 AC_PROG_YACC
  91 AM_PROG_LEX
  92 # Only available since automake 1.12
  93 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  94 AC_CHECK_TOOL([READELF], [readelf])
  95 AC_CHECK_TOOL([NM], [nm])
  96
  97 # We use -std=gnu99 but have explicit checks for some language constructs
  98 # and GNU extensions since some compilers claim GNU99 support, but don't
  99 # really support all language extensions. In particular we need
 100 # Mixed Declarations and Code
 101 # https://gcc.gnu.org/onlinedocs/gcc/Mixed-Declarations.html
 102 # Nested Functions
 103 # https://gcc.gnu.org/onlinedocs/gcc/Nested-Functions.html
 104 # Arrays of Variable Length
 105 # https://gcc.gnu.org/onlinedocs/gcc/Variable-Length.html
 106 AC_CACHE_CHECK([for gcc with GNU99 support], ac_cv_c99, [dnl
 107 old_CFLAGS="$CFLAGS"
 108 CFLAGS="$CFLAGS -std=gnu99"
 109 AC_COMPILE_IFELSE([AC_LANG_SOURCE([dnl
 110 int foo (int a)
 111 {
 112   for (int i = 0; i < a; ++i) if (i % 4) break; int s = a; return s;
 113 }
 114
 115 double bar (double a, double b)
 116 {
 117   double square (double z) { return z * z; }
 118   return square (a) + square (b);
 119 }
 120
 121 void baz (int n)
 122 {
 123   struct S { int x[[n]]; };
 124 }])],
 125                   ac_cv_c99=yes, ac_cv_c99=no)
 126 CFLAGS="$old_CFLAGS"])
 127 AS_IF([test "x$ac_cv_c99" != xyes],
 128       AC_MSG_ERROR([gcc with GNU99 support required]))
 129
 130 AC_CACHE_CHECK([whether gcc supports __attribute__((visibility()))],
 131         ac_cv_visibility, [dnl
 132 save_CFLAGS="$CFLAGS"
 133 CFLAGS="$save_CFLAGS -Werror"
 134 AC_COMPILE_IFELSE([AC_LANG_SOURCE([dnl
 135 int __attribute__((visibility("hidden")))
 136 foo (int a)
 137 {
 138   return a;
 139 }])], ac_cv_visibility=yes, ac_cv_visibility=no)
 140 CFLAGS="$save_CFLAGS"])
 141 if test "$ac_cv_visibility" = "yes"; then
 142         AC_DEFINE([HAVE_VISIBILITY], [1],
 143                   [Defined if __attribute__((visibility())) is supported])
 144 fi
 145
 146 AC_CACHE_CHECK([whether gcc supports -fPIC], ac_cv_fpic, [dnl
 147 save_CFLAGS="$CFLAGS"
 148 CFLAGS="$save_CFLAGS -fPIC -Werror"
 149 AC_COMPILE_IFELSE([AC_LANG_SOURCE()], ac_cv_fpic=yes, ac_cv_fpic=no)
 150 CFLAGS="$save_CFLAGS"
 151 ])
 152 if test "$ac_cv_fpic" = "yes"; then
 153         fpic_CFLAGS="-fPIC"
 154 else
 155         fpic_CFLAGS=""
 156 fi
 157 AC_SUBST([fpic_CFLAGS])
 158
 159 AC_CACHE_CHECK([whether gcc supports -fPIE], ac_cv_fpie, [dnl
 160 save_CFLAGS="$CFLAGS"
 161 CFLAGS="$save_CFLAGS -fPIE -Werror"
 162 AC_COMPILE_IFELSE([AC_LANG_SOURCE()], ac_cv_fpie=yes, ac_cv_fpie=no)
 163 CFLAGS="$save_CFLAGS"
 164 ])
 165 if test "$ac_cv_fpie" = "yes"; then
 166         fpie_CFLAGS="-fPIE"
 167 else
 168         fpie_CFLAGS=""
 169 fi
 170 AC_SUBST([fpie_CFLAGS])
 171
 172 dso_LDFLAGS="-shared"
 173
 174 ZDEFS_LDFLAGS="-Wl,-z,defs"
 175 AC_CACHE_CHECK([whether gcc supports $ZDEFS_LDFLAGS], ac_cv_zdefs, [dnl
 176 save_LDFLAGS="$LDFLAGS"
 177 LDFLAGS="$ZDEFS_LDFLAGS $save_LDFLAGS"
 178 AC_LINK_IFELSE([AC_LANG_PROGRAM()], ac_cv_zdefs=yes, ac_cv_zdefs=no)
 179 LDFLAGS="$save_LDFLAGS"
 180 ])
 181 if test "$ac_cv_zdefs" = "yes"; then
 182         dso_LDFLAGS="$dso_LDFLAGS $ZDEFS_LDFLAGS"
 183 fi
 184
 185 ZRELRO_LDFLAGS="-Wl,-z,relro"
 186 AC_CACHE_CHECK([whether gcc supports $ZRELRO_LDFLAGS], ac_cv_zrelro, [dnl
 187 save_LDFLAGS="$LDFLAGS"
 188 LDFLAGS="$ZRELRO_LDFLAGS $save_LDFLAGS"
 189 AC_LINK_IFELSE([AC_LANG_PROGRAM()], ac_cv_zrelro=yes, ac_cv_zrelro=no)
 190 LDFLAGS="$save_LDFLAGS"
 191 ])
 192 if test "$ac_cv_zrelro" = "yes"; then
 193         dso_LDFLAGS="$dso_LDFLAGS $ZRELRO_LDFLAGS"
 194 fi
 195
 196 AC_SUBST([dso_LDFLAGS])
 197
 198 AC_CACHE_CHECK([for __thread support], ac_cv_tls, [dnl
 199 # Use the same flags that we use for our DSOs, so the test is representative.
 200 # Some old compiler/linker/libc combinations fail some ways and not others.
 201 save_CFLAGS="$CFLAGS"
 202 save_LDFLAGS="$LDFLAGS"
 203 CFLAGS="$fpic_CFLAGS $CFLAGS"
 204 LDFLAGS="$dso_LDFLAGS $LDFLAGS"
 205 AC_LINK_IFELSE([dnl
 206 AC_LANG_PROGRAM([[#include <stdlib.h>
 207 #undef __thread
 208 static __thread int a; int foo (int b) { return a + b; }]],
 209                 [[exit (foo (0));]])],
 210                ac_cv_tls=yes, ac_cv_tls=no)
 211 CFLAGS="$save_CFLAGS"
 212 LDFLAGS="$save_LDFLAGS"])
 213 AS_IF([test "x$ac_cv_tls" != xyes],
 214       AC_MSG_ERROR([__thread support required]))
 215
 216 dnl This test must come as early as possible after the compiler configuration
 217 dnl tests, because the choice of the file model can (in principle) affect
 218 dnl whether functions and headers are available, whether they work, etc.
 219 AC_SYS_LARGEFILE
 220
 221 dnl Older glibc had a broken fts that didn't work with Large File Systems.
 222 dnl We want the version that can handler LFS, but include workaround if we
 223 dnl get a bad one. Add define to CFLAGS (not AC_DEFINE it) since we need to
 224 dnl check it before including config.h (which might define _FILE_OFFSET_BITS).
 225 AC_CACHE_CHECK([whether fts.h is bad when included (with LFS)], ac_cv_bad_fts,
 226   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <fts.h>]])],
 227                      ac_cv_bad_fts=no, ac_cv_bad_fts=yes)])
 228 AS_IF([test "x$ac_cv_bad_fts" = "xyes"], [CFLAGS="$CFLAGS -DBAD_FTS=1"])
 229
 230 # See if we can add -D_FORTIFY_SOURCE=2. Don't do it if it is already
 231 # (differently) defined or if it generates warnings/errors because we
 232 # don't use the right optimisation level (string.h will warn about that).
 233 AC_MSG_CHECKING([whether to add -D_FORTIFY_SOURCE=2 to CFLAGS])
 234 case "$CFLAGS" in
 235   *-D_FORTIFY_SOURCE=2*)
 236     AC_MSG_RESULT([no, already there])
 237     ;;
 238   *)
 239     save_CFLAGS="$CFLAGS"
 240     CFLAGS="-D_FORTIFY_SOURCE=2 -Werror $CFLAGS"
 241     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 242       #include <string.h>
 243       int main() { return 0; }
 244     ]])], [ AC_MSG_RESULT([yes])
 245             CFLAGS="-D_FORTIFY_SOURCE=2 $save_CFLAGS" ],
 246           [ AC_MSG_RESULT([no])
 247             CFLAGS="$save_CFLAGS"])
 248   ;;
 249 esac
 250
 251 dnl enable debugging of branch prediction.
 252 AC_ARG_ENABLE([debugpred],
 253 AS_HELP_STRING([--enable-debugpred],[build binaries with support to debug branch prediction]),
 254 [use_debugpred=$enableval], [use_debugpred=no])
 255 case $use_debugpred in
 256  yes) use_debugpred_val=1 ;;
 257  *)   use_debugpred_val=0 ;;
 258 esac
 259 AC_SUBST([DEBUGPRED], $use_debugpred_val)
 260
 261 dnl Enable gprof suport.
 262 AC_ARG_ENABLE([gprof],
 263 AS_HELP_STRING([--enable-gprof],[build binaries with gprof support]), [use_gprof=$enableval], [use_gprof=no])
 264 if test "$use_gprof" = yes; then
 265   CFLAGS="$CFLAGS -pg"
 266   LDFLAGS="$LDFLAGS -pg"
 267 fi
 268 AM_CONDITIONAL(GPROF, test "$use_gprof" = yes)
 269
 270 # Enable gcov suport.
 271 AC_ARG_ENABLE([gcov],
 272 AS_HELP_STRING([--enable-gcov],[build binaries with gcov support]), [use_gcov=$enableval], [use_gcov=no])
 273 if test "$use_gcov" = yes; then
 274   CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 275   LDFLAGS="$LDFLAGS -fprofile-arcs"
 276 fi
 277 AM_CONDITIONAL(GCOV, test "$use_gcov" = yes)
 278
 279 AC_ARG_ENABLE([sanitize-undefined],
 280               AS_HELP_STRING([--enable-sanitize-undefined],
 281                              [Use gcc undefined behaviour sanitizer]),
 282                              [use_undefined=$enableval], [use_undefined=no])
 283 if test "$use_undefined" = yes; then
 284   old_CFLAGS="$CFLAGS"
 285   old_CXXFLAGS="$CXXFLAGS"
 286   # We explicitly use unaligned access when possible (see ALLOW_UNALIGNED)
 287   # We want to fail immediately on first error, don't try to recover.
 288   CFLAGS="$CFLAGS -fsanitize=undefined -fno-sanitize-recover"
 289   CXXFLAGS="$CXXFLAGS -fsanitize=undefined -fno-sanitize-recover"
 290   AC_LINK_IFELSE([AC_LANG_SOURCE([int main (int argc, char **argv) { return 0; }])], use_undefined=yes, use_undefined=no)
 291   AS_IF([test "x$use_undefined" != xyes],
 292         AC_MSG_WARN([gcc undefined behaviour sanitizer not available])
 293         CFLAGS="$old_CFLAGS" CXXFLAGS="$old_CXXFLAGS")
 294 fi
 295 case $use_undefined in
 296  yes) check_undefined_val=1 ;;
 297  *)   check_undefined_val=0 ;;
 298 esac
 299 AC_DEFINE_UNQUOTED(CHECK_UNDEFINED, $check_undefined_val,
 300                    [Building with -fsanitize=undefined or not])
 301
 302 AC_ARG_ENABLE([valgrind],
 303 AS_HELP_STRING([--enable-valgrind],[run all tests under valgrind]),
 304 [use_valgrind=$enableval], [use_valgrind=no])
 305 if test "$use_valgrind" = yes; then
 306   AC_CHECK_PROG(HAVE_VALGRIND, valgrind, yes, no)
 307   if test "$HAVE_VALGRIND" = "no"; then
 308     AC_MSG_ERROR([valgrind not found])
 309   fi
 310 fi
 311 AM_CONDITIONAL(USE_VALGRIND, test "$use_valgrind" = yes)
 312
 313 AM_CONDITIONAL(BUILD_STATIC, [dnl
 314 test "$use_gprof" = yes -o "$use_gcov" = yes])
 315
 316 AC_ARG_ENABLE([tests-rpath],
 317 AS_HELP_STRING([--enable-tests-rpath],[build $ORIGIN-using rpath into tests]),
 318                [tests_use_rpath=$enableval], [tests_use_rpath=no])
 319 AM_CONDITIONAL(TESTS_RPATH, test "$tests_use_rpath" = yes)
 320
 321 LIBEBL_SUBDIR="$PACKAGE"
 322 AC_ARG_ENABLE([libebl-subdir],
 323 AS_HELP_STRING([--enable-libebl-subdir=DIR],
 324 [install libebl_CPU modules in $(libdir)/DIR]), [dnl
 325 LIBEBL_SUBDIR="$enable_libebl_subdir"])
 326 AC_SUBST([LIBEBL_SUBDIR])
 327 AC_DEFINE_UNQUOTED(LIBEBL_SUBDIR, "$LIBEBL_SUBDIR")
 328 AH_TEMPLATE([LIBEBL_SUBDIR], [$libdir subdirectory containing libebl modules.])
 329
 330 dnl zlib is mandatory.
 331 save_LIBS="$LIBS"
 332 LIBS=
 333 eu_ZIPLIB(zlib,ZLIB,z,gzdirect,gzip)
 334 AS_IF([test "x$with_zlib" = xno], [AC_MSG_ERROR([zlib not found but is required])])
 335 LIBS="$save_LIBS"
 336
 337 dnl Test for bzlib and xz/lzma, gives BZLIB/LZMALIB .am
 338 dnl conditional and config.h USE_BZLIB/USE_LZMALIB #define.
 339 save_LIBS="$LIBS"
 340 LIBS=
 341 eu_ZIPLIB(bzlib,BZLIB,bz2,BZ2_bzdopen,bzip2)
 342 # We need this since bzip2 doesn't have a pkgconfig file.
 343 BZ2_LIB="$LIBS"
 344 AC_SUBST([BZ2_LIB])
 345 eu_ZIPLIB(lzma,LZMA,lzma,lzma_auto_decoder,[LZMA (xz)])
 346 AS_IF([test "x$with_lzma" = xyes], [LIBLZMA="liblzma"], [LIBLZMA=""])
 347 AC_SUBST([LIBLZMA])
 348 zip_LIBS="$LIBS"
 349 LIBS="$save_LIBS"
 350 AC_SUBST([zip_LIBS])
 351
 352 AC_CHECK_DECLS([memrchr, rawmemchr],[],[],
 353                [#define _GNU_SOURCE
 354                 #include <string.h>])
 355 AC_CHECK_DECLS([powerof2],[],[],[#include <sys/param.h>])
 356 AC_CHECK_DECLS([mempcpy],[],[],
 357                [#define _GNU_SOURCE
 358                 #include <string.h>])
 359
 360 AC_CHECK_LIB([stdc++], [__cxa_demangle], [dnl
 361 AC_DEFINE([USE_DEMANGLE], [1], [Defined if demangling is enabled])])
 362 AM_CONDITIONAL(DEMANGLE, test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes")
 363 AS_IF([test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes"],
 364       [enable_demangler=yes],[enable_demangler=no])
 365
 366 AC_ARG_ENABLE([textrelcheck],
 367 AS_HELP_STRING([--disable-textrelcheck],
 368                [Disable textrelcheck being a fatal error]))
 369 AM_CONDITIONAL(FATAL_TEXTREL, [test "x$enable_textrelcheck" != "xno"])
 370 AS_IF([test "x$enable_textrelcheck" != "xno"],
 371       [enable_textrelcheck=yes],[enable_textrelcheck=no])
 372
 373 AC_ARG_ENABLE([symbol-versioning],
 374 AS_HELP_STRING([--disable-symbol-versioning],
 375                [Disable symbol versioning in shared objects]))
 376 AM_CONDITIONAL(SYMBOL_VERSIONING, [test "x$enable_symbol_versioning" != "xno"])
 377 AS_IF([test "x$enable_symbol_versioning" = "xno"],
 378       [AC_MSG_WARN([Disabling symbol versioning breaks ABI compatibility.])
 379        enable_symbol_versioning=no],[enable_symbol_versioning=yes])
 380
 381 AC_CACHE_CHECK([whether gcc accepts -Wstack-usage], ac_cv_stack_usage, [dnl
 382 old_CFLAGS="$CFLAGS"
 383 CFLAGS="$CFLAGS -Wstack-usage=262144 -Werror"
 384 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 385                   ac_cv_stack_usage=yes, ac_cv_stack_usage=no)
 386 CFLAGS="$old_CFLAGS"])
 387 AM_CONDITIONAL(ADD_STACK_USAGE_WARNING, [test "x$ac_cv_stack_usage" != "xno"])
 388
 389 # -Wlogical-op was too fragile in the past, make sure we get a sane one.
 390 AC_CACHE_CHECK([whether gcc has a sane -Wlogical-op], ac_cv_logical_op, [dnl
 391 old_CFLAGS="$CFLAGS"
 392 CFLAGS="$CFLAGS -Wlogical-op -Werror"
 393 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
 394         [#define FLAG 1
 395         int f (int r, int f) { return (r && (FLAG || (FLAG & f))); }])],
 396                   ac_cv_logical_op=yes, ac_cv_logical_op=no)
 397 CFLAGS="$old_CFLAGS"])
 398 AM_CONDITIONAL(SANE_LOGICAL_OP_WARNING,
 399                [test "x$ac_cv_logical_op" != "xno"])
 400
 401 # -Wduplicated-cond was added by GCC6
 402 AC_CACHE_CHECK([whether gcc accepts -Wduplicated-cond], ac_cv_duplicated_cond, [dnl
 403 old_CFLAGS="$CFLAGS"
 404 CFLAGS="$CFLAGS -Wduplicated-cond -Werror"
 405 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 406                   ac_cv_duplicated_cond=yes, ac_cv_duplicated_cond=no)
 407 CFLAGS="$old_CFLAGS"])
 408 AM_CONDITIONAL(HAVE_DUPLICATED_COND_WARNING,
 409                [test "x$ac_cv_duplicated_cond" != "xno"])
 410
 411 # -Wnull-dereference was added by GCC6
 412 AC_CACHE_CHECK([whether gcc accepts -Wnull-dereference], ac_cv_null_dereference, [dnl
 413 old_CFLAGS="$CFLAGS"
 414 CFLAGS="$CFLAGS -Wnull-dereference -Werror"
 415 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 416                   ac_cv_null_dereference=yes, ac_cv_null_dereference=no)
 417 CFLAGS="$old_CFLAGS"])
 418 AM_CONDITIONAL(HAVE_NULL_DEREFERENCE_WARNING,
 419                [test "x$ac_cv_null_dereference" != "xno"])
 420
 421 # -Wimplicit-fallthrough was added by GCC7
 422 AC_CACHE_CHECK([whether gcc accepts -Wimplicit-fallthrough], ac_cv_implicit_fallthrough, [dnl
 423 old_CFLAGS="$CFLAGS"
 424 CFLAGS="$CFLAGS -Wimplicit-fallthrough -Werror"
 425 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 426                   ac_cv_implicit_fallthrough=yes, ac_cv_implicit_fallthrough=no)
 427 CFLAGS="$old_CFLAGS"])
 428 AM_CONDITIONAL(HAVE_IMPLICIT_FALLTHROUGH_WARNING,
 429                [test "x$ac_cv_implicit_fallthrough" != "xno"])
 430
 431 dnl Check if we have argp available from our libc
 432 AC_LINK_IFELSE(
 433         [AC_LANG_PROGRAM(
 434                 [#include <argp.h>],
 435                 [int argc=1; char *argv[]={"test"}; argp_parse(0,argc,&argv,0,0,0); return 0;]
 436                 )],
 437         [libc_has_argp="true"],
 438         [libc_has_argp="false"]
 439 )
 440
 441 dnl If our libc doesn't provide argp, then test for libargp
 442 if test "$libc_has_argp" = "false" ; then
 443         AC_MSG_WARN("libc does not have argp")
 444         AC_CHECK_LIB([argp], [argp_parse], [have_argp="true"], [have_argp="false"])
 445
 446         if test "$have_argp" = "false"; then
 447                 AC_MSG_ERROR("no libargp found")
 448         else
 449                 argp_LDADD="-largp"
 450         fi
 451 else
 452         argp_LDADD=""
 453 fi
 454 AC_SUBST([argp_LDADD])
 455
 456 dnl The directories with content.
 457
 458 dnl Documentation.
 459 dnl Commented out for now.
 460 dnl AC_CONFIG_FILES([doc/Makefile])
 461
 462 dnl Support library.
 463 AC_CONFIG_FILES([lib/Makefile])
 464
 465 dnl ELF library.
 466 AC_CONFIG_FILES([libelf/Makefile])
 467
 468 dnl Higher-level ELF support library.
 469 AC_CONFIG_FILES([libebl/Makefile])
 470
 471 dnl DWARF-ELF Lower-level Functions support library.
 472 AC_CONFIG_FILES([libdwelf/Makefile])
 473
 474 dnl DWARF library.
 475 AC_CONFIG_FILES([libdw/Makefile])
 476
 477 dnl Higher-level DWARF support library.
 478 AC_CONFIG_FILES([libdwfl/Makefile])
 479
 480 dnl CPU handling library.
 481 AC_CONFIG_FILES([libcpu/Makefile])
 482
 483 dnl Assembler library.
 484 AM_CONDITIONAL(HAVE_LIBASM, true)dnl Used in tests/Makefile.am, which see.
 485 AC_CONFIG_FILES([libasm/Makefile])
 486
 487 dnl CPU-specific backend libraries.
 488 AC_CONFIG_FILES([backends/Makefile])
 489
 490 dnl Tools.
 491 AC_CONFIG_FILES([src/Makefile po/Makefile.in])
 492
 493 dnl Test suite.
 494 AM_CONDITIONAL(STANDALONE, false)dnl Used in tests/Makefile.am, which see.
 495 AC_CONFIG_FILES([tests/Makefile])
 496
 497 dnl pkgconfig files
 498 AC_CONFIG_FILES([config/libelf.pc config/libdw.pc])
 499
 500 # Get the definitions necessary to create the Makefiles in the po
 501 # subdirectories.  This is a small subset of the gettext rules.
 502 AC_SUBST(USE_NLS, yes)
 503 AM_PO_SUBDIRS
 504
 505 dnl Appended to the config.h file.
 506 dnl We hide all kinds of configuration magic in lib/eu-config.h.
 507 AH_BOTTOM([#include <eu-config.h>])
 508
 509 dnl Version compatibility header.
 510 AC_CONFIG_FILES([version.h:config/version.h.in])
 511 AC_SUBST([eu_version])
 512
 513 # 1.234<whatever> -> 1234<whatever>
 514 case "$PACKAGE_VERSION" in
 515 [[0-9]].*) eu_version=`echo "$PACKAGE_VERSION" | sed 's@\.@@'` ;;
 516 *)         AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 517 esac
 518 case "$eu_version" in
 519 *.*)
 520   # 1234.567 -> "1234", "567"
 521   eu_extra_version="${eu_version#*.}"
 522   eu_version="${eu_version%%.*}"
 523   case "$eu_extra_version" in
 524   [[0-9]][[0-9]][[0-9]]) ;;
 525   [[0-9]][[0-9]])       eu_extra_version="${eu_extra_version}0" ;;
 526   [[0-9]])              eu_extra_version="${eu_extra_version}00" ;;
 527   *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 528   esac
 529   ;;
 530 *)
 531   eu_extra_version=000
 532   ;;
 533 esac
 534
 535 case "$eu_version" in
 536       0[[0-9]][[0-9]][[0-9]]) eu_version="${eu_version#0}$eu_extra_version" ;;
 537 [[0-9]][[0-9]][[0-9]][[0-9]]) eu_version="${eu_version}$eu_extra_version" ;;
 538 [[0-9]][[0-9]][[0-9]])        eu_version="${eu_version}0$eu_extra_version" ;;
 539 [[0-9]][[0-9]])               eu_version="${eu_version}00$eu_extra_version";;
 540 *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 541 esac
 542
 543 # Round up to the next release API (x.y) version.
 544 eu_version=$(( (eu_version + 999) / 1000 ))
 545
 546 dnl Unique ID for this build.
 547 MODVERSION="Build for ${LIBEBL_SUBDIR} ${eu_version} ${ac_cv_build}"
 548 AC_SUBST([MODVERSION])
 549 AC_DEFINE_UNQUOTED(MODVERSION, "$MODVERSION")
 550 AH_TEMPLATE([MODVERSION], [Identifier for modules in the build.])
 551
 552 AC_CHECK_SIZEOF(long)
 553
 554 # On aarch64 before glibc 2.20 we would get the kernel user_pt_regs instead
 555 # of the user_regs_struct from sys/user.h. They are structurally the same
 556 # but we get either one or the other.
 557 AC_CHECK_TYPE([struct user_regs_struct],
 558               [sys_user_has_user_regs=yes], [sys_user_has_user_regs=no],
 559               [[#include <sys/ptrace.h>]
 560                [#include <sys/time.h>]
 561                [#include <sys/user.h>]])
 562 if test "$sys_user_has_user_regs" = "yes"; then
 563   AC_DEFINE(HAVE_SYS_USER_REGS, 1,
 564             [Define to 1 if <sys/user.h> defines struct user_regs_struct])
 565 fi
 566
 567 # On a 64-bit host where can can use $CC -m32, we'll run two sets of tests.
 568 # Likewise in a 32-bit build on a host where $CC -m64 works.
 569 utrace_BIARCH
 570 # `$utrace_biarch' will be `-m64' even on an uniarch i386 machine.
 571 CC_BIARCH="$CC $utrace_biarch"
 572 AC_SUBST([CC_BIARCH])
 573
 574 # In maintainer mode we really need flex and bison.
 575 # Otherwise we really need a release dir with maintainer files generated.
 576 if test "x$enable_maintainer_mode" = xyes; then
 577   AC_CHECK_PROG(HAVE_FLEX, flex, yes, no)
 578   if test "$HAVE_FLEX" = "no"; then
 579     AC_MSG_ERROR([flex needed in maintainer mode])
 580   fi
 581   AC_CHECK_PROG(HAVE_BISON, bison, yes, no)
 582   if test "$HAVE_BISON" = "no"; then
 583     AC_MSG_ERROR([bison needed in maintainer mode])
 584   fi
 585 else
 586   if test ! -f ${srcdir}/libdw/known-dwarf.h; then
 587     AC_MSG_ERROR([No libdw/known-dwarf.h. configure --enable-maintainer-mode])
 588   fi
 589 fi
 590
 591 # The testfiles are all compressed, we need bunzip2 when running make check
 592 AC_CHECK_PROG(HAVE_BUNZIP2, bunzip2, yes, no)
 593 if test "$HAVE_BUNZIP2" = "no"; then
 594   AC_MSG_WARN([No bunzip2, needed to run make check])
 595 fi
 596
 597 AC_OUTPUT
 598
 599 AC_MSG_NOTICE([
 600 =====================================================================
 601         elfutils: ${PACKAGE_VERSION} (eu_version: ${eu_version})
 602 =====================================================================
 603
 604     Prefix                             : ${prefix}
 605     Program prefix ("eu-" recommended) : ${program_prefix}
 606     Source code location               : ${srcdir}
 607     Maintainer mode                    : ${enable_maintainer_mode}
 608     libebl modules subdirectory        : ${LIBEBL_SUBDIR}
 609     build arch                         : ${ac_cv_build}
 610
 611   RECOMMENDED FEATURES (should all be yes)
 612     gzip support                       : ${with_zlib}
 613     bzip2 support                      : ${with_bzlib}
 614     lzma/xz support                    : ${with_lzma}
 615     libstdc++ demangle support         : ${enable_demangler}
 616     File textrel check                 : ${enable_textrelcheck}
 617     Symbol versioning                  : ${enable_symbol_versioning}
 618
 619   NOT RECOMMENDED FEATURES (should all be no)
 620     Experimental thread safety         : ${use_locks}
 621
 622   OTHER FEATURES
 623     Deterministic archives by default  : ${default_ar_deterministic}
 624     Native language support            : ${USE_NLS}
 625
 626   EXTRA TEST FEATURES (used with make check)
 627     have bunzip2 installed (required)  : ${HAVE_BUNZIP2}
 628     debug branch prediction            : ${use_debugpred}
 629     gprof support                      : ${use_gprof}
 630     gcov support                       : ${use_gcov}
 631     run all tests under valgrind       : ${use_valgrind}
 632     gcc undefined behaviour sanitizer  : ${use_undefined}
 633     use rpath in tests                 : ${tests_use_rpath}
 634     test biarch                        : ${utrace_cv_cc_biarch}
 635 ])