configure.ac

   1 AC_PREREQ(2.69)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, cvs and prerelease does Werror too
   6 AC_INIT(GStreamer libav, 1.7.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gst-libav)
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([ext/libav/gstav.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output by default
  34 AM_SILENT_RULES([yes])
  35
  36 dnl our libraries and install dirs use major.minor as a version
  37 GST_API_VERSION=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  38 dnl we override it here if we need to for the release candidate of new series
  39 GST_API_VERSION=1.0
  40 AC_SUBST(GST_API_VERSION)
  41
  42 AG_GST_LIBTOOL_PREPARE
  43 AS_LIBTOOL(GST, 701, 0, 701)
  44
  45 dnl *** required versions of GStreamer stuff ***
  46 GST_REQ=1.7.1
  47 GST_PBREQ=1.7.1
  48
  49 ORC_REQ=0.4.16
  50 ORC_CHECK([$ORC_REQ])
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl *** check for arguments to configure ***
  61
  62 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  63 AG_GST_ARG_ENABLE_EXTRA_CHECKS
  64
  65 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  66 AG_GST_ARG_WITH_PACKAGE_NAME
  67 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  68 AG_GST_ARG_VALGRIND
  69 AG_GST_ARG_GCOV
  70
  71 dnl *** checks for platform ***
  72
  73 dnl * hardware/architecture *
  74
  75 dnl common/m4/gst-arch.m4
  76 dnl check CPU type
  77 AG_GST_ARCH
  78
  79 dnl *** checks for programs ***
  80
  81 dnl find a compiler
  82 AC_PROG_CC
  83 AC_PROG_CC_STDC
  84
  85 dnl check if the compiler supports '-c' and '-o' options
  86 AM_PROG_CC_C_O
  87
  88 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
  89 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
  90
  91 dnl check for documentation tools
  92 GTK_DOC_CHECK([1.12])
  93 AG_GST_PLUGIN_DOCS([1.12])
  94
  95 dnl *** checks for libraries ***
  96
  97 dnl check for libm, for sin()
  98 LT_LIB_M
  99 AC_SUBST(LIBM)
 100
 101 dnl *** checks for header files ***
 102
 103 dnl check if we have ANSI C header files
 104 AC_HEADER_STDC
 105
 106 dnl *** checks for types/defines ***
 107
 108 dnl *** checks for structures ***
 109
 110 dnl *** checks for compiler characteristics ***
 111
 112 dnl *** checks for library functions ***
 113
 114 dnl *** checks for dependancy libraries ***
 115
 116 dnl GLib is required
 117 GLIB_REQ=2.40.0
 118 AC_SUBST([GLIB_REQ])
 119 AG_GST_GLIB_CHECK([$GLIB_REQ])
 120
 121 dnl checks for gstreamer
 122 dnl uninstalled is selected preferentially -- see pkg-config(1)
 123 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ])
 124 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ])
 125 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GST_PBREQ])
 126 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 127 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 128
 129 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 130 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 131
 132 dnl Check for -Bsymbolic-functions linker flag used to avoid
 133 dnl intra-library PLT jumps, if available.
 134 AC_ARG_ENABLE(Bsymbolic,
 135               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 136               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
 137                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 138                LDFLAGS=-Wl,-Bsymbolic-functions
 139                LIBS=
 140                AC_TRY_LINK([], [return 0],
 141                            AC_MSG_RESULT(yes)
 142                            enable_Bsymbolic=yes,
 143                            AC_MSG_RESULT(no)
 144                            enable_Bsymbolic=no)
 145                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
 146
 147 dnl *** set variables based on configure arguments ***
 148
 149 dnl set location of plugin directory
 150 AG_GST_SET_PLUGINDIR
 151
 152 dnl build static plugins or not
 153 AC_MSG_CHECKING([whether to build static plugins or not])
 154 AC_ARG_ENABLE(
 155   static-plugins,
 156   AC_HELP_STRING(
 157     [--enable-static-plugins],
 158     [build static plugins @<:@default=no@:>@]),
 159   [AS_CASE(
 160     [$enableval], [no], [], [yes], [],
 161     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 162   [enable_static_plugins=no])
 163 AC_MSG_RESULT([$enable_static_plugins])
 164 if test "x$enable_static_plugins" = xyes; then
 165   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 166     [Define if static plugins should be built])
 167   GST_PLUGIN_LIBTOOLFLAGS=""
 168 else
 169   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 170 fi
 171 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 172 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 173
 174 dnl define an ERROR_CFLAGS Makefile variable
 175 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 176     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 177     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 178     -Winit-self -Wmissing-include-dirs -Waddress
 179     -Waggregate-return -Wno-multichar -Wnested-externs ])
 180
 181 dnl define correct level for debugging messages
 182 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 183
 184 dnl *** finalize CFLAGS, LDFLAGS, LIBS ***
 185
 186 dnl Overview:
 187 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 188 dnl GST_*:              flags shared by built objects to link against GStreamer
 189 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 190 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 191 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 192 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 193
 194 dnl GST_OPTION_CFLAGS
 195 if test "x$USE_DEBUG" = xyes; then
 196    PROFILE_CFLAGS="-g"
 197 fi
 198 AC_SUBST(PROFILE_CFLAGS)
 199
 200 if test "x$GST_GIT" = "xyes"; then
 201   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 202 else
 203   DEPRECATED_CFLAGS=""
 204 fi
 205 AC_SUBST(DEPRECATED_CFLAGS)
 206
 207 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 208 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 209
 210 AC_SUBST(GST_OPTION_CFLAGS)
 211
 212 dnl FIXME: do we want to rename to GST_ALL_* ?
 213 dnl prefer internal headers to already installed ones
 214 dnl also add builddir include for enumtypes and marshal
 215 dnl add GST_OPTION_CFLAGS, but overridable
 216 GST_CFLAGS="$GST_CFLAGS"
 217 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 218 AC_SUBST(GST_CFLAGS)
 219 AC_SUBST(GST_LIBS)
 220
 221 GST_ALL_LDFLAGS="-no-undefined"
 222 if test "x${enable_Bsymbolic}" = "xyes"; then
 223   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 224 fi
 225 AC_SUBST(GST_ALL_LDFLAGS)
 226
 227 dnl this really should only contain flags, not libs - they get added before
 228 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 229 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 230 AC_SUBST(GST_PLUGIN_LDFLAGS)
 231
 232 dnl Add MacOSX specific flags
 233 AC_CANONICAL_HOST
 234 case $host_os in
 235      darwin*)
 236         DARWIN_LDFLAGS="-Wl,-read_only_relocs,suppress"
 237         ;;
 238      *)
 239         DARWIN_LDFLAGS=""
 240         ;;
 241 esac
 242 AC_SUBST(DARWIN_LDFLAGS)
 243
 244 dnl *** Check for bz2
 245 save_LIBS=$LIBS
 246 LIBS="$LIBS -lbz2"
 247 AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 248 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 249 AC_MSG_RESULT($HAVE_BZ2)
 250 LIBS=$save_LIBS
 251 AM_CONDITIONAL(HAVE_BZ2, test "x$HAVE_BZ2" = "xyes")
 252 if test "x$HAVE_BZ2" = "xno"; then
 253   AC_WARN([libbz2 not found, matroska demuxer will not be able to read bz2 tracks])
 254 fi
 255
 256 dnl *** Check for lzma
 257 save_LIBS=$LIBS
 258 LIBS="$LIBS -llzma"
 259 AC_MSG_CHECKING([for lzma_version_string in -llzma])
 260 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <lzma.h>]], [[const char *version = lzma_version_string ();]])],[HAVE_LZMA=yes],[HAVE_LZMA=no])
 261 AC_MSG_RESULT($HAVE_LZMA)
 262 LIBS=$save_LIBS
 263 AM_CONDITIONAL(HAVE_LZMA, test "x$HAVE_LZMA" = "xyes")
 264 if test "x$HAVE_LZMA" = "xno"; then
 265     AC_WARN([lzma not found, tiff reader will not be able to read lzma files])
 266 fi
 267
 268 AC_ARG_ENABLE(gpl,
 269               [AC_HELP_STRING([--enable-gpl], [build a GPL licensed gst-libav])])
 270 AM_CONDITIONAL(GST_LIBAV_ENABLE_GPL, test "x$enable_gpl" = "xyes")
 271 if test "x$enable_gpl" = "xyes"; then
 272   AC_DEFINE([GST_LIBAV_ENABLE_GPL], [], [Defined if building a GPL-licensed version of gst-libav])
 273 fi
 274
 275 dnl *** configure external libs ***
 276
 277 HAVE_LIBAV_UNINSTALLED=1
 278
 279 AC_ARG_WITH(system-libav,
 280             [AC_HELP_STRING([--with-system-libav], [use system Libav libraries])])
 281
 282 if test "x$with_system_libav" = "xyes"; then
 283   PKG_CHECK_MODULES(LIBAV, libavformat libavcodec libavutil)
 284   PKG_CHECK_MODULES(SWSCALE, libswscale libavutil)
 285   saved_CPPFLAGS="$CPPFLAGS"
 286   CPPFLAGS="$CPPFLAGS $LIBAV_CFLAGS"
 287   AC_CHECK_HEADERS([avi.h])
 288   CPPFLAGS="$saved_CPPFLAGS"
 289   AC_DEFINE([LIBAV_SOURCE], ["system install"], [Describes where the Libav libraries come from.])
 290   HAVE_LIBAV_UNINSTALLED=0
 291   AC_MSG_NOTICE([Using system-installed libav code])
 292   AC_MSG_CHECKING([whether libav is provided by FFmpeg])
 293   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 294     #include <libavcodec/avcodec.h>
 295     ]],[[
 296         #if LIBAVCODEC_VERSION_MICRO >= 100
 297         /* FFmpeg uses 100+ as its micro version */
 298         #else
 299         #error libav provider should be FFmpeg
 300         #endif
 301     ]])], [is_ffmpeg=yes], [is_ffmpeg=no])
 302   AC_MSG_RESULT([$is_ffmpeg])
 303   if test "$is_ffmpeg" = no; then
 304     AC_MSG_ERROR([Uncompatible libavcodec found])
 305   fi
 306 else
 307   AC_MSG_NOTICE([Using local Libav snapshot])
 308
 309   dnl libgstlibav.la: include dirs
 310   LIBAV_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 311                 -I \$(top_builddir)/gst-libs/ext/libav \
 312                  -Wno-deprecated-declarations"
 313
 314   LIBAV_DEPS="\$(top_builddir)/gst-libs/ext/libav/libavformat/libavformat.a \
 315               \$(top_builddir)/gst-libs/ext/libav/libavcodec/libavcodec.a \
 316               \$(top_builddir)/gst-libs/ext/libav/libswresample/libswresample.a \
 317               \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 318   if test "x$enable_static_plugins" = xyes; then
 319       dnl with static linking we can't use the .a archive directly as they would
 320       dnl be included in the final libgstlibav.a as a file and won't be usable.
 321       dnl libav*.a must be copied to the final destination too
 322       LIBAV_LIBS="-lavformat -lavcodec -lswresample -lavutil"
 323   else
 324       dnl libgstlibav.la: libs to statically link to
 325       LIBAV_LIBS="$LIBAV_DEPS"
 326   fi
 327
 328   dnl
 329   SWSCALE_CFLAGS="-I \$(top_srcdir)/gst-libs/ext/libav \
 330                   -I \$(top_builddir)/gst-libs/ext/libav \
 331                   -Wno-deprecated-declarations"
 332
 333   SWSCALE_DEPS="\$(top_builddir)/gst-libs/ext/libav/libswscale/libswscale.a \
 334                 \$(top_builddir)/gst-libs/ext/libav/libavutil/libavutil.a"
 335   if test "x$enable_static_plugins" = xyes; then
 336       dnl with static linking we can't use the .a archive directly as they would
 337       dnl be included in the final libgstswscale.a as a file and won't be usable.
 338       dnl libav*.a must be copied to the final destination too
 339       SWSCALE_LIBS="-lswscale -lavutil"
 340   else
 341       dnl libgstswscale.la: libs to statically link to
 342       SWSCALE_LIBS="$SWSCALE_DEPS"
 343   fi
 344
 345   LIBAV_SUBDIRS=gst-libs
 346   AC_DEFINE(HAVE_AVI_H)
 347   AC_DEFINE([LIBAV_SOURCE], ["local snapshot"], [Describes where the Libav libraries come from.])
 348
 349   AC_ARG_WITH(libav-extra-configure,
 350       AC_HELP_STRING([--with-libav-extra-configure="xxx"],
 351       [extra configure options for internal libav ./configure script]),,
 352       with_libav=no)
 353
 354   # basic arguments
 355   emblibav_configure_args="--prefix=$prefix"
 356
 357   # Enable pic and static so that we get .a files, but with PIC code.
 358   emblibav_configure_args="$emblibav_configure_args \
 359         --enable-static --enable-pic \
 360         --disable-avdevice --disable-postproc --disable-avfilter \
 361         --disable-programs --disable-ffserver --disable-ffplay --disable-ffprobe --disable-ffmpeg \
 362         --disable-encoder=flac --disable-protocols --disable-devices \
 363         --disable-network --disable-hwaccels --disable-dxva2 --disable-vdpau \
 364         --disable-filters --disable-doc --disable-vda --disable-d3d11va --disable-dxva2 \
 365         --disable-iconv --enable-optimizations"
 366
 367   if test "x$enable_gpl" == "xyes"; then
 368     emblibav_configure_args="$emblibav_configure_args --enable-gpl"
 369   fi
 370
 371   # if we are cross-compiling, tell libav so
 372   case $host in
 373       *android*)
 374         target_os=linux
 375       ;;
 376       *darwin*)
 377         target_os=darwin
 378       ;;
 379       *)
 380         target_os=`echo $host_os | sed 's/-gnu//'`
 381       ;;
 382   esac
 383
 384   if test "x$cross_compiling" = xyes; then
 385     emblibav_configure_args="$emblibav_configure_args --enable-cross-compile \
 386         --target-os=$target_os --arch=$host_cpu --cross-prefix=$host_alias-"
 387   fi
 388
 389   case $host_os in
 390     mingw32*)
 391       emblibav_configure_args="$emblibav_configure_args --enable-memalign-hack"
 392       WIN32_LIBS="-lws2_32"
 393       ;;
 394     *)
 395       WIN32_LIBS=
 396       ;;
 397   esac
 398
 399   if test x"$AR" != x; then
 400     emblibav_configure_args="$emblibav_configure_args --ar=\\\"\\\$AR\\\""
 401   fi
 402
 403   if test x"$AS" != x; then
 404     emblibav_configure_args="$emblibav_configure_args --as=\\\"\\\$CC\\\""
 405   fi
 406
 407   if test x"$CC" != x; then
 408     emblibav_configure_args="$emblibav_configure_args --cc=\\\"\\\$CC\\\""
 409   fi
 410
 411   if test x"$LD" != x; then
 412     emblibav_configure_args="$emblibav_configure_args --ld=\\\"\\\$CC\\\""
 413   fi
 414
 415   if test x"$NM" != x; then
 416     emblibav_configure_args="$emblibav_configure_args --nm=\\\"\\\$NM\\\""
 417   fi
 418
 419   dnl checks for extra enable/disable flags
 420   LIBAV_OPTS=`cd $srcdir/gst-libs/ext/libav && ./configure --help`
 421   # Let's check if we can disable the building of the libav binary
 422   can_disable=`echo "$LIBAV_OPTS" | grep 'disable-ffmpeg'`
 423   if test "$can_disable" != ""; then
 424     emblibav_configure_args="$emblibav_configure_args --disable-ffmpeg"
 425   fi
 426   dnl check if libswscale needs enabling explicitly
 427   can_enable=`echo "$LIBAV_OPTS" | grep 'enable-swscale'`
 428   if test "$can_enable" != ""; then
 429     emblibav_configure_args="$emblibav_configure_args --enable-swscale"
 430   fi
 431
 432   # append extra configure options to emblibav_configure_args if needed
 433   if test "x$with_libav_extra_configure" != "xno"; then
 434     emblibav_configure_args="$emblibav_configure_args $with_libav_extra_configure"
 435   fi
 436
 437   AC_SUBST(LIBAV_CO_DIR)
 438   AC_SUBST(LIBAV_SVN)
 439   AC_SUBST(LIBAV_REVISION)
 440   AC_SUBST(LIBAV_EXTERNALS_REVISION)
 441   AC_CONFIG_COMMANDS([configure-embedded-libav],
 442     [echo "Configuring included Libav instance with args $emblibav_configure_args"
 443      origdir=`pwd`
 444      dnl Don't put path on the configure call when not needed, as FFmpeg's configure relies on it
 445      dnl to detect out-of-tree builds
 446      if test -z "$srcdir" -o "$srcdir" = .; then
 447        confcmd=./configure
 448      else
 449        confcmd="$ac_abs_top_srcdir"/gst-libs/ext/libav/configure
 450      fi
 451
 452      AS_MKDIR_P(["$ac_top_build_prefix"gst-libs/ext/libav])
 453      cd "$ac_top_build_prefix"gst-libs/ext/libav &&
 454          eval "$confcmd $emblibav_configure_args" ||
 455          AC_MSG_ERROR([Failed to configure embedded Libav tree])
 456      cd "$origdir"
 457     ],
 458     [emblibav_configure_args="$emblibav_configure_args"])
 459   AC_MSG_NOTICE([Using included Libav code])
 460 fi
 461
 462 AC_SUBST(LIBAV_CFLAGS)
 463 AC_SUBST(LIBAV_DEPS)
 464 AC_SUBST(LIBAV_LIBS)
 465 AC_SUBST(LIBAV_SUBDIRS)
 466 AC_SUBST(SWSCALE_CFLAGS)
 467 AC_SUBST(SWSCALE_DEPS)
 468 AC_SUBST(SWSCALE_LIBS)
 469 AC_SUBST(WIN32_LIBS)
 470
 471 if test x$HAVE_LIBAV_UNINSTALLED = x1; then
 472   AC_DEFINE(HAVE_LIBAV_UNINSTALLED, [], [Defined if building against uninstalled Libav source])
 473 fi
 474 AM_CONDITIONAL(HAVE_LIBAV_UNINSTALLED, test x$HAVE_LIBAV_UNINSTALLED = x1)
 475
 476 AC_CONFIG_FILES(
 477 Makefile
 478 common/Makefile
 479 common/m4/Makefile
 480 gst-libav.spec
 481 ext/Makefile
 482 ext/libav/Makefile
 483 ext/libswscale/Makefile
 484 gst-libs/Makefile
 485 gst-libs/ext/Makefile
 486 docs/Makefile
 487 docs/plugins/Makefile
 488 docs/version.entities
 489 tests/Makefile
 490 tests/check/Makefile
 491 tests/files/Makefile
 492 pkgconfig/Makefile
 493 pkgconfig/gstreamer-plugins-libav-uninstalled.pc
 494 )
 495 AC_OUTPUT
 496
 497 ORC_OUTPUT