configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [5])
   4 m4_define([gst_vaapi_micro_version], [0])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # gstreamer-vaapi library (libtool) version number
  13 m4_define([gst_vaapi_lt_current],  [1])
  14 m4_define([gst_vaapi_lt_revision], [0])
  15 m4_define([gst_vaapi_lt_age],      [0])
  16
  17 # glib version number
  18 m4_define([glib_major_version], [2])
  19 m4_define([glib_minor_version], [28])
  20 m4_define([glib_micro_version], [0])
  21 m4_define([glib_major_minor_version],
  22           [glib_major_version.glib_minor_version])
  23 m4_define([glib_version],
  24           [glib_major_version.glib_minor_version.glib_micro_version])
  25
  26 # gst version number
  27 m4_define([gst_major_version], [0])
  28 m4_define([gst_minor_version], [10])
  29 m4_define([gst_micro_version], [36])
  30 m4_define([gst_major_minor_version],
  31           [gst_major_version.gst_minor_version])
  32 m4_define([gst_version],
  33           [gst_major_version.gst_minor_version.gst_micro_version])
  34
  35 # gst plugins-base version number
  36 m4_define([gst_plugins_base_major_version], [0])
  37 m4_define([gst_plugins_base_minor_version], [10])
  38 m4_define([gst_plugins_base_micro_version], [31])
  39 m4_define([gst_plugins_base_version],
  40           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  41
  42 # gst plugins-bad version number
  43 m4_define([gst_plugins_bad_major_version], [0])
  44 m4_define([gst_plugins_bad_minor_version], [10])
  45 m4_define([gst_plugins_bad_micro_version], [22])
  46 m4_define([gst_plugins_bad_version],
  47           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
  48
  49 # Wayland minimum version number
  50 m4_define([wayland_api_version], [1.0.0])
  51
  52 # VA-API minimum version number
  53 m4_define([va_api_version],     [0.30.4])
  54 m4_define([va_api_drm_version], [0.33.0])
  55 m4_define([va_api_x11_version], [0.31.0])
  56 m4_define([va_api_glx_version], [0.32.0])
  57 m4_define([va_api_wld_version], [0.33.0])
  58
  59 # libva package version number
  60 m4_define([libva_drm_package_version], [1.1.0])
  61 m4_define([libva_x11_package_version], [1.0.3])
  62 m4_define([libva_glx_package_version], [1.0.9])
  63 m4_define([libva_wld_package_version], [1.1.0])
  64
  65 # gtk-doc version number
  66 # XXX: introspection annotations require gtk-doc >= 1.12
  67 m4_define([gtkdoc_major_version], [1])
  68 m4_define([gtkdoc_minor_version], [9])
  69 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  70
  71 AC_PREREQ([2.58])
  72 AC_INIT([gst_vaapi], [gst_vaapi_version],
  73     [gwenole.beauchesne@intel.com],
  74     [gstreamer-vaapi])
  75
  76 AC_CONFIG_HEADERS([config.h])
  77 AC_CONFIG_SRCDIR([Makefile.am])
  78 AC_CONFIG_MACRO_DIR([m4])
  79 AC_CONFIG_AUX_DIR([build-aux])
  80
  81 AC_CANONICAL_TARGET
  82
  83 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-bzip2])
  84
  85 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  86 AC_SUBST(TODAY)
  87
  88 GST_VAAPI_MAJOR_VERSION=gst_vaapi_lt_current
  89 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  90
  91 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  92 AC_SUBST(LIBVA_PACKAGE_VERSION)
  93
  94 WAYLAND_API_VERSION=wayland_api_version
  95 AC_SUBST(WAYLAND_API_VERSION)
  96
  97 dnl Versions for GStreamer and plugins-base
  98 GST_MAJORMINOR=gst_major_minor_version
  99 GST_VERSION_REQUIRED=gst_version
 100 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
 101 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
 102 AC_SUBST(GST_MAJORMINOR)
 103 AC_SUBST(GST_VERSION_REQUIRED)
 104 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
 105 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
 106
 107 dnl Use pretty build output with automake >= 1.11
 108 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
 109   AM_DEFAULT_VERBOSITY=1
 110   AC_SUBST(AM_DEFAULT_VERBOSITY)
 111 ])
 112
 113 dnl Check for tools
 114 AC_PROG_CC
 115 AM_PROG_CC_C_O
 116
 117 dnl Initialize libtool
 118 LT_PREREQ([2.2])
 119 LT_INIT
 120
 121 AC_ARG_ENABLE(drm,
 122     AS_HELP_STRING([--enable-drm],
 123                    [enable DRM backend @<:@default=yes@:>@]),
 124     [], [enable_drm="yes"])
 125
 126 AC_ARG_ENABLE(x11,
 127     AS_HELP_STRING([--enable-x11],
 128                    [enable X11 output @<:@default=yes@:>@]),
 129     [], [enable_x11="yes"])
 130
 131 AC_ARG_ENABLE(glx,
 132     AS_HELP_STRING([--enable-glx],
 133                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
 134     [], [enable_glx="yes"])
 135
 136 AC_ARG_ENABLE(wayland,
 137     AC_HELP_STRING([--enable-wayland],
 138                    [enable Wayland output @<:@default=yes@:>@]),
 139     [], [enable_wayland="yes"])
 140
 141 dnl Check for basic libraries
 142 AC_CHECK_LIB(m, tan)
 143
 144 dnl Check for Gtk doc
 145 GTKDOC_VERSION=gtkdoc_version
 146 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 147 m4_ifdef([GTK_DOC_CHECK], [
 148 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 149 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 150 AC_SUBST(GTKDOC_VERSION)
 151
 152 dnl Check for GLib
 153 GLIB_VERSION_REQUIRED=glib_version
 154 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 155 AC_SUBST(GLIB_VERSION_REQUIRED)
 156
 157 dnl ---------------------------------------------------------------------------
 158 dnl -- GStreamer                                                             --
 159 dnl ---------------------------------------------------------------------------
 160
 161 dnl GStreamer Core
 162 PKG_CHECK_MODULES([GST],      [gstreamer-$GST_MAJORMINOR >= gst_version])
 163 PKG_CHECK_MODULES([GST_BASE], [gstreamer-base-$GST_MAJORMINOR >= gst_version])
 164
 165 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 166     saved_CPPFLAGS="$CPPFLAGS"
 167     CPPFLAGS="$CPPFLAGS $GST_BASE_CFLAGS"
 168     saved_LIBS="$LIBS"
 169     LIBS="$LIBS $GST_BASE_LIBS"
 170     AC_COMPILE_IFELSE(
 171         [AC_LANG_PROGRAM(
 172             [[#include <gst/base/gstbasesink.h>]],
 173             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 174         [ac_cv_have_gst_base_sink_query="yes"],
 175         [ac_cv_have_gst_base_sink_query="no"]
 176     )
 177     CPPFLAGS="$saved_CPPFLAGS"
 178     LIBS="$saved_LIBS"
 179 ])
 180 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 181     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 182 fi
 183
 184 dnl GStreamer -base plugins
 185 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 186     [gstreamer-plugins-base-$GST_MAJORMINOR >= gst_plugins_base_version])
 187 PKG_CHECK_MODULES([GST_INTERFACES],
 188     [gstreamer-interfaces-$GST_MAJORMINOR >= gst_plugins_base_version])
 189
 190 dnl ... GstVideoOverlayComposition (gstreamer-video)
 191 PKG_CHECK_MODULES([GST_VIDEO],
 192     [gstreamer-video-$GST_MAJORMINOR >= gst_plugins_base_version])
 193
 194 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 195     ac_cv_have_gst_video_overlay_composition, [
 196     saved_CPPFLAGS="$CPPFLAGS"
 197     CPPFLAGS="$CPPFLAGS $GST_CFLAGS"
 198     saved_LIBS="$LIBS"
 199     LIBS="$LIBS $GST_LIBS"
 200     AC_COMPILE_IFELSE(
 201         [AC_LANG_PROGRAM(
 202             [[#include <gst/video/video-overlay-composition.h>]],
 203             [[GstVideoOverlayComposition *c;
 204               c = gst_video_overlay_composition_new(0);]])],
 205         [ac_cv_have_gst_video_overlay_composition="yes"],
 206         [ac_cv_have_gst_video_overlay_composition="no"]
 207     )
 208     CPPFLAGS="$saved_CPPFLAGS"
 209     LIBS="$saved_LIBS"
 210 ])
 211 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 212     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 213 fi
 214
 215 AC_CACHE_CHECK([... with advanced format flags],
 216     ac_cv_have_gst_video_overlay_hwcaps, [
 217     saved_CPPFLAGS="$CPPFLAGS"
 218     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_VIDEO_CFLAGS"
 219     saved_LIBS="$LIBS"
 220     LIBS="$LIBS $GST_LIBS $GST_VIDEO_LIBS"
 221     AC_COMPILE_IFELSE(
 222         [AC_LANG_PROGRAM(
 223             [[#include <gst/video/video-overlay-composition.h>]],
 224             [[GstVideoOverlayRectangle *rect;
 225               const guint w = 64, h = 64;
 226               guint flags = (
 227                   GST_VIDEO_OVERLAY_FORMAT_FLAG_PREMULTIPLIED_ALPHA|
 228                   GST_VIDEO_OVERLAY_FORMAT_FLAG_GLOBAL_ALPHA);
 229               rect = gst_video_overlay_rectangle_new_argb(NULL, w, h, w * 4,
 230                   0, 0, w, h, flags);
 231               gst_video_overlay_rectangle_set_global_alpha(rect, 0.5f);]])],
 232         [ac_cv_have_gst_video_overlay_hwcaps="yes"],
 233         [ac_cv_have_gst_video_overlay_hwcaps="no"]
 234     )
 235     CPPFLAGS="$saved_CPPFLAGS"
 236     LIBS="$saved_LIBS"
 237 ])
 238 if test "$ac_cv_have_gst_video_overlay_hwcaps" = "yes"; then
 239     AC_DEFINE_UNQUOTED([HAVE_GST_VIDEO_OVERLAY_HWCAPS], 1,
 240         [Defined to 1 if GstVideoOverlayComposition API supports HW hints.])
 241 fi
 242
 243 dnl ... GstVideoDecoder (gstreamer-video)
 244 AC_CACHE_CHECK([for GstVideoDecoder],
 245     ac_cv_have_gst_video_decoder, [
 246     saved_CPPFLAGS="$CPPFLAGS"
 247     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_VIDEO_CFLAGS"
 248     saved_LIBS="$LIBS"
 249     LIBS="$LIBS $GST_LIBS $GST_VIDEO_LIBS"
 250     AC_COMPILE_IFELSE(
 251         [AC_LANG_PROGRAM(
 252             [[#include <gst/video/gstvideodecoder.h>]],
 253             [[GstVideoCodecFrame *f;
 254               GstVideoDecoder vdec;
 255               f = g_slice_new0(GstVideoCodecFrame);
 256               f->ref_count = 1;
 257               gst_video_decoder_have_frame(&vdec);
 258               gst_video_decoder_finish_frame(&vdec, f);
 259               gst_video_codec_frame_unref(f);]])],
 260         [ac_cv_have_gst_video_decoder="yes"],
 261         [ac_cv_have_gst_video_decoder="no"]
 262     )
 263     CPPFLAGS="$saved_CPPFLAGS"
 264     LIBS="$saved_LIBS"
 265 ])
 266 AM_CONDITIONAL([USE_LOCAL_GST_VIDEO_DECODER],
 267     [test "$ac_cv_have_gst_video_decoder" != "yes"])
 268
 269 dnl GStreamer -bad plugins
 270 PKG_CHECK_MODULES([GST_BASEVIDEO],
 271     [gstreamer-basevideo-$GST_MAJORMINOR >= gst_plugins_bad_version])
 272
 273 dnl ... bitstream parsers
 274 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 275     [gstreamer-codecparsers-$GST_MAJORMINOR >= gst_plugins_bad_version])
 276
 277 dnl ... MPEG-2 parser, with the required extensions
 278 AC_CACHE_CHECK([for MPEG-2 parser],
 279     ac_cv_have_gst_mpeg2_parser, [
 280     saved_CPPFLAGS="$CPPFLAGS"
 281     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 282     saved_LIBS="$LIBS"
 283     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 284     AC_COMPILE_IFELSE(
 285         [AC_LANG_PROGRAM(
 286             [[#include <gst/codecparsers/gstmpegvideoparser.h>]],
 287             [[GstMpegVideoSequenceHdr seq_hdr;
 288               GstMpegVideoSequenceExt seq_ext;
 289               GstMpegVideoSequenceDisplayExt seq_dpy;
 290               gst_mpeg_video_finalise_mpeg2_sequence_header(&seq_hdr,
 291                   &seq_ext, &seq_dpy);]])],
 292         [ac_cv_have_gst_mpeg2_parser="yes"],
 293         [ac_cv_have_gst_mpeg2_parser="no"]
 294     )
 295     CPPFLAGS="$saved_CPPFLAGS"
 296     LIBS="$saved_LIBS"
 297 ])
 298 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_MPEG2],
 299     [test "$ac_cv_have_gst_mpeg2_parser" != "yes"])
 300
 301 dnl ... H.264 parser, with the required extensions
 302 AC_CACHE_CHECK([for H.264 parser],
 303     ac_cv_have_gst_h264_parser, [
 304     saved_CPPFLAGS="$CPPFLAGS"
 305     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 306     saved_LIBS="$LIBS"
 307     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 308     AC_COMPILE_IFELSE(
 309         [AC_LANG_PROGRAM(
 310             [[#include <gst/codecparsers/gsth264parser.h>]],
 311             [[GstH264SliceHdr slice_hdr;
 312               GstH264VUIParams vui_params;
 313               slice_hdr.n_emulation_prevention_bytes = 0;
 314               vui_params.par_n = 0;
 315               vui_params.par_d = 0;]])],
 316         [ac_cv_have_gst_h264_parser="yes"],
 317         [ac_cv_have_gst_h264_parser="no"]
 318     )
 319     CPPFLAGS="$saved_CPPFLAGS"
 320     LIBS="$saved_LIBS"
 321 ])
 322 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_H264],
 323     [test "$ac_cv_have_gst_h264_parser" != "yes"])
 324
 325 dnl ... JPEG parser, not upstream yet
 326 AC_CACHE_CHECK([for JPEG parser],
 327     ac_cv_have_gst_jpeg_parser, [
 328     saved_CPPFLAGS="$CPPFLAGS"
 329     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 330     saved_LIBS="$LIBS"
 331     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 332     AC_COMPILE_IFELSE(
 333         [AC_LANG_PROGRAM(
 334             [[#include <gst/codecparsers/gstjpegparser.h>]],
 335             [[GstJpegImage jpeg_image;]])],
 336         [ac_cv_have_gst_jpeg_parser="yes"],
 337         [ac_cv_have_gst_jpeg_parser="no"]
 338     )
 339     CPPFLAGS="$saved_CPPFLAGS"
 340     LIBS="$saved_LIBS"
 341 ])
 342 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_JPEG],
 343     [test "$ac_cv_have_gst_jpeg_parser" != "yes"])
 344
 345 dnl GST_VAAPI_LT_LDFLAGS:
 346 GST_VAAPI_LT_CURRENT=gst_vaapi_lt_current
 347 GST_VAAPI_LT_REV=gst_vaapi_lt_revision
 348 GST_VAAPI_LT_AGE=gst_vaapi_lt_age
 349 GST_VAAPI_LT_VERSION="$GST_VAAPI_LT_CURRENT:$GST_VAAPI_LT_REV:$GST_VAAPI_LT_AGE"
 350 GST_VAAPI_LT_LDFLAGS="-version-info $GST_VAAPI_LT_VERSION"
 351 AC_SUBST(GST_VAAPI_LT_VERSION)
 352 AC_SUBST(GST_VAAPI_LT_LDFLAGS)
 353
 354 dnl GST_ALL_LDFLAGS:
 355 dnl LDFLAGS really should only contain flags, not libs - they get added before
 356 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 357 GST_ALL_LDFLAGS="-no-undefined"
 358 AC_SUBST(GST_ALL_LDFLAGS)
 359
 360 dnl GST_PLUGIN_LDFLAGS:
 361 dnl this really should only contain flags, not libs - they get added before
 362 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 363 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 364 AC_SUBST(GST_PLUGIN_LDFLAGS)
 365
 366 dnl Check for the GStreamer plugins directory
 367 AC_ARG_VAR([GST_PLUGIN_PATH], [installation path for gstreamer-vaapi plugin elements])
 368 AC_MSG_CHECKING([for GStreamer plugins directory])
 369 if test -d "$GST_PLUGIN_PATH"; then
 370     GST_PLUGINS_DIR="$GST_PLUGIN_PATH"
 371 else
 372     GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 373     if test -z "$GST_PLUGINS_DIR"; then
 374         GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 375     fi
 376 fi
 377 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 378 plugindir="$GST_PLUGINS_DIR"
 379 AC_SUBST(plugindir)
 380
 381 dnl ---------------------------------------------------------------------------
 382 dnl -- Renderers                                                             --
 383 dnl ---------------------------------------------------------------------------
 384
 385 dnl Check for DRM/libudev
 386 USE_DRM=0
 387 if test "$enable_drm" = "yes"; then
 388     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
 389     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
 390
 391     if test $USE_DRM -eq 1; then
 392         saved_CPPFLAGS="$CPPFLAGS"
 393         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 394         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
 395         CPPFLAGS="$saved_CPPFLAGS"
 396     fi
 397 fi
 398
 399 dnl Check for X11
 400 USE_X11=0
 401 if test "$enable_x11" = "yes"; then
 402     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 403     if test $USE_X11 -eq 1; then
 404         saved_CPPFLAGS="$CPPFLAGS"
 405         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 406         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 407         CPPFLAGS="$saved_CPPFLAGS"
 408     fi
 409 fi
 410
 411 dnl Check for XRandR
 412 HAVE_XRANDR=0
 413 if test $USE_X11 -eq 1; then
 414     HAVE_XRANDR=1
 415     PKG_CHECK_MODULES([XRANDR], [xrandr], [:], [HAVE_XRANDR=0])
 416     if test $HAVE_XRANDR -eq 1; then
 417         saved_CPPFLAGS="$CPPFLAGS"
 418         CPPFLAGS="$CPPFLAGS $XRANDR_CFLAGS"
 419         AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [:], [HAVE_XRANDR=0])
 420         CPPFLAGS="$saved_CPPFLAGS"
 421     fi
 422 fi
 423 if test $HAVE_XRANDR -eq 1; then
 424     AC_DEFINE_UNQUOTED(HAVE_XRANDR, 1,
 425         [Defined to 1 if the XRandR extension exists.])
 426 fi
 427
 428 dnl OpenGL
 429 enable_opengl="no"
 430 if test "$enable_glx" = "yes"; then
 431     enable_opengl="yes"
 432 fi
 433
 434 HAVE_GL=0
 435 if test "$enable_opengl" = "yes"; then
 436     HAVE_GL=1
 437     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 438     saved_CPPFLAGS="$CPPFLAGS"
 439     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 440     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 441 #ifdef HAVE_GL_GL_H
 442 # include <GL/gl.h>
 443 #endif
 444     ])
 445     CPPFLAGS="$saved_CPPFLAGS"
 446 fi
 447
 448 dnl ... GLX
 449 USE_GLX=0
 450 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 451     USE_GLX=1
 452     saved_CPPFLAGS="$CPPFLAGS"
 453     saved_LIBS="$LIBS"
 454     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 455     LIBS="$LIBS $GL_LIBS"
 456     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 457 #ifdef HAVE_GL_GL_H
 458 # include <GL/gl.h>
 459 #endif
 460     ])
 461     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 462     CPPFLAGS="$saved_CPPFLAGS"
 463     LIBS="$saved_LIBS"
 464 fi
 465
 466 dnl Check for Wayland
 467 USE_WAYLAND=0
 468 if test "$enable_wayland" = "yes"; then
 469     PKG_CHECK_MODULES(WAYLAND, [wayland-client >= wayland_api_version],
 470         [USE_WAYLAND=1], [USE_WAYLAND=0])
 471
 472     if test $USE_WAYLAND -eq 1; then
 473         saved_CPPFLAGS="$CPPFLAGS"
 474         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 475         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
 476         CPPFLAGS="$saved_CPPFLAGS"
 477     fi
 478 fi
 479
 480 dnl ---------------------------------------------------------------------------
 481 dnl -- VA-API                                                                --
 482 dnl ---------------------------------------------------------------------------
 483
 484 dnl Core API
 485 LIBVA_PKGNAME="libva"
 486 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 487 AC_SUBST(LIBVA_PKGNAME)
 488
 489 VA_VERSION=`$PKG_CONFIG --modversion libva`
 490 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 491 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 492 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 493 VA_VERSION_STR="$VA_VERSION"
 494
 495 dnl VA/DRM API
 496 HAVE_VA_DRM=0
 497 if test $USE_DRM -eq 1; then
 498     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
 499         [HAVE_VA_DRM=1], [USE_DRM=0])
 500
 501     if test $HAVE_VA_DRM -eq 1; then
 502         saved_CPPFLAGS="$CPPFLAGS"
 503         CPPFLAGS="$LIBVA_DRM_CFLAGS"
 504         AC_CHECK_HEADERS([va/va_drm.h], [:], [HAVE_VA_DRM=0 USE_DRM=0])
 505         CPPFLAGS="$saved_CPPFLAGS"
 506     fi
 507 fi
 508
 509 dnl VA/X11 API
 510 HAVE_VA_X11=0
 511 LIBVA_X11_PKGNAME="libva-x11"
 512 if test $USE_X11 -eq 1; then
 513     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 514         [HAVE_VA_X11=1], [USE_X11=0])
 515 fi
 516 AC_SUBST(LIBVA_X11_PKGNAME)
 517
 518 dnl VA/GLX API
 519 HAVE_VA_GLX=0
 520 LIBVA_GLX_PKGNAME="libva-glx"
 521 if test $USE_GLX -eq 1; then
 522     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
 523         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
 524
 525     if test $HAVE_VA_GLX -eq 1; then
 526         saved_CPPFLAGS="$CPPFLAGS"
 527         CPPFLAGS="$LIBVA_GLX_CFLAGS"
 528         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
 529         CPPFLAGS="$saved_CPPFLAGS"
 530     fi
 531 fi
 532 AC_SUBST(LIBVA_GLX_PKGNAME)
 533
 534 dnl Check for JPEG decoding API (0.32.1+)
 535 USE_JPEG_DECODER=0
 536 AC_CACHE_CHECK([for JPEG decoding API],
 537     ac_cv_have_jpeg_decoding_api, [
 538     saved_CPPFLAGS="$CPPFLAGS"
 539     CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 540     saved_LIBS="$LIBS"
 541     LIBS="$LIBS $LIBVA_LIBS"
 542     AC_COMPILE_IFELSE(
 543         [AC_LANG_PROGRAM(
 544             [[#include <va/va.h>]],
 545             [[VAPictureParameterBufferJPEGBaseline pic_param;
 546               VASliceParameterBufferJPEGBaseline slice_param;
 547               VAHuffmanTableBufferJPEGBaseline huffman_table;
 548               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
 549         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 550         [ac_cv_have_jpeg_decoding_api="no"]
 551     )
 552     CPPFLAGS="$saved_CPPFLAGS"
 553     LIBS="$saved_LIBS"
 554 ])
 555
 556 dnl VA/Wayland API
 557 if test "$enable_wayland" = "yes"; then
 558     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
 559         [:], [USE_WAYLAND=0])
 560 fi
 561
 562 dnl ---------------------------------------------------------------------------
 563 dnl -- Generate files and summary                                            --
 564 dnl ---------------------------------------------------------------------------
 565
 566 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
 567 *:1:*)
 568     ;;
 569 *)
 570     AC_MSG_ERROR([No renderer is enabled])
 571     ;;
 572 esac
 573
 574 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 575     [Defined to 1 if JPEG decoder is used])
 576 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 577
 578 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
 579     [Defined to 1 if DRM is enabled])
 580 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
 581
 582 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 583     [Defined to 1 if X11 is enabled])
 584 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 585
 586 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 587     [Defined to 1 if GLX is enabled])
 588 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 589
 590 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
 591     [Defined to 1 if WAYLAND is enabled])
 592 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
 593
 594 pkgconfigdir=${libdir}/pkgconfig
 595 AC_SUBST(pkgconfigdir)
 596
 597 AC_CONFIG_FILES([
 598     Makefile
 599     debian.upstream/Makefile
 600     debian.upstream/changelog
 601     debian.upstream/control
 602     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 603 debian.upstream/gstreamer-vaapi-doc.install.in
 604     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 605 debian.upstream/gstreamer-vaapi.install.in
 606     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 607 debian.upstream/libgstvaapi.install.in
 608     debian.upstream/libgstvaapi-dev.install
 609     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
 610 debian.upstream/libgstvaapi-drm.install.in
 611     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 612 debian.upstream/libgstvaapi-glx.install.in
 613     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
 614 debian.upstream/libgstvaapi-wayland.install.in
 615     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 616 debian.upstream/libgstvaapi-x11.install.in
 617     docs/Makefile
 618     docs/reference/Makefile
 619     docs/reference/libs/Makefile
 620     docs/reference/libs/libs-docs.xml
 621     docs/reference/plugins/Makefile
 622     docs/reference/plugins/plugins-docs.xml
 623     ext/Makefile
 624     gst-libs/Makefile
 625     gst-libs/gst/Makefile
 626     gst-libs/gst/codecparsers/Makefile
 627     gst-libs/gst/vaapi/Makefile
 628     gst-libs/gst/video/Makefile
 629     gst/Makefile
 630     gst/vaapi/Makefile
 631     pkgconfig/Makefile
 632     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 633 pkgconfig/gstreamer-vaapi.pc.in
 634     pkgconfig/gstreamer-vaapi-drm-$GST_MAJORMINOR.pc:\
 635 pkgconfig/gstreamer-vaapi-drm.pc.in
 636     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 637 pkgconfig/gstreamer-vaapi-glx.pc.in
 638     pkgconfig/gstreamer-vaapi-wayland-$GST_MAJORMINOR.pc:\
 639 pkgconfig/gstreamer-vaapi-wayland.pc.in
 640     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 641 pkgconfig/gstreamer-vaapi-x11.pc.in
 642     tests/Makefile
 643 ])
 644 AC_OUTPUT
 645
 646 dnl Print summary
 647 yesno() {
 648     test $1 -eq 1 && echo yes || echo no
 649 }
 650
 651 VIDEO_OUTPUTS=""
 652 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
 653 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
 654 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
 655 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
 656
 657 echo
 658 echo $PACKAGE configuration summary:
 659 echo
 660 echo VA-API version ................... : $VA_VERSION_STR
 661 echo Video outputs .................... : $VIDEO_OUTPUTS
 662 echo