configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [29])
  30 m4_define([glib_micro_version], [17])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AC_CANONICAL_HOST
 112
 113 AC_MSG_CHECKING([for the BeOS])
 114 case $host in
 115   *-*-beos*)
 116     glib_native_beos="yes"
 117     ;;
 118   *)
 119     glib_native_beos="no"
 120     ;;
 121 esac
 122 AC_MSG_RESULT([$glib_native_beos])
 123
 124 dnl
 125
 126 AC_MSG_CHECKING([for Win32])
 127 LIB_EXE_MACHINE_FLAG=X86
 128 case "$host" in
 129   *-*-mingw*)
 130     glib_native_win32=yes
 131     glib_pid_type='void *'
 132     glib_cv_stack_grows=no
 133     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 134     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 135     # (Sorry, I don't know exactly what is the problem, but it is related to
 136     # floating point formatting and decimal point vs. comma.)
 137     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 138     # rigorous enough to notice, though.
 139     # So preset the autoconf cache variables.
 140     ac_cv_func_vsnprintf_c99=no
 141     ac_cv_func_snprintf_c99=no
 142     case "$host" in
 143     x86_64-*-*)
 144       LIB_EXE_MACHINE_FLAG=X64
 145       ;;
 146     esac
 147     ;;
 148   *)
 149     glib_native_win32=no
 150     glib_pid_type=int
 151     ;;
 152 esac
 153 case $host in
 154   *-*-linux*)
 155     glib_os_linux=yes
 156     ;;
 157 esac
 158
 159 AC_MSG_RESULT([$glib_native_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162
 163 glib_have_carbon=no
 164 AC_MSG_CHECKING([for Mac OS X Carbon support])
 165 AC_TRY_CPP([
 166 #include <Carbon/Carbon.h>
 167 #include <CoreServices/CoreServices.h>
 168 ], glib_have_carbon=yes)
 169
 170 AC_MSG_RESULT([$glib_have_carbon])
 171
 172 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 173 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 174 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 175 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 176 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 177
 178 if test "$glib_native_win32" = "yes"; then
 179   AC_CHECK_TOOL(WINDRES, windres, no)
 180   if test "$WINDRES" = no; then
 181     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 182   fi
 183   AC_CHECK_TOOL(NM, nm, no)
 184   if test "$NM" = no; then
 185     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 186   fi
 187   AC_CHECK_TOOL(RANLIB, ranlib, :)
 188   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 189 fi
 190 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 191
 192 if test "$glib_native_win32" != yes; then
 193     # libtool option to control which symbols are exported
 194     # right now, symbols starting with _ are not exported
 195     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 196 else
 197     # We currently use .def files on Windows
 198     LIBTOOL_EXPORT_OPTIONS=
 199 fi
 200 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 201
 202 if test "x$glib_have_carbon" = "xyes"; then
 203   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 204   LDFLAGS="$LDFLAGS -framework Carbon"
 205 fi
 206
 207 gl_GLIBC21
 208 if test "x$GLIBC21" = "xyes"; then
 209   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 210 fi
 211
 212 dnl declare --enable-* args and collect ac_help strings
 213 AC_ARG_ENABLE(debug,
 214               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 215                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 216               enable_debug=glib_debug_default)
 217
 218 AC_ARG_ENABLE(gc_friendly,
 219               [AC_HELP_STRING([--enable-gc-friendly],
 220                               [turn on garbage collector friendliness [default=no]])],,
 221               [enable_gc_friendly=no])
 222 AC_ARG_ENABLE(mem_pools,
 223               [AC_HELP_STRING([--disable-mem-pools],
 224                               [disable all glib memory pools])],,
 225               [disable_mem_pools=no])
 226 AC_ARG_ENABLE(threads,
 227               [AC_HELP_STRING([--enable-threads],
 228                               [turn on basic thread support [default=yes]
 229 ([=no] will override --with-threads)])],,
 230               [enable_threads=yes])
 231 AC_ARG_ENABLE(rebuilds,
 232               [AC_HELP_STRING([--disable-rebuilds],
 233                               [disable all source autogeneration rules])],,
 234               [enable_rebuilds=yes])
 235
 236 if test "x$enable_threads" != "xyes"; then
 237   enable_threads=no
 238 fi
 239
 240 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 241 if test "x$enable_gc_friendly" = "xyes"; then
 242   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 243   AC_MSG_RESULT([yes])
 244 else
 245   AC_MSG_RESULT([no])
 246 fi
 247
 248 AC_MSG_CHECKING([whether to disable memory pools])
 249 if test "x$disable_mem_pools" = "xno"; then
 250   AC_MSG_RESULT([no])
 251 else
 252   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 253   AC_SUBST(DISABLE_MEM_POOLS)
 254   AC_MSG_RESULT([yes])
 255 fi
 256
 257 dnl location to install runtime libraries, e.g. ../../lib to install
 258 dnl to /lib if libdir is /usr/lib
 259 AC_ARG_WITH(runtime-libdir,
 260            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 261                            [Install runtime libraries relative to libdir])],
 262            [],
 263            [with_runtime_libdir=""])
 264 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 265 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 266 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 267 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 268 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 269
 270 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 271 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 272 AC_LANG_SAVE
 273 AC_LANG_CPLUSPLUS
 274 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 275 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 276 AC_LANG_RESTORE
 277
 278 AM_PROG_CC_STDC
 279 AM_PROG_CC_C_O
 280 AC_PROG_INSTALL
 281
 282 AC_SYS_LARGEFILE
 283
 284 PKG_PROG_PKG_CONFIG(0.16)
 285
 286 if test "x$enable_debug" = "xyes"; then
 287   if test x$cflags_set != xset ; then
 288       case " $CFLAGS " in
 289       *[[\ \    ]]-g[[\ \       ]]*) ;;
 290       *) CFLAGS="$CFLAGS -g" ;;
 291       esac
 292   fi
 293
 294   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 295 else
 296   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 297
 298   if test "x$enable_debug" = "xno"; then
 299     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 300   fi
 301 fi
 302
 303 # Ensure MSVC-compatible struct packing convention is used when
 304 # compiling for Win32 with gcc.
 305 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 306 # gcc2 uses "-fnative-struct".
 307 if test x"$glib_native_win32" = xyes; then
 308   if test x"$GCC" = xyes; then
 309     msnative_struct=''
 310     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 311     if test -z "$ac_cv_prog_CC"; then
 312       our_gcc="$CC"
 313     else
 314       our_gcc="$ac_cv_prog_CC"
 315     fi
 316     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 317       2.)
 318         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 319           msnative_struct='-fnative-struct'
 320         fi
 321         ;;
 322       *)
 323         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 324           msnative_struct='-mms-bitfields'
 325         fi
 326         ;;
 327     esac
 328     if test x"$msnative_struct" = x ; then
 329       AC_MSG_RESULT([no way])
 330       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 331     else
 332       CFLAGS="$CFLAGS $msnative_struct"
 333       AC_MSG_RESULT([${msnative_struct}])
 334     fi
 335   fi
 336 fi
 337 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 338 AC_SUBST(GLIB_EXTRA_CFLAGS)
 339
 340 AC_EXEEXT
 341
 342 # define a MAINT-like variable REBUILD which is set if Perl
 343 # and awk are found, so autogenerated sources can be rebuilt
 344 AC_PROG_AWK
 345 AC_CHECK_PROGS(PERL, [perl5 perl])
 346 # We would like indent, but don't require it.
 347 AC_CHECK_PROG(INDENT, indent, indent)
 348 REBUILD=\#
 349 if test "x$enable_rebuilds" = "xyes" && \
 350      test -n "$PERL" && \
 351      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 352      test -n "$AWK" ; then
 353   REBUILD=
 354 fi
 355 AC_SUBST(REBUILD)
 356
 357 # Need full path to Perl for glib-mkenums
 358 #
 359 if test "x$PERL" != x ; then
 360   AC_PATH_PROG(PERL_PATH, [$PERL])
 361 fi
 362 if test "x$PERL_PATH" = x ; then
 363   PERL_PATH="/usr/bin/env perl"
 364 fi
 365 AC_SUBST(PERL_PATH)
 366
 367 # Need suitable python path for greport
 368 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 369
 370
 371 dnl ***********************
 372 dnl *** Tests for iconv ***
 373 dnl ***********************
 374 dnl
 375 dnl We do this before the gettext checks, to avoid distortion
 376
 377 dnl On Windows we use a native implementation
 378
 379 if test x"$glib_native_win32" = xyes; then
 380   with_libiconv=native
 381 else
 382   AC_ARG_WITH(libiconv,
 383               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 384                               [use the libiconv library])],,
 385               [with_libiconv=maybe])
 386
 387   found_iconv=no
 388   case $with_libiconv in
 389     maybe)
 390       # Check in the C library first
 391       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 392       # Check if we have GNU libiconv
 393       if test $found_iconv = "no"; then
 394         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 395       fi
 396       # Check if we have a iconv in -liconv, possibly from vendor
 397       if test $found_iconv = "no"; then
 398         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 399       fi
 400       ;;
 401     no)
 402       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 403       ;;
 404     gnu|yes)
 405       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 406       ;;
 407     native)
 408       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 409       ;;
 410   esac
 411
 412   if test "x$found_iconv" = "xno" ; then
 413      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 414   fi
 415 fi
 416
 417 AC_ARG_ENABLE(iconv-cache,
 418               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 419                               [cache iconv descriptors [default=auto]])],,
 420               [enable_iconv_cache=auto])
 421
 422 AC_MSG_CHECKING([whether to cache iconv descriptors])
 423 case $enable_iconv_cache in
 424   auto)
 425     if test $ac_cv_gnu_library_2_1 = yes; then
 426       enable_iconv_cache=no
 427     else
 428       enable_iconv_cache=yes
 429     fi
 430   ;;
 431   yes|no)
 432   ;;
 433   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 434   ;;
 435 esac
 436
 437 if test $enable_iconv_cache = yes; then
 438    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 439 fi
 440
 441 AC_MSG_RESULT($enable_iconv_cache)
 442
 443
 444 dnl
 445 dnl zlib support
 446 dnl
 447 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 448 if test "x$found_zlib" = "xno" ; then
 449   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 450   if test "x$found_zlib" = "xno" ; then
 451     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 452   fi
 453   ZLIB_LIBS='-lz'
 454   AC_SUBST(ZLIB_LIBS)
 455 fi
 456
 457 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 458 AC_SUBST(LIBFFI_CFLAGS)
 459 AC_SUBST(LIBFFI_LIBS)
 460
 461 dnl
 462 dnl gettext support
 463 dnl
 464
 465 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 466 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 467 GLIB_GNU_GETTEXT
 468
 469 if test "$gt_cv_have_gettext" != "yes" ; then
 470   AC_MSG_ERROR([
 471 *** You must have either have gettext support in your C library, or use the
 472 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 473 ])
 474 fi
 475
 476 LIBS="$INTLLIBS $LIBS"
 477
 478 GETTEXT_PACKAGE=glib20
 479 AC_SUBST(GETTEXT_PACKAGE)
 480 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 481   [Define the gettext package to be used])
 482
 483 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 484
 485 dnl
 486 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 487 dnl
 488
 489 if test x"$glib_native_win32" != xyes; then
 490   if test x$with_libiconv != xno ; then
 491     case " $INTLLIBS " in
 492     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 493     *) ICONV_LIBS="-liconv" ;;
 494     esac
 495   fi
 496 fi
 497 AC_SUBST(ICONV_LIBS)
 498
 499 case $with_libiconv in
 500   gnu)
 501     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 502     ;;
 503   native)
 504     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 505     ;;
 506 esac
 507
 508 dnl Initialize libtool
 509 LT_PREREQ([2.2])
 510 LT_INIT([disable-static win32-dll])
 511 dnl when using libtool 2.x create libtool early, because it's used in configure
 512 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 513
 514
 515 if test "x$GCC" = "xyes"; then
 516   case " $CFLAGS " in
 517   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 518   *) CFLAGS="$CFLAGS -Wall" ;;
 519   esac
 520 fi
 521
 522 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 523
 524 if test "$glib_native_win32" = "yes"; then
 525   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 526     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 527   fi
 528   if test x$enable_static = xyes; then
 529     glib_win32_static_compilation=yes
 530     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 531 #define GOBJECT_STATIC_COMPILATION 1"
 532     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 533   fi
 534 fi
 535 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 536
 537 dnl
 538 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 539 dnl
 540 if test $cross_compiling != yes ; then
 541     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 542     glib_save_LIBS=$LIBS
 543     LIBS="$LIBS -lm"
 544     AC_TRY_RUN([#include <math.h>
 545                  int main (void) { return (log(1) != log(1.)); }],
 546          AC_MSG_RESULT(none needed),
 547          glib_save_CFLAGS=$CFLAGS
 548          CFLAGS="$CFLAGS -std1"
 549          AC_TRY_RUN([#include <math.h>
 550                      int main (void) { return (log(1) != log(1.)); }],
 551              AC_MSG_RESULT(-std1),
 552              AC_MSG_RESULT()
 553              CFLAGS=$glib_save_CFLAGS
 554              AC_MSG_WARN(
 555                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 556          )
 557     )
 558     LIBS=$glib_save_LIBS
 559 fi
 560
 561 dnl NeXTStep cc seems to need this
 562 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 563 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 564   AC_MSG_RESULT(none needed),
 565   glib_save_CFLAGS=$CFLAGS
 566   CFLAGS="$CFLAGS -posix"
 567   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 568     AC_MSG_RESULT(-posix),
 569     AC_MSG_RESULT()
 570     CFLAGS=$glib_save_CFLAGS
 571     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 572
 573 # Checks for header files.
 574 AC_HEADER_STDC
 575
 576 # Checks for library functions.
 577 AC_FUNC_VPRINTF
 578 AC_FUNC_ALLOCA
 579 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 580 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 581
 582 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 583 dnl be automatically defined, which we don't want to do
 584 dnl until we have checked this function is actually usable
 585 AC_CHECK_FUNC([qsort_r])
 586
 587 # BSD has a qsort_r with wrong argument order
 588 if test x$ac_cv_func_qsort_r = xyes ; then
 589   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 590   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 591   #define _GNU_SOURCE
 592   #include <stdlib.h>
 593
 594   static int
 595   cmp (const void *a, const void *b, void *c)
 596   {
 597     const int *ia = a;
 598     const int *ib = b;
 599
 600     if (*ia < *ib)
 601       return -1;
 602     else if (*ia > *ib)
 603       return 1;
 604     else
 605       return 0;
 606   }
 607
 608   int
 609   main (int argc, char **argv)
 610   {
 611     int arr[3] = { 1, 2, 0 };
 612     int d = 3;
 613
 614     qsort_r (arr, 3, sizeof (int), cmp, &d);
 615
 616     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 617       return 0;
 618     else
 619       return 1;
 620   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 621 fi
 622
 623 if test x$glib_cv_have_qsort_r = xyes ; then
 624   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 625 fi
 626
 627 AC_CHECK_SIZEOF(char)
 628 AC_CHECK_SIZEOF(short)
 629 AC_CHECK_SIZEOF(long)
 630 AC_CHECK_SIZEOF(int)
 631 AC_CHECK_SIZEOF(void *)
 632 AC_CHECK_SIZEOF(long long)
 633 AC_CHECK_SIZEOF(__int64)
 634
 635 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 636   :
 637 else
 638   AC_MSG_ERROR([
 639 *** GLib requires a 64 bit type. You might want to consider
 640 *** using the GNU C compiler.
 641 ])
 642 fi
 643
 644 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 645         # long long is a 64 bit integer.
 646         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 647         AC_CACHE_VAL(glib_cv_long_long_format,[
 648                 for format in ll q I64; do
 649                   AC_TRY_RUN([#include <stdio.h>
 650                         int main()
 651                         {
 652                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 653                           char buffer[1000];
 654                           sprintf (buffer, "%${format}u", a);
 655                           sscanf (buffer, "%${format}u", &b);
 656                           exit (b!=a);
 657                         }
 658                         ],
 659                         [glib_cv_long_long_format=${format}
 660                         break],
 661                         [],[:])
 662                 done])
 663         if test -n "$glib_cv_long_long_format"; then
 664           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 665           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 666           if test x"$glib_cv_long_long_format" = xI64; then
 667             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 668           fi
 669         else
 670           AC_MSG_RESULT(none)
 671         fi
 672 elif test x$ac_cv_sizeof___int64 = x8; then
 673         # __int64 is a 64 bit integer.
 674         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 675         # We know this is MSVCRT.DLL, and what the formats are
 676         glib_cv_long_long_format=I64
 677         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 678         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 679         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 680 fi
 681
 682 dnl long doubles were not used, and a portability problem
 683 dnl AC_C_LONG_DOUBLE
 684 AC_C_CONST
 685
 686 dnl ok, here we try to check whether the systems prototypes for
 687 dnl malloc and friends actually match the prototypes provided
 688 dnl by gmem.h (keep in sync). i currently only know how to check
 689 dnl this reliably with gcc (-Werror), improvements for other
 690 dnl compilers are apprechiated.
 691 SANE_MALLOC_PROTOS=no
 692 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 693 glib_save_CFLAGS=$CFLAGS
 694 if test "x$GCC" = "xyes"; then
 695   CFLAGS="$CFLAGS -Werror"
 696   AC_TRY_COMPILE([#include <stdlib.h>], [
 697     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 698     void* (*my_malloc_p)  (size_t)         = malloc;
 699     void  (*my_free_p)    (void*)          = free;
 700     void* (*my_realloc_p) (void*, size_t)  = realloc;
 701     my_calloc_p = 0;
 702     my_malloc_p = 0;
 703     my_free_p = 0;
 704     my_realloc_p = 0;
 705   ],
 706     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 707       [Define if you have correct malloc prototypes])
 708     SANE_MALLOC_PROTOS=yes)
 709 fi
 710 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 711 CFLAGS=$glib_save_CFLAGS
 712
 713 dnl
 714 dnl check in which direction the stack grows
 715 dnl
 716 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 717         AC_TRY_RUN([
 718         volatile int *a = 0, *b = 0;
 719         void foo (void);
 720         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 721         void foo (void) { volatile int x = 5; b = &x; }
 722         ],
 723         glib_cv_stack_grows=no
 724         ,
 725         glib_cv_stack_grows=yes
 726         ,)
 727 ])
 728
 729 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 730 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 731 dnl actually supported.
 732 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 733         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 734         __inline int foo () { return 0; }
 735         int main () { return foo (); }
 736         ]])],
 737         glib_cv_has__inline=yes
 738         ,
 739         glib_cv_has__inline=no
 740         ,)
 741 ])
 742 case x$glib_cv_has__inline in
 743 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 744 esac
 745 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 746         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 747         __inline__ int foo () { return 0; }
 748         int main () { return foo (); }
 749         ]])],
 750         glib_cv_has__inline__=yes
 751         ,
 752         glib_cv_has__inline__=no
 753         ,)
 754 ])
 755 case x$glib_cv_has__inline__ in
 756 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 757 esac
 758 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 759         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 760         #undef inline
 761         inline int foo () { return 0; }
 762         int main () { return foo (); }
 763         ]])],
 764         glib_cv_hasinline=yes
 765         ,
 766         glib_cv_hasinline=no
 767         ,)
 768 ])
 769 case x$glib_cv_hasinline in
 770 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 771 esac
 772
 773 # if we can use inline functions in headers
 774 AC_MSG_CHECKING(if inline functions in headers work)
 775 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 776 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 777 #  undef inline
 778 #  define inline __inline__
 779 #elif !defined (G_HAVE_INLINE)
 780 #  undef inline
 781 #  if defined (G_HAVE___INLINE__)
 782 #    define inline __inline__
 783 #  elif defined (G_HAVE___INLINE)
 784 #    define inline __inline
 785 #  endif
 786 #endif
 787
 788 int glib_test_func2 (int);
 789
 790 static inline int
 791 glib_test_func1 (void) {
 792   return glib_test_func2 (1);
 793 }
 794
 795 int
 796 main (void) {
 797   int i = 1;
 798 }]])],[g_can_inline=yes],[g_can_inline=no])
 799 AC_MSG_RESULT($g_can_inline)
 800
 801 dnl *** check for working do while(0) macros ***
 802 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 803         AC_TRY_COMPILE([],[
 804         #define STMT_START do
 805         #define STMT_END while(0)
 806         #define STMT_TEST STMT_START { i = 0; } STMT_END
 807         int main(void) { int i = 1; STMT_TEST; return i; }],
 808         [g_cv_support_dowhile_macros=yes],
 809         [g_cv_support_dowhile_macros=no],
 810         [g_cv_support_dowhile_macros=yes])
 811 ])
 812 if test x$g_cv_support_dowhile_macros = xyes; then
 813   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 814 fi
 815
 816 # check for flavours of varargs macros
 817 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 818 AC_TRY_COMPILE([],[
 819 int a(int p1, int p2, int p3);
 820 #define call_a(...) a(1,__VA_ARGS__)
 821 call_a(2,3);
 822 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 823 AC_MSG_RESULT($g_have_iso_c_varargs)
 824
 825 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 826 if test "$CXX" = ""; then
 827 dnl No C++ compiler
 828   g_have_iso_cxx_varargs=no
 829 else
 830   AC_LANG_CPLUSPLUS
 831   AC_TRY_COMPILE([],[
 832 int a(int p1, int p2, int p3);
 833 #define call_a(...) a(1,__VA_ARGS__)
 834 call_a(2,3);
 835 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 836   AC_LANG_C
 837 fi
 838 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 839
 840 AC_MSG_CHECKING(for GNUC varargs macros)
 841 AC_TRY_COMPILE([],[
 842 int a(int p1, int p2, int p3);
 843 #define call_a(params...) a(1,params)
 844 call_a(2,3);
 845 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 846 AC_MSG_RESULT($g_have_gnuc_varargs)
 847
 848 # check for GNUC visibility support
 849 AC_MSG_CHECKING(for GNUC visibility attribute)
 850 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 851 void
 852 __attribute__ ((visibility ("hidden")))
 853      f_hidden (void)
 854 {
 855 }
 856 void
 857 __attribute__ ((visibility ("internal")))
 858      f_internal (void)
 859 {
 860 }
 861 void
 862 __attribute__ ((visibility ("protected")))
 863      f_protected (void)
 864 {
 865 }
 866 void
 867 __attribute__ ((visibility ("default")))
 868      f_default (void)
 869 {
 870 }
 871 int main (int argc, char **argv)
 872 {
 873         f_hidden();
 874         f_internal();
 875         f_protected();
 876         f_default();
 877         return 0;
 878 }
 879 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 880 AC_MSG_RESULT($g_have_gnuc_visibility)
 881 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 882
 883 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 884 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 885 #else
 886 # include "error: this is not Sun Studio."
 887 #endif
 888 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 889 AC_MSG_RESULT($g_have_sunstudio_visibility)
 890 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 891
 892 # check for bytesex stuff
 893 AC_C_BIGENDIAN
 894 if test x$ac_cv_c_bigendian = xuniversal ; then
 895 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 896 #else
 897 #error Not a big endian.
 898 #endif],
 899     ac_cv_c_bigendian=yes
 900     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 901 #else
 902 #error Not a little endian.
 903 #endif],
 904     ac_cv_c_bigendian=no
 905     ,AC_MSG_WARN([Could not determine endianness.])))
 906 fi
 907
 908
 909 # check for header files
 910 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 911 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 912 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 913 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 914 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 915 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 916 AC_CHECK_HEADERS([linux/magic.h])
 917
 918 # check for structure fields
 919 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 920 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 921 #include <sys/stat.h>
 922 #include <unistd.h>
 923 #ifdef HAVE_SYS_STATFS_H
 924 #include <sys/statfs.h>
 925 #endif
 926 #ifdef HAVE_SYS_PARAM_H
 927 #include <sys/param.h>
 928 #endif
 929 #ifdef HAVE_SYS_MOUNT_H
 930 #include <sys/mount.h>
 931 #endif])
 932 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 933 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 934 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 935
 936 # Checks for libcharset
 937 AM_LANGINFO_CODESET
 938 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 939 AC_CHECK_FUNCS(setlocale)
 940
 941 # check additional type sizes
 942 AC_CHECK_SIZEOF(size_t)
 943
 944 dnl Try to figure out whether gsize, gssize should be long or int
 945 AC_MSG_CHECKING([for the appropriate definition for size_t])
 946
 947 case $ac_cv_sizeof_size_t in
 948   $ac_cv_sizeof_short)
 949       glib_size_type=short
 950       ;;
 951   $ac_cv_sizeof_int)
 952       glib_size_type=int
 953       ;;
 954   $ac_cv_sizeof_long)
 955       glib_size_type=long
 956       ;;
 957   $ac_cv_sizeof_long_long)
 958       glib_size_type='long long'
 959       ;;
 960   $ac_cv_sizeof__int64)
 961       glib_size_type='__int64'
 962       ;;
 963   *)  AC_MSG_ERROR([No type matching size_t in size])
 964       ;;
 965 esac
 966
 967 dnl If int/long are the same size, we see which one produces
 968 dnl warnings when used in the location as size_t. (This matters
 969 dnl on AIX with xlc)
 970 dnl
 971 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 972    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 973   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 974 #if defined(_AIX) && !defined(__GNUC__)
 975 #pragma options langlvl=stdc89
 976 #endif
 977 #include <stddef.h>
 978 int main ()
 979 {
 980   size_t s = 1;
 981   unsigned int *size_int = &s;
 982   return (int)*size_int;
 983 }
 984     ]])],glib_size_type=int,
 985       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 986 #if defined(_AIX) && !defined(__GNUC__)
 987 #pragma options langlvl=stdc89
 988 #endif
 989 #include <stddef.h>
 990 int main ()
 991 {
 992    size_t s = 1;
 993    unsigned long *size_long = &s;
 994    return (int)*size_long;
 995 }
 996         ]])],glib_size_type=long)])
 997 fi
 998
 999 AC_MSG_RESULT(unsigned $glib_size_type)
1000
1001 # Check for some functions
1002 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1003 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1004 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getmntinfo)
1005 # Check for high-resolution sleep functions
1006 AC_CHECK_FUNCS(splice)
1007
1008 # To avoid finding a compatibility unusable statfs, which typically
1009 # successfully compiles, but warns to use the newer statvfs interface:
1010 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1011 AS_IF([test $ac_cv_header_sys_statfs_h  = yes], [AC_CHECK_FUNCS([statfs])])
1012
1013 AC_MSG_CHECKING([whether to use statfs or statvfs])
1014 # Some systems have both statfs and statvfs, pick the most "native" for these
1015 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1016    [
1017    # on solaris and irix, statfs doesn't even have the f_bavail field
1018    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1019       [ac_cv_func_statfs=no],
1020    # else, at least on linux, statfs is the actual syscall
1021       [ac_cv_func_statvfs=no])
1022    ])
1023
1024 AS_IF([test x$ac_cv_func_statfs = xyes],
1025       [
1026          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1027          AC_MSG_RESULT([statfs])
1028       ],
1029       [test x$ac_cv_func_statvfs = xyes],
1030       [
1031          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1032          AC_MSG_RESULT([statvfs])
1033       ],
1034       [  AC_MSG_RESULT([neither])])
1035
1036 AC_CHECK_HEADERS(crt_externs.h)
1037 AC_CHECK_FUNCS(_NSGetEnviron)
1038
1039 AC_FUNC_VSNPRINTF_C99
1040 AC_FUNC_PRINTF_UNIX98
1041
1042 # Internet address families
1043 if test $glib_native_win32 = yes; then
1044   glib_inet_includes=["
1045 #include <winsock2.h>
1046   "]
1047 else
1048   glib_inet_includes=["
1049 #include <sys/types.h>
1050 #include <sys/socket.h>
1051   "]
1052 fi
1053
1054 glib_failed=false
1055 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1056 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1057 # winsock defines this even though it doesn't support it
1058 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1059 if $glib_failed ; then
1060   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1061 fi
1062
1063 glib_failed=false
1064 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1065 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1066 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1067 if $glib_failed ; then
1068   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1069 fi
1070
1071 AC_CHECK_FUNCS(getprotobyname_r endservent)
1072 AC_CHECK_HEADERS([netdb.h wspiapi.h])
1073
1074 # For gio/libasyncns
1075 if test $glib_native_win32 = no; then
1076   AC_CHECK_FUNCS(strndup setresuid setreuid)
1077   AC_CHECK_HEADERS(sys/prctl.h arpa/nameser_compat.h)
1078
1079   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1080   AC_MSG_CHECKING([for res_query])
1081   AC_TRY_LINK([#include <sys/types.h>
1082 #include <netinet/in.h>
1083 #include <arpa/nameser.h>
1084 #include <resolv.h>],
1085               [res_query("test", 0, 0, (void *)0, 0);],
1086               [AC_MSG_RESULT([yes])],
1087               [save_libs="$LIBS"
1088                LIBS="-lresolv $LIBS"
1089                AC_TRY_LINK([#include <sys/types.h>
1090 #include <netinet/in.h>
1091 #include <arpa/nameser.h>
1092 #include <resolv.h>],
1093                            [res_query("test", 0, 0, (void *)0, 0);],
1094                            [AC_MSG_RESULT([in -lresolv])
1095                             LIBASYNCNS_LIBADD="-lresolv"],
1096                            [LIBS="-lbind $save_libs"
1097                             AC_TRY_LINK([#include <resolv.h>],
1098                                         [res_query("test", 0, 0, (void *)0, 0);],
1099                                         [AC_MSG_RESULT([in -lbind])
1100                                          LIBASYNCNS_LIBADD="-lbind"],
1101                                         [AC_MSG_ERROR(not found)])])
1102                LIBS="$save_libs"])
1103   AC_SUBST(LIBASYNCNS_LIBADD)
1104 fi
1105
1106 case $host in
1107   *-*-solaris* )
1108      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1109      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1110      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1111      ;;
1112 esac
1113
1114 dnl
1115 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1116 dnl
1117 if test "$ac_cv_func_statfs" = yes ; then
1118   AC_MSG_CHECKING([number of arguments to statfs()])
1119   AC_TRY_COMPILE([#include <unistd.h>
1120   #ifdef HAVE_SYS_PARAM_H
1121   #include <sys/param.h>
1122   #endif
1123   #ifdef HAVE_SYS_VFS_H
1124   #include <sys/vfs.h>
1125   #endif
1126   #ifdef HAVE_SYS_MOUNT_H
1127   #include <sys/mount.h>
1128   #endif
1129   #ifdef HAVE_SYS_STATFS_H
1130   #include <sys/statfs.h>
1131   #endif], [struct statfs st;
1132   statfs(NULL, &st);],[
1133     AC_MSG_RESULT([2])
1134     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1135     AC_TRY_COMPILE([#include <unistd.h>
1136   #ifdef HAVE_SYS_PARAM_H
1137   #include <sys/param.h>
1138   #endif
1139   #ifdef HAVE_SYS_VFS_H
1140   #include <sys/vfs.h>
1141   #endif
1142   #ifdef HAVE_SYS_MOUNT_H
1143   #include <sys/mount.h>
1144   #endif
1145   #ifdef HAVE_SYS_STATFS_H
1146   #include <sys/statfs.h>
1147   #endif], [struct statfs st;
1148   statfs(NULL, &st, sizeof (st), 0);],[
1149       AC_MSG_RESULT([4])
1150       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1151       AC_MSG_RESULT(unknown)
1152       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1153 fi
1154
1155 #
1156 # Check whether to use an included printf
1157 #
1158
1159 AC_ARG_ENABLE(included-printf,
1160               [AC_HELP_STRING([--enable-included-printf],
1161                               [use included printf [default=auto]])],
1162               enable_included_printf="$enableval")
1163
1164 need_included_printf=no
1165 if test "x$enable_included_printf" = "xyes" ; then
1166   need_included_printf=yes
1167 fi
1168 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1169   need_included_printf=yes
1170 fi
1171 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1172   need_included_printf=yes
1173 fi
1174 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1175    test -z "$glib_cv_long_long_format" ; then
1176   need_included_printf=yes
1177 fi
1178
1179 if test "x$enable_included_printf" = "xno" &&
1180    test "x$need_included_printf" = "xyes" ; then
1181   AC_MSG_ERROR([
1182 *** Your C library's printf doesn't appear to have the features that
1183 *** GLib needs, but you specified --enable-included-printf=no.])
1184 fi
1185
1186 enable_included_printf=$need_included_printf
1187
1188 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1189 if test "$enable_included_printf" != "yes" ; then
1190   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1191 else
1192   if test -z "$glib_cv_long_long_format" ; then
1193     glib_cv_long_long_format="ll"
1194   fi
1195   AC_DEFINE(HAVE_VASPRINTF,1)
1196 fi
1197
1198 # Checks needed for gnulib vasnprintf
1199 bh_C_SIGNED
1200 jm_AC_TYPE_LONG_LONG
1201 gt_TYPE_LONGDOUBLE
1202 gt_TYPE_WCHAR_T
1203 gt_TYPE_WINT_T
1204 AC_TYPE_SIZE_T
1205 AC_CHECK_TYPES(ptrdiff_t)
1206 jm_AC_TYPE_INTMAX_T
1207 AC_CHECK_FUNCS([snprintf wcslen])
1208 AC_FUNC_SNPRINTF_C99
1209
1210 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1211 # The check is borrowed from the PERL Configure script.
1212 if test "$ac_cv_func_memmove" != "yes"; then
1213   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1214     glib_cv_working_bcopy,[AC_TRY_RUN([
1215       int main() {
1216         char buf[128], abc[128], *b;
1217         int len, off, align;
1218         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1219         for (align = 7; align >= 0; align--) {
1220           for (len = 36; len; len--) {
1221             b = buf+align; bcopy(abc, b, len);
1222             for (off = 1; off <= len; off++) {
1223               bcopy(b, b+off, len); bcopy(b+off, b, len);
1224                 if (bcmp(b, abc, len)) return(1);
1225             }
1226           }
1227         }
1228         return(0);
1229       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1230
1231   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1232   if test "$glib_cv_working_bcopy" = "yes"; then
1233     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1234   fi
1235 fi
1236
1237 # Check for sys_errlist
1238 AC_MSG_CHECKING(for sys_errlist)
1239 AC_TRY_LINK(, [
1240 extern char *sys_errlist[];
1241 extern int sys_nerr;
1242 sys_errlist[sys_nerr-1][0] = 0;
1243 ], glib_ok=yes, glib_ok=no)
1244 AC_MSG_RESULT($glib_ok)
1245 if test "$glib_ok" = "no"; then
1246     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1247 fi
1248
1249 # Check for sys_siglist
1250 AC_MSG_CHECKING(for sys_siglist)
1251 AC_TRY_LINK(, [
1252 extern char *sys_siglist[];
1253 exit (sys_siglist[0]);
1254 ], glib_ok=yes, glib_ok=no)
1255 AC_MSG_RESULT($glib_ok)
1256 if test "$glib_ok" = "no"; then
1257     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1258 fi
1259
1260 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1261 AC_MSG_CHECKING(for sys_siglist declaration)
1262 AC_TRY_COMPILE([#include <signal.h>], [
1263 strlen (sys_siglist[0]);
1264 ], glib_ok=yes, glib_ok=no)
1265 AC_MSG_RESULT($glib_ok)
1266 if test "$glib_ok" = "no"; then
1267     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1268 fi
1269
1270 # Check if <sys/select.h> needs to be included for fd_set
1271 AC_MSG_CHECKING([for fd_set])
1272 AC_TRY_COMPILE([#include <sys/types.h>],
1273         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1274 if test "$gtk_ok" = "yes"; then
1275     AC_MSG_RESULT([yes, found in sys/types.h])
1276 else
1277     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1278     if test "$gtk_ok" = "yes"; then
1279         # *** FIXME: give it a different name
1280         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1281         AC_MSG_RESULT([yes, found in sys/select.h])
1282     else
1283         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1284         AC_MSG_RESULT(no)
1285     fi
1286 fi
1287
1288 dnl *** check for sane realloc() ***
1289 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1290         AC_TRY_RUN([#include <stdlib.h>
1291         int main() {
1292           return realloc (0, sizeof (int)) == 0;
1293         }],
1294         [glib_cv_sane_realloc=yes],
1295         [glib_cv_sane_realloc=no],
1296         [glib_cv_sane_realloc=yes])
1297 ])
1298 if test x$glib_cv_sane_realloc = xyes; then
1299   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1300 fi
1301
1302 dnl Check for nl_langinfo and CODESET
1303 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1304         AC_TRY_COMPILE([#include <langinfo.h>],
1305                 [char *codeset = nl_langinfo (CODESET);],
1306                 [glib_cv_langinfo_codeset=yes],
1307                 [glib_cv_langinfo_codeset=no])])
1308 if test x$glib_cv_langinfo_codeset = xyes; then
1309   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1310 fi
1311
1312 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1313 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1314         AC_TRY_COMPILE([#include <langinfo.h>],
1315                 [char *str;
1316                  str = nl_langinfo (PM_STR);
1317                  str = nl_langinfo (D_FMT);
1318                  str = nl_langinfo (T_FMT);
1319                  str = nl_langinfo (MON_1);
1320                  str = nl_langinfo (ABMON_12);
1321                  str = nl_langinfo (DAY_1);
1322                  str = nl_langinfo (ABDAY_7);],
1323                 [glib_cv_langinfo_time=yes],
1324                 [glib_cv_langinfo_time=no])])
1325 if test x$glib_cv_langinfo_time = xyes; then
1326   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1327 fi
1328
1329 dnl ****************************************
1330 dnl *** posix_memalign                   ***
1331 dnl ****************************************
1332 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1333 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1334     glib_cv_compliant_posix_memalign=0
1335     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1336         AC_TRY_RUN([
1337                 #define _XOPEN_SOURCE 600
1338                 #include <stdlib.h> /* posix_memalign() should be defined here */
1339                 /* some systems break if #include <malloc.h> used */
1340                 static void test_memalign (size_t boundary, size_t size) {
1341                     void *mem = 0;
1342                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1343                         exit (1);
1344                     else
1345                       free (mem);
1346                 }
1347                 int main() {
1348                     test_memalign (  128,   128 - 2 * sizeof (void*));
1349                     test_memalign (  256,   256 - 2 * sizeof (void*));
1350                     test_memalign (  512,   512 - 2 * sizeof (void*));
1351                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1352                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1353                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1354                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1355                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1356                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1357                     exit (0); /* success */
1358                 }
1359                 ],
1360             [glib_cv_compliant_posix_memalign=1], [], [:])
1361       :
1362     fi
1363     ])
1364 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1365     AC_MSG_RESULT(yes)
1366     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1367 else
1368     AC_MSG_RESULT(no)
1369 fi
1370
1371
1372 dnl ****************************************
1373 dnl *** strlcpy/strlcat                  ***
1374 dnl ****************************************
1375 # Check for strlcpy
1376 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1377 AC_TRY_RUN([#include <stdlib.h>
1378 #include <string.h>
1379 int main() {
1380   char p[10];
1381   (void) strlcpy (p, "hi", 10);
1382   if (strlcat (p, "bye", 0) != 3)
1383     return 1;
1384   return 0;
1385 }], glib_cv_have_strlcpy=yes,
1386     glib_cv_have_strlcpy=no,
1387     glib_cv_have_strlcpy=no)])
1388 if test "$glib_cv_have_strlcpy" = "yes"; then
1389     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1390 fi
1391
1392
1393 dnl **********************
1394 dnl *** va_copy checks ***
1395 dnl **********************
1396 dnl we currently check for all three va_copy possibilities, so we get
1397 dnl all results in config.log for bug reports.
1398 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1399         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1400 #include <stdlib.h>
1401         void f (int i, ...) {
1402         va_list args1, args2;
1403         va_start (args1, i);
1404         va_copy (args2, args1);
1405         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1406           exit (1);
1407         va_end (args1); va_end (args2);
1408         }
1409         int main() {
1410           f (0, 42);
1411           return 0;
1412         }]])],
1413         [glib_cv_va_copy=yes],
1414         [glib_cv_va_copy=no])
1415 ])
1416 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1417         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1418 #include <stdlib.h>
1419         void f (int i, ...) {
1420         va_list args1, args2;
1421         va_start (args1, i);
1422         __va_copy (args2, args1);
1423         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1424           exit (1);
1425         va_end (args1); va_end (args2);
1426         }
1427         int main() {
1428           f (0, 42);
1429           return 0;
1430         }]])],
1431         [glib_cv___va_copy=yes],
1432         [glib_cv___va_copy=no])
1433 ])
1434
1435 if test "x$glib_cv_va_copy" = "xyes"; then
1436   g_va_copy_func=va_copy
1437 else if test "x$glib_cv___va_copy" = "xyes"; then
1438   g_va_copy_func=__va_copy
1439 fi
1440 fi
1441
1442 if test -n "$g_va_copy_func"; then
1443   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1444 fi
1445
1446 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1447         AC_TRY_RUN([#include <stdarg.h>
1448 #include <stdlib.h>
1449         void f (int i, ...) {
1450         va_list args1, args2;
1451         va_start (args1, i);
1452         args2 = args1;
1453         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1454           exit (1);
1455         va_end (args1); va_end (args2);
1456         }
1457         int main() {
1458           f (0, 42);
1459           return 0;
1460         }],
1461         [glib_cv_va_val_copy=yes],
1462         [glib_cv_va_val_copy=no],
1463         [glib_cv_va_val_copy=yes])
1464 ])
1465
1466 if test "x$glib_cv_va_val_copy" = "xno"; then
1467   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1468 fi
1469
1470 dnl ***********************
1471 dnl *** g_module checks ***
1472 dnl ***********************
1473 G_MODULE_LIBS=
1474 G_MODULE_LIBS_EXTRA=
1475 G_MODULE_PLUGIN_LIBS=
1476 if test x"$glib_native_win32" = xyes; then
1477   dnl No use for this on Win32
1478   G_MODULE_LDFLAGS=
1479 else
1480   export SED
1481   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1482 fi
1483 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1484 G_MODULE_NEED_USCORE=0
1485 G_MODULE_BROKEN_RTLD_GLOBAL=0
1486 G_MODULE_HAVE_DLERROR=0
1487 dnl *** force native WIN32 shared lib loader
1488 if test -z "$G_MODULE_IMPL"; then
1489   case "$host" in
1490   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1491   esac
1492 fi
1493 dnl *** force native AIX library loader
1494 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1495 if test -z "$G_MODULE_IMPL"; then
1496   case "$host" in
1497   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1498   esac
1499 fi
1500 dnl *** dlopen() and dlsym() in system libraries
1501 if test -z "$G_MODULE_IMPL"; then
1502         AC_CHECK_FUNC(dlopen,
1503                       [AC_CHECK_FUNC(dlsym,
1504                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1505                       [])
1506 fi
1507 dnl *** load_image (BeOS)
1508 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1509   AC_CHECK_LIB(root, load_image,
1510       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1511       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1512       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1513       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1514       [])
1515 fi
1516 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1517 if test -z "$G_MODULE_IMPL"; then
1518         AC_CHECK_FUNC(NSLinkModule,
1519                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1520                        G_MODULE_NEED_USCORE=1],
1521                       [])
1522 fi
1523 dnl *** dlopen() and dlsym() in libdl
1524 if test -z "$G_MODULE_IMPL"; then
1525         AC_CHECK_LIB(dl, dlopen,
1526                      [AC_CHECK_LIB(dl, dlsym,
1527                                    [G_MODULE_LIBS=-ldl
1528                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1529                      [])
1530 fi
1531 dnl *** shl_load() in libdld (HP-UX)
1532 if test -z "$G_MODULE_IMPL"; then
1533         AC_CHECK_LIB(dld, shl_load,
1534                 [G_MODULE_LIBS=-ldld
1535                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1536                 [])
1537 fi
1538 dnl *** additional checks for G_MODULE_IMPL_DL
1539 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1540         LIBS_orig="$LIBS"
1541         LDFLAGS_orig="$LDFLAGS"
1542         LIBS="$G_MODULE_LIBS $LIBS"
1543         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1544 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1545         echo "void glib_plugin_test(void) { }" > plugin.c
1546         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1547                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1548         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1549                 glib_cv_rtldglobal_broken,[
1550                 AC_TRY_RUN([
1551 #include <dlfcn.h>
1552 #ifndef RTLD_GLOBAL
1553 #  define RTLD_GLOBAL 0
1554 #endif
1555 #ifndef RTLD_LAZY
1556 #  define RTLD_LAZY 0
1557 #endif
1558 int glib_plugin_test;
1559 int main () {
1560     void *handle, *global, *local;
1561     global = &glib_plugin_test;
1562     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1563     if (!handle) return 0;
1564     local = dlsym (handle, "glib_plugin_test");
1565     return global == local;
1566 }                       ],
1567                         [glib_cv_rtldglobal_broken=no],
1568                         [glib_cv_rtldglobal_broken=yes],
1569                         [glib_cv_rtldglobal_broken=no])
1570                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1571                 rmdir .libs 2>/dev/null
1572         ])
1573         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1574                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1575         else
1576                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1577         fi
1578 dnl *** check whether we need preceeding underscores
1579         AC_CACHE_CHECK([for preceeding underscore in symbols],
1580                 glib_cv_uscore,[
1581                 AC_TRY_RUN([#include <dlfcn.h>
1582                 int glib_underscore_test (void) { return 42; }
1583                 int main() {
1584                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1585                   handle = dlopen ((void*)0, 0);
1586                   if (handle) {
1587                     f1 = dlsym (handle, "glib_underscore_test");
1588                     f2 = dlsym (handle, "_glib_underscore_test");
1589                   } return (!f2 || f1);
1590                 }],
1591                         [glib_cv_uscore=yes],
1592                         [glib_cv_uscore=no],
1593                         [])
1594                 rm -f plugin.c plugin.$ac_objext plugin.lo
1595         ])
1596         GLIB_ASSERT_SET(glib_cv_uscore)
1597         if test "x$glib_cv_uscore" = "xyes"; then
1598                 G_MODULE_NEED_USCORE=1
1599         else
1600                 G_MODULE_NEED_USCORE=0
1601         fi
1602
1603         LDFLAGS="$LDFLAGS_orig"
1604 dnl *** check for having dlerror()
1605         AC_CHECK_FUNC(dlerror,
1606                 [G_MODULE_HAVE_DLERROR=1],
1607                 [G_MODULE_HAVE_DLERROR=0])
1608         LIBS="$LIBS_orig"
1609 fi
1610 dnl *** done, have we got an implementation?
1611 if test -z "$G_MODULE_IMPL"; then
1612         G_MODULE_IMPL=0
1613         G_MODULE_SUPPORTED=false
1614 else
1615         G_MODULE_SUPPORTED=true
1616 fi
1617
1618 AC_MSG_CHECKING(for the suffix of module shared libraries)
1619 export SED
1620 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1621 eval $shrext_cmds
1622 module=yes eval std_shrext=$shrext_cmds
1623 # chop the initial dot
1624 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1625 AC_MSG_RESULT(.$glib_gmodule_suffix)
1626 # any reason it may fail?
1627 if test "x$glib_gmodule_suffix" = x; then
1628         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1629 fi
1630
1631 AC_SUBST(G_MODULE_SUPPORTED)
1632 AC_SUBST(G_MODULE_IMPL)
1633 AC_SUBST(G_MODULE_LIBS)
1634 AC_SUBST(G_MODULE_LIBS_EXTRA)
1635 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1636 AC_SUBST(G_MODULE_LDFLAGS)
1637 AC_SUBST(G_MODULE_HAVE_DLERROR)
1638 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1639 AC_SUBST(G_MODULE_NEED_USCORE)
1640 AC_SUBST(GLIB_DEBUG_FLAGS)
1641
1642 dnl **********************
1643 dnl *** g_spawn checks ***
1644 dnl **********************
1645
1646 AC_MSG_CHECKING(for gspawn implementation)
1647 case "$host" in
1648   *-*-mingw*)
1649     GSPAWN=gspawn-win32.lo
1650     ;;
1651   *)
1652     GSPAWN=gspawn.lo
1653     ;;
1654 esac
1655 AC_MSG_RESULT($GSPAWN)
1656 AC_SUBST(GSPAWN)
1657
1658 dnl *************************
1659 dnl *** GIOChannel checks ***
1660 dnl *************************
1661
1662 AC_MSG_CHECKING(for GIOChannel implementation)
1663 case "$host" in
1664   *-*-mingw*)
1665     GIO=giowin32.lo
1666     ;;
1667   *)
1668     GIO=giounix.lo
1669     ;;
1670 esac
1671 AC_MSG_RESULT($GIO)
1672 AC_SUBST(GIO)
1673
1674 dnl *********************************
1675 dnl *** Directory for GIO modules ***
1676 dnl *********************************
1677
1678 AC_ARG_WITH(gio-module-dir,
1679            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1680                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1681            [],
1682            [with_gio_module_dir='${libdir}/gio/modules'])
1683 GIO_MODULE_DIR=$with_gio_module_dir
1684 AC_SUBST(GIO_MODULE_DIR)
1685
1686 dnl **********************************
1687 dnl *** Check for libselinux (GIO) ***
1688 dnl **********************************
1689 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1690 msg_selinux=no
1691 SELINUX_LIBS=
1692 if test "x$enable_selinux" != "xno"; then
1693
1694  AC_CHECK_LIB(selinux, is_selinux_enabled,
1695    [AC_CHECK_HEADERS(selinux/selinux.h,
1696      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1697        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1698         SELINUX_LIBS="-lselinux"
1699         msg_selinux=yes])
1700      ])
1701    ])
1702 fi
1703 AC_SUBST(SELINUX_LIBS)
1704
1705 dnl *****************************
1706 dnl ** Check for inotify (GIO) **
1707 dnl *****************************
1708 inotify_support=no
1709 AC_CHECK_HEADERS([sys/inotify.h],
1710 [
1711         inotify_support=yes
1712         AC_CHECK_FUNCS(inotify_init1)
1713 ])
1714
1715 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1716
1717 dnl *********************************
1718 dnl ** Check for Solaris FEN (GIO) **
1719 dnl *********************************
1720 fen_support=no
1721 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1722 #include <port.h>
1723 #ifndef PORT_SOURCE_FILE
1724 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1725 #endif
1726 int main() { return 0; } ]])],
1727 [
1728         fen_support=yes
1729 ],)
1730
1731 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1732
1733 dnl ****************************
1734 dnl *** Checks for FAM (GIO) ***
1735 dnl ****************************
1736
1737 should_disable_fam=no
1738
1739 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1740                          [
1741                                 if test "x$enable_fam" = "xno"; then
1742                                         should_disable_fam=yes
1743                                         echo "Not building FAM support"
1744                                 fi
1745                          ]
1746                          )
1747 fam_support=no
1748 FAM_LIBS=
1749 if test "x$should_disable_fam" = "xno"; then
1750 AC_CHECK_LIB(fam, FAMOpen,
1751   [AC_CHECK_HEADERS(fam.h,
1752     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1753      AC_CHECK_LIB(fam, FAMNoExists,
1754                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1755      FAM_LIBS="-lfam"]
1756      fam_support=yes,
1757     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1758   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1759 AC_SUBST(FAM_LIBS)
1760 fi
1761 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1762
1763
1764 dnl *****************************
1765 dnl *** Check for xattr (GIO) ***
1766 dnl *****************************
1767 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1768 msg_xattr=no
1769 XATTR_LIBS=
1770 if test "x$enable_xattr" != "xno"; then
1771
1772 dnl either glibc or libattr can provide xattr support
1773
1774 dnl for both of them, we check for getxattr being in
1775 dnl the library and a valid xattr header.
1776
1777 dnl try glibc
1778  AC_CHECK_LIB(c, getxattr,
1779    [AC_CHECK_HEADERS(sys/xattr.h,
1780      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1781       msg_xattr=yes])
1782    ])
1783
1784   if test "x$msg_xattr" != "xyes"; then
1785 dnl   failure. try libattr
1786    AC_CHECK_LIB(attr, getxattr,
1787       [AC_CHECK_HEADERS(attr/xattr.h,
1788        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1789         XATTR_LIBS="-lattr"
1790         msg_xattr=yes])
1791       ])
1792   fi
1793
1794   if test "x$msg_xattr" = "xyes"; then
1795     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1796     AC_TRY_COMPILE([
1797       #include <stdio.h>
1798       #ifdef HAVE_SYS_TYPES_H
1799       #include <sys/types.h>
1800       #endif
1801       #ifdef HAVE_SYS_XATTR_H
1802       #include <sys/xattr.h>
1803       #elif HAVE_ATTR_XATTR_H
1804       #include <attr/xattr.h>
1805       #endif
1806     ],
1807     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1808     [
1809       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1810       AC_MSG_RESULT([yes])
1811     ],
1812     [AC_MSG_RESULT([no])]
1813     )
1814   fi
1815
1816 fi
1817 AC_SUBST(XATTR_LIBS)
1818
1819 dnl ****************************************
1820 dnl *** platform dependent source checks ***
1821 dnl ****************************************
1822
1823 AC_MSG_CHECKING(for platform-dependent source)
1824 case "$host" in
1825   *-*-cygwin*|*-*-mingw*)
1826     PLATFORMDEP=gwin32.lo
1827     ;;
1828   *)
1829     PLATFORMDEP=
1830     ;;
1831 esac
1832 AC_MSG_RESULT($PLATFORMDEP)
1833 AC_SUBST(PLATFORMDEP)
1834
1835 AC_MSG_CHECKING([whether to compile timeloop])
1836 case "$host" in
1837   *-*-cygwin*|*-*-mingw*|*-*-minix)
1838     enable_timeloop=no
1839     ;;
1840   *)
1841     enable_timeloop=yes
1842     ;;
1843 esac
1844 AC_MSG_RESULT($enable_timeloop)
1845 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1846
1847 AC_MSG_CHECKING([if building for some Win32 platform])
1848 case "$host" in
1849   *-*-mingw*|*-*-cygwin*)
1850     platform_win32=yes
1851     ;;
1852   *)
1853     platform_win32=no
1854     ;;
1855 esac
1856 AC_MSG_RESULT($platform_win32)
1857 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1858
1859 dnl ***********************
1860 dnl *** g_thread checks ***
1861 dnl ***********************
1862
1863 AC_ARG_WITH(threads,
1864            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1865                            [specify a thread implementation to use])],
1866            [if test "x$with_threads" = x; then
1867                 want_threads=yes
1868             else
1869                 want_threads=$with_threads
1870             fi],
1871            [want_threads=yes])
1872 if test "x$enable_threads" = "xno"; then
1873         want_threads=no
1874 fi
1875
1876 dnl error and warning message
1877 dnl *************************
1878
1879 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1880                 computer. GLib will not have a default thread implementation."
1881
1882 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1883                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1884                 compilation now, but then your programs might not work.
1885                 Please provide information on how it is done on your system."
1886
1887 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1888                 "
1889
1890 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1891                 provide information on your thread implementation.
1892                 You can also run 'configure --disable-threads'
1893                 to compile without thread support."
1894
1895 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1896                 functions will not be MT-safe during their first call because
1897                 there is no working 'getpwuid_r' on your system."
1898
1899 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1900                 because there is no 'localtime_r' on your system."
1901
1902 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1903                 crude surrogate will be used. If you happen to know a
1904                 yield function for your system, please inform the GLib
1905                 developers."
1906
1907 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1908                 threads on your system. Thus threads can only have the default
1909                 priority. If you happen to know these main/max
1910                 priorities, please inform the GLib developers."
1911
1912 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1913                 linking threaded applications. As GLib cannot do that
1914                 automatically, you will get an linkg error everytime you are
1915                 not using the right compiler. In that case you have to relink
1916                 with the right compiler. Ususally just '_r' is appended
1917                 to the compiler name."
1918
1919 dnl determination of thread implementation
1920 dnl ***************************************
1921
1922 # have_threads=no   means no thread support
1923 # have_threads=none means no default thread implementation
1924
1925 have_threads=no
1926 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1927                                 || test "x$want_threads" = xdce; then
1928         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1929         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1930         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1931         glib_save_CPPFLAGS="$CPPFLAGS"
1932         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1933         if test "x$have_threads" = xno; then
1934                 AC_TRY_COMPILE([#include <pthread.h>],
1935                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1936                         have_threads=posix)
1937         fi
1938         if test "x$have_threads" = xno; then
1939                 AC_TRY_COMPILE([#include <pthread.h>],
1940                         [pthread_mutex_t m;
1941                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1942                         have_threads=dce)
1943         fi
1944         # Tru64Unix requires -pthread to find pthread.h. See #103020
1945         CPPFLAGS="$CPPFLAGS -pthread"
1946         if test "x$have_threads" = xno; then
1947         AC_TRY_COMPILE([#include <pthread.h>],
1948                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1949                        have_threads=posix)
1950         fi
1951         CPPFLAGS="$glib_save_CPPFLAGS"
1952 fi
1953 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1954         case $host in
1955                 *-*-mingw*)
1956                 have_threads=win32
1957                 ;;
1958         esac
1959 fi
1960 if test "x$want_threads" = xnone; then
1961         have_threads=none
1962 fi
1963
1964 AC_MSG_CHECKING(for thread implementation)
1965
1966 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1967         AC_MSG_RESULT(none available)
1968         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1969 else
1970         AC_MSG_RESULT($have_threads)
1971 fi
1972
1973
1974 dnl determination of G_THREAD_CFLAGS
1975 dnl ********************************
1976
1977 G_THREAD_LIBS=
1978 G_THREAD_LIBS_EXTRA=
1979 G_THREAD_CFLAGS=
1980
1981 dnl
1982 dnl Test program for basic POSIX threads functionality
1983 dnl
1984 m4_define([glib_thread_test],[
1985 #include <pthread.h>
1986 int check_me = 0;
1987 void* func(void* data) {check_me = 42; return &check_me;}
1988 int main()
1989  { pthread_t t;
1990    void *ret;
1991    pthread_create (&t, $1, func, 0);
1992    pthread_join (t, &ret);
1993    return (check_me != 42 || ret != &check_me);
1994 }])
1995
1996 dnl
1997 dnl Test program for sched_get_priority_min()
1998 dnl
1999 m4_define([glib_sched_priority_test],[
2000 #include <sched.h>
2001 #include <errno.h>
2002 int main() {
2003     errno = 0;
2004     return sched_get_priority_min(SCHED_OTHER)==-1
2005            && errno != 0;
2006 }])
2007
2008 if test x"$have_threads" != xno; then
2009
2010   if test x"$have_threads" = xposix; then
2011     # First we test for posix, whether -pthread or -pthreads do the trick as
2012     # both CPPFLAG and LIBS.
2013     # One of them does for most gcc versions and some other platforms/compilers
2014     # too and could be considered as the canonical way to go.
2015     case $host in
2016       *-*-cygwin*|*-*-darwin*)
2017          # skip cygwin and darwin -pthread or -pthreads test
2018          ;;
2019       *-solaris*)
2020         # These compiler/linker flags work with both Sun Studio and gcc
2021         # Sun Studio expands -mt to -D_REENTRANT and -lthread
2022         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2023         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2024         G_THREAD_LIBS="-lpthread -lthread"
2025         ;;
2026       *)
2027         for flag in pthread pthreads mt; do
2028           glib_save_CFLAGS="$CFLAGS"
2029           CFLAGS="$CFLAGS -$flag"
2030           AC_TRY_RUN(glib_thread_test(0),
2031                      glib_flag_works=yes,
2032                      glib_flag_works=no,
2033                      [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2034                                      glib_flag_works=yes,
2035                                      glib_flag_works=no)])
2036           CFLAGS="$glib_save_CFLAGS"
2037           if test $glib_flag_works = yes ; then
2038              G_THREAD_CFLAGS=-$flag
2039              G_THREAD_LIBS=-$flag
2040              break;
2041           fi
2042         done
2043          ;;
2044     esac
2045   fi
2046
2047   if test x"$G_THREAD_CFLAGS" = x; then
2048
2049     # The canonical -pthread[s] does not work. Try something different.
2050
2051     case $host in
2052         *-aix*)
2053                 if test x"$GCC" = xyes; then
2054                         # GCC 3.0 and above needs -pthread.
2055                         # Should be coverd by the case above.
2056                         # GCC 2.x and below needs -mthreads
2057                         G_THREAD_CFLAGS="-mthreads"
2058                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2059                 else
2060                         # We are probably using the aix compiler. Normaly a
2061                         # program would have to be compiled with the _r variant
2062                         # of the corresponding compiler, but we as GLib cannot
2063                         # do that: but the good news is that for compiling the
2064                         # only difference is the added -D_THREAD_SAFE compile
2065                         # option. This is according to the "C for AIX User's
2066                         # Guide".
2067                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2068                 fi
2069                 ;;
2070         *-dg-dgux*)  # DG/UX
2071                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2072                 ;;
2073         *-osf*)
2074                 # So we are using dce threads. posix threads are already
2075                 # catched above.
2076                 G_THREAD_CFLAGS="-threads"
2077                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2078                 ;;
2079         *-sysv5uw7*) # UnixWare 7
2080                 # We are not using gcc with -pthread. Catched above.
2081                 G_THREAD_CFLAGS="-Kthread"
2082                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2083                 ;;
2084         *-mingw*)
2085                 # No flag needed when using MSVCRT.DLL
2086                 G_THREAD_CFLAGS=""
2087                 ;;
2088         *)
2089                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2090                 ;;
2091     esac
2092
2093   fi
2094
2095     # if we are not finding the localtime_r function, then we probably are
2096     # not using the proper multithread flag
2097
2098     glib_save_CPPFLAGS="$CPPFLAGS"
2099     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2100
2101     # First we test, whether localtime_r is declared in time.h
2102     # directly. Then we test whether a macro localtime_r exists, in
2103     # which case localtime_r in the test program is replaced and thus
2104     # if we still find localtime_r in the output, it is not defined as
2105     # a macro.
2106
2107     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2108       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2109                                                            localtime_r(a,b)],
2110                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2111
2112     CPPFLAGS="$glib_save_CPPFLAGS"
2113
2114     AC_MSG_CHECKING(thread related cflags)
2115     AC_MSG_RESULT($G_THREAD_CFLAGS)
2116     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2117 fi
2118
2119 dnl determination of G_THREAD_LIBS
2120 dnl ******************************
2121
2122 mutex_has_default=no
2123 case $have_threads in
2124         posix|dce)
2125           glib_save_CPPFLAGS="$CPPFLAGS"
2126           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2127           if test x"$G_THREAD_LIBS" = x; then
2128             case $host in
2129               *-aix*)
2130                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2131                 # probably using the aix compiler.
2132                 AC_MSG_WARN($AIX_COMPILE_INFO)
2133                 ;;
2134               *)
2135                 G_THREAD_LIBS=error
2136                 glib_save_LIBS="$LIBS"
2137                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2138                         if test x"$thread_lib" = x; then
2139                                 add_thread_lib=""
2140                                 IN=""
2141                         else
2142                                 add_thread_lib="-l$thread_lib"
2143                                 IN=" in -l$thread_lib"
2144                         fi
2145                         if test x"$have_threads" = xposix; then
2146                                 defattr=0
2147                         else
2148                                 defattr=pthread_attr_default
2149                         fi
2150
2151                         LIBS="$add_thread_lib $glib_save_LIBS"
2152
2153                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2154                         AC_TRY_RUN(glib_thread_test($defattr),
2155                                    glib_result=yes,
2156                                    glib_result=no,
2157                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2158                                                    glib_result=yes,
2159                                                    glib_result=no)])
2160                         AC_MSG_RESULT($glib_result)
2161
2162                         if test "$glib_result" = "yes" ; then
2163                           G_THREAD_LIBS="$add_thread_lib"
2164                           break
2165                         fi
2166                 done
2167                 if test "x$G_THREAD_LIBS" = xerror; then
2168                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2169                 fi
2170                 LIBS="$glib_save_LIBS"
2171                 ;;
2172             esac
2173           fi
2174
2175           glib_save_LIBS="$LIBS"
2176           for thread_lib in "" rt rte; do
2177             if test x"$thread_lib" = x; then
2178               add_thread_lib=""
2179               IN=""
2180             else
2181               add_thread_lib="-l$thread_lib"
2182               IN=" in -l$thread_lib"
2183             fi
2184             LIBS="$add_thread_lib $glib_save_LIBS"
2185
2186             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2187             AC_TRY_RUN(glib_sched_priority_test,
2188                        glib_result=yes,
2189                        glib_result=no,
2190                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2191                                        glib_result=yes,
2192                                        glib_result=no)])
2193             AC_MSG_RESULT($glib_result)
2194
2195             if test "$glib_result" = "yes" ; then
2196                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2197                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2198                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2199                break
2200             fi
2201           done
2202           LIBS="$glib_save_LIBS"
2203           mutex_has_default=yes
2204           mutex_default_type='pthread_mutex_t'
2205           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2206           mutex_header_file='pthread.h'
2207           if test "x$have_threads" = "xposix"; then
2208             g_threads_impl="POSIX"
2209           else
2210             g_threads_impl="DCE"
2211             have_threads="posix"
2212           fi
2213           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2214           CPPFLAGS="$glib_save_CPPFLAGS"
2215           ;;
2216         win32)
2217            g_threads_impl="WIN32"
2218            ;;
2219         none|no)
2220            g_threads_impl="NONE"
2221            ;;
2222         *)
2223            g_threads_impl="NONE"
2224            G_THREAD_LIBS=error
2225            ;;
2226 esac
2227
2228 if test "x$G_THREAD_LIBS" = xerror; then
2229         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2230 fi
2231
2232 case $host in
2233   *-*-beos*)
2234     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2235     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2236     ;;
2237   *)
2238     ;;
2239 esac
2240
2241 AC_MSG_CHECKING(thread related libraries)
2242 AC_MSG_RESULT($G_THREAD_LIBS)
2243
2244 dnl check for mt safe function variants and some posix functions
2245 dnl ************************************************************
2246
2247 if test x"$have_threads" != xno; then
2248         glib_save_LIBS="$LIBS"
2249         # we are not doing the following for now, as this might require glib
2250         # to always be linked with the thread libs on some platforms.
2251         # LIBS="$LIBS $G_THREAD_LIBS"
2252         AC_CHECK_FUNCS(localtime_r gmtime_r)
2253         if test "$ac_cv_header_pwd_h" = "yes"; then
2254                 AC_CACHE_CHECK([for posix getpwuid_r],
2255                         ac_cv_func_posix_getpwuid_r,
2256                         [AC_TRY_RUN([
2257 #include <errno.h>
2258 #include <pwd.h>
2259 int main () {
2260     char buffer[10000];
2261     struct passwd pwd, *pwptr = &pwd;
2262     int error;
2263     errno = 0;
2264     error = getpwuid_r (0, &pwd, buffer,
2265                         sizeof (buffer), &pwptr);
2266    return (error < 0 && errno == ENOSYS)
2267            || error == ENOSYS;
2268 }                               ],
2269                                 [ac_cv_func_posix_getpwuid_r=yes],
2270                                 [ac_cv_func_posix_getpwuid_r=no])])
2271                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2272                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2273                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2274                                 [Have POSIX function getpwuid_r])
2275                 else
2276                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2277                                 ac_cv_func_nonposix_getpwuid_r,
2278                                 [AC_TRY_LINK([#include <pwd.h>],
2279                                         [char buffer[10000];
2280                                         struct passwd pwd;
2281                                         getpwuid_r (0, &pwd, buffer,
2282                                                         sizeof (buffer));],
2283                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2284                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2285                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2286                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2287                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2288                                         [Have non-POSIX function getpwuid_r])
2289                         fi
2290                 fi
2291         fi
2292         if test "$ac_cv_header_grp_h" = "yes"; then
2293                 AC_CACHE_CHECK([for posix getgrgid_r],
2294                         ac_cv_func_posix_getgrgid_r,
2295                         [AC_TRY_RUN([
2296 #include <errno.h>
2297 #include <grp.h>
2298 int main () {
2299     char buffer[10000];
2300     struct group grp, *grpptr = &grp;
2301     int error;
2302     errno = 0;
2303     error = getgrgid_r (0, &grp, buffer,
2304                         sizeof (buffer), &grpptr);
2305    return (error < 0 && errno == ENOSYS)
2306            || error == ENOSYS;
2307 }                              ],
2308                                [ac_cv_func_posix_getgrgid_r=yes],
2309                                [ac_cv_func_posix_getgrgid_r=no])])
2310                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2311                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2312                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2313                                 [Have POSIX function getgrgid_r])
2314                 else
2315                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2316                                 ac_cv_func_nonposix_getgrgid_r,
2317                                 [AC_TRY_LINK([#include <grp.h>],
2318                                         [char buffer[10000];
2319                                         struct group grp;
2320                                         getgrgid_r (0, &grp, buffer,
2321                                         sizeof (buffer));],
2322                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2323                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2324                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2325                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2326                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2327                                         [Have non-POSIX function getgrgid_r])
2328                         fi
2329                 fi
2330         fi
2331         LIBS="$G_THREAD_LIBS $LIBS"
2332         if test x"$have_threads" = xposix; then
2333                 glib_save_CPPFLAGS="$CPPFLAGS"
2334                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2335                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2336                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2337                 # This is not AC_CHECK_FUNC to also work with function
2338                 # name mangling in header files.
2339                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2340                 AC_TRY_LINK([#include <pthread.h>],
2341                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2342                         [AC_MSG_RESULT(yes)
2343                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2344                                   [Have function pthread_attr_setstacksize])],
2345                         [AC_MSG_RESULT(no)])
2346                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2347                 if test x"$posix_priority_min" = x; then
2348                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2349                                 PX_PRIO_MIN],,[
2350                                 posix_priority_min=PX_PRIO_MIN
2351                                 posix_priority_max=PX_PRIO_MAX])
2352                 fi
2353                 if test x"$posix_priority_min" = x; then
2354                         # AIX
2355                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2356                                 PTHREAD_PRIO_MIN],,[
2357                                 posix_priority_min=PTHREAD_PRIO_MIN
2358                                 posix_priority_max=PTHREAD_PRIO_MAX])
2359                 fi
2360                 if test x"$posix_priority_min" = x; then
2361                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2362                                 PRI_OTHER_MIN],,[
2363                                 posix_priority_min=PRI_OTHER_MIN
2364                                 posix_priority_max=PRI_OTHER_MAX])
2365                 fi
2366                 if test x"$posix_priority_min" = x; then
2367                         AC_MSG_RESULT(none found)
2368                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2369                         posix_priority_min=-1
2370                         posix_priority_max=-1
2371                 else
2372                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2373                         AC_MSG_CHECKING(for pthread_setschedparam)
2374                         AC_TRY_LINK([#include <pthread.h>],
2375                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2376                           [AC_MSG_RESULT(yes)
2377                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2378                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2379                           [AC_MSG_RESULT(no)
2380                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2381                 fi
2382                 posix_yield_func=none
2383                 AC_MSG_CHECKING(for posix yield function)
2384                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2385                                                         thr_yield; do
2386                         AC_TRY_LINK([#include <pthread.h>],
2387                                 [$yield_func()],
2388                                 [posix_yield_func="$yield_func"
2389                                 break])
2390                 done
2391                 if test x"$posix_yield_func" = xnone; then
2392                         AC_MSG_RESULT(none found)
2393                         AC_MSG_WARN($POSIX_NO_YIELD)
2394                         posix_yield_func="g_usleep(1000)"
2395                 else
2396                         AC_MSG_RESULT($posix_yield_func)
2397                         posix_yield_func="$posix_yield_func()"
2398                 fi
2399                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2400                 CPPFLAGS="$glib_save_CPPFLAGS"
2401
2402         elif test x"$have_threads" = xwin32; then
2403                 # It's a pointer to a private struct
2404                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2405         fi
2406
2407         LIBS="$glib_save_LIBS"
2408
2409         # now spit out all the warnings.
2410         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2411            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2412                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2413         fi
2414         if test "$ac_cv_func_localtime_r" != "yes"; then
2415                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2416         fi
2417 fi
2418
2419 if test x"$glib_cv_sizeof_system_thread" = x; then
2420    # use a pointer as a fallback.
2421    GLIB_SIZEOF(,void *, system_thread)
2422 fi
2423
2424 #
2425 # Hack to deal with:
2426 #
2427 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2428 #     building shared libraries with linux.
2429 #  b) FreeBSD doesn't do this either.
2430 #
2431 case $host in
2432   *-*-freebsd*|*-*-linux*)
2433     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2434     ;;
2435   *)
2436     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2437     ;;
2438 esac
2439
2440 AM_CONDITIONAL(HAVE_THREADS, [test "$have_threads" != "none"])
2441 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2442                    [Source file containing theread implementation])
2443 AC_SUBST(G_THREAD_CFLAGS)
2444 AC_SUBST(G_THREAD_LIBS)
2445 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2446 AC_SUBST(G_THREAD_LIBS_EXTRA)
2447
2448 dnl **********************************************
2449 dnl *** GDefaultMutex setup and initialization ***
2450 dnl **********************************************
2451 dnl
2452 dnl if mutex_has_default = yes, we also got
2453 dnl mutex_default_type, mutex_default_init and mutex_header_file
2454 if test $mutex_has_default = yes ; then
2455         glib_save_CPPFLAGS="$CPPFLAGS"
2456         glib_save_LIBS="$LIBS"
2457         LIBS="$G_THREAD_LIBS $LIBS"
2458         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2459         GLIB_SIZEOF([#include <$mutex_header_file>],
2460                     $mutex_default_type,
2461                     gmutex)
2462         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2463                            $mutex_default_type,
2464                            gmutex,
2465                            $glib_cv_sizeof_gmutex,
2466                            $mutex_default_init)
2467         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2468                 mutex_has_default=no
2469         fi
2470         CPPFLAGS="$glib_save_CPPFLAGS"
2471         LIBS="$glib_save_LIBS"
2472 fi
2473
2474 AC_CHECK_FUNCS(clock_gettime, [], [
2475   AC_CHECK_LIB(rt, clock_gettime, [
2476     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2477     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2478     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2479     GLIB_RT_LIBS="-lrt"
2480   ])
2481 ])
2482 AC_SUBST(GLIB_RT_LIBS)
2483
2484 AC_CACHE_CHECK(for monotonic clocks,
2485     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2486 #include <time.h>
2487 #include <unistd.h>
2488 int main() {
2489 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2490         #error No monotonic clock
2491 #endif
2492         return 0;
2493 }
2494 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2495 if test "$glib_cv_monotonic_clock" = "yes"; then
2496   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2497 fi
2498
2499
2500 dnl ************************
2501 dnl *** g_atomic_* tests ***
2502 dnl ************************
2503
2504 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2505     case $host_cpu in
2506       i386)
2507         AC_MSG_RESULT([none])
2508         glib_memory_barrier_needed=no
2509         ;;
2510       i?86)
2511         AC_MSG_RESULT([i486])
2512         AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2513                            [i486 atomic implementation])
2514         glib_memory_barrier_needed=no
2515         ;;
2516       sparc*)
2517         SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2518                          when you are using a sparc with v9 instruction set (most
2519                          sparcs nowadays). This will make the code for atomic
2520                          operations much faster. The resulting code will not run
2521                          on very old sparcs though."
2522
2523         AC_LINK_IFELSE([AC_LANG_SOURCE([[
2524           main ()
2525           {
2526             int tmp1, tmp2, tmp3;
2527             __asm__ __volatile__("casx [%2], %0, %1"
2528                                  : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2529           }]])],
2530           AC_MSG_RESULT([sparcv9])
2531           AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2532                              [sparcv9 atomic implementation]),
2533           AC_MSG_RESULT([no])
2534           AC_MSG_WARN([[$SPARCV9_WARNING]]))
2535         glib_memory_barrier_needed=yes
2536         ;;
2537       alpha*)
2538         AC_MSG_RESULT([alpha])
2539         AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2540                            [alpha atomic implementation])
2541         glib_memory_barrier_needed=yes
2542         ;;
2543       x86_64)
2544         AC_MSG_RESULT([x86_64])
2545         AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2546                            [x86_64 atomic implementation])
2547         glib_memory_barrier_needed=no
2548        ;;
2549       powerpc*)
2550         AC_MSG_RESULT([powerpc])
2551         AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2552                            [powerpc atomic implementation])
2553         glib_memory_barrier_needed=yes
2554         AC_MSG_CHECKING([whether asm supports numbered local labels])
2555         AC_TRY_COMPILE(
2556                        ,[
2557                        __asm__ __volatile__ ("1:       nop\n"
2558                                "         bne-    1b")
2559                        ],[
2560                        AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2561                        AC_MSG_RESULT([yes])
2562                        ],[
2563                        AC_MSG_RESULT([no])
2564                        ])
2565         ;;
2566       ia64)
2567         AC_MSG_RESULT([ia64])
2568         AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2569                            [ia64 atomic implementation])
2570         glib_memory_barrier_needed=yes
2571         ;;
2572       s390|s390x)
2573         AC_MSG_RESULT([s390])
2574         AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2575                            [s390 atomic implementation])
2576         glib_memory_barrier_needed=no
2577         ;;
2578       arm*)
2579         AC_MSG_RESULT([arm])
2580         AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2581                            [arm atomic implementation])
2582         glib_memory_barrier_needed=no
2583         ;;
2584       crisv32*|etraxfs*)
2585         AC_MSG_RESULT([crisv32])
2586         AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2587                            [crisv32 atomic implementation])
2588         glib_memory_barrier_needed=no
2589         ;;
2590       cris*|etrax*)
2591         AC_MSG_RESULT([cris])
2592         AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2593                            [cris atomic implementation])
2594         glib_memory_barrier_needed=no
2595         ;;
2596       *)
2597         AC_MSG_RESULT([none])
2598         glib_memory_barrier_needed=yes
2599         ;;
2600     esac
2601
2602 glib_cv_gcc_has_builtin_atomic_operations=no
2603 if test x"$GCC" = xyes; then
2604   AC_MSG_CHECKING([whether GCC supports built-in atomic intrinsics])
2605   AC_TRY_LINK([],
2606               [int i;
2607                __sync_synchronize ();
2608                __sync_bool_compare_and_swap (&i, 0, 1);
2609                __sync_fetch_and_add (&i, 1);
2610               ],
2611               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2612               [glib_cv_gcc_has_builtin_atomic_operations=no])
2613
2614   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2615 fi
2616 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2617                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2618
2619 AC_MSG_CHECKING([for Win32 atomic intrinsics])
2620 glib_cv_has_win32_atomic_operations=no
2621 AC_TRY_LINK([],
2622         [int i; _InterlockedExchangeAdd (&i, 0);],
2623         [glib_cv_has_win32_atomic_operations=yes],
2624         [glib_cv_has_win32_atomic_operations=no])
2625 AC_MSG_RESULT($glib_cv_has_win32_atomic_operations)
2626 if test "x$glib_cv_has_win32_atomic_operations" = xyes; then
2627         AC_DEFINE(HAVE_WIN32_BUILTINS_FOR_ATOMIC_OPERATIONS,1,[Have Win32 atomic intrinsics])
2628 fi
2629
2630 dnl ************************
2631 dnl ** Check for futex(2) **
2632 dnl ************************
2633 AC_CACHE_CHECK(for futex(2) system call,
2634     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2635 #include <linux/futex.h>
2636 #include <sys/syscall.h>
2637 #include <unistd.h>
2638 ],[
2639 int
2640 main (void)
2641 {
2642   /* it is not like this actually runs or anything... */
2643   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2644   return 0;
2645 }
2646 ])],glib_cv_futex=yes,glib_cv_futex=no))
2647 if test x"$glib_cv_futex" = xyes; then
2648   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2649 fi
2650
2651 AC_CACHE_CHECK(for eventfd(2) system call,
2652     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2653 #include <sys/eventfd.h>
2654 #include <unistd.h>
2655 ],[
2656 int
2657 main (void)
2658 {
2659   eventfd (0, EFD_CLOEXEC);
2660   return 0;
2661 }
2662 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2663 if test x"$glib_cv_eventfd" = x"yes"; then
2664   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2665 fi
2666 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2667
2668 dnl ****************************************
2669 dnl *** GLib POLL* compatibility defines ***
2670 dnl ****************************************
2671
2672 glib_poll_includes=["
2673 #include <sys/types.h>
2674 #include <sys/poll.h>
2675 "]
2676
2677 if test $ac_cv_header_sys_types_h = yes &&
2678    test $ac_cv_header_sys_poll_h = yes ; then
2679   glib_failed=false
2680   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2681   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2682   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2683   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2684   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2685   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2686   if $glib_failed ; then
2687     AC_MSG_ERROR([Could not determine values for POLL* constants])
2688   fi
2689 else
2690   glib_cv_value_POLLIN=1
2691   glib_cv_value_POLLOUT=4
2692   glib_cv_value_POLLPRI=2
2693   glib_cv_value_POLLERR=8
2694   glib_cv_value_POLLHUP=16
2695   glib_cv_value_POLLNVAL=32
2696 fi
2697
2698 AC_MSG_CHECKING([for broken poll])
2699 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2700         #include <stdlib.h>
2701         #include <fcntl.h>
2702         #include <poll.h>
2703         #ifdef HAVE_SYS_POLL_H
2704         #include <sys/poll.h>
2705         #endif
2706         int main(void) {
2707           struct pollfd fds[1];
2708           int fd;
2709           fd = open("/dev/null", 1);
2710           fds[0].fd = fd;
2711           fds[0].events = POLLIN;
2712           fds[0].revents = 0;
2713           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2714                 exit(1);  /* Does not work for devices -- fail */
2715           }
2716           exit(0);
2717         }]])],
2718   [broken_poll=no],
2719   [broken_poll=yes
2720    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2721   [broken_poll="no (cross compiling)"])
2722 AC_MSG_RESULT($broken_poll)
2723
2724 dnl *********************
2725 dnl *** GRegex checks ***
2726 dnl *********************
2727 PCRE_REQUIRED_VERSION=8.11
2728
2729 # Check if we should compile GRegex
2730 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2731               [disable the compilation of GRegex]),
2732 [case "${enableval}" in
2733   yes) enable_regex=true ;;
2734   no)  enable_regex=false ;;
2735   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2736 esac],
2737 [enable_regex=true])
2738
2739 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2740
2741 if test x$enable_regex = xtrue; then
2742   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2743   # Check if we should use the internal or the system-supplied pcre
2744   AC_ARG_WITH(pcre,
2745              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2746                              [specify whether to use the internal or the
2747                               system-supplied PCRE library])])
2748
2749   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2750
2751   if test "x$with_pcre" = xsystem; then
2752     PKG_CHECK_MODULES(PCRE,
2753                       libpcre >= $PCRE_REQUIRED_VERSION)
2754     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2755                    glib_save_CFLAGS="$CFLAGS"
2756                    glib_save_LIBS="$LIBS"
2757                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2758                    AC_TRY_RUN([#include <pcre.h>
2759                                int main () {
2760                                  int support;
2761                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2762                                  if (!support)
2763                                    return 1;
2764                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2765                                  if (!support)
2766                                    return 1;
2767                                  return 0;
2768                                }],
2769                    glib_cv_pcre_has_unicode=yes,
2770                    glib_cv_pcre_has_unicode=no,
2771                    glib_cv_pcre_has_unicode=yes)
2772                    CFLAGS="$glib_save_CFLAGS"
2773                    LIBS="$glib_save_LIBS"
2774         ])
2775     if test "$glib_cv_pcre_has_unicode" = "no"; then
2776       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2777     fi
2778     AC_SUBST(PCRE_CFLAGS)
2779     AC_SUBST(PCRE_LIBS)
2780     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2781     PCRE_REQUIRES=libpcre
2782     AC_SUBST(PCRE_REQUIRES)
2783   else
2784     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2785     if test x"$GCC" = xyes; then
2786       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2787       save_CFLAGS="$CFLAGS"
2788       CFLAGS="$CFLAGS -Wno-pointer-sign"
2789       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2790                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2791       CFLAGS="$save_CFLAGS"
2792     fi
2793   fi
2794   AC_SUBST(PCRE_WARN_CFLAGS)
2795 else
2796   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2797 fi
2798
2799 dnl **********************
2800 dnl *** Win32 API libs ***
2801 dnl **********************
2802
2803 case $host in
2804   *-*-cygwin*)
2805         G_LIBS_EXTRA="-luser32 -lkernel32"
2806     ;;
2807   *-*-mingw*)
2808         G_LIBS_EXTRA="-lws2_32 -lole32"
2809     ;;
2810   *)
2811         G_LIBS_EXTRA=""
2812     ;;
2813 esac
2814 AC_SUBST(G_LIBS_EXTRA)
2815
2816 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2817 dnl since we need it for g_iconv()
2818
2819 AC_MSG_CHECKING([for EILSEQ])
2820 AC_TRY_COMPILE([
2821 #include <errno.h>
2822 ],
2823 [
2824 int error = EILSEQ;
2825 ], have_eilseq=yes, have_eilseq=no);
2826 AC_MSG_RESULT($have_eilseq)
2827
2828 dnl ******************************************************************
2829 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2830 dnl *** glib-compile-schemas in PATH                               ***
2831 dnl ******************************************************************
2832
2833 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2834
2835 if test $cross_compiling = yes; then
2836   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2837   if test x$GLIB_GENMARSHAL = xno; then
2838     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2839   fi
2840
2841   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2842   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2843     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2844   fi
2845 fi
2846
2847 dnl **************************
2848 dnl *** Checks for gtk-doc ***
2849 dnl **************************
2850
2851 GTK_DOC_CHECK([1.15])
2852
2853 AC_ARG_ENABLE(man,
2854               [AC_HELP_STRING([--enable-man],
2855                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2856               enable_man=no)
2857
2858 if test "${enable_man}" != no; then
2859 dnl
2860 dnl Check for xsltproc
2861 dnl
2862 AC_PATH_PROG([XSLTPROC], [xsltproc])
2863   if test -z "$XSLTPROC"; then
2864     enable_man=no
2865   fi
2866
2867   dnl check for DocBook DTD and stylesheets in the local catalog.
2868   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2869      [DocBook XML DTD V4.1.2],,enable_man=no)
2870   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2871      [DocBook XSL Stylesheets],,enable_man=no)
2872 fi
2873
2874 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2875
2876 dnl
2877 dnl Tracing
2878 dnl
2879
2880 AC_ARG_ENABLE([dtrace],
2881              [AS_HELP_STRING([--enable-dtrace],
2882                               [Enable inclusion of dtrace trace support])])
2883 have_dtrace=no
2884 AC_MSG_CHECKING([whether to include dtrace tracing support])
2885 if test "x$enable_dtrace" != xno; then
2886   if test x$glib_have_carbon = xyes; then
2887     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2888   else
2889     AC_MSG_RESULT([yes])
2890     AC_CHECK_PROGS(DTRACE, dtrace)
2891     if test -z "$DTRACE"; then
2892       if test "x$enable_dtrace" = xyes; then
2893         AC_MSG_ERROR([dtrace not found])
2894       fi
2895     else
2896       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2897                       [if test "x$enable_dtrace" = xyes; then
2898                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2899                        fi])
2900     fi
2901   fi
2902 else
2903   AC_MSG_RESULT([no])
2904 fi
2905 if test "x$have_dtrace" = xyes; then
2906   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2907 fi
2908 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2909
2910 AC_MSG_CHECKING([whether to include systemtap tracing support])
2911 AC_ARG_ENABLE([systemtap],
2912              [AS_HELP_STRING([--enable-systemtap],
2913                               [Enable inclusion of systemtap trace support])])
2914 have_systemtap=no
2915 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2916   have_systemtap=yes
2917 fi
2918 AC_MSG_RESULT(${have_systemtap})
2919
2920 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2921
2922 AC_ARG_WITH([tapset-install-dir],
2923             [AS_HELP_STRING([--with-tapset-install-dir],
2924             [The absolute path where the systemtap tapsets will be installed])],
2925             [if test "x${withval}" = x; then
2926                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2927              else
2928                ABS_TAPSET_DIR="${withval}"
2929               fi],
2930             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2931 AC_SUBST(ABS_TAPSET_DIR)
2932
2933 dnl ************************************
2934 dnl *** Enable lcov coverage reports ***
2935 dnl ************************************
2936
2937 AC_ARG_ENABLE(gcov,
2938   AS_HELP_STRING([--enable-gcov],
2939                  [Enable gcov]),
2940   [use_gcov=$enableval], [use_gcov=no])
2941
2942 if test "x$use_gcov" = "xyes"; then
2943   dnl we need gcc:
2944   if test "$GCC" != "yes"; then
2945     AC_MSG_ERROR([GCC is required for --enable-gcov])
2946   fi
2947
2948   dnl Check if ccache is being used
2949   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2950   case `$SHTOOL path $CC` in
2951     *ccache*[)] gcc_ccache=yes;;
2952     *[)] gcc_ccache=no;;
2953   esac
2954
2955   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2956     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2957   fi
2958
2959   ltp_version_list="1.6 1.7 1.8 1.9"
2960   AC_CHECK_PROG(LTP, lcov, lcov)
2961   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2962
2963   if test "$LTP"; then
2964     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2965       glib_cv_ltp_version=invalid
2966       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2967       for ltp_check_version in $ltp_version_list; do
2968         if test "$ltp_version" = "$ltp_check_version"; then
2969           glib_cv_ltp_version="$ltp_check_version (ok)"
2970         fi
2971       done
2972     ])
2973   else
2974     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2975     AC_MSG_ERROR([$ltp_msg])
2976   fi
2977
2978   case $glib_cv_ltp_version in
2979     ""|invalid[)]
2980       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2981       AC_MSG_ERROR([$ltp_msg])
2982       LTP="exit 0;"
2983       ;;
2984   esac
2985
2986   if test -z "$LTP_GENHTML"; then
2987     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2988   fi
2989
2990   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2991
2992   dnl Remove all optimization flags from CFLAGS
2993   changequote({,})
2994   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2995   changequote([,])
2996
2997   dnl Add the special gcc flags
2998   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2999   LDFLAGS="$LDFLAGS -lgcov"
3000 fi
3001
3002 dnl ******************************
3003 dnl *** output the whole stuff ***
3004 dnl ******************************
3005
3006 dnl this section will only be run if config.status is invoked with no
3007 dnl arguments, or with "glib/glibconfig.h" as an argument.
3008 AC_CONFIG_COMMANDS([glib/glibconfig.h],
3009 [
3010         outfile=glib/glibconfig.h-tmp
3011         cat > $outfile <<\_______EOF
3012 /* glibconfig.h
3013  *
3014  * This is a generated file.  Please modify 'configure.ac'
3015  */
3016
3017 #ifndef __G_LIBCONFIG_H__
3018 #define __G_LIBCONFIG_H__
3019
3020 #include <glib/gmacros.h>
3021
3022 _______EOF
3023
3024         if test x$glib_limits_h = xyes; then
3025           echo '#include <limits.h>' >> $outfile
3026         fi
3027         if test x$glib_float_h = xyes; then
3028           echo '#include <float.h>' >> $outfile
3029         fi
3030         if test x$glib_values_h = xyes; then
3031           echo '#include <values.h>' >> $outfile
3032         fi
3033         if test "$glib_header_alloca_h" = "yes"; then
3034           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
3035         fi
3036         if test x$glib_sys_poll_h = xyes; then
3037           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
3038         fi
3039         if test x$glib_included_printf != xyes; then
3040           echo "
3041 /* Specifies that GLib's g_print*() functions wrap the
3042  * system printf functions.  This is useful to know, for example,
3043  * when using glibc's register_printf_function().
3044  */" >> $outfile
3045           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
3046         fi
3047
3048         cat >> $outfile <<_______EOF
3049
3050 G_BEGIN_DECLS
3051
3052 #define G_MINFLOAT      $glib_mf
3053 #define G_MAXFLOAT      $glib_Mf
3054 #define G_MINDOUBLE     $glib_md
3055 #define G_MAXDOUBLE     $glib_Md
3056 #define G_MINSHORT      $glib_ms
3057 #define G_MAXSHORT      $glib_Ms
3058 #define G_MAXUSHORT     $glib_Mus
3059 #define G_MININT        $glib_mi
3060 #define G_MAXINT        $glib_Mi
3061 #define G_MAXUINT       $glib_Mui
3062 #define G_MINLONG       $glib_ml
3063 #define G_MAXLONG       $glib_Ml
3064 #define G_MAXULONG      $glib_Mul
3065
3066 _______EOF
3067
3068
3069         ### this should always be true in a modern C/C++ compiler
3070         cat >>$outfile <<_______EOF
3071 typedef signed char gint8;
3072 typedef unsigned char guint8;
3073 _______EOF
3074
3075
3076         if test -n "$gint16"; then
3077           cat >>$outfile <<_______EOF
3078 typedef signed $gint16 gint16;
3079 typedef unsigned $gint16 guint16;
3080 #define G_GINT16_MODIFIER $gint16_modifier
3081 #define G_GINT16_FORMAT $gint16_format
3082 #define G_GUINT16_FORMAT $guint16_format
3083 _______EOF
3084         fi
3085
3086
3087         if test -n "$gint32"; then
3088           cat >>$outfile <<_______EOF
3089 typedef signed $gint32 gint32;
3090 typedef unsigned $gint32 guint32;
3091 #define G_GINT32_MODIFIER $gint32_modifier
3092 #define G_GINT32_FORMAT $gint32_format
3093 #define G_GUINT32_FORMAT $guint32_format
3094 _______EOF
3095         fi
3096
3097         cat >>$outfile <<_______EOF
3098 #define G_HAVE_GINT64 1          /* deprecated, always true */
3099
3100 ${glib_extension}typedef signed $gint64 gint64;
3101 ${glib_extension}typedef unsigned $gint64 guint64;
3102
3103 #define G_GINT64_CONSTANT(val)  $gint64_constant
3104 #define G_GUINT64_CONSTANT(val) $guint64_constant
3105 _______EOF
3106
3107         if test x$gint64_format != x ; then
3108           cat >>$outfile <<_______EOF
3109 #define G_GINT64_MODIFIER $gint64_modifier
3110 #define G_GINT64_FORMAT $gint64_format
3111 #define G_GUINT64_FORMAT $guint64_format
3112 _______EOF
3113         else
3114           cat >>$outfile <<_______EOF
3115 #undef G_GINT64_MODIFIER
3116 #undef G_GINT64_FORMAT
3117 #undef G_GUINT64_FORMAT
3118 _______EOF
3119         fi
3120
3121         cat >>$outfile <<_______EOF
3122
3123 #define GLIB_SIZEOF_VOID_P $glib_void_p
3124 #define GLIB_SIZEOF_LONG   $glib_long
3125 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3126
3127 _______EOF
3128
3129         cat >>$outfile <<_______EOF
3130 typedef signed $glib_size_type_define gssize;
3131 typedef unsigned $glib_size_type_define gsize;
3132 #define G_GSIZE_MODIFIER $gsize_modifier
3133 #define G_GSSIZE_FORMAT $gssize_format
3134 #define G_GSIZE_FORMAT $gsize_format
3135
3136 #define G_MAXSIZE       G_MAXU$glib_msize_type
3137 #define G_MINSSIZE      G_MIN$glib_msize_type
3138 #define G_MAXSSIZE      G_MAX$glib_msize_type
3139
3140 typedef gint64 goffset;
3141 #define G_MINOFFSET     G_MININT64
3142 #define G_MAXOFFSET     G_MAXINT64
3143
3144 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3145 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3146 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3147
3148 _______EOF
3149
3150         if test -z "$glib_unknown_void_p"; then
3151           cat >>$outfile <<_______EOF
3152
3153 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3154 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3155
3156 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3157 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3158
3159 typedef signed $glib_intptr_type_define gintptr;
3160 typedef unsigned $glib_intptr_type_define guintptr;
3161
3162 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3163 #define G_GINTPTR_FORMAT        $gintptr_format
3164 #define G_GUINTPTR_FORMAT       $guintptr_format
3165 _______EOF
3166         else
3167           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3168         fi
3169
3170
3171
3172         cat >>$outfile <<_______EOF
3173 $glib_atexit
3174 $glib_memmove
3175 $glib_defines
3176 $glib_os
3177 $glib_static_compilation
3178
3179 $glib_vacopy
3180
3181 #ifdef  __cplusplus
3182 #define G_HAVE_INLINE   1
3183 #else   /* !__cplusplus */
3184 $glib_inline
3185 #endif  /* !__cplusplus */
3186
3187 #ifdef  __cplusplus
3188 #define G_CAN_INLINE    1
3189 _______EOF
3190
3191         if test x$g_can_inline = xyes ; then
3192                 cat >>$outfile <<_______EOF
3193 #else   /* !__cplusplus */
3194 #define G_CAN_INLINE    1
3195 _______EOF
3196         fi
3197
3198         cat >>$outfile <<_______EOF
3199 #endif
3200
3201 _______EOF
3202
3203         if test x$g_have_iso_c_varargs = xyes ; then
3204                 cat >>$outfile <<_______EOF
3205 #ifndef __cplusplus
3206 # define G_HAVE_ISO_VARARGS 1
3207 #endif
3208 _______EOF
3209         fi
3210         if test x$g_have_iso_cxx_varargs = xyes ; then
3211                 cat >>$outfile <<_______EOF
3212 #ifdef __cplusplus
3213 # define G_HAVE_ISO_VARARGS 1
3214 #endif
3215 _______EOF
3216         fi
3217         if test x$g_have_gnuc_varargs = xyes ; then
3218                 cat >>$outfile <<_______EOF
3219
3220 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3221  * is passed ISO vararg support is turned off, and there is no work
3222  * around to turn it on, so we unconditionally turn it off.
3223  */
3224 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3225 #  undef G_HAVE_ISO_VARARGS
3226 #endif
3227
3228 #define G_HAVE_GNUC_VARARGS 1
3229 _______EOF
3230         fi
3231
3232         case x$g_stack_grows in
3233         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3234         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3235         esac
3236
3237
3238         echo >>$outfile
3239         if test x$g_have_eilseq = xno; then
3240                 cat >>$outfile <<_______EOF
3241 #ifndef EILSEQ
3242 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3243  * The correspondence between this and the corresponding definition
3244  * in libiconv is essential.
3245  */
3246 #  define EILSEQ ENOENT
3247 #endif
3248 _______EOF
3249
3250         fi
3251
3252         if test x$g_have_gnuc_visibility = xyes; then
3253                 cat >>$outfile <<_______EOF
3254 #define G_HAVE_GNUC_VISIBILITY 1
3255 _______EOF
3256         fi
3257                 cat >>$outfile <<_______EOF
3258 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3259 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3260 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3261 #define G_GNUC_INTERNAL __hidden
3262 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3263 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3264 #else
3265 #define G_GNUC_INTERNAL
3266 #endif
3267 _______EOF
3268
3269
3270         echo >>$outfile
3271         if test x$g_mutex_has_default = xyes; then
3272                 cat >>$outfile <<_______EOF
3273 $g_enable_threads_def G_THREADS_ENABLED
3274 #define G_THREADS_IMPL_$g_threads_impl_def
3275 typedef struct _GStaticMutex GStaticMutex;
3276 struct _GStaticMutex
3277 {
3278   struct _GMutex *runtime_mutex;
3279   union {
3280     char   pad[[$g_mutex_sizeof]];
3281     double dummy_double;
3282     void  *dummy_pointer;
3283     long   dummy_long;
3284   } static_mutex;
3285 };
3286 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
3287 #define g_static_mutex_get_mutex(mutex) \\
3288   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
3289    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
3290 _______EOF
3291         else
3292                 cat >>$outfile <<_______EOF
3293 $g_enable_threads_def G_THREADS_ENABLED
3294 #define G_THREADS_IMPL_$g_threads_impl_def
3295 typedef struct _GMutex* GStaticMutex;
3296 #define G_STATIC_MUTEX_INIT NULL
3297 #define g_static_mutex_get_mutex(mutex) \\
3298   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3299 _______EOF
3300         fi
3301
3302         cat >>$outfile <<_______EOF
3303 /* This represents a system thread as used by the implementation. An
3304  * alien implementaion, as loaded by g_thread_init can only count on
3305  * "sizeof (gpointer)" bytes to store their info. We however need more
3306  * for some of our native implementations. */
3307 typedef union _GSystemThread GSystemThread;
3308 union _GSystemThread
3309 {
3310   char   data[[$g_system_thread_sizeof]];
3311   double dummy_double;
3312   void  *dummy_pointer;
3313   long   dummy_long;
3314 };
3315 _______EOF
3316         if test x"$g_memory_barrier_needed" != xno; then
3317           echo >>$outfile
3318           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3319         fi
3320         if test x"$g_gcc_atomic_ops" != xno; then
3321           echo >>$outfile
3322           echo "#define G_ATOMIC_OP_USE_GCC_BUILTINS 1" >>$outfile
3323         fi
3324         echo >>$outfile
3325         g_bit_sizes="16 32 64"
3326         for bits in $g_bit_sizes; do
3327           cat >>$outfile <<_______EOF
3328 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3329 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3330 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3331 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3332 _______EOF
3333         done
3334
3335         cat >>$outfile <<_______EOF
3336 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3337 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3338 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3339 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3340 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3341 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3342 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3343 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3344 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3345 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3346 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3347 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3348 #define G_BYTE_ORDER $g_byte_order
3349
3350 #define GLIB_SYSDEF_POLLIN =$g_pollin
3351 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3352 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3353 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3354 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3355 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3356
3357 #define G_MODULE_SUFFIX "$g_module_suffix"
3358
3359 /* A GPid is an abstraction for a process "handle". It is *not* an
3360  * abstraction for a process identifier in general. GPid is used in
3361  * GLib only for descendant processes spawned with the g_spawn*
3362  * functions. On POSIX there is no "process handle" concept as such,
3363  * but on Windows a GPid is a handle to a process, a kind of pointer,
3364  * not a process identifier.
3365  */
3366 typedef $g_pid_type GPid;
3367
3368 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3369 #define GLIB_SYSDEF_AF_INET $g_af_inet
3370 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3371
3372 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3373 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3374 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3375
3376 G_END_DECLS
3377
3378 #endif /* GLIBCONFIG_H */
3379 _______EOF
3380
3381
3382         if cmp -s $outfile glib/glibconfig.h; then
3383           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3384           rm -f $outfile
3385         else
3386           mv $outfile glib/glibconfig.h
3387         fi
3388 ],[
3389
3390 # Note that if two cases are the same, case goes with the first one.
3391 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3392 # on variable expansion in case labels.  Look at the generated config.status
3393 # for a hint.
3394
3395 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3396   glib_header_alloca_h="$ac_cv_working_alloca_h"
3397 else
3398   glib_header_alloca_h="$ac_cv_header_alloca_h"
3399 fi
3400
3401 case xyes in
3402 x$ac_cv_header_float_h)
3403   glib_float_h=yes
3404   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3405   glib_md=DBL_MIN glib_Md=DBL_MAX
3406   ;;
3407 x$ac_cv_header_values_h)
3408   glib_values_h=yes
3409   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3410   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3411   ;;
3412 esac
3413
3414 case xyes in
3415 x$ac_cv_header_limits_h)
3416   glib_limits_h=yes
3417   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3418   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3419   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3420   ;;
3421 x$ac_cv_header_values_h)
3422   glib_values_h=yes
3423   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3424   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3425   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3426   ;;
3427 esac
3428
3429 if test x$ac_cv_header_sys_poll_h = xyes ; then
3430   glib_sys_poll_h=yes
3431 fi
3432
3433 if test x$enable_included_printf = xyes ; then
3434   glib_included_printf=yes
3435 fi
3436
3437 case 2 in
3438 $ac_cv_sizeof_short)
3439   gint16=short
3440   gint16_modifier='"h"'
3441   gint16_format='"hi"'
3442   guint16_format='"hu"'
3443   ;;
3444 $ac_cv_sizeof_int)
3445   gint16=int
3446   gint16_modifier='""'
3447   gint16_format='"i"'
3448   guint16_format='"u"'
3449   ;;
3450 esac
3451 case 4 in
3452 $ac_cv_sizeof_short)
3453   gint32=short
3454   gint32_modifier='"h"'
3455   gint32_format='"hi"'
3456   guint32_format='"hu"'
3457   ;;
3458 $ac_cv_sizeof_int)
3459   gint32=int
3460   gint32_modifier='""'
3461   gint32_format='"i"'
3462   guint32_format='"u"'
3463   ;;
3464 $ac_cv_sizeof_long)
3465   gint32=long
3466   gint32_modifier='"l"'
3467   gint32_format='"li"'
3468   guint32_format='"lu"'
3469   ;;
3470 esac
3471 case 8 in
3472 $ac_cv_sizeof_int)
3473   gint64=int
3474   gint64_modifier='""'
3475   gint64_format='"i"'
3476   guint64_format='"u"'
3477   glib_extension=
3478   gint64_constant='(val)'
3479   guint64_constant='(val)'
3480   ;;
3481 $ac_cv_sizeof_long)
3482   gint64=long
3483   gint64_modifier='"l"'
3484   gint64_format='"li"'
3485   guint64_format='"lu"'
3486   glib_extension=
3487   gint64_constant='(val##L)'
3488   guint64_constant='(val##UL)'
3489   ;;
3490 $ac_cv_sizeof_long_long)
3491   gint64='long long'
3492   if test -n "$glib_cv_long_long_format"; then
3493     gint64_modifier='"'$glib_cv_long_long_format'"'
3494     gint64_format='"'$glib_cv_long_long_format'i"'
3495     guint64_format='"'$glib_cv_long_long_format'u"'
3496   fi
3497   glib_extension='G_GNUC_EXTENSION '
3498   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3499   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3500   ;;
3501 $ac_cv_sizeof___int64)
3502   gint64='__int64'
3503   if test -n "$glib_cv_long_long_format"; then
3504     gint64_modifier='"'$glib_cv_long_long_format'"'
3505     gint64_format='"'$glib_cv_long_long_format'i"'
3506     guint64_format='"'$glib_cv_long_long_format'u"'
3507   fi
3508   glib_extension=
3509   gint64_constant='(val##i64)'
3510   guint64_constant='(val##ui64)'
3511   ;;
3512 esac
3513 glib_size_t=$ac_cv_sizeof_size_t
3514 glib_size_type_define="$glib_size_type"
3515 glib_void_p=$ac_cv_sizeof_void_p
3516 glib_long=$ac_cv_sizeof_long
3517
3518 case "$glib_size_type" in
3519 short)
3520   gsize_modifier='"h"'
3521   gsize_format='"hu"'
3522   gssize_format='"hi"'
3523   glib_msize_type='SHRT'
3524   ;;
3525 int)
3526   gsize_modifier='""'
3527   gsize_format='"u"'
3528   gssize_format='"i"'
3529   glib_msize_type='INT'
3530   ;;
3531 long)
3532   gsize_modifier='"l"'
3533   gsize_format='"lu"'
3534   gssize_format='"li"'
3535   glib_msize_type='LONG'
3536   ;;
3537 "long long"|__int64)
3538   gsize_modifier='"I64"'
3539   gsize_format='"I64u"'
3540   gssize_format='"I64i"'
3541   glib_msize_type='INT64'
3542   ;;
3543 esac
3544
3545 gintbits=`expr $ac_cv_sizeof_int \* 8`
3546 glongbits=`expr $ac_cv_sizeof_long \* 8`
3547 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3548
3549 case $ac_cv_sizeof_void_p in
3550 $ac_cv_sizeof_int)
3551   glib_intptr_type_define=int
3552   gintptr_modifier='""'
3553   gintptr_format='"i"'
3554   guintptr_format='"u"'
3555   glib_gpi_cast=''
3556   glib_gpui_cast=''
3557   ;;
3558 $ac_cv_sizeof_long)
3559   glib_intptr_type_define=long
3560   gintptr_modifier='"l"'
3561   gintptr_format='"li"'
3562   guintptr_format='"lu"'
3563   glib_gpi_cast='(glong)'
3564   glib_gpui_cast='(gulong)'
3565   ;;
3566 $ac_cv_sizeof_long_long)
3567   glib_intptr_type_define='long long'
3568   gintptr_modifier='"I64"'
3569   gintptr_format='"I64i"'
3570   guintptr_format='"I64u"'
3571   glib_gpi_cast='(gint64)'
3572   glib_gpui_cast='(guint64)'
3573   ;;
3574 $ac_cv_sizeof___int64)
3575   glib_intptr_type_define=__int64
3576   gintptr_modifier='"I64"'
3577   gintptr_format='"I64i"'
3578   guintptr_format='"I64u"'
3579   glib_gpi_cast='(gint64)'
3580   glib_gpui_cast='(guint64)'
3581   ;;
3582 *)
3583   glib_unknown_void_p=yes
3584   ;;
3585 esac
3586
3587
3588 case xyes in
3589 x$ac_cv_func_atexit)
3590   glib_atexit="
3591 #ifdef NeXT /* @#%@! NeXTStep */
3592 # define g_ATEXIT(proc) (!atexit (proc))
3593 #else
3594 # define g_ATEXIT(proc) (atexit (proc))
3595 #endif"
3596   ;;
3597 x$ac_cv_func_on_exit)
3598   glib_atexit="
3599 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3600   ;;
3601 esac
3602
3603 case xyes in
3604 x$ac_cv_func_memmove)
3605   glib_memmove='
3606 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3607   ;;
3608 x$glib_cv_working_bcopy)
3609   glib_memmove="
3610 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3611 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3612   ;;
3613 *)
3614   glib_memmove="
3615 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3616  * so we have to roll our own copy routine. */
3617 void g_memmove (void* dest, const void * src, unsigned long len);"
3618   ;;
3619 esac
3620
3621 glib_defines="
3622 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3623 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3624 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3625 "
3626
3627 case xyes in
3628 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3629 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3630 *)                      glib_vacopy=''
3631 esac
3632
3633 if test x$glib_cv_va_val_copy = xno; then
3634   glib_vacopy="\$glib_vacopy
3635 #define G_VA_COPY_AS_ARRAY 1"
3636 fi
3637
3638 if test x$glib_cv_hasinline = xyes; then
3639     glib_inline='#define G_HAVE_INLINE 1'
3640 fi
3641 if test x$glib_cv_has__inline = xyes; then
3642     glib_inline="\$glib_inline
3643 #define G_HAVE___INLINE 1"
3644 fi
3645 if test x$glib_cv_has__inline__ = xyes; then
3646     glib_inline="\$glib_inline
3647 #define G_HAVE___INLINE__ 1"
3648 fi
3649
3650 g_have_gnuc_varargs=$g_have_gnuc_varargs
3651 g_have_iso_c_varargs=$g_have_iso_c_varargs
3652 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3653
3654 g_can_inline=$g_can_inline
3655 g_have_gnuc_visibility=$g_have_gnuc_visibility
3656 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3657
3658 if test x$ac_cv_c_bigendian = xyes; then
3659   g_byte_order=G_BIG_ENDIAN
3660   g_bs_native=BE
3661   g_bs_alien=LE
3662 else
3663   g_byte_order=G_LITTLE_ENDIAN
3664   g_bs_native=LE
3665   g_bs_alien=BE
3666 fi
3667
3668 g_pollin=$glib_cv_value_POLLIN
3669 g_pollout=$glib_cv_value_POLLOUT
3670 g_pollpri=$glib_cv_value_POLLPRI
3671 g_pollhup=$glib_cv_value_POLLHUP
3672 g_pollerr=$glib_cv_value_POLLERR
3673 g_pollnval=$glib_cv_value_POLLNVAL
3674
3675 g_af_unix=$glib_cv_value_AF_UNIX
3676 g_af_inet=$glib_cv_value_AF_INET
3677 g_af_inet6=$glib_cv_value_AF_INET6
3678
3679 g_msg_peek=$glib_cv_value_MSG_PEEK
3680 g_msg_oob=$glib_cv_value_MSG_OOB
3681 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3682
3683 g_stack_grows=$glib_cv_stack_grows
3684
3685 g_have_eilseq=$have_eilseq
3686
3687 case x$have_threads in
3688 xno)    g_enable_threads_def="#undef";;
3689 *)      g_enable_threads_def="#define";;
3690 esac
3691
3692 g_threads_impl_def=$g_threads_impl
3693
3694 g_mutex_has_default="$mutex_has_default"
3695 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3696 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3697 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3698
3699 g_memory_barrier_needed="$glib_memory_barrier_needed"
3700 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3701
3702 g_module_suffix="$glib_gmodule_suffix"
3703
3704 g_pid_type="$glib_pid_type"
3705 case $host in
3706   *-*-beos*)
3707     glib_os="#define G_OS_BEOS"
3708     ;;
3709   *-*-cygwin*)
3710     glib_os="#define G_OS_UNIX
3711 #define G_PLATFORM_WIN32
3712 #define G_WITH_CYGWIN"
3713     ;;
3714   *-*-mingw*)
3715     glib_os="#define G_OS_WIN32
3716 #define G_PLATFORM_WIN32"
3717     ;;
3718   *)
3719     glib_os="#define G_OS_UNIX"
3720     ;;
3721 esac
3722 glib_static_compilation=""
3723 if test x$glib_win32_static_compilation = xyes; then
3724   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3725 #define GOBJECT_STATIC_COMPILATION 1"
3726 fi
3727 ])
3728
3729 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3730 #
3731 # 1.2.14 required for dbus_message_set_serial
3732 PKG_CHECK_MODULES(DBUS1,
3733                   dbus-1 >= 1.2.14,
3734                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3735                   have_dbus1=no)
3736 AC_SUBST(DBUS1_CFLAGS)
3737 AC_SUBST(DBUS1_LIBS)
3738 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3739
3740 dnl
3741 dnl Check for -Bsymbolic-functions linker flag used to avoid
3742 dnl intra-library PLT jumps, if available.
3743 dnl
3744
3745 AC_ARG_ENABLE(Bsymbolic,
3746               [AC_HELP_STRING([--disable-Bsymbolic],
3747                               [avoid linking with -Bsymbolic])],,
3748               [SAVED_LDFLAGS="${LDFLAGS}"
3749                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3750                LDFLAGS=-Wl,-Bsymbolic-functions
3751                AC_TRY_LINK([], [int main (void) { return 0; }],
3752                            AC_MSG_RESULT(yes)
3753                            enable_Bsymbolic=yes,
3754                            AC_MSG_RESULT(no)
3755                            enable_Bsymbolic=no)
3756                LDFLAGS="${SAVED_LDFLAGS}"])
3757
3758 if test "x${enable_Bsymbolic}" == "xyes"; then
3759   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3760 fi
3761
3762 AC_SUBST(GLIB_LINK_FLAGS)
3763
3764 #
3765 # Define variables corresponding to the correct include paths to use for
3766 # in-tree building.
3767 #
3768
3769 # for config.h:
3770 config_h_INCLUDES='-I$(top_builddir)'
3771 AC_SUBST(config_h_INCLUDES)
3772
3773 # glib:
3774 #   config.h
3775 #   $(top_builddir)/glib: for glibconfig.h
3776 #   $(top_srcdir)/glib:   for glib.h
3777 #   $(top_srcdir):        for everything
3778 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3779 AC_SUBST(glib_INCLUDES)
3780
3781 # gthread:
3782 #   same as glib
3783 gthread_INCLUDES='$(glib_INCLUDES)'
3784 AC_SUBST(gthread_INCLUDES)
3785
3786 # gobject:
3787 #   same as gthread
3788 gobject_INCLUDES='$(gthread_INCLUDES)'
3789 AC_SUBST(gobject_INCLUDES)
3790
3791 # gmodule:
3792 #   glib includes
3793 #   $(top_srcdir)/gmodule: for gmodule.h
3794 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3795 AC_SUBST(gmodule_INCLUDES)
3796
3797 # gio:
3798 #   same as gmodule
3799 gio_INCLUDES='$(gmodule_INCLUDES)'
3800 AC_SUBST(gio_INCLUDES)
3801
3802
3803 AC_CONFIG_FILES([
3804 glib-2.0.pc
3805 glib-2.0-uninstalled.pc
3806 gmodule-2.0.pc
3807 gmodule-export-2.0.pc
3808 gmodule-no-export-2.0.pc
3809 gmodule-2.0-uninstalled.pc
3810 gmodule-no-export-2.0-uninstalled.pc
3811 gthread-2.0.pc
3812 gthread-2.0-uninstalled.pc
3813 gobject-2.0.pc
3814 gobject-2.0-uninstalled.pc
3815 gio-2.0.pc
3816 gio-unix-2.0.pc
3817 gio-windows-2.0.pc
3818 gio-2.0-uninstalled.pc
3819 gio-unix-2.0-uninstalled.pc
3820 glib-zip
3821 glib-gettextize
3822 Makefile
3823 build/Makefile
3824 build/win32/Makefile
3825 build/win32/dirent/Makefile
3826 build/win32/vs9/Makefile
3827 build/win32/vs10/Makefile
3828 glib/Makefile
3829 glib/glib.stp
3830 glib/libcharset/Makefile
3831 glib/gnulib/Makefile
3832 glib/pcre/Makefile
3833 glib/update-pcre/Makefile
3834 glib/tests/Makefile
3835 gmodule/Makefile
3836 gmodule/gmoduleconf.h
3837 gobject/Makefile
3838 gobject/gobject.stp
3839 gobject/glib-mkenums
3840 gobject/tests/Makefile
3841 gthread/Makefile
3842 gthread/tests/Makefile
3843 gio/Makefile
3844 gio/gdbus-2.0/codegen/Makefile
3845 gio/gdbus-2.0/codegen/config.py
3846 gio/xdgmime/Makefile
3847 gio/inotify/Makefile
3848 gio/libasyncns/Makefile
3849 gio/fen/Makefile
3850 gio/fam/Makefile
3851 gio/win32/Makefile
3852 gio/tests/Makefile
3853 gio/tests/gdbus-object-manager-example/Makefile
3854 po/Makefile.in
3855 docs/Makefile
3856 docs/reference/Makefile
3857 docs/reference/glib/Makefile
3858 docs/reference/glib/version.xml
3859 docs/reference/gobject/Makefile
3860 docs/reference/gobject/version.xml
3861 docs/reference/gio/Makefile
3862 docs/reference/gio/gdbus-object-manager-example/Makefile
3863 docs/reference/gio/version.xml
3864 tests/Makefile
3865 tests/gobject/Makefile
3866 tests/refcount/Makefile
3867 m4macros/Makefile
3868 ])
3869
3870 AC_CONFIG_COMMANDS([chmod-scripts],
3871 [chmod 0755 glib-zip
3872 chmod 0755 glib-gettextize
3873 chmod 0755 gobject/glib-mkenums])
3874
3875 # we want to invoke this macro solely so that the config.status script
3876 # and automake generated makefiles know about these generated files.
3877 # They are only needed to distcheck the package
3878 if false; then
3879   AC_CONFIG_FILES([
3880     INSTALL
3881     README
3882     config.h.win32
3883     glib/glibconfig.h.win32
3884     glib/makefile.msc
3885     glib/glib.rc
3886     gmodule/makefile.msc
3887     gmodule/gmodule.rc
3888     gobject/makefile.msc
3889     gobject/gobject.rc
3890     gthread/makefile.msc
3891     gthread/gthread.rc
3892     gio/gio.rc
3893     tests/makefile.msc
3894   ])
3895 fi
3896
3897 AC_OUTPUT