configure.ac

   1 # get rid of that stupid cache mechanism
   2 rm -f config.cache
   3
   4 AC_INIT([e_dbus], [0.5.0.063], [enlightenment-devel@lists.sourceforge.net])
   5 release="ver-pre-svn-05"
   6 AC_PREREQ([2.52])
   7 AC_CONFIG_SRCDIR([configure.ac])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CANONICAL_BUILD
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  13 AM_CONFIG_HEADER([config.h])
  14 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  15
  16 AC_PROG_CC
  17 AC_HEADER_STDC
  18 AM_PROG_CC_C_O
  19 AC_C___ATTRIBUTE__
  20
  21 AC_LIBTOOL_WIN32_DLL
  22 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  23 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  24 AC_PROG_LIBTOOL
  25
  26 VMAJ=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $1);}'`
  27 VMIN=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $2);}'`
  28 VMIC=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $3);}'`
  29 SNAP=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $4);}'`
  30 version_info=`expr $VMAJ + $VMIN`":$VMIC:$VMIN"
  31 econnman_release_info="-release $release"
  32 edbus_release_info="-release $release"
  33 ehal_release_info="-release $release"
  34 enm_release_info="-release $release"
  35 enotify_release_info="-release $release"
  36 AC_SUBST(version_info)
  37 AC_SUBST(econnman_release_info)
  38 AC_SUBST(edbus_release_info)
  39 AC_SUBST(ehal_release_info)
  40 AC_SUBST(enm_release_info)
  41 AC_SUBST(enotify_release_info)
  42
  43 dnl Check enabled modules to build
  44 AC_ARG_ENABLE([ehal],
  45    [AC_HELP_STRING([--disable-ehal], [Disable ehal build])],
  46    [enable_ehal=$enableval],
  47    [enable_ehal="yes"])
  48
  49 AC_ARG_ENABLE([enm],
  50    [AC_HELP_STRING([--enable-enm], [Enable enm (network manager) build])],
  51    [enable_enm=$enableval],
  52    [enable_enm="no"])
  53
  54 AC_ARG_ENABLE([econnman],
  55    [AC_HELP_STRING([--enable-econnman], [Enable econnman build])],
  56    [enable_econnman=$enableval],
  57    [enable_econnman="yes"])
  58
  59 AC_ARG_ENABLE([enotify],
  60    [AC_HELP_STRING([--disable-enotify], [Disable enotify build])],
  61    [enable_enotify=$enableval],
  62    [enable_enotify="yes"])
  63
  64 # pkg-config
  65 PKG_PROG_PKG_CONFIG
  66
  67 # Check whether pkg-config supports Requires.private
  68 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
  69    pkgconfig_requires_private="Requires.private"
  70 else
  71    pkgconfig_requires_private="Requires"
  72 fi
  73 AC_SUBST(pkgconfig_requires_private)
  74
  75 PKG_CHECK_MODULES([EINA], [eina-0])
  76
  77 PKG_CHECK_MODULES([EDBUS], [
  78   dbus-1 >= 0.62
  79   ecore >= 0.9.9
  80 ])
  81
  82 AC_FUNC_ALLOCA
  83
  84 dnl evas
  85 if test "x${enable_enotify}" = "xyes" ; then
  86    PKG_CHECK_MODULES(EVAS, [evas >= 0.9.9], [], [enable_enotify="no"])
  87 fi
  88
  89 AC_ARG_ENABLE([build-test-gui],
  90    [AS_HELP_STRING([--enable-build-test-gui], [Build with gui for testing])],
  91    [PKG_CHECK_MODULES([HAL_TEST_GUI],
  92        [ewl efreet],
  93     # temporarily disable until update to newer tree2 api
  94     [AC_DEFINE([EWL_GUI], 0, [An ewl gui for e_dbus_hal])],
  95     [AC_DEFINE([EWL_GUI], 0, [An ewl gui for e_dbus_hal])])
  96    ])
  97
  98 AM_CONDITIONAL([BUILD_EHAL],     [test "x${enable_ehal}"     = "xyes"])
  99 AM_CONDITIONAL([BUILD_ENM],      [test "x${enable_enm}"      = "xyes"])
 100 AM_CONDITIONAL([BUILD_ENOTIFY],  [test "x${enable_enotify}"  = "xyes"])
 101 AM_CONDITIONAL([BUILD_ECONNMAN], [test "x${enable_econnman}" = "xyes"])
 102
 103 EFL_EDBUS_BUILD=""
 104 lt_enable_auto_import=""
 105 case "$host_os" in
 106    mingw* | cegcc*)
 107       EFL_EDBUS_BUILD="-DEFL_EDBUS_BUILD"
 108       lt_enable_auto_import="-Wl,--enable-auto-import"
 109    ;;
 110 esac
 111 AC_SUBST(EFL_EDBUS_BUILD)
 112 AC_SUBST(lt_enable_auto_import)
 113
 114 AC_OUTPUT([
 115 e_dbus.spec
 116 Makefile
 117 src/Makefile
 118 src/lib/Makefile
 119 src/lib/dbus/Makefile
 120 src/lib/hal/Makefile
 121 src/lib/nm/Makefile
 122 src/lib/notification/Makefile
 123 src/lib/connman/Makefile
 124 src/bin/Makefile
 125 edbus.pc
 126 ehal.pc
 127 enotify.pc
 128 enm.pc
 129 econnman.pc
 130 ])
 131
 132
 133 #####################################################################
 134 ## Info
 135
 136 echo
 137 echo
 138 echo
 139 echo "------------------------------------------------------------------------"
 140 echo "$PACKAGE $VERSION"
 141 echo "------------------------------------------------------------------------"
 142 echo
 143 echo "Configuration Options Summary:"
 144 echo
 145 echo "  Modules:"
 146 echo
 147 echo "    EHal...............: $enable_ehal"
 148 echo "    ENM................: $enable_enm"
 149 echo "    EConnman...........: $enable_econnman"
 150 echo "    ENotify............: $enable_enotify"
 151 echo
 152 echo "Compilation............: make (or gmake)"
 153 echo "  CPPFLAGS.............: $CPPFLAGS"
 154 echo "  CFLAGS...............: $CFLAGS"
 155 echo "  LDFLAGS..............: $LDFLAGS"
 156 echo
 157 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 158 echo "  prefix...............: $prefix"
 159 echo