configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [31])
  30 m4_define([glib_micro_version], [0])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(rebuilds,
 229               [AC_HELP_STRING([--disable-rebuilds],
 230                               [disable all source autogeneration rules])],,
 231               [enable_rebuilds=yes])
 232
 233 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 234 if test "x$enable_gc_friendly" = "xyes"; then
 235   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 236   AC_MSG_RESULT([yes])
 237 else
 238   AC_MSG_RESULT([no])
 239 fi
 240
 241 AC_MSG_CHECKING([whether to disable memory pools])
 242 if test "x$disable_mem_pools" = "xno"; then
 243   AC_MSG_RESULT([no])
 244 else
 245   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 246   AC_SUBST(DISABLE_MEM_POOLS)
 247   AC_MSG_RESULT([yes])
 248 fi
 249
 250 dnl location to install runtime libraries, e.g. ../../lib to install
 251 dnl to /lib if libdir is /usr/lib
 252 AC_ARG_WITH(runtime-libdir,
 253            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 254                            [install runtime libraries relative to libdir])],
 255            [],
 256            [with_runtime_libdir=""])
 257 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 258 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 259 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 260 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 261 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 262
 263 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 264 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 265 AC_LANG_SAVE
 266 AC_LANG_CPLUSPLUS
 267 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 268 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 269 AC_LANG_RESTORE
 270
 271 AM_PROG_CC_STDC
 272 AM_PROG_CC_C_O
 273 AC_PROG_INSTALL
 274
 275 AC_SYS_LARGEFILE
 276
 277 PKG_PROG_PKG_CONFIG(0.16)
 278
 279 if test "x$enable_debug" = "xyes"; then
 280   if test x$cflags_set != xset ; then
 281       case " $CFLAGS " in
 282       *[[\ \    ]]-g[[\ \       ]]*) ;;
 283       *) CFLAGS="$CFLAGS -g" ;;
 284       esac
 285   fi
 286
 287   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 288 else
 289   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 290
 291   if test "x$enable_debug" = "xno"; then
 292     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 293   fi
 294 fi
 295
 296 # Ensure MSVC-compatible struct packing convention is used when
 297 # compiling for Win32 with gcc.
 298 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 299 # gcc2 uses "-fnative-struct".
 300 if test x"$glib_native_win32" = xyes; then
 301   if test x"$GCC" = xyes; then
 302     msnative_struct=''
 303     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 304     if test -z "$ac_cv_prog_CC"; then
 305       our_gcc="$CC"
 306     else
 307       our_gcc="$ac_cv_prog_CC"
 308     fi
 309     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 310       2.)
 311         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 312           msnative_struct='-fnative-struct'
 313         fi
 314         ;;
 315       *)
 316         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 317           msnative_struct='-mms-bitfields'
 318         fi
 319         ;;
 320     esac
 321     if test x"$msnative_struct" = x ; then
 322       AC_MSG_RESULT([no way])
 323       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 324     else
 325       CFLAGS="$CFLAGS $msnative_struct"
 326       AC_MSG_RESULT([${msnative_struct}])
 327     fi
 328   fi
 329 fi
 330 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 331 AC_SUBST(GLIB_EXTRA_CFLAGS)
 332
 333 AC_EXEEXT
 334
 335 # define a MAINT-like variable REBUILD which is set if Perl
 336 # and awk are found, so autogenerated sources can be rebuilt
 337 AC_PROG_AWK
 338 AC_CHECK_PROGS(PERL, [perl5 perl])
 339 # We would like indent, but don't require it.
 340 AC_CHECK_PROG(INDENT, indent, indent)
 341 REBUILD=\#
 342 if test "x$enable_rebuilds" = "xyes" && \
 343      test -n "$PERL" && \
 344      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 345      test -n "$AWK" ; then
 346   REBUILD=
 347 fi
 348 AC_SUBST(REBUILD)
 349
 350 # Need full path to Perl for glib-mkenums
 351 #
 352 if test "x$PERL" != x ; then
 353   AC_PATH_PROG(PERL_PATH, [$PERL])
 354 fi
 355 if test "x$PERL_PATH" = x ; then
 356   PERL_PATH="/usr/bin/env perl"
 357 fi
 358 AC_SUBST(PERL_PATH)
 359
 360 # Need suitable python path for greport
 361 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 362
 363
 364 dnl ***********************
 365 dnl *** Tests for iconv ***
 366 dnl ***********************
 367 dnl
 368 dnl We do this before the gettext checks, to avoid distortion
 369
 370 dnl On Windows we use a native implementation
 371
 372 if test x"$glib_native_win32" = xyes; then
 373   with_libiconv=native
 374 else
 375   AC_ARG_WITH(libiconv,
 376               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 377                               [use the libiconv library])],,
 378               [with_libiconv=maybe])
 379
 380   found_iconv=no
 381   case $with_libiconv in
 382     maybe)
 383       # Check in the C library first
 384       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385       # Check if we have GNU libiconv
 386       if test $found_iconv = "no"; then
 387         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388       fi
 389       # Check if we have a iconv in -liconv, possibly from vendor
 390       if test $found_iconv = "no"; then
 391         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 392       fi
 393       ;;
 394     no)
 395       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 396       ;;
 397     gnu|yes)
 398       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 399       ;;
 400     native)
 401       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 402       ;;
 403   esac
 404
 405   if test "x$found_iconv" = "xno" ; then
 406      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 407   fi
 408 fi
 409
 410 AC_ARG_ENABLE(iconv-cache,
 411               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 412                               [cache iconv descriptors [default=auto]])],,
 413               [enable_iconv_cache=auto])
 414
 415 AC_MSG_CHECKING([whether to cache iconv descriptors])
 416 case $enable_iconv_cache in
 417   auto)
 418     if test $ac_cv_gnu_library_2_1 = yes; then
 419       enable_iconv_cache=no
 420     else
 421       enable_iconv_cache=yes
 422     fi
 423   ;;
 424   yes|no)
 425   ;;
 426   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 427   ;;
 428 esac
 429
 430 if test $enable_iconv_cache = yes; then
 431    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 432 fi
 433
 434 AC_MSG_RESULT($enable_iconv_cache)
 435
 436
 437 dnl
 438 dnl zlib support
 439 dnl
 440 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 441 if test "x$found_zlib" = "xno" ; then
 442   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 443   if test "x$found_zlib" = "xno" ; then
 444     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 445   fi
 446   ZLIB_LIBS='-lz'
 447   AC_SUBST(ZLIB_LIBS)
 448 fi
 449
 450 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 451 AC_SUBST(LIBFFI_CFLAGS)
 452 AC_SUBST(LIBFFI_LIBS)
 453
 454 dnl
 455 dnl gettext support
 456 dnl
 457
 458 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 459 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 460 GLIB_GNU_GETTEXT
 461
 462 if test "$gt_cv_have_gettext" != "yes" ; then
 463   AC_MSG_ERROR([
 464 *** You must have either have gettext support in your C library, or use the
 465 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 466 ])
 467 fi
 468
 469 LIBS="$INTLLIBS $LIBS"
 470
 471 GETTEXT_PACKAGE=glib20
 472 AC_SUBST(GETTEXT_PACKAGE)
 473 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 474   [Define the gettext package to be used])
 475
 476 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 477
 478 dnl
 479 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 480 dnl
 481
 482 if test x"$glib_native_win32" != xyes; then
 483   if test x$with_libiconv != xno ; then
 484     case " $INTLLIBS " in
 485     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 486     *) ICONV_LIBS="-liconv" ;;
 487     esac
 488   fi
 489 fi
 490 AC_SUBST(ICONV_LIBS)
 491
 492 case $with_libiconv in
 493   gnu)
 494     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 495     ;;
 496   native)
 497     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 498     ;;
 499 esac
 500
 501 dnl Initialize libtool
 502 LT_PREREQ([2.2])
 503 LT_INIT([disable-static win32-dll])
 504 dnl when using libtool 2.x create libtool early, because it's used in configure
 505 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 506
 507
 508 if test "x$GCC" = "xyes"; then
 509   case " $CFLAGS " in
 510   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 511   *) CFLAGS="$CFLAGS -Wall" ;;
 512   esac
 513 fi
 514
 515 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 516
 517 if test "$glib_native_win32" = "yes"; then
 518   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 519     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 520   fi
 521   if test x$enable_static = xyes; then
 522     glib_win32_static_compilation=yes
 523     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 524 #define GOBJECT_STATIC_COMPILATION 1"
 525     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 526   fi
 527 fi
 528 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 529
 530 dnl
 531 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 532 dnl
 533 if test $cross_compiling != yes ; then
 534     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 535     glib_save_LIBS=$LIBS
 536     LIBS="$LIBS -lm"
 537     AC_TRY_RUN([#include <math.h>
 538                  int main (void) { return (log(1) != log(1.)); }],
 539          AC_MSG_RESULT(none needed),
 540          glib_save_CFLAGS=$CFLAGS
 541          CFLAGS="$CFLAGS -std1"
 542          AC_TRY_RUN([#include <math.h>
 543                      int main (void) { return (log(1) != log(1.)); }],
 544              AC_MSG_RESULT(-std1),
 545              AC_MSG_RESULT()
 546              CFLAGS=$glib_save_CFLAGS
 547              AC_MSG_WARN(
 548                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 549          )
 550     )
 551     LIBS=$glib_save_LIBS
 552 fi
 553
 554 dnl NeXTStep cc seems to need this
 555 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 556 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 557   AC_MSG_RESULT(none needed),
 558   glib_save_CFLAGS=$CFLAGS
 559   CFLAGS="$CFLAGS -posix"
 560   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 561     AC_MSG_RESULT(-posix),
 562     AC_MSG_RESULT()
 563     CFLAGS=$glib_save_CFLAGS
 564     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 565
 566 # Checks for header files.
 567 AC_HEADER_STDC
 568
 569 # Checks for library functions.
 570 AC_FUNC_VPRINTF
 571 AC_FUNC_ALLOCA
 572 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 573 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 574
 575 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 576 dnl be automatically defined, which we don't want to do
 577 dnl until we have checked this function is actually usable
 578 AC_CHECK_FUNC([qsort_r])
 579
 580 # BSD has a qsort_r with wrong argument order
 581 if test x$ac_cv_func_qsort_r = xyes ; then
 582   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 583   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 584   #define _GNU_SOURCE
 585   #include <stdlib.h>
 586
 587   static int
 588   cmp (const void *a, const void *b, void *c)
 589   {
 590     const int *ia = a;
 591     const int *ib = b;
 592
 593     if (*ia < *ib)
 594       return -1;
 595     else if (*ia > *ib)
 596       return 1;
 597     else
 598       return 0;
 599   }
 600
 601   int
 602   main (int argc, char **argv)
 603   {
 604     int arr[3] = { 1, 2, 0 };
 605     int d = 3;
 606
 607     qsort_r (arr, 3, sizeof (int), cmp, &d);
 608
 609     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 610       return 0;
 611     else
 612       return 1;
 613   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 614 fi
 615
 616 if test x$glib_cv_have_qsort_r = xyes ; then
 617   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 618 fi
 619
 620 AC_CHECK_SIZEOF(char)
 621 AC_CHECK_SIZEOF(short)
 622 AC_CHECK_SIZEOF(long)
 623 AC_CHECK_SIZEOF(int)
 624 AC_CHECK_SIZEOF(void *)
 625 AC_CHECK_SIZEOF(long long)
 626 AC_CHECK_SIZEOF(__int64)
 627
 628 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 629   :
 630 else
 631   AC_MSG_ERROR([
 632 *** GLib requires a 64 bit type. You might want to consider
 633 *** using the GNU C compiler.
 634 ])
 635 fi
 636
 637 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 638         # long long is a 64 bit integer.
 639         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 640         AC_CACHE_VAL(glib_cv_long_long_format,[
 641                 for format in ll q I64; do
 642                   AC_TRY_RUN([#include <stdio.h>
 643                         int main()
 644                         {
 645                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 646                           char buffer[1000];
 647                           sprintf (buffer, "%${format}u", a);
 648                           sscanf (buffer, "%${format}u", &b);
 649                           exit (b!=a);
 650                         }
 651                         ],
 652                         [glib_cv_long_long_format=${format}
 653                         break],
 654                         [],[:])
 655                 done])
 656         if test -n "$glib_cv_long_long_format"; then
 657           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 658           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 659           if test x"$glib_cv_long_long_format" = xI64; then
 660             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 661           fi
 662         else
 663           AC_MSG_RESULT(none)
 664         fi
 665 elif test x$ac_cv_sizeof___int64 = x8; then
 666         # __int64 is a 64 bit integer.
 667         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 668         # We know this is MSVCRT.DLL, and what the formats are
 669         glib_cv_long_long_format=I64
 670         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 671         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 672         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 673 fi
 674
 675 dnl long doubles were not used, and a portability problem
 676 dnl AC_C_LONG_DOUBLE
 677 AC_C_CONST
 678
 679 dnl ok, here we try to check whether the systems prototypes for
 680 dnl malloc and friends actually match the prototypes provided
 681 dnl by gmem.h (keep in sync). i currently only know how to check
 682 dnl this reliably with gcc (-Werror), improvements for other
 683 dnl compilers are apprechiated.
 684 SANE_MALLOC_PROTOS=no
 685 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 686 glib_save_CFLAGS=$CFLAGS
 687 if test "x$GCC" = "xyes"; then
 688   CFLAGS="$CFLAGS -Werror"
 689   AC_TRY_COMPILE([#include <stdlib.h>], [
 690     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 691     void* (*my_malloc_p)  (size_t)         = malloc;
 692     void  (*my_free_p)    (void*)          = free;
 693     void* (*my_realloc_p) (void*, size_t)  = realloc;
 694     my_calloc_p = 0;
 695     my_malloc_p = 0;
 696     my_free_p = 0;
 697     my_realloc_p = 0;
 698   ],
 699     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 700       [Define if you have correct malloc prototypes])
 701     SANE_MALLOC_PROTOS=yes)
 702 fi
 703 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 704 CFLAGS=$glib_save_CFLAGS
 705
 706 dnl
 707 dnl check in which direction the stack grows
 708 dnl
 709 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 710         AC_TRY_RUN([
 711         volatile int *a = 0, *b = 0;
 712         void foo (void);
 713         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 714         void foo (void) { volatile int x = 5; b = &x; }
 715         ],
 716         glib_cv_stack_grows=no
 717         ,
 718         glib_cv_stack_grows=yes
 719         ,)
 720 ])
 721
 722 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 723 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 724 dnl actually supported.
 725 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 726         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 727         __inline int foo () { return 0; }
 728         int main () { return foo (); }
 729         ]])],
 730         glib_cv_has__inline=yes
 731         ,
 732         glib_cv_has__inline=no
 733         ,)
 734 ])
 735 case x$glib_cv_has__inline in
 736 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 737 esac
 738 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 739         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 740         __inline__ int foo () { return 0; }
 741         int main () { return foo (); }
 742         ]])],
 743         glib_cv_has__inline__=yes
 744         ,
 745         glib_cv_has__inline__=no
 746         ,)
 747 ])
 748 case x$glib_cv_has__inline__ in
 749 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 750 esac
 751 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 752         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 753         #undef inline
 754         inline int foo () { return 0; }
 755         int main () { return foo (); }
 756         ]])],
 757         glib_cv_hasinline=yes
 758         ,
 759         glib_cv_hasinline=no
 760         ,)
 761 ])
 762 case x$glib_cv_hasinline in
 763 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 764 esac
 765
 766 # if we can use inline functions in headers
 767 AC_MSG_CHECKING(if inline functions in headers work)
 768 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 769 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 770 #  undef inline
 771 #  define inline __inline__
 772 #elif !defined (G_HAVE_INLINE)
 773 #  undef inline
 774 #  if defined (G_HAVE___INLINE__)
 775 #    define inline __inline__
 776 #  elif defined (G_HAVE___INLINE)
 777 #    define inline __inline
 778 #  endif
 779 #endif
 780
 781 int glib_test_func2 (int);
 782
 783 static inline int
 784 glib_test_func1 (void) {
 785   return glib_test_func2 (1);
 786 }
 787
 788 int
 789 main (void) {
 790   int i = 1;
 791 }]])],[g_can_inline=yes],[g_can_inline=no])
 792 AC_MSG_RESULT($g_can_inline)
 793
 794 dnl *** check for working do while(0) macros ***
 795 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 796         AC_TRY_COMPILE([],[
 797         #define STMT_START do
 798         #define STMT_END while(0)
 799         #define STMT_TEST STMT_START { i = 0; } STMT_END
 800         int main(void) { int i = 1; STMT_TEST; return i; }],
 801         [g_cv_support_dowhile_macros=yes],
 802         [g_cv_support_dowhile_macros=no],
 803         [g_cv_support_dowhile_macros=yes])
 804 ])
 805 if test x$g_cv_support_dowhile_macros = xyes; then
 806   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 807 fi
 808
 809 # check for flavours of varargs macros
 810 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 811 AC_TRY_COMPILE([],[
 812 int a(int p1, int p2, int p3);
 813 #define call_a(...) a(1,__VA_ARGS__)
 814 call_a(2,3);
 815 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 816 AC_MSG_RESULT($g_have_iso_c_varargs)
 817
 818 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 819 if test "$CXX" = ""; then
 820 dnl No C++ compiler
 821   g_have_iso_cxx_varargs=no
 822 else
 823   AC_LANG_CPLUSPLUS
 824   AC_TRY_COMPILE([],[
 825 int a(int p1, int p2, int p3);
 826 #define call_a(...) a(1,__VA_ARGS__)
 827 call_a(2,3);
 828 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 829   AC_LANG_C
 830 fi
 831 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 832
 833 AC_MSG_CHECKING(for GNUC varargs macros)
 834 AC_TRY_COMPILE([],[
 835 int a(int p1, int p2, int p3);
 836 #define call_a(params...) a(1,params)
 837 call_a(2,3);
 838 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 839 AC_MSG_RESULT($g_have_gnuc_varargs)
 840
 841 # check for GNUC visibility support
 842 AC_MSG_CHECKING(for GNUC visibility attribute)
 843 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 844 void
 845 __attribute__ ((visibility ("hidden")))
 846      f_hidden (void)
 847 {
 848 }
 849 void
 850 __attribute__ ((visibility ("internal")))
 851      f_internal (void)
 852 {
 853 }
 854 void
 855 __attribute__ ((visibility ("protected")))
 856      f_protected (void)
 857 {
 858 }
 859 void
 860 __attribute__ ((visibility ("default")))
 861      f_default (void)
 862 {
 863 }
 864 int main (int argc, char **argv)
 865 {
 866         f_hidden();
 867         f_internal();
 868         f_protected();
 869         f_default();
 870         return 0;
 871 }
 872 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 873 AC_MSG_RESULT($g_have_gnuc_visibility)
 874 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 875
 876 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 877 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 878 #else
 879 # include "error: this is not Sun Studio."
 880 #endif
 881 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 882 AC_MSG_RESULT($g_have_sunstudio_visibility)
 883 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 884
 885 # check for bytesex stuff
 886 AC_C_BIGENDIAN
 887 if test x$ac_cv_c_bigendian = xuniversal ; then
 888 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 889 #else
 890 #error Not a big endian.
 891 #endif],
 892     ac_cv_c_bigendian=yes
 893     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 894 #else
 895 #error Not a little endian.
 896 #endif],
 897     ac_cv_c_bigendian=no
 898     ,AC_MSG_WARN([Could not determine endianness.])))
 899 fi
 900
 901
 902 # check for header files
 903 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 904 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 905 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 906 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 907 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 908 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 909 AC_CHECK_HEADERS([linux/magic.h])
 910 AC_CHECK_HEADERS([sys/prctl.h])
 911
 912 # check for structure fields
 913 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 914 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 915 #include <sys/stat.h>
 916 #include <unistd.h>
 917 #ifdef HAVE_SYS_STATFS_H
 918 #include <sys/statfs.h>
 919 #endif
 920 #ifdef HAVE_SYS_PARAM_H
 921 #include <sys/param.h>
 922 #endif
 923 #ifdef HAVE_SYS_MOUNT_H
 924 #include <sys/mount.h>
 925 #endif])
 926 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 927 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 928 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 929 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 930
 931 # Checks for libcharset
 932 AM_LANGINFO_CODESET
 933 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 934 AC_CHECK_FUNCS(setlocale)
 935
 936 # check additional type sizes
 937 AC_CHECK_SIZEOF(size_t)
 938
 939 dnl Try to figure out whether gsize, gssize should be long or int
 940 AC_MSG_CHECKING([for the appropriate definition for size_t])
 941
 942 case $ac_cv_sizeof_size_t in
 943   $ac_cv_sizeof_short)
 944       glib_size_type=short
 945       ;;
 946   $ac_cv_sizeof_int)
 947       glib_size_type=int
 948       ;;
 949   $ac_cv_sizeof_long)
 950       glib_size_type=long
 951       ;;
 952   $ac_cv_sizeof_long_long)
 953       glib_size_type='long long'
 954       ;;
 955   $ac_cv_sizeof__int64)
 956       glib_size_type='__int64'
 957       ;;
 958   *)  AC_MSG_ERROR([No type matching size_t in size])
 959       ;;
 960 esac
 961
 962 dnl If int/long are the same size, we see which one produces
 963 dnl warnings when used in the location as size_t. (This matters
 964 dnl on AIX with xlc)
 965 dnl
 966 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 967    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 968   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 969 #if defined(_AIX) && !defined(__GNUC__)
 970 #pragma options langlvl=stdc89
 971 #endif
 972 #include <stddef.h>
 973 int main ()
 974 {
 975   size_t s = 1;
 976   unsigned int *size_int = &s;
 977   return (int)*size_int;
 978 }
 979     ]])],glib_size_type=int,
 980       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 981 #if defined(_AIX) && !defined(__GNUC__)
 982 #pragma options langlvl=stdc89
 983 #endif
 984 #include <stddef.h>
 985 int main ()
 986 {
 987    size_t s = 1;
 988    unsigned long *size_long = &s;
 989    return (int)*size_long;
 990 }
 991         ]])],glib_size_type=long)])
 992 fi
 993
 994 AC_MSG_RESULT(unsigned $glib_size_type)
 995
 996 # Check for some functions
 997 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 998 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
 999 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1000 # Check for high-resolution sleep functions
1001 AC_CHECK_FUNCS(splice)
1002 AC_CHECK_FUNCS(prlimit)
1003
1004 # To avoid finding a compatibility unusable statfs, which typically
1005 # successfully compiles, but warns to use the newer statvfs interface:
1006 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1007 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1008
1009 AC_MSG_CHECKING([whether to use statfs or statvfs])
1010 # Some systems have both statfs and statvfs, pick the most "native" for these
1011 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1012    [
1013    # on solaris and irix, statfs doesn't even have the f_bavail field
1014    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1015       [ac_cv_func_statfs=no],
1016    # else, at least on linux, statfs is the actual syscall
1017       [ac_cv_func_statvfs=no])
1018    ])
1019
1020 AS_IF([test x$ac_cv_func_statfs = xyes],
1021       [
1022          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1023          AC_MSG_RESULT([statfs])
1024       ],
1025       [test x$ac_cv_func_statvfs = xyes],
1026       [
1027          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1028          AC_MSG_RESULT([statvfs])
1029       ],
1030       [  AC_MSG_RESULT([neither])])
1031
1032 AC_CHECK_HEADERS(crt_externs.h)
1033 AC_CHECK_FUNCS(_NSGetEnviron)
1034
1035 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1036
1037 AC_FUNC_VSNPRINTF_C99
1038 AC_FUNC_PRINTF_UNIX98
1039
1040 # Internet address families
1041 if test $glib_native_win32 = yes; then
1042   glib_inet_includes=["
1043 #include <winsock2.h>
1044   "]
1045 else
1046   glib_inet_includes=["
1047 #include <sys/types.h>
1048 #include <sys/socket.h>
1049   "]
1050 fi
1051
1052 glib_failed=false
1053 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1054 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1055 # winsock defines this even though it doesn't support it
1056 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1057 if $glib_failed ; then
1058   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1059 fi
1060
1061 glib_failed=false
1062 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1063 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1064 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1065 if $glib_failed ; then
1066   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1067 fi
1068
1069 AC_CHECK_FUNCS(getprotobyname_r endservent)
1070 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1071
1072 if test $glib_native_win32 = no; then
1073   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1074   NETWORK_LIBS=""
1075   AC_MSG_CHECKING([for res_query])
1076   AC_TRY_LINK([#include <sys/types.h>
1077                #include <netinet/in.h>
1078                #include <arpa/nameser.h>
1079                #include <resolv.h>
1080               ],[
1081                res_query("test", 0, 0, (void *)0, 0);
1082               ],[AC_MSG_RESULT([yes])],
1083               [save_libs="$LIBS"
1084                LIBS="-lresolv $LIBS"
1085                AC_TRY_LINK([#include <sys/types.h>
1086                             #include <netinet/in.h>
1087                             #include <arpa/nameser.h>
1088                             #include <resolv.h>
1089                            ],[
1090                             res_query("test", 0, 0, (void *)0, 0);
1091                            ],[AC_MSG_RESULT([in -lresolv])
1092                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1093                            [LIBS="-lbind $save_libs"
1094                             AC_TRY_LINK([#include <resolv.h>],
1095                                         [res_query("test", 0, 0, (void *)0, 0);],
1096                                         [AC_MSG_RESULT([in -lbind])
1097                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1098                                         [AC_MSG_ERROR(not found)])])
1099                LIBS="$save_libs"])
1100   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1101                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1102                                         [AC_MSG_ERROR(Could not find socket())]))
1103 fi
1104 AC_SUBST(NETWORK_LIBS)
1105
1106 case $host in
1107   *-*-solaris* )
1108      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1109      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1110      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1111      ;;
1112 esac
1113
1114 dnl
1115 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1116 dnl
1117 if test "$ac_cv_func_statfs" = yes ; then
1118   AC_MSG_CHECKING([number of arguments to statfs()])
1119   AC_TRY_COMPILE([#include <unistd.h>
1120   #ifdef HAVE_SYS_PARAM_H
1121   #include <sys/param.h>
1122   #endif
1123   #ifdef HAVE_SYS_VFS_H
1124   #include <sys/vfs.h>
1125   #endif
1126   #ifdef HAVE_SYS_MOUNT_H
1127   #include <sys/mount.h>
1128   #endif
1129   #ifdef HAVE_SYS_STATFS_H
1130   #include <sys/statfs.h>
1131   #endif], [struct statfs st;
1132   statfs(NULL, &st);],[
1133     AC_MSG_RESULT([2])
1134     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1135     AC_TRY_COMPILE([#include <unistd.h>
1136   #ifdef HAVE_SYS_PARAM_H
1137   #include <sys/param.h>
1138   #endif
1139   #ifdef HAVE_SYS_VFS_H
1140   #include <sys/vfs.h>
1141   #endif
1142   #ifdef HAVE_SYS_MOUNT_H
1143   #include <sys/mount.h>
1144   #endif
1145   #ifdef HAVE_SYS_STATFS_H
1146   #include <sys/statfs.h>
1147   #endif], [struct statfs st;
1148   statfs(NULL, &st, sizeof (st), 0);],[
1149       AC_MSG_RESULT([4])
1150       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1151       AC_MSG_RESULT(unknown)
1152       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1153 fi
1154
1155 #
1156 # Check whether to use an included printf
1157 #
1158
1159 AC_ARG_ENABLE(included-printf,
1160               [AC_HELP_STRING([--enable-included-printf],
1161                               [use included printf [default=auto]])],
1162               enable_included_printf="$enableval")
1163
1164 need_included_printf=no
1165 if test "x$enable_included_printf" = "xyes" ; then
1166   need_included_printf=yes
1167 fi
1168 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1169   need_included_printf=yes
1170 fi
1171 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1172   need_included_printf=yes
1173 fi
1174 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1175    test -z "$glib_cv_long_long_format" ; then
1176   need_included_printf=yes
1177 fi
1178
1179 if test "x$enable_included_printf" = "xno" &&
1180    test "x$need_included_printf" = "xyes" ; then
1181   AC_MSG_ERROR([
1182 *** Your C library's printf doesn't appear to have the features that
1183 *** GLib needs, but you specified --enable-included-printf=no.])
1184 fi
1185
1186 enable_included_printf=$need_included_printf
1187
1188 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1189 if test "$enable_included_printf" != "yes" ; then
1190   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1191 else
1192   if test -z "$glib_cv_long_long_format" ; then
1193     glib_cv_long_long_format="ll"
1194   fi
1195   AC_DEFINE(HAVE_VASPRINTF,1)
1196 fi
1197
1198 # Checks needed for gnulib vasnprintf
1199 bh_C_SIGNED
1200 jm_AC_TYPE_LONG_LONG
1201 gt_TYPE_LONGDOUBLE
1202 gt_TYPE_WCHAR_T
1203 gt_TYPE_WINT_T
1204 AC_TYPE_SIZE_T
1205 AC_CHECK_TYPES(ptrdiff_t)
1206 jm_AC_TYPE_INTMAX_T
1207 AC_CHECK_FUNCS([snprintf wcslen])
1208 AC_FUNC_SNPRINTF_C99
1209
1210 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1211 # The check is borrowed from the PERL Configure script.
1212 if test "$ac_cv_func_memmove" != "yes"; then
1213   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1214     glib_cv_working_bcopy,[AC_TRY_RUN([
1215       int main() {
1216         char buf[128], abc[128], *b;
1217         int len, off, align;
1218         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1219         for (align = 7; align >= 0; align--) {
1220           for (len = 36; len; len--) {
1221             b = buf+align; bcopy(abc, b, len);
1222             for (off = 1; off <= len; off++) {
1223               bcopy(b, b+off, len); bcopy(b+off, b, len);
1224                 if (bcmp(b, abc, len)) return(1);
1225             }
1226           }
1227         }
1228         return(0);
1229       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1230
1231   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1232   if test "$glib_cv_working_bcopy" = "yes"; then
1233     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1234   fi
1235 fi
1236
1237 # Check if <sys/select.h> needs to be included for fd_set
1238 AC_MSG_CHECKING([for fd_set])
1239 AC_TRY_COMPILE([#include <sys/types.h>],
1240         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1241 if test "$gtk_ok" = "yes"; then
1242     AC_MSG_RESULT([yes, found in sys/types.h])
1243 else
1244     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1245     if test "$gtk_ok" = "yes"; then
1246         # *** FIXME: give it a different name
1247         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1248         AC_MSG_RESULT([yes, found in sys/select.h])
1249     else
1250         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1251         AC_MSG_RESULT(no)
1252     fi
1253 fi
1254
1255 dnl *** check for sane realloc() ***
1256 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1257         AC_TRY_RUN([#include <stdlib.h>
1258         int main() {
1259           return realloc (0, sizeof (int)) == 0;
1260         }],
1261         [glib_cv_sane_realloc=yes],
1262         [glib_cv_sane_realloc=no],
1263         [glib_cv_sane_realloc=yes])
1264 ])
1265 if test x$glib_cv_sane_realloc = xyes; then
1266   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1267 fi
1268
1269 dnl Check for nl_langinfo and CODESET
1270 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1271         AC_TRY_COMPILE([#include <langinfo.h>],
1272                 [char *codeset = nl_langinfo (CODESET);],
1273                 [glib_cv_langinfo_codeset=yes],
1274                 [glib_cv_langinfo_codeset=no])])
1275 if test x$glib_cv_langinfo_codeset = xyes; then
1276   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1277 fi
1278
1279 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1280 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1281         AC_TRY_COMPILE([#include <langinfo.h>],
1282                 [char *str;
1283                  str = nl_langinfo (PM_STR);
1284                  str = nl_langinfo (D_T_FMT);
1285                  str = nl_langinfo (D_FMT);
1286                  str = nl_langinfo (T_FMT);
1287                  str = nl_langinfo (T_FMT_AMPM);
1288                  str = nl_langinfo (MON_1);
1289                  str = nl_langinfo (ABMON_12);
1290                  str = nl_langinfo (DAY_1);
1291                  str = nl_langinfo (ABDAY_7);],
1292                 [glib_cv_langinfo_time=yes],
1293                 [glib_cv_langinfo_time=no])])
1294 if test x$glib_cv_langinfo_time = xyes; then
1295   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1296 fi
1297
1298 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1299 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1300         AC_TRY_COMPILE([#include <langinfo.h>],
1301                 [char *str;
1302                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1303                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1304                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1305                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1306                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1307                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1308                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1309                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1310                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1311                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1312                 [glib_cv_langinfo_outdigit=yes],
1313                 [glib_cv_langinfo_outdigit=no])])
1314 if test x$glib_cv_langinfo_outdigit = xyes; then
1315   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1316 fi
1317
1318 dnl ****************************************
1319 dnl *** posix_memalign                   ***
1320 dnl ****************************************
1321 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1322 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1323     glib_cv_compliant_posix_memalign=0
1324     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1325         AC_TRY_RUN([
1326                 #define _XOPEN_SOURCE 600
1327                 #include <stdlib.h> /* posix_memalign() should be defined here */
1328                 /* some systems break if #include <malloc.h> used */
1329                 static void test_memalign (size_t boundary, size_t size) {
1330                     void *mem = 0;
1331                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1332                         exit (1);
1333                     else
1334                       free (mem);
1335                 }
1336                 int main() {
1337                     test_memalign (  128,   128 - 2 * sizeof (void*));
1338                     test_memalign (  256,   256 - 2 * sizeof (void*));
1339                     test_memalign (  512,   512 - 2 * sizeof (void*));
1340                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1341                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1342                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1343                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1344                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1345                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1346                     exit (0); /* success */
1347                 }
1348                 ],
1349             [glib_cv_compliant_posix_memalign=1], [], [:])
1350       :
1351     fi
1352     ])
1353 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1354     AC_MSG_RESULT(yes)
1355     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1356 else
1357     AC_MSG_RESULT(no)
1358 fi
1359
1360
1361 dnl ****************************************
1362 dnl *** strlcpy/strlcat                  ***
1363 dnl ****************************************
1364 # Check for strlcpy
1365 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1366 AC_TRY_RUN([#include <stdlib.h>
1367 #include <string.h>
1368 int main() {
1369   char p[10];
1370   (void) strlcpy (p, "hi", 10);
1371   if (strlcat (p, "bye", 0) != 3)
1372     return 1;
1373   return 0;
1374 }], glib_cv_have_strlcpy=yes,
1375     glib_cv_have_strlcpy=no,
1376     glib_cv_have_strlcpy=no)])
1377 if test "$glib_cv_have_strlcpy" = "yes"; then
1378     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1379 fi
1380
1381
1382 dnl **********************
1383 dnl *** va_copy checks ***
1384 dnl **********************
1385 dnl we currently check for all three va_copy possibilities, so we get
1386 dnl all results in config.log for bug reports.
1387 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1388         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1389 #include <stdlib.h>
1390         void f (int i, ...) {
1391         va_list args1, args2;
1392         va_start (args1, i);
1393         va_copy (args2, args1);
1394         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1395           exit (1);
1396         va_end (args1); va_end (args2);
1397         }
1398         int main() {
1399           f (0, 42);
1400           return 0;
1401         }]])],
1402         [glib_cv_va_copy=yes],
1403         [glib_cv_va_copy=no])
1404 ])
1405 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1406         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1407 #include <stdlib.h>
1408         void f (int i, ...) {
1409         va_list args1, args2;
1410         va_start (args1, i);
1411         __va_copy (args2, args1);
1412         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1413           exit (1);
1414         va_end (args1); va_end (args2);
1415         }
1416         int main() {
1417           f (0, 42);
1418           return 0;
1419         }]])],
1420         [glib_cv___va_copy=yes],
1421         [glib_cv___va_copy=no])
1422 ])
1423
1424 if test "x$glib_cv_va_copy" = "xyes"; then
1425   g_va_copy_func=va_copy
1426 else if test "x$glib_cv___va_copy" = "xyes"; then
1427   g_va_copy_func=__va_copy
1428 fi
1429 fi
1430
1431 if test -n "$g_va_copy_func"; then
1432   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1433 fi
1434
1435 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1436         AC_TRY_RUN([#include <stdarg.h>
1437 #include <stdlib.h>
1438         void f (int i, ...) {
1439         va_list args1, args2;
1440         va_start (args1, i);
1441         args2 = args1;
1442         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1443           exit (1);
1444         va_end (args1); va_end (args2);
1445         }
1446         int main() {
1447           f (0, 42);
1448           return 0;
1449         }],
1450         [glib_cv_va_val_copy=yes],
1451         [glib_cv_va_val_copy=no],
1452         [glib_cv_va_val_copy=yes])
1453 ])
1454
1455 if test "x$glib_cv_va_val_copy" = "xno"; then
1456   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1457 fi
1458
1459 dnl ***********************
1460 dnl *** g_module checks ***
1461 dnl ***********************
1462 G_MODULE_LIBS=
1463 G_MODULE_LIBS_EXTRA=
1464 G_MODULE_PLUGIN_LIBS=
1465 if test x"$glib_native_win32" = xyes; then
1466   dnl No use for this on Win32
1467   G_MODULE_LDFLAGS=
1468 else
1469   export SED
1470   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1471 fi
1472 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1473 G_MODULE_NEED_USCORE=0
1474 G_MODULE_BROKEN_RTLD_GLOBAL=0
1475 G_MODULE_HAVE_DLERROR=0
1476 dnl *** force native WIN32 shared lib loader
1477 if test -z "$G_MODULE_IMPL"; then
1478   case "$host" in
1479   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1480   esac
1481 fi
1482 dnl *** force native AIX library loader
1483 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1484 if test -z "$G_MODULE_IMPL"; then
1485   case "$host" in
1486   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1487   esac
1488 fi
1489 dnl *** dlopen() and dlsym() in system libraries
1490 if test -z "$G_MODULE_IMPL"; then
1491         AC_CHECK_FUNC(dlopen,
1492                       [AC_CHECK_FUNC(dlsym,
1493                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1494                       [])
1495 fi
1496 dnl *** load_image (BeOS)
1497 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1498   AC_CHECK_LIB(root, load_image,
1499       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1500       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1501       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1502       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1503       [])
1504 fi
1505 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1506 if test -z "$G_MODULE_IMPL"; then
1507         AC_CHECK_FUNC(NSLinkModule,
1508                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1509                        G_MODULE_NEED_USCORE=1],
1510                       [])
1511 fi
1512 dnl *** dlopen() and dlsym() in libdl
1513 if test -z "$G_MODULE_IMPL"; then
1514         AC_CHECK_LIB(dl, dlopen,
1515                      [AC_CHECK_LIB(dl, dlsym,
1516                                    [G_MODULE_LIBS=-ldl
1517                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1518                      [])
1519 fi
1520 dnl *** shl_load() in libdld (HP-UX)
1521 if test -z "$G_MODULE_IMPL"; then
1522         AC_CHECK_LIB(dld, shl_load,
1523                 [G_MODULE_LIBS=-ldld
1524                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1525                 [])
1526 fi
1527 dnl *** additional checks for G_MODULE_IMPL_DL
1528 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1529         LIBS_orig="$LIBS"
1530         LDFLAGS_orig="$LDFLAGS"
1531         LIBS="$G_MODULE_LIBS $LIBS"
1532         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1533 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1534         echo "void glib_plugin_test(void) { }" > plugin.c
1535         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1536                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1537         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1538                 glib_cv_rtldglobal_broken,[
1539                 AC_TRY_RUN([
1540 #include <dlfcn.h>
1541 #ifndef RTLD_GLOBAL
1542 #  define RTLD_GLOBAL 0
1543 #endif
1544 #ifndef RTLD_LAZY
1545 #  define RTLD_LAZY 0
1546 #endif
1547 int glib_plugin_test;
1548 int main () {
1549     void *handle, *global, *local;
1550     global = &glib_plugin_test;
1551     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1552     if (!handle) return 0;
1553     local = dlsym (handle, "glib_plugin_test");
1554     return global == local;
1555 }                       ],
1556                         [glib_cv_rtldglobal_broken=no],
1557                         [glib_cv_rtldglobal_broken=yes],
1558                         [glib_cv_rtldglobal_broken=no])
1559                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1560                 rmdir .libs 2>/dev/null
1561         ])
1562         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1563                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1564         else
1565                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1566         fi
1567 dnl *** check whether we need preceeding underscores
1568         AC_CACHE_CHECK([for preceeding underscore in symbols],
1569                 glib_cv_uscore,[
1570                 AC_TRY_RUN([#include <dlfcn.h>
1571                 int glib_underscore_test (void) { return 42; }
1572                 int main() {
1573                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1574                   handle = dlopen ((void*)0, 0);
1575                   if (handle) {
1576                     f1 = dlsym (handle, "glib_underscore_test");
1577                     f2 = dlsym (handle, "_glib_underscore_test");
1578                   } return (!f2 || f1);
1579                 }],
1580                         [glib_cv_uscore=yes],
1581                         [glib_cv_uscore=no],
1582                         [])
1583                 rm -f plugin.c plugin.$ac_objext plugin.lo
1584         ])
1585         GLIB_ASSERT_SET(glib_cv_uscore)
1586         if test "x$glib_cv_uscore" = "xyes"; then
1587                 G_MODULE_NEED_USCORE=1
1588         else
1589                 G_MODULE_NEED_USCORE=0
1590         fi
1591
1592         LDFLAGS="$LDFLAGS_orig"
1593 dnl *** check for having dlerror()
1594         AC_CHECK_FUNC(dlerror,
1595                 [G_MODULE_HAVE_DLERROR=1],
1596                 [G_MODULE_HAVE_DLERROR=0])
1597         LIBS="$LIBS_orig"
1598 fi
1599 dnl *** done, have we got an implementation?
1600 if test -z "$G_MODULE_IMPL"; then
1601         G_MODULE_IMPL=0
1602         G_MODULE_SUPPORTED=false
1603 else
1604         G_MODULE_SUPPORTED=true
1605 fi
1606
1607 AC_MSG_CHECKING(for the suffix of module shared libraries)
1608 export SED
1609 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1610 eval $shrext_cmds
1611 module=yes eval std_shrext=$shrext_cmds
1612 # chop the initial dot
1613 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1614 AC_MSG_RESULT(.$glib_gmodule_suffix)
1615 # any reason it may fail?
1616 if test "x$glib_gmodule_suffix" = x; then
1617         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1618 fi
1619
1620 AC_SUBST(G_MODULE_SUPPORTED)
1621 AC_SUBST(G_MODULE_IMPL)
1622 AC_SUBST(G_MODULE_LIBS)
1623 AC_SUBST(G_MODULE_LIBS_EXTRA)
1624 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1625 AC_SUBST(G_MODULE_LDFLAGS)
1626 AC_SUBST(G_MODULE_HAVE_DLERROR)
1627 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1628 AC_SUBST(G_MODULE_NEED_USCORE)
1629 AC_SUBST(GLIB_DEBUG_FLAGS)
1630
1631 dnl **********************
1632 dnl *** g_spawn checks ***
1633 dnl **********************
1634
1635 AC_MSG_CHECKING(for gspawn implementation)
1636 case "$host" in
1637   *-*-mingw*)
1638     GSPAWN=gspawn-win32.lo
1639     ;;
1640   *)
1641     GSPAWN=gspawn.lo
1642     ;;
1643 esac
1644 AC_MSG_RESULT($GSPAWN)
1645 AC_SUBST(GSPAWN)
1646
1647 dnl *************************
1648 dnl *** GIOChannel checks ***
1649 dnl *************************
1650
1651 AC_MSG_CHECKING(for GIOChannel implementation)
1652 case "$host" in
1653   *-*-mingw*)
1654     GIO=giowin32.lo
1655     ;;
1656   *)
1657     GIO=giounix.lo
1658     ;;
1659 esac
1660 AC_MSG_RESULT($GIO)
1661 AC_SUBST(GIO)
1662
1663 dnl *********************************
1664 dnl *** Directory for GIO modules ***
1665 dnl *********************************
1666
1667 AC_ARG_WITH(gio-module-dir,
1668            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1669                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1670            [],
1671            [with_gio_module_dir='${libdir}/gio/modules'])
1672 GIO_MODULE_DIR=$with_gio_module_dir
1673 AC_SUBST(GIO_MODULE_DIR)
1674
1675 dnl **********************************
1676 dnl *** Check for libselinux (GIO) ***
1677 dnl **********************************
1678 AC_ARG_ENABLE(selinux,
1679               AC_HELP_STRING([--disable-selinux],
1680                              [build without selinux support]))
1681 msg_selinux=no
1682 SELINUX_LIBS=
1683 if test "x$enable_selinux" != "xno"; then
1684
1685  AC_CHECK_LIB(selinux, is_selinux_enabled,
1686    [AC_CHECK_HEADERS(selinux/selinux.h,
1687      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1688        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1689         SELINUX_LIBS="-lselinux"
1690         msg_selinux=yes])
1691      ])
1692    ])
1693 fi
1694 AC_SUBST(SELINUX_LIBS)
1695
1696 dnl *****************************
1697 dnl ** Check for inotify (GIO) **
1698 dnl *****************************
1699 inotify_support=no
1700 AC_CHECK_HEADERS([sys/inotify.h],
1701 [
1702         inotify_support=yes
1703         AC_CHECK_FUNCS(inotify_init1)
1704 ])
1705
1706 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1707
1708 dnl *********************************
1709 dnl ** Check for Solaris FEN (GIO) **
1710 dnl *********************************
1711 fen_support=no
1712 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1713 #include <port.h>
1714 #ifndef PORT_SOURCE_FILE
1715 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1716 #endif
1717 int main() { return 0; } ]])],
1718 [
1719         fen_support=yes
1720 ],)
1721
1722 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1723
1724 dnl ****************************
1725 dnl *** Checks for FAM (GIO) ***
1726 dnl ****************************
1727
1728 should_disable_fam=no
1729
1730 AC_ARG_ENABLE(fam,
1731               AC_HELP_STRING([--disable-fam],
1732                              [don't use fam for file system monitoring]),
1733                          [
1734                                 if test "x$enable_fam" = "xno"; then
1735                                         should_disable_fam=yes
1736                                 fi
1737                          ]
1738                          )
1739 fam_support=no
1740 FAM_LIBS=
1741 if test "x$should_disable_fam" = "xno"; then
1742 AC_CHECK_LIB(fam, FAMOpen,
1743   [AC_CHECK_HEADERS(fam.h,
1744     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1745      AC_CHECK_LIB(fam, FAMNoExists,
1746                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1747      FAM_LIBS="-lfam"]
1748      fam_support=yes,
1749     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1750   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1751 AC_SUBST(FAM_LIBS)
1752 fi
1753 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1754
1755
1756 dnl *****************************
1757 dnl *** Check for xattr (GIO) ***
1758 dnl *****************************
1759 AC_ARG_ENABLE(xattr,
1760               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1761 msg_xattr=no
1762 XATTR_LIBS=
1763 if test "x$enable_xattr" != "xno"; then
1764
1765 dnl either glibc or libattr can provide xattr support
1766
1767 dnl for both of them, we check for getxattr being in
1768 dnl the library and a valid xattr header.
1769
1770 dnl try glibc
1771  AC_CHECK_LIB(c, getxattr,
1772    [AC_CHECK_HEADERS(sys/xattr.h,
1773      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1774       msg_xattr=yes])
1775    ])
1776
1777   if test "x$msg_xattr" != "xyes"; then
1778 dnl   failure. try libattr
1779    AC_CHECK_LIB(attr, getxattr,
1780       [AC_CHECK_HEADERS(attr/xattr.h,
1781        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1782         XATTR_LIBS="-lattr"
1783         msg_xattr=yes])
1784       ])
1785   fi
1786
1787   if test "x$msg_xattr" = "xyes"; then
1788     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1789     AC_TRY_COMPILE([
1790       #include <stdio.h>
1791       #ifdef HAVE_SYS_TYPES_H
1792       #include <sys/types.h>
1793       #endif
1794       #ifdef HAVE_SYS_XATTR_H
1795       #include <sys/xattr.h>
1796       #elif HAVE_ATTR_XATTR_H
1797       #include <attr/xattr.h>
1798       #endif
1799     ],
1800     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1801     [
1802       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1803       AC_MSG_RESULT([yes])
1804     ],
1805     [AC_MSG_RESULT([no])]
1806     )
1807   fi
1808
1809 fi
1810 AC_SUBST(XATTR_LIBS)
1811
1812 dnl ****************************************
1813 dnl *** platform dependent source checks ***
1814 dnl ****************************************
1815
1816 AC_MSG_CHECKING(for platform-dependent source)
1817 case "$host" in
1818   *-*-cygwin*|*-*-mingw*)
1819     PLATFORMDEP=gwin32.lo
1820     ;;
1821   *)
1822     PLATFORMDEP=
1823     ;;
1824 esac
1825 AC_MSG_RESULT($PLATFORMDEP)
1826 AC_SUBST(PLATFORMDEP)
1827
1828 AC_MSG_CHECKING([whether to compile timeloop])
1829 case "$host" in
1830   *-*-cygwin*|*-*-mingw*|*-*-minix)
1831     enable_timeloop=no
1832     ;;
1833   *)
1834     enable_timeloop=yes
1835     ;;
1836 esac
1837 AC_MSG_RESULT($enable_timeloop)
1838 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1839
1840 AC_MSG_CHECKING([if building for some Win32 platform])
1841 case "$host" in
1842   *-*-mingw*|*-*-cygwin*)
1843     platform_win32=yes
1844     ;;
1845   *)
1846     platform_win32=no
1847     ;;
1848 esac
1849 AC_MSG_RESULT($platform_win32)
1850 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1851
1852 dnl ***********************
1853 dnl *** g_thread checks ***
1854 dnl ***********************
1855
1856 AC_ARG_WITH(threads,
1857            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1858                            [specify a thread implementation to use])],
1859            [if test "x$with_threads" = x; then
1860                 want_threads=yes
1861             else
1862                 want_threads=$with_threads
1863             fi],
1864            [want_threads=yes])
1865
1866 dnl error and warning message
1867 dnl *************************
1868
1869 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1870                 computer."
1871
1872 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1873                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1874                 compilation now, but then your programs might not work.
1875                 Please provide information on how it is done on your system."
1876
1877 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1878                 "
1879
1880 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1881                 provide information on your thread implementation."
1882
1883 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1884                 functions will not be MT-safe during their first call because
1885                 there is no working 'getpwuid_r' on your system."
1886
1887 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1888                 because there is no 'localtime_r' on your system."
1889
1890 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1891                 crude surrogate will be used. If you happen to know a
1892                 yield function for your system, please inform the GLib
1893                 developers."
1894
1895 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1896                 threads on your system. Thus threads can only have the default
1897                 priority. If you happen to know these main/max
1898                 priorities, please inform the GLib developers."
1899
1900 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1901                 linking threaded applications. As GLib cannot do that
1902                 automatically, you will get an linkg error everytime you are
1903                 not using the right compiler. In that case you have to relink
1904                 with the right compiler. Ususally just '_r' is appended
1905                 to the compiler name."
1906
1907 dnl determination of thread implementation
1908 dnl ***************************************
1909
1910 have_threads=no
1911 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1912                                 || test "x$want_threads" = xdce; then
1913         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1914         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1915         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1916         glib_save_CPPFLAGS="$CPPFLAGS"
1917         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1918         if test "x$have_threads" = xno; then
1919                 AC_TRY_COMPILE([#include <pthread.h>],
1920                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1921                         have_threads=posix)
1922         fi
1923         # Tru64Unix requires -pthread to find pthread.h. See #103020
1924         CPPFLAGS="$CPPFLAGS -pthread"
1925         if test "x$have_threads" = xno; then
1926         AC_TRY_COMPILE([#include <pthread.h>],
1927                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1928                        have_threads=posix)
1929         fi
1930         CPPFLAGS="$glib_save_CPPFLAGS"
1931 fi
1932 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1933         case $host in
1934                 *-*-mingw*)
1935                 have_threads=win32
1936                 ;;
1937         esac
1938 fi
1939
1940 AC_MSG_CHECKING(for thread implementation)
1941
1942 if test "x$have_threads" = xno; then
1943         AC_MSG_RESULT(none available)
1944         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1945 else
1946         AC_MSG_RESULT($have_threads)
1947 fi
1948
1949
1950 dnl determination of G_THREAD_CFLAGS
1951 dnl ********************************
1952
1953 G_THREAD_LIBS=
1954 G_THREAD_LIBS_EXTRA=
1955 G_THREAD_CFLAGS=
1956
1957 dnl
1958 dnl Test program for basic POSIX threads functionality
1959 dnl
1960 m4_define([glib_thread_test],[
1961 #include <pthread.h>
1962 int check_me = 0;
1963 void* func(void* data) {check_me = 42; return &check_me;}
1964 int main()
1965  { pthread_t t;
1966    void *ret;
1967    pthread_create (&t, $1, func, 0);
1968    pthread_join (t, &ret);
1969    return (check_me != 42 || ret != &check_me);
1970 }])
1971
1972 dnl
1973 dnl Test program for sched_get_priority_min()
1974 dnl
1975 m4_define([glib_sched_priority_test],[
1976 #include <sched.h>
1977 #include <errno.h>
1978 int main() {
1979     errno = 0;
1980     return sched_get_priority_min(SCHED_OTHER)==-1
1981            && errno != 0;
1982 }])
1983
1984 if test x"$have_threads" = xposix; then
1985   # First we test for posix, whether -pthread or -pthreads do the trick as
1986   # both CPPFLAG and LIBS.
1987   # One of them does for most gcc versions and some other platforms/compilers
1988   # too and could be considered as the canonical way to go.
1989   case $host in
1990     *-*-cygwin*|*-*-darwin*)
1991        # skip cygwin and darwin -pthread or -pthreads test
1992        ;;
1993     *-solaris*)
1994       # These compiler/linker flags work with both Sun Studio and gcc
1995       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1996       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1997       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1998       G_THREAD_LIBS="-lpthread -lthread"
1999       ;;
2000     *)
2001       for flag in pthread pthreads mt; do
2002         glib_save_CFLAGS="$CFLAGS"
2003         CFLAGS="$CFLAGS -$flag"
2004         AC_TRY_RUN(glib_thread_test(0),
2005                    glib_flag_works=yes,
2006                    glib_flag_works=no,
2007                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2008                                    glib_flag_works=yes,
2009                                    glib_flag_works=no)])
2010         CFLAGS="$glib_save_CFLAGS"
2011         if test $glib_flag_works = yes ; then
2012            G_THREAD_CFLAGS=-$flag
2013         G_THREAD_LIBS=-$flag
2014         break;
2015         fi
2016       done
2017        ;;
2018   esac
2019 fi
2020
2021 if test x"$G_THREAD_CFLAGS" = x; then
2022
2023   # The canonical -pthread[s] does not work. Try something different.
2024
2025   case $host in
2026         *-aix*)
2027                 if test x"$GCC" = xyes; then
2028                         # GCC 3.0 and above needs -pthread.
2029                         # Should be coverd by the case above.
2030                         # GCC 2.x and below needs -mthreads
2031                         G_THREAD_CFLAGS="-mthreads"
2032                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2033                 else
2034                         # We are probably using the aix compiler. Normaly a
2035                         # program would have to be compiled with the _r variant
2036                         # of the corresponding compiler, but we as GLib cannot
2037                         # do that: but the good news is that for compiling the
2038                         # only difference is the added -D_THREAD_SAFE compile
2039                         # option. This is according to the "C for AIX User's
2040                         # Guide".
2041                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2042                 fi
2043                 ;;
2044         *-dg-dgux*)  # DG/UX
2045                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2046                 ;;
2047         *-sysv5uw7*) # UnixWare 7
2048                 # We are not using gcc with -pthread. Catched above.
2049                 G_THREAD_CFLAGS="-Kthread"
2050                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2051                 ;;
2052         *-mingw*)
2053                 # No flag needed when using MSVCRT.DLL
2054                 G_THREAD_CFLAGS=""
2055                 ;;
2056         *)
2057                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2058                 ;;
2059   esac
2060
2061 fi
2062
2063 # if we are not finding the localtime_r function, then we probably are
2064 # not using the proper multithread flag
2065
2066 glib_save_CPPFLAGS="$CPPFLAGS"
2067 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2068
2069 # First we test, whether localtime_r is declared in time.h
2070 # directly. Then we test whether a macro localtime_r exists, in
2071 # which case localtime_r in the test program is replaced and thus
2072 # if we still find localtime_r in the output, it is not defined as
2073 # a macro.
2074
2075 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2076   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2077                                                            localtime_r(a,b)],
2078                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2079
2080 CPPFLAGS="$glib_save_CPPFLAGS"
2081
2082 AC_MSG_CHECKING(thread related cflags)
2083 AC_MSG_RESULT($G_THREAD_CFLAGS)
2084 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2085
2086 dnl determination of G_THREAD_LIBS
2087 dnl ******************************
2088
2089 case $have_threads in
2090         posix)
2091           glib_save_CPPFLAGS="$CPPFLAGS"
2092           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2093           if test x"$G_THREAD_LIBS" = x; then
2094             case $host in
2095               *-aix*)
2096                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2097                 # probably using the aix compiler.
2098                 AC_MSG_WARN($AIX_COMPILE_INFO)
2099                 ;;
2100               *)
2101                 G_THREAD_LIBS=error
2102                 glib_save_LIBS="$LIBS"
2103                 for thread_lib in "" pthread pthread32 pthreads thread; do
2104                         if test x"$thread_lib" = x; then
2105                                 add_thread_lib=""
2106                                 IN=""
2107                         else
2108                                 add_thread_lib="-l$thread_lib"
2109                                 IN=" in -l$thread_lib"
2110                         fi
2111                         if test x"$have_threads" = xposix; then
2112                                 defattr=0
2113                         else
2114                                 defattr=pthread_attr_default
2115                         fi
2116
2117                         LIBS="$add_thread_lib $glib_save_LIBS"
2118
2119                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2120                         AC_TRY_RUN(glib_thread_test($defattr),
2121                                    glib_result=yes,
2122                                    glib_result=no,
2123                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2124                                                    glib_result=yes,
2125                                                    glib_result=no)])
2126                         AC_MSG_RESULT($glib_result)
2127
2128                         if test "$glib_result" = "yes" ; then
2129                           G_THREAD_LIBS="$add_thread_lib"
2130                           break
2131                         fi
2132                 done
2133                 if test "x$G_THREAD_LIBS" = xerror; then
2134                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2135                 fi
2136                 LIBS="$glib_save_LIBS"
2137                 ;;
2138             esac
2139           fi
2140
2141           glib_save_LIBS="$LIBS"
2142           for thread_lib in "" rt rte; do
2143             if test x"$thread_lib" = x; then
2144               add_thread_lib=""
2145               IN=""
2146             else
2147               add_thread_lib="-l$thread_lib"
2148               IN=" in -l$thread_lib"
2149             fi
2150             LIBS="$add_thread_lib $glib_save_LIBS"
2151
2152             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2153             AC_TRY_RUN(glib_sched_priority_test,
2154                        glib_result=yes,
2155                        glib_result=no,
2156                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2157                                        glib_result=yes,
2158                                        glib_result=no)])
2159             AC_MSG_RESULT($glib_result)
2160
2161             if test "$glib_result" = "yes" ; then
2162                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2163                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2164                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2165                break
2166             fi
2167           done
2168           LIBS="$glib_save_LIBS"
2169           g_threads_impl="POSIX"
2170           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2171           CPPFLAGS="$glib_save_CPPFLAGS"
2172           ;;
2173         win32)
2174            g_threads_impl="WIN32"
2175            ;;
2176         *)
2177            g_threads_impl="NONE"
2178            G_THREAD_LIBS=error
2179            ;;
2180 esac
2181
2182 if test "x$G_THREAD_LIBS" = xerror; then
2183         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2184 fi
2185
2186 case $host in
2187   *-*-beos*)
2188     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2189     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2190     ;;
2191   *)
2192     ;;
2193 esac
2194
2195 AC_MSG_CHECKING(thread related libraries)
2196 AC_MSG_RESULT($G_THREAD_LIBS)
2197
2198 dnl check for mt safe function variants and some posix functions
2199 dnl ************************************************************
2200
2201 glib_save_LIBS="$LIBS"
2202 # we are not doing the following for now, as this might require glib
2203 # to always be linked with the thread libs on some platforms.
2204 # LIBS="$LIBS $G_THREAD_LIBS"
2205 AC_CHECK_FUNCS(localtime_r gmtime_r)
2206 if test "$ac_cv_header_pwd_h" = "yes"; then
2207         AC_CACHE_CHECK([for posix getpwuid_r],
2208                 ac_cv_func_posix_getpwuid_r,
2209                 [AC_TRY_RUN([
2210 #include <errno.h>
2211 #include <pwd.h>
2212 int main () {
2213     char buffer[10000];
2214     struct passwd pwd, *pwptr = &pwd;
2215     int error;
2216     errno = 0;
2217     error = getpwuid_r (0, &pwd, buffer,
2218                         sizeof (buffer), &pwptr);
2219    return (error < 0 && errno == ENOSYS)
2220            || error == ENOSYS;
2221 }                               ],
2222                         [ac_cv_func_posix_getpwuid_r=yes],
2223                         [ac_cv_func_posix_getpwuid_r=no])])
2224         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2225         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2226                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2227                         [Have POSIX function getpwuid_r])
2228         else
2229                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2230                         ac_cv_func_nonposix_getpwuid_r,
2231                         [AC_TRY_LINK([#include <pwd.h>],
2232                                 [char buffer[10000];
2233                                 struct passwd pwd;
2234                                 getpwuid_r (0, &pwd, buffer,
2235                                                 sizeof (buffer));],
2236                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2237                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2238                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2239                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2240                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2241                                 [Have non-POSIX function getpwuid_r])
2242                 fi
2243         fi
2244 fi
2245 if test "$ac_cv_header_grp_h" = "yes"; then
2246         AC_CACHE_CHECK([for posix getgrgid_r],
2247                 ac_cv_func_posix_getgrgid_r,
2248                 [AC_TRY_RUN([
2249 #include <errno.h>
2250 #include <grp.h>
2251 int main () {
2252     char buffer[10000];
2253     struct group grp, *grpptr = &grp;
2254     int error;
2255     errno = 0;
2256     error = getgrgid_r (0, &grp, buffer,
2257                         sizeof (buffer), &grpptr);
2258    return (error < 0 && errno == ENOSYS)
2259            || error == ENOSYS;
2260 }                              ],
2261                        [ac_cv_func_posix_getgrgid_r=yes],
2262                        [ac_cv_func_posix_getgrgid_r=no])])
2263         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2264         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2265                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2266                         [Have POSIX function getgrgid_r])
2267         else
2268                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2269                         ac_cv_func_nonposix_getgrgid_r,
2270                         [AC_TRY_LINK([#include <grp.h>],
2271                                 [char buffer[10000];
2272                                 struct group grp;
2273                                 getgrgid_r (0, &grp, buffer,
2274                                 sizeof (buffer));],
2275                         [ac_cv_func_nonposix_getgrgid_r=yes],
2276                         [ac_cv_func_nonposix_getgrgid_r=no])])
2277                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2278                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2279                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2280                                 [Have non-POSIX function getgrgid_r])
2281                 fi
2282         fi
2283 fi
2284 LIBS="$G_THREAD_LIBS $LIBS"
2285 if test x"$have_threads" = xposix; then
2286         glib_save_CPPFLAGS="$CPPFLAGS"
2287         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2288         dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2289         GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2290         # This is not AC_CHECK_FUNC to also work with function
2291         # name mangling in header files.
2292         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2293         AC_TRY_LINK([#include <pthread.h>],
2294                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2295                 [AC_MSG_RESULT(yes)
2296                 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2297                           [Have function pthread_attr_setstacksize])],
2298                 [AC_MSG_RESULT(no)])
2299         AC_MSG_CHECKING(for minimal/maximal thread priority)
2300         if test x"$posix_priority_min" = x; then
2301                 AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2302                         PX_PRIO_MIN],,[
2303                         posix_priority_min=PX_PRIO_MIN
2304                         posix_priority_max=PX_PRIO_MAX])
2305         fi
2306         if test x"$posix_priority_min" = x; then
2307                 # AIX
2308                 AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2309                         PTHREAD_PRIO_MIN],,[
2310                         posix_priority_min=PTHREAD_PRIO_MIN
2311                         posix_priority_max=PTHREAD_PRIO_MAX])
2312         fi
2313         if test x"$posix_priority_min" = x; then
2314                 AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2315                         PRI_OTHER_MIN],,[
2316                         posix_priority_min=PRI_OTHER_MIN
2317                         posix_priority_max=PRI_OTHER_MAX])
2318         fi
2319         if test x"$posix_priority_min" = x; then
2320                 AC_MSG_RESULT(none found)
2321                 AC_MSG_WARN($POSIX_NO_PRIORITIES)
2322                 posix_priority_min=-1
2323                 posix_priority_max=-1
2324         else
2325                 AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2326                 AC_MSG_CHECKING(for pthread_setschedparam)
2327                 AC_TRY_LINK([#include <pthread.h>],
2328                   [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2329                   [AC_MSG_RESULT(yes)
2330                 AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2331                    AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2332                   [AC_MSG_RESULT(no)
2333                    AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2334         fi
2335         posix_yield_func=none
2336         AC_MSG_CHECKING(for posix yield function)
2337         for yield_func in sched_yield pthread_yield_np pthread_yield \
2338                                                 thr_yield; do
2339                 AC_TRY_LINK([#include <pthread.h>],
2340                         [$yield_func()],
2341                         [posix_yield_func="$yield_func"
2342                         break])
2343         done
2344         if test x"$posix_yield_func" = xnone; then
2345                 AC_MSG_RESULT(none found)
2346                 AC_MSG_WARN($POSIX_NO_YIELD)
2347                 posix_yield_func="g_usleep(1000)"
2348         else
2349                 AC_MSG_RESULT($posix_yield_func)
2350                 posix_yield_func="$posix_yield_func()"
2351         fi
2352         AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2353         CPPFLAGS="$glib_save_CPPFLAGS"
2354
2355 elif test x"$have_threads" = xwin32; then
2356         # It's a pointer to a private struct
2357         GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2358 fi
2359
2360 LIBS="$glib_save_LIBS"
2361
2362 # now spit out all the warnings.
2363 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2364    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2365         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2366 fi
2367 if test "$ac_cv_func_localtime_r" != "yes"; then
2368         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2369 fi
2370
2371 if test x"$glib_cv_sizeof_system_thread" = x; then
2372    # use a pointer as a fallback.
2373    GLIB_SIZEOF(,void *, system_thread)
2374 fi
2375
2376 #
2377 # Hack to deal with:
2378 #
2379 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2380 #     building shared libraries with linux.
2381 #  b) FreeBSD doesn't do this either.
2382 #
2383 case $host in
2384   *-*-freebsd*|*-*-linux*)
2385     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2386     ;;
2387   *)
2388     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2389     ;;
2390 esac
2391
2392 AC_SUBST(G_THREAD_CFLAGS)
2393 AC_SUBST(G_THREAD_LIBS)
2394 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2395 AC_SUBST(G_THREAD_LIBS_EXTRA)
2396
2397 AC_CHECK_FUNCS(clock_gettime, [], [
2398   AC_CHECK_LIB(rt, clock_gettime, [
2399     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2400     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2401     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2402     GLIB_RT_LIBS="-lrt"
2403   ])
2404 ])
2405 AC_SUBST(GLIB_RT_LIBS)
2406
2407 AC_CACHE_CHECK(for monotonic clocks,
2408     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2409 #include <time.h>
2410 #include <unistd.h>
2411 int main() {
2412 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2413         #error No monotonic clock
2414 #endif
2415         return 0;
2416 }
2417 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2418 if test "$glib_cv_monotonic_clock" = "yes"; then
2419   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2420 fi
2421
2422
2423 dnl ************************
2424 dnl *** g_atomic_* tests ***
2425 dnl ************************
2426
2427     case $host_cpu in
2428       i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2429         glib_memory_barrier_needed=no
2430         ;;
2431       sparc*|alpha*|powerpc*|ia64)
2432         glib_memory_barrier_needed=yes
2433         ;;
2434       *)
2435         glib_memory_barrier_needed=yes
2436         ;;
2437     esac
2438
2439 glib_cv_gcc_has_builtin_atomic_operations=no
2440 if test x"$GCC" = xyes; then
2441   AC_MSG_CHECKING([whether GCC supports built-in atomic intrinsics])
2442   AC_TRY_LINK([],
2443               [int i;
2444                __sync_synchronize ();
2445                __sync_bool_compare_and_swap (&i, 0, 1);
2446                __sync_fetch_and_add (&i, 1);
2447               ],
2448               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2449               [glib_cv_gcc_has_builtin_atomic_operations=no])
2450
2451   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2452 fi
2453 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2454                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2455
2456 AC_MSG_CHECKING([for Win32 atomic intrinsics])
2457 glib_cv_has_win32_atomic_operations=no
2458 AC_TRY_LINK([],
2459         [int i; _InterlockedExchangeAdd (&i, 0);],
2460         [glib_cv_has_win32_atomic_operations=yes],
2461         [glib_cv_has_win32_atomic_operations=no])
2462 AC_MSG_RESULT($glib_cv_has_win32_atomic_operations)
2463 if test "x$glib_cv_has_win32_atomic_operations" = xyes; then
2464         AC_DEFINE(HAVE_WIN32_BUILTINS_FOR_ATOMIC_OPERATIONS,1,[Have Win32 atomic intrinsics])
2465 fi
2466
2467 dnl ************************
2468 dnl ** Check for futex(2) **
2469 dnl ************************
2470 AC_CACHE_CHECK(for futex(2) system call,
2471     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2472 #include <linux/futex.h>
2473 #include <sys/syscall.h>
2474 #include <unistd.h>
2475 ],[
2476 int
2477 main (void)
2478 {
2479   /* it is not like this actually runs or anything... */
2480   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2481   return 0;
2482 }
2483 ])],glib_cv_futex=yes,glib_cv_futex=no))
2484 if test x"$glib_cv_futex" = xyes; then
2485   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2486 fi
2487
2488 AC_CACHE_CHECK(for eventfd(2) system call,
2489     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2490 #include <sys/eventfd.h>
2491 #include <unistd.h>
2492 ],[
2493 int
2494 main (void)
2495 {
2496   eventfd (0, EFD_CLOEXEC);
2497   return 0;
2498 }
2499 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2500 if test x"$glib_cv_eventfd" = x"yes"; then
2501   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2502 fi
2503 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2504
2505 dnl ****************************************
2506 dnl *** GLib POLL* compatibility defines ***
2507 dnl ****************************************
2508
2509 glib_poll_includes=["
2510 #include <sys/types.h>
2511 #include <sys/poll.h>
2512 "]
2513
2514 if test $ac_cv_header_sys_types_h = yes &&
2515    test $ac_cv_header_sys_poll_h = yes ; then
2516   glib_failed=false
2517   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2518   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2519   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2520   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2521   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2522   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2523   if $glib_failed ; then
2524     AC_MSG_ERROR([Could not determine values for POLL* constants])
2525   fi
2526 else
2527   glib_cv_value_POLLIN=1
2528   glib_cv_value_POLLOUT=4
2529   glib_cv_value_POLLPRI=2
2530   glib_cv_value_POLLERR=8
2531   glib_cv_value_POLLHUP=16
2532   glib_cv_value_POLLNVAL=32
2533 fi
2534
2535 AC_MSG_CHECKING([for broken poll])
2536 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2537         #include <stdlib.h>
2538         #include <fcntl.h>
2539         #include <poll.h>
2540         #ifdef HAVE_SYS_POLL_H
2541         #include <sys/poll.h>
2542         #endif
2543         int main(void) {
2544           struct pollfd fds[1];
2545           int fd;
2546           fd = open("/dev/null", 1);
2547           fds[0].fd = fd;
2548           fds[0].events = POLLIN;
2549           fds[0].revents = 0;
2550           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2551                 exit(1);  /* Does not work for devices -- fail */
2552           }
2553           exit(0);
2554         }]])],
2555   [broken_poll=no],
2556   [broken_poll=yes
2557    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2558   [broken_poll="no (cross compiling)"])
2559 AC_MSG_RESULT($broken_poll)
2560
2561 dnl *********************
2562 dnl *** GRegex checks ***
2563 dnl *********************
2564 PCRE_REQUIRED_VERSION=8.11
2565
2566 # Check if we should compile GRegex
2567 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2568                                     [disable the compilation of GRegex]),
2569 [case "${enableval}" in
2570   yes) enable_regex=true ;;
2571   no)  enable_regex=false ;;
2572   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2573 esac],
2574 [enable_regex=true])
2575
2576 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2577
2578 if test x$enable_regex = xtrue; then
2579   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2580   # Check if we should use the internal or the system-supplied pcre
2581   AC_ARG_WITH(pcre,
2582              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2583                              [whether to use system PCRE [default=internal]])])
2584
2585   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2586
2587   if test "x$with_pcre" = xsystem; then
2588     PKG_CHECK_MODULES(PCRE,
2589                       libpcre >= $PCRE_REQUIRED_VERSION)
2590     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2591                    glib_save_CFLAGS="$CFLAGS"
2592                    glib_save_LIBS="$LIBS"
2593                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2594                    AC_TRY_RUN([#include <pcre.h>
2595                                int main () {
2596                                  int support;
2597                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2598                                  if (!support)
2599                                    return 1;
2600                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2601                                  if (!support)
2602                                    return 1;
2603                                  return 0;
2604                                }],
2605                    glib_cv_pcre_has_unicode=yes,
2606                    glib_cv_pcre_has_unicode=no,
2607                    glib_cv_pcre_has_unicode=yes)
2608                    CFLAGS="$glib_save_CFLAGS"
2609                    LIBS="$glib_save_LIBS"
2610         ])
2611     if test "$glib_cv_pcre_has_unicode" = "no"; then
2612       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2613     fi
2614     AC_SUBST(PCRE_CFLAGS)
2615     AC_SUBST(PCRE_LIBS)
2616     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2617     PCRE_REQUIRES=libpcre
2618     AC_SUBST(PCRE_REQUIRES)
2619   else
2620     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2621     if test x"$GCC" = xyes; then
2622       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2623       save_CFLAGS="$CFLAGS"
2624       CFLAGS="$CFLAGS -Wno-pointer-sign"
2625       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2626                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2627       CFLAGS="$save_CFLAGS"
2628     fi
2629   fi
2630   AC_SUBST(PCRE_WARN_CFLAGS)
2631 else
2632   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2633 fi
2634
2635 dnl **********************
2636 dnl *** Win32 API libs ***
2637 dnl **********************
2638
2639 case $host in
2640   *-*-cygwin*)
2641         G_LIBS_EXTRA="-luser32 -lkernel32"
2642     ;;
2643   *-*-mingw*)
2644         G_LIBS_EXTRA="-lws2_32 -lole32"
2645     ;;
2646   *)
2647         G_LIBS_EXTRA=""
2648     ;;
2649 esac
2650 AC_SUBST(G_LIBS_EXTRA)
2651
2652 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2653 dnl since we need it for g_iconv()
2654
2655 AC_MSG_CHECKING([for EILSEQ])
2656 AC_TRY_COMPILE([
2657 #include <errno.h>
2658 ],
2659 [
2660 int error = EILSEQ;
2661 ], have_eilseq=yes, have_eilseq=no);
2662 AC_MSG_RESULT($have_eilseq)
2663
2664 dnl ******************************************************************
2665 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2666 dnl *** glib-compile-schemas in PATH                               ***
2667 dnl ******************************************************************
2668
2669 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2670
2671 if test $cross_compiling = yes; then
2672   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2673   if test x$GLIB_GENMARSHAL = xno; then
2674     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2675   fi
2676
2677   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2678   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2679     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2680   fi
2681 fi
2682
2683 dnl **************************
2684 dnl *** Checks for gtk-doc ***
2685 dnl **************************
2686
2687 GTK_DOC_CHECK([1.15])
2688
2689 AC_ARG_ENABLE(man,
2690               [AC_HELP_STRING([--enable-man],
2691                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2692               enable_man=no)
2693
2694 if test "${enable_man}" != no; then
2695 dnl
2696 dnl Check for xsltproc
2697 dnl
2698 AC_PATH_PROG([XSLTPROC], [xsltproc])
2699   if test -z "$XSLTPROC"; then
2700     enable_man=no
2701   fi
2702
2703   dnl check for DocBook DTD and stylesheets in the local catalog.
2704   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2705      [DocBook XML DTD V4.1.2],,enable_man=no)
2706   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2707      [DocBook XSL Stylesheets],,enable_man=no)
2708 fi
2709
2710 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2711
2712 dnl
2713 dnl Tracing
2714 dnl
2715
2716 AC_ARG_ENABLE([dtrace],
2717              [AS_HELP_STRING([--enable-dtrace],
2718                               [include tracing support for dtrace])])
2719 have_dtrace=no
2720 AC_MSG_CHECKING([whether to include dtrace tracing support])
2721 if test "x$enable_dtrace" != xno; then
2722   if test x$glib_have_carbon = xyes; then
2723     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2724   else
2725     AC_MSG_RESULT([yes])
2726     AC_CHECK_PROGS(DTRACE, dtrace)
2727     if test -z "$DTRACE"; then
2728       if test "x$enable_dtrace" = xyes; then
2729         AC_MSG_ERROR([dtrace not found])
2730       fi
2731     else
2732       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2733                       [if test "x$enable_dtrace" = xyes; then
2734                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2735                        fi])
2736     fi
2737   fi
2738 else
2739   AC_MSG_RESULT([no])
2740 fi
2741 if test "x$have_dtrace" = xyes; then
2742   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2743 fi
2744 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2745
2746 AC_MSG_CHECKING([whether to include systemtap tracing support])
2747 AC_ARG_ENABLE([systemtap],
2748              [AS_HELP_STRING([--enable-systemtap],
2749                               [include tracing support for systemtap])])
2750 have_systemtap=no
2751 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2752   have_systemtap=yes
2753 fi
2754 AC_MSG_RESULT(${have_systemtap})
2755
2756 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2757
2758 AC_ARG_WITH([tapset-install-dir],
2759             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2760                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2761             [if test "x${withval}" = x; then
2762                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2763              else
2764                ABS_TAPSET_DIR="${withval}"
2765               fi],
2766             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2767 AC_SUBST(ABS_TAPSET_DIR)
2768
2769 dnl ************************************
2770 dnl *** Enable lcov coverage reports ***
2771 dnl ************************************
2772
2773 AC_ARG_ENABLE(gcov,
2774   AS_HELP_STRING([--enable-gcov],
2775                  [enable coverage testing with gcov]),
2776   [use_gcov=$enableval], [use_gcov=no])
2777
2778 if test "x$use_gcov" = "xyes"; then
2779   dnl we need gcc:
2780   if test "$GCC" != "yes"; then
2781     AC_MSG_ERROR([GCC is required for --enable-gcov])
2782   fi
2783
2784   dnl Check if ccache is being used
2785   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2786   case `$SHTOOL path $CC` in
2787     *ccache*[)] gcc_ccache=yes;;
2788     *[)] gcc_ccache=no;;
2789   esac
2790
2791   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2792     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2793   fi
2794
2795   ltp_version_list="1.6 1.7 1.8 1.9"
2796   AC_CHECK_PROG(LTP, lcov, lcov)
2797   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2798
2799   if test "$LTP"; then
2800     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2801       glib_cv_ltp_version=invalid
2802       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2803       for ltp_check_version in $ltp_version_list; do
2804         if test "$ltp_version" = "$ltp_check_version"; then
2805           glib_cv_ltp_version="$ltp_check_version (ok)"
2806         fi
2807       done
2808     ])
2809   else
2810     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2811     AC_MSG_ERROR([$ltp_msg])
2812   fi
2813
2814   case $glib_cv_ltp_version in
2815     ""|invalid[)]
2816       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2817       AC_MSG_ERROR([$ltp_msg])
2818       LTP="exit 0;"
2819       ;;
2820   esac
2821
2822   if test -z "$LTP_GENHTML"; then
2823     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2824   fi
2825
2826   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2827
2828   dnl Remove all optimization flags from CFLAGS
2829   changequote({,})
2830   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2831   changequote([,])
2832
2833   dnl Add the special gcc flags
2834   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2835   LDFLAGS="$LDFLAGS -lgcov"
2836 fi
2837
2838 dnl ******************************
2839 dnl *** output the whole stuff ***
2840 dnl ******************************
2841
2842 dnl this section will only be run if config.status is invoked with no
2843 dnl arguments, or with "glib/glibconfig.h" as an argument.
2844 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2845 [
2846         outfile=glib/glibconfig.h-tmp
2847         cat > $outfile <<\_______EOF
2848 /* glibconfig.h
2849  *
2850  * This is a generated file.  Please modify 'configure.ac'
2851  */
2852
2853 #ifndef __G_LIBCONFIG_H__
2854 #define __G_LIBCONFIG_H__
2855
2856 #include <glib/gmacros.h>
2857
2858 _______EOF
2859
2860         if test x$glib_limits_h = xyes; then
2861           echo '#include <limits.h>' >> $outfile
2862         fi
2863         if test x$glib_float_h = xyes; then
2864           echo '#include <float.h>' >> $outfile
2865         fi
2866         if test x$glib_values_h = xyes; then
2867           echo '#include <values.h>' >> $outfile
2868         fi
2869         if test "$glib_header_alloca_h" = "yes"; then
2870           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2871         fi
2872         if test x$glib_sys_poll_h = xyes; then
2873           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2874         fi
2875         if test x$glib_included_printf != xyes; then
2876           echo "
2877 /* Specifies that GLib's g_print*() functions wrap the
2878  * system printf functions.  This is useful to know, for example,
2879  * when using glibc's register_printf_function().
2880  */" >> $outfile
2881           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2882         fi
2883
2884         cat >> $outfile <<_______EOF
2885
2886 G_BEGIN_DECLS
2887
2888 #define G_MINFLOAT      $glib_mf
2889 #define G_MAXFLOAT      $glib_Mf
2890 #define G_MINDOUBLE     $glib_md
2891 #define G_MAXDOUBLE     $glib_Md
2892 #define G_MINSHORT      $glib_ms
2893 #define G_MAXSHORT      $glib_Ms
2894 #define G_MAXUSHORT     $glib_Mus
2895 #define G_MININT        $glib_mi
2896 #define G_MAXINT        $glib_Mi
2897 #define G_MAXUINT       $glib_Mui
2898 #define G_MINLONG       $glib_ml
2899 #define G_MAXLONG       $glib_Ml
2900 #define G_MAXULONG      $glib_Mul
2901
2902 _______EOF
2903
2904
2905         ### this should always be true in a modern C/C++ compiler
2906         cat >>$outfile <<_______EOF
2907 typedef signed char gint8;
2908 typedef unsigned char guint8;
2909 _______EOF
2910
2911
2912         if test -n "$gint16"; then
2913           cat >>$outfile <<_______EOF
2914 typedef signed $gint16 gint16;
2915 typedef unsigned $gint16 guint16;
2916 #define G_GINT16_MODIFIER $gint16_modifier
2917 #define G_GINT16_FORMAT $gint16_format
2918 #define G_GUINT16_FORMAT $guint16_format
2919 _______EOF
2920         fi
2921
2922
2923         if test -n "$gint32"; then
2924           cat >>$outfile <<_______EOF
2925 typedef signed $gint32 gint32;
2926 typedef unsigned $gint32 guint32;
2927 #define G_GINT32_MODIFIER $gint32_modifier
2928 #define G_GINT32_FORMAT $gint32_format
2929 #define G_GUINT32_FORMAT $guint32_format
2930 _______EOF
2931         fi
2932
2933         cat >>$outfile <<_______EOF
2934 #define G_HAVE_GINT64 1          /* deprecated, always true */
2935
2936 ${glib_extension}typedef signed $gint64 gint64;
2937 ${glib_extension}typedef unsigned $gint64 guint64;
2938
2939 #define G_GINT64_CONSTANT(val)  $gint64_constant
2940 #define G_GUINT64_CONSTANT(val) $guint64_constant
2941 _______EOF
2942
2943         if test x$gint64_format != x ; then
2944           cat >>$outfile <<_______EOF
2945 #define G_GINT64_MODIFIER $gint64_modifier
2946 #define G_GINT64_FORMAT $gint64_format
2947 #define G_GUINT64_FORMAT $guint64_format
2948 _______EOF
2949         else
2950           cat >>$outfile <<_______EOF
2951 #undef G_GINT64_MODIFIER
2952 #undef G_GINT64_FORMAT
2953 #undef G_GUINT64_FORMAT
2954 _______EOF
2955         fi
2956
2957         cat >>$outfile <<_______EOF
2958
2959 #define GLIB_SIZEOF_VOID_P $glib_void_p
2960 #define GLIB_SIZEOF_LONG   $glib_long
2961 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2962
2963 _______EOF
2964
2965         cat >>$outfile <<_______EOF
2966 typedef signed $glib_size_type_define gssize;
2967 typedef unsigned $glib_size_type_define gsize;
2968 #define G_GSIZE_MODIFIER $gsize_modifier
2969 #define G_GSSIZE_FORMAT $gssize_format
2970 #define G_GSIZE_FORMAT $gsize_format
2971
2972 #define G_MAXSIZE       G_MAXU$glib_msize_type
2973 #define G_MINSSIZE      G_MIN$glib_msize_type
2974 #define G_MAXSSIZE      G_MAX$glib_msize_type
2975
2976 typedef gint64 goffset;
2977 #define G_MINOFFSET     G_MININT64
2978 #define G_MAXOFFSET     G_MAXINT64
2979
2980 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2981 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2982 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2983
2984 _______EOF
2985
2986         if test -z "$glib_unknown_void_p"; then
2987           cat >>$outfile <<_______EOF
2988
2989 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2990 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2991
2992 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2993 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2994
2995 typedef signed $glib_intptr_type_define gintptr;
2996 typedef unsigned $glib_intptr_type_define guintptr;
2997
2998 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2999 #define G_GINTPTR_FORMAT        $gintptr_format
3000 #define G_GUINTPTR_FORMAT       $guintptr_format
3001 _______EOF
3002         else
3003           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3004         fi
3005
3006
3007
3008         cat >>$outfile <<_______EOF
3009 $glib_atexit
3010 $glib_memmove
3011 $glib_defines
3012 $glib_os
3013 $glib_static_compilation
3014
3015 $glib_vacopy
3016
3017 #ifdef  __cplusplus
3018 #define G_HAVE_INLINE   1
3019 #else   /* !__cplusplus */
3020 $glib_inline
3021 #endif  /* !__cplusplus */
3022
3023 #ifdef  __cplusplus
3024 #define G_CAN_INLINE    1
3025 _______EOF
3026
3027         if test x$g_can_inline = xyes ; then
3028                 cat >>$outfile <<_______EOF
3029 #else   /* !__cplusplus */
3030 #define G_CAN_INLINE    1
3031 _______EOF
3032         fi
3033
3034         cat >>$outfile <<_______EOF
3035 #endif
3036
3037 _______EOF
3038
3039         if test x$g_have_iso_c_varargs = xyes ; then
3040                 cat >>$outfile <<_______EOF
3041 #ifndef __cplusplus
3042 # define G_HAVE_ISO_VARARGS 1
3043 #endif
3044 _______EOF
3045         fi
3046         if test x$g_have_iso_cxx_varargs = xyes ; then
3047                 cat >>$outfile <<_______EOF
3048 #ifdef __cplusplus
3049 # define G_HAVE_ISO_VARARGS 1
3050 #endif
3051 _______EOF
3052         fi
3053         if test x$g_have_gnuc_varargs = xyes ; then
3054                 cat >>$outfile <<_______EOF
3055
3056 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3057  * is passed ISO vararg support is turned off, and there is no work
3058  * around to turn it on, so we unconditionally turn it off.
3059  */
3060 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3061 #  undef G_HAVE_ISO_VARARGS
3062 #endif
3063
3064 #define G_HAVE_GNUC_VARARGS 1
3065 _______EOF
3066         fi
3067
3068         case x$g_stack_grows in
3069         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3070         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3071         esac
3072
3073
3074         echo >>$outfile
3075         if test x$g_have_eilseq = xno; then
3076                 cat >>$outfile <<_______EOF
3077 #ifndef EILSEQ
3078 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3079  * The correspondence between this and the corresponding definition
3080  * in libiconv is essential.
3081  */
3082 #  define EILSEQ ENOENT
3083 #endif
3084 _______EOF
3085
3086         fi
3087
3088         if test x$g_have_gnuc_visibility = xyes; then
3089                 cat >>$outfile <<_______EOF
3090 #define G_HAVE_GNUC_VISIBILITY 1
3091 _______EOF
3092         fi
3093                 cat >>$outfile <<_______EOF
3094 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3095 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3096 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3097 #define G_GNUC_INTERNAL __hidden
3098 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3099 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3100 #else
3101 #define G_GNUC_INTERNAL
3102 #endif
3103 _______EOF
3104
3105         echo >>$outfile
3106         cat >>$outfile <<_______EOF
3107 #define G_THREADS_ENABLED
3108 #define G_THREADS_IMPL_$g_threads_impl_def
3109 _______EOF
3110
3111         cat >>$outfile <<_______EOF
3112 /* This represents a system thread as used by the implementation. An
3113  * alien implementaion, as loaded by g_thread_init can only count on
3114  * "sizeof (gpointer)" bytes to store their info. We however need more
3115  * for some of our native implementations. */
3116 typedef union _GSystemThread GSystemThread;
3117 union _GSystemThread
3118 {
3119   char   data[[$g_system_thread_sizeof]];
3120   double dummy_double;
3121   void  *dummy_pointer;
3122   long   dummy_long;
3123 };
3124 _______EOF
3125         if test x"$g_memory_barrier_needed" != xno; then
3126           echo >>$outfile
3127           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3128         fi
3129         if test x"$g_gcc_atomic_ops" != xno; then
3130           echo >>$outfile
3131           echo "#define G_ATOMIC_OP_USE_GCC_BUILTINS 1" >>$outfile
3132         fi
3133         echo >>$outfile
3134         g_bit_sizes="16 32 64"
3135         for bits in $g_bit_sizes; do
3136           cat >>$outfile <<_______EOF
3137 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3138 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3139 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3140 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3141 _______EOF
3142         done
3143
3144         cat >>$outfile <<_______EOF
3145 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3146 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3147 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3148 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3149 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3150 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3151 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3152 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3153 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3154 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3155 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3156 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3157 #define G_BYTE_ORDER $g_byte_order
3158
3159 #define GLIB_SYSDEF_POLLIN =$g_pollin
3160 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3161 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3162 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3163 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3164 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3165
3166 #define G_MODULE_SUFFIX "$g_module_suffix"
3167
3168 /* A GPid is an abstraction for a process "handle". It is *not* an
3169  * abstraction for a process identifier in general. GPid is used in
3170  * GLib only for descendant processes spawned with the g_spawn*
3171  * functions. On POSIX there is no "process handle" concept as such,
3172  * but on Windows a GPid is a handle to a process, a kind of pointer,
3173  * not a process identifier.
3174  */
3175 typedef $g_pid_type GPid;
3176
3177 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3178 #define GLIB_SYSDEF_AF_INET $g_af_inet
3179 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3180
3181 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3182 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3183 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3184
3185 G_END_DECLS
3186
3187 #endif /* GLIBCONFIG_H */
3188 _______EOF
3189
3190
3191         if cmp -s $outfile glib/glibconfig.h; then
3192           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3193           rm -f $outfile
3194         else
3195           mv $outfile glib/glibconfig.h
3196         fi
3197 ],[
3198
3199 # Note that if two cases are the same, case goes with the first one.
3200 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3201 # on variable expansion in case labels.  Look at the generated config.status
3202 # for a hint.
3203
3204 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3205   glib_header_alloca_h="$ac_cv_working_alloca_h"
3206 else
3207   glib_header_alloca_h="$ac_cv_header_alloca_h"
3208 fi
3209
3210 case xyes in
3211 x$ac_cv_header_float_h)
3212   glib_float_h=yes
3213   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3214   glib_md=DBL_MIN glib_Md=DBL_MAX
3215   ;;
3216 x$ac_cv_header_values_h)
3217   glib_values_h=yes
3218   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3219   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3220   ;;
3221 esac
3222
3223 case xyes in
3224 x$ac_cv_header_limits_h)
3225   glib_limits_h=yes
3226   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3227   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3228   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3229   ;;
3230 x$ac_cv_header_values_h)
3231   glib_values_h=yes
3232   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3233   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3234   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3235   ;;
3236 esac
3237
3238 if test x$ac_cv_header_sys_poll_h = xyes ; then
3239   glib_sys_poll_h=yes
3240 fi
3241
3242 if test x$enable_included_printf = xyes ; then
3243   glib_included_printf=yes
3244 fi
3245
3246 case 2 in
3247 $ac_cv_sizeof_short)
3248   gint16=short
3249   gint16_modifier='"h"'
3250   gint16_format='"hi"'
3251   guint16_format='"hu"'
3252   ;;
3253 $ac_cv_sizeof_int)
3254   gint16=int
3255   gint16_modifier='""'
3256   gint16_format='"i"'
3257   guint16_format='"u"'
3258   ;;
3259 esac
3260 case 4 in
3261 $ac_cv_sizeof_short)
3262   gint32=short
3263   gint32_modifier='"h"'
3264   gint32_format='"hi"'
3265   guint32_format='"hu"'
3266   ;;
3267 $ac_cv_sizeof_int)
3268   gint32=int
3269   gint32_modifier='""'
3270   gint32_format='"i"'
3271   guint32_format='"u"'
3272   ;;
3273 $ac_cv_sizeof_long)
3274   gint32=long
3275   gint32_modifier='"l"'
3276   gint32_format='"li"'
3277   guint32_format='"lu"'
3278   ;;
3279 esac
3280 case 8 in
3281 $ac_cv_sizeof_int)
3282   gint64=int
3283   gint64_modifier='""'
3284   gint64_format='"i"'
3285   guint64_format='"u"'
3286   glib_extension=
3287   gint64_constant='(val)'
3288   guint64_constant='(val)'
3289   ;;
3290 $ac_cv_sizeof_long)
3291   gint64=long
3292   gint64_modifier='"l"'
3293   gint64_format='"li"'
3294   guint64_format='"lu"'
3295   glib_extension=
3296   gint64_constant='(val##L)'
3297   guint64_constant='(val##UL)'
3298   ;;
3299 $ac_cv_sizeof_long_long)
3300   gint64='long long'
3301   if test -n "$glib_cv_long_long_format"; then
3302     gint64_modifier='"'$glib_cv_long_long_format'"'
3303     gint64_format='"'$glib_cv_long_long_format'i"'
3304     guint64_format='"'$glib_cv_long_long_format'u"'
3305   fi
3306   glib_extension='G_GNUC_EXTENSION '
3307   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3308   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3309   ;;
3310 $ac_cv_sizeof___int64)
3311   gint64='__int64'
3312   if test -n "$glib_cv_long_long_format"; then
3313     gint64_modifier='"'$glib_cv_long_long_format'"'
3314     gint64_format='"'$glib_cv_long_long_format'i"'
3315     guint64_format='"'$glib_cv_long_long_format'u"'
3316   fi
3317   glib_extension=
3318   gint64_constant='(val##i64)'
3319   guint64_constant='(val##ui64)'
3320   ;;
3321 esac
3322 glib_size_t=$ac_cv_sizeof_size_t
3323 glib_size_type_define="$glib_size_type"
3324 glib_void_p=$ac_cv_sizeof_void_p
3325 glib_long=$ac_cv_sizeof_long
3326
3327 case "$glib_size_type" in
3328 short)
3329   gsize_modifier='"h"'
3330   gsize_format='"hu"'
3331   gssize_format='"hi"'
3332   glib_msize_type='SHRT'
3333   ;;
3334 int)
3335   gsize_modifier='""'
3336   gsize_format='"u"'
3337   gssize_format='"i"'
3338   glib_msize_type='INT'
3339   ;;
3340 long)
3341   gsize_modifier='"l"'
3342   gsize_format='"lu"'
3343   gssize_format='"li"'
3344   glib_msize_type='LONG'
3345   ;;
3346 "long long"|__int64)
3347   gsize_modifier='"I64"'
3348   gsize_format='"I64u"'
3349   gssize_format='"I64i"'
3350   glib_msize_type='INT64'
3351   ;;
3352 esac
3353
3354 gintbits=`expr $ac_cv_sizeof_int \* 8`
3355 glongbits=`expr $ac_cv_sizeof_long \* 8`
3356 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3357
3358 case $ac_cv_sizeof_void_p in
3359 $ac_cv_sizeof_int)
3360   glib_intptr_type_define=int
3361   gintptr_modifier='""'
3362   gintptr_format='"i"'
3363   guintptr_format='"u"'
3364   glib_gpi_cast=''
3365   glib_gpui_cast=''
3366   ;;
3367 $ac_cv_sizeof_long)
3368   glib_intptr_type_define=long
3369   gintptr_modifier='"l"'
3370   gintptr_format='"li"'
3371   guintptr_format='"lu"'
3372   glib_gpi_cast='(glong)'
3373   glib_gpui_cast='(gulong)'
3374   ;;
3375 $ac_cv_sizeof_long_long)
3376   glib_intptr_type_define='long long'
3377   gintptr_modifier='"I64"'
3378   gintptr_format='"I64i"'
3379   guintptr_format='"I64u"'
3380   glib_gpi_cast='(gint64)'
3381   glib_gpui_cast='(guint64)'
3382   ;;
3383 $ac_cv_sizeof___int64)
3384   glib_intptr_type_define=__int64
3385   gintptr_modifier='"I64"'
3386   gintptr_format='"I64i"'
3387   guintptr_format='"I64u"'
3388   glib_gpi_cast='(gint64)'
3389   glib_gpui_cast='(guint64)'
3390   ;;
3391 *)
3392   glib_unknown_void_p=yes
3393   ;;
3394 esac
3395
3396
3397 case xyes in
3398 x$ac_cv_func_atexit)
3399   glib_atexit="
3400 #ifdef NeXT /* @#%@! NeXTStep */
3401 # define g_ATEXIT(proc) (!atexit (proc))
3402 #else
3403 # define g_ATEXIT(proc) (atexit (proc))
3404 #endif"
3405   ;;
3406 x$ac_cv_func_on_exit)
3407   glib_atexit="
3408 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3409   ;;
3410 esac
3411
3412 case xyes in
3413 x$ac_cv_func_memmove)
3414   glib_memmove='
3415 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3416   ;;
3417 x$glib_cv_working_bcopy)
3418   glib_memmove="
3419 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3420 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3421   ;;
3422 *)
3423   glib_memmove="
3424 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3425  * so we have to roll our own copy routine. */
3426 void g_memmove (void* dest, const void * src, unsigned long len);"
3427   ;;
3428 esac
3429
3430 glib_defines="
3431 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3432 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3433 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3434 "
3435
3436 case xyes in
3437 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3438 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3439 *)                      glib_vacopy=''
3440 esac
3441
3442 if test x$glib_cv_va_val_copy = xno; then
3443   glib_vacopy="\$glib_vacopy
3444 #define G_VA_COPY_AS_ARRAY 1"
3445 fi
3446
3447 if test x$glib_cv_hasinline = xyes; then
3448     glib_inline='#define G_HAVE_INLINE 1'
3449 fi
3450 if test x$glib_cv_has__inline = xyes; then
3451     glib_inline="\$glib_inline
3452 #define G_HAVE___INLINE 1"
3453 fi
3454 if test x$glib_cv_has__inline__ = xyes; then
3455     glib_inline="\$glib_inline
3456 #define G_HAVE___INLINE__ 1"
3457 fi
3458
3459 g_have_gnuc_varargs=$g_have_gnuc_varargs
3460 g_have_iso_c_varargs=$g_have_iso_c_varargs
3461 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3462
3463 g_can_inline=$g_can_inline
3464 g_have_gnuc_visibility=$g_have_gnuc_visibility
3465 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3466
3467 if test x$ac_cv_c_bigendian = xyes; then
3468   g_byte_order=G_BIG_ENDIAN
3469   g_bs_native=BE
3470   g_bs_alien=LE
3471 else
3472   g_byte_order=G_LITTLE_ENDIAN
3473   g_bs_native=LE
3474   g_bs_alien=BE
3475 fi
3476
3477 g_pollin=$glib_cv_value_POLLIN
3478 g_pollout=$glib_cv_value_POLLOUT
3479 g_pollpri=$glib_cv_value_POLLPRI
3480 g_pollhup=$glib_cv_value_POLLHUP
3481 g_pollerr=$glib_cv_value_POLLERR
3482 g_pollnval=$glib_cv_value_POLLNVAL
3483
3484 g_af_unix=$glib_cv_value_AF_UNIX
3485 g_af_inet=$glib_cv_value_AF_INET
3486 g_af_inet6=$glib_cv_value_AF_INET6
3487
3488 g_msg_peek=$glib_cv_value_MSG_PEEK
3489 g_msg_oob=$glib_cv_value_MSG_OOB
3490 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3491
3492 g_stack_grows=$glib_cv_stack_grows
3493
3494 g_have_eilseq=$have_eilseq
3495
3496 g_threads_impl_def=$g_threads_impl
3497
3498 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3499
3500 g_memory_barrier_needed="$glib_memory_barrier_needed"
3501 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3502
3503 g_module_suffix="$glib_gmodule_suffix"
3504
3505 g_pid_type="$glib_pid_type"
3506 case $host in
3507   *-*-beos*)
3508     glib_os="#define G_OS_BEOS"
3509     ;;
3510   *-*-cygwin*)
3511     glib_os="#define G_OS_UNIX
3512 #define G_PLATFORM_WIN32
3513 #define G_WITH_CYGWIN"
3514     ;;
3515   *-*-mingw*)
3516     glib_os="#define G_OS_WIN32
3517 #define G_PLATFORM_WIN32"
3518     ;;
3519   *)
3520     glib_os="#define G_OS_UNIX"
3521     ;;
3522 esac
3523 glib_static_compilation=""
3524 if test x$glib_win32_static_compilation = xyes; then
3525   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3526 #define GOBJECT_STATIC_COMPILATION 1"
3527 fi
3528 ])
3529
3530 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3531 #
3532 # 1.2.14 required for dbus_message_set_serial
3533 PKG_CHECK_MODULES(DBUS1,
3534                   dbus-1 >= 1.2.14,
3535                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3536                   have_dbus1=no)
3537 AC_SUBST(DBUS1_CFLAGS)
3538 AC_SUBST(DBUS1_LIBS)
3539 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3540
3541 dnl
3542 dnl Check for -Bsymbolic-functions linker flag used to avoid
3543 dnl intra-library PLT jumps, if available.
3544 dnl
3545
3546 AC_ARG_ENABLE(Bsymbolic,
3547               [AC_HELP_STRING([--disable-Bsymbolic],
3548                               [avoid linking with -Bsymbolic])],,
3549               [SAVED_LDFLAGS="${LDFLAGS}"
3550                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3551                LDFLAGS=-Wl,-Bsymbolic-functions
3552                AC_TRY_LINK([], [int main (void) { return 0; }],
3553                            AC_MSG_RESULT(yes)
3554                            enable_Bsymbolic=yes,
3555                            AC_MSG_RESULT(no)
3556                            enable_Bsymbolic=no)
3557                LDFLAGS="${SAVED_LDFLAGS}"])
3558
3559 if test "x${enable_Bsymbolic}" == "xyes"; then
3560   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3561 fi
3562
3563 AC_SUBST(GLIB_LINK_FLAGS)
3564
3565 #
3566 # Define variables corresponding to the correct include paths to use for
3567 # in-tree building.
3568 #
3569
3570 # for config.h:
3571 config_h_INCLUDES='-I$(top_builddir)'
3572 AC_SUBST(config_h_INCLUDES)
3573
3574 # glib:
3575 #   config.h
3576 #   $(top_builddir)/glib: for glibconfig.h
3577 #   $(top_srcdir)/glib:   for glib.h
3578 #   $(top_srcdir):        for everything
3579 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3580 AC_SUBST(glib_INCLUDES)
3581
3582 # gthread:
3583 #   same as glib
3584 gthread_INCLUDES='$(glib_INCLUDES)'
3585 AC_SUBST(gthread_INCLUDES)
3586
3587 # gobject:
3588 #   same as gthread
3589 gobject_INCLUDES='$(gthread_INCLUDES)'
3590 AC_SUBST(gobject_INCLUDES)
3591
3592 # gmodule:
3593 #   glib includes
3594 #   $(top_srcdir)/gmodule: for gmodule.h
3595 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3596 AC_SUBST(gmodule_INCLUDES)
3597
3598 # gio:
3599 #   same as gmodule
3600 gio_INCLUDES='$(gmodule_INCLUDES)'
3601 AC_SUBST(gio_INCLUDES)
3602
3603
3604 AC_CONFIG_FILES([
3605 glib-2.0.pc
3606 glib-2.0-uninstalled.pc
3607 gmodule-2.0.pc
3608 gmodule-export-2.0.pc
3609 gmodule-no-export-2.0.pc
3610 gmodule-2.0-uninstalled.pc
3611 gmodule-no-export-2.0-uninstalled.pc
3612 gthread-2.0.pc
3613 gthread-2.0-uninstalled.pc
3614 gobject-2.0.pc
3615 gobject-2.0-uninstalled.pc
3616 gio-2.0.pc
3617 gio-unix-2.0.pc
3618 gio-windows-2.0.pc
3619 gio-2.0-uninstalled.pc
3620 gio-unix-2.0-uninstalled.pc
3621 glib-zip
3622 glib-gettextize
3623 Makefile
3624 build/Makefile
3625 build/win32/Makefile
3626 build/win32/dirent/Makefile
3627 build/win32/vs9/Makefile
3628 build/win32/vs10/Makefile
3629 glib/Makefile
3630 glib/glib.stp
3631 glib/libcharset/Makefile
3632 glib/gnulib/Makefile
3633 glib/pcre/Makefile
3634 glib/update-pcre/Makefile
3635 glib/tests/Makefile
3636 gmodule/Makefile
3637 gmodule/gmoduleconf.h
3638 gobject/Makefile
3639 gobject/gobject.stp
3640 gobject/glib-mkenums
3641 gobject/tests/Makefile
3642 gthread/Makefile
3643 gthread/tests/Makefile
3644 gio/Makefile
3645 gio/gdbus-2.0/codegen/Makefile
3646 gio/gdbus-2.0/codegen/config.py
3647 gio/xdgmime/Makefile
3648 gio/inotify/Makefile
3649 gio/fen/Makefile
3650 gio/fam/Makefile
3651 gio/win32/Makefile
3652 gio/tests/Makefile
3653 gio/tests/gdbus-object-manager-example/Makefile
3654 po/Makefile.in
3655 docs/Makefile
3656 docs/reference/Makefile
3657 docs/reference/glib/Makefile
3658 docs/reference/glib/version.xml
3659 docs/reference/gobject/Makefile
3660 docs/reference/gobject/version.xml
3661 docs/reference/gio/Makefile
3662 docs/reference/gio/gdbus-object-manager-example/Makefile
3663 docs/reference/gio/version.xml
3664 tests/Makefile
3665 tests/gobject/Makefile
3666 tests/refcount/Makefile
3667 m4macros/Makefile
3668 ])
3669
3670 AC_CONFIG_COMMANDS([chmod-scripts],
3671 [chmod 0755 glib-zip
3672 chmod 0755 glib-gettextize
3673 chmod 0755 gobject/glib-mkenums])
3674
3675 # we want to invoke this macro solely so that the config.status script
3676 # and automake generated makefiles know about these generated files.
3677 # They are only needed to distcheck the package
3678 if false; then
3679   AC_CONFIG_FILES([
3680     INSTALL
3681     README
3682     config.h.win32
3683     glib/glibconfig.h.win32
3684     glib/makefile.msc
3685     glib/glib.rc
3686     gmodule/makefile.msc
3687     gmodule/gmodule.rc
3688     gobject/makefile.msc
3689     gobject/gobject.rc
3690     gthread/makefile.msc
3691     gthread/gthread.rc
3692     gio/gio.rc
3693     tests/makefile.msc
3694   ])
3695 fi
3696
3697 AC_OUTPUT