configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [29])
  30 m4_define([glib_micro_version], [19])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AC_CANONICAL_HOST
 112
 113 AC_MSG_CHECKING([for the BeOS])
 114 case $host in
 115   *-*-beos*)
 116     glib_native_beos="yes"
 117     ;;
 118   *)
 119     glib_native_beos="no"
 120     ;;
 121 esac
 122 AC_MSG_RESULT([$glib_native_beos])
 123
 124 dnl
 125
 126 AC_MSG_CHECKING([for Win32])
 127 LIB_EXE_MACHINE_FLAG=X86
 128 case "$host" in
 129   *-*-mingw*)
 130     glib_native_win32=yes
 131     glib_pid_type='void *'
 132     glib_cv_stack_grows=no
 133     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 134     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 135     # (Sorry, I don't know exactly what is the problem, but it is related to
 136     # floating point formatting and decimal point vs. comma.)
 137     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 138     # rigorous enough to notice, though.
 139     # So preset the autoconf cache variables.
 140     ac_cv_func_vsnprintf_c99=no
 141     ac_cv_func_snprintf_c99=no
 142     case "$host" in
 143     x86_64-*-*)
 144       LIB_EXE_MACHINE_FLAG=X64
 145       ;;
 146     esac
 147     ;;
 148   *)
 149     glib_native_win32=no
 150     glib_pid_type=int
 151     ;;
 152 esac
 153 case $host in
 154   *-*-linux*)
 155     glib_os_linux=yes
 156     ;;
 157 esac
 158
 159 AC_MSG_RESULT([$glib_native_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162
 163 glib_have_carbon=no
 164 AC_MSG_CHECKING([for Mac OS X Carbon support])
 165 AC_TRY_CPP([
 166 #include <Carbon/Carbon.h>
 167 #include <CoreServices/CoreServices.h>
 168 ], glib_have_carbon=yes)
 169
 170 AC_MSG_RESULT([$glib_have_carbon])
 171
 172 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 173 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 174 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 175 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 176 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 177
 178 if test "$glib_native_win32" = "yes"; then
 179   AC_CHECK_TOOL(WINDRES, windres, no)
 180   if test "$WINDRES" = no; then
 181     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 182   fi
 183   AC_CHECK_TOOL(NM, nm, no)
 184   if test "$NM" = no; then
 185     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 186   fi
 187   AC_CHECK_TOOL(RANLIB, ranlib, :)
 188   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 189 fi
 190 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 191
 192 if test "$glib_native_win32" != yes; then
 193     # libtool option to control which symbols are exported
 194     # right now, symbols starting with _ are not exported
 195     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 196 else
 197     # We currently use .def files on Windows
 198     LIBTOOL_EXPORT_OPTIONS=
 199 fi
 200 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 201
 202 if test "x$glib_have_carbon" = "xyes"; then
 203   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 204   LDFLAGS="$LDFLAGS -framework Carbon"
 205 fi
 206
 207 gl_GLIBC21
 208 if test "x$GLIBC21" = "xyes"; then
 209   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 210 fi
 211
 212 dnl declare --enable-* args and collect ac_help strings
 213 AC_ARG_ENABLE(debug,
 214               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 215                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 216               enable_debug=glib_debug_default)
 217
 218 AC_ARG_ENABLE(gc_friendly,
 219               [AC_HELP_STRING([--enable-gc-friendly],
 220                               [turn on garbage collector friendliness [default=no]])],,
 221               [enable_gc_friendly=no])
 222 AC_ARG_ENABLE(mem_pools,
 223               [AC_HELP_STRING([--disable-mem-pools],
 224                               [disable all glib memory pools])],,
 225               [disable_mem_pools=no])
 226 AC_ARG_ENABLE(threads,
 227               [AC_HELP_STRING([--enable-threads],
 228                               [turn on basic thread support [default=yes]
 229 ([=no] will override --with-threads)])],,
 230               [enable_threads=yes])
 231 AC_ARG_ENABLE(rebuilds,
 232               [AC_HELP_STRING([--disable-rebuilds],
 233                               [disable all source autogeneration rules])],,
 234               [enable_rebuilds=yes])
 235
 236 if test "x$enable_threads" != "xyes"; then
 237   enable_threads=no
 238 fi
 239
 240 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 241 if test "x$enable_gc_friendly" = "xyes"; then
 242   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 243   AC_MSG_RESULT([yes])
 244 else
 245   AC_MSG_RESULT([no])
 246 fi
 247
 248 AC_MSG_CHECKING([whether to disable memory pools])
 249 if test "x$disable_mem_pools" = "xno"; then
 250   AC_MSG_RESULT([no])
 251 else
 252   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 253   AC_SUBST(DISABLE_MEM_POOLS)
 254   AC_MSG_RESULT([yes])
 255 fi
 256
 257 dnl location to install runtime libraries, e.g. ../../lib to install
 258 dnl to /lib if libdir is /usr/lib
 259 AC_ARG_WITH(runtime-libdir,
 260            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 261                            [Install runtime libraries relative to libdir])],
 262            [],
 263            [with_runtime_libdir=""])
 264 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 265 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 266 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 267 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 268 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 269
 270 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 271 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 272 AC_LANG_SAVE
 273 AC_LANG_CPLUSPLUS
 274 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 275 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 276 AC_LANG_RESTORE
 277
 278 AM_PROG_CC_STDC
 279 AM_PROG_CC_C_O
 280 AC_PROG_INSTALL
 281
 282 AC_SYS_LARGEFILE
 283
 284 PKG_PROG_PKG_CONFIG(0.16)
 285
 286 if test "x$enable_debug" = "xyes"; then
 287   if test x$cflags_set != xset ; then
 288       case " $CFLAGS " in
 289       *[[\ \    ]]-g[[\ \       ]]*) ;;
 290       *) CFLAGS="$CFLAGS -g" ;;
 291       esac
 292   fi
 293
 294   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 295 else
 296   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 297
 298   if test "x$enable_debug" = "xno"; then
 299     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 300   fi
 301 fi
 302
 303 # Ensure MSVC-compatible struct packing convention is used when
 304 # compiling for Win32 with gcc.
 305 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 306 # gcc2 uses "-fnative-struct".
 307 if test x"$glib_native_win32" = xyes; then
 308   if test x"$GCC" = xyes; then
 309     msnative_struct=''
 310     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 311     if test -z "$ac_cv_prog_CC"; then
 312       our_gcc="$CC"
 313     else
 314       our_gcc="$ac_cv_prog_CC"
 315     fi
 316     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 317       2.)
 318         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 319           msnative_struct='-fnative-struct'
 320         fi
 321         ;;
 322       *)
 323         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 324           msnative_struct='-mms-bitfields'
 325         fi
 326         ;;
 327     esac
 328     if test x"$msnative_struct" = x ; then
 329       AC_MSG_RESULT([no way])
 330       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 331     else
 332       CFLAGS="$CFLAGS $msnative_struct"
 333       AC_MSG_RESULT([${msnative_struct}])
 334     fi
 335   fi
 336 fi
 337 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 338 AC_SUBST(GLIB_EXTRA_CFLAGS)
 339
 340 AC_EXEEXT
 341
 342 # define a MAINT-like variable REBUILD which is set if Perl
 343 # and awk are found, so autogenerated sources can be rebuilt
 344 AC_PROG_AWK
 345 AC_CHECK_PROGS(PERL, [perl5 perl])
 346 # We would like indent, but don't require it.
 347 AC_CHECK_PROG(INDENT, indent, indent)
 348 REBUILD=\#
 349 if test "x$enable_rebuilds" = "xyes" && \
 350      test -n "$PERL" && \
 351      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 352      test -n "$AWK" ; then
 353   REBUILD=
 354 fi
 355 AC_SUBST(REBUILD)
 356
 357 # Need full path to Perl for glib-mkenums
 358 #
 359 if test "x$PERL" != x ; then
 360   AC_PATH_PROG(PERL_PATH, [$PERL])
 361 fi
 362 if test "x$PERL_PATH" = x ; then
 363   PERL_PATH="/usr/bin/env perl"
 364 fi
 365 AC_SUBST(PERL_PATH)
 366
 367 # Need suitable python path for greport
 368 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 369
 370
 371 dnl ***********************
 372 dnl *** Tests for iconv ***
 373 dnl ***********************
 374 dnl
 375 dnl We do this before the gettext checks, to avoid distortion
 376
 377 dnl On Windows we use a native implementation
 378
 379 if test x"$glib_native_win32" = xyes; then
 380   with_libiconv=native
 381 else
 382   AC_ARG_WITH(libiconv,
 383               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 384                               [use the libiconv library])],,
 385               [with_libiconv=maybe])
 386
 387   found_iconv=no
 388   case $with_libiconv in
 389     maybe)
 390       # Check in the C library first
 391       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 392       # Check if we have GNU libiconv
 393       if test $found_iconv = "no"; then
 394         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 395       fi
 396       # Check if we have a iconv in -liconv, possibly from vendor
 397       if test $found_iconv = "no"; then
 398         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 399       fi
 400       ;;
 401     no)
 402       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 403       ;;
 404     gnu|yes)
 405       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 406       ;;
 407     native)
 408       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 409       ;;
 410   esac
 411
 412   if test "x$found_iconv" = "xno" ; then
 413      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 414   fi
 415 fi
 416
 417 AC_ARG_ENABLE(iconv-cache,
 418               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 419                               [cache iconv descriptors [default=auto]])],,
 420               [enable_iconv_cache=auto])
 421
 422 AC_MSG_CHECKING([whether to cache iconv descriptors])
 423 case $enable_iconv_cache in
 424   auto)
 425     if test $ac_cv_gnu_library_2_1 = yes; then
 426       enable_iconv_cache=no
 427     else
 428       enable_iconv_cache=yes
 429     fi
 430   ;;
 431   yes|no)
 432   ;;
 433   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 434   ;;
 435 esac
 436
 437 if test $enable_iconv_cache = yes; then
 438    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 439 fi
 440
 441 AC_MSG_RESULT($enable_iconv_cache)
 442
 443
 444 dnl
 445 dnl zlib support
 446 dnl
 447 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 448 if test "x$found_zlib" = "xno" ; then
 449   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 450   if test "x$found_zlib" = "xno" ; then
 451     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 452   fi
 453   ZLIB_LIBS='-lz'
 454   AC_SUBST(ZLIB_LIBS)
 455 fi
 456
 457 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 458 AC_SUBST(LIBFFI_CFLAGS)
 459 AC_SUBST(LIBFFI_LIBS)
 460
 461 dnl
 462 dnl gettext support
 463 dnl
 464
 465 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 466 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 467 GLIB_GNU_GETTEXT
 468
 469 if test "$gt_cv_have_gettext" != "yes" ; then
 470   AC_MSG_ERROR([
 471 *** You must have either have gettext support in your C library, or use the
 472 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 473 ])
 474 fi
 475
 476 LIBS="$INTLLIBS $LIBS"
 477
 478 GETTEXT_PACKAGE=glib20
 479 AC_SUBST(GETTEXT_PACKAGE)
 480 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 481   [Define the gettext package to be used])
 482
 483 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 484
 485 dnl
 486 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 487 dnl
 488
 489 if test x"$glib_native_win32" != xyes; then
 490   if test x$with_libiconv != xno ; then
 491     case " $INTLLIBS " in
 492     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 493     *) ICONV_LIBS="-liconv" ;;
 494     esac
 495   fi
 496 fi
 497 AC_SUBST(ICONV_LIBS)
 498
 499 case $with_libiconv in
 500   gnu)
 501     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 502     ;;
 503   native)
 504     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 505     ;;
 506 esac
 507
 508 dnl Initialize libtool
 509 LT_PREREQ([2.2])
 510 LT_INIT([disable-static win32-dll])
 511 dnl when using libtool 2.x create libtool early, because it's used in configure
 512 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 513
 514
 515 if test "x$GCC" = "xyes"; then
 516   case " $CFLAGS " in
 517   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 518   *) CFLAGS="$CFLAGS -Wall" ;;
 519   esac
 520 fi
 521
 522 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 523
 524 if test "$glib_native_win32" = "yes"; then
 525   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 526     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 527   fi
 528   if test x$enable_static = xyes; then
 529     glib_win32_static_compilation=yes
 530     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 531 #define GOBJECT_STATIC_COMPILATION 1"
 532     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 533   fi
 534 fi
 535 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 536
 537 dnl
 538 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 539 dnl
 540 if test $cross_compiling != yes ; then
 541     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 542     glib_save_LIBS=$LIBS
 543     LIBS="$LIBS -lm"
 544     AC_TRY_RUN([#include <math.h>
 545                  int main (void) { return (log(1) != log(1.)); }],
 546          AC_MSG_RESULT(none needed),
 547          glib_save_CFLAGS=$CFLAGS
 548          CFLAGS="$CFLAGS -std1"
 549          AC_TRY_RUN([#include <math.h>
 550                      int main (void) { return (log(1) != log(1.)); }],
 551              AC_MSG_RESULT(-std1),
 552              AC_MSG_RESULT()
 553              CFLAGS=$glib_save_CFLAGS
 554              AC_MSG_WARN(
 555                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 556          )
 557     )
 558     LIBS=$glib_save_LIBS
 559 fi
 560
 561 dnl NeXTStep cc seems to need this
 562 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 563 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 564   AC_MSG_RESULT(none needed),
 565   glib_save_CFLAGS=$CFLAGS
 566   CFLAGS="$CFLAGS -posix"
 567   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 568     AC_MSG_RESULT(-posix),
 569     AC_MSG_RESULT()
 570     CFLAGS=$glib_save_CFLAGS
 571     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 572
 573 # Checks for header files.
 574 AC_HEADER_STDC
 575
 576 # Checks for library functions.
 577 AC_FUNC_VPRINTF
 578 AC_FUNC_ALLOCA
 579 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 580 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 581
 582 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 583 dnl be automatically defined, which we don't want to do
 584 dnl until we have checked this function is actually usable
 585 AC_CHECK_FUNC([qsort_r])
 586
 587 # BSD has a qsort_r with wrong argument order
 588 if test x$ac_cv_func_qsort_r = xyes ; then
 589   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 590   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 591   #define _GNU_SOURCE
 592   #include <stdlib.h>
 593
 594   static int
 595   cmp (const void *a, const void *b, void *c)
 596   {
 597     const int *ia = a;
 598     const int *ib = b;
 599
 600     if (*ia < *ib)
 601       return -1;
 602     else if (*ia > *ib)
 603       return 1;
 604     else
 605       return 0;
 606   }
 607
 608   int
 609   main (int argc, char **argv)
 610   {
 611     int arr[3] = { 1, 2, 0 };
 612     int d = 3;
 613
 614     qsort_r (arr, 3, sizeof (int), cmp, &d);
 615
 616     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 617       return 0;
 618     else
 619       return 1;
 620   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 621 fi
 622
 623 if test x$glib_cv_have_qsort_r = xyes ; then
 624   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 625 fi
 626
 627 AC_CHECK_SIZEOF(char)
 628 AC_CHECK_SIZEOF(short)
 629 AC_CHECK_SIZEOF(long)
 630 AC_CHECK_SIZEOF(int)
 631 AC_CHECK_SIZEOF(void *)
 632 AC_CHECK_SIZEOF(long long)
 633 AC_CHECK_SIZEOF(__int64)
 634
 635 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 636   :
 637 else
 638   AC_MSG_ERROR([
 639 *** GLib requires a 64 bit type. You might want to consider
 640 *** using the GNU C compiler.
 641 ])
 642 fi
 643
 644 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 645         # long long is a 64 bit integer.
 646         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 647         AC_CACHE_VAL(glib_cv_long_long_format,[
 648                 for format in ll q I64; do
 649                   AC_TRY_RUN([#include <stdio.h>
 650                         int main()
 651                         {
 652                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 653                           char buffer[1000];
 654                           sprintf (buffer, "%${format}u", a);
 655                           sscanf (buffer, "%${format}u", &b);
 656                           exit (b!=a);
 657                         }
 658                         ],
 659                         [glib_cv_long_long_format=${format}
 660                         break],
 661                         [],[:])
 662                 done])
 663         if test -n "$glib_cv_long_long_format"; then
 664           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 665           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 666           if test x"$glib_cv_long_long_format" = xI64; then
 667             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 668           fi
 669         else
 670           AC_MSG_RESULT(none)
 671         fi
 672 elif test x$ac_cv_sizeof___int64 = x8; then
 673         # __int64 is a 64 bit integer.
 674         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 675         # We know this is MSVCRT.DLL, and what the formats are
 676         glib_cv_long_long_format=I64
 677         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 678         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 679         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 680 fi
 681
 682 dnl long doubles were not used, and a portability problem
 683 dnl AC_C_LONG_DOUBLE
 684 AC_C_CONST
 685
 686 dnl ok, here we try to check whether the systems prototypes for
 687 dnl malloc and friends actually match the prototypes provided
 688 dnl by gmem.h (keep in sync). i currently only know how to check
 689 dnl this reliably with gcc (-Werror), improvements for other
 690 dnl compilers are apprechiated.
 691 SANE_MALLOC_PROTOS=no
 692 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 693 glib_save_CFLAGS=$CFLAGS
 694 if test "x$GCC" = "xyes"; then
 695   CFLAGS="$CFLAGS -Werror"
 696   AC_TRY_COMPILE([#include <stdlib.h>], [
 697     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 698     void* (*my_malloc_p)  (size_t)         = malloc;
 699     void  (*my_free_p)    (void*)          = free;
 700     void* (*my_realloc_p) (void*, size_t)  = realloc;
 701     my_calloc_p = 0;
 702     my_malloc_p = 0;
 703     my_free_p = 0;
 704     my_realloc_p = 0;
 705   ],
 706     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 707       [Define if you have correct malloc prototypes])
 708     SANE_MALLOC_PROTOS=yes)
 709 fi
 710 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 711 CFLAGS=$glib_save_CFLAGS
 712
 713 dnl
 714 dnl check in which direction the stack grows
 715 dnl
 716 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 717         AC_TRY_RUN([
 718         volatile int *a = 0, *b = 0;
 719         void foo (void);
 720         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 721         void foo (void) { volatile int x = 5; b = &x; }
 722         ],
 723         glib_cv_stack_grows=no
 724         ,
 725         glib_cv_stack_grows=yes
 726         ,)
 727 ])
 728
 729 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 730 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 731 dnl actually supported.
 732 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 733         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 734         __inline int foo () { return 0; }
 735         int main () { return foo (); }
 736         ]])],
 737         glib_cv_has__inline=yes
 738         ,
 739         glib_cv_has__inline=no
 740         ,)
 741 ])
 742 case x$glib_cv_has__inline in
 743 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 744 esac
 745 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 746         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 747         __inline__ int foo () { return 0; }
 748         int main () { return foo (); }
 749         ]])],
 750         glib_cv_has__inline__=yes
 751         ,
 752         glib_cv_has__inline__=no
 753         ,)
 754 ])
 755 case x$glib_cv_has__inline__ in
 756 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 757 esac
 758 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 759         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 760         #undef inline
 761         inline int foo () { return 0; }
 762         int main () { return foo (); }
 763         ]])],
 764         glib_cv_hasinline=yes
 765         ,
 766         glib_cv_hasinline=no
 767         ,)
 768 ])
 769 case x$glib_cv_hasinline in
 770 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 771 esac
 772
 773 # if we can use inline functions in headers
 774 AC_MSG_CHECKING(if inline functions in headers work)
 775 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 776 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 777 #  undef inline
 778 #  define inline __inline__
 779 #elif !defined (G_HAVE_INLINE)
 780 #  undef inline
 781 #  if defined (G_HAVE___INLINE__)
 782 #    define inline __inline__
 783 #  elif defined (G_HAVE___INLINE)
 784 #    define inline __inline
 785 #  endif
 786 #endif
 787
 788 int glib_test_func2 (int);
 789
 790 static inline int
 791 glib_test_func1 (void) {
 792   return glib_test_func2 (1);
 793 }
 794
 795 int
 796 main (void) {
 797   int i = 1;
 798 }]])],[g_can_inline=yes],[g_can_inline=no])
 799 AC_MSG_RESULT($g_can_inline)
 800
 801 dnl *** check for working do while(0) macros ***
 802 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 803         AC_TRY_COMPILE([],[
 804         #define STMT_START do
 805         #define STMT_END while(0)
 806         #define STMT_TEST STMT_START { i = 0; } STMT_END
 807         int main(void) { int i = 1; STMT_TEST; return i; }],
 808         [g_cv_support_dowhile_macros=yes],
 809         [g_cv_support_dowhile_macros=no],
 810         [g_cv_support_dowhile_macros=yes])
 811 ])
 812 if test x$g_cv_support_dowhile_macros = xyes; then
 813   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 814 fi
 815
 816 # check for flavours of varargs macros
 817 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 818 AC_TRY_COMPILE([],[
 819 int a(int p1, int p2, int p3);
 820 #define call_a(...) a(1,__VA_ARGS__)
 821 call_a(2,3);
 822 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 823 AC_MSG_RESULT($g_have_iso_c_varargs)
 824
 825 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 826 if test "$CXX" = ""; then
 827 dnl No C++ compiler
 828   g_have_iso_cxx_varargs=no
 829 else
 830   AC_LANG_CPLUSPLUS
 831   AC_TRY_COMPILE([],[
 832 int a(int p1, int p2, int p3);
 833 #define call_a(...) a(1,__VA_ARGS__)
 834 call_a(2,3);
 835 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 836   AC_LANG_C
 837 fi
 838 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 839
 840 AC_MSG_CHECKING(for GNUC varargs macros)
 841 AC_TRY_COMPILE([],[
 842 int a(int p1, int p2, int p3);
 843 #define call_a(params...) a(1,params)
 844 call_a(2,3);
 845 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 846 AC_MSG_RESULT($g_have_gnuc_varargs)
 847
 848 # check for GNUC visibility support
 849 AC_MSG_CHECKING(for GNUC visibility attribute)
 850 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 851 void
 852 __attribute__ ((visibility ("hidden")))
 853      f_hidden (void)
 854 {
 855 }
 856 void
 857 __attribute__ ((visibility ("internal")))
 858      f_internal (void)
 859 {
 860 }
 861 void
 862 __attribute__ ((visibility ("protected")))
 863      f_protected (void)
 864 {
 865 }
 866 void
 867 __attribute__ ((visibility ("default")))
 868      f_default (void)
 869 {
 870 }
 871 int main (int argc, char **argv)
 872 {
 873         f_hidden();
 874         f_internal();
 875         f_protected();
 876         f_default();
 877         return 0;
 878 }
 879 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 880 AC_MSG_RESULT($g_have_gnuc_visibility)
 881 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 882
 883 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 884 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 885 #else
 886 # include "error: this is not Sun Studio."
 887 #endif
 888 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 889 AC_MSG_RESULT($g_have_sunstudio_visibility)
 890 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 891
 892 # check for bytesex stuff
 893 AC_C_BIGENDIAN
 894 if test x$ac_cv_c_bigendian = xuniversal ; then
 895 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 896 #else
 897 #error Not a big endian.
 898 #endif],
 899     ac_cv_c_bigendian=yes
 900     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 901 #else
 902 #error Not a little endian.
 903 #endif],
 904     ac_cv_c_bigendian=no
 905     ,AC_MSG_WARN([Could not determine endianness.])))
 906 fi
 907
 908
 909 # check for header files
 910 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 911 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 912 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 913 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 914 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 915 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 916 AC_CHECK_HEADERS([linux/magic.h])
 917
 918 # check for structure fields
 919 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 920 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 921 #include <sys/stat.h>
 922 #include <unistd.h>
 923 #ifdef HAVE_SYS_STATFS_H
 924 #include <sys/statfs.h>
 925 #endif
 926 #ifdef HAVE_SYS_PARAM_H
 927 #include <sys/param.h>
 928 #endif
 929 #ifdef HAVE_SYS_MOUNT_H
 930 #include <sys/mount.h>
 931 #endif])
 932 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 933 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 934 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 935
 936 # Checks for libcharset
 937 AM_LANGINFO_CODESET
 938 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 939 AC_CHECK_FUNCS(setlocale)
 940
 941 # check additional type sizes
 942 AC_CHECK_SIZEOF(size_t)
 943
 944 dnl Try to figure out whether gsize, gssize should be long or int
 945 AC_MSG_CHECKING([for the appropriate definition for size_t])
 946
 947 case $ac_cv_sizeof_size_t in
 948   $ac_cv_sizeof_short)
 949       glib_size_type=short
 950       ;;
 951   $ac_cv_sizeof_int)
 952       glib_size_type=int
 953       ;;
 954   $ac_cv_sizeof_long)
 955       glib_size_type=long
 956       ;;
 957   $ac_cv_sizeof_long_long)
 958       glib_size_type='long long'
 959       ;;
 960   $ac_cv_sizeof__int64)
 961       glib_size_type='__int64'
 962       ;;
 963   *)  AC_MSG_ERROR([No type matching size_t in size])
 964       ;;
 965 esac
 966
 967 dnl If int/long are the same size, we see which one produces
 968 dnl warnings when used in the location as size_t. (This matters
 969 dnl on AIX with xlc)
 970 dnl
 971 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 972    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 973   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 974 #if defined(_AIX) && !defined(__GNUC__)
 975 #pragma options langlvl=stdc89
 976 #endif
 977 #include <stddef.h>
 978 int main ()
 979 {
 980   size_t s = 1;
 981   unsigned int *size_int = &s;
 982   return (int)*size_int;
 983 }
 984     ]])],glib_size_type=int,
 985       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 986 #if defined(_AIX) && !defined(__GNUC__)
 987 #pragma options langlvl=stdc89
 988 #endif
 989 #include <stddef.h>
 990 int main ()
 991 {
 992    size_t s = 1;
 993    unsigned long *size_long = &s;
 994    return (int)*size_long;
 995 }
 996         ]])],glib_size_type=long)])
 997 fi
 998
 999 AC_MSG_RESULT(unsigned $glib_size_type)
1000
1001 # Check for some functions
1002 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1003 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1004 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getmntinfo)
1005 # Check for high-resolution sleep functions
1006 AC_CHECK_FUNCS(splice)
1007
1008 # To avoid finding a compatibility unusable statfs, which typically
1009 # successfully compiles, but warns to use the newer statvfs interface:
1010 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1011 AS_IF([test $ac_cv_header_sys_statfs_h  = yes], [AC_CHECK_FUNCS([statfs])])
1012
1013 AC_MSG_CHECKING([whether to use statfs or statvfs])
1014 # Some systems have both statfs and statvfs, pick the most "native" for these
1015 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1016    [
1017    # on solaris and irix, statfs doesn't even have the f_bavail field
1018    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1019       [ac_cv_func_statfs=no],
1020    # else, at least on linux, statfs is the actual syscall
1021       [ac_cv_func_statvfs=no])
1022    ])
1023
1024 AS_IF([test x$ac_cv_func_statfs = xyes],
1025       [
1026          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1027          AC_MSG_RESULT([statfs])
1028       ],
1029       [test x$ac_cv_func_statvfs = xyes],
1030       [
1031          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1032          AC_MSG_RESULT([statvfs])
1033       ],
1034       [  AC_MSG_RESULT([neither])])
1035
1036 AC_CHECK_HEADERS(crt_externs.h)
1037 AC_CHECK_FUNCS(_NSGetEnviron)
1038
1039 AC_FUNC_VSNPRINTF_C99
1040 AC_FUNC_PRINTF_UNIX98
1041
1042 # Internet address families
1043 if test $glib_native_win32 = yes; then
1044   glib_inet_includes=["
1045 #include <winsock2.h>
1046   "]
1047 else
1048   glib_inet_includes=["
1049 #include <sys/types.h>
1050 #include <sys/socket.h>
1051   "]
1052 fi
1053
1054 glib_failed=false
1055 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1056 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1057 # winsock defines this even though it doesn't support it
1058 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1059 if $glib_failed ; then
1060   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1061 fi
1062
1063 glib_failed=false
1064 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1065 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1066 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1067 if $glib_failed ; then
1068   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1069 fi
1070
1071 AC_CHECK_FUNCS(getprotobyname_r endservent)
1072 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1073
1074 # For gio/libasyncns
1075 AC_CHECK_FUNCS(strndup setresuid setreuid)
1076 AC_CHECK_HEADERS(sys/prctl.h)
1077
1078 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1079 NETWORK_LIBS=""
1080 AC_MSG_CHECKING([for res_query])
1081 AC_TRY_LINK([#include <sys/types.h>
1082              #include <netinet/in.h>
1083              #include <arpa/nameser.h>
1084              #include <resolv.h>
1085             ],[
1086              res_query("test", 0, 0, (void *)0, 0);
1087             ],[AC_MSG_RESULT([yes])],
1088             [save_libs="$LIBS"
1089              LIBS="-lresolv $LIBS"
1090              AC_TRY_LINK([#include <sys/types.h>
1091                           #include <netinet/in.h>
1092                           #include <arpa/nameser.h>
1093                           #include <resolv.h>
1094                          ],[
1095                           res_query("test", 0, 0, (void *)0, 0);
1096                          ],[AC_MSG_RESULT([in -lresolv])
1097                             NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1098                          [LIBS="-lbind $save_libs"
1099                           AC_TRY_LINK([#include <resolv.h>],
1100                                       [res_query("test", 0, 0, (void *)0, 0);],
1101                                       [AC_MSG_RESULT([in -lbind])
1102                                        NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1103                                       [AC_MSG_ERROR(not found)])])
1104              LIBS="$save_libs"])
1105 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1106                                       [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1107                                       [AC_MSG_ERROR(Could not find socket())]))
1108 AC_SUBST(NETWORK_LIBS)
1109
1110 case $host in
1111   *-*-solaris* )
1112      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1113      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1114      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1115      ;;
1116 esac
1117
1118 dnl
1119 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1120 dnl
1121 if test "$ac_cv_func_statfs" = yes ; then
1122   AC_MSG_CHECKING([number of arguments to statfs()])
1123   AC_TRY_COMPILE([#include <unistd.h>
1124   #ifdef HAVE_SYS_PARAM_H
1125   #include <sys/param.h>
1126   #endif
1127   #ifdef HAVE_SYS_VFS_H
1128   #include <sys/vfs.h>
1129   #endif
1130   #ifdef HAVE_SYS_MOUNT_H
1131   #include <sys/mount.h>
1132   #endif
1133   #ifdef HAVE_SYS_STATFS_H
1134   #include <sys/statfs.h>
1135   #endif], [struct statfs st;
1136   statfs(NULL, &st);],[
1137     AC_MSG_RESULT([2])
1138     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1139     AC_TRY_COMPILE([#include <unistd.h>
1140   #ifdef HAVE_SYS_PARAM_H
1141   #include <sys/param.h>
1142   #endif
1143   #ifdef HAVE_SYS_VFS_H
1144   #include <sys/vfs.h>
1145   #endif
1146   #ifdef HAVE_SYS_MOUNT_H
1147   #include <sys/mount.h>
1148   #endif
1149   #ifdef HAVE_SYS_STATFS_H
1150   #include <sys/statfs.h>
1151   #endif], [struct statfs st;
1152   statfs(NULL, &st, sizeof (st), 0);],[
1153       AC_MSG_RESULT([4])
1154       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1155       AC_MSG_RESULT(unknown)
1156       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1157 fi
1158
1159 #
1160 # Check whether to use an included printf
1161 #
1162
1163 AC_ARG_ENABLE(included-printf,
1164               [AC_HELP_STRING([--enable-included-printf],
1165                               [use included printf [default=auto]])],
1166               enable_included_printf="$enableval")
1167
1168 need_included_printf=no
1169 if test "x$enable_included_printf" = "xyes" ; then
1170   need_included_printf=yes
1171 fi
1172 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1173   need_included_printf=yes
1174 fi
1175 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1176   need_included_printf=yes
1177 fi
1178 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1179    test -z "$glib_cv_long_long_format" ; then
1180   need_included_printf=yes
1181 fi
1182
1183 if test "x$enable_included_printf" = "xno" &&
1184    test "x$need_included_printf" = "xyes" ; then
1185   AC_MSG_ERROR([
1186 *** Your C library's printf doesn't appear to have the features that
1187 *** GLib needs, but you specified --enable-included-printf=no.])
1188 fi
1189
1190 enable_included_printf=$need_included_printf
1191
1192 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1193 if test "$enable_included_printf" != "yes" ; then
1194   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1195 else
1196   if test -z "$glib_cv_long_long_format" ; then
1197     glib_cv_long_long_format="ll"
1198   fi
1199   AC_DEFINE(HAVE_VASPRINTF,1)
1200 fi
1201
1202 # Checks needed for gnulib vasnprintf
1203 bh_C_SIGNED
1204 jm_AC_TYPE_LONG_LONG
1205 gt_TYPE_LONGDOUBLE
1206 gt_TYPE_WCHAR_T
1207 gt_TYPE_WINT_T
1208 AC_TYPE_SIZE_T
1209 AC_CHECK_TYPES(ptrdiff_t)
1210 jm_AC_TYPE_INTMAX_T
1211 AC_CHECK_FUNCS([snprintf wcslen])
1212 AC_FUNC_SNPRINTF_C99
1213
1214 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1215 # The check is borrowed from the PERL Configure script.
1216 if test "$ac_cv_func_memmove" != "yes"; then
1217   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1218     glib_cv_working_bcopy,[AC_TRY_RUN([
1219       int main() {
1220         char buf[128], abc[128], *b;
1221         int len, off, align;
1222         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1223         for (align = 7; align >= 0; align--) {
1224           for (len = 36; len; len--) {
1225             b = buf+align; bcopy(abc, b, len);
1226             for (off = 1; off <= len; off++) {
1227               bcopy(b, b+off, len); bcopy(b+off, b, len);
1228                 if (bcmp(b, abc, len)) return(1);
1229             }
1230           }
1231         }
1232         return(0);
1233       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1234
1235   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1236   if test "$glib_cv_working_bcopy" = "yes"; then
1237     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1238   fi
1239 fi
1240
1241 # Check for sys_errlist
1242 AC_MSG_CHECKING(for sys_errlist)
1243 AC_TRY_LINK(, [
1244 extern char *sys_errlist[];
1245 extern int sys_nerr;
1246 sys_errlist[sys_nerr-1][0] = 0;
1247 ], glib_ok=yes, glib_ok=no)
1248 AC_MSG_RESULT($glib_ok)
1249 if test "$glib_ok" = "no"; then
1250     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1251 fi
1252
1253 # Check for sys_siglist
1254 AC_MSG_CHECKING(for sys_siglist)
1255 AC_TRY_LINK(, [
1256 extern char *sys_siglist[];
1257 exit (sys_siglist[0]);
1258 ], glib_ok=yes, glib_ok=no)
1259 AC_MSG_RESULT($glib_ok)
1260 if test "$glib_ok" = "no"; then
1261     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1262 fi
1263
1264 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1265 AC_MSG_CHECKING(for sys_siglist declaration)
1266 AC_TRY_COMPILE([#include <signal.h>], [
1267 strlen (sys_siglist[0]);
1268 ], glib_ok=yes, glib_ok=no)
1269 AC_MSG_RESULT($glib_ok)
1270 if test "$glib_ok" = "no"; then
1271     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1272 fi
1273
1274 # Check if <sys/select.h> needs to be included for fd_set
1275 AC_MSG_CHECKING([for fd_set])
1276 AC_TRY_COMPILE([#include <sys/types.h>],
1277         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1278 if test "$gtk_ok" = "yes"; then
1279     AC_MSG_RESULT([yes, found in sys/types.h])
1280 else
1281     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1282     if test "$gtk_ok" = "yes"; then
1283         # *** FIXME: give it a different name
1284         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1285         AC_MSG_RESULT([yes, found in sys/select.h])
1286     else
1287         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1288         AC_MSG_RESULT(no)
1289     fi
1290 fi
1291
1292 dnl *** check for sane realloc() ***
1293 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1294         AC_TRY_RUN([#include <stdlib.h>
1295         int main() {
1296           return realloc (0, sizeof (int)) == 0;
1297         }],
1298         [glib_cv_sane_realloc=yes],
1299         [glib_cv_sane_realloc=no],
1300         [glib_cv_sane_realloc=yes])
1301 ])
1302 if test x$glib_cv_sane_realloc = xyes; then
1303   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1304 fi
1305
1306 dnl Check for nl_langinfo and CODESET
1307 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1308         AC_TRY_COMPILE([#include <langinfo.h>],
1309                 [char *codeset = nl_langinfo (CODESET);],
1310                 [glib_cv_langinfo_codeset=yes],
1311                 [glib_cv_langinfo_codeset=no])])
1312 if test x$glib_cv_langinfo_codeset = xyes; then
1313   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1314 fi
1315
1316 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1317 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1318         AC_TRY_COMPILE([#include <langinfo.h>],
1319                 [char *str;
1320                  str = nl_langinfo (PM_STR);
1321                  str = nl_langinfo (D_FMT);
1322                  str = nl_langinfo (T_FMT);
1323                  str = nl_langinfo (MON_1);
1324                  str = nl_langinfo (ABMON_12);
1325                  str = nl_langinfo (DAY_1);
1326                  str = nl_langinfo (ABDAY_7);],
1327                 [glib_cv_langinfo_time=yes],
1328                 [glib_cv_langinfo_time=no])])
1329 if test x$glib_cv_langinfo_time = xyes; then
1330   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1331 fi
1332
1333 dnl ****************************************
1334 dnl *** posix_memalign                   ***
1335 dnl ****************************************
1336 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1337 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1338     glib_cv_compliant_posix_memalign=0
1339     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1340         AC_TRY_RUN([
1341                 #define _XOPEN_SOURCE 600
1342                 #include <stdlib.h> /* posix_memalign() should be defined here */
1343                 /* some systems break if #include <malloc.h> used */
1344                 static void test_memalign (size_t boundary, size_t size) {
1345                     void *mem = 0;
1346                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1347                         exit (1);
1348                     else
1349                       free (mem);
1350                 }
1351                 int main() {
1352                     test_memalign (  128,   128 - 2 * sizeof (void*));
1353                     test_memalign (  256,   256 - 2 * sizeof (void*));
1354                     test_memalign (  512,   512 - 2 * sizeof (void*));
1355                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1356                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1357                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1358                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1359                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1360                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1361                     exit (0); /* success */
1362                 }
1363                 ],
1364             [glib_cv_compliant_posix_memalign=1], [], [:])
1365       :
1366     fi
1367     ])
1368 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1369     AC_MSG_RESULT(yes)
1370     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1371 else
1372     AC_MSG_RESULT(no)
1373 fi
1374
1375
1376 dnl ****************************************
1377 dnl *** strlcpy/strlcat                  ***
1378 dnl ****************************************
1379 # Check for strlcpy
1380 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1381 AC_TRY_RUN([#include <stdlib.h>
1382 #include <string.h>
1383 int main() {
1384   char p[10];
1385   (void) strlcpy (p, "hi", 10);
1386   if (strlcat (p, "bye", 0) != 3)
1387     return 1;
1388   return 0;
1389 }], glib_cv_have_strlcpy=yes,
1390     glib_cv_have_strlcpy=no,
1391     glib_cv_have_strlcpy=no)])
1392 if test "$glib_cv_have_strlcpy" = "yes"; then
1393     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1394 fi
1395
1396
1397 dnl **********************
1398 dnl *** va_copy checks ***
1399 dnl **********************
1400 dnl we currently check for all three va_copy possibilities, so we get
1401 dnl all results in config.log for bug reports.
1402 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1403         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1404 #include <stdlib.h>
1405         void f (int i, ...) {
1406         va_list args1, args2;
1407         va_start (args1, i);
1408         va_copy (args2, args1);
1409         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1410           exit (1);
1411         va_end (args1); va_end (args2);
1412         }
1413         int main() {
1414           f (0, 42);
1415           return 0;
1416         }]])],
1417         [glib_cv_va_copy=yes],
1418         [glib_cv_va_copy=no])
1419 ])
1420 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1421         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1422 #include <stdlib.h>
1423         void f (int i, ...) {
1424         va_list args1, args2;
1425         va_start (args1, i);
1426         __va_copy (args2, args1);
1427         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1428           exit (1);
1429         va_end (args1); va_end (args2);
1430         }
1431         int main() {
1432           f (0, 42);
1433           return 0;
1434         }]])],
1435         [glib_cv___va_copy=yes],
1436         [glib_cv___va_copy=no])
1437 ])
1438
1439 if test "x$glib_cv_va_copy" = "xyes"; then
1440   g_va_copy_func=va_copy
1441 else if test "x$glib_cv___va_copy" = "xyes"; then
1442   g_va_copy_func=__va_copy
1443 fi
1444 fi
1445
1446 if test -n "$g_va_copy_func"; then
1447   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1448 fi
1449
1450 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1451         AC_TRY_RUN([#include <stdarg.h>
1452 #include <stdlib.h>
1453         void f (int i, ...) {
1454         va_list args1, args2;
1455         va_start (args1, i);
1456         args2 = args1;
1457         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1458           exit (1);
1459         va_end (args1); va_end (args2);
1460         }
1461         int main() {
1462           f (0, 42);
1463           return 0;
1464         }],
1465         [glib_cv_va_val_copy=yes],
1466         [glib_cv_va_val_copy=no],
1467         [glib_cv_va_val_copy=yes])
1468 ])
1469
1470 if test "x$glib_cv_va_val_copy" = "xno"; then
1471   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1472 fi
1473
1474 dnl ***********************
1475 dnl *** g_module checks ***
1476 dnl ***********************
1477 G_MODULE_LIBS=
1478 G_MODULE_LIBS_EXTRA=
1479 G_MODULE_PLUGIN_LIBS=
1480 if test x"$glib_native_win32" = xyes; then
1481   dnl No use for this on Win32
1482   G_MODULE_LDFLAGS=
1483 else
1484   export SED
1485   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1486 fi
1487 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1488 G_MODULE_NEED_USCORE=0
1489 G_MODULE_BROKEN_RTLD_GLOBAL=0
1490 G_MODULE_HAVE_DLERROR=0
1491 dnl *** force native WIN32 shared lib loader
1492 if test -z "$G_MODULE_IMPL"; then
1493   case "$host" in
1494   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1495   esac
1496 fi
1497 dnl *** force native AIX library loader
1498 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1499 if test -z "$G_MODULE_IMPL"; then
1500   case "$host" in
1501   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1502   esac
1503 fi
1504 dnl *** dlopen() and dlsym() in system libraries
1505 if test -z "$G_MODULE_IMPL"; then
1506         AC_CHECK_FUNC(dlopen,
1507                       [AC_CHECK_FUNC(dlsym,
1508                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1509                       [])
1510 fi
1511 dnl *** load_image (BeOS)
1512 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1513   AC_CHECK_LIB(root, load_image,
1514       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1515       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1516       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1517       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1518       [])
1519 fi
1520 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1521 if test -z "$G_MODULE_IMPL"; then
1522         AC_CHECK_FUNC(NSLinkModule,
1523                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1524                        G_MODULE_NEED_USCORE=1],
1525                       [])
1526 fi
1527 dnl *** dlopen() and dlsym() in libdl
1528 if test -z "$G_MODULE_IMPL"; then
1529         AC_CHECK_LIB(dl, dlopen,
1530                      [AC_CHECK_LIB(dl, dlsym,
1531                                    [G_MODULE_LIBS=-ldl
1532                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1533                      [])
1534 fi
1535 dnl *** shl_load() in libdld (HP-UX)
1536 if test -z "$G_MODULE_IMPL"; then
1537         AC_CHECK_LIB(dld, shl_load,
1538                 [G_MODULE_LIBS=-ldld
1539                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1540                 [])
1541 fi
1542 dnl *** additional checks for G_MODULE_IMPL_DL
1543 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1544         LIBS_orig="$LIBS"
1545         LDFLAGS_orig="$LDFLAGS"
1546         LIBS="$G_MODULE_LIBS $LIBS"
1547         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1548 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1549         echo "void glib_plugin_test(void) { }" > plugin.c
1550         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1551                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1552         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1553                 glib_cv_rtldglobal_broken,[
1554                 AC_TRY_RUN([
1555 #include <dlfcn.h>
1556 #ifndef RTLD_GLOBAL
1557 #  define RTLD_GLOBAL 0
1558 #endif
1559 #ifndef RTLD_LAZY
1560 #  define RTLD_LAZY 0
1561 #endif
1562 int glib_plugin_test;
1563 int main () {
1564     void *handle, *global, *local;
1565     global = &glib_plugin_test;
1566     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1567     if (!handle) return 0;
1568     local = dlsym (handle, "glib_plugin_test");
1569     return global == local;
1570 }                       ],
1571                         [glib_cv_rtldglobal_broken=no],
1572                         [glib_cv_rtldglobal_broken=yes],
1573                         [glib_cv_rtldglobal_broken=no])
1574                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1575                 rmdir .libs 2>/dev/null
1576         ])
1577         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1578                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1579         else
1580                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1581         fi
1582 dnl *** check whether we need preceeding underscores
1583         AC_CACHE_CHECK([for preceeding underscore in symbols],
1584                 glib_cv_uscore,[
1585                 AC_TRY_RUN([#include <dlfcn.h>
1586                 int glib_underscore_test (void) { return 42; }
1587                 int main() {
1588                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1589                   handle = dlopen ((void*)0, 0);
1590                   if (handle) {
1591                     f1 = dlsym (handle, "glib_underscore_test");
1592                     f2 = dlsym (handle, "_glib_underscore_test");
1593                   } return (!f2 || f1);
1594                 }],
1595                         [glib_cv_uscore=yes],
1596                         [glib_cv_uscore=no],
1597                         [])
1598                 rm -f plugin.c plugin.$ac_objext plugin.lo
1599         ])
1600         GLIB_ASSERT_SET(glib_cv_uscore)
1601         if test "x$glib_cv_uscore" = "xyes"; then
1602                 G_MODULE_NEED_USCORE=1
1603         else
1604                 G_MODULE_NEED_USCORE=0
1605         fi
1606
1607         LDFLAGS="$LDFLAGS_orig"
1608 dnl *** check for having dlerror()
1609         AC_CHECK_FUNC(dlerror,
1610                 [G_MODULE_HAVE_DLERROR=1],
1611                 [G_MODULE_HAVE_DLERROR=0])
1612         LIBS="$LIBS_orig"
1613 fi
1614 dnl *** done, have we got an implementation?
1615 if test -z "$G_MODULE_IMPL"; then
1616         G_MODULE_IMPL=0
1617         G_MODULE_SUPPORTED=false
1618 else
1619         G_MODULE_SUPPORTED=true
1620 fi
1621
1622 AC_MSG_CHECKING(for the suffix of module shared libraries)
1623 export SED
1624 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1625 eval $shrext_cmds
1626 module=yes eval std_shrext=$shrext_cmds
1627 # chop the initial dot
1628 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1629 AC_MSG_RESULT(.$glib_gmodule_suffix)
1630 # any reason it may fail?
1631 if test "x$glib_gmodule_suffix" = x; then
1632         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1633 fi
1634
1635 AC_SUBST(G_MODULE_SUPPORTED)
1636 AC_SUBST(G_MODULE_IMPL)
1637 AC_SUBST(G_MODULE_LIBS)
1638 AC_SUBST(G_MODULE_LIBS_EXTRA)
1639 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1640 AC_SUBST(G_MODULE_LDFLAGS)
1641 AC_SUBST(G_MODULE_HAVE_DLERROR)
1642 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1643 AC_SUBST(G_MODULE_NEED_USCORE)
1644 AC_SUBST(GLIB_DEBUG_FLAGS)
1645
1646 dnl **********************
1647 dnl *** g_spawn checks ***
1648 dnl **********************
1649
1650 AC_MSG_CHECKING(for gspawn implementation)
1651 case "$host" in
1652   *-*-mingw*)
1653     GSPAWN=gspawn-win32.lo
1654     ;;
1655   *)
1656     GSPAWN=gspawn.lo
1657     ;;
1658 esac
1659 AC_MSG_RESULT($GSPAWN)
1660 AC_SUBST(GSPAWN)
1661
1662 dnl *************************
1663 dnl *** GIOChannel checks ***
1664 dnl *************************
1665
1666 AC_MSG_CHECKING(for GIOChannel implementation)
1667 case "$host" in
1668   *-*-mingw*)
1669     GIO=giowin32.lo
1670     ;;
1671   *)
1672     GIO=giounix.lo
1673     ;;
1674 esac
1675 AC_MSG_RESULT($GIO)
1676 AC_SUBST(GIO)
1677
1678 dnl *********************************
1679 dnl *** Directory for GIO modules ***
1680 dnl *********************************
1681
1682 AC_ARG_WITH(gio-module-dir,
1683            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1684                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1685            [],
1686            [with_gio_module_dir='${libdir}/gio/modules'])
1687 GIO_MODULE_DIR=$with_gio_module_dir
1688 AC_SUBST(GIO_MODULE_DIR)
1689
1690 dnl **********************************
1691 dnl *** Check for libselinux (GIO) ***
1692 dnl **********************************
1693 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1694 msg_selinux=no
1695 SELINUX_LIBS=
1696 if test "x$enable_selinux" != "xno"; then
1697
1698  AC_CHECK_LIB(selinux, is_selinux_enabled,
1699    [AC_CHECK_HEADERS(selinux/selinux.h,
1700      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1701        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1702         SELINUX_LIBS="-lselinux"
1703         msg_selinux=yes])
1704      ])
1705    ])
1706 fi
1707 AC_SUBST(SELINUX_LIBS)
1708
1709 dnl *****************************
1710 dnl ** Check for inotify (GIO) **
1711 dnl *****************************
1712 inotify_support=no
1713 AC_CHECK_HEADERS([sys/inotify.h],
1714 [
1715         inotify_support=yes
1716         AC_CHECK_FUNCS(inotify_init1)
1717 ])
1718
1719 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1720
1721 dnl *********************************
1722 dnl ** Check for Solaris FEN (GIO) **
1723 dnl *********************************
1724 fen_support=no
1725 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1726 #include <port.h>
1727 #ifndef PORT_SOURCE_FILE
1728 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1729 #endif
1730 int main() { return 0; } ]])],
1731 [
1732         fen_support=yes
1733 ],)
1734
1735 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1736
1737 dnl ****************************
1738 dnl *** Checks for FAM (GIO) ***
1739 dnl ****************************
1740
1741 should_disable_fam=no
1742
1743 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1744                          [
1745                                 if test "x$enable_fam" = "xno"; then
1746                                         should_disable_fam=yes
1747                                         echo "Not building FAM support"
1748                                 fi
1749                          ]
1750                          )
1751 fam_support=no
1752 FAM_LIBS=
1753 if test "x$should_disable_fam" = "xno"; then
1754 AC_CHECK_LIB(fam, FAMOpen,
1755   [AC_CHECK_HEADERS(fam.h,
1756     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1757      AC_CHECK_LIB(fam, FAMNoExists,
1758                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1759      FAM_LIBS="-lfam"]
1760      fam_support=yes,
1761     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1762   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1763 AC_SUBST(FAM_LIBS)
1764 fi
1765 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1766
1767
1768 dnl *****************************
1769 dnl *** Check for xattr (GIO) ***
1770 dnl *****************************
1771 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1772 msg_xattr=no
1773 XATTR_LIBS=
1774 if test "x$enable_xattr" != "xno"; then
1775
1776 dnl either glibc or libattr can provide xattr support
1777
1778 dnl for both of them, we check for getxattr being in
1779 dnl the library and a valid xattr header.
1780
1781 dnl try glibc
1782  AC_CHECK_LIB(c, getxattr,
1783    [AC_CHECK_HEADERS(sys/xattr.h,
1784      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1785       msg_xattr=yes])
1786    ])
1787
1788   if test "x$msg_xattr" != "xyes"; then
1789 dnl   failure. try libattr
1790    AC_CHECK_LIB(attr, getxattr,
1791       [AC_CHECK_HEADERS(attr/xattr.h,
1792        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1793         XATTR_LIBS="-lattr"
1794         msg_xattr=yes])
1795       ])
1796   fi
1797
1798   if test "x$msg_xattr" = "xyes"; then
1799     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1800     AC_TRY_COMPILE([
1801       #include <stdio.h>
1802       #ifdef HAVE_SYS_TYPES_H
1803       #include <sys/types.h>
1804       #endif
1805       #ifdef HAVE_SYS_XATTR_H
1806       #include <sys/xattr.h>
1807       #elif HAVE_ATTR_XATTR_H
1808       #include <attr/xattr.h>
1809       #endif
1810     ],
1811     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1812     [
1813       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1814       AC_MSG_RESULT([yes])
1815     ],
1816     [AC_MSG_RESULT([no])]
1817     )
1818   fi
1819
1820 fi
1821 AC_SUBST(XATTR_LIBS)
1822
1823 dnl ****************************************
1824 dnl *** platform dependent source checks ***
1825 dnl ****************************************
1826
1827 AC_MSG_CHECKING(for platform-dependent source)
1828 case "$host" in
1829   *-*-cygwin*|*-*-mingw*)
1830     PLATFORMDEP=gwin32.lo
1831     ;;
1832   *)
1833     PLATFORMDEP=
1834     ;;
1835 esac
1836 AC_MSG_RESULT($PLATFORMDEP)
1837 AC_SUBST(PLATFORMDEP)
1838
1839 AC_MSG_CHECKING([whether to compile timeloop])
1840 case "$host" in
1841   *-*-cygwin*|*-*-mingw*|*-*-minix)
1842     enable_timeloop=no
1843     ;;
1844   *)
1845     enable_timeloop=yes
1846     ;;
1847 esac
1848 AC_MSG_RESULT($enable_timeloop)
1849 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1850
1851 AC_MSG_CHECKING([if building for some Win32 platform])
1852 case "$host" in
1853   *-*-mingw*|*-*-cygwin*)
1854     platform_win32=yes
1855     ;;
1856   *)
1857     platform_win32=no
1858     ;;
1859 esac
1860 AC_MSG_RESULT($platform_win32)
1861 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1862
1863 dnl ***********************
1864 dnl *** g_thread checks ***
1865 dnl ***********************
1866
1867 AC_ARG_WITH(threads,
1868            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1869                            [specify a thread implementation to use])],
1870            [if test "x$with_threads" = x; then
1871                 want_threads=yes
1872             else
1873                 want_threads=$with_threads
1874             fi],
1875            [want_threads=yes])
1876 if test "x$enable_threads" = "xno"; then
1877         want_threads=no
1878 fi
1879
1880 dnl error and warning message
1881 dnl *************************
1882
1883 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1884                 computer. GLib will not have a default thread implementation."
1885
1886 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1887                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1888                 compilation now, but then your programs might not work.
1889                 Please provide information on how it is done on your system."
1890
1891 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1892                 "
1893
1894 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1895                 provide information on your thread implementation.
1896                 You can also run 'configure --disable-threads'
1897                 to compile without thread support."
1898
1899 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1900                 functions will not be MT-safe during their first call because
1901                 there is no working 'getpwuid_r' on your system."
1902
1903 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1904                 because there is no 'localtime_r' on your system."
1905
1906 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1907                 crude surrogate will be used. If you happen to know a
1908                 yield function for your system, please inform the GLib
1909                 developers."
1910
1911 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1912                 threads on your system. Thus threads can only have the default
1913                 priority. If you happen to know these main/max
1914                 priorities, please inform the GLib developers."
1915
1916 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1917                 linking threaded applications. As GLib cannot do that
1918                 automatically, you will get an linkg error everytime you are
1919                 not using the right compiler. In that case you have to relink
1920                 with the right compiler. Ususally just '_r' is appended
1921                 to the compiler name."
1922
1923 dnl determination of thread implementation
1924 dnl ***************************************
1925
1926 # have_threads=no   means no thread support
1927 # have_threads=none means no default thread implementation
1928
1929 have_threads=no
1930 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1931                                 || test "x$want_threads" = xdce; then
1932         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1933         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1934         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1935         glib_save_CPPFLAGS="$CPPFLAGS"
1936         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1937         if test "x$have_threads" = xno; then
1938                 AC_TRY_COMPILE([#include <pthread.h>],
1939                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1940                         have_threads=posix)
1941         fi
1942         if test "x$have_threads" = xno; then
1943                 AC_TRY_COMPILE([#include <pthread.h>],
1944                         [pthread_mutex_t m;
1945                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1946                         have_threads=dce)
1947         fi
1948         # Tru64Unix requires -pthread to find pthread.h. See #103020
1949         CPPFLAGS="$CPPFLAGS -pthread"
1950         if test "x$have_threads" = xno; then
1951         AC_TRY_COMPILE([#include <pthread.h>],
1952                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1953                        have_threads=posix)
1954         fi
1955         CPPFLAGS="$glib_save_CPPFLAGS"
1956 fi
1957 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1958         case $host in
1959                 *-*-mingw*)
1960                 have_threads=win32
1961                 ;;
1962         esac
1963 fi
1964 if test "x$want_threads" = xnone; then
1965         have_threads=none
1966 fi
1967
1968 AC_MSG_CHECKING(for thread implementation)
1969
1970 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1971         AC_MSG_RESULT(none available)
1972         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1973 else
1974         AC_MSG_RESULT($have_threads)
1975 fi
1976
1977
1978 dnl determination of G_THREAD_CFLAGS
1979 dnl ********************************
1980
1981 G_THREAD_LIBS=
1982 G_THREAD_LIBS_EXTRA=
1983 G_THREAD_CFLAGS=
1984
1985 dnl
1986 dnl Test program for basic POSIX threads functionality
1987 dnl
1988 m4_define([glib_thread_test],[
1989 #include <pthread.h>
1990 int check_me = 0;
1991 void* func(void* data) {check_me = 42; return &check_me;}
1992 int main()
1993  { pthread_t t;
1994    void *ret;
1995    pthread_create (&t, $1, func, 0);
1996    pthread_join (t, &ret);
1997    return (check_me != 42 || ret != &check_me);
1998 }])
1999
2000 dnl
2001 dnl Test program for sched_get_priority_min()
2002 dnl
2003 m4_define([glib_sched_priority_test],[
2004 #include <sched.h>
2005 #include <errno.h>
2006 int main() {
2007     errno = 0;
2008     return sched_get_priority_min(SCHED_OTHER)==-1
2009            && errno != 0;
2010 }])
2011
2012 if test x"$have_threads" != xno; then
2013
2014   if test x"$have_threads" = xposix; then
2015     # First we test for posix, whether -pthread or -pthreads do the trick as
2016     # both CPPFLAG and LIBS.
2017     # One of them does for most gcc versions and some other platforms/compilers
2018     # too and could be considered as the canonical way to go.
2019     case $host in
2020       *-*-cygwin*|*-*-darwin*)
2021          # skip cygwin and darwin -pthread or -pthreads test
2022          ;;
2023       *-solaris*)
2024         # These compiler/linker flags work with both Sun Studio and gcc
2025         # Sun Studio expands -mt to -D_REENTRANT and -lthread
2026         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2027         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2028         G_THREAD_LIBS="-lpthread -lthread"
2029         ;;
2030       *)
2031         for flag in pthread pthreads mt; do
2032           glib_save_CFLAGS="$CFLAGS"
2033           CFLAGS="$CFLAGS -$flag"
2034           AC_TRY_RUN(glib_thread_test(0),
2035                      glib_flag_works=yes,
2036                      glib_flag_works=no,
2037                      [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2038                                      glib_flag_works=yes,
2039                                      glib_flag_works=no)])
2040           CFLAGS="$glib_save_CFLAGS"
2041           if test $glib_flag_works = yes ; then
2042              G_THREAD_CFLAGS=-$flag
2043              G_THREAD_LIBS=-$flag
2044              break;
2045           fi
2046         done
2047          ;;
2048     esac
2049   fi
2050
2051   if test x"$G_THREAD_CFLAGS" = x; then
2052
2053     # The canonical -pthread[s] does not work. Try something different.
2054
2055     case $host in
2056         *-aix*)
2057                 if test x"$GCC" = xyes; then
2058                         # GCC 3.0 and above needs -pthread.
2059                         # Should be coverd by the case above.
2060                         # GCC 2.x and below needs -mthreads
2061                         G_THREAD_CFLAGS="-mthreads"
2062                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2063                 else
2064                         # We are probably using the aix compiler. Normaly a
2065                         # program would have to be compiled with the _r variant
2066                         # of the corresponding compiler, but we as GLib cannot
2067                         # do that: but the good news is that for compiling the
2068                         # only difference is the added -D_THREAD_SAFE compile
2069                         # option. This is according to the "C for AIX User's
2070                         # Guide".
2071                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2072                 fi
2073                 ;;
2074         *-dg-dgux*)  # DG/UX
2075                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2076                 ;;
2077         *-osf*)
2078                 # So we are using dce threads. posix threads are already
2079                 # catched above.
2080                 G_THREAD_CFLAGS="-threads"
2081                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2082                 ;;
2083         *-sysv5uw7*) # UnixWare 7
2084                 # We are not using gcc with -pthread. Catched above.
2085                 G_THREAD_CFLAGS="-Kthread"
2086                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2087                 ;;
2088         *-mingw*)
2089                 # No flag needed when using MSVCRT.DLL
2090                 G_THREAD_CFLAGS=""
2091                 ;;
2092         *)
2093                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2094                 ;;
2095     esac
2096
2097   fi
2098
2099     # if we are not finding the localtime_r function, then we probably are
2100     # not using the proper multithread flag
2101
2102     glib_save_CPPFLAGS="$CPPFLAGS"
2103     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2104
2105     # First we test, whether localtime_r is declared in time.h
2106     # directly. Then we test whether a macro localtime_r exists, in
2107     # which case localtime_r in the test program is replaced and thus
2108     # if we still find localtime_r in the output, it is not defined as
2109     # a macro.
2110
2111     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2112       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2113                                                            localtime_r(a,b)],
2114                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2115
2116     CPPFLAGS="$glib_save_CPPFLAGS"
2117
2118     AC_MSG_CHECKING(thread related cflags)
2119     AC_MSG_RESULT($G_THREAD_CFLAGS)
2120     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2121 fi
2122
2123 dnl determination of G_THREAD_LIBS
2124 dnl ******************************
2125
2126 mutex_has_default=no
2127 case $have_threads in
2128         posix|dce)
2129           glib_save_CPPFLAGS="$CPPFLAGS"
2130           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2131           if test x"$G_THREAD_LIBS" = x; then
2132             case $host in
2133               *-aix*)
2134                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2135                 # probably using the aix compiler.
2136                 AC_MSG_WARN($AIX_COMPILE_INFO)
2137                 ;;
2138               *)
2139                 G_THREAD_LIBS=error
2140                 glib_save_LIBS="$LIBS"
2141                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2142                         if test x"$thread_lib" = x; then
2143                                 add_thread_lib=""
2144                                 IN=""
2145                         else
2146                                 add_thread_lib="-l$thread_lib"
2147                                 IN=" in -l$thread_lib"
2148                         fi
2149                         if test x"$have_threads" = xposix; then
2150                                 defattr=0
2151                         else
2152                                 defattr=pthread_attr_default
2153                         fi
2154
2155                         LIBS="$add_thread_lib $glib_save_LIBS"
2156
2157                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2158                         AC_TRY_RUN(glib_thread_test($defattr),
2159                                    glib_result=yes,
2160                                    glib_result=no,
2161                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2162                                                    glib_result=yes,
2163                                                    glib_result=no)])
2164                         AC_MSG_RESULT($glib_result)
2165
2166                         if test "$glib_result" = "yes" ; then
2167                           G_THREAD_LIBS="$add_thread_lib"
2168                           break
2169                         fi
2170                 done
2171                 if test "x$G_THREAD_LIBS" = xerror; then
2172                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2173                 fi
2174                 LIBS="$glib_save_LIBS"
2175                 ;;
2176             esac
2177           fi
2178
2179           glib_save_LIBS="$LIBS"
2180           for thread_lib in "" rt rte; do
2181             if test x"$thread_lib" = x; then
2182               add_thread_lib=""
2183               IN=""
2184             else
2185               add_thread_lib="-l$thread_lib"
2186               IN=" in -l$thread_lib"
2187             fi
2188             LIBS="$add_thread_lib $glib_save_LIBS"
2189
2190             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2191             AC_TRY_RUN(glib_sched_priority_test,
2192                        glib_result=yes,
2193                        glib_result=no,
2194                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2195                                        glib_result=yes,
2196                                        glib_result=no)])
2197             AC_MSG_RESULT($glib_result)
2198
2199             if test "$glib_result" = "yes" ; then
2200                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2201                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2202                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2203                break
2204             fi
2205           done
2206           LIBS="$glib_save_LIBS"
2207           mutex_has_default=yes
2208           mutex_default_type='pthread_mutex_t'
2209           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2210           mutex_header_file='pthread.h'
2211           if test "x$have_threads" = "xposix"; then
2212             g_threads_impl="POSIX"
2213           else
2214             g_threads_impl="DCE"
2215             have_threads="posix"
2216           fi
2217           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2218           CPPFLAGS="$glib_save_CPPFLAGS"
2219           ;;
2220         win32)
2221            g_threads_impl="WIN32"
2222            ;;
2223         none|no)
2224            g_threads_impl="NONE"
2225            ;;
2226         *)
2227            g_threads_impl="NONE"
2228            G_THREAD_LIBS=error
2229            ;;
2230 esac
2231
2232 if test "x$G_THREAD_LIBS" = xerror; then
2233         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2234 fi
2235
2236 case $host in
2237   *-*-beos*)
2238     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2239     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2240     ;;
2241   *)
2242     ;;
2243 esac
2244
2245 AC_MSG_CHECKING(thread related libraries)
2246 AC_MSG_RESULT($G_THREAD_LIBS)
2247
2248 dnl check for mt safe function variants and some posix functions
2249 dnl ************************************************************
2250
2251 if test x"$have_threads" != xno; then
2252         glib_save_LIBS="$LIBS"
2253         # we are not doing the following for now, as this might require glib
2254         # to always be linked with the thread libs on some platforms.
2255         # LIBS="$LIBS $G_THREAD_LIBS"
2256         AC_CHECK_FUNCS(localtime_r gmtime_r)
2257         if test "$ac_cv_header_pwd_h" = "yes"; then
2258                 AC_CACHE_CHECK([for posix getpwuid_r],
2259                         ac_cv_func_posix_getpwuid_r,
2260                         [AC_TRY_RUN([
2261 #include <errno.h>
2262 #include <pwd.h>
2263 int main () {
2264     char buffer[10000];
2265     struct passwd pwd, *pwptr = &pwd;
2266     int error;
2267     errno = 0;
2268     error = getpwuid_r (0, &pwd, buffer,
2269                         sizeof (buffer), &pwptr);
2270    return (error < 0 && errno == ENOSYS)
2271            || error == ENOSYS;
2272 }                               ],
2273                                 [ac_cv_func_posix_getpwuid_r=yes],
2274                                 [ac_cv_func_posix_getpwuid_r=no])])
2275                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2276                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2277                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2278                                 [Have POSIX function getpwuid_r])
2279                 else
2280                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2281                                 ac_cv_func_nonposix_getpwuid_r,
2282                                 [AC_TRY_LINK([#include <pwd.h>],
2283                                         [char buffer[10000];
2284                                         struct passwd pwd;
2285                                         getpwuid_r (0, &pwd, buffer,
2286                                                         sizeof (buffer));],
2287                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2288                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2289                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2290                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2291                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2292                                         [Have non-POSIX function getpwuid_r])
2293                         fi
2294                 fi
2295         fi
2296         if test "$ac_cv_header_grp_h" = "yes"; then
2297                 AC_CACHE_CHECK([for posix getgrgid_r],
2298                         ac_cv_func_posix_getgrgid_r,
2299                         [AC_TRY_RUN([
2300 #include <errno.h>
2301 #include <grp.h>
2302 int main () {
2303     char buffer[10000];
2304     struct group grp, *grpptr = &grp;
2305     int error;
2306     errno = 0;
2307     error = getgrgid_r (0, &grp, buffer,
2308                         sizeof (buffer), &grpptr);
2309    return (error < 0 && errno == ENOSYS)
2310            || error == ENOSYS;
2311 }                              ],
2312                                [ac_cv_func_posix_getgrgid_r=yes],
2313                                [ac_cv_func_posix_getgrgid_r=no])])
2314                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2315                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2316                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2317                                 [Have POSIX function getgrgid_r])
2318                 else
2319                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2320                                 ac_cv_func_nonposix_getgrgid_r,
2321                                 [AC_TRY_LINK([#include <grp.h>],
2322                                         [char buffer[10000];
2323                                         struct group grp;
2324                                         getgrgid_r (0, &grp, buffer,
2325                                         sizeof (buffer));],
2326                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2327                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2328                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2329                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2330                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2331                                         [Have non-POSIX function getgrgid_r])
2332                         fi
2333                 fi
2334         fi
2335         LIBS="$G_THREAD_LIBS $LIBS"
2336         if test x"$have_threads" = xposix; then
2337                 glib_save_CPPFLAGS="$CPPFLAGS"
2338                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2339                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2340                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2341                 # This is not AC_CHECK_FUNC to also work with function
2342                 # name mangling in header files.
2343                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2344                 AC_TRY_LINK([#include <pthread.h>],
2345                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2346                         [AC_MSG_RESULT(yes)
2347                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2348                                   [Have function pthread_attr_setstacksize])],
2349                         [AC_MSG_RESULT(no)])
2350                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2351                 if test x"$posix_priority_min" = x; then
2352                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2353                                 PX_PRIO_MIN],,[
2354                                 posix_priority_min=PX_PRIO_MIN
2355                                 posix_priority_max=PX_PRIO_MAX])
2356                 fi
2357                 if test x"$posix_priority_min" = x; then
2358                         # AIX
2359                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2360                                 PTHREAD_PRIO_MIN],,[
2361                                 posix_priority_min=PTHREAD_PRIO_MIN
2362                                 posix_priority_max=PTHREAD_PRIO_MAX])
2363                 fi
2364                 if test x"$posix_priority_min" = x; then
2365                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2366                                 PRI_OTHER_MIN],,[
2367                                 posix_priority_min=PRI_OTHER_MIN
2368                                 posix_priority_max=PRI_OTHER_MAX])
2369                 fi
2370                 if test x"$posix_priority_min" = x; then
2371                         AC_MSG_RESULT(none found)
2372                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2373                         posix_priority_min=-1
2374                         posix_priority_max=-1
2375                 else
2376                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2377                         AC_MSG_CHECKING(for pthread_setschedparam)
2378                         AC_TRY_LINK([#include <pthread.h>],
2379                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2380                           [AC_MSG_RESULT(yes)
2381                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2382                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2383                           [AC_MSG_RESULT(no)
2384                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2385                 fi
2386                 posix_yield_func=none
2387                 AC_MSG_CHECKING(for posix yield function)
2388                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2389                                                         thr_yield; do
2390                         AC_TRY_LINK([#include <pthread.h>],
2391                                 [$yield_func()],
2392                                 [posix_yield_func="$yield_func"
2393                                 break])
2394                 done
2395                 if test x"$posix_yield_func" = xnone; then
2396                         AC_MSG_RESULT(none found)
2397                         AC_MSG_WARN($POSIX_NO_YIELD)
2398                         posix_yield_func="g_usleep(1000)"
2399                 else
2400                         AC_MSG_RESULT($posix_yield_func)
2401                         posix_yield_func="$posix_yield_func()"
2402                 fi
2403                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2404                 CPPFLAGS="$glib_save_CPPFLAGS"
2405
2406         elif test x"$have_threads" = xwin32; then
2407                 # It's a pointer to a private struct
2408                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2409         fi
2410
2411         LIBS="$glib_save_LIBS"
2412
2413         # now spit out all the warnings.
2414         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2415            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2416                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2417         fi
2418         if test "$ac_cv_func_localtime_r" != "yes"; then
2419                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2420         fi
2421 fi
2422
2423 if test x"$glib_cv_sizeof_system_thread" = x; then
2424    # use a pointer as a fallback.
2425    GLIB_SIZEOF(,void *, system_thread)
2426 fi
2427
2428 #
2429 # Hack to deal with:
2430 #
2431 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2432 #     building shared libraries with linux.
2433 #  b) FreeBSD doesn't do this either.
2434 #
2435 case $host in
2436   *-*-freebsd*|*-*-linux*)
2437     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2438     ;;
2439   *)
2440     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2441     ;;
2442 esac
2443
2444 AM_CONDITIONAL(HAVE_THREADS, [test "$have_threads" != "none"])
2445 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2446                    [Source file containing theread implementation])
2447 AC_SUBST(G_THREAD_CFLAGS)
2448 AC_SUBST(G_THREAD_LIBS)
2449 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2450 AC_SUBST(G_THREAD_LIBS_EXTRA)
2451
2452 dnl **********************************************
2453 dnl *** GDefaultMutex setup and initialization ***
2454 dnl **********************************************
2455 dnl
2456 dnl if mutex_has_default = yes, we also got
2457 dnl mutex_default_type, mutex_default_init and mutex_header_file
2458 if test $mutex_has_default = yes ; then
2459         glib_save_CPPFLAGS="$CPPFLAGS"
2460         glib_save_LIBS="$LIBS"
2461         LIBS="$G_THREAD_LIBS $LIBS"
2462         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2463         GLIB_SIZEOF([#include <$mutex_header_file>],
2464                     $mutex_default_type,
2465                     gmutex)
2466         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2467                            $mutex_default_type,
2468                            gmutex,
2469                            $glib_cv_sizeof_gmutex,
2470                            $mutex_default_init)
2471         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2472                 mutex_has_default=no
2473         fi
2474         CPPFLAGS="$glib_save_CPPFLAGS"
2475         LIBS="$glib_save_LIBS"
2476 fi
2477
2478 AC_CHECK_FUNCS(clock_gettime, [], [
2479   AC_CHECK_LIB(rt, clock_gettime, [
2480     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2481     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2482     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2483     GLIB_RT_LIBS="-lrt"
2484   ])
2485 ])
2486 AC_SUBST(GLIB_RT_LIBS)
2487
2488 AC_CACHE_CHECK(for monotonic clocks,
2489     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2490 #include <time.h>
2491 #include <unistd.h>
2492 int main() {
2493 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2494         #error No monotonic clock
2495 #endif
2496         return 0;
2497 }
2498 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2499 if test "$glib_cv_monotonic_clock" = "yes"; then
2500   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2501 fi
2502
2503
2504 dnl ************************
2505 dnl *** g_atomic_* tests ***
2506 dnl ************************
2507
2508 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2509     case $host_cpu in
2510       i386)
2511         AC_MSG_RESULT([none])
2512         glib_memory_barrier_needed=no
2513         ;;
2514       i?86)
2515         AC_MSG_RESULT([i486])
2516         AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2517                            [i486 atomic implementation])
2518         glib_memory_barrier_needed=no
2519         ;;
2520       sparc*)
2521         SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2522                          when you are using a sparc with v9 instruction set (most
2523                          sparcs nowadays). This will make the code for atomic
2524                          operations much faster. The resulting code will not run
2525                          on very old sparcs though."
2526
2527         AC_LINK_IFELSE([AC_LANG_SOURCE([[
2528           main ()
2529           {
2530             int tmp1, tmp2, tmp3;
2531             __asm__ __volatile__("casx [%2], %0, %1"
2532                                  : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2533           }]])],
2534           AC_MSG_RESULT([sparcv9])
2535           AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2536                              [sparcv9 atomic implementation]),
2537           AC_MSG_RESULT([no])
2538           AC_MSG_WARN([[$SPARCV9_WARNING]]))
2539         glib_memory_barrier_needed=yes
2540         ;;
2541       alpha*)
2542         AC_MSG_RESULT([alpha])
2543         AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2544                            [alpha atomic implementation])
2545         glib_memory_barrier_needed=yes
2546         ;;
2547       x86_64)
2548         AC_MSG_RESULT([x86_64])
2549         AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2550                            [x86_64 atomic implementation])
2551         glib_memory_barrier_needed=no
2552        ;;
2553       powerpc*)
2554         AC_MSG_RESULT([powerpc])
2555         AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2556                            [powerpc atomic implementation])
2557         glib_memory_barrier_needed=yes
2558         AC_MSG_CHECKING([whether asm supports numbered local labels])
2559         AC_TRY_COMPILE(
2560                        ,[
2561                        __asm__ __volatile__ ("1:       nop\n"
2562                                "         bne-    1b")
2563                        ],[
2564                        AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2565                        AC_MSG_RESULT([yes])
2566                        ],[
2567                        AC_MSG_RESULT([no])
2568                        ])
2569         ;;
2570       ia64)
2571         AC_MSG_RESULT([ia64])
2572         AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2573                            [ia64 atomic implementation])
2574         glib_memory_barrier_needed=yes
2575         ;;
2576       s390|s390x)
2577         AC_MSG_RESULT([s390])
2578         AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2579                            [s390 atomic implementation])
2580         glib_memory_barrier_needed=no
2581         ;;
2582       arm*)
2583         AC_MSG_RESULT([arm])
2584         AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2585                            [arm atomic implementation])
2586         glib_memory_barrier_needed=no
2587         ;;
2588       crisv32*|etraxfs*)
2589         AC_MSG_RESULT([crisv32])
2590         AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2591                            [crisv32 atomic implementation])
2592         glib_memory_barrier_needed=no
2593         ;;
2594       cris*|etrax*)
2595         AC_MSG_RESULT([cris])
2596         AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2597                            [cris atomic implementation])
2598         glib_memory_barrier_needed=no
2599         ;;
2600       *)
2601         AC_MSG_RESULT([none])
2602         glib_memory_barrier_needed=yes
2603         ;;
2604     esac
2605
2606 glib_cv_gcc_has_builtin_atomic_operations=no
2607 if test x"$GCC" = xyes; then
2608   AC_MSG_CHECKING([whether GCC supports built-in atomic intrinsics])
2609   AC_TRY_LINK([],
2610               [int i;
2611                __sync_synchronize ();
2612                __sync_bool_compare_and_swap (&i, 0, 1);
2613                __sync_fetch_and_add (&i, 1);
2614               ],
2615               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2616               [glib_cv_gcc_has_builtin_atomic_operations=no])
2617
2618   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2619 fi
2620 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2621                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2622
2623 AC_MSG_CHECKING([for Win32 atomic intrinsics])
2624 glib_cv_has_win32_atomic_operations=no
2625 AC_TRY_LINK([],
2626         [int i; _InterlockedExchangeAdd (&i, 0);],
2627         [glib_cv_has_win32_atomic_operations=yes],
2628         [glib_cv_has_win32_atomic_operations=no])
2629 AC_MSG_RESULT($glib_cv_has_win32_atomic_operations)
2630 if test "x$glib_cv_has_win32_atomic_operations" = xyes; then
2631         AC_DEFINE(HAVE_WIN32_BUILTINS_FOR_ATOMIC_OPERATIONS,1,[Have Win32 atomic intrinsics])
2632 fi
2633
2634 dnl ************************
2635 dnl ** Check for futex(2) **
2636 dnl ************************
2637 AC_CACHE_CHECK(for futex(2) system call,
2638     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2639 #include <linux/futex.h>
2640 #include <sys/syscall.h>
2641 #include <unistd.h>
2642 ],[
2643 int
2644 main (void)
2645 {
2646   /* it is not like this actually runs or anything... */
2647   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2648   return 0;
2649 }
2650 ])],glib_cv_futex=yes,glib_cv_futex=no))
2651 if test x"$glib_cv_futex" = xyes; then
2652   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2653 fi
2654
2655 AC_CACHE_CHECK(for eventfd(2) system call,
2656     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2657 #include <sys/eventfd.h>
2658 #include <unistd.h>
2659 ],[
2660 int
2661 main (void)
2662 {
2663   eventfd (0, EFD_CLOEXEC);
2664   return 0;
2665 }
2666 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2667 if test x"$glib_cv_eventfd" = x"yes"; then
2668   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2669 fi
2670 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2671
2672 dnl ****************************************
2673 dnl *** GLib POLL* compatibility defines ***
2674 dnl ****************************************
2675
2676 glib_poll_includes=["
2677 #include <sys/types.h>
2678 #include <sys/poll.h>
2679 "]
2680
2681 if test $ac_cv_header_sys_types_h = yes &&
2682    test $ac_cv_header_sys_poll_h = yes ; then
2683   glib_failed=false
2684   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2685   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2686   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2687   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2688   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2689   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2690   if $glib_failed ; then
2691     AC_MSG_ERROR([Could not determine values for POLL* constants])
2692   fi
2693 else
2694   glib_cv_value_POLLIN=1
2695   glib_cv_value_POLLOUT=4
2696   glib_cv_value_POLLPRI=2
2697   glib_cv_value_POLLERR=8
2698   glib_cv_value_POLLHUP=16
2699   glib_cv_value_POLLNVAL=32
2700 fi
2701
2702 AC_MSG_CHECKING([for broken poll])
2703 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2704         #include <stdlib.h>
2705         #include <fcntl.h>
2706         #include <poll.h>
2707         #ifdef HAVE_SYS_POLL_H
2708         #include <sys/poll.h>
2709         #endif
2710         int main(void) {
2711           struct pollfd fds[1];
2712           int fd;
2713           fd = open("/dev/null", 1);
2714           fds[0].fd = fd;
2715           fds[0].events = POLLIN;
2716           fds[0].revents = 0;
2717           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2718                 exit(1);  /* Does not work for devices -- fail */
2719           }
2720           exit(0);
2721         }]])],
2722   [broken_poll=no],
2723   [broken_poll=yes
2724    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2725   [broken_poll="no (cross compiling)"])
2726 AC_MSG_RESULT($broken_poll)
2727
2728 dnl *********************
2729 dnl *** GRegex checks ***
2730 dnl *********************
2731 PCRE_REQUIRED_VERSION=8.11
2732
2733 # Check if we should compile GRegex
2734 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2735               [disable the compilation of GRegex]),
2736 [case "${enableval}" in
2737   yes) enable_regex=true ;;
2738   no)  enable_regex=false ;;
2739   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2740 esac],
2741 [enable_regex=true])
2742
2743 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2744
2745 if test x$enable_regex = xtrue; then
2746   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2747   # Check if we should use the internal or the system-supplied pcre
2748   AC_ARG_WITH(pcre,
2749              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2750                              [specify whether to use the internal or the
2751                               system-supplied PCRE library])])
2752
2753   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2754
2755   if test "x$with_pcre" = xsystem; then
2756     PKG_CHECK_MODULES(PCRE,
2757                       libpcre >= $PCRE_REQUIRED_VERSION)
2758     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2759                    glib_save_CFLAGS="$CFLAGS"
2760                    glib_save_LIBS="$LIBS"
2761                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2762                    AC_TRY_RUN([#include <pcre.h>
2763                                int main () {
2764                                  int support;
2765                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2766                                  if (!support)
2767                                    return 1;
2768                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2769                                  if (!support)
2770                                    return 1;
2771                                  return 0;
2772                                }],
2773                    glib_cv_pcre_has_unicode=yes,
2774                    glib_cv_pcre_has_unicode=no,
2775                    glib_cv_pcre_has_unicode=yes)
2776                    CFLAGS="$glib_save_CFLAGS"
2777                    LIBS="$glib_save_LIBS"
2778         ])
2779     if test "$glib_cv_pcre_has_unicode" = "no"; then
2780       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2781     fi
2782     AC_SUBST(PCRE_CFLAGS)
2783     AC_SUBST(PCRE_LIBS)
2784     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2785     PCRE_REQUIRES=libpcre
2786     AC_SUBST(PCRE_REQUIRES)
2787   else
2788     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2789     if test x"$GCC" = xyes; then
2790       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2791       save_CFLAGS="$CFLAGS"
2792       CFLAGS="$CFLAGS -Wno-pointer-sign"
2793       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2794                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2795       CFLAGS="$save_CFLAGS"
2796     fi
2797   fi
2798   AC_SUBST(PCRE_WARN_CFLAGS)
2799 else
2800   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2801 fi
2802
2803 dnl **********************
2804 dnl *** Win32 API libs ***
2805 dnl **********************
2806
2807 case $host in
2808   *-*-cygwin*)
2809         G_LIBS_EXTRA="-luser32 -lkernel32"
2810     ;;
2811   *-*-mingw*)
2812         G_LIBS_EXTRA="-lws2_32 -lole32"
2813     ;;
2814   *)
2815         G_LIBS_EXTRA=""
2816     ;;
2817 esac
2818 AC_SUBST(G_LIBS_EXTRA)
2819
2820 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2821 dnl since we need it for g_iconv()
2822
2823 AC_MSG_CHECKING([for EILSEQ])
2824 AC_TRY_COMPILE([
2825 #include <errno.h>
2826 ],
2827 [
2828 int error = EILSEQ;
2829 ], have_eilseq=yes, have_eilseq=no);
2830 AC_MSG_RESULT($have_eilseq)
2831
2832 dnl ******************************************************************
2833 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2834 dnl *** glib-compile-schemas in PATH                               ***
2835 dnl ******************************************************************
2836
2837 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2838
2839 if test $cross_compiling = yes; then
2840   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2841   if test x$GLIB_GENMARSHAL = xno; then
2842     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2843   fi
2844
2845   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2846   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2847     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2848   fi
2849 fi
2850
2851 dnl **************************
2852 dnl *** Checks for gtk-doc ***
2853 dnl **************************
2854
2855 GTK_DOC_CHECK([1.15])
2856
2857 AC_ARG_ENABLE(man,
2858               [AC_HELP_STRING([--enable-man],
2859                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2860               enable_man=no)
2861
2862 if test "${enable_man}" != no; then
2863 dnl
2864 dnl Check for xsltproc
2865 dnl
2866 AC_PATH_PROG([XSLTPROC], [xsltproc])
2867   if test -z "$XSLTPROC"; then
2868     enable_man=no
2869   fi
2870
2871   dnl check for DocBook DTD and stylesheets in the local catalog.
2872   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2873      [DocBook XML DTD V4.1.2],,enable_man=no)
2874   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2875      [DocBook XSL Stylesheets],,enable_man=no)
2876 fi
2877
2878 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2879
2880 dnl
2881 dnl Tracing
2882 dnl
2883
2884 AC_ARG_ENABLE([dtrace],
2885              [AS_HELP_STRING([--enable-dtrace],
2886                               [Enable inclusion of dtrace trace support])])
2887 have_dtrace=no
2888 AC_MSG_CHECKING([whether to include dtrace tracing support])
2889 if test "x$enable_dtrace" != xno; then
2890   if test x$glib_have_carbon = xyes; then
2891     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2892   else
2893     AC_MSG_RESULT([yes])
2894     AC_CHECK_PROGS(DTRACE, dtrace)
2895     if test -z "$DTRACE"; then
2896       if test "x$enable_dtrace" = xyes; then
2897         AC_MSG_ERROR([dtrace not found])
2898       fi
2899     else
2900       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2901                       [if test "x$enable_dtrace" = xyes; then
2902                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2903                        fi])
2904     fi
2905   fi
2906 else
2907   AC_MSG_RESULT([no])
2908 fi
2909 if test "x$have_dtrace" = xyes; then
2910   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2911 fi
2912 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2913
2914 AC_MSG_CHECKING([whether to include systemtap tracing support])
2915 AC_ARG_ENABLE([systemtap],
2916              [AS_HELP_STRING([--enable-systemtap],
2917                               [Enable inclusion of systemtap trace support])])
2918 have_systemtap=no
2919 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2920   have_systemtap=yes
2921 fi
2922 AC_MSG_RESULT(${have_systemtap})
2923
2924 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2925
2926 AC_ARG_WITH([tapset-install-dir],
2927             [AS_HELP_STRING([--with-tapset-install-dir],
2928             [The absolute path where the systemtap tapsets will be installed])],
2929             [if test "x${withval}" = x; then
2930                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2931              else
2932                ABS_TAPSET_DIR="${withval}"
2933               fi],
2934             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2935 AC_SUBST(ABS_TAPSET_DIR)
2936
2937 dnl ************************************
2938 dnl *** Enable lcov coverage reports ***
2939 dnl ************************************
2940
2941 AC_ARG_ENABLE(gcov,
2942   AS_HELP_STRING([--enable-gcov],
2943                  [Enable gcov]),
2944   [use_gcov=$enableval], [use_gcov=no])
2945
2946 if test "x$use_gcov" = "xyes"; then
2947   dnl we need gcc:
2948   if test "$GCC" != "yes"; then
2949     AC_MSG_ERROR([GCC is required for --enable-gcov])
2950   fi
2951
2952   dnl Check if ccache is being used
2953   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2954   case `$SHTOOL path $CC` in
2955     *ccache*[)] gcc_ccache=yes;;
2956     *[)] gcc_ccache=no;;
2957   esac
2958
2959   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2960     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2961   fi
2962
2963   ltp_version_list="1.6 1.7 1.8 1.9"
2964   AC_CHECK_PROG(LTP, lcov, lcov)
2965   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2966
2967   if test "$LTP"; then
2968     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2969       glib_cv_ltp_version=invalid
2970       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2971       for ltp_check_version in $ltp_version_list; do
2972         if test "$ltp_version" = "$ltp_check_version"; then
2973           glib_cv_ltp_version="$ltp_check_version (ok)"
2974         fi
2975       done
2976     ])
2977   else
2978     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2979     AC_MSG_ERROR([$ltp_msg])
2980   fi
2981
2982   case $glib_cv_ltp_version in
2983     ""|invalid[)]
2984       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2985       AC_MSG_ERROR([$ltp_msg])
2986       LTP="exit 0;"
2987       ;;
2988   esac
2989
2990   if test -z "$LTP_GENHTML"; then
2991     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2992   fi
2993
2994   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2995
2996   dnl Remove all optimization flags from CFLAGS
2997   changequote({,})
2998   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2999   changequote([,])
3000
3001   dnl Add the special gcc flags
3002   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
3003   LDFLAGS="$LDFLAGS -lgcov"
3004 fi
3005
3006 dnl ******************************
3007 dnl *** output the whole stuff ***
3008 dnl ******************************
3009
3010 dnl this section will only be run if config.status is invoked with no
3011 dnl arguments, or with "glib/glibconfig.h" as an argument.
3012 AC_CONFIG_COMMANDS([glib/glibconfig.h],
3013 [
3014         outfile=glib/glibconfig.h-tmp
3015         cat > $outfile <<\_______EOF
3016 /* glibconfig.h
3017  *
3018  * This is a generated file.  Please modify 'configure.ac'
3019  */
3020
3021 #ifndef __G_LIBCONFIG_H__
3022 #define __G_LIBCONFIG_H__
3023
3024 #include <glib/gmacros.h>
3025
3026 _______EOF
3027
3028         if test x$glib_limits_h = xyes; then
3029           echo '#include <limits.h>' >> $outfile
3030         fi
3031         if test x$glib_float_h = xyes; then
3032           echo '#include <float.h>' >> $outfile
3033         fi
3034         if test x$glib_values_h = xyes; then
3035           echo '#include <values.h>' >> $outfile
3036         fi
3037         if test "$glib_header_alloca_h" = "yes"; then
3038           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
3039         fi
3040         if test x$glib_sys_poll_h = xyes; then
3041           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
3042         fi
3043         if test x$glib_included_printf != xyes; then
3044           echo "
3045 /* Specifies that GLib's g_print*() functions wrap the
3046  * system printf functions.  This is useful to know, for example,
3047  * when using glibc's register_printf_function().
3048  */" >> $outfile
3049           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
3050         fi
3051
3052         cat >> $outfile <<_______EOF
3053
3054 G_BEGIN_DECLS
3055
3056 #define G_MINFLOAT      $glib_mf
3057 #define G_MAXFLOAT      $glib_Mf
3058 #define G_MINDOUBLE     $glib_md
3059 #define G_MAXDOUBLE     $glib_Md
3060 #define G_MINSHORT      $glib_ms
3061 #define G_MAXSHORT      $glib_Ms
3062 #define G_MAXUSHORT     $glib_Mus
3063 #define G_MININT        $glib_mi
3064 #define G_MAXINT        $glib_Mi
3065 #define G_MAXUINT       $glib_Mui
3066 #define G_MINLONG       $glib_ml
3067 #define G_MAXLONG       $glib_Ml
3068 #define G_MAXULONG      $glib_Mul
3069
3070 _______EOF
3071
3072
3073         ### this should always be true in a modern C/C++ compiler
3074         cat >>$outfile <<_______EOF
3075 typedef signed char gint8;
3076 typedef unsigned char guint8;
3077 _______EOF
3078
3079
3080         if test -n "$gint16"; then
3081           cat >>$outfile <<_______EOF
3082 typedef signed $gint16 gint16;
3083 typedef unsigned $gint16 guint16;
3084 #define G_GINT16_MODIFIER $gint16_modifier
3085 #define G_GINT16_FORMAT $gint16_format
3086 #define G_GUINT16_FORMAT $guint16_format
3087 _______EOF
3088         fi
3089
3090
3091         if test -n "$gint32"; then
3092           cat >>$outfile <<_______EOF
3093 typedef signed $gint32 gint32;
3094 typedef unsigned $gint32 guint32;
3095 #define G_GINT32_MODIFIER $gint32_modifier
3096 #define G_GINT32_FORMAT $gint32_format
3097 #define G_GUINT32_FORMAT $guint32_format
3098 _______EOF
3099         fi
3100
3101         cat >>$outfile <<_______EOF
3102 #define G_HAVE_GINT64 1          /* deprecated, always true */
3103
3104 ${glib_extension}typedef signed $gint64 gint64;
3105 ${glib_extension}typedef unsigned $gint64 guint64;
3106
3107 #define G_GINT64_CONSTANT(val)  $gint64_constant
3108 #define G_GUINT64_CONSTANT(val) $guint64_constant
3109 _______EOF
3110
3111         if test x$gint64_format != x ; then
3112           cat >>$outfile <<_______EOF
3113 #define G_GINT64_MODIFIER $gint64_modifier
3114 #define G_GINT64_FORMAT $gint64_format
3115 #define G_GUINT64_FORMAT $guint64_format
3116 _______EOF
3117         else
3118           cat >>$outfile <<_______EOF
3119 #undef G_GINT64_MODIFIER
3120 #undef G_GINT64_FORMAT
3121 #undef G_GUINT64_FORMAT
3122 _______EOF
3123         fi
3124
3125         cat >>$outfile <<_______EOF
3126
3127 #define GLIB_SIZEOF_VOID_P $glib_void_p
3128 #define GLIB_SIZEOF_LONG   $glib_long
3129 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3130
3131 _______EOF
3132
3133         cat >>$outfile <<_______EOF
3134 typedef signed $glib_size_type_define gssize;
3135 typedef unsigned $glib_size_type_define gsize;
3136 #define G_GSIZE_MODIFIER $gsize_modifier
3137 #define G_GSSIZE_FORMAT $gssize_format
3138 #define G_GSIZE_FORMAT $gsize_format
3139
3140 #define G_MAXSIZE       G_MAXU$glib_msize_type
3141 #define G_MINSSIZE      G_MIN$glib_msize_type
3142 #define G_MAXSSIZE      G_MAX$glib_msize_type
3143
3144 typedef gint64 goffset;
3145 #define G_MINOFFSET     G_MININT64
3146 #define G_MAXOFFSET     G_MAXINT64
3147
3148 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3149 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3150 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3151
3152 _______EOF
3153
3154         if test -z "$glib_unknown_void_p"; then
3155           cat >>$outfile <<_______EOF
3156
3157 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3158 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3159
3160 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3161 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3162
3163 typedef signed $glib_intptr_type_define gintptr;
3164 typedef unsigned $glib_intptr_type_define guintptr;
3165
3166 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3167 #define G_GINTPTR_FORMAT        $gintptr_format
3168 #define G_GUINTPTR_FORMAT       $guintptr_format
3169 _______EOF
3170         else
3171           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3172         fi
3173
3174
3175
3176         cat >>$outfile <<_______EOF
3177 $glib_atexit
3178 $glib_memmove
3179 $glib_defines
3180 $glib_os
3181 $glib_static_compilation
3182
3183 $glib_vacopy
3184
3185 #ifdef  __cplusplus
3186 #define G_HAVE_INLINE   1
3187 #else   /* !__cplusplus */
3188 $glib_inline
3189 #endif  /* !__cplusplus */
3190
3191 #ifdef  __cplusplus
3192 #define G_CAN_INLINE    1
3193 _______EOF
3194
3195         if test x$g_can_inline = xyes ; then
3196                 cat >>$outfile <<_______EOF
3197 #else   /* !__cplusplus */
3198 #define G_CAN_INLINE    1
3199 _______EOF
3200         fi
3201
3202         cat >>$outfile <<_______EOF
3203 #endif
3204
3205 _______EOF
3206
3207         if test x$g_have_iso_c_varargs = xyes ; then
3208                 cat >>$outfile <<_______EOF
3209 #ifndef __cplusplus
3210 # define G_HAVE_ISO_VARARGS 1
3211 #endif
3212 _______EOF
3213         fi
3214         if test x$g_have_iso_cxx_varargs = xyes ; then
3215                 cat >>$outfile <<_______EOF
3216 #ifdef __cplusplus
3217 # define G_HAVE_ISO_VARARGS 1
3218 #endif
3219 _______EOF
3220         fi
3221         if test x$g_have_gnuc_varargs = xyes ; then
3222                 cat >>$outfile <<_______EOF
3223
3224 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3225  * is passed ISO vararg support is turned off, and there is no work
3226  * around to turn it on, so we unconditionally turn it off.
3227  */
3228 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3229 #  undef G_HAVE_ISO_VARARGS
3230 #endif
3231
3232 #define G_HAVE_GNUC_VARARGS 1
3233 _______EOF
3234         fi
3235
3236         case x$g_stack_grows in
3237         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3238         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3239         esac
3240
3241
3242         echo >>$outfile
3243         if test x$g_have_eilseq = xno; then
3244                 cat >>$outfile <<_______EOF
3245 #ifndef EILSEQ
3246 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3247  * The correspondence between this and the corresponding definition
3248  * in libiconv is essential.
3249  */
3250 #  define EILSEQ ENOENT
3251 #endif
3252 _______EOF
3253
3254         fi
3255
3256         if test x$g_have_gnuc_visibility = xyes; then
3257                 cat >>$outfile <<_______EOF
3258 #define G_HAVE_GNUC_VISIBILITY 1
3259 _______EOF
3260         fi
3261                 cat >>$outfile <<_______EOF
3262 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3263 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3264 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3265 #define G_GNUC_INTERNAL __hidden
3266 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3267 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3268 #else
3269 #define G_GNUC_INTERNAL
3270 #endif
3271 _______EOF
3272
3273
3274         echo >>$outfile
3275         if test x$g_mutex_has_default = xyes; then
3276                 cat >>$outfile <<_______EOF
3277 $g_enable_threads_def G_THREADS_ENABLED
3278 #define G_THREADS_IMPL_$g_threads_impl_def
3279 typedef struct _GStaticMutex GStaticMutex;
3280 struct _GStaticMutex
3281 {
3282   struct _GMutex *runtime_mutex;
3283   union {
3284     char   pad[[$g_mutex_sizeof]];
3285     double dummy_double;
3286     void  *dummy_pointer;
3287     long   dummy_long;
3288   } static_mutex;
3289 };
3290 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
3291 #define g_static_mutex_get_mutex(mutex) \\
3292   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
3293    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
3294 _______EOF
3295         else
3296                 cat >>$outfile <<_______EOF
3297 $g_enable_threads_def G_THREADS_ENABLED
3298 #define G_THREADS_IMPL_$g_threads_impl_def
3299 typedef struct _GMutex* GStaticMutex;
3300 #define G_STATIC_MUTEX_INIT NULL
3301 #define g_static_mutex_get_mutex(mutex) \\
3302   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3303 _______EOF
3304         fi
3305
3306         cat >>$outfile <<_______EOF
3307 /* This represents a system thread as used by the implementation. An
3308  * alien implementaion, as loaded by g_thread_init can only count on
3309  * "sizeof (gpointer)" bytes to store their info. We however need more
3310  * for some of our native implementations. */
3311 typedef union _GSystemThread GSystemThread;
3312 union _GSystemThread
3313 {
3314   char   data[[$g_system_thread_sizeof]];
3315   double dummy_double;
3316   void  *dummy_pointer;
3317   long   dummy_long;
3318 };
3319 _______EOF
3320         if test x"$g_memory_barrier_needed" != xno; then
3321           echo >>$outfile
3322           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3323         fi
3324         if test x"$g_gcc_atomic_ops" != xno; then
3325           echo >>$outfile
3326           echo "#define G_ATOMIC_OP_USE_GCC_BUILTINS 1" >>$outfile
3327         fi
3328         echo >>$outfile
3329         g_bit_sizes="16 32 64"
3330         for bits in $g_bit_sizes; do
3331           cat >>$outfile <<_______EOF
3332 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3333 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3334 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3335 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3336 _______EOF
3337         done
3338
3339         cat >>$outfile <<_______EOF
3340 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3341 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3342 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3343 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3344 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3345 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3346 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3347 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3348 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3349 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3350 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3351 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3352 #define G_BYTE_ORDER $g_byte_order
3353
3354 #define GLIB_SYSDEF_POLLIN =$g_pollin
3355 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3356 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3357 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3358 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3359 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3360
3361 #define G_MODULE_SUFFIX "$g_module_suffix"
3362
3363 /* A GPid is an abstraction for a process "handle". It is *not* an
3364  * abstraction for a process identifier in general. GPid is used in
3365  * GLib only for descendant processes spawned with the g_spawn*
3366  * functions. On POSIX there is no "process handle" concept as such,
3367  * but on Windows a GPid is a handle to a process, a kind of pointer,
3368  * not a process identifier.
3369  */
3370 typedef $g_pid_type GPid;
3371
3372 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3373 #define GLIB_SYSDEF_AF_INET $g_af_inet
3374 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3375
3376 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3377 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3378 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3379
3380 G_END_DECLS
3381
3382 #endif /* GLIBCONFIG_H */
3383 _______EOF
3384
3385
3386         if cmp -s $outfile glib/glibconfig.h; then
3387           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3388           rm -f $outfile
3389         else
3390           mv $outfile glib/glibconfig.h
3391         fi
3392 ],[
3393
3394 # Note that if two cases are the same, case goes with the first one.
3395 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3396 # on variable expansion in case labels.  Look at the generated config.status
3397 # for a hint.
3398
3399 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3400   glib_header_alloca_h="$ac_cv_working_alloca_h"
3401 else
3402   glib_header_alloca_h="$ac_cv_header_alloca_h"
3403 fi
3404
3405 case xyes in
3406 x$ac_cv_header_float_h)
3407   glib_float_h=yes
3408   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3409   glib_md=DBL_MIN glib_Md=DBL_MAX
3410   ;;
3411 x$ac_cv_header_values_h)
3412   glib_values_h=yes
3413   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3414   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3415   ;;
3416 esac
3417
3418 case xyes in
3419 x$ac_cv_header_limits_h)
3420   glib_limits_h=yes
3421   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3422   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3423   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3424   ;;
3425 x$ac_cv_header_values_h)
3426   glib_values_h=yes
3427   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3428   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3429   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3430   ;;
3431 esac
3432
3433 if test x$ac_cv_header_sys_poll_h = xyes ; then
3434   glib_sys_poll_h=yes
3435 fi
3436
3437 if test x$enable_included_printf = xyes ; then
3438   glib_included_printf=yes
3439 fi
3440
3441 case 2 in
3442 $ac_cv_sizeof_short)
3443   gint16=short
3444   gint16_modifier='"h"'
3445   gint16_format='"hi"'
3446   guint16_format='"hu"'
3447   ;;
3448 $ac_cv_sizeof_int)
3449   gint16=int
3450   gint16_modifier='""'
3451   gint16_format='"i"'
3452   guint16_format='"u"'
3453   ;;
3454 esac
3455 case 4 in
3456 $ac_cv_sizeof_short)
3457   gint32=short
3458   gint32_modifier='"h"'
3459   gint32_format='"hi"'
3460   guint32_format='"hu"'
3461   ;;
3462 $ac_cv_sizeof_int)
3463   gint32=int
3464   gint32_modifier='""'
3465   gint32_format='"i"'
3466   guint32_format='"u"'
3467   ;;
3468 $ac_cv_sizeof_long)
3469   gint32=long
3470   gint32_modifier='"l"'
3471   gint32_format='"li"'
3472   guint32_format='"lu"'
3473   ;;
3474 esac
3475 case 8 in
3476 $ac_cv_sizeof_int)
3477   gint64=int
3478   gint64_modifier='""'
3479   gint64_format='"i"'
3480   guint64_format='"u"'
3481   glib_extension=
3482   gint64_constant='(val)'
3483   guint64_constant='(val)'
3484   ;;
3485 $ac_cv_sizeof_long)
3486   gint64=long
3487   gint64_modifier='"l"'
3488   gint64_format='"li"'
3489   guint64_format='"lu"'
3490   glib_extension=
3491   gint64_constant='(val##L)'
3492   guint64_constant='(val##UL)'
3493   ;;
3494 $ac_cv_sizeof_long_long)
3495   gint64='long long'
3496   if test -n "$glib_cv_long_long_format"; then
3497     gint64_modifier='"'$glib_cv_long_long_format'"'
3498     gint64_format='"'$glib_cv_long_long_format'i"'
3499     guint64_format='"'$glib_cv_long_long_format'u"'
3500   fi
3501   glib_extension='G_GNUC_EXTENSION '
3502   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3503   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3504   ;;
3505 $ac_cv_sizeof___int64)
3506   gint64='__int64'
3507   if test -n "$glib_cv_long_long_format"; then
3508     gint64_modifier='"'$glib_cv_long_long_format'"'
3509     gint64_format='"'$glib_cv_long_long_format'i"'
3510     guint64_format='"'$glib_cv_long_long_format'u"'
3511   fi
3512   glib_extension=
3513   gint64_constant='(val##i64)'
3514   guint64_constant='(val##ui64)'
3515   ;;
3516 esac
3517 glib_size_t=$ac_cv_sizeof_size_t
3518 glib_size_type_define="$glib_size_type"
3519 glib_void_p=$ac_cv_sizeof_void_p
3520 glib_long=$ac_cv_sizeof_long
3521
3522 case "$glib_size_type" in
3523 short)
3524   gsize_modifier='"h"'
3525   gsize_format='"hu"'
3526   gssize_format='"hi"'
3527   glib_msize_type='SHRT'
3528   ;;
3529 int)
3530   gsize_modifier='""'
3531   gsize_format='"u"'
3532   gssize_format='"i"'
3533   glib_msize_type='INT'
3534   ;;
3535 long)
3536   gsize_modifier='"l"'
3537   gsize_format='"lu"'
3538   gssize_format='"li"'
3539   glib_msize_type='LONG'
3540   ;;
3541 "long long"|__int64)
3542   gsize_modifier='"I64"'
3543   gsize_format='"I64u"'
3544   gssize_format='"I64i"'
3545   glib_msize_type='INT64'
3546   ;;
3547 esac
3548
3549 gintbits=`expr $ac_cv_sizeof_int \* 8`
3550 glongbits=`expr $ac_cv_sizeof_long \* 8`
3551 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3552
3553 case $ac_cv_sizeof_void_p in
3554 $ac_cv_sizeof_int)
3555   glib_intptr_type_define=int
3556   gintptr_modifier='""'
3557   gintptr_format='"i"'
3558   guintptr_format='"u"'
3559   glib_gpi_cast=''
3560   glib_gpui_cast=''
3561   ;;
3562 $ac_cv_sizeof_long)
3563   glib_intptr_type_define=long
3564   gintptr_modifier='"l"'
3565   gintptr_format='"li"'
3566   guintptr_format='"lu"'
3567   glib_gpi_cast='(glong)'
3568   glib_gpui_cast='(gulong)'
3569   ;;
3570 $ac_cv_sizeof_long_long)
3571   glib_intptr_type_define='long long'
3572   gintptr_modifier='"I64"'
3573   gintptr_format='"I64i"'
3574   guintptr_format='"I64u"'
3575   glib_gpi_cast='(gint64)'
3576   glib_gpui_cast='(guint64)'
3577   ;;
3578 $ac_cv_sizeof___int64)
3579   glib_intptr_type_define=__int64
3580   gintptr_modifier='"I64"'
3581   gintptr_format='"I64i"'
3582   guintptr_format='"I64u"'
3583   glib_gpi_cast='(gint64)'
3584   glib_gpui_cast='(guint64)'
3585   ;;
3586 *)
3587   glib_unknown_void_p=yes
3588   ;;
3589 esac
3590
3591
3592 case xyes in
3593 x$ac_cv_func_atexit)
3594   glib_atexit="
3595 #ifdef NeXT /* @#%@! NeXTStep */
3596 # define g_ATEXIT(proc) (!atexit (proc))
3597 #else
3598 # define g_ATEXIT(proc) (atexit (proc))
3599 #endif"
3600   ;;
3601 x$ac_cv_func_on_exit)
3602   glib_atexit="
3603 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3604   ;;
3605 esac
3606
3607 case xyes in
3608 x$ac_cv_func_memmove)
3609   glib_memmove='
3610 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3611   ;;
3612 x$glib_cv_working_bcopy)
3613   glib_memmove="
3614 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3615 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3616   ;;
3617 *)
3618   glib_memmove="
3619 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3620  * so we have to roll our own copy routine. */
3621 void g_memmove (void* dest, const void * src, unsigned long len);"
3622   ;;
3623 esac
3624
3625 glib_defines="
3626 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3627 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3628 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3629 "
3630
3631 case xyes in
3632 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3633 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3634 *)                      glib_vacopy=''
3635 esac
3636
3637 if test x$glib_cv_va_val_copy = xno; then
3638   glib_vacopy="\$glib_vacopy
3639 #define G_VA_COPY_AS_ARRAY 1"
3640 fi
3641
3642 if test x$glib_cv_hasinline = xyes; then
3643     glib_inline='#define G_HAVE_INLINE 1'
3644 fi
3645 if test x$glib_cv_has__inline = xyes; then
3646     glib_inline="\$glib_inline
3647 #define G_HAVE___INLINE 1"
3648 fi
3649 if test x$glib_cv_has__inline__ = xyes; then
3650     glib_inline="\$glib_inline
3651 #define G_HAVE___INLINE__ 1"
3652 fi
3653
3654 g_have_gnuc_varargs=$g_have_gnuc_varargs
3655 g_have_iso_c_varargs=$g_have_iso_c_varargs
3656 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3657
3658 g_can_inline=$g_can_inline
3659 g_have_gnuc_visibility=$g_have_gnuc_visibility
3660 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3661
3662 if test x$ac_cv_c_bigendian = xyes; then
3663   g_byte_order=G_BIG_ENDIAN
3664   g_bs_native=BE
3665   g_bs_alien=LE
3666 else
3667   g_byte_order=G_LITTLE_ENDIAN
3668   g_bs_native=LE
3669   g_bs_alien=BE
3670 fi
3671
3672 g_pollin=$glib_cv_value_POLLIN
3673 g_pollout=$glib_cv_value_POLLOUT
3674 g_pollpri=$glib_cv_value_POLLPRI
3675 g_pollhup=$glib_cv_value_POLLHUP
3676 g_pollerr=$glib_cv_value_POLLERR
3677 g_pollnval=$glib_cv_value_POLLNVAL
3678
3679 g_af_unix=$glib_cv_value_AF_UNIX
3680 g_af_inet=$glib_cv_value_AF_INET
3681 g_af_inet6=$glib_cv_value_AF_INET6
3682
3683 g_msg_peek=$glib_cv_value_MSG_PEEK
3684 g_msg_oob=$glib_cv_value_MSG_OOB
3685 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3686
3687 g_stack_grows=$glib_cv_stack_grows
3688
3689 g_have_eilseq=$have_eilseq
3690
3691 case x$have_threads in
3692 xno)    g_enable_threads_def="#undef";;
3693 *)      g_enable_threads_def="#define";;
3694 esac
3695
3696 g_threads_impl_def=$g_threads_impl
3697
3698 g_mutex_has_default="$mutex_has_default"
3699 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3700 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3701 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3702
3703 g_memory_barrier_needed="$glib_memory_barrier_needed"
3704 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3705
3706 g_module_suffix="$glib_gmodule_suffix"
3707
3708 g_pid_type="$glib_pid_type"
3709 case $host in
3710   *-*-beos*)
3711     glib_os="#define G_OS_BEOS"
3712     ;;
3713   *-*-cygwin*)
3714     glib_os="#define G_OS_UNIX
3715 #define G_PLATFORM_WIN32
3716 #define G_WITH_CYGWIN"
3717     ;;
3718   *-*-mingw*)
3719     glib_os="#define G_OS_WIN32
3720 #define G_PLATFORM_WIN32"
3721     ;;
3722   *)
3723     glib_os="#define G_OS_UNIX"
3724     ;;
3725 esac
3726 glib_static_compilation=""
3727 if test x$glib_win32_static_compilation = xyes; then
3728   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3729 #define GOBJECT_STATIC_COMPILATION 1"
3730 fi
3731 ])
3732
3733 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3734 #
3735 # 1.2.14 required for dbus_message_set_serial
3736 PKG_CHECK_MODULES(DBUS1,
3737                   dbus-1 >= 1.2.14,
3738                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3739                   have_dbus1=no)
3740 AC_SUBST(DBUS1_CFLAGS)
3741 AC_SUBST(DBUS1_LIBS)
3742 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3743
3744 dnl
3745 dnl Check for -Bsymbolic-functions linker flag used to avoid
3746 dnl intra-library PLT jumps, if available.
3747 dnl
3748
3749 AC_ARG_ENABLE(Bsymbolic,
3750               [AC_HELP_STRING([--disable-Bsymbolic],
3751                               [avoid linking with -Bsymbolic])],,
3752               [SAVED_LDFLAGS="${LDFLAGS}"
3753                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3754                LDFLAGS=-Wl,-Bsymbolic-functions
3755                AC_TRY_LINK([], [int main (void) { return 0; }],
3756                            AC_MSG_RESULT(yes)
3757                            enable_Bsymbolic=yes,
3758                            AC_MSG_RESULT(no)
3759                            enable_Bsymbolic=no)
3760                LDFLAGS="${SAVED_LDFLAGS}"])
3761
3762 if test "x${enable_Bsymbolic}" == "xyes"; then
3763   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3764 fi
3765
3766 AC_SUBST(GLIB_LINK_FLAGS)
3767
3768 #
3769 # Define variables corresponding to the correct include paths to use for
3770 # in-tree building.
3771 #
3772
3773 # for config.h:
3774 config_h_INCLUDES='-I$(top_builddir)'
3775 AC_SUBST(config_h_INCLUDES)
3776
3777 # glib:
3778 #   config.h
3779 #   $(top_builddir)/glib: for glibconfig.h
3780 #   $(top_srcdir)/glib:   for glib.h
3781 #   $(top_srcdir):        for everything
3782 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3783 AC_SUBST(glib_INCLUDES)
3784
3785 # gthread:
3786 #   same as glib
3787 gthread_INCLUDES='$(glib_INCLUDES)'
3788 AC_SUBST(gthread_INCLUDES)
3789
3790 # gobject:
3791 #   same as gthread
3792 gobject_INCLUDES='$(gthread_INCLUDES)'
3793 AC_SUBST(gobject_INCLUDES)
3794
3795 # gmodule:
3796 #   glib includes
3797 #   $(top_srcdir)/gmodule: for gmodule.h
3798 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3799 AC_SUBST(gmodule_INCLUDES)
3800
3801 # gio:
3802 #   same as gmodule
3803 gio_INCLUDES='$(gmodule_INCLUDES)'
3804 AC_SUBST(gio_INCLUDES)
3805
3806
3807 AC_CONFIG_FILES([
3808 glib-2.0.pc
3809 glib-2.0-uninstalled.pc
3810 gmodule-2.0.pc
3811 gmodule-export-2.0.pc
3812 gmodule-no-export-2.0.pc
3813 gmodule-2.0-uninstalled.pc
3814 gmodule-no-export-2.0-uninstalled.pc
3815 gthread-2.0.pc
3816 gthread-2.0-uninstalled.pc
3817 gobject-2.0.pc
3818 gobject-2.0-uninstalled.pc
3819 gio-2.0.pc
3820 gio-unix-2.0.pc
3821 gio-windows-2.0.pc
3822 gio-2.0-uninstalled.pc
3823 gio-unix-2.0-uninstalled.pc
3824 glib-zip
3825 glib-gettextize
3826 Makefile
3827 build/Makefile
3828 build/win32/Makefile
3829 build/win32/dirent/Makefile
3830 build/win32/vs9/Makefile
3831 build/win32/vs10/Makefile
3832 glib/Makefile
3833 glib/glib.stp
3834 glib/libcharset/Makefile
3835 glib/gnulib/Makefile
3836 glib/pcre/Makefile
3837 glib/update-pcre/Makefile
3838 glib/tests/Makefile
3839 gmodule/Makefile
3840 gmodule/gmoduleconf.h
3841 gobject/Makefile
3842 gobject/gobject.stp
3843 gobject/glib-mkenums
3844 gobject/tests/Makefile
3845 gthread/Makefile
3846 gthread/tests/Makefile
3847 gio/Makefile
3848 gio/gdbus-2.0/codegen/Makefile
3849 gio/gdbus-2.0/codegen/config.py
3850 gio/xdgmime/Makefile
3851 gio/inotify/Makefile
3852 gio/libasyncns/Makefile
3853 gio/fen/Makefile
3854 gio/fam/Makefile
3855 gio/win32/Makefile
3856 gio/tests/Makefile
3857 gio/tests/gdbus-object-manager-example/Makefile
3858 po/Makefile.in
3859 docs/Makefile
3860 docs/reference/Makefile
3861 docs/reference/glib/Makefile
3862 docs/reference/glib/version.xml
3863 docs/reference/gobject/Makefile
3864 docs/reference/gobject/version.xml
3865 docs/reference/gio/Makefile
3866 docs/reference/gio/gdbus-object-manager-example/Makefile
3867 docs/reference/gio/version.xml
3868 tests/Makefile
3869 tests/gobject/Makefile
3870 tests/refcount/Makefile
3871 m4macros/Makefile
3872 ])
3873
3874 AC_CONFIG_COMMANDS([chmod-scripts],
3875 [chmod 0755 glib-zip
3876 chmod 0755 glib-gettextize
3877 chmod 0755 gobject/glib-mkenums])
3878
3879 # we want to invoke this macro solely so that the config.status script
3880 # and automake generated makefiles know about these generated files.
3881 # They are only needed to distcheck the package
3882 if false; then
3883   AC_CONFIG_FILES([
3884     INSTALL
3885     README
3886     config.h.win32
3887     glib/glibconfig.h.win32
3888     glib/makefile.msc
3889     glib/glib.rc
3890     gmodule/makefile.msc
3891     gmodule/gmodule.rc
3892     gobject/makefile.msc
3893     gobject/gobject.rc
3894     gthread/makefile.msc
3895     gthread/gthread.rc
3896     gio/gio.rc
3897     tests/makefile.msc
3898   ])
3899 fi
3900
3901 AC_OUTPUT