configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # VA-API version
  24 # - increment major for any ABI change (which shall not occur!)
  25 # - increment minor for any interface change (e.g. new/modified function)
  26 # - increment micro for any other change (new flag, new codec definition, etc.)
  27 # - reset micro version to zero when minor version is incremented
  28 # - reset minor version to zero when major version is incremented
  29 m4_define([va_api_major_version], [0])
  30 m4_define([va_api_minor_version], [34])
  31 m4_define([va_api_micro_version], [0])
  32
  33 m4_define([va_api_version],
  34           [va_api_major_version.va_api_minor_version.va_api_micro_version])
  35
  36 # libva package version number, (as distinct from shared library version)
  37 # XXX: we want the package version to remain at 1.0.x for VA-API 0.32.y
  38 #
  39 # - major version is automatically generated from VA-API major version
  40 # - minor version is automatically generated from VA-API minor version
  41 # - increment micro for any library release
  42 # - reset micro version to zero when VA-API major or minor version is changed
  43 m4_define([libva_major_version], [m4_eval(va_api_major_version + 1)])
  44 m4_define([libva_minor_version], [m4_eval(va_api_minor_version - 32)])
  45 m4_define([libva_micro_version], [0])
  46 m4_define([libva_pre_version],   [1])
  47
  48 m4_define([libva_version],
  49           [libva_major_version.libva_minor_version.libva_micro_version])
  50 m4_if(libva_pre_version, [0], [], [
  51 m4_append([libva_version], libva_pre_version, [.pre])
  52 ])
  53
  54 # libva library version number (generated, do not change)
  55 # XXX: we want the SONAME to remain at libva.so.1 for VA-API major == 0
  56 #
  57 # The library name is generated libva.<x>.<y>.0 where
  58 # <x> = VA-API major version + 1
  59 # <y> = 100 * VA-API minor version + VA-API micro version
  60 #
  61 # For example:
  62 # VA-API 0.32.0 generates libva.so.1.3200.0
  63 # VA-API 0.34.1 generates libva.so.1.3401.0
  64 # VA-API 1.2.13 generates libva.so.2.213.0
  65 m4_define([libva_interface_bias], [m4_eval(va_api_major_version + 1)])
  66 m4_define([libva_interface_age],  [0])
  67 m4_define([libva_binary_age],
  68           [m4_eval(100 * va_api_minor_version + va_api_micro_version - libva_interface_age)])
  69
  70 m4_define([libva_lt_current],
  71           [m4_eval(100 * va_api_minor_version + va_api_micro_version + libva_interface_bias)])
  72 m4_define([libva_lt_revision],
  73           [m4_eval(libva_interface_age)])
  74 m4_define([libva_lt_age],
  75           [m4_eval(libva_binary_age - libva_interface_age)])
  76
  77 # libdrm minimun version requirement
  78 m4_define([libdrm_version], [2.4])
  79
  80 AC_PREREQ(2.57)
  81 AC_INIT([libva], [libva_version], [waldo.bastian@intel.com], libva)
  82 AC_CONFIG_SRCDIR([Makefile.am])
  83 AM_INIT_AUTOMAKE([dist-bzip2])
  84
  85 AM_CONFIG_HEADER([config.h])
  86 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  87
  88 VA_API_MAJOR_VERSION=va_api_major_version
  89 VA_API_MINOR_VERSION=va_api_minor_version
  90 VA_API_MICRO_VERSION=va_api_micro_version
  91 VA_API_VERSION=va_api_version
  92 AC_SUBST(VA_API_MAJOR_VERSION)
  93 AC_SUBST(VA_API_MINOR_VERSION)
  94 AC_SUBST(VA_API_MICRO_VERSION)
  95 AC_SUBST(VA_API_VERSION)
  96
  97 LIBVA_MAJOR_VERSION=libva_major_version
  98 LIBVA_MINOR_VERSION=libva_minor_version
  99 LIBVA_MICRO_VERSION=libva_micro_version
 100 LIBVA_VERSION=libva_version
 101 AC_SUBST(LIBVA_MAJOR_VERSION)
 102 AC_SUBST(LIBVA_MINOR_VERSION)
 103 AC_SUBST(LIBVA_MICRO_VERSION)
 104 AC_SUBST(LIBVA_VERSION)
 105
 106 LIBVA_LT_CURRENT=libva_lt_current
 107 LIBVA_LT_REV=libva_lt_revision
 108 LIBVA_LT_AGE=libva_lt_age
 109 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
 110 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
 111 AC_SUBST(LIBVA_LT_VERSION)
 112 AC_SUBST(LIBVA_LT_LDFLAGS)
 113
 114 AC_ARG_ENABLE(docs,
 115     [AC_HELP_STRING([--enable-docs],
 116                     [build Doxygen documentation @<:@default=no@:>@])],
 117     [], [enable_docs="no"])
 118
 119 AC_ARG_ENABLE(drm,
 120     [AC_HELP_STRING([--enable-drm],
 121                     [build with VA/DRM API support @<:@default=yes@:>@])],
 122     [], [enable_drm="yes"])
 123
 124 AC_ARG_ENABLE(x11,
 125     [AC_HELP_STRING([--enable-x11],
 126                     [build with VA/X11 API support @<:@default=yes@:>@])],
 127     [], [enable_x11="yes"])
 128
 129 AC_ARG_ENABLE(glx,
 130     [AC_HELP_STRING([--enable-glx],
 131                     [build with GLX support @<:@default=yes@:>@])],
 132     [], [enable_glx="yes"])
 133
 134 AC_ARG_ENABLE(egl,
 135     [AC_HELP_STRING([--enable-egl],
 136                     [build with EGL support @<:@default=yes@:>@])],
 137     [], [enable_egl="yes"])
 138
 139 AC_ARG_ENABLE(dummy-driver,
 140     [AC_HELP_STRING([--enable-dummy-driver],
 141                     [build dummy video driver @<:@default=yes@:>@])],
 142     [], [enable_dummy_driver="yes"])
 143 AM_CONDITIONAL(BUILD_DUMMY_DRIVER, test x$enable_dummy_driver = xyes)
 144
 145 AC_ARG_ENABLE(dummy-backend,
 146     [AC_HELP_STRING([--enable-dummy-backend],
 147                     [build dummy libva backend])],
 148     [], [enable_dummy_backend="no"])
 149
 150 AC_ARG_WITH(drivers-path,
 151     [AC_HELP_STRING([--with-drivers-path=[[path]]],
 152                     [drivers path])],
 153     [], [with_drivers_path="$libdir/dri"])
 154
 155 LIBVA_DRIVERS_PATH="$with_drivers_path"
 156 AC_SUBST(LIBVA_DRIVERS_PATH)
 157
 158 AC_DISABLE_STATIC
 159 AC_PROG_LIBTOOL
 160 AC_PROG_CC
 161 AC_PROG_CXX
 162 AM_PROG_CC_C_O
 163 PKG_PROG_PKG_CONFIG
 164
 165 AC_HEADER_STDC
 166 AC_SYS_LARGEFILE
 167
 168 # Check for Doxygen
 169 if test "$enable_docs" = "yes"; then
 170     AC_CHECK_TOOL([DOXYGEN], [doxygen], [enable_docs="no"])
 171 fi
 172 AM_CONDITIONAL(ENABLE_DOCS, test "$enable_docs" = "yes")
 173
 174 # Check for __attribute__((visibility()))
 175 AC_CACHE_CHECK([whether __attribute__((visibility())) is supported],
 176     ac_cv_have_gnuc_visibility_attribute,
 177     [cat > conftest.c <<EOF
 178 int foo __attribute__ ((visibility ("hidden"))) = 1;
 179 int bar __attribute__ ((visibility ("protected"))) = 1;
 180 EOF
 181     ac_cv_have_gnuc_visibility_attribute="no"
 182     if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
 183         if grep '\.hidden.*foo' conftest.s >/dev/null; then
 184             if grep '\.protected.*bar' conftest.s >/dev/null; then
 185                 ac_cv_have_gnuc_visibility_attribute="yes"
 186             fi
 187         fi
 188     fi
 189     rm -f conftest.[cs]
 190 ])
 191 if test "$ac_cv_have_gnuc_visibility_attribute" = "yes"; then
 192     AC_DEFINE([HAVE_GNUC_VISIBILITY_ATTRIBUTE], [1],
 193               [Defined to 1 if GCC visibility attribute is supported])
 194 fi
 195
 196 # Check for X11
 197 USE_X11="no"
 198 if test "$enable_x11" = "yes"; then
 199     PKG_CHECK_MODULES([X11],    [x11])
 200     PKG_CHECK_MODULES([XEXT],   [xext])
 201     PKG_CHECK_MODULES([XFIXES], [xfixes])
 202     USE_X11="yes"
 203     AC_DEFINE([HAVE_VA_X11], [1], [Defined to 1 if VA/X11 API is built])
 204 fi
 205 AM_CONDITIONAL(USE_X11, test "$USE_X11" = "yes")
 206
 207 # Check for DRM
 208 LIBDRM_VERSION=libdrm_version
 209 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
 210 AC_SUBST(LIBDRM_VERSION)
 211
 212 if test x$enable_dummy_backend = xyes; then
 213     PKG_CHECK_MODULES([UDEV], [libudev], [libudev=yes], [libudev=no])
 214 fi
 215 if test x$libudev = xno; then
 216    enable_dummy_backend=no
 217 fi
 218 AM_CONDITIONAL(BUILD_DUMMY_BACKEND, test x$enable_dummy_backend = xyes)
 219
 220 USE_DRM="no"
 221 if test "$enable_drm" = "yes"; then
 222     USE_DRM="yes"
 223     AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is built])
 224 fi
 225 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
 226
 227 # Check for GLX
 228 USE_GLX="no"
 229 GL_DEPS_CFLAGS=""
 230 GL_DEPS_LIBS=""
 231 if test "$USE_X11:$enable_glx" = "yes:yes"; then
 232     saved_CFLAGS="$CFLAGS"
 233     saved_LIBS="$LIBS"
 234     PKG_CHECK_MODULES([GL_DEPS], [gl], [], [GL_DEPS_LIBS="-lX11 -lGL"])
 235     CFLAGS="$CFLAGS $GL_DEPS_CFLAGS"
 236     LIBS="$LIBS $GL_DEPS_LIBS"
 237     AC_CHECK_HEADERS([GL/gl.h])
 238     AC_CHECK_HEADERS([GL/glx.h])
 239     AC_CHECK_LIB(GL, glXCreateContext, [USE_GLX="yes"])
 240     CFLAGS="$saved_CFLAGS"
 241     LIBS="$saved_LIBS"
 242 fi
 243 AC_SUBST(GL_DEPS_CFLAGS)
 244 AC_SUBST(GL_DEPS_LIBS)
 245 AM_CONDITIONAL(USE_GLX, test "$USE_GLX" = "yes")
 246
 247 # Check for EGL
 248 USE_EGL="no"
 249 EGL_DEPS_CFLAGS=""
 250 EGL_DEPS_LIBS=""
 251 if test "$enable_egl" = "yes"; then
 252     saved_CFLAGS="$CFLAGS"
 253     saved_LIBS="$LIBS"
 254     PKG_CHECK_MODULES([EGL_DEPS], [egl], [], [EGL_DEPS_LIBS="-lEGL"])
 255     CFLAGS="$CFLAGS $EGL_DEPS_CFLAGS"
 256     LIBS="$LIBS $EGL_DEPS_LIBS"
 257     AC_CHECK_HEADERS([EGL/egl.h], [USE_EGL="yes"], [USE_EGL="no"])
 258
 259     if test "x$USE_EGL" = "xyes"; then
 260         AC_CHECK_LIB(EGL, eglGetDisplay, [USE_EGL="yes"], [USE_EGL="no"])
 261     fi
 262
 263     CFLAGS="$saved_CFLAGS"
 264     LIBS="$saved_LIBS"
 265 fi
 266 AC_SUBST(EGL_DEPS_CFLAGS)
 267 AC_SUBST(EGL_DEPS_LIBS)
 268 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 269
 270 # We only need the headers, we don't link against the DRM libraries
 271 LIBVA_CFLAGS="$DRM_CFLAGS"
 272 AC_SUBST(LIBVA_CFLAGS)
 273 AC_SUBST(LIBVA_LIBS)
 274
 275 pkgconfigdir=${libdir}/pkgconfig
 276 AC_SUBST(pkgconfigdir)
 277
 278 # Check for builds without backend
 279 if test "$USE_X11:$USE_DRM" = "no:no"; then
 280     AC_MSG_ERROR([Please select at least VA/X11 or VA/DRM backend])
 281 fi
 282
 283 LIBVA_DISPLAY="drm"
 284 if test "$USE_X11" = "yes"; then
 285     LIBVA_DISPLAY="x11"
 286 fi
 287 libvacorelib=libva.la
 288 libvabackendlib=libva-$LIBVA_DISPLAY.la
 289 AC_SUBST([libvacorelib])
 290 AC_SUBST([libvabackendlib])
 291
 292 AC_OUTPUT([
 293     Makefile
 294     debian.upstream/Makefile
 295     doc/Makefile
 296     dummy_drv_video/Makefile
 297     pkgconfig/Makefile
 298     pkgconfig/libva-drm.pc
 299     pkgconfig/libva-egl.pc
 300     pkgconfig/libva-glx.pc
 301     pkgconfig/libva-tpi.pc
 302     pkgconfig/libva-x11.pc
 303     pkgconfig/libva.pc
 304     test/Makefile
 305     test/basic/Makefile
 306     test/common/Makefile
 307     test/decode/Makefile
 308     test/encode/Makefile
 309     test/putsurface/Makefile
 310     test/transcode/Makefile
 311     test/vainfo/Makefile
 312     va/Makefile
 313     va/drm/Makefile
 314     va/dummy/Makefile
 315     va/egl/Makefile
 316     va/glx/Makefile
 317     va/va_version.h
 318     va/x11/Makefile
 319 ])
 320
 321 # Print a small summary
 322 AS_IF([test x$USE_DRM = xyes], [BACKENDS="drm $BACKENDS"])
 323 AS_IF([test x$USE_X11 = xyes], [BACKENDS="x11 $BACKENDS"])
 324 AS_IF([test x$USE_GLX = xyes], [BACKENDS="glx $BACKENDS"])
 325 AS_IF([test x$USE_EGL = xyes], [BACKENDS="egl $BACKENDS"])
 326
 327 echo
 328 echo "libva - ${LIBVA_VERSION} (VA-API ${VA_API_VERSION})"
 329 echo
 330 echo Installation prefix .............. : $prefix
 331 echo Default driver path .............. : $LIBVA_DRIVERS_PATH
 332 echo Extra window systems ............. : $BACKENDS
 333 echo build dummy backend .............. : $enable_dummy_backend
 334 echo Build dummy driver ............... : $enable_dummy_driver
 335 echo Build documentation .............. : $enable_docs
 336 echo