configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [12])
   6 m4_define([dbus_micro_version], [2])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CONFIG_AUX_DIR([build-aux])
  12
  13 m4_pattern_forbid([^AX_],
  14   [Unexpanded AX_ macro found. Please install GNU autoconf-archive])
  15
  16 AC_CANONICAL_HOST
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AC_CONFIG_MACRO_DIR([m4])
  20
  21 AM_INIT_AUTOMAKE([1.13 tar-ustar -Wno-portability subdir-objects])
  22
  23 GETTEXT_PACKAGE=dbus-1
  24 AC_SUBST(GETTEXT_PACKAGE)
  25 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  26
  27 # By default, rebuild autotools files on demand; only use ./missing if the
  28 # user says --disable-maintainer-mode (some distributions like to do this)
  29 AM_MAINTAINER_MODE([enable])
  30
  31 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  32
  33 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  34
  35 # libtool versioning - this applies to libdbus
  36 #
  37 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  38 #
  39
  40 ## increment if the interface has additions, changes, removals.
  41 LT_CURRENT=22
  42
  43 ## increment any time the source changes; set to
  44 ##  0 if you increment CURRENT
  45 LT_REVISION=4
  46
  47 ## increment if any interfaces have been added; set to 0
  48 ## if any interfaces have been changed or removed. removal has
  49 ## precedence over adding, so set to 0 if both happened.
  50 LT_AGE=19
  51
  52 AC_SUBST(LT_CURRENT)
  53 AC_SUBST(LT_REVISION)
  54 AC_SUBST(LT_AGE)
  55 SOVERSION=`expr ${LT_CURRENT} - ${LT_AGE}`
  56 AC_SUBST([SOVERSION])
  57
  58 DBUS_MAJOR_VERSION=dbus_major_version
  59 DBUS_MINOR_VERSION=dbus_minor_version
  60 DBUS_MICRO_VERSION=dbus_micro_version
  61 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  62
  63 AC_SUBST(DBUS_MAJOR_VERSION)
  64 AC_SUBST(DBUS_MINOR_VERSION)
  65 AC_SUBST(DBUS_MICRO_VERSION)
  66 AC_SUBST(DBUS_VERSION)
  67
  68 dnl
  69 dnl Build configuration
  70 dnl
  71
  72 dnl This must come first: other options use this to set their defaults. Don't
  73 dnl enable developer mode on production builds.
  74 AC_ARG_ENABLE([developer],
  75   [AS_HELP_STRING([--enable-developer],
  76     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
  77   [enable_developer=$enableval],
  78   [enable_developer=no])
  79
  80 dnl 'disable_developer' is the negation of 'enable_developer'. If
  81 dnl 'enable-developer' is set to 'no' (the default), the value of
  82 dnl 'disable_developer' is set to 'yes', and vice versa. It's used
  83 dnl for macros that require the opposite of 'enable_developer', such
  84 dnl as several AX_ macros.
  85 dnl See https://bugs.freedesktop.org/show_bug.cgi?id=97357
  86 AS_IF([test "x$enable_developer" = "xyes"],[
  87     disable_developer=no
  88   ],[
  89     disable_developer=yes
  90   ])
  91
  92 # The debugging check must run before the compiler tests. Other command-line
  93 # options also use it to set their defaults. We disable debugging by default,
  94 # except for developer builds.
  95 AX_CHECK_ENABLE_DEBUG([$enable_developer])
  96
  97 AC_PROG_CC
  98 AM_PROG_CC_C_O
  99 AC_PROG_CXX
 100 AC_USE_SYSTEM_EXTENSIONS
 101 AC_SYS_LARGEFILE
 102 AC_ISC_POSIX
 103 AC_HEADER_STDC
 104 AC_C_INLINE
 105 AM_PROG_LIBTOOL
 106 AC_PROG_MKDIR_P
 107 PKG_PROG_PKG_CONFIG
 108
 109 # TAP test driver support
 110 AC_PROG_AWK
 111 AC_REQUIRE_AUX_FILE([tap-driver.sh])
 112
 113 # This must come before we set up compiler warnings because it assumes
 114 # non-use of -Werror=missing-prototypes
 115 gl_VISIBILITY
 116 AM_CONDITIONAL([HAVE_VISIBILITY], [test "x$HAVE_VISIBILITY" = x1])
 117
 118 # Initialize libtool
 119 LT_INIT([win32-dll])
 120 LT_LANG([Windows Resource])
 121
 122 # Set some internal variables depending on the platform for later use.
 123 dbus_win=no
 124 dbus_cygwin=no
 125 dbus_unix=no
 126 case "${host}" in
 127     *-mingw32ce*)
 128         dbus_win=yes
 129         dbus_wince=yes
 130         ;;
 131     *-mingw32*)
 132         dbus_win=yes
 133         ;;
 134     *-cygwin*)
 135         dbus_cygwin=yes
 136         dbus_unix=yes
 137         ;;
 138     *)
 139         dbus_unix=yes
 140        ;;
 141 esac
 142
 143 # Special defines for certain platforms
 144 if test "$dbus_win" = yes; then
 145     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 146     # Yes, on Windows it really does work like this.
 147     # http://support.microsoft.com/kb/111855
 148     AC_DEFINE(FD_SETSIZE,8192,[The maximum number of connections that can be handled at once])
 149     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 150     AC_SUBST(BUILD_TIMESTAMP)
 151     # Assume DBUS_VERSION is always three numbers
 152     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 153     AC_SUBST(BUILD_FILEVERSION)
 154     AS_IF([test -z "$RC"],
 155         [AC_MSG_ERROR([An implementation of windres is required])])
 156     if test "$dbus_wince" = yes; then
 157       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 158       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 159     fi
 160 else
 161     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 162 fi
 163 if test "$dbus_cygwin" = yes; then
 164     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 165 fi
 166
 167 # For best security, assume that all non-Windows platforms can do
 168 # credentials-passing.
 169 AS_IF([test "$dbus_win" = yes],
 170     [DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL="<!--<auth>EXTERNAL</auth>-->"],
 171     [DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL="<auth>EXTERNAL</auth>"])
 172 AC_SUBST([DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL])
 173
 174 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 175 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 176 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 177 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 178
 179 DBUS_STATIC_BUILD_CPPFLAGS=
 180 if test "x$enable_shared" = xno; then
 181     # On Windows, linking against the static library requires special effort
 182     # to turn off DLL import/export processing. We normally link some things
 183     # against the dynamic library, but if we're not building that, we'll
 184     # have to link everything statically.
 185     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 186 fi
 187 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 188
 189 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 190 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 191 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 192 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 193 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 194 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 195 AC_ARG_ENABLE([ducktype-docs],
 196               AS_HELP_STRING([--enable-ducktype-docs],
 197                              [build Ducktype documentation (requires Ducktype)]),
 198               [enable_ducktype_docs=$enableval], [enable_ducktype_docs=auto])
 199 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 200 AC_ARG_ENABLE([apparmor],
 201   [AS_HELP_STRING([--enable-apparmor], [build with AppArmor support])],
 202   [enable_apparmor=$enableval],
 203   [enable_apparmor=auto])
 204 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 205 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 206 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 207 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 208 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 209 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 210
 211 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 212 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 213 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 214 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 215 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 216 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 217 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 218 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 219 AC_ARG_WITH([test_user],
 220   [AS_HELP_STRING([--with-test-user=<user>],
 221     [Unprivileged user for regression tests, other than root and the dbus_user (default: nobody)])])
 222 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 223
 224 AC_ARG_ENABLE([embedded-tests],
 225   AS_HELP_STRING([--enable-embedded-tests],
 226     [enable unit test code in the library and binaries]),
 227   [], [enable_embedded_tests=$enable_developer])
 228 AC_ARG_ENABLE([modular-tests],
 229   AS_HELP_STRING([--enable-modular-tests],
 230     [enable modular regression tests (requires GLib)]),
 231   [], [enable_modular_tests=auto])
 232 # --enable-tests overrides both --enable-embedded-tests and
 233 # --enable-modular-tests
 234 AC_ARG_ENABLE([tests],
 235   AS_HELP_STRING([--enable-tests],
 236     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 237   [
 238   if test "x$enableval" = xyes; then
 239     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 240     AC_MSG_NOTICE([This has many dependencies (GLib, Python etc.)])
 241   fi
 242   enable_embedded_tests=$enableval
 243   enable_modular_tests=$enableval
 244   ],
 245   [])
 246
 247 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 248 # and also some stuff in the test/ subdir.
 249 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 250   [test "x$enable_embedded_tests" = xyes])
 251 if test "x$enable_embedded_tests" = xyes; then
 252     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 253       [Define to build test code into the library and binaries])
 254 fi
 255
 256 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 257 # These use GTest, from GLib, because life's too short. They're enabled by
 258 # default (unless you don't have GLib), because they don't bloat the library
 259 # or binaries.
 260
 261 AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_40], [Ignore post-2.40 deprecations])
 262 AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [GLIB_VERSION_2_40], [Prevent post-2.40 APIs])
 263
 264 with_glib=yes
 265
 266 AS_IF([test "x$enable_modular_tests" != xno],
 267   [
 268   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.40, gio-2.0 >= 2.40],
 269     [
 270       AS_IF([test "x$dbus_unix" = xyes],
 271         [PKG_CHECK_MODULES([GIO_UNIX], [gio-unix-2.0],
 272            [AC_DEFINE([HAVE_GIO_UNIX], [1], [Define if you have gio-unix-2.0])], [])])
 273     ],
 274     [if test "x$enable_modular_tests" = xyes; then
 275       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 276       AC_MSG_ERROR([$GLIB_ERRORS])
 277     else # assumed to be "auto"
 278       with_glib=no
 279     fi])
 280   ],
 281   [with_glib=no])
 282
 283 if test "x$enable_modular_tests" != xno; then
 284   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 285     [Define to build independent test binaries])
 286 fi
 287 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 288   [test "x$enable_modular_tests" != xno])
 289
 290 if test "x$with_glib" != xno; then
 291   AC_DEFINE([DBUS_WITH_GLIB], [1],
 292     [Define if GLib, GObject, GIO are available])
 293 fi
 294 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 295
 296 AC_ARG_ENABLE([installed-tests],
 297   AS_HELP_STRING([--enable-installed-tests],
 298     [enable unit test code in the library and binaries]),
 299   [], [enable_installed_tests=no])
 300 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 301   [test "x$enable_installed_tests" = xyes])
 302
 303 if test "x$enable_tests" = xyes; then
 304   # full test coverage is required, Python is a hard dependency
 305   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygi])
 306   AM_PATH_PYTHON([2.6])
 307   AC_MSG_CHECKING([for Python modules for full test coverage])
 308   if "$PYTHON" -c "import dbus, gi.repository.GObject, dbus.mainloop.glib"; then
 309     AC_MSG_RESULT([yes])
 310   else
 311     AC_MSG_RESULT([no])
 312     AC_MSG_ERROR([cannot import dbus, gi.repository.GObject, dbus.mainloop.glib Python modules])
 313   fi
 314 else
 315   # --enable-tests not given: do not abort if Python is missing
 316   AM_PATH_PYTHON([2.6], [], [:])
 317 fi
 318
 319 if test x$enable_verbose_mode = xyes; then
 320     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 321 fi
 322
 323 dnl Intentional:
 324 dnl - $DISABLE_WARNINGS disables unused-label warnings if not
 325 dnl   checking or not asserting (tested further below)
 326 dnl - we are not going to stop using deprecated functions on a stable
 327 dnl   branch
 328 dnl - missing field initializers being 0 is a C feature, not a bug
 329 dnl - unused-parameter is to make writing callbacks less annoying
 330 DISABLE_WARNINGS="$DISABLE_WARNINGS
 331                   -Wno-deprecated-declarations
 332                   -Wno-missing-field-initializers
 333                   -Wno-unused-parameter"
 334
 335 if test x$enable_asserts = xno; then
 336     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 337     DISABLE_WARNINGS="$DISABLE_WARNINGS -Wno-unused-label"
 338     R_DYNAMIC_LDFLAG=""
 339     if test x$enable_embedded_tests = xyes; then
 340         DISABLE_WARNINGS="$DISABLE_WARNINGS
 341                           -Wno-unused-but-set-variable
 342                           -Wno-unused-variable
 343                           -Wno-unused-function"
 344     fi
 345 else
 346     # -rdynamic is needed for glibc's backtrace_symbols to work.
 347     # No clue how much overhead this adds, but it's useful
 348     # to do this on any assertion failure,
 349     # so for now it's enabled anytime asserts are (currently not
 350     # in production builds).
 351
 352     # To get -rdynamic you pass -export-dynamic to libtool.
 353     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 354     R_DYNAMIC_LDFLAG=-export-dynamic
 355 fi
 356 AC_SUBST(R_DYNAMIC_LDFLAG)
 357
 358 if test x$enable_checks = xno; then
 359     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 360     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 361     DISABLE_WARNINGS="$DISABLE_WARNINGS -Wno-unused-label"
 362 fi
 363
 364 AH_BOTTOM([
 365 /* explicitly define these macros to get less confusing conditions */
 366 #ifndef DBUS_DISABLE_ASSERT
 367 #  define DBUS_ENABLE_ASSERT 1
 368 #endif
 369 #ifndef DBUS_DISABLE_CHECKS
 370 #  define DBUS_ENABLE_CHECKS 1
 371 #endif])
 372
 373 # Test for code-coverage tools if --enable-code-coverage
 374 AX_CODE_COVERAGE
 375
 376 AS_IF([test x$enable_code_coverage = xyes],[
 377     AC_DEFINE_UNQUOTED(
 378       [DBUS_GCOV_ENABLED], [1],
 379       [Defined if gcov is enabled to force a rebuild due to config.h changing])
 380   ])
 381
 382 #### Integer sizes
 383
 384 AC_CHECK_SIZEOF(char)
 385 AC_CHECK_SIZEOF(short)
 386 AC_CHECK_SIZEOF(long)
 387 AC_CHECK_SIZEOF(int)
 388 AC_CHECK_SIZEOF(void *)
 389 AC_CHECK_SIZEOF(long long)
 390 AC_CHECK_SIZEOF(__int64)
 391
 392 ### See what our 64 bit type is called
 393 AC_MSG_CHECKING([64-bit integer type])
 394
 395 case 8 in
 396 $ac_cv_sizeof_int)
 397   dbusint64=int
 398   dbusint64_constant='(val)'
 399   dbusuint64_constant='(val)'
 400   ;;
 401 $ac_cv_sizeof_long)
 402   dbusint64=long
 403   dbusint64_constant='(val##L)'
 404   dbusuint64_constant='(val##UL)'
 405   ;;
 406 $ac_cv_sizeof_long_long)
 407   dbusint64='long long'
 408   dbusint64_constant='(val##LL)'
 409   dbusuint64_constant='(val##ULL)'
 410   ;;
 411 $ac_cv_sizeof___int64)
 412   dbusint64=__int64
 413   dbusint64_constant='(val##i64)'
 414   dbusuint64_constant='(val##ui64)'
 415   ;;
 416 esac
 417
 418 AS_IF(
 419   [test -z "$dbusint64"],
 420   [AC_MSG_RESULT([not found])
 421   AC_MSG_ERROR([Could not find a 64-bit integer type.
 422
 423 Please report a bug here with details of your platform and compiler:
 424
 425     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core])
 426   ],
 427   dnl else
 428   [
 429         DBUS_INT64_TYPE="$dbusint64"
 430         DBUS_INT64_CONSTANT="$dbusint64_constant"
 431         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 432         AC_MSG_RESULT($DBUS_INT64_TYPE)
 433   ])
 434
 435 AC_SUBST(DBUS_INT64_TYPE)
 436 AC_SUBST(DBUS_INT64_CONSTANT)
 437 AC_SUBST(DBUS_UINT64_CONSTANT)
 438
 439 ### see what 32-bit int is called
 440 AC_MSG_CHECKING([32-bit integer type])
 441
 442 case 4 in
 443 $ac_cv_sizeof_short)
 444   dbusint32=short
 445   ;;
 446 $ac_cv_sizeof_int)
 447   dbusint32=int
 448   ;;
 449 $ac_cv_sizeof_long)
 450   dbusint32=long
 451   ;;
 452 esac
 453
 454 if test -z "$dbusint32" ; then
 455         DBUS_INT32_TYPE="no_int32_type_detected"
 456         AC_MSG_ERROR([No 32-bit integer type found])
 457 else
 458         DBUS_INT32_TYPE="$dbusint32"
 459         AC_MSG_RESULT($DBUS_INT32_TYPE)
 460 fi
 461
 462 AC_SUBST(DBUS_INT32_TYPE)
 463
 464 ### see what 16-bit int is called
 465 AC_MSG_CHECKING([16-bit integer type])
 466
 467 case 2 in
 468 $ac_cv_sizeof_short)
 469   dbusint16=short
 470   ;;
 471 $ac_cv_sizeof_int)
 472   dbusint16=int
 473   ;;
 474 esac
 475
 476 if test -z "$dbusint16" ; then
 477         DBUS_INT16_TYPE="no_int16_type_detected"
 478         AC_MSG_ERROR([No 16-bit integer type found])
 479 else
 480         DBUS_INT16_TYPE="$dbusint16"
 481         AC_MSG_RESULT($DBUS_INT16_TYPE)
 482 fi
 483
 484 AC_SUBST(DBUS_INT16_TYPE)
 485
 486 ## byte order
 487 case $host_os in
 488         darwin*)
 489                 # check at compile-time, so that it is possible to build universal
 490                 # (with multiple architectures at once on the compile line)
 491                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 492                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 493                         #if defined(__BIG_ENDIAN__)
 494                         #define WORDS_BIGENDIAN 1
 495                         #endif
 496                 ])
 497                 ;;
 498         *)
 499                 AC_C_BIGENDIAN
 500                 ;;
 501 esac
 502
 503 # As a GNU extension, glibc declares environ in unistd.h, which is one of
 504 # the AC_INCLUDES_DEFAULT.
 505 AC_CHECK_DECLS([environ])
 506
 507 dnl **********************************
 508 dnl *** va_copy checks (from GLib) ***
 509 dnl **********************************
 510 dnl we currently check for all three va_copy possibilities, so we get
 511 dnl all results in config.log for bug reports.
 512 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 513         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 514 #include <stdlib.h>
 515         static void f (int i, ...) {
 516         va_list args1, args2;
 517         va_start (args1, i);
 518         va_copy (args2, args1);
 519         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 520           exit (1);
 521         va_end (args1); va_end (args2);
 522         }
 523         int main() {
 524           f (0, 42);
 525           return 0;
 526         }])],
 527         [dbus_cv_va_copy=yes],
 528         [dbus_cv_va_copy=no])
 529 ])
 530 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 531         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 532 #include <stdlib.h>
 533         static void f (int i, ...) {
 534         va_list args1, args2;
 535         va_start (args1, i);
 536         __va_copy (args2, args1);
 537         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 538           exit (1);
 539         va_end (args1); va_end (args2);
 540         }
 541         int main() {
 542           f (0, 42);
 543           return 0;
 544         }])],
 545         [dbus_cv___va_copy=yes],
 546         [dbus_cv___va_copy=no])
 547 ])
 548
 549 if test "x$dbus_cv_va_copy" = "xyes"; then
 550   dbus_va_copy_func=va_copy
 551 else if test "x$dbus_cv___va_copy" = "xyes"; then
 552   dbus_va_copy_func=__va_copy
 553 fi
 554 fi
 555
 556 if test -n "$dbus_va_copy_func"; then
 557   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 558 fi
 559
 560 AC_LANG_PUSH(C)
 561 AC_CACHE_CHECK([whether va_lists can be copied by value],
 562         dbus_cv_va_val_copy,
 563         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 564 [[
 565         #include <stdarg.h>
 566         #include <stdlib.h>
 567 ]],
 568 [[
 569         static void f (int i, ...) {
 570         va_list args1, args2;
 571         va_start (args1, i);
 572         args2 = args1;
 573         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 574           exit (1);
 575         va_end (args1); va_end (args2);
 576         }
 577         int main() {
 578           f (0, 42);
 579           return 0;
 580         }
 581 ]])],
 582         [dbus_cv_va_val_copy=yes],
 583         [dbus_cv_va_val_copy=no],
 584         [dbus_cv_va_val_copy=yes])
 585 ])
 586 AC_LANG_POP(C)
 587
 588 if test "x$dbus_cv_va_val_copy" = "xno"; then
 589   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 590 fi
 591
 592
 593 #### Atomic integers
 594
 595 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 596   dbus_cv_sync_sub_and_fetch,
 597   [AC_LINK_IFELSE([
 598      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 599      [dbus_cv_sync_sub_and_fetch=yes],
 600      [dbus_cv_sync_sub_and_fetch=no])
 601   ])
 602
 603 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 604    have_sync=1
 605 else
 606    have_sync=0
 607 fi
 608
 609 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 610
 611 #### Various functions
 612 AC_SEARCH_LIBS(socket,[socket network])
 613 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 614
 615 AC_CHECK_FUNCS([vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid setresuid getrlimit])
 616
 617 AC_CHECK_HEADERS([syslog.h])
 618 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 619   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 620 fi
 621
 622 # For test-segfault.c
 623 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 624 AC_CHECK_FUNCS_ONCE([prctl raise])
 625
 626 #### Check for broken poll; taken from Glib's configure
 627
 628 AC_MSG_CHECKING([for broken poll])
 629 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 630     #include <stdlib.h>
 631     #include <fcntl.h>
 632     #include <poll.h>
 633     #ifdef HAVE_SYS_POLL_H
 634     #include <sys/poll.h>
 635     #endif
 636     int main(void) {
 637       struct pollfd fds[1];
 638       int fd;
 639       fd = open("/dev/null", 1);
 640       fds[0].fd = fd;
 641       fds[0].events = POLLIN;
 642       fds[0].revents = 0;
 643       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 644             exit(1);  /* Does not work for devices -- fail */
 645       }
 646       exit(0);
 647     }]])],
 648   [broken_poll=no],
 649   [broken_poll=yes
 650    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 651   [broken_poll="no (cross compiling)"])
 652 AC_MSG_RESULT($broken_poll)
 653
 654 AC_MSG_CHECKING(for dirfd)
 655 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 656 #include <sys/types.h>
 657 #include <dirent.h>
 658 ]], [[
 659 DIR *dirp;
 660 dirp = opendir(".");
 661 dirfd(dirp);
 662 closedir(dirp);
 663 ]])],
 664 [dbus_have_dirfd=yes],
 665 [dbus_have_dirfd=no])
 666 AC_MSG_RESULT($dbus_have_dirfd)
 667 if test "$dbus_have_dirfd" = yes; then
 668         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 669 else
 670         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 671         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 672 #include <sys/types.h>
 673 #include <dirent.h>
 674         ]], [[
 675 DIR *dirp;
 676 int fd;
 677 dirp = opendir(".");
 678 fd = dirp->dd_fd;
 679 closedir(dirp);
 680         ]])],
 681         [dbus_have_ddfd=yes],
 682         [dbus_have_ddfd=no])
 683         AC_MSG_RESULT($dbus_have_ddfd)
 684         if test "$dbus_have_ddfd" = yes; then
 685                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 686         fi
 687 fi
 688
 689 AC_CHECK_HEADERS(sys/resource.h)
 690
 691 AC_CHECK_HEADERS(dirent.h)
 692
 693 AC_CHECK_HEADERS([execinfo.h],
 694         [AC_SEARCH_LIBS([backtrace], [execinfo],
 695                 [AC_DEFINE([HAVE_BACKTRACE], [1],
 696                         [Define to 1 if you have backtrace().])])])
 697
 698 AC_CHECK_HEADERS(errno.h)
 699
 700 AC_CHECK_HEADERS(signal.h)
 701
 702 AC_CHECK_HEADERS(locale.h)
 703
 704 AC_CHECK_HEADERS(byteswap.h)
 705
 706 AC_CHECK_HEADERS(unistd.h)
 707
 708 AC_CHECK_HEADERS([stdint.h])
 709
 710 AC_CHECK_HEADERS(ws2tcpip.h)
 711
 712 AC_CHECK_HEADERS(alloca.h)
 713
 714 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 715 #
 716 case $host_os in
 717     solaris*)
 718        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 719 esac
 720
 721 # checking for a posix version of getpwnam_r
 722 # if we are cross compiling and can not run the test
 723 # assume getpwnam_r is the posix version
 724 # it is up to the person cross compiling to change
 725 # this behavior if desired
 726 AC_LANG_PUSH(C)
 727 AC_CACHE_CHECK([for posix getpwnam_r],
 728                 ac_cv_func_posix_getpwnam_r,
 729                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 730 [[
 731 #include <errno.h>
 732 #include <pwd.h>
 733 ]],
 734 [[
 735     char buffer[10000];
 736     struct passwd pwd, *pwptr = &pwd;
 737     int error;
 738     errno = 0;
 739     error = getpwnam_r ("", &pwd, buffer,
 740                         sizeof (buffer), &pwptr);
 741    return (error < 0 && errno == ENOSYS)
 742            || error == ENOSYS;
 743 ]])],
 744         [ac_cv_func_posix_getpwnam_r=yes],
 745         [ac_cv_func_posix_getpwnam_r=no],
 746         [ac_cv_func_posix_getpwnam_r=yes]
 747 )])
 748 AC_LANG_POP(C)
 749
 750 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 751         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 752                 [Have POSIX function getpwnam_r])
 753 else
 754         AC_CACHE_CHECK([for nonposix getpwnam_r],
 755                 ac_cv_func_nonposix_getpwnam_r,
 756                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 757                         struct passwd pwd;
 758                         getpwnam_r ("", &pwd, buffer,
 759                                         sizeof (buffer));]])],
 760                         [ac_cv_func_nonposix_getpwnam_r=yes],
 761                         [ac_cv_func_nonposix_getpwnam_r=no])])
 762                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 763                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 764                         [Have non-POSIX function getpwnam_r])
 765         fi
 766 fi
 767
 768 dnl check for socklen_t
 769 AC_MSG_CHECKING(whether socklen_t is defined)
 770 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 771 #include <sys/types.h>
 772 #include <sys/socket.h>
 773 #include <netdb.h>
 774 ]], [[
 775 socklen_t foo;
 776 foo = 1;
 777 ]])],
 778 [dbus_have_socklen_t=yes],
 779 [dbus_have_socklen_t=no])
 780 AC_MSG_RESULT($dbus_have_socklen_t)
 781
 782 if test "x$dbus_have_socklen_t" = "xyes"; then
 783     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 784 fi
 785
 786 dnl check for writev header and writev function so we're
 787 dnl good to go if HAVE_WRITEV gets defined.
 788 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 789
 790 dnl needed on darwin for NAME_MAX
 791 AC_CHECK_HEADERS(sys/syslimits.h)
 792
 793 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 794 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 795 #include <sys/socket.h> ]])
 796
 797 dnl check for flavours of varargs macros (test from GLib)
 798 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 799 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 800 int a(int p1, int p2, int p3);
 801 #define call_a(...) a(1,__VA_ARGS__)
 802 call_a(2,3);
 803 ]])],
 804 [dbus_have_iso_c_varargs=yes],
 805 [dbus_have_iso_c_varargs=no])
 806 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 807
 808 AC_MSG_CHECKING(for GNUC varargs macros)
 809 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 810 int a(int p1, int p2, int p3);
 811 #define call_a(params...) a(1,params)
 812 call_a(2,3);
 813 ]])],
 814 [dbus_have_gnuc_varargs=yes],
 815 [dbus_have_gnuc_varargs=no])
 816 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 817
 818 dnl Output varargs tests
 819 if test x$dbus_have_iso_c_varargs = xyes; then
 820     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 821 fi
 822 if test x$dbus_have_gnuc_varargs = xyes; then
 823     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 824 fi
 825
 826 dnl Check for various credentials.
 827 AC_MSG_CHECKING(for struct cmsgcred)
 828 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 829 #include <sys/types.h>
 830 #include <sys/socket.h>
 831 ]], [[
 832 struct cmsgcred cred;
 833
 834 cred.cmcred_pid = 0;
 835 ]])],
 836 [dbus_have_struct_cmsgcred=yes],
 837 [dbus_have_struct_cmsgcred=no])
 838 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 839
 840 if test x$dbus_have_struct_cmsgcred = xyes; then
 841     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 842 fi
 843
 844 AC_CHECK_MEMBER([struct unpcbid.unp_pid],
 845                 [AC_DEFINE([HAVE_UNPCBID], 1, [Have unpcbid structure])],
 846                 [],
 847                 [[#include <sys/un.h>]])
 848
 849 AC_CHECK_FUNCS(getpeerucred getpeereid)
 850
 851 AC_CHECK_FUNCS(pipe2 accept4)
 852
 853 PKG_CHECK_MODULES([EXPAT], [expat])
 854
 855 save_cflags="$CFLAGS"
 856 save_libs="$LIBS"
 857 CFLAGS="$CFLAGS $EXPAT_CFLAGS"
 858 LIBS="$LIBS $EXPAT_LIBS"
 859 AC_CHECK_FUNCS([XML_SetHashSalt])
 860 CFLAGS="$save_cflags"
 861 LIBS="$save_libs"
 862
 863 # Thread lib detection
 864 AC_ARG_VAR([THREAD_LIBS])
 865 save_libs="$LIBS"
 866 LIBS="$LIBS $THREAD_LIBS"
 867
 868 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 869
 870 # Don't do these automatic checks if the user set THREAD_LIBS on the
 871 # configure command-line. If they did, we assume they're right.
 872 #
 873 # We also don't do these checks on Windows, because you don't need magical
 874 # linker flags to have threading support there.
 875 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 876   [
 877     # Mandatory pthread functions. In principle, some of these could be made
 878     # optional if there are platforms that don't have them.
 879     #
 880     # Currently, we only look in -lpthread.
 881     # In principle we might need to look in -lpthreads, -lthreads, ...
 882     # as well - please file a bug if your platform needs this.
 883     AC_SEARCH_LIBS([pthread_cond_timedwait],
 884         [pthread],
 885         [THREAD_LIBS="$LIBS"],
 886         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 887         [])
 888     AC_SEARCH_LIBS([pthread_mutexattr_init],
 889         [pthread],
 890         [THREAD_LIBS="$LIBS"],
 891         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 892         [])
 893     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 894         [pthread],
 895         [THREAD_LIBS="$LIBS"],
 896         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 897         [])
 898
 899     # Optional, for monotonic clocks. Because it's optional, this check
 900     # is non-fatal if we don't find it.
 901     AC_SEARCH_LIBS([pthread_condattr_setclock],
 902         [pthread],
 903         [THREAD_LIBS="$LIBS"])
 904
 905     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
 906       [
 907         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
 908         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 909         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 910 [[#include <time.h>
 911 #include <pthread.h>
 912 ]], [[
 913 struct timespec monotonic_timer;
 914 pthread_condattr_t attr;
 915 pthread_condattr_init (&attr);
 916 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 917 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 918 ]])],
 919             [have_clock_monotonic=true],
 920             [have_clock_monotonic=false])
 921         AS_IF([test x$have_clock_monotonic = xtrue],
 922           [
 923             AC_MSG_RESULT([found])
 924             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 925           ],
 926           [AC_MSG_RESULT([not found])])
 927       ]) dnl have pthread_condattr_setclock
 928   ]) dnl on Unix
 929
 930 LIBS="$save_libs"
 931
 932 AC_SUBST([THREAD_LIBS])
 933
 934 # SELinux detection
 935 if test x$enable_selinux = xno ; then
 936     have_selinux=no;
 937 else
 938     # See if we have SELinux library
 939     PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0.86],
 940                  [have_selinux=yes], [have_selinux=no])
 941
 942     if test x$enable_selinux = xauto ; then
 943         if test x$have_selinux = xno ; then
 944                 AC_MSG_WARN([Sufficiently new SELinux library not found])
 945         fi
 946     else
 947         if test x$have_selinux = xno ; then
 948                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
 949         fi
 950     fi
 951 fi
 952
 953 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
 954
 955 if test x$have_selinux = xyes ; then
 956     # the selinux code creates threads
 957     # which requires libpthread even on linux
 958     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
 959                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
 960
 961     SELINUX_LIBS="$SELINUX_LIBS $SELINUX_THREAD_LIBS"
 962     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
 963 else
 964     SELINUX_LIBS=
 965 fi
 966
 967 # AppArmor detection
 968 AS_IF([test x$enable_apparmor = xno],
 969   [have_apparmor=no],
 970   [
 971   PKG_CHECK_MODULES([APPARMOR], [libapparmor >= 2.8.95],
 972                     [have_apparmor=yes], [have_apparmor=no])
 973   PKG_CHECK_MODULES([APPARMOR_2_10], [libapparmor >= 2.10],
 974                     [have_apparmor_2_10=yes], [have_apparmor_2_10=no])
 975
 976   AS_IF([test x$enable_apparmor = xauto && test x$have_apparmor = xno],
 977         [AC_MSG_WARN([Sufficiently new AppArmor library not found])])
 978   AS_IF([test x$enable_apparmor != xauto && test x$have_apparmor = xno],
 979         [AC_MSG_ERROR([AppArmor explicitly required, and AppArmor library not found])])
 980   ])
 981
 982 AS_IF([test x$have_apparmor = xyes],
 983       [AC_DEFINE([HAVE_APPARMOR], [1], [AppArmor Support])])
 984 AS_IF([test x$have_apparmor_2_10 = xyes],
 985       [AC_DEFINE([HAVE_APPARMOR_2_10], [1],
 986                  [Define if libapparmor is version 2.10 or later])])
 987
 988 # inotify checks
 989 if test x$enable_inotify = xno ; then
 990     have_inotify=no;
 991 else
 992     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
 993 fi
 994
 995 dnl check if inotify backend is enabled
 996 if test x$have_inotify = xyes; then
 997    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
 998    AC_CHECK_FUNCS(inotify_init1)
 999 fi
1000
1001 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1002
1003 # For simplicity, we require the userland API for epoll_create1 at
1004 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1005 # not to have it at runtime.
1006 AC_ARG_ENABLE([epoll],
1007               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1008               [enable_epoll=$enableval], [enable_epoll=auto])
1009 if test x$enable_epoll = xno; then
1010     have_linux_epoll=no
1011 else
1012     AC_MSG_CHECKING([for Linux epoll(4)])
1013     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1014         [
1015         #ifndef __linux__
1016         #error This is not Linux
1017         #endif
1018         #include <sys/epoll.h>
1019         ],
1020         [epoll_create1 (EPOLL_CLOEXEC);])],
1021         [have_linux_epoll=yes],
1022         [have_linux_epoll=no])
1023     AC_MSG_RESULT([$have_linux_epoll])
1024 fi
1025 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1026     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1027 fi
1028 if test x$have_linux_epoll = xyes; then
1029   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1030 fi
1031 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1032
1033 # kqueue checks
1034 if test x$enable_kqueue = xno ; then
1035     have_kqueue=no
1036 else
1037     have_kqueue=yes
1038     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1039     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1040
1041     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1042         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1043     fi
1044 fi
1045
1046 dnl check if kqueue backend is enabled
1047 if test x$have_kqueue = xyes; then
1048    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1049 fi
1050
1051 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1052
1053 # launchd checks
1054 if test x$enable_launchd = xno ; then
1055     have_launchd=no
1056 else
1057     have_launchd=yes
1058     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1059     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1060     if test "x$LAUNCHCTL" = "x"; then
1061         have_launchd=no
1062     fi
1063
1064     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1065         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1066     fi
1067 fi
1068
1069 dnl check if launchd is enabled
1070 if test x$have_launchd = xyes; then
1071     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1072 fi
1073
1074 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1075
1076 #### Directory to place launchd agent file
1077 if test "x$with_launchd_agent_dir" = "x"; then
1078    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1079 else
1080    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1081 fi
1082
1083 AC_SUBST(LAUNCHD_AGENT_DIR)
1084
1085 dnl console owner file
1086 if test x$enable_console_owner_file = xno ; then
1087     have_console_owner_file=no;
1088 else
1089     case $host_os in
1090     solaris*)
1091         have_console_owner_file=yes;
1092         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1093         ;;
1094     *)
1095         have_console_owner_file=no;;
1096     esac
1097 fi
1098
1099 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1100
1101 dnl systemd detection
1102 if test x$enable_systemd = xno ; then
1103     have_systemd=no;
1104 else
1105     PKG_CHECK_MODULES([SYSTEMD],
1106         [libsystemd >= 209],
1107         [have_systemd=yes],
1108         [PKG_CHECK_MODULES([SYSTEMD],
1109             [libsystemd-login >= 32, libsystemd-daemon >= 32, libsystemd-journal >= 32],
1110             [have_systemd=yes],
1111             [have_systemd=no])])
1112 fi
1113
1114 if test x$have_systemd = xyes; then
1115     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1116 fi
1117
1118 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1119     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1120 fi
1121
1122 # If not found in $PATH, we might still have systemd and systemctl at runtime
1123 # (perhaps dbus is being compiled in a minimal chroot with no systemd).
1124 # Assume the upstream-recommended location. Distributors with split /usr
1125 # can override this with ./configure SYSTEMCTL=/bin/systemctl
1126 AC_PATH_PROG([SYSTEMCTL], [systemctl], [/usr/bin/systemctl])
1127
1128 # libaudit detection
1129 if test x$enable_libaudit = xno ; then
1130     have_libaudit=no;
1131 else
1132     # See if we have audit daemon & capabilities library
1133     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1134                  have_libaudit=yes, have_libaudit=no)
1135     if test x$have_libaudit = xyes ; then
1136         AC_CHECK_LIB(cap-ng, capng_clear,
1137                  have_libaudit=yes, have_libaudit=no)
1138     fi
1139 fi
1140
1141 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1142
1143 if test x$have_libaudit = xyes ; then
1144     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1145     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1146 fi
1147
1148 AC_SUBST([SELINUX_LIBS])
1149
1150 # Check for ADT API (Solaris Basic Security Mode auditing)
1151 AC_MSG_CHECKING(for ADT API)
1152 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1153 #include <bsm/adt.h>
1154 adt_user_context = ADT_USER;
1155 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1156
1157 if test ${check_adt_audit} = yes
1158 then
1159    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1160    ADT_LIBS="-lbsm"
1161    LIBS="-lbsm $LIBS"
1162    AC_MSG_RESULT(yes)
1163 else
1164    AC_MSG_RESULT(no)
1165 fi
1166 AC_SUBST([ADT_LIBS])
1167
1168 # Check for SCM_RIGHTS
1169 AC_MSG_CHECKING([for SCM_RIGHTS])
1170 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1171 #include <sys/types.h>
1172 #include <sys/socket.h>
1173 #include <sys/un.h>
1174 static int x = SCM_RIGHTS;
1175 ]], [[]])],
1176 [ AC_MSG_RESULT([supported])
1177   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1178 [ AC_MSG_RESULT([not supported]) ])
1179
1180 NETWORK_libs=
1181 if test x$dbus_win = xyes ; then
1182   if test x$dbus_wince = xyes ; then
1183     NETWORK_libs="-lws2"
1184   else
1185     NETWORK_libs="-lws2_32 -liphlpapi -ldbghelp"
1186   fi
1187 fi
1188
1189 AC_SUBST([NETWORK_libs])
1190
1191 AC_ARG_WITH([valgrind],
1192   [AS_HELP_STRING([--with-valgrind],
1193      [Add instrumentation to help valgrind to understand our allocator])],
1194   [],
1195   [with_valgrind=no])
1196
1197 AS_IF([test "x$with_valgrind" = xauto],
1198   [PKG_CHECK_EXISTS([valgrind >= 3.6],
1199     [with_valgrind=yes], [with_valgrind=no])])
1200
1201 if test x$with_valgrind != xno; then
1202   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1203   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1204 fi
1205
1206 #### Set up final flags
1207 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs $SYSTEMD_LIBS"
1208 AC_SUBST([LIBDBUS_LIBS])
1209
1210 ### X11 detection
1211 DBUS_X_LIBS=
1212 DBUS_X_CFLAGS=
1213
1214 AC_ARG_ENABLE([x11-autolaunch],
1215   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1216   [], [enable_x11_autolaunch=auto])
1217
1218 if test "x$dbus_win" = xyes; then
1219     if test "x$enable_x11_autolaunch" = xyes; then
1220         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1221     fi
1222
1223     enable_x11_autolaunch=no
1224     have_x11=no
1225 else
1226     AC_PATH_XTRA
1227
1228     if test "x$no_x" = xyes; then
1229         have_x11=no
1230     else
1231         have_x11=yes
1232         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1233         DBUS_X_CFLAGS="$X_CFLAGS"
1234     fi
1235 fi
1236
1237 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1238     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1239 else
1240     # move from "auto" to "yes" or "no" if necessary
1241     if test "x$enable_x11_autolaunch" != xno; then
1242         enable_x11_autolaunch="$have_x11"
1243     fi
1244 fi
1245
1246 if test "x$have_x11" = xyes ; then
1247    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1248 fi
1249
1250 if test "x$enable_x11_autolaunch" = xyes ; then
1251    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1252 fi
1253 AM_CONDITIONAL([DBUS_ENABLE_X11_AUTOLAUNCH],
1254   [test "x$enable_x11_autolaunch" = xyes])
1255
1256 AC_SUBST([DBUS_X_CFLAGS])
1257 AC_SUBST([DBUS_X_LIBS])
1258
1259 # We're treating -fno-common like a warning: it makes the linker more
1260 # strict, because on some systems the linker is *always* this strict
1261 TEST_CFLAGS="$TEST_CFLAGS -fno-common"
1262
1263 AS_IF([test "x$enable_ansi" = "xyes"],[
1264     TEST_CFLAGS="$TEST_CFLAGS -ansi -pedantic"
1265     AC_DEFINE([_POSIX_C_SOURCE],[199309L],[Define to enable POSIX features])
1266     AC_DEFINE([_BSD_SOURCE],[1],[Define to enable BSD features])
1267   ])
1268
1269 dnl We are only calling this for its side-effect of setting up
1270 dnl --enable-compile-warnings; the WARN_CFLAGS, etc. are ignored,
1271 dnl to work around https://github.com/peti/autoconf-archive/pull/96
1272 AX_COMPILER_FLAGS([], [], [$disable_developer])
1273
1274 dnl Work around https://github.com/peti/autoconf-archive/pull/96 by using
1275 dnl a non-default variable name here (in particular there is no way to tell
1276 dnl AX_COMPILER_FLAGS to not use WARN_CXXFLAGS)
1277 AX_COMPILER_FLAGS_CFLAGS([EXTRA_CFLAGS],
1278                          [$disable_developer],
1279                          [$TEST_CFLAGS],
1280                          [-Wchar-subscripts \
1281                           -Wfloat-equal \
1282                           -Wpointer-sign \
1283                           $DISABLE_WARNINGS])
1284 dnl cc1plus: warning: command line option ‘-Wpointer-sign’ is valid for
1285 dnl C/ObjC but not for C++
1286 AX_COMPILER_FLAGS_CXXFLAGS([EXTRA_CXXFLAGS],
1287                            [$disable_developer],
1288                            [],
1289                            [-Wchar-subscripts \
1290                             -Wfloat-equal \
1291                             $DISABLE_WARNINGS])
1292 AX_COMPILER_FLAGS_LDFLAGS([EXTRA_LDFLAGS],
1293                           [$disable_developer])
1294
1295 dnl TODO: In principle we should put EXTRA_CFLAGS in each Makefile.am like
1296 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1297 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1298 dnl is the next best thing.
1299 CFLAGS="$EXTRA_CFLAGS $CFLAGS"
1300 CXXFLAGS="$EXTRA_CXXFLAGS $CXXFLAGS"
1301 LDFLAGS="$EXTRA_LDFLAGS $LDFLAGS"
1302
1303 case $host_os in
1304     solaris*)
1305         # Solaris' C library apparently needs these runes to be threadsafe...
1306         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1307         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1308         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1309         # ... and this opt-in to get file descriptor passing support
1310         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1311         ;;
1312 esac
1313
1314 ### Detect if ld supports --version-script
1315
1316 gl_LD_VERSION_SCRIPT
1317 AM_CONDITIONAL([HAVE_LD_VERSION_SCRIPT],
1318                [test "x$have_ld_version_script" = xyes])
1319 ### Doxygen Documentation
1320
1321 AC_PATH_PROG(DOXYGEN, doxygen, no)
1322
1323 AC_MSG_CHECKING([whether to build Doxygen documentation])
1324
1325 if test x$DOXYGEN = xno ; then
1326     have_doxygen=no
1327 else
1328     have_doxygen=yes
1329 fi
1330
1331 if test x$enable_doxygen_docs = xauto ; then
1332     if test x$have_doxygen = xno ; then
1333         enable_doxygen_docs=no
1334     else
1335         enable_doxygen_docs=yes
1336     fi
1337 fi
1338
1339 if test x$enable_doxygen_docs = xyes; then
1340     if test x$have_doxygen = xno; then
1341         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1342     fi
1343 fi
1344
1345 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1346 AC_MSG_RESULT($enable_doxygen_docs)
1347
1348 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1349 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1350
1351 ### Ducktype/Yelp documentation
1352
1353 AC_PATH_PROG([DUCKTYPE],[ducktype],[no])
1354 AC_PATH_PROG([YELP_BUILD],[yelp-build],[no])
1355
1356 AC_MSG_CHECKING([whether to build Ducktype documentation])
1357
1358 AS_IF([test "$DUCKTYPE" = "no"],[have_ducktype=no],[have_ducktype=yes])
1359 AS_IF([test "$YELP_BUILD" = "no"],[have_yelp_build=no],[have_yelp_build=yes])
1360
1361 AS_IF([test "$enable_ducktype_docs" = "auto"],[
1362     AS_IF([test "$have_ducktype" = "no" || test "$have_yelp_build" = "no"],[
1363         enable_ducktype_docs=no
1364     ],[
1365         enable_ducktype_docs=yes
1366     ])
1367 ])
1368
1369 AS_IF([test "$enable_ducktype_docs" = "yes"],[
1370     AS_IF([test "$have_ducktype" = "no"],[
1371         AC_MSG_ERROR([Building Ducktype docs explicitly required, but ducktype not found])
1372     ])
1373     AS_IF([test "$have_yelp_build" = "no"],[
1374         AC_MSG_ERROR([Building Ducktype docs explicitly required, but yelp-build not found])
1375     ])
1376 ])
1377
1378 AM_CONDITIONAL([DBUS_DUCKTYPE_DOCS_ENABLED],[test "$enable_ducktype_docs" = "yes"])
1379 AC_MSG_RESULT([$enable_ducktype_docs])
1380
1381 ### XML Documentation
1382
1383 AC_PATH_PROG(XMLTO, xmlto, no)
1384
1385 AC_MSG_CHECKING([whether to build XML documentation])
1386
1387 if test x$XMLTO = xno ; then
1388     have_xmlto=no
1389 else
1390     have_xmlto=yes
1391 fi
1392
1393 if test x$enable_xml_docs = xauto ; then
1394     if test x$have_xmlto = xno ; then
1395         enable_xml_docs=no
1396     else
1397         enable_xml_docs=yes
1398     fi
1399 fi
1400
1401 if test x$enable_xml_docs = xyes; then
1402     if test x$have_xmlto = xno; then
1403         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1404     fi
1405 fi
1406
1407 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1408 AC_MSG_RESULT($enable_xml_docs)
1409
1410 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1411     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes &&
1412      test x$enable_ducktype_docs = xyes])
1413
1414 # Autoconf 2.70 will support this, and many distros patch this option in,
1415 # but Autoconf 2.70 hasn't actually been released yet.
1416 AS_IF([test -z "${runstatedir}"], [runstatedir='${localstatedir}/run'])
1417 AC_SUBST([runstatedir])
1418
1419 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1420
1421 #### find the actual value for $prefix that we'll end up with
1422 ##   (I know this is broken and should be done in the Makefile, but
1423 ##    that's a major pain and almost nobody actually seems to care)
1424 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1425 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1426 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1427 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1428 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1429 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1430 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1431 AS_AC_EXPAND(EXPANDED_RUNSTATEDIR, "$runstatedir")
1432
1433 ##### systemd unit files
1434 AC_ARG_WITH([systemdsystemunitdir],
1435 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1436     [],
1437     [
1438     PKG_CHECK_EXISTS([systemd],
1439       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1440       [with_systemdsystemunitdir=no])
1441     ])
1442 if test "x$with_systemdsystemunitdir" != xno; then
1443    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1444 fi
1445 AM_CONDITIONAL(HAVE_SYSTEMD, [test "x$have_systemd" != "xno" -a -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1446
1447 AC_ARG_WITH([systemduserunitdir],
1448 AS_HELP_STRING([--with-systemduserunitdir=DIR], [Directory for systemd user service files]),
1449     [],
1450     [
1451     PKG_CHECK_EXISTS([systemd],
1452       [with_systemduserunitdir=$($PKG_CONFIG --variable=systemduserunitdir systemd)],
1453       [with_systemduserunitdir='${libdir}/systemd/user'])
1454     ])
1455 AC_SUBST([systemduserunitdir], [$with_systemduserunitdir])
1456
1457 ##### Set up location for system bus socket
1458 if ! test -z "$with_system_socket"; then
1459    DBUS_SYSTEM_SOCKET=$with_system_socket
1460 else
1461    # We don't use runstatedir for this (yet?), because /var/run has been the
1462    # interoperable system bus socket for 10+ years.
1463    # See https://bugs.freedesktop.org/show_bug.cgi?id=101628
1464    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1465 fi
1466
1467 AC_SUBST(DBUS_SYSTEM_SOCKET)
1468 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1469
1470 ## System bus only listens on local domain sockets, and never
1471 ## on an abstract socket (so only root can create the socket).
1472 ##
1473 ## This won't work on Windows. It's not meant to - the system bus is
1474 ## meaningless on Windows anyway.
1475 ##
1476 ## This has to be suitable for hard-coding in client libraries as well as
1477 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1478 ## and also to connect to. If this ever changes, it'll need to be split into
1479 ## two variables, one for the listening address and one for the connecting
1480 ## address.
1481 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1482 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1483 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1484
1485 #### Set up the pid file
1486 if ! test -z "$with_system_pid_file"; then
1487    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1488 else
1489    DBUS_SYSTEM_PID_FILE="${EXPANDED_RUNSTATEDIR}/dbus/pid"
1490 fi
1491
1492 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1493
1494 #### Directory to check for console ownership
1495 AS_IF([test -n "$with_console_auth_dir" && test "x$with_console_auth_dir" != xno],
1496     [AC_DEFINE_UNQUOTED([DBUS_CONSOLE_AUTH_DIR], ["$with_console_auth_dir"],
1497         [Directory to check for pam_console/pam_foreground flag files, or undefined])],
1498     [with_console_auth_dir=])
1499
1500 #### File to check for console ownership
1501 if test x$have_console_owner_file = xyes; then
1502    if ! test -z "$with_console_owner_file"; then
1503       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1504    else
1505       DBUS_CONSOLE_OWNER_FILE=/dev/console
1506    fi
1507 else
1508   DBUS_CONSOLE_OWNER_FILE=
1509 fi
1510
1511 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1512 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1513
1514 #### User to start the system bus as
1515 if test -z "$with_dbus_user" ; then
1516     DBUS_USER=messagebus
1517 else
1518     DBUS_USER=$with_dbus_user
1519 fi
1520 AC_SUBST(DBUS_USER)
1521 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1522
1523 #### User for regression tests
1524 AS_IF([test -z "$with_test_user"], [with_test_user=nobody])
1525 DBUS_TEST_USER="$with_test_user"
1526 AC_SUBST([DBUS_TEST_USER])
1527 AC_DEFINE_UNQUOTED([DBUS_TEST_USER], ["$DBUS_TEST_USER"],
1528   [Unprivileged user used in some regression tests])
1529
1530 #### Prefix to install into
1531 DBUS_PREFIX=$EXPANDED_PREFIX
1532 AC_SUBST(DBUS_PREFIX)
1533 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1534
1535 #### Direcotry to install data files into
1536 DBUS_DATADIR=$EXPANDED_DATADIR
1537 AC_SUBST(DBUS_DATADIR)
1538 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1539
1540 #### Directory to install dbus-daemon
1541 if test -z "$with_dbus_daemondir" ; then
1542     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1543     dbus_daemondir='$bindir'
1544 else
1545     DBUS_DAEMONDIR=$with_dbus_daemondir
1546     dbus_daemondir=$with_dbus_daemondir
1547 fi
1548 AC_SUBST(DBUS_DAEMONDIR)
1549 AC_SUBST(dbus_daemondir)
1550 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1551
1552 #### Directory to install the other binaries
1553 DBUS_BINDIR="$EXPANDED_BINDIR"
1554 AC_SUBST(DBUS_BINDIR)
1555 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1556
1557 #### Directory to install the libexec binaries
1558 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1559 AC_SUBST(DBUS_LIBEXECDIR)
1560 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1561
1562 AC_ARG_ENABLE([relocation],
1563   [AS_HELP_STRING([--enable-relocation[=yes/no/auto]],
1564     [Make pkg-config metadata relocatable [default=auto]])],
1565   [], [enable_relocation=auto])
1566
1567 can_relocate=yes
1568
1569 AS_CASE(["${exec_prefix}"],
1570   ['NONE'|'${prefix}'],
1571     [:],
1572   [*],
1573     [can_relocate=no])
1574
1575 AS_CASE(["${libdir}"],
1576   ['${prefix}/lib'|'${prefix}/lib64'|'${exec_prefix}/lib'|'${exec_prefix}/lib64'],
1577     [:],
1578   [*],
1579     [can_relocate=no])
1580
1581 # If the user said --enable-relocation but we can't do it, error out
1582 AS_IF([test "x$can_relocate" = xno && test "x$enable_relocation" = xyes],
1583   [AC_MSG_ERROR([Relocatable pkg-config metadata requires --exec-prefix='\${prefix}' and the default libdir])])
1584
1585 # By default, on Windows we are relocatable if possible
1586 AS_IF([test "x$enable_relocation" = xauto && test "x$dbus_win" = xyes],
1587   [enable_relocation="$can_relocate"])
1588
1589 # By default, on non-Windows we are not relocatable because it can interfere
1590 # with pkg-config's ability to filter out system include directories,
1591 # resulting in linking an outdated system-wide library in preference to a
1592 # newer version installed elsewhere
1593 AS_IF([test "x$enable_relocation" = xauto],
1594   [enable_relocation="no"])
1595
1596
1597 AS_IF([test "x$enable_relocation" = xyes],
1598   [AC_SUBST([pkgconfig_prefix], ['${pcfiledir}/../../'])],
1599   [AC_SUBST([pkgconfig_prefix], ['${original_prefix}'])])
1600
1601 #### Directory to source sysconfdir configuration from
1602
1603 # On Windows this is relative to where we put the bus setup, in
1604 # ${datadir}/dbus-1. For simplicity, we only do this if
1605 # ${sysconfdir} = ${prefix}/etc and ${datadir} = ${prefix}/share.
1606 #
1607 # On Unix, or on Windows with weird install layouts, it's the absolute path.
1608 AS_IF([test "${dbus_win}" = yes && \
1609        test "$EXPANDED_SYSCONFDIR" = "$EXPANDED_PREFIX/etc" && \
1610        test "$EXPANDED_DATADIR" = "$EXPANDED_PREFIX/share"],
1611       [SYSCONFDIR_FROM_PKGDATADIR="../../etc"
1612        DATADIR_FROM_PKGSYSCONFDIR="../../share"],
1613       [SYSCONFDIR_FROM_PKGDATADIR="$EXPANDED_SYSCONFDIR"
1614        DATADIR_FROM_PKGSYSCONFDIR="$EXPANDED_DATADIR"])
1615 AC_SUBST([SYSCONFDIR_FROM_PKGDATADIR])
1616 AC_SUBST([DATADIR_FROM_PKGSYSCONFDIR])
1617
1618 #### Tell tests where to find certain stuff in builddir
1619
1620 DBUS_PWD=`pwd`
1621 # Useful in a cross-compilation environment, where the tests are run on the host system.
1622 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1623                            DBUS_PWD=$withval)
1624
1625 DBUS_TEST_EXEC="$DBUS_PWD/test"
1626 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1627
1628 AC_SUBST([DBUS_TEST_DATA])
1629 AC_SUBST([DBUS_TEST_EXEC])
1630
1631 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1632                    [Extension for executables, typically empty or .exe])
1633
1634 ## Export the non-setuid external helper
1635 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1636 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1637 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1638                    [Full path to the launch helper test program in the builddir])
1639
1640 #### Find socket directories
1641 if ! test -z "$TMPDIR" ; then
1642    DEFAULT_SOCKET_DIR=$TMPDIR
1643 elif ! test -z "$TEMP" ; then
1644    DEFAULT_SOCKET_DIR=$TEMP
1645 elif ! test -z "$TMP" ; then
1646    DEFAULT_SOCKET_DIR=$TMP
1647 else
1648    DEFAULT_SOCKET_DIR=/tmp
1649 fi
1650
1651 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1652
1653 if ! test -z "$with_test_socket_dir" ; then
1654    TEST_SOCKET_DIR="$with_test_socket_dir"
1655 else
1656    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1657 fi
1658 AC_SUBST(TEST_SOCKET_DIR)
1659 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1660
1661 if test "x$dbus_unix" = xyes; then
1662   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1663 else
1664   TEST_LISTEN="tcp:host=localhost"
1665 fi
1666 AC_SUBST([TEST_LISTEN])
1667 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1668   [Listening address for regression tests])
1669
1670 if ! test -z "$with_session_socket_dir" ; then
1671    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1672 else
1673    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1674 fi
1675 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1676 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1677
1678 # This must be a listening address. It doesn't necessarily need to be an
1679 # address you can connect to - it can be something vague like
1680 # "nonce-tcp:".
1681 #
1682 # The default varies by platform.
1683 AC_ARG_WITH([dbus_session_bus_listen_address],
1684             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1685                            [default address for a session bus to listen on (see configure.ac)]),
1686             [with_dbus_session_bus_listen_address=$withval],
1687             [with_dbus_session_bus_listen_address=])
1688
1689 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1690         # the user specified something, trust them
1691         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1692 elif test x$dbus_win = xyes; then
1693         # On Windows, you can (and should) listen on autolaunch addresses,
1694         # because autolaunching is different.
1695         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1696         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1697 elif test x$have_launchd = xyes; then
1698         # Mac OS X default is to use launchd
1699         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1700 else
1701         # The default on all other Unix platforms (notably Linux)
1702         # is to create a randomly named socket in /tmp or similar
1703         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1704 fi
1705 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1706
1707 # This must be an address you can connect to. It doesn't necessarily
1708 # need to be an address you can listen on - it can be "autolaunch:",
1709 # even on Unix.
1710 #
1711 # The default varies by platform.
1712 AC_ARG_WITH([dbus_session_bus_connect_address],
1713             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1714                            [fallback address for a session bus client to connect to (see configure.ac)]),
1715             [with_dbus_session_bus_connect_address=$withval],
1716             [with_dbus_session_bus_connect_address=])
1717
1718 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1719         # the user specified something, trust them
1720         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1721 elif test x$dbus_win = xyes; then
1722         # Windows autolaunching is a bit different; leaving it in its own
1723         # branch of the conditional because the default might conceivably
1724         # change (see #38201)
1725         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1726 else
1727         # The default on all other Unix platforms (notably Linux)
1728         # is to use auto-launching - this works a bit differently on Mac OS X
1729         # but comes out basically the same in the end
1730         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1731 fi
1732 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1733 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1734   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1735   [Fallback address for session bus clients])
1736
1737 # darwin needs this to initialize the environment
1738 AC_CHECK_HEADERS(crt_externs.h)
1739 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1740 AH_VERBATIM(_DARWIN_ENVIRON,
1741 [
1742 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1743 # include <sys/time.h>
1744 # include <crt_externs.h>
1745 # define environ (*_NSGetEnviron())
1746 #endif
1747 ])
1748
1749 AC_ARG_ENABLE([stats],
1750   [AS_HELP_STRING([--disable-stats],
1751     [disable bus daemon usage statistics])],
1752   [], [enable_stats=yes])
1753 if test "x$enable_stats" = xyes; then
1754   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1755     [Define to enable bus daemon usage statistics])
1756 fi
1757
1758 AC_ARG_ENABLE([user-session],
1759   [AS_HELP_STRING([--enable-user-session],
1760     [enable user-session semantics for session bus under systemd])],
1761   [], [enable_user_session=no])
1762 AM_CONDITIONAL([DBUS_ENABLE_USER_SESSION],
1763   [test "x$enable_user_session" = xyes])
1764
1765 AC_CONFIG_FILES([
1766 Doxyfile
1767 dbus/Version
1768 dbus/versioninfo.rc
1769 dbus/dbus-arch-deps.h
1770 bus/system.conf
1771 bus/session.conf
1772 bus/legacy-config/system.conf
1773 bus/legacy-config/session.conf
1774 bus/example-system-enable-stats.conf
1775 bus/example-session-disable-stats.conf
1776 bus/org.freedesktop.dbus-session.plist
1777 bus/dbus.service
1778 bus/dbus.socket
1779 bus/systemd-user/dbus.service
1780 bus/systemd-user/dbus.socket
1781 bus/sysusers.d/dbus.conf
1782 bus/tmpfiles.d/dbus.conf
1783 Makefile
1784 dbus/Makefile
1785 bus/Makefile
1786 tools/Makefile
1787 test/Makefile
1788 test/name-test/Makefile
1789 doc/Makefile
1790 doc/dbus-cleanup-sockets.1.xml
1791 doc/dbus-daemon.1.xml
1792 doc/dbus-launch.1.xml
1793 doc/dbus-monitor.1.xml
1794 doc/dbus-run-session.1.xml
1795 doc/dbus-send.1.xml
1796 doc/dbus-test-tool.1.xml
1797 doc/dbus-update-activation-environment.1.xml
1798 doc/dbus-uuidgen.1.xml
1799 dbus-1.pc
1800 dbus-1-uninstalled.pc
1801 cmake/DBus1Config.cmake:cmake/DBus1Config.pkgconfig.in
1802 cmake/DBus1ConfigVersion.cmake
1803 ])
1804 AC_OUTPUT
1805
1806 dnl ==========================================================================
1807 echo "
1808                     D-Bus $VERSION
1809                   ==============
1810
1811         prefix:                   ${EXPANDED_PREFIX}
1812         exec_prefix:              ${exec_prefix}
1813         libdir:                   ${EXPANDED_LIBDIR}
1814         libexecdir:               ${EXPANDED_LIBEXECDIR}
1815         bindir:                   ${EXPANDED_BINDIR}
1816         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1817         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1818         runstatedir:              ${EXPANDED_RUNSTATEDIR}
1819         datadir:                  ${EXPANDED_DATADIR}
1820         source code location:     ${srcdir}
1821         compiler:                 ${CC}
1822         cflags:                   ${CFLAGS}
1823         cppflags:                 ${CPPFLAGS}
1824         cxxflags:                 ${CXXFLAGS}
1825         ldflags:                  ${LDFLAGS}
1826         64-bit int:               ${DBUS_INT64_TYPE}
1827         32-bit int:               ${DBUS_INT32_TYPE}
1828         16-bit int:               ${DBUS_INT16_TYPE}
1829         Doxygen:                  ${DOXYGEN:-not found}
1830         xmlto:                    ${XMLTO:-not found}
1831         ducktype:                 ${DUCKTYPE:-not found}
1832         yelp-build:               ${YELP_BUILD:-not found}"
1833
1834 echo "
1835         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1836         gcc coverage profiling:   ${enable_code_coverage}
1837         Building embedded tests:  ${enable_embedded_tests}
1838         Building modular tests:   ${enable_modular_tests}
1839             - with GLib:          ${with_glib}
1840         Installing tests:         ${enable_installed_tests}
1841         Building verbose mode:    ${enable_verbose_mode}
1842         Building assertions:      ${enable_asserts}
1843         Building checks:          ${enable_checks}
1844         Building bus stats API:   ${enable_stats}
1845         Building SELinux support: ${have_selinux}
1846         Building AppArmor support: ${have_apparmor}
1847         Building inotify support: ${have_inotify}
1848         Building kqueue support:  ${have_kqueue}
1849         Building systemd support: ${have_systemd}
1850         Building X11 code:        ${have_x11}
1851         Building Doxygen docs:    ${enable_doxygen_docs}
1852         Building Ducktype docs:   ${enable_ducktype_docs}
1853         Building XML docs:        ${enable_xml_docs}
1854         Building launchd support: ${have_launchd}
1855         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1856         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1857         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1858         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1859         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1860         pam_console auth dir:     ${with_console_auth_dir:-(none)}
1861         Console owner file:       ${have_console_owner_file}
1862         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1863         System bus user:          ${DBUS_USER}
1864         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1865         'make check' socket dir:  ${TEST_SOCKET_DIR}
1866 "
1867 if test x$have_launchd = xyes; then
1868         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1869 fi
1870 echo
1871
1872 if test x$enable_embedded_tests = xyes; then
1873         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1874 fi
1875 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1876         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1877 fi
1878 AS_IF([test x$enable_code_coverage = xyes],[
1879     AC_MSG_WARN([Building with coverage profiling is definitely for developers only.])
1880   ])
1881 if test x$enable_verbose_mode = xyes; then
1882         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1883 fi
1884 if test x$enable_asserts = xyes; then
1885         echo "NOTE: building with assertions increases library size and decreases performance."
1886 fi
1887 if test x$enable_checks = xno; then
1888         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1889 fi