configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [999])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([ecore], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39
  40 AC_LIBTOOL_WIN32_DLL
  41 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  42 AC_PROG_LIBTOOL
  43
  44 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  45 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  46 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  47 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  48 AC_DEFINE_UNQUOTED(VERS_MAJ, [v_maj], [Major version])
  49 AC_DEFINE_UNQUOTED(VERS_MIN, [v_min], [Minor version])
  50 AC_DEFINE_UNQUOTED(VERS_MIC, [v_mic], [Micro version])
  51 AC_DEFINE_UNQUOTED(VERS_REV, [v_rev], [Revison])
  52 version_info="lt_cur:lt_rev:lt_age"
  53 release_info="v_rel"
  54 AC_SUBST(version_info)
  55 AC_SUBST(release_info)
  56 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  57 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  58 VMAJ=v_maj
  59 AC_SUBST(VMAJ)
  60
  61 m4_ifdef([AM_GNU_GETTEXT_VERSION], [
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 ])
  64
  65 m4_ifdef([AM_GNU_GETTEXT], [
  66 AM_GNU_GETTEXT([external])
  67 po_makefile_in=po/Makefile.in
  68 have_po="yes"
  69 ],[
  70 have_po="no"
  71 ])
  72 AC_SUBST(LTLIBINTL)
  73
  74 if test "x${POSUB}" = "x" ; then
  75    have_po="no"
  76 fi
  77
  78 AM_CONDITIONAL([HAVE_PO], [test "x${have_po}" = "xyes"])
  79
  80 with_max_log_level="<unset>"
  81 AC_ARG_WITH(internal-maximum-log-level,
  82    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
  83                    [limit ecore internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
  84    [
  85     if test "x${withval}" != "xno"; then
  86        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
  87           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
  88           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
  89           with_max_log_level="${withval}"
  90        else
  91           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
  92        fi
  93     fi
  94     ], [:])
  95
  96
  97 ### Default options with respect to host
  98
  99 AC_CANONICAL_BUILD
 100 AC_CANONICAL_HOST
 101
 102 # dependencies and options
 103 want_curl="no"
 104 want_local_sockets="yes"
 105 want_abstract_sockets="no"
 106 want_gnutls="no"
 107 want_openssl="no"
 108 want_cares="no"
 109 want_cipher="no"
 110 want_signature="no"
 111 want_poll="yes"
 112 want_inotify="no"
 113 want_notify_win32="no"
 114 want_tslib="no"
 115 want_glib="no"
 116
 117 # core modules
 118 want_ecore_con="yes"
 119 want_ecore_ipc="yes"
 120 want_ecore_file="yes"
 121 #want_ecore_config="no"
 122 want_ecore_imf="no"
 123 want_ecore_input="yes"
 124
 125 # graphic system modules
 126 want_evas_simple_x11="no"
 127 want_ecore_x_xcb="no"
 128 want_ecore_x="no"
 129 want_ecore_win32="no"
 130 want_ecore_cocoa="no"
 131 want_ecore_sdl="no"
 132 want_ecore_fb="no"
 133 want_ecore_directfb="no"
 134 want_ecore_wince="no"
 135
 136 # ecore_x options (both xlib and xcb)
 137 want_ecore_x_composite="yes"
 138 want_ecore_x_damage="yes"
 139 want_ecore_x_dpms="yes"
 140 want_ecore_x_randr="yes"
 141 want_ecore_x_render="yes"
 142 want_ecore_x_screensaver="yes"
 143 want_ecore_x_shape="yes"
 144 want_ecore_x_sync="yes"
 145 want_ecore_x_xfixes="yes"
 146 want_ecore_x_xinerama="yes"
 147 want_ecore_x_xprint="yes"
 148 want_ecore_x_xtest="yes"
 149 want_ecore_x_cursor="yes"
 150 want_ecore_x_input="yes"
 151 want_ecore_x_dri="yes"
 152
 153 # ecore_evas modules
 154 want_ecore_evas="yes"
 155 want_ecore_evas_software_buffer="yes"
 156 want_ecore_evas_software_x11="no"
 157 want_ecore_evas_opengl_x11="no"
 158 want_ecore_evas_software_16_x11="no"
 159 want_ecore_evas_software_8_x11="no"
 160 want_ecore_evas_software_xcb="no"
 161 want_ecore_evas_software_gdi="no"
 162 want_ecore_evas_software_ddraw="no"
 163 want_ecore_evas_direct3d="no"
 164 want_ecore_evas_opengl_glew="no"
 165 want_ecore_evas_software_16_ddraw="no"
 166 want_ecore_evas_software_sdl="no"
 167 want_ecore_evas_gl_sdl="no"
 168 want_ecore_evas_gl_cocoa="no"
 169 want_ecore_evas_directfb="no"
 170 want_ecore_evas_fb="no"
 171 want_ecore_evas_software_16_wince="no"
 172 want_ecore_evas_ews="yes"
 173
 174 # ecore_imf modules
 175 want_ecore_imf_xim="no"
 176
 177 case "$host_os" in
 178    mingw32ce* | cegcc*)
 179       want_ecore_con="no"
 180       want_ecore_ipc="no"
 181       want_ecore_wince="yes"
 182       want_ecore_evas_software_16_wince="yes"
 183       ;;
 184    mingw*)
 185       want_notify_win32="yes"
 186       want_curl="yes"
 187       want_glib="auto"
 188       want_gnutls="auto"
 189       want_openssl="auto"
 190       want_ecore_imf="yes"
 191       want_ecore_win32="yes"
 192       want_ecore_evas_software_gdi="yes"
 193       want_ecore_evas_software_ddraw="yes"
 194       want_ecore_evas_direct3d="yes"
 195       want_ecore_evas_opengl_glew="yes"
 196       want_ecore_evas_software_16_ddraw="auto"
 197       want_ecore_evas_software_sdl="yes"
 198       want_ecore_evas_gl_sdl="yes"
 199       ;;
 200    darwin*)
 201       want_curl="yes"
 202       want_glib="auto"
 203       want_gnutls="auto"
 204       want_openssl="auto"
 205       want_ecore_imf="yes"
 206       want_ecore_cocoa="yes"
 207       want_ecore_evas_software_sdl="yes"
 208       want_ecore_evas_gl_sdl="yes"
 209       want_ecore_evas_gl_cocoa="yes"
 210       ;;
 211    *)
 212       want_curl="yes"
 213       want_glib="auto"
 214       want_abstract_sockets="yes"
 215       want_gnutls="auto"
 216       want_openssl="auto"
 217       want_cipher="yes"
 218       want_signature="yes"
 219       want_inotify="yes"
 220       want_tslib="yes"
 221       want_ecore_fb="yes"
 222       want_ecore_imf="yes"
 223       want_ecore_x="yes"
 224       want_ecore_evas_software_x11="yes"
 225       want_ecore_evas_opengl_x11="yes"
 226       want_ecore_evas_software_16_x11="yes"
 227       want_ecore_evas_software_8_x11="yes"
 228       want_ecore_evas_software_xcb="no"
 229       want_ecore_evas_software_sdl="yes"
 230       want_ecore_evas_gl_sdl="yes"
 231       want_ecore_evas_gl_cocoa="no"
 232       want_ecore_evas_directfb="yes"
 233       want_ecore_evas_fb="yes"
 234       want_ecore_imf_xim="yes"
 235       ;;
 236 esac
 237
 238 case "$host_vendor" in
 239   ps3*)
 240       want_local_sockets="no"
 241       ;;
 242 esac
 243 requirements_ecore=""
 244 requirements_ecore_con=""
 245 #requirements_ecore_config=""
 246 requirements_ecore_directfb=""
 247 requirements_ecore_evas=""
 248 requirements_ecore_fb=""
 249 requirements_ecore_file=""
 250 requirements_ecore_imf=""
 251 requirements_ecore_imf_evas=""
 252 requirements_ecore_input=""
 253 requirements_ecore_input_evas=""
 254 requirements_ecore_ipc=""
 255 requirements_ecore_cocoa=""
 256 requirements_ecore_sdl=""
 257 requirements_ecore_x=""
 258 requirements_ecore_win32=""
 259 requirements_ecore_wince=""
 260 requirements_ecore_imf_xim=""
 261
 262 AC_CHECK_DECL([MAXHOSTNAMELEN],[FOUND_MAXHOSTNAMELEN=yes])
 263
 264 if test x$FOUND_MAXHOSTNAMELEN != xyes ; then
 265   AC_MSG_CHECKING([for header that defines MAXHOSTNAMELEN])
 266
 267   FOUND_MAXHOSTNAMELEN='not found'
 268
 269   AC_COMPILE_IFELSE(
 270         AC_LANG_PROGRAM([#include <sys/param.h>],
 271                 [int h = MAXHOSTNAMELEN;]),
 272         [FOUND_MAXHOSTNAMELEN='sys/param.h'
 273            AC_DEFINE(NEED_SYS_PARAM_H,1,
 274              [Define to 1 if you need <sys/param.h> to define MAXHOSTNAMELEN])])
 275
 276         AC_COMPILE_IFELSE(
 277             AC_LANG_PROGRAM([#include <netdb.h>],
 278                             [int h = MAXHOSTNAMELEN;]),
 279             [FOUND_MAXHOSTNAMELEN='netdb.h'
 280              AC_DEFINE(NEED_NETDB_H,1,
 281                [Define to 1 if you need <netdb.h> to define MAXHOSTNAMELEN])])
 282
 283   AC_MSG_RESULT([$FOUND_MAXHOSTNAMELEN])
 284 fi
 285
 286 ### Additional options to configure
 287
 288 want_glib_integration_always=no
 289 AC_ARG_ENABLE(glib-integration-always,
 290   AC_HELP_STRING([--enable-glib-integration-always], [enable glib integration when ecore_init() is called always]),
 291   [want_glib_integration_always=$enableval])
 292
 293 if test "x${want_glib_integration_always}" = "xyes" ; then
 294   AC_DEFINE([GLIB_INTEGRATION_ALWAYS], [1], [Always integrate glib if support compiled])
 295   want_glib=yes
 296 fi
 297
 298 want_g_main_loop=no
 299 AC_ARG_ENABLE(g-main-loop,
 300   AC_HELP_STRING([--enable-g-main-loop], [ecore_main_loop based on g_main_loop]),
 301   [want_g_main_loop=$enableval])
 302
 303 if test "x${want_g_main_loop}" = "xyes" ; then
 304   AC_DEFINE([USE_G_MAIN_LOOP], [1], [Use g_main_loop in ecore])
 305   want_glib=yes
 306 fi
 307
 308 if test "x${want_glib_integration_always}" = "xyes" -a "x${want_g_main_loop}" = "xyes"; then
 309   AC_MSG_ERROR([--enable-glib-integration-always and --enable-glib-main-loop are mutually exclusive])
 310 fi
 311
 312 # local sockets (ecore_con.c)
 313 AC_ARG_ENABLE([local-sockets],
 314    [AC_HELP_STRING([--disable-local-sockets], [disable local sockets.])],
 315    [
 316     if test "x${enableval}" = "xyes" ; then
 317        want_ecore_con_local_sockets="yes"
 318     else
 319        want_ecore_con_local_sockets="no"
 320     fi
 321    ],
 322    [want_ecore_con_local_sockets=${want_local_sockets}])
 323
 324 if test "x${want_ecore_con_local_sockets}" = "xyes" ; then
 325    AC_DEFINE([HAVE_LOCAL_SOCKETS], [1], [Have local sockets support])
 326 fi
 327
 328 # abstract sockets (ecore_con.c)
 329 AC_ARG_ENABLE([abstract-sockets],
 330    [AC_HELP_STRING([--disable-abstract-sockets], [disable abstract sockets.])],
 331    [
 332     if test "x${enableval}" = "xyes" ; then
 333        want_ecore_con_abstract_sockets="yes"
 334     else
 335        want_ecore_con_abstract_sockets="no"
 336     fi
 337    ],
 338    [want_ecore_con_abstract_sockets=${want_abstract_sockets}])
 339
 340 if test "x${want_ecore_con_abstract_sockets}" = "xyes" ; then
 341    AC_DEFINE([HAVE_ABSTRACT_SOCKETS], [1], [Have abstract sockets namespace])
 342 fi
 343
 344 # Simple X11 build/link
 345
 346 AC_ARG_ENABLE(simple-x11,
 347   AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking]),
 348   [want_evas_simple_x11=$enableval])
 349
 350 # XIM
 351 AC_ARG_ENABLE([xim],
 352    [AC_HELP_STRING([--disable-xim], [disable X Input Method.])],
 353    [
 354     if test "x${enableval}" = "xyes" ; then
 355        want_xim="yes"
 356     else
 357        want_xim="no"
 358     fi
 359    ],
 360    [want_xim="yes"])
 361
 362 if test "x${want_xim}" = "xyes" ; then
 363    AC_DEFINE([ENABLE_XIM], [1], [Enable X Input Method])
 364 fi
 365
 366 # Unit tests
 367
 368 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 369
 370 ### Checks for programs
 371
 372 m4_ifdef([AC_PROG_OBJC],
 373    [
 374     AC_PROG_OBJC
 375     _AM_DEPENDENCIES(OBJC)
 376    ],
 377    [
 378     AC_CHECK_TOOL([OBJC], [gcc])
 379     AC_SUBST([OBJC])
 380     AC_SUBST([OBJCFLAGS])
 381    ])
 382 m4_ifndef([am__fastdepOBJC], [
 383     AM_CONDITIONAL([am__fastdepOBJC], [false])
 384     AC_SUBST([cocoa_ldflags])
 385 ])
 386
 387 AC_PROG_CXX
 388 AC_PROG_CC
 389
 390 have_gnu_objc=${ac_cv_objc_compiler_gnu}
 391
 392 # doxygen program for documentation building
 393
 394 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 395
 396 m4_ifdef([v_mic],
 397    [
 398     EFL_COMPILER_FLAG([-Wall])
 399     EFL_COMPILER_FLAG([-W])
 400    ])
 401
 402 # The first call to PKG_CHECK_MODULES is done conditionally,
 403 # so we should include this here:
 404 PKG_PROG_PKG_CONFIG
 405
 406 # Check whether pkg-config supports Requires.private
 407 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 408    pkgconfig_requires_private="Requires.private"
 409 else
 410    pkgconfig_requires_private="Requires"
 411 fi
 412 AC_SUBST(pkgconfig_requires_private)
 413
 414 ### Checks for some build time option
 415 have_backtrace="no"
 416 AC_CHECK_FUNCS([backtrace], [have_backtrace="yes"], [])
 417
 418 want_ecore_timer_dump="yes"
 419
 420 AC_ARG_ENABLE([ecore-timer-dump],
 421    [AC_HELP_STRING([--disable-ecore-timer-dump], [disable tracking of timer allocation. @<:@default=enable@:>@])],
 422    [want_ecore_timer_dump=$enableval], [])
 423
 424 if test "x$want_ecore_timer_dump" = "xyes" -a "x$have_backtrace" = "xyes"; then
 425    AC_DEFINE(WANT_ECORE_TIMER_DUMP, [1], [Want Ecore_Timer dump infrastructure])
 426 fi
 427
 428 ### Checks for libraries
 429
 430 # Evil library for compilation on Windows
 431
 432 case "$host_os" in
 433    mingw* | cegcc*)
 434       PKG_CHECK_MODULES([EVIL], [evil])
 435       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 436       requirements_ecore="evil ${requirements_ecore}"
 437       requirements_ecore_evas="evil ${requirements_ecore_evas}"
 438       requirements_ecore_file="evil ${requirements_ecore_file}"
 439       requirements_ecore_imf="evil ${requirements_ecore_imf}"
 440       requirements_ecore_imf_evas="evil ${requirements_ecore_imf_evas}"
 441       EFL_ECORE_BUILD="-DEFL_ECORE_BUILD"
 442       EFL_ECORE_CON_BUILD="-DEFL_ECORE_CON_BUILD"
 443       EFL_ECORE_EVAS_BUILD="-DEFL_ECORE_EVAS_BUILD"
 444       EFL_ECORE_FILE_BUILD="-DEFL_ECORE_FILE_BUILD"
 445       EFL_ECORE_IMF_BUILD="-DEFL_ECORE_IMF_BUILD"
 446       EFL_ECORE_IMF_EVAS_BUILD="-DEFL_ECORE_IMF_EVAS_BUILD"
 447       EFL_ECORE_INPUT_BUILD="-DEFL_ECORE_INPUT_BUILD"
 448       EFL_ECORE_INPUT_EVAS_BUILD="-DEFL_ECORE_INPUT_EVAS_BUILD"
 449       EFL_ECORE_IPC_BUILD="-DEFL_ECORE_IPC_BUILD"
 450       ;;
 451 esac
 452
 453 have_win32=""
 454 have_wince=""
 455 case "$host_os" in
 456    mingw32ce* | cegcc*)
 457       EFL_ECORE_WINCE_BUILD="-DEFL_ECORE_WINCE_BUILD"
 458       requirements_ecore_wince="evil ${requirements_ecore_wince}"
 459       have_wince="yes"
 460       ;;
 461    mingw*)
 462       EFL_ECORE_WIN32_BUILD="-DEFL_ECORE_WIN32_BUILD"
 463       EFL_ECORE_SDL_BUILD="-DEFL_ECORE_SDL_BUILD"
 464       requirements_ecore_win32="evil ${requirements_ecore_win32}"
 465       requirements_ecore_sdl="evil ${requirements_ecore_sdl}"
 466       have_win32="yes"
 467       ;;
 468 esac
 469
 470 AC_SUBST(EFL_ECORE_BUILD)
 471 AC_SUBST(EFL_ECORE_CON_BUILD)
 472 AC_SUBST(EFL_ECORE_EVAS_BUILD)
 473 AC_SUBST(EFL_ECORE_FILE_BUILD)
 474 AC_SUBST(EFL_ECORE_IMF_BUILD)
 475 AC_SUBST(EFL_ECORE_IMF_EVAS_BUILD)
 476 AC_SUBST(EFL_ECORE_INPUT_BUILD)
 477 AC_SUBST(EFL_ECORE_INPUT_EVAS_BUILD)
 478 AC_SUBST(EFL_ECORE_IPC_BUILD)
 479 AC_SUBST(EFL_ECORE_WINCE_BUILD)
 480 AC_SUBST(EFL_ECORE_WIN32_BUILD)
 481 AC_SUBST(EFL_ECORE_SDL_BUILD)
 482
 483 AM_CONDITIONAL(ECORE_HAVE_WINCE, test "x${have_wince}" = "xyes")
 484 AM_CONDITIONAL(ECORE_HAVE_WIN32, test "x${have_win32}" = "xyes")
 485
 486 WIN32_LIBS=""
 487 case "$host_os" in
 488    mingw32ce* | cegcc*)
 489       WIN32_LIBS="-lws2"
 490       dlopen_libs="-ldl"
 491       ;;
 492    mingw*)
 493       WIN32_LIBS="-lws2_32"
 494       dlopen_libs="-ldl"
 495       ;;
 496    *)
 497       AC_CHECK_LIB([c], [dlopen],
 498          [],
 499          [AC_CHECK_LIB([dl], [dlopen],
 500              [dlopen_libs=-ldl])
 501          ])
 502       AC_CHECK_LIB([c], [clock_gettime],
 503          [AC_DEFINE(HAVE_CLOCK_GETTIME, [1], [Have clock_gettime()])],
 504          [AC_CHECK_LIB([rt], [clock_gettime],
 505              [
 506               rt_libs=-lrt
 507               AC_DEFINE(HAVE_CLOCK_GETTIME, [1], [Have clock_gettime()])
 508              ])
 509          ])
 510       ;;
 511 esac
 512 AC_SUBST(WIN32_LIBS)
 513 AC_SUBST(dlopen_libs)
 514 AC_SUBST(rt_libs)
 515
 516 # Eina library
 517
 518 PKG_CHECK_MODULES(EINA, [eina >= 1.0.0])
 519 #FIXME check all the requirements when the eina move will be finished
 520 requirements_ecore="eina >= 1.0.0 ${requirements_ecore}"
 521 requirements_ecore_con="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_con}"
 522 #requirements_ecore_config="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_config}"
 523 requirements_ecore_directfb="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_directfb}"
 524 requirements_ecore_evas="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_evas}"
 525 requirements_ecore_fb="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_fb}"
 526 requirements_ecore_file="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_file}"
 527 requirements_ecore_imf="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_imf}"
 528 requirements_ecore_imf_evas="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_imf_evas}"
 529 requirements_ecore_input="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_input}"
 530 requirements_ecore_input_evas="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_input_evas}"
 531 requirements_ecore_ipc="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_ipc}"
 532 requirements_ecore_cocoa="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_cocoa}"
 533 requirements_ecore_sdl="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_sdl}"
 534 requirements_ecore_win32="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_win32}"
 535 requirements_ecore_wince="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_wince}"
 536 requirements_ecore_x="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_x}"
 537
 538
 539 # glib support (main loop integration)
 540 AC_ARG_ENABLE([glib],
 541    [AC_HELP_STRING([--disable-glib], [disable glib support. @<:@default=detect@:>@])],
 542    [want_glib=$enableval], [])
 543
 544 if test "x$want_glib" != "xno"; then
 545    PKG_CHECK_MODULES([GLIB], [glib-2.0], [have_glib="yes"], [have_glib="no"])
 546 else
 547    have_glib="no"
 548 fi
 549 if test "x$want_glib" = "xyes" -a "x$have_glib" = "xno"; then
 550    AC_MSG_ERROR([GLib support requested, but no GLib found by pkg-config.])
 551 elif test "x$have_glib" = "xyes"; then
 552    AC_DEFINE(HAVE_GLIB, [1], [Have GLib])
 553    requirements_ecore="glib-2.0 ${requirements_ecore}"
 554 fi
 555
 556
 557 # SDL library (ecore_sdl)
 558
 559 have_sdl="no"
 560 PKG_CHECK_MODULES([SDL], [sdl >= 1.2.0], [have_sdl="yes"], [have_sdl="no"])
 561 if test "x${have_sdl}" != "xyes" ; then
 562    SDL_CONFIG="sdl-config"
 563    AC_ARG_WITH([sdl-config],
 564       [AC_HELP_STRING([--with-sdl-config=PATH], [use sdl-config specified])],
 565       [
 566        SDL_CONFIG=$withval
 567        AC_MSG_NOTICE([using ${SDL_CONFIG} for sdl-config])
 568       ])
 569
 570    AC_PATH_PROG([SDL_CONFIG], ["sdl-config"], [""], [$PATH])
 571
 572    if test -n "$SDL_CONFIG" ; then
 573       SDL_CFLAGS=`$SDL_CONFIG --cflags`
 574       SDL_LIBS=`$SDL_CONFIG --libs`
 575       AC_SUBST(SDL_CFLAGS)
 576       AC_SUBST(SDL_LIBS)
 577       have_sdl="yes"
 578    fi
 579 fi
 580
 581 if test "x${have_sdl}" = "xyes" ; then
 582    PKG_CHECK_EXISTS([sdl >= 1.3.0],
 583       [AC_DEFINE(BUILD_ECORE_EVAS_SDL_130, 1, [Support for SVN SDL])])
 584 fi
 585
 586
 587 # DirectFB library (ecore_directfb)
 588
 589 PKG_CHECK_MODULES([DIRECTFB],
 590    [directfb >= 0.9.16],
 591    [have_directfb="yes"],
 592    [have_directfb="no"])
 593
 594
 595 # Eet library (ecore_config)
 596
 597 #PKG_CHECK_MODULES([EET],
 598 #   [eet >= 1.4.0],
 599 #   [have_eet="yes"],
 600 #   [have_eet="no"])
 601
 602
 603 # Xlib and XCB (ecore_x)
 604
 605 have_x="no"
 606 have_ecore_x="no"
 607 have_ecore_x_xlib="no"
 608 have_ecore_x_xcb="no"
 609
 610 x_dir="";
 611 x_includes="";
 612 x_cflags="";
 613 x_libs="";
 614
 615 ecore_x_libs_private=""
 616
 617 AC_ARG_ENABLE(ecore-x-composite,
 618    [AC_HELP_STRING([--disable-ecore-x-composite],
 619        [disable the ecore_x support for Xcomposite extension.
 620         @<:@default=detect@:>@])],
 621    [want_ecore_x_composite=$enableval])
 622
 623 AC_ARG_ENABLE(ecore-x-damage,
 624    [AC_HELP_STRING([--disable-ecore-x-damage],
 625        [disable the ecore_x support for Xdamage extension.
 626         @<:@default=detect@:>@])],
 627    [want_ecore_x_damage=$enableval])
 628
 629 AC_ARG_ENABLE(ecore-x-dpms,
 630    [AC_HELP_STRING([--disable-ecore-x-dpms],
 631        [disable the ecore_x support for Xdpms extension.
 632         @<:@default=detect@:>@])],
 633    [want_ecore_x_dpms=$enableval])
 634
 635 AC_ARG_ENABLE(ecore-x-randr,
 636    [AC_HELP_STRING([--disable-ecore-x-randr],
 637        [disable the ecore_x support for Xrandr extension.
 638         @<:@default=detect@:>@])],
 639    [want_ecore_x_randr=$enableval])
 640
 641 AC_ARG_ENABLE(ecore-x-render,
 642    [AC_HELP_STRING([--disable-ecore-x-render],
 643        [disable the ecore_x support for Xrender extension.
 644         @<:@default=detect@:>@])],
 645    [want_ecore_x_render=$enableval])
 646
 647 AC_ARG_ENABLE(ecore-x-screensaver,
 648    [AC_HELP_STRING([--disable-ecore-x-screensaver],
 649        [disable the ecore_x support for Xscreensaver extension.
 650         @<:@default=detect@:>@])],
 651    [want_ecore_x_screensaver=$enableval])
 652
 653 AC_ARG_ENABLE(ecore-x-shape,
 654    [AC_HELP_STRING([--disable-ecore-x-shape],
 655        [disable the ecore_x support for Xshape extension.
 656         @<:@default=detect@:>@])],
 657    [want_ecore_x_shape=$enableval])
 658
 659 AC_ARG_ENABLE(ecore-x-sync,
 660    [AC_HELP_STRING([--disable-ecore-x-sync],
 661        [disable the ecore_x support for Xsync extension.
 662         @<:@default=detect@:>@])],
 663    [want_ecore_x_sync=$enableval])
 664
 665 AC_ARG_ENABLE(ecore-x-xfixes,
 666    [AC_HELP_STRING([--disable-ecore-x-xfixes],
 667        [disable the ecore_x support for Xfixes extension.
 668         @<:@default=detect@:>@])],
 669    [want_ecore_x_xfixes=$enableval])
 670
 671 AC_ARG_ENABLE(ecore-x-xinerama,
 672    [AC_HELP_STRING([--disable-ecore-x-xinerama],
 673        [disable the ecore_x support for Xinerama extension.
 674         @<:@default=detect@:>@])],
 675    [want_ecore_x_xinerama=$enableval])
 676
 677 AC_ARG_ENABLE(ecore-x-xprint,
 678    [AC_HELP_STRING([--disable-ecore-x-xprint],
 679        [disable the ecore_x support for Xprint extension.
 680         @<:@default=detect@:>@])],
 681    [want_ecore_x_xprint=$enableval])
 682
 683 AC_ARG_ENABLE(ecore-x-xtest,
 684    [AC_HELP_STRING([--disable-ecore-x-xtest],
 685        [disable the ecore_x support for Xtest extension.
 686         @<:@default=detect@:>@])],
 687    [want_ecore_x_xtest=$enableval])
 688
 689 AC_ARG_ENABLE(ecore-x-cursor,
 690    [AC_HELP_STRING([--disable-ecore-x-cursor],
 691        [disable the ecore_x support for Xcursor extension.
 692         @<:@default=detect@:>@])],
 693    [want_ecore_x_cursor=$enableval])
 694
 695 AC_ARG_ENABLE(ecore-x-input,
 696    [AC_HELP_STRING([--disable-ecore-x-input],
 697        [disable the ecore_x support for Xinput/Xinput2 extension.
 698         @<:@default=detect@:>@])],
 699    [want_ecore_x_input=$enableval])
 700
 701 AC_ARG_ENABLE(ecore-x-dri,
 702    [AC_HELP_STRING([--disable-ecore-x-dri],
 703        [disable the ecore_x support for DRI extension.
 704         @<:@default=detect@:>@])],
 705    [want_ecore_x_dri=$enableval])
 706
 707 AC_ARG_ENABLE(ecore-x-xcb,
 708    [AC_HELP_STRING([--enable-ecore-x-xcb],
 709        [enable the ecore_x module with XCB backend. @<:@default=disabled@:>@])],
 710    [want_ecore_x_xcb=$enableval])
 711
 712 AC_MSG_CHECKING(whether ecore_x with XCB backend is to be built)
 713 AC_MSG_RESULT($want_ecore_x_xcb)
 714
 715 if test "x$want_ecore_x_xcb" = "xyes" ; then
 716
 717   AC_MSG_CHECKING([keysym definitions])
 718   KEYSYMDEFDIR=`$PKG_CONFIG --variable=includedir xproto`/X11
 719   FILES="keysymdef.h XF86keysym.h Sunkeysym.h DECkeysym.h HPkeysym.h"
 720   for i in $FILES; do
 721       if test -f "$KEYSYMDEFDIR/$i"; then
 722         KEYSYMDEFS="$KEYSYMDEFS $KEYSYMDEFDIR/$i"
 723       elif test "x$i" = "xkeysymdef.h"; then
 724         AC_MSG_ERROR([Cannot find keysymdef.h])
 725       fi
 726   done
 727   AC_MSG_RESULT([$KEYSYMDEFS])
 728   AC_SUBST(KEYSYMDEFS)
 729
 730   have_iconv="no"
 731   AC_ARG_WITH([iconv-link],
 732     AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 733       [
 734         LIBS="$withval $LIBS"
 735         have_iconv="yes"
 736       ])
 737
 738   AC_MSG_CHECKING(for explicit iconv link options)
 739   if test "x${iconv_libs}" = "x" ; then
 740     AC_MSG_RESULT([no explicit iconv link option])
 741   else
 742     AC_MSG_RESULT([$iconv_libs])
 743   fi
 744
 745   if test "x${have_iconv}" = "xno" ; then
 746     AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 747
 748     if test "x${have_iconv}" = "xyes" ; then
 749       AC_MSG_CHECKING([whether iconv() is in libc])
 750
 751       AC_LINK_IFELSE(
 752         [AC_LANG_PROGRAM(
 753         [[
 754           #include <stdlib.h>
 755           #include <iconv.h>
 756         ]],
 757         [[
 758           iconv_t ic;
 759           size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 760         ]])],
 761         [have_iconv="yes"],
 762         [have_iconv="no"])
 763
 764       AC_MSG_RESULT([${have_iconv}])
 765     fi
 766
 767     if test "x${have_iconv}" = "xno" ; then
 768       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 769
 770       LIBS_save="${LIBS}"
 771       LIBS="-liconv $LIBS"
 772       AC_LINK_IFELSE(
 773       [AC_LANG_PROGRAM(
 774         [[
 775           #include <stdlib.h>
 776           #include <iconv.h>
 777         ]],
 778         [[
 779           iconv_t ic;
 780           size_t count;
 781           count = iconv(ic, NULL, NULL, NULL, NULL);
 782         ]])],
 783         [have_iconv="yes"],
 784         [
 785           have_iconv="no"
 786           LIBS=${LIBS_save}
 787         ])
 788
 789       AC_MSG_RESULT([${have_iconv}])
 790     fi
 791
 792     if test "x${have_iconv}" = "xno" ; then
 793       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 794
 795       LIBS_save="${LIBS}"
 796       LIBS="-liconv_plug $LIBS"
 797       AC_LINK_IFELSE(
 798       [AC_LANG_PROGRAM(
 799       [[
 800         #include <stdlib.h>
 801         #include <iconv.h>
 802       ]],
 803       [[
 804         iconv_t ic;
 805         size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 806       ]])],
 807       [have_iconv="yes"],
 808       [
 809         have_iconv="no"
 810         LIBS=${LIBS_save}
 811       ])
 812
 813       AC_MSG_RESULT([${have_iconv}])
 814     fi
 815
 816     if test "x${have_iconv}" = "xyes" ; then
 817       AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 818     fi
 819   fi
 820
 821   PKG_CHECK_MODULES(ECORE_XCB, x11-xcb xcb xcb-shm xcb-event xcb-icccm >= 0.3.8 xcb-util >= 0.3.8 xcb-image xcb-keysyms >= 0.3.8,
 822     [ have_ecore_x_xcb="yes"
 823       requirements_ecore_x="x11-xcb xcb xcb-shm xcb-event xcb-icccm xcb-util xcb-image xcb-keysyms ${requirements_ecore_x}"
 824     ],
 825     [
 826         PKG_CHECK_MODULES(ECORE_XCB, x11-xcb xcb xcb-event xcb-shm xcb-icccm xcb-image xcb-keysyms,
 827           [ have_ecore_x_xcb="yes"
 828             AC_DEFINE(OLD_XCB_VERSION, 1, [xcb version])
 829             requirements_ecore_x="x11-xcb xcb xcb-event xcb-shm xcb-icccm xcb-image xcb-keysyms ${requirements_ecore_x}" ],
 830           [ have_ecore_x_xcb="no" ])
 831     ],
 832     [have_ecore_x_xcb="no" ])
 833
 834   if test "x$have_ecore_x_xcb" = "xyes" ; then
 835
 836    PKG_CHECK_MODULES([PIXMAN],
 837       [pixman-1],
 838       [
 839        have_pixman="yes"
 840        AC_DEFINE(HAVE_PIXMAN, 1, [have pixman for rendering])
 841        requirements_ecore_x="pixman-1 ${requirements_ecore_x}"
 842       ],
 843       [
 844        if test "x${want_pixman}" = "xyes" -a "x${use_strict}" = "xyes" ; then
 845           AC_MSG_ERROR([Pixman not found (strict dependencies checking)])
 846        fi
 847       ])
 848
 849     if test "x$want_ecore_x_composite" != "xno"; then
 850       PKG_CHECK_MODULES(XCB_COMPOSITE, xcb-composite,
 851         [ have_ecore_x_xcb_composite="yes"
 852           requirements_ecore_x="xcb-composite ${requirements_ecore_x}"
 853           AC_DEFINE(ECORE_XCB_COMPOSITE, 1, [Build support for XCB composite]) ],
 854         [ have_ecore_x_xcb_composite="no" ])
 855     else
 856       have_ecore_x_xcb_composite="no"
 857       AC_MSG_NOTICE("composite extension explicitly disabled")
 858     fi
 859
 860     if test "x$want_ecore_x_damage" != "xno"; then
 861       PKG_CHECK_MODULES(XCB_DAMAGE, xcb-damage,
 862         [ have_ecore_x_xcb_damage="yes"
 863           requirements_ecore_x="xcb-damage ${requirements_ecore_x}"
 864           AC_DEFINE(ECORE_XCB_DAMAGE, 1, [Build support for XCB damage]) ],
 865         [ have_ecore_x_xcb_damage="no" ])
 866     else
 867       have_ecore_x_xcb_damage="no"
 868       AC_MSG_NOTICE("damage extension explicitly disabled")
 869     fi
 870
 871     if test "x$want_ecore_x_dpms" != "xno"; then
 872       PKG_CHECK_MODULES(XCB_DPMS, xcb-dpms,
 873         [ have_ecore_x_xcb_dpms="yes"
 874           requirements_ecore_x="xcb-dpms ${requirements_ecore_x}"
 875           AC_DEFINE(ECORE_XCB_DPMS, 1, [Build support for XCB dpms]) ],
 876         [ have_ecore_x_xcb_dpms="no" ])
 877     else
 878       have_ecore_x_xcb_dpms="no"
 879       AC_MSG_NOTICE("dpms extension explicitly disabled")
 880     fi
 881
 882     if test "x$want_ecore_x_randr" != "xno"; then
 883       PKG_CHECK_MODULES(XCB_RANDR, xcb-randr,
 884         [ have_ecore_x_xcb_randr="yes"
 885           requirements_ecore_x="xcb-randr ${requirements_ecore_x}"
 886           AC_DEFINE(ECORE_XCB_RANDR, 1, [Build support for XCB randr]) ],
 887         [ have_ecore_x_xcb_randr="no" ])
 888     else
 889       have_ecore_x_xcb_randr="no"
 890       AC_MSG_NOTICE("randr extension explicitly disabled")
 891     fi
 892
 893     if test "x$want_ecore_x_render" != "xno"; then
 894       PKG_CHECK_MODULES(XCB_RENDER, xcb-render xcb-renderutil,
 895         [ have_ecore_x_xcb_render="yes"
 896           requirements_ecore_x="xcb-render xcb-renderutil ${requirements_ecore_x}"
 897           AC_DEFINE(ECORE_XCB_RENDER, 1, [Build support for XCB render]) ],
 898         [ have_ecore_x_xcb_render="no" ])
 899     else
 900       have_ecore_x_xcb_render="no"
 901       AC_MSG_NOTICE("render extension explicitly disabled")
 902     fi
 903
 904     if test "x$want_ecore_x_screensaver" != "xno"; then
 905       PKG_CHECK_MODULES(XCB_SCREENSAVER, xcb-screensaver,
 906         [ have_ecore_x_xcb_screensaver="yes"
 907           requirements_ecore_x="xcb-screensaver ${requirements_ecore_x}"
 908           AC_DEFINE(ECORE_XCB_SCREENSAVER, 1, [Build support for XCB screensaver]) ],
 909         [ have_ecore_x_xcb_screensaver="no" ])
 910     else
 911       have_ecore_x_xcb_screensaver="no"
 912       AC_MSG_NOTICE("screensaver extension explicitly disabled")
 913     fi
 914
 915     if test "x$want_ecore_x_shape" != "xno"; then
 916       PKG_CHECK_MODULES(XCB_SHAPE, xcb-shape,
 917         [ have_ecore_x_xcb_shape="yes"
 918           requirements_ecore_x="xcb-shape ${requirements_ecore_x}"
 919           AC_DEFINE(ECORE_XCB_SHAPE, 1, [Build support for XCB shape]) ],
 920         [ have_ecore_x_xcb_shape="no" ])
 921     else
 922       have_ecore_x_xcb_shape="no"
 923       AC_MSG_NOTICE("shape extension explicitly disabled")
 924     fi
 925
 926     if test "x$want_ecore_x_sync" != "xno"; then
 927       PKG_CHECK_MODULES(XCB_SYNC, xcb-sync,
 928         [ have_ecore_x_xcb_sync="yes"
 929           requirements_ecore_x="xcb-sync ${requirements_ecore_x}"
 930           AC_DEFINE(ECORE_XCB_SYNC, 1, [Build support for XCB sync]) ],
 931         [ have_ecore_x_xcb_sync="no" ])
 932     else
 933       have_ecore_x_xcb_sync="no"
 934       AC_MSG_NOTICE("sync extension explicitly disabled")
 935     fi
 936
 937     if test "x$want_ecore_x_xfixes" != "xno"; then
 938       PKG_CHECK_MODULES(XCB_XFIXES, xcb-xfixes,
 939         [ have_ecore_x_xcb_xfixes="yes"
 940           requirements_ecore_x="xcb-xfixes ${requirements_ecore_x}"
 941           AC_DEFINE(ECORE_XCB_XFIXES, 1, [Build support for XCB xfixes]) ],
 942         [ have_ecore_x_xcb_xfixes="no" ])
 943     else
 944       have_ecore_x_xcb_xfixes="no"
 945       AC_MSG_NOTICE("xfixes extension explicitly disabled")
 946     fi
 947
 948     if test "x$want_ecore_x_xinerama" != "xno"; then
 949       PKG_CHECK_MODULES(XCB_XINERAMA, xcb-xinerama,
 950         [ have_ecore_x_xcb_xinerama="yes"
 951           requirements_ecore_x="xcb-xinerama ${requirements_ecore_x}"
 952           AC_DEFINE(ECORE_XCB_XINERAMA, 1, [Build support for XCB xinerama]) ],
 953         [ have_ecore_x_xcb_xinerama="no" ])
 954     else
 955       have_ecore_x_xcb_xinerama="no"
 956       AC_MSG_NOTICE("xinerama extension explicitly disabled")
 957     fi
 958
 959     if test "x$want_ecore_x_xprint" != "xno"; then
 960       PKG_CHECK_MODULES(XCB_XPRINT, xcb-xprint,
 961         [ have_ecore_x_xcb_xprint="yes"
 962           requirements_ecore_x="xcb-xprint ${requirements_ecore_x}"
 963           AC_DEFINE(ECORE_XCB_XPRINT, 1, [Build support for XCB xprint]) ],
 964         [ have_ecore_x_xcb_xprint="no" ])
 965     else
 966       have_ecore_x_xcb_xprint="no"
 967       AC_MSG_NOTICE("xprint extension explicitly disabled")
 968     fi
 969
 970     if test "x$want_ecore_x_xtest" != "xno"; then
 971       PKG_CHECK_MODULES(XCB_XTEST, xcb-xtest,
 972         [ have_ecore_x_xcb_xtest="yes"
 973           requirements_ecore_x="xcb-xtest ${requirements_ecore_x}"
 974           AC_DEFINE(ECORE_XCB_XTEST, 1, [Build support for XCB xtest]) ],
 975         [ have_ecore_x_xcb_xtest="no" ])
 976     else
 977       have_ecore_x_xcb_xtest="no"
 978       AC_MSG_NOTICE("xtest extension explicitly disabled")
 979     fi
 980
 981 # input extension disabled currently in xcb as xcb-input has some issues
 982     want_ecore_x_input="no"
 983     if test "x$want_ecore_x_input" != "xno"; then
 984       PKG_CHECK_MODULES(XCB_XINPUT, xcb-xinput,
 985         [ have_ecore_x_xcb_xinput="yes"
 986           requirements_ecore_x="xcb-xinput ${requirements_ecore_x}"
 987           AC_DEFINE(ECORE_XCB_XINPUT, 1, [Build support for XCB xinput]) ],
 988         [ have_ecore_x_xcb_xinput="no" ])
 989     else
 990       have_ecore_x_xcb_xinput="no"
 991       AC_MSG_NOTICE("xinput extension explicitly disabled")
 992     fi
 993
 994     if test "x$want_ecore_x_cursor" != "xno"; then
 995       PKG_CHECK_MODULES(XCB_CURSOR, xcb-render xcb-renderutil,
 996         [ have_ecore_x_xcb_cursor="yes"
 997           requirements_ecore_x="xcb-render xcb-renderutil ${requirements_ecore_x}"
 998           AC_DEFINE(ECORE_XCB_CURSOR, 1, [Build support for XCB cursor]) ],
 999         [ have_ecore_x_xcb_cursor="no" ])
1000     else
1001       have_ecore_x_xcb_cursor="no"
1002       AC_MSG_NOTICE("cursor extension explicitly disabled")
1003     fi
1004
1005 #    if test "x$want_ecore_x_dri" != "xno"; then
1006 #      PKG_CHECK_MODULES(XCB_DRI, xcb-dri2,
1007 #        [ have_ecore_x_xcb_dri="yes"
1008 #          requirements_ecore_x="xcb-dri2 ${requirements_ecore_x}"
1009 #          AC_DEFINE(ECORE_XCB_DRI, 1, [Build support for XCB dri/dri2]) ],
1010 #        [ have_ecore_x_xcb_dri="no" ])
1011 #    else
1012 #      have_ecore_x_xcb_dri="no"
1013 #      AC_MSG_NOTICE("dri extension explicitly disabled")
1014 #    fi
1015
1016     AC_DEFINE(HAVE_ECORE_X_XCB, 1, [Defined to 1 if XCB is enabled.])
1017
1018     x_cflags=$ECORE_XCB_CFLAGS
1019     x_libs=$ECORE_XCB_LIBS
1020     have_x="yes"
1021
1022     have_ecore_x_xcb_define="-DHAVE_ECORE_X_XCB"
1023     AC_SUBST(have_ecore_x_xcb_define)
1024   fi
1025 fi
1026
1027 if ! test "x$have_ecore_x_xcb" = "xyes" ; then
1028   AC_PATH_XTRA
1029   AC_CHECK_HEADER(X11/X.h,
1030     [
1031      if test "x$want_evas_simple_x11" = "xyes"; then
1032        x_libs="${x_libs} -lX11 -lXext"
1033      else
1034        x_dir=${x_dir:-/usr/X11R6}
1035        x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
1036        x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
1037      fi
1038      have_ecore_x_xlib="yes"
1039     ]
1040   )
1041
1042   if test "x$have_ecore_x_xlib" = "xyes"; then
1043     Xcursor_libs=""
1044     Xcursor_cflags=""
1045     use_Xcursor="no"
1046     PCFLAGS=$CFLAGS
1047     CFLAGS="$x_cflags $x_includes"
1048
1049     if test "x$want_ecore_x_cursor" = "xyes"; then
1050       AC_CHECK_HEADER(X11/Xcursor/Xcursor.h,
1051         [
1052           AC_CHECK_LIB(Xcursor, XcursorImageLoadCursor,
1053             [
1054               AC_DEFINE(ECORE_XCURSOR, 1, [Build support for Xcursor])
1055               Xcursor_cflags=""
1056               Xcursor_libs="-lXcursor"
1057               use_Xcursor="yes"
1058             ], [
1059               Xcursor_cflags=""
1060               Xcursor_libs=""
1061               use_Xcursor="no"
1062             ], [
1063               $x_libs -lXrender
1064             ]
1065           )
1066         ], [
1067           Xcursor_cflags=""
1068           Xcursor_libs=""
1069           use_Xcursor="no"
1070         ], [
1071           #include <X11/Xlib.h>
1072         ]
1073       )
1074       CFLAGS=$PCFLAGS
1075     else
1076       Xcursor_cflags=""
1077       Xcursor_libs=""
1078       use_Xcursor="no"
1079       AC_MSG_NOTICE("Xcursor explicitly disabled")
1080     fi
1081
1082     AC_SUBST(Xcursor_cflags)
1083     AC_SUBST(Xcursor_libs)
1084
1085     ECORE_CHECK_X_EXTENSION([Xkb], [XKB.h], [X11], [XkbSetDetectableAutoRepeat], [$want_ecore_x_xkb])
1086     ECORE_CHECK_X_EXTENSION([Xcomposite], [Xcomposite.h], [Xcomposite], [XCompositeQueryExtension], [$want_ecore_x_composite])
1087     ECORE_CHECK_X_EXTENSION([Xdamage], [Xdamage.h], [Xdamage], [XDamageSubtract], [$want_ecore_x_damage])
1088     ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xdpms], [DPMSQueryExtension], [$want_ecore_x_dpms])
1089     if test "x$use_xdpms" = "xno" ; then
1090       ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xext], [DPMSQueryExtension], [$want_ecore_x_dpms])
1091     fi
1092     ECORE_CHECK_X_EXTENSION([Xfixes], [Xfixes.h], [Xfixes], [XFixesExpandRegion], [$want_ecore_x_xfixes])
1093     ECORE_CHECK_X_EXTENSION([Xinerama], [Xinerama.h], [Xinerama], [XineramaQueryScreens], [$want_ecore_x_xinerama])
1094     ECORE_CHECK_X_EXTENSION([Xprint], [Print.h], [Xp], [XpQueryScreens], [$want_ecore_x_xprint])
1095     ECORE_CHECK_X_EXTENSION([Xrandr], [Xrandr.h], [Xrandr], [XRRGetScreenResourcesCurrent], [$want_ecore_x_randr])
1096     ECORE_CHECK_X_EXTENSION([Xrender], [Xrender.h], [Xrender], [XRenderFindVisualFormat], [$want_ecore_x_render])
1097     ECORE_CHECK_X_EXTENSION([Xtest], [XTest.h], [Xtst], [XTestFakeKeyEvent], [$want_ecore_x_xtest])
1098     ECORE_CHECK_X_EXTENSION([Xss], [scrnsaver.h], [Xss], [XScreenSaverSelectInput], [$want_ecore_x_screensaver])
1099     ECORE_CHECK_X_EXTENSION([Xi2], [XInput2.h], [Xi], [XIQueryDevice], [$want_ecore_x_input])
1100
1101     ecore_x_libs_private="${Xcursor_libs} ${XKB_LIBS} ${XCOMPOSITE_LIBS} ${XDAMAGE_LIBS} ${XDPMS_LIBS} ${XFIXES_LIBS} ${XINERAMA_LIBS} ${XPRINT_LIBS} ${XRANDR_LIBS} ${XRENDER_LIBS} ${XTEST_LIBS} ${XSS_LIBS} ${XI2_LIBS}"
1102
1103     AC_DEFINE(HAVE_ECORE_X_XLIB, 1, [Defined to 1 if Xlib is enabled.])
1104     have_x="yes"
1105
1106     have_ecore_x_xlib="yes"
1107   fi
1108 fi
1109
1110 AC_SUBST(x_cflags)
1111 AC_SUBST(x_includes)
1112 AC_SUBST(x_libs)
1113 AC_SUBST(ecore_x_libs_private)
1114
1115 AM_CONDITIONAL(BUILD_ECORE_X_XLIB, test $have_ecore_x_xlib = yes)
1116 AM_CONDITIONAL(BUILD_ECORE_X_XCB, test $have_ecore_x_xcb = yes)
1117
1118
1119 # Evas library (ecore_config, ecore_input_evas, ecore_imf_evas and ecore_evas)
1120
1121 PKG_CHECK_MODULES([EVAS], [evas >= 1.0.0],
1122    [have_evas="yes"],
1123    [have_evas="no"])
1124
1125
1126 ### Checks for header files
1127
1128 AC_CHECK_HEADERS([sys/select.h sys/prctl.h])
1129
1130 EFL_CHECK_PATH_MAX
1131
1132 AC_HEADER_SYS_WAIT
1133 AC_SYS_LARGEFILE
1134
1135 have_addrinfo="no"
1136 case "$host_os" in
1137    mingw* | cegcc*)
1138       AC_DEFINE(HAVE_DLFCN_H, 1, [Define to 1 if you have the <dlfcn.h> header file.])
1139       AC_DEFINE(HAVE_SYS_MMAN_H, 1, [Define to 1 if you have the <sys/mman.h> header file.])
1140       AC_DEFINE(HAVE_SYS_TIME_H, 1, [Define to 1 if you have the <sys/time.h> header file.])
1141       have_addrinfo="yes"
1142       ;;
1143    *)
1144       AC_CHECK_HEADERS([dlfcn.h features.h langinfo.h locale.h sys/time.h sys/mman.h signal.h sys/resource.h])
1145       ;;
1146 esac
1147
1148 # ecore_con
1149
1150 AC_CHECK_HEADERS([arpa/inet.h arpa/nameser.h netinet/tcp.h netinet/in.h sys/socket.h sys/un.h ws2tcpip.h netdb.h])
1151
1152 if test "x${ac_cv_header_netdb_h}" = "xyes" ; then
1153    have_addrinfo="yes"
1154 fi
1155
1156 # Framebuffer (ecore_fb)
1157 have_fb="no"
1158 AC_CHECK_HEADER([linux/fb.h],
1159    [AC_CHECK_HEADER([linux/input.h], [have_fb="yes"])])
1160
1161 # Cocoa header files (ecore_cocoa)
1162
1163 cocoa_ldflags=""
1164 have_cocoa="no"
1165 m4_ifdef([AC_PROG_OBJC], [
1166     if test "x${have_gnu_objc}" = "xyes" ; then
1167        AC_LANG_PUSH([Objective C])
1168        LIBS_save="$LIBS"
1169        LIBS="$LIBS -framework Cocoa"
1170        AC_LINK_IFELSE(
1171           [AC_LANG_PROGRAM(
1172               [[
1173 #include <Cocoa/Cocoa.h>
1174               ]],
1175               [[
1176 NSWindow *window;
1177 window = [[NSWindow alloc]
1178            initWithContentRect:NSMakeRect(0, 0, 1, 1)
1179            styleMask:(NSTitledWindowMask)
1180            backing:NSBackingStoreBuffered
1181            defer:NO
1182            screen:nil
1183          ];
1184               ]])],
1185           [
1186            have_cocoa="yes"
1187            cocoa_ldflags="-framework Cocoa"
1188           ],
1189           [have_cocoa="no"])
1190        LIBS="$LIBS_save"
1191        AC_MSG_CHECKING([whether Cocoa framework is supported])
1192        AC_MSG_RESULT([${have_cocoa}])
1193        AC_LANG_POP([Objective C])
1194     fi
1195 ])
1196 AC_SUBST(cocoa_ldflags)
1197
1198 want_epoll=yes
1199 AC_ARG_ENABLE(epoll,
1200   AC_HELP_STRING([--enable-epoll], [enable or disable epoll support]),
1201   [want_epoll=$enableval])
1202
1203 if test "x${want_epoll}" = "xyes" ; then
1204   # check for epoll support
1205   AC_CHECK_HEADERS([sys/epoll.h])
1206 fi
1207
1208 # timerfd_create
1209 AC_CHECK_HEADERS([sys/timerfd.h])
1210 AC_CHECK_FUNCS(timerfd_create)
1211
1212 # thread support
1213
1214 EFL_CHECK_THREADS(
1215    [
1216     if test "x${_efl_have_posix_threads}" = "xyes" ; then
1217        have_threads="POSIX"
1218     else
1219        if test "x${_efl_have_win32_threads}" = "xyes" ; then
1220           have_threads="Win32"
1221        else
1222           have_threads="no"
1223        fi
1224     fi
1225    ],
1226    [have_threads="no"])
1227
1228 ### enable thread safety if we have threads, unless specifically asked not to
1229 if test "x${have_threads}" = "xno"
1230 then
1231   want_thread_safety="no"
1232 else
1233   want_thread_safety="no"  # to be changed to yes when ready
1234   AC_ARG_ENABLE(thread-safety,
1235     AC_HELP_STRING([--enable-thread-safety], [enable or disable thread safety]),
1236     [want_thread_safety=$enableval])
1237 fi
1238
1239 if test "x${want_thread_safety}" = "xyes"
1240 then
1241    AC_DEFINE([HAVE_THREAD_SAFETY], [1], [Define to enable thread safety])
1242 fi
1243
1244 ### Checks for types
1245 AC_CHECK_SIZEOF(int, 4)
1246 AC_CHECK_SIZEOF(long, 4)
1247
1248
1249 ### Checks for structures
1250
1251
1252 ### Checks for compiler characteristics
1253 AM_PROG_CC_STDC
1254 AC_C_CONST
1255 AC_C_BIGENDIAN
1256 AC_HEADER_STDC
1257 AC_C___ATTRIBUTE__
1258
1259 WIN32_CPPFLAGS=""
1260 WIN32_CFLAGS=""
1261 case "$host_os" in
1262    mingw32ce*)
1263       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
1264       ;;
1265    cegcc*)
1266       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
1267       WIN32_CFLAGS="-mwin32"
1268       ;;
1269    mingw*)
1270       WIN32_CPPFLAGS="-D_WIN32_WINNT=0x0501"
1271       ;;
1272 esac
1273 AC_SUBST(WIN32_CPPFLAGS)
1274 AC_SUBST(WIN32_CFLAGS)
1275
1276
1277 ### Checks for linker characteristics
1278
1279 # use --enable-auto-import on Windows
1280
1281 lt_enable_auto_import=""
1282 case "$host_os" in
1283    mingw* | cegcc*)
1284       lt_enable_auto_import="-Wl,--enable-auto-import"
1285       ;;
1286 esac
1287 AC_SUBST(lt_enable_auto_import)
1288
1289 ### Checks for library functions
1290 AC_ISC_POSIX
1291 AC_FUNC_ALLOCA
1292 AC_CHECK_FUNCS([gettimeofday strlcpy execvp])
1293
1294 AC_COMPILE_IFELSE(
1295    [AC_LANG_PROGRAM(
1296        [[
1297 #include <math.h>
1298        ]],
1299        [[
1300 int i = isfinite(0);
1301        ]])],
1302    [
1303     AC_DEFINE(HAVE_ISFINITE, 1, [Define to 1 if you have `isfinite', as a function or macro.])
1304     have_isfinite="yes"
1305    ],
1306    [have_isfinite="no"])
1307
1308 AC_MSG_CHECKING([for isfinite])
1309 AC_MSG_RESULT([${have_isfinite}])
1310
1311 have_atfile_source=auto
1312 AC_ARG_ENABLE([atfile-source],
1313    [AC_HELP_STRING([--disable-atfile-source],
1314        [disable use of atfile source functions as openat and mkdirat @<:@default=detect@:>@])],
1315    [
1316     if test "x${enableval}" = "xyes" ; then
1317        have_atfile_source="yes"
1318     else
1319        have_atfile_source="no"
1320     fi],
1321    [have_atfile_source=auto])
1322
1323 if ! test "x${have_atfile_source}" = "xno" ; then
1324    AC_CHECK_FUNCS(mkdirat,
1325       [
1326        have_atfile_source="yes"
1327        AC_DEFINE(HAVE_ATFILE_SOURCE, 1, [mkdirat exists])
1328       ],
1329       [
1330        if test "x${have_atfile_source}" = "xyes" ; then
1331           AC_MSG_ERROR([required atfile-source but no mkdirat()])
1332        fi
1333        have_atfile_source="no"
1334       ])
1335 fi
1336
1337 ### Checks for optionnal feature
1338 AC_CHECK_FUNC([mallinfo],
1339    [
1340     have_mallinfo="yes"
1341     AC_DEFINE(HAVE_MALLINFO, 1, [Gather memory statistic])
1342    ],
1343    [have_mallinfo="no"])
1344
1345 ### Ecore modules
1346
1347 ## Core modules
1348
1349 # ecore_con
1350 ECORE_CHECK_MODULE([con], [${want_ecore_con}], [Con], [${have_addrinfo}])
1351
1352 have_curl="no"
1353 have_gnutls="no"
1354 have_openssl="no"
1355 have_cares="no"
1356 want_ipv6="yes"
1357 have_ipv6="no"
1358
1359 AC_ARG_ENABLE([ipv6],
1360    [AC_HELP_STRING([--disable-ipv6],
1361        [disable ipv6 functionality @<:@default=detect@:>@])],
1362    [
1363     if test "x${enableval}" = "xyes" ; then
1364        want_ipv6="yes"
1365     else
1366        want_ipv6="no"
1367     fi],
1368    [want_ipv6="auto"])
1369
1370 if test "x${have_ecore_con}" = "xyes" ; then
1371
1372    # Verify IPV6 availability in headers
1373    if test "x${want_ipv6}" != "xno" ; then
1374       AC_CHECK_TYPES([struct ipv6_mreq],
1375          [have_ipv6="yes"],
1376          [have_ipv6="no"],
1377          [[
1378 #ifdef HAVE_NETINET_IN_H
1379 # include <netinet/in.h>
1380 #endif
1381 #ifdef HAVE_WS2TCPIP_H
1382 # include <ws2tcpip.h>
1383 #endif
1384          ]])
1385    fi
1386
1387    if test "x${have_ipv6}" = "xyes" ; then
1388       AC_DEFINE(HAVE_IPV6, 1, [Define if IPV6 is supported])
1389    fi
1390
1391    ECORE_CHECK_CURL([${want_curl}],
1392       [
1393        have_curl="yes"
1394        requirements_ecore_con="libcurl ${requirements_ecore_con}"
1395       ],
1396       [have_curl="no"])
1397
1398    ECORE_CHECK_GNUTLS([${want_gnutls}],
1399       [have_gnutls="yes"],
1400       [have_gnutls="no"])
1401
1402    ECORE_CHECK_OPENSSL([${want_openssl}],
1403       [have_openssl="yes"],
1404       [have_openssl="no"])
1405
1406    if test "x${have_gnutls}" = "xyes" ; then
1407       requirements_ecore_con="gnutls ${requirements_ecore_con}"
1408       # no need to add it to req_ecore_ipc, since they
1409       # depends on ecore_con anyway.
1410    else
1411       if test "x${have_openssl}" = "xyes" ; then
1412          requirements_ecore_con="openssl ${requirements_ecore_con}"
1413          # no need to add it to req_ecore_ipc, since they
1414          # depends on ecore_con anyway.
1415       fi
1416    fi
1417
1418    ECORE_CHECK_CARES([${want_cares}],
1419       [
1420        have_cares="yes"
1421        requirements_ecore_con="libcares ${requirements_ecore_con}"
1422       ],
1423       [have_cares="no"])
1424
1425 fi
1426
1427 AM_CONDITIONAL([HAVE_CARES], [test "x${have_cares}" = "xyes"])
1428
1429 # ecore_ipc
1430 ECORE_CHECK_MODULE([ipc], [${want_ecore_ipc}], [Ipc], [${have_ecore_con}],
1431    [requirements_ecore_ipc="ecore-con >= 1.0.0 ${requirements_ecore_ipc}"])
1432
1433 # ecore_file
1434 ECORE_CHECK_MODULE([file], [${want_ecore_file}], [File])
1435
1436 have_poll="no"
1437 have_inotify="no"
1438 have_notify_win32="no"
1439 if test "x${have_ecore_file}" = "xyes" ; then
1440    ECORE_CHECK_POLL([${want_poll}], [have_poll="yes"], [have_poll="no"])
1441    ECORE_CHECK_INOTIFY([${want_inotify}], [have_inotify="yes"], [have_inotify="no"])
1442    ECORE_CHECK_NOTIFY_WIN32([${want_notify_win32}], [have_notify_win32="yes"], [have_notify_win32="no"])
1443
1444    if test "x${have_ecore_con}" = "xyes" ; then
1445       requirements_ecore_file="ecore-con >= 1.0.0 ${requirements_ecore_file}"
1446    else
1447       ECORE_CHECK_CURL([${want_curl}],
1448          [
1449           have_curl="yes"
1450           requirements_ecore_file="libcurl ${requirements_ecore_file}"
1451          ],
1452          [have_curl="no"])
1453    fi
1454
1455 fi
1456
1457 # ecore_config
1458 #ecore_config_deps="no"
1459 #if test "x${have_eet}" = "xyes" -a "x${have_evas}"  -a "x${have_ecore_ipc}" ; then
1460 #   ecore_config_deps="yes"
1461 #fi
1462
1463 #ECORE_CHECK_MODULE([config], [${want_ecore_config}], [Config], [${ecore_config_deps}],
1464 #   [requirements_ecore_config="ecore-ipc >= 1.0.0 evas >= 1.0.0 eet >= 1.4.0 ${requirements_ecore_config}"])
1465
1466 AM_CONDITIONAL(BUILD_ECORE_CONFIG, false)
1467
1468 # ecore_imf
1469
1470 ECORE_CHECK_MODULE([imf], [${want_ecore_imf}], [Imf])
1471
1472 # ecore_imf_evas
1473
1474 ecore_imf_evas_deps="no"
1475 if test "x${have_ecore_imf}" = "xyes" -a "x${have_evas}" = "xyes" ; then
1476    ecore_imf_evas_deps="yes"
1477 fi
1478
1479 ECORE_CHECK_MODULE([imf-evas], [${want_ecore_imf}], [Imf_Evas], [${ecore_imf_evas_deps}],
1480    [requirements_ecore_imf_evas="ecore-imf >= 1.0.0 evas >= 1.0.0 ${requirements_ecore_imf_evas}"])
1481
1482 # ecore_input{_evas}
1483 ECORE_CHECK_MODULE([input], [${want_ecore_input}], [Input])
1484 ECORE_CHECK_MODULE([input-evas], [${want_ecore_input}], [Input_Evas], [${have_evas}],
1485    [requirements_ecore_input_evas="ecore-input >= 1.0.0 evas >= 1.0.0 ${requirements_ecore_input}"])
1486
1487 # ecore_imf_xim
1488 AM_CONDITIONAL(BUILD_ECORE_IMF_XIM, false)
1489 ecore_imf_xim_deps="no"
1490 echo "have_ecore_x_xlib: ${have_ecore_x_xlib}"
1491 if test    "x${have_ecore_imf}" = "xyes" \
1492         -a "x${have_ecore_x_xlib}" = "xyes" \
1493         -a "x${have_ecore_input}" = "xyes" ; then
1494    ecore_imf_xim_deps="yes"
1495    AC_DEFINE(BUILD_ECORE_IMF_XIM, 1, [Ecore Imf XIM Support])
1496 fi
1497
1498 ECORE_CHECK_MODULE([imf-xim], [${want_ecore_imf}], [Imf_XIM], [${ecore_imf_xim_deps}],
1499    [requirements_ecore_imf_xim="ecore-imf >= 1.0.0 ecore-x >= 1.0.0 ecore-input >= 1.0.0 ${requirements_ecore_imf_xim}"])
1500
1501 ## Graphic systems
1502
1503 # ecore_x{cb}
1504
1505 ecore_x_deps="no"
1506 if test "x${have_x}" = "xyes" -a \
1507         "x${have_ecore_input}" = "xyes" ; then
1508    ecore_x_deps="yes"
1509 fi
1510
1511 ECORE_CHECK_MODULE([x], [${want_ecore_x}], [X], [${ecore_x_deps}],
1512   [
1513    ecore_x_libs="$ecore_x_libs $x_libs"
1514    requirements_ecore_x="ecore-input >= 1.0.0 ${requirements_ecore_x}"
1515   ])
1516
1517 # ecore_win32
1518
1519 ECORE_CHECK_MODULE([win32], [${want_ecore_win32}], [Win32], [${have_ecore_input}],
1520    [
1521     ecore_win32_libs="-lole32 -lgdi32"
1522     requirements_ecore_win32="ecore-input >= 1.0.0 ${requirements_ecore_win32}"
1523    ])
1524 AC_SUBST(ecore_win32_libs)
1525
1526 # ecore_cocoa
1527
1528 ecore_cocoa_deps="no"
1529 if test "x${have_ecore_input}" = "xyes" -a "x${have_cocoa}" = "xyes" ; then
1530    ecore_cocoa_deps="yes"
1531 fi
1532
1533 ECORE_CHECK_MODULE([cocoa], [${want_ecore_cocoa}], [Cocoa], [${ecore_cocoa_deps}],
1534    [requirements_ecore_cocoa="ecore-input >= 1.0.0 ${requirements_ecore_cocoa}"])
1535
1536 # ecore_sdl
1537
1538 ecore_sdl_deps="no"
1539 if test "x${have_sdl}" = "xyes" -a "x${have_ecore_input}" = "xyes" ; then
1540    ecore_sdl_deps="yes"
1541 fi
1542
1543 ECORE_CHECK_MODULE([sdl], [${want_ecore_sdl}], [Sdl], [${ecore_sdl_deps}],
1544    [requirements_ecore_sdl="ecore-input >= 1.0.0 ${requirements_ecore_sdl}"])
1545
1546 # ecore_fb
1547 ECORE_CHECK_MODULE([fb], [${want_ecore_fb}], [FB], [$have_fb])
1548
1549 if test "x${have_ecore_fb}" = "xyes" ; then
1550    ECORE_CHECK_TSLIB([${want_tslib}],
1551       [
1552        have_tslib="yes"
1553        requirements_ecore_fb="${_tslib_requirement} ${requirements_ecore_fb}"
1554       ],
1555       [have_tslib="no"])
1556 fi
1557
1558 # ecore_directfb
1559
1560 ECORE_CHECK_MODULE([directfb], [${want_ecore_directfb}], [DirectFB], [${have_directfb}],
1561    [requirements_ecore_directfb="directfb ${requirements_ecore_directfb}"])
1562
1563 # ecore_wince
1564
1565 ECORE_CHECK_MODULE([wince], [${want_ecore_wince}], [WinCE], [${have_ecore_input}],
1566    [requirements_ecore_win32="ecore-input >= 1.0.0 ${requirements_ecore_win32}"])
1567
1568 ## Ecore Evas
1569
1570 # ecore_evas
1571
1572 ecore_evas_deps="no"
1573 if test "x${have_evas}" = "xyes" -a "x${have_ecore_input}" = "xyes" -a "x${have_ecore_input_evas}" = "xyes" ; then
1574    ecore_evas_deps="yes"
1575 fi
1576
1577 ECORE_CHECK_MODULE([evas], [${want_ecore_evas}], [Evas], [${ecore_evas_deps}],
1578   [requirements_ecore_evas="ecore-input >= 1.0.0 ecore-input-evas >= 1.0.0 evas >= 1.0.0 ${requirements_ecore_evas}"])
1579
1580 # ecore_evas_buffer
1581
1582 ECORE_EVAS_CHECK_MODULE([software-buffer],
1583    [${want_ecore_evas_software_buffer}],
1584    [Software Buffer],
1585    [yes])
1586
1587 # ecore_evas_x11
1588
1589 # ecore_evas_software_x11
1590
1591 ECORE_EVAS_CHECK_MODULE([software-x11],
1592    [${want_ecore_evas_software_x11}],
1593    [Software X11],
1594    [${have_ecore_x}])
1595
1596 have_ecore_evas_software_xlib="no"
1597 have_ecore_evas_software_xcb="no"
1598 if test "x$have_ecore_evas_software_x11" = "xyes" ; then
1599    have_ecore_evas_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
1600    if test "x${have_ecore_evas_software_xlib}" = "xstatic"; then
1601       have_ecore_evas_software_xlib="yes"
1602    fi
1603    if test "x${have_ecore_evas_software_xlib}" = "xyes" -a "x${have_ecore_x_xlib}" = "xyes" ; then
1604       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
1605    fi
1606    have_ecore_evas_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
1607    if test "x$have_ecore_evas_software_xcb" = "xstatic"; then
1608       have_ecore_evas_software_xcb="yes"
1609    fi
1610    if test "x$have_ecore_evas_software_xcb" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1611       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
1612    fi
1613 fi
1614
1615 # ecore_evas_opengl_x11
1616
1617 ECORE_EVAS_CHECK_MODULE([opengl-x11],
1618    [${want_ecore_evas_opengl_x11}],
1619    [OpenGL Xlib],
1620    [${have_ecore_x}])
1621
1622 have_ecore_evas_opengl_xlib="no"
1623 have_ecore_evas_opengl_xcb="no"
1624 if test "x${have_ecore_evas_opengl_x11}" = "xyes" -o "x${have_ecore_evas_opengl_x11}" = "xstatic" ; then
1625    have_ecore_evas_opengl_xlib=`${PKG_CONFIG} --variable=Xlib evas-opengl-x11`
1626    if test "x${have_ecore_evas_opengl_xlib}" = "xyes" ; then
1627       AC_DEFINE(BUILD_ECORE_EVAS_OPENGL_XLIB, 1, [OpenGL Xlib rendering backend])
1628    fi
1629
1630 # opengl does not work with xcb (yet)
1631    have_ecore_evas_opengl_xcb=`${PKG_CONFIG} --variable=XCB evas-opengl-x11`
1632    if test "x${have_ecore_evas_opengl_xcb}" = "xstatic"; then
1633       have_ecore_evas_opengl_xcb="yes"
1634    fi
1635    if test "x${have_ecore_evas_opengl_xcb}" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1636       PKG_CHECK_MODULES(XCB_X11, x11-xcb,
1637         [ have_ecore_x_opengl_xcb="yes"
1638           requirements_ecore_x="x11-xcb ${requirements_ecore_x}"
1639           AC_DEFINE(BUILD_ECORE_X_OPENGL_XCB, 1, [Build support for XCB-based OpenGL])
1640           AC_DEFINE(BUILD_ECORE_EVAS_OPENGL_XCB, 1, [OpenGL XCB rendering backend])
1641         ],
1642         [ have_ecore_x_opengl_xcb="no" ])
1643     else
1644       have_ecore_x_opengl_xcb="no"
1645       AC_MSG_NOTICE("XCB-based OpenGL explicitly disabled")
1646     fi
1647 fi
1648
1649 # ecore_evas_software_x11 16 bits
1650
1651 ECORE_EVAS_CHECK_MODULE([software-16-x11],
1652    [${want_ecore_evas_software_16_x11}],
1653    [Software Xlib 16 bits],
1654    [${have_ecore_x_xlib}])
1655
1656 ECORE_EVAS_CHECK_MODULE([software-8-x11],
1657     [$want_ecore_evas_software_8_x11],
1658     [Software 8bit X11],
1659     $have_ecore_x_xcb)
1660
1661
1662 if test "x$have_ecore_evas_software_x11" = "xyes" -o \
1663         "x$have_ecore_evas_opengl_x11" = "xyes" -o \
1664         "x$have_ecore_evas_software_8_x11" = "xyes" -o \
1665         "x$have_ecore_evas_software_16_x11" = "xyes" -o \
1666         "x$have_ecore_evas_software_xcb" = "xyes"; then
1667    AC_DEFINE(BUILD_ECORE_EVAS_X11, 1, [Support for X Window Engines in Ecore_Evas])
1668    requirements_ecore_evas="ecore-x >= 1.0.0 ${requirements_ecore_evas}"
1669 fi
1670
1671 # ecore_evas_win32
1672
1673 ECORE_EVAS_CHECK_MODULE([software-gdi],
1674    [${want_ecore_evas_software_gdi}],
1675    [Software GDI],
1676    [${have_ecore_win32}])
1677
1678 ECORE_EVAS_CHECK_MODULE([software-ddraw],
1679    [${want_ecore_evas_software_ddraw}],
1680    [Software DirectDraw],
1681    [${have_ecore_win32}])
1682
1683 ECORE_EVAS_CHECK_MODULE([direct3d],
1684    [${want_ecore_evas_direct3d}],
1685    [Direct3d],
1686    [${have_ecore_win32}])
1687
1688 ECORE_EVAS_CHECK_MODULE([opengl-glew],
1689    [${want_ecore_evas_opengl_glew}],
1690    [Glew OpenGL],
1691    [${have_ecore_win32}])
1692
1693 ECORE_EVAS_CHECK_MODULE([software-16-ddraw],
1694    [${want_ecore_evas_software_16_ddraw}],
1695    [16 bpp Software DirectDraw],
1696    [${have_ecore_win32}])
1697
1698 if test "x${have_ecore_evas_software_gdi}" = "xyes" -o \
1699         "x${have_ecore_evas_software_ddraw}" = "xyes" -o \
1700         "x${have_ecore_evas_direct3d}" = "xyes" -o \
1701         "x${have_ecore_evas_opengl_glew}" = "xyes" -o \
1702         "x${have_ecore_evas_software_16_ddraw}" = "xyes" ; then
1703    AC_DEFINE(BUILD_ECORE_EVAS_WIN32, 1, [Support for Win32 Engine in Ecore_Evas])
1704    requirements_ecore_evas="ecore-win32 >= 1.0.0 ${requirements_ecore_evas}"
1705 fi
1706
1707 # ecore_evas_software_sdl
1708
1709 ECORE_EVAS_CHECK_MODULE([software-sdl],
1710    [${want_ecore_evas_software_sdl}],
1711    [Software SDL],
1712    [${have_ecore_sdl}],
1713    [requirements_ecore_evas="ecore-sdl >= 1.0.0 ${requirements_ecore_evas}"])
1714
1715 # ecore_evas_gl_sdl
1716
1717 ECORE_EVAS_CHECK_MODULE([opengl-sdl],
1718    [${want_ecore_evas_gl_sdl}],
1719    [OpenGL SDL],
1720    [${have_ecore_sdl}],
1721    [requirements_ecore_evas="ecore-sdl >= 1.0.0 ${requirements_ecore_evas}"])
1722
1723 # ecore_evas_cocoa
1724
1725 ECORE_EVAS_CHECK_MODULE([opengl-cocoa],
1726    [${want_ecore_evas_gl_cocoa}],
1727    [OpenGL Cocoa],
1728    [${have_ecore_cocoa}],
1729    [requirements_ecore_evas="ecore-cocoa >= 1.0.0 ${requirements_ecore_evas}"])
1730
1731 # ecore_evas_directfb
1732
1733 ECORE_EVAS_CHECK_MODULE([directfb],
1734    [${want_ecore_evas_directfb}],
1735    [DirectFB],
1736    [${have_ecore_directfb}],
1737    [requirements_ecore_evas="ecore-directfb >= 1.0.0 ${requirements_ecore_evas}"])
1738
1739 # ecore_evas_fb
1740
1741 ECORE_EVAS_CHECK_MODULE([fb],
1742    [${want_ecore_evas_fb}],
1743    [Linux Framebuffer],
1744    [${have_ecore_fb}],
1745    [requirements_ecore_evas="ecore-fb >= 1.0.0 ${requirements_ecore_evas}"])
1746
1747 # ecore_evas_wince
1748
1749 ECORE_EVAS_CHECK_MODULE([software-16-wince],
1750    [${want_ecore_evas_software_16_wince}],
1751    [16 bpp Software Windows CE],
1752    [${have_ecore_wince}],
1753    [requirements_ecore_evas="ecore-wince >= 1.0.0 ${requirements_ecore_evas}"])
1754
1755 # ecore_evas_ews
1756
1757 ECORE_EVAS_CHECK_MODULE_FULL([ews], [software-buffer],
1758    [${want_ecore_evas_ews}],
1759    [Ecore Evas Single Process Windowing System],
1760    [yes], [])
1761
1762 ### install and build examples
1763
1764 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
1765 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
1766
1767 ### requirements
1768
1769 AC_SUBST(requirements_ecore)
1770 AC_SUBST(requirements_ecore_con)
1771 #AC_SUBST(requirements_ecore_config)
1772 AC_SUBST(requirements_ecore_directfb)
1773 AC_SUBST(requirements_ecore_evas)
1774 AC_SUBST(requirements_ecore_fb)
1775 AC_SUBST(requirements_ecore_file)
1776 AC_SUBST(requirements_ecore_imf)
1777 AC_SUBST(requirements_ecore_imf_evas)
1778 AC_SUBST(requirements_ecore_input)
1779 AC_SUBST(requirements_ecore_input_evas)
1780 AC_SUBST(requirements_ecore_ipc)
1781 AC_SUBST(requirements_ecore_cocoa)
1782 AC_SUBST(requirements_ecore_sdl)
1783 AC_SUBST(requirements_ecore_x)
1784 AC_SUBST(requirements_ecore_win32)
1785 AC_SUBST(requirements_ecore_wince)
1786 AC_SUBST(requirements_ecore_imf_xim)
1787
1788 AC_CONFIG_FILES([
1789 Makefile
1790 ecore-con.pc
1791 ecore-config.pc
1792 ecore-directfb.pc
1793 ecore-evas.pc
1794 ecore-fb.pc
1795 ecore-file.pc
1796 ecore-imf.pc
1797 ecore-imf-evas.pc
1798 ecore-ipc.pc
1799 ecore-x.pc
1800 ecore-input.pc
1801 ecore-input-evas.pc
1802 ecore-win32.pc
1803 ecore-sdl.pc
1804 ecore-cocoa.pc
1805 ecore-wince.pc
1806 ecore.pc
1807 doc/ecore.dox
1808 doc/Makefile
1809 doc/Doxyfile
1810 src/Makefile
1811 src/util/Makefile
1812 src/bin/Makefile
1813 src/lib/Makefile
1814 src/lib/ecore/Makefile
1815 src/lib/ecore_con/Makefile
1816 src/lib/ecore_config/Makefile
1817 src/lib/ecore_directfb/Makefile
1818 src/lib/ecore_evas/Makefile
1819 src/lib/ecore_fb/Makefile
1820 src/lib/ecore_file/Makefile
1821 src/lib/ecore_cocoa/Makefile
1822 src/lib/ecore_sdl/Makefile
1823 src/lib/ecore_imf/Makefile
1824 src/lib/ecore_imf_evas/Makefile
1825 src/lib/ecore_input/Makefile
1826 src/lib/ecore_input_evas/Makefile
1827 src/lib/ecore_ipc/Makefile
1828 src/lib/ecore_win32/Makefile
1829 src/lib/ecore_wince/Makefile
1830 src/lib/ecore_x/Makefile
1831 src/lib/ecore_x/xlib/Makefile
1832 src/lib/ecore_x/xcb/Makefile
1833 src/examples/Makefile
1834 src/tests/Makefile
1835 src/modules/Makefile
1836 src/modules/immodules/Makefile
1837 src/modules/immodules/xim/Makefile
1838 README
1839 ecore.spec
1840 $po_makefile_in
1841 ])
1842
1843 AC_OUTPUT
1844
1845 echo
1846 echo "$PACKAGE $VERSION"
1847 echo
1848 echo "Optional Modules:"
1849 echo
1850 echo " Core:"
1851 echo
1852 echo "  Ecore........................: always"
1853 echo "    Thread support.............: $have_threads"
1854 echo "    Thread safety..............: $want_thread_safety"
1855 echo "    GLib support...............: $have_glib"
1856 echo "    Always integrate GLib......: $want_glib_integration_always"
1857 echo "    Use g_main_loop............: $want_g_main_loop"
1858 echo "    Gathering memory statistic.: $have_mallinfo"
1859 echo "    Gathering timer allocation.: $want_ecore_timer_dump"
1860 echo "  Ecore_Con....................: $have_ecore_con"
1861 if test "x$have_ecore_con" = "xyes" ; then
1862   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1863 if test "x$have_gnutls" = "xyes" ; then
1864   echo " (disabled)"
1865 else
1866   echo
1867 fi
1868   echo "    IPv6.......................: $have_ipv6"
1869   echo "    GnuTLS.....................: $have_gnutls"
1870   echo "    CURL.......................: $have_curl"
1871   echo "    Local Sockets..............: $want_ecore_con_local_sockets"
1872 if test "x$want_ecore_con_local_sockets" = "xyes" ; then
1873   echo "      Abstract Sockets.........: $want_ecore_con_abstract_sockets"
1874 fi
1875   echo "    c-ares.....................: $have_cares"
1876 fi
1877 echo "  Ecore_Ipc....................: $have_ecore_ipc"
1878 if test "x$have_ecore_ipc" = "xyes" ; then
1879   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1880 if test "x$have_gnutls" = "xyes" ; then
1881   echo " (disabled)"
1882 else
1883   echo
1884 fi
1885   echo "    GnuTLS.....................: $have_gnutls"
1886 fi
1887 echo "  Ecore_File...................: $have_ecore_file"
1888 if test "x$have_ecore_file" = "xyes" ; then
1889   echo "    Inotify....................: $have_inotify"
1890   echo "    Windows notification.......: $have_notify_win32"
1891   echo "    Poll.......................: $have_poll"
1892   echo "    CURL.......................: $have_curl"
1893 fi
1894 #echo "  Ecore_Config.................: $have_ecore_config (deprecated)"
1895 echo "  Ecore_IMF....................: $have_ecore_imf"
1896 echo "    XIM........................: $have_ecore_imf_xim"
1897 echo "  Ecore_IMF_Evas...............: $have_ecore_imf_evas"
1898 echo "  Ecore_Input..................: $have_ecore_input"
1899 echo "  Ecore_Input_Evas.............: $have_ecore_input_evas"
1900
1901 echo
1902 echo " Graphic systems:"
1903 echo
1904
1905 if test "x$have_ecore_x" = "xyes" ; then
1906   if test "x$have_ecore_x_xcb" = "xyes" ; then
1907     echo "  Ecore_X (XCB backend)........: $have_ecore_x_xcb"
1908     echo "    Xprint.....................: $have_ecore_x_xcb_xprint"
1909     echo "    Xinerama...................: $have_ecore_x_xcb_xinerama"
1910     echo "    Xrandr.....................: $have_ecore_x_xcb_randr"
1911     echo "    Xscreensaver...............: $have_ecore_x_xcb_screensaver"
1912     echo "    Xshape.....................: $have_ecore_x_xcb_shape"
1913     echo "    Xsync......................: $have_ecore_x_xcb_sync"
1914     echo "    Xrender....................: $have_ecore_x_xcb_render"
1915     echo "    Xcomposite.................: $have_ecore_x_xcb_composite"
1916     echo "    Xfixes.....................: $have_ecore_x_xcb_xfixes"
1917     echo "    Xdamage....................: $have_ecore_x_xcb_damage"
1918     echo "    Xdpms......................: $have_ecore_x_xcb_dpms"
1919     echo "    Xtest......................: $have_ecore_x_xcb_xtest"
1920   else
1921     echo "  Ecore_X (Xlib backend).......: $have_ecore_x"
1922     echo "    Xcursor....................: $use_Xcursor"
1923     echo "    Xkb........................: $use_xkb"
1924     echo "    Xprint.....................: $use_xprint"
1925     echo "    Xinerama...................: $use_xinerama"
1926     echo "    Xrandr.....................: $use_xrandr"
1927     echo "    Xscreensaver...............: $use_xss"
1928     echo "    Xrender....................: $use_xrender"
1929     echo "    Xcomposite.................: $use_xcomposite"
1930     echo "    Xfixes.....................: $use_xfixes"
1931     echo "    Xdamage....................: $use_xdamage"
1932     echo "    Xdpms......................: $use_xdpms"
1933     echo "    Xtest......................: $use_xtest"
1934     echo "    XIM........................: $want_xim"
1935     echo "    Xi2........................: $use_xi2"
1936   fi
1937 else
1938   echo "  Ecore_X......................: $have_ecore_x"
1939 fi
1940 echo "  Ecore_Win32..................: $have_ecore_win32"
1941 echo "  Ecore_Cocoa..................: $have_ecore_cocoa"
1942 echo "  Ecore_SDL....................: $have_ecore_sdl"
1943 echo "  Ecore_FB.....................: $have_ecore_fb"
1944 if test "x${have_ecore_fb}" = "xyes" ; then
1945   echo "    Touchscreen................: $have_tslib"
1946 fi
1947 echo "  Ecore_DirectFB...............: $have_ecore_directfb"
1948 echo "  Ecore_WinCE..................: $have_ecore_wince"
1949
1950 echo
1951 echo " Ecore Evas:"
1952 echo
1953
1954 echo "  Ecore_Evas...................: $have_ecore_evas"
1955 if test "x${have_ecore_evas}" = "xyes" ; then
1956   echo "    Software Memory Buffer.....: $have_ecore_evas_software_buffer"
1957   if test "x${have_ecore_evas_software_x11}" = "xyes" ; then
1958     echo "    Software X11...............: $have_ecore_evas_software_x11 (Xlib=${have_ecore_evas_software_xlib}) (XCB=${have_ecore_evas_software_xcb})"
1959   else
1960     echo "    Software X11...............: $have_ecore_evas_software_x11"
1961   fi
1962   if test "x${have_ecore_evas_opengl_x11}" = "xyes" ; then
1963     echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11 (Xlib=${have_ecore_evas_opengl_xlib}) (XCB=${have_ecore_evas_opengl_xcb})"
1964   else
1965     echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11"
1966   fi
1967   echo "    Software GDI...............: $have_ecore_evas_software_gdi"
1968   echo "    Software DirectDraw........: $have_ecore_evas_software_ddraw"
1969   echo "    Direct3D...................: $have_ecore_evas_direct3d"
1970   echo "    OpenGL Glew................: $have_ecore_evas_opengl_glew"
1971   echo "    Software SDL...............: $have_ecore_evas_software_sdl"
1972   echo "    OpenGL SDL.................: $have_ecore_evas_opengl_sdl"
1973   echo "    OpenGL Cocoa...............: $have_ecore_evas_opengl_cocoa"
1974   echo "    DirectFB...................: $have_ecore_evas_directfb"
1975   echo "    Software Framebuffer.......: $have_ecore_evas_fb"
1976   echo "    Software 8bit grayscale XCB: $have_ecore_evas_software_8_x11"
1977   echo "    Software 16bit X11.........: $have_ecore_evas_software_16_x11"
1978   echo "    Software 16bit DirectDraw..: $have_ecore_evas_software_16_ddraw"
1979   echo "    Software 16bit WinCE.......: $have_ecore_evas_software_16_wince"
1980   echo "    Sing.Proc. Windowing System: $have_ecore_evas_ews"
1981 fi
1982 echo
1983 echo "  Tests................: ${enable_tests}"
1984 echo "  Maximum log level....: ${with_max_log_level}"
1985 echo "Documentation..........: ${build_doc}"
1986 echo
1987 echo "Compilation............: make (or gmake)"
1988 echo "  CPPFLAGS.............: $CPPFLAGS"
1989 echo "  CFLAGS...............: $CFLAGS"
1990 echo "  CXXFLAGS.............: $CXXFLAGS"
1991 echo "  LDFLAGS..............: $LDFLAGS"
1992 echo
1993 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
1994 echo "  prefix...............: $prefix"
1995 echo