configure.ac

   1 # get rid of that stupid cache mechanism
   2 rm -f config.cache
   3
   4 AC_INIT([eet], [1.2.3], [enlightenment-devel@lists.sourceforge.net])
   5 AC_PREREQ([2.52])
   6 AC_CONFIG_SRCDIR([configure.ac])
   7 AC_CONFIG_MACRO_DIR([m4])
   8 AC_CANONICAL_BUILD
   9 AC_CANONICAL_HOST
  10 AC_ISC_POSIX
  11
  12 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  13 AM_CONFIG_HEADER([config.h])
  14 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  15
  16 AC_LIBTOOL_WIN32_DLL
  17 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  18 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  19 AC_PROG_LIBTOOL
  20
  21 VMAJ=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $1);}'`
  22 VMIN=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $2);}'`
  23 VMIC=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $3);}'`
  24 SNAP=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $4);}'`
  25 version_info=`expr $VMAJ + $VMIN`":$VMIC:$VMIN"
  26 #release="ver-pre-svn-00"
  27 #release_info="-release $release"
  28 release_info=""
  29 AC_SUBST(version_info)
  30 AC_SUBST(release_info)
  31
  32 ### Default options with respect to host
  33
  34 case "$host_os" in
  35    mingw* | cegcc*)
  36       want_gnutls="no"
  37       want_openssl="no"
  38       want_cipher="no"
  39       want_signature="no"
  40       ;;
  41    *)
  42       want_gnutls="auto"
  43       want_openssl="auto"
  44       want_cipher="yes"
  45       want_signature="yes"
  46       ;;
  47 esac
  48
  49 requirement_eet=""
  50
  51
  52 ### Additional options to configure
  53
  54 AC_ARG_ENABLE([amalgamation],
  55    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
  56    [if test "x${enableval}" = "xyes"; then
  57        do_amalgamation="yes"
  58     else
  59        do_amalgamation="no"
  60     fi
  61    ],
  62    [do_amalgamation="no"]
  63 )
  64 AM_CONDITIONAL(EET_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
  65
  66 # Old eet file format support
  67
  68 old_eet_file_format="yes"
  69 AC_ARG_ENABLE(old-eet-file-format,
  70    [AC_HELP_STRING(
  71       [--disable-old-eet-file-format],
  72       [disable old eet file format support. [[default=enabled]]]
  73     )],
  74    [old_eet_file_format=$enableval]
  75 )
  76 AC_MSG_CHECKING([whether to support old eet file format])
  77 AC_MSG_RESULT([${old_eet_file_format}])
  78
  79 if test "x${old_eet_file_format}" = "xyes" ; then
  80    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 1, [support old eet file format])
  81 else
  82    AC_DEFINE(EET_OLD_EET_FILE_FORMAT, 0, [support old eet file format])
  83 fi
  84
  85 # Gnutls support
  86
  87 AC_ARG_ENABLE([gnutls],
  88    [AC_HELP_STRING([--disable-gnutls], [disable gnutls eet support])],
  89    [want_gnutls=$enableval]
  90 )
  91 AC_MSG_CHECKING([whether to use Gnutls])
  92 AC_MSG_RESULT([${want_gnutls}])
  93
  94 # Specific GNUTLS improvement
  95
  96 new_gnutls_api="no"
  97 AC_ARG_ENABLE(new-gnutls-api,
  98    [AC_HELP_STRING(
  99       [--enable-new-gnutls-api],
 100       [enable use of gnutls_x509_crt_verify_hash. [[default=disable]]]
 101     )],
 102    [new_gnutls_api=$enableval]
 103 )
 104 AC_MSG_CHECKING([whether to use gnutls_x509_crt_verify_hash])
 105 AC_MSG_RESULT([${new_gnutls_api}])
 106
 107 if test "x${new_gnutls_api}" = "xyes" ; then
 108    AC_DEFINE(EET_USE_NEW_GNUTLS_API, 1, [use gnutls_x509_crt_verify_hash])
 109 else
 110    AC_DEFINE(EET_USE_NEW_GNUTLS_API, 0, [don't use gnutls_x509_crt_verify_hash])
 111 fi
 112
 113 # Openssl support
 114
 115 AC_ARG_ENABLE([openssl],
 116    [AC_HELP_STRING([--disable-openssl], [disable openssl eet support])],
 117    [want_openssl=$enableval]
 118 )
 119 AC_MSG_CHECKING([whether to use OpenSSL])
 120 AC_MSG_RESULT([${want_openssl}])
 121
 122 # Cryptography support
 123
 124 AC_ARG_ENABLE([cipher],
 125    [AC_HELP_STRING([--disable-cipher], [disable cipher support for eet API])],
 126    [want_cipher=$enableval]
 127 )
 128 AC_MSG_CHECKING([whether to use cipher])
 129 AC_MSG_RESULT([${want_cipher}])
 130
 131 AC_ARG_ENABLE([signature],
 132    [AC_HELP_STRING([--disable-signature], [disable signature file support for eet])],
 133    [want_signature=$enableval]
 134 )
 135 AC_MSG_CHECKING([whether to use signature])
 136 AC_MSG_RESULT([${want_signature}])
 137
 138 # Assert or fail.
 139 prefer_assert="no"
 140 AC_ARG_ENABLE([assert],
 141    [AC_HELP_STRING([--enable-assert], [enable assert, [[default=disabled]]])],
 142    [prefer_assert=$enableval]
 143 )
 144
 145 # Unit tests, coverage and benchmarking
 146
 147 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 148 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 149
 150 if test "x${prefer_assert}" = "xno"; then
 151    DEBUG_CFLAGS="-DNDEBUG"
 152 else
 153 # use debug symbols and set DEBUG if coverage support is enabled
 154    DEBUG_CFLAGS="${EFL_DEBUG_CFLAGS}"
 155 fi
 156 AC_SUBST(DEBUG_CFLAGS)
 157
 158
 159 ### Checks for programs
 160 AC_PROG_CC
 161
 162 # pkg-config
 163 PKG_PROG_PKG_CONFIG
 164
 165 # Check whether pkg-config supports Requires.private
 166 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 167    pkgconfig_requires_private="Requires.private"
 168 else
 169    pkgconfig_requires_private="Requires"
 170 fi
 171 AC_SUBST(pkgconfig_requires_private)
 172
 173
 174 # doxygen program for documentation building
 175
 176 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 177
 178 ### Checks for libraries
 179
 180 EFL_CHECK_PTHREAD([have_pthread="yes"], [have_pthread="no"])
 181
 182 # Evil library for compilation on Windows
 183
 184 EFL_EET_BUILD=""
 185 case "$host_os" in
 186    mingw* | cegcc*)
 187       PKG_CHECK_MODULES([EVIL], [evil])
 188       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 189       requirement_eet="evil ${requirement_eet}"
 190       EFL_EET_BUILD="-DEFL_EET_BUILD"
 191    ;;
 192 esac
 193 AC_SUBST(EFL_EET_BUILD)
 194
 195 EET_LIBS=""
 196 case "$host_os" in
 197    mingw32ce*)
 198       EET_LIBS="-lws2"
 199       ;;
 200    cegcc*)
 201       EET_LIBS="-lws2"
 202       ;;
 203    mingw*)
 204       EET_LIBS="-lws2_32"
 205       ;;
 206 esac
 207 AC_SUBST(EET_LIBS)
 208
 209 # Eina library
 210
 211 PKG_CHECK_MODULES(EINA, [eina-0])
 212 requirement_eet="eina-0 ${requirement_eet}"
 213
 214 # Gnutls library
 215 have_gnutls="no"
 216 if test "x${want_gnutls}" = "xyes" -o "x${want_gnutls}" = "xauto" ; then
 217    PKG_CHECK_MODULES(GNUTLS, [gnutls >= 1.7.6],
 218       [
 219        have_gnutls="yes"
 220        want_openssl="no"
 221        AC_DEFINE(HAVE_GNUTLS, 1, [Have Gnutls support])
 222        requirement_eet="gnutls ${requirement_eet}"
 223       ],
 224       [have_gnutls="no"])
 225    if test "x${have_gnutls}" = "xyes" ; then
 226       AC_PATH_GENERIC([libgcrypt], [], [have_gnutls="yes"], [have_gnutls="no"])
 227       if test "x${have_gnutls}" = "xyes" ; then
 228          GNUTLS_CFLAGS="${GNUTLS_CFLAGS} ${LIBGCRYPT_CFLAGS}"
 229          GNUTLS_LIBS="${GNUTLS_LIBS} ${LIBGCRYPT_LIBS}"
 230       fi
 231    fi
 232 fi
 233
 234 # Openssl library
 235 have_openssl="no"
 236 if test "x${want_openssl}" = "xyes" -o "x${want_openssl}" = "xauto" ; then
 237    PKG_CHECK_MODULES(OPENSSL, openssl,
 238       [
 239        have_openssl="yes"
 240        AC_DEFINE(HAVE_OPENSSL, 1, [Have Openssl support])
 241        requirement_eet="openssl ${requirement_eet}"
 242       ],
 243       [have_openssl="no"])
 244 fi
 245
 246 have_cipher="no"
 247 if test "x${have_gnutls}" = "xyes" -a "x${want_cipher}" = "xyes" ; then
 248    have_cipher="yes"
 249    AC_DEFINE(HAVE_CIPHER, 1, [Have cipher support built in eet])
 250 elif test "x${have_openssl}" = "xyes" -a "x${want_cipher}" = "xyes" ; then
 251    have_cipher="yes"
 252    AC_DEFINE(HAVE_CIPHER, 1, [Have cipher support built in eet])
 253 fi
 254
 255 AC_MSG_CHECKING(whether to activate cipher support in eet)
 256 AC_MSG_RESULT(${have_cipher})
 257
 258 have_signature="no"
 259 if test "x${have_gnutls}" = "xyes" -a "x${want_signature}" = "xyes" ; then
 260    have_signature="yes"
 261    AC_DEFINE(HAVE_SIGNATURE, 1, [Have signature support for eet file])
 262 elif test "x${have_openssl}" = "xyes" -a "x${want_signature}" = "xyes" ; then
 263    have_signature="yes"
 264    AC_DEFINE(HAVE_SIGNATURE, 1, [Have signature support for eet file])
 265 fi
 266
 267 AC_MSG_CHECKING(whether to activate signature support in eet)
 268 AC_MSG_RESULT(${have_signature})
 269
 270
 271 ### Checks for header files
 272
 273 AC_CHECK_HEADER([zlib.h],
 274    [dummy="yes"],
 275    [AC_MSG_ERROR("Cannot find zlib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file")])
 276
 277 AC_CHECK_HEADER([jpeglib.h],
 278    [dummy="yes"],
 279    [AC_MSG_ERROR("Cannot find jpeglib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file")])
 280
 281 AC_CHECK_HEADERS(netinet/in.h)
 282
 283 AC_CHECK_HEADER([fnmatch.h],
 284    [dummy="yes"],
 285    [AC_MSG_ERROR([Cannot find fnmatch.h. Make sure your CFLAGS environment variable contains include lines for the location of this file. MinGW users: see the INSTALL file])])
 286
 287
 288 ### Checks for types
 289
 290
 291 ### Checks for structures
 292
 293
 294 ### Checks for compiler characteristics
 295 AM_PROG_CC_C_O
 296 AC_C_CONST
 297 AC_C_INLINE
 298 AC_PROG_CC_STDC
 299 AC_C___ATTRIBUTE__
 300
 301 # Check whether the null pointer is zero on this arch
 302 AC_TRY_RUN(
 303    [
 304 #include <stdlib.h>
 305 int main (int argc, char **argv) {
 306   void *foo = NULL;
 307   int bar = (int)foo;
 308   return (int)foo;
 309 }
 310    ],
 311    [have_null="yes"],
 312    [have_null="no"],
 313    [
 314     AC_MSG_WARN([Cannot check when cross-compiling -- assuming null is okay])
 315     have_null="yes"
 316    ])
 317 AC_MSG_CHECKING([value of the null pointer])
 318 AC_MSG_RESULT([${have_null}])
 319
 320 if test ! "x${have_null}" = "xyes" ; then
 321    AC_MSG_WARN([Your system is a bit too funny, eet might not work properly])
 322 fi
 323
 324 # These are needed for fmemopen/open_memstream
 325 AC_DEFINE(_GNU_SOURCE, , [Enable GNU extensions])
 326
 327 EET_CPPFLAGS=""
 328 EET_CFLAGS=""
 329 case "$host_os" in
 330    mingw32ce*)
 331       EET_CPPFLAGS="-D_WIN32_WCE=0x0420"
 332       ;;
 333    cegcc*)
 334       EET_CPPFLAGS="-D_WIN32_WCE=0x0420"
 335       EET_CFLAGS="-mwin32"
 336       ;;
 337 esac
 338 AC_SUBST(EET_CPPFLAGS)
 339 AC_SUBST(EET_CFLAGS)
 340
 341
 342 ### Checks for linker characteristics
 343
 344 # use --enable-auto-import on Windows
 345
 346 lt_enable_auto_import=""
 347 case "$host_os" in
 348    mingw* | cegcc*)
 349       lt_enable_auto_import="-Wl,--enable-auto-import"
 350       ;;
 351 esac
 352 AC_SUBST(lt_enable_auto_import)
 353
 354 # use --as-needed if supported
 355
 356 LDFLAGS_SAVE=${LDFLAGS}
 357 LDFLAGS="${LDFLAGS} -Wl,--as-needed"
 358
 359 AC_LINK_IFELSE(
 360    [AC_LANG_PROGRAM([[]], [])],
 361    [ld_as_needed="-Wl,--as-needed"],
 362    [ld_as_needed=""]
 363 )
 364
 365 LDFLAGS=${LDFLAGS_SAVE}
 366 AC_SUBST(ld_as_needed)
 367
 368
 369 ### Checks for library functions
 370 AC_FUNC_ALLOCA
 371
 372 AC_CHECK_FUNCS(fmemopen open_memstream realpath)
 373
 374 fnmatch_libs=""
 375 AC_CHECK_FUNCS([fnmatch], [res="yes"], [res="no"])
 376 if test "x$res" = "xno"; then
 377    AC_SEARCH_LIBS([fnmatch],
 378       [fnmatch evil iberty],
 379       [res="yes"],
 380       [res="no"])
 381    if test "x$res" = "xno"; then
 382       AC_MSG_ERROR([Cannot find fnmatch() in neither libc nor libfnmatch, nor libiberty, nor libevil])
 383    fi
 384    fnmatch_libs="${ac_cv_search_fnmatch}"
 385 fi
 386 AC_SUBST(fnmatch_libs)
 387
 388
 389 AC_SUBST(requirement_eet)
 390
 391 AC_OUTPUT([
 392 Makefile
 393 eet.pc
 394 doc/Makefile
 395 doc/eet.dox
 396 src/Makefile
 397 src/lib/Makefile
 398 src/bin/Makefile
 399 src/tests/Makefile
 400 README
 401 eet.spec
 402 ])
 403
 404
 405 #####################################################################
 406 ## Info
 407
 408 echo
 409 echo
 410 echo
 411 echo "------------------------------------------------------------------------"
 412 echo "$PACKAGE_NAME $PACKAGE_VERSION"
 413 echo "------------------------------------------------------------------------"
 414 echo
 415 echo "Configuration Options Summary:"
 416 echo
 417 echo "  Gnutls...............: ${have_gnutls}"
 418 echo "  Openssl..............: ${have_openssl}"
 419 echo "    Cipher support.....: ${have_cipher}"
 420 echo "    Signature..........: ${have_signature}"
 421 echo "  Thread Support.......: ${have_pthread}"
 422 echo
 423 echo "  Amalgamation.........: ${do_amalgamation}"
 424 echo "  Documentation........: ${build_doc}"
 425 echo "  Tests................: ${enable_tests}"
 426 echo "  Coverage.............: ${enable_coverage}"
 427 echo
 428 echo "  Old eet file format..: ${old_eet_file_format}"
 429 echo
 430 echo "  Compilation..........: make"
 431 echo
 432 echo "  Installation.........: make install"
 433 echo
 434 echo "    prefix.............: $prefix"
 435 echo