configure.ac

   1 m4_define([weston_major_version], [1])
   2 m4_define([weston_minor_version], [2])
   3 m4_define([weston_micro_version], [0])
   4 m4_define([weston_version],
   5           [weston_major_version.weston_minor_version.weston_micro_version])
   6
   7 AC_PREREQ([2.64])
   8 AC_INIT([weston],
   9         [weston_version],
  10         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=weston&version=weston_version],
  11         [weston],
  12         [http://wayland.freedesktop.org/])
  13
  14 AC_SUBST([WESTON_VERSION_MAJOR], [weston_major_version])
  15 AC_SUBST([WESTON_VERSION_MINOR], [weston_minor_version])
  16 AC_SUBST([WESTON_VERSION_MICRO], [weston_micro_version])
  17 AC_SUBST([WESTON_VERSION], [weston_version])
  18
  19 AC_CONFIG_HEADERS([config.h])
  20
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_INIT_AUTOMAKE([1.11 parallel-tests foreign no-dist-gzip dist-xz color-tests])
  24
  25 AM_SILENT_RULES([yes])
  26
  27 # Check for programs
  28 AC_PROG_CC
  29 AC_PROG_SED
  30
  31 # Initialize libtool
  32 LT_PREREQ([2.2])
  33 LT_INIT([disable-static])
  34
  35 AC_ARG_VAR([WESTON_NATIVE_BACKEND],
  36            [Set the native backend to use, if Weston is not running under Wayland nor X11. @<:@default=drm-backend.so@:>@])
  37
  38 PKG_PROG_PKG_CONFIG()
  39
  40 AC_CHECK_FUNC([dlopen], [],
  41               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  42 AC_SUBST(DLOPEN_LIBS)
  43
  44 AC_CHECK_DECL(SFD_CLOEXEC,[],
  45               [AC_MSG_ERROR("SFD_CLOEXEC is needed to compile weston")],
  46               [[#include <sys/signalfd.h>]])
  47 AC_CHECK_DECL(TFD_CLOEXEC,[],
  48               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile weston")],
  49               [[#include <sys/timerfd.h>]])
  50 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
  51               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile weston")],
  52               [[#include <time.h>]])
  53 AC_CHECK_HEADERS([execinfo.h])
  54
  55 AC_CHECK_FUNCS([mkostemp strchrnul initgroups])
  56
  57 COMPOSITOR_MODULES="wayland-server >= 1.1.90 pixman-1"
  58
  59 AC_ARG_ENABLE(egl, [  --disable-egl],,
  60               enable_egl=yes)
  61 AM_CONDITIONAL(ENABLE_EGL, test x$enable_egl = xyes)
  62 if test x$enable_egl = xyes; then
  63         AC_DEFINE([ENABLE_EGL], [1], [Build Weston with EGL support])
  64         COMPOSITOR_MODULES="$COMPOSITOR_MODULES egl >= 7.10 glesv2"
  65 fi
  66
  67 AC_ARG_ENABLE(xkbcommon,
  68               AS_HELP_STRING([--disable-xkbcommon], [Disable libxkbcommon
  69                               support: This is only useful in environments
  70                               where you do not have a hardware keyboard. If
  71                               libxkbcommon support is disabled clients will not
  72                               be sent a keymap and and must know how to
  73                               interpret the keycode sent for any key event.]),,
  74               enable_xkbcommon=yes)
  75 if test x$enable_xkbcommon = xyes; then
  76         AC_DEFINE(ENABLE_XKBCOMMON, [1], [Build Weston with libxkbcommon support])
  77         COMPOSITOR_MODULES="$COMPOSITOR_MODULES xkbcommon"
  78 fi
  79
  80 PKG_CHECK_MODULES(COMPOSITOR, [$COMPOSITOR_MODULES])
  81
  82 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
  83               enable_setuid_install=yes)
  84 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
  85
  86
  87 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
  88               enable_xwayland=yes)
  89 AC_ARG_ENABLE(xwayland-test, [  --enable-xwayland-test],,
  90               enable_xwayland_test=yes)
  91 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
  92 AM_CONDITIONAL(ENABLE_XWAYLAND_TEST, test x$enable_xwayland = xyes -a x$enable_xwayland_test = xyes)
  93 if test x$enable_xwayland = xyes; then
  94   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcursor cairo-xcb)
  95   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
  96
  97   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
  98               [Path to X server]), [XSERVER_PATH="$withval"],
  99               [XSERVER_PATH="$bindir/Xorg"])
 100   AC_SUBST([XSERVER_PATH])
 101   if test x$enable_xwayland_test = xyes; then
 102     PKG_CHECK_MODULES([XWAYLAND_TEST], xcb xcb-dri2 libdrm)
 103   fi
 104 fi
 105
 106
 107 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
 108               enable_x11_compositor=yes)
 109 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
 110 if test x$enable_x11_compositor = xyes; then
 111   PKG_CHECK_MODULES([XCB], xcb)
 112   xcb_save_LIBS=$LIBS
 113   xcb_save_CFLAGS=$CFLAGS
 114   CFLAGS=$XCB_CFLAGS
 115   LIBS=$XCB_LIBS
 116   AC_CHECK_FUNCS([xcb_poll_for_queued_event])
 117   LIBS=$xcb_save_LIBS
 118   CFLAGS=$xcb_save_CFLAGS
 119
 120   X11_COMPOSITOR_MODULES="x11 x11-xcb xcb-shm"
 121
 122   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb],
 123                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
 124   if test "x$have_xcb_xkb" = xyes; then
 125         # Most versions of XCB have totally broken XKB bindings, where the
 126         # events don't work.  Make sure we can actually use them.
 127         xcb_xkb_save_CFLAGS=$CFLAGS
 128         CFLAGS=$X11_COMPOSITOR_XKB_CFLAGS
 129         AC_CHECK_MEMBER([struct xcb_xkb_state_notify_event_t.xkbType],
 130                         [], [have_xcb_xkb=no], [[#include <xcb/xkb.h>]])
 131         CFLAGS=$xcb_xkb_save_CFLAGS
 132   fi
 133   if test "x$have_xcb_xkb" = xyes; then
 134         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
 135         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
 136   fi
 137
 138   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
 139   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
 140 fi
 141
 142
 143 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
 144               enable_drm_compositor=yes)
 145 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes -a x$enable_egl = xyes)
 146 if test x$enable_drm_compositor = xyes -a x$enable_egl = xyes; then
 147   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
 148   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm mtdev >= 1.1.0])
 149 fi
 150
 151
 152 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 153               enable_wayland_compositor=yes)
 154 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 155                test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes)
 156 if test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes; then
 157   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 158             [Build the Wayland (nested) compositor])
 159   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client wayland-egl])
 160 fi
 161
 162
 163 AC_ARG_ENABLE(headless-compositor, [  --enable-headless-compositor],,
 164               enable_headless_compositor=yes)
 165 AM_CONDITIONAL(ENABLE_HEADLESS_COMPOSITOR,
 166                test x$enable_headless_compositor = xyes)
 167
 168
 169 AC_ARG_ENABLE(rpi-compositor,
 170               AS_HELP_STRING([--disable-rpi-compositor],
 171                              [do not build the Raspberry Pi backend]),,
 172               enable_rpi_compositor=yes)
 173 AM_CONDITIONAL(ENABLE_RPI_COMPOSITOR, test "x$enable_rpi_compositor" = "xyes")
 174 have_bcm_host="no"
 175 if test "x$enable_rpi_compositor" = "xyes"; then
 176   AC_DEFINE([BUILD_RPI_COMPOSITOR], [1], [Build the compositor for Raspberry Pi])
 177   PKG_CHECK_MODULES(RPI_COMPOSITOR, [libudev >= 136 mtdev >= 1.1.0])
 178   PKG_CHECK_MODULES(RPI_BCM_HOST, [bcm_host],
 179                     [have_bcm_host="yes"
 180                      AC_DEFINE([HAVE_BCM_HOST], [1], [have Raspberry Pi BCM headers])],
 181                     [AC_MSG_WARN([Raspberry Pi BCM host libraries not found, will use stubs instead.])])
 182 fi
 183 AM_CONDITIONAL(INSTALL_RPI_COMPOSITOR, test "x$have_bcm_host" = "xyes")
 184
 185
 186 AC_ARG_ENABLE([fbdev-compositor], [  --enable-fbdev-compositor],,
 187               enable_fbdev_compositor=yes)
 188 AM_CONDITIONAL([ENABLE_FBDEV_COMPOSITOR],
 189                [test x$enable_fbdev_compositor = xyes])
 190 AS_IF([test x$enable_fbdev_compositor = xyes], [
 191   AC_DEFINE([BUILD_FBDEV_COMPOSITOR], [1], [Build the fbdev compositor])
 192   PKG_CHECK_MODULES([FBDEV_COMPOSITOR], [libudev >= 136 mtdev >= 1.1.0])
 193 ])
 194
 195 AC_ARG_ENABLE([rdp-compositor], [  --enable-rdp-compositor],,
 196               enable_rdp_compositor=no)
 197 AM_CONDITIONAL([ENABLE_RDP_COMPOSITOR],
 198                [test x$enable_rdp_compositor = xyes])
 199 if test x$enable_rdp_compositor = xyes; then
 200   AC_DEFINE([BUILD_RDP_COMPOSITOR], [1], [Build the RDP compositor])
 201   PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp >= 1.1.0])
 202 fi
 203
 204 AC_ARG_WITH(cairo,
 205             AS_HELP_STRING([--with-cairo=@<:@image|gl|glesv2@:>@]
 206                            [Which Cairo renderer to use for the clients]),
 207                            [],[with_cairo="image"])
 208
 209 if test "x$with_cairo" = "ximage"; then
 210         cairo_modules="cairo"
 211 else
 212 if test "x$with_cairo" = "xgl"; then
 213         cairo_modules="cairo-gl"
 214 else
 215 if test "x$with_cairo" = "xglesv2"; then
 216         cairo_modules="cairo-glesv2"
 217 else
 218         AC_ERROR([Unknown cairo renderer requested])
 219 fi
 220 fi
 221 fi
 222
 223 # Included for legacy compat
 224 AC_ARG_WITH(cairo-glesv2,
 225             AS_HELP_STRING([--with-cairo-glesv2],
 226                            [Use GLESv2 cairo]))
 227 if test "x$with_cairo_glesv2" = "xyes"; then
 228   cairo_modules="cairo-glesv2"
 229   with_cairo="glesv2"
 230 fi
 231
 232 if test "x$cairo_modules" = "xcairo-glesv2"; then
 233 AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 234 fi
 235
 236 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 237 PKG_CHECK_MODULES(PNG, [libpng])
 238 PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])
 239 AS_IF([test "x$have_webp" = "xyes"],
 240       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])])
 241
 242 AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], have_jpeglib=yes)
 243 if test x$have_jpeglib = xyes; then
 244   JPEG_LIBS="-ljpeg"
 245 else
 246   AC_ERROR([libjpeg not found])
 247 fi
 248 AC_SUBST(JPEG_LIBS)
 249
 250 PKG_CHECK_MODULES(CAIRO, [cairo])
 251
 252 AC_ARG_ENABLE(simple-clients,
 253               AS_HELP_STRING([--disable-simple-clients],
 254                              [do not build the simple wl_shm clients]),,
 255               enable_simple_clients=yes)
 256 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 257 if test x$enable_simple_clients = xyes; then
 258   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 259 fi
 260
 261 AC_ARG_ENABLE(simple-egl-clients,
 262               AS_HELP_STRING([--disable-simple-egl-clients],
 263                              [do not build the simple EGL clients]),,
 264               enable_simple_egl_clients=yes)
 265 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes" -a "x$enable_egl" = "xyes")
 266 if test x$enable_simple_egl_clients = xyes -a x$enable_egl = xyes; then
 267   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 268                     [egl >= 7.10 glesv2 wayland-client wayland-egl wayland-cursor])
 269 fi
 270
 271 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 272 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 273 if test x$enable_clients = xyes; then
 274   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 275
 276   PKG_CHECK_MODULES(CLIENT, [wayland-client cairo >= 1.10.0 xkbcommon wayland-cursor])
 277   PKG_CHECK_MODULES(SERVER, [wayland-server])
 278   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client])
 279
 280   PKG_CHECK_MODULES(POPPLER, [poppler-glib glib-2.0 gobject-2.0 gio-2.0 ],
 281                              [have_poppler=yes], [have_poppler=no])
 282
 283   # Only check for cairo-egl if a GL or GLES renderer requested
 284   AS_IF([test "x$cairo_modules" = "xcairo-gl" -o "x$cairo_modules" = "xcairo-glesv2"], [
 285     PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl >= 7.10 cairo-egl >= 1.11.3 $cairo_modules],
 286                       [have_cairo_egl=yes], [have_cairo_egl=no])
 287     AS_IF([test "x$have_cairo_egl" = "xyes"],
 288           [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 289           [AC_ERROR([cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])],
 290   [have_cairo_egl=no])
 291
 292   PKG_CHECK_MODULES(PANGO, [pangocairo], [have_pango=yes], [have_pango=no])
 293 fi
 294
 295 AC_ARG_ENABLE(resize-optimization,
 296               AS_HELP_STRING([--disable-resize-optimization],
 297                              [disable resize optimization allocating a big buffer in toytoolkit]),,
 298               enable_resize_optimization=yes)
 299 AS_IF([test "x$enable_resize_optimization" = "xyes"],
 300       [AC_DEFINE([USE_RESIZE_POOL], [1], [Use resize memory pool as a performance optimization])])
 301
 302 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 303 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch == xyes)
 304 if test x$enable_weston_launch == xyes; then
 305   PKG_CHECK_MODULES(WESTON_LAUNCH, [libdrm])
 306   PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login],
 307                     [have_systemd_login=yes], [have_systemd_login=no])
 308   AS_IF([test "x$have_systemd_login" = "xyes"],
 309         [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 310
 311   AC_CHECK_LIB([pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 312   if test x$have_pam == xno; then
 313     AC_ERROR([weston-launch requires pam])
 314   fi
 315   WESTON_LAUNCH_LIBS="$WESTON_LAUNCH_LIBS -lpam"
 316 fi
 317
 318 if test x$enable_egl = xyes; then
 319   PKG_CHECK_MODULES(GLU, [glu], [have_glu=yes], [have_glu=no])
 320 fi
 321 AM_CONDITIONAL(HAVE_GLU, test "x$have_glu" = "xyes")
 322
 323
 324 AM_CONDITIONAL(HAVE_POPPLER, test "x$have_poppler" = "xyes")
 325
 326 AM_CONDITIONAL(HAVE_PANGO, test "x$have_pango" = "xyes")
 327
 328 AM_CONDITIONAL(HAVE_CAIRO_GLESV2,
 329                [test "x$have_cairo_egl" = "xyes" -a "x$cairo_modules" = "xcairo-glesv2" -a "x$enable_egl" = "xyes"])
 330
 331 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 332                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes" -a "x$enable_egl" = "xyes")
 333
 334 AM_CONDITIONAL(BUILD_SUBSURFACES_CLIENT,
 335                [test '(' "x$have_cairo_egl" != "xyes" -o "x$cairo_modules" = "xcairo-glesv2" ')' -a "x$enable_simple_egl_clients" = "xyes"])
 336
 337 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 338
 339 AC_ARG_ENABLE(tablet-shell,
 340               AS_HELP_STRING([--disable-tablet-shell],
 341                              [do not build tablet-shell server plugin and client]),,
 342               enable_tablet_shell=yes)
 343 AM_CONDITIONAL(ENABLE_TABLET_SHELL,
 344                test "x$enable_tablet_shell" = "xyes")
 345
 346 # CMS modules
 347 AC_ARG_ENABLE(colord,
 348               AS_HELP_STRING([--disable-colord],
 349                              [do not build colord CMS support]),,
 350               enable_colord=auto)
 351 if test "x$enable_colord" != "xno"; then
 352         PKG_CHECK_MODULES(COLORD,
 353                           colord >= 0.1.27,
 354                           have_colord=yes,
 355                           have_colord=no)
 356         if test "x$have_colord" = "xno" -a "x$enable_colord" = "xyes"; then
 357           AC_MSG_ERROR([colord support explicitly requested, but colord couldn't be found])
 358         fi
 359         if test "x$have_colord" = "xyes"; then
 360              enable_colord=yes
 361         fi
 362 fi
 363 AM_CONDITIONAL(ENABLE_COLORD, test "x$enable_colord" = "xyes")
 364
 365 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 366 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 367 if test x$enable_wcap_tools = xyes; then
 368   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 369   PKG_CHECK_MODULES(WCAP, [cairo])
 370   WCAP_LIBS="$WCAP_LIBS -lm"
 371 fi
 372
 373 AC_CHECK_PROG(RSVG_CONVERT, rsvg-convert, rsvg-convert)
 374 AM_CONDITIONAL(HAVE_RSVG_CONVERT, test -n "$RSVG_CONVERT")
 375
 376 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 377 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 378
 379 if test "x$GCC" = "xyes"; then
 380         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter \
 381                 -Wno-missing-field-initializers -g -fvisibility=hidden \
 382                 -Wstrict-prototypes -Wmissing-prototypes"
 383 fi
 384 AC_SUBST(GCC_CFLAGS)
 385
 386 AC_ARG_ENABLE(libunwind,
 387               AS_HELP_STRING([--disable-libunwind],
 388                              [Disable libunwind usage for backtraces]),,
 389               enable_libunwind=auto)
 390 AM_CONDITIONAL(HAVE_LIBUNWIND, [test "x$enable_libunwind" = xyes])
 391 if test "x$enable_libunwind" != "xno"; then
 392         PKG_CHECK_MODULES(LIBUNWIND,
 393                           libunwind,
 394                           have_libunwind=yes,
 395                           have_libunwind=no)
 396         if test "x$have_libunwind" = "xno" -a "x$enable_libunwind" = "xyes"; then
 397           AC_MSG_ERROR([libunwind support explicitly requested, but libunwind couldn't be found])
 398         fi
 399         if test "x$have_libunwind" = "xyes"; then
 400              enable_libunwind=yes
 401              AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
 402         fi
 403 fi
 404
 405
 406 if test "x$WESTON_NATIVE_BACKEND" = "x"; then
 407         WESTON_NATIVE_BACKEND="drm-backend.so"
 408 fi
 409 AC_MSG_NOTICE([Weston's native backend: $WESTON_NATIVE_BACKEND])
 410 AC_DEFINE_UNQUOTED([WESTON_NATIVE_BACKEND], ["$WESTON_NATIVE_BACKEND"],
 411                    [The default backend to load, if not wayland nor x11.])
 412
 413 AC_ARG_ENABLE(demo-clients,
 414               AS_HELP_STRING([--enable-demo-clients],
 415                              [install demo clients built with weston]),,
 416               enable_demo_clients=no)
 417 AM_CONDITIONAL(ENABLE_DEMO_CLIENTS, [test "x$enable_demo_clients" = "xyes"])
 418
 419 PKG_CHECK_MODULES(LCMS, lcms2,
 420                   [have_lcms=yes], [have_lcms=no])
 421 if test "x$have_lcms" = xyes; then
 422        AC_DEFINE(HAVE_LCMS, 1, [Have lcms support])
 423 fi
 424 AM_CONDITIONAL(HAVE_LCMS, [test "x$have_lcms" = xyes])
 425
 426 m4_ifndef([WAYLAND_SCANNER_RULES],
 427           [m4_fatal([WAYLAND_SCANNER_RULES not found. Point ACLOCAL to wayland-scanner.m4 before running autoconf/autogen])])
 428 WAYLAND_SCANNER_RULES(['$(top_srcdir)/protocol'])
 429
 430 AC_CONFIG_FILES([Makefile
 431                  shared/Makefile
 432                  src/Makefile
 433                  src/xwayland/Makefile
 434                  src/version.h
 435                  src/weston.pc
 436                  clients/Makefile
 437                  wcap/Makefile
 438                  data/Makefile
 439                  protocol/Makefile
 440                  man/Makefile
 441                  tests/Makefile])
 442 AC_OUTPUT
 443
 444 AC_MSG_RESULT([
 445         Native Backend                  ${WESTON_NATIVE_BACKEND}
 446         setuid Install                  ${enable_setuid_install}
 447
 448         Cairo Renderer                  ${with_cairo}
 449         EGL                             ${enable_egl}
 450         libxkbcommon                    ${enable_xkbcommon}
 451         XWayland                        ${enable_xwayland}
 452
 453         Build wcap utility              ${enable_wcap_tools}
 454         Build Tablet Shell              ${enable_tablet_shell}
 455
 456         weston-launch utility           ${enable_weston_launch}
 457         weston-launch systemd support   ${have_systemd_login}
 458
 459         DRM Compositor                  ${enable_drm_compositor}
 460         X11 Compositor                  ${enable_x11_compositor}
 461         Wayland Compositor              ${enable_wayland_compositor}
 462         Headless Compositor             ${enable_headless_compositor}
 463         RPI Compositor                  ${enable_rpi_compositor}
 464         FBDEV Compositor                ${enable_fbdev_compositor}
 465         RDP Compositor                  ${enable_rdp_compositor}
 466
 467         Raspberry Pi BCM headers        ${have_bcm_host}
 468
 469         Build Clients                   ${enable_clients}
 470         Build EGL Clients               ${have_cairo_egl}
 471         Build Simple Clients            ${enable_simple_clients}
 472         Build Simple EGL Clients        ${enable_simple_egl_clients}
 473
 474         Install Demo Clients            ${enable_demo_clients}
 475
 476         Colord Support                  ${have_colord}
 477         GLU Support                     ${have_glu}
 478         LCMS2 Support                   ${have_lcms}
 479         libwebp Support                 ${have_webp}
 480         libunwind Support               ${have_libunwind}
 481 ])