configure.ac

   1 # clutter package version number, (as distinct from shared library version)
   2 # An odd micro number indicates in-progress development from Git
   3 # An even micro number indicates a released version
   4 #
   5 # Making a point release:
   6 # - increase clutter_micro_version to the next even number
   7 # - increase clutter_interface_age to the next even number
   8 # After the release:
   9 # - increase clutter_micro_version to the next odd number
  10 # - increase clutter_interface_version to the next odd number
  11 m4_define([clutter_major_version], [1])
  12 m4_define([clutter_minor_version], [9])
  13 m4_define([clutter_micro_version], [3])
  14
  15 # • for stable releases: increase the interface age by 1 for each release;
  16 #   if the API changes, set to 0. interface_age and binary_age are used to
  17 #   create the soname of the shared object:
  18 #
  19 #  (<minor> * 100 + <micro>) - <interface_age>
  20 #
  21 # this allows using the same soname for different micro-releases in case
  22 # no API was added or deprecated. for instance:
  23 #
  24 #   clutter 1.2.0  -> 100 * 2 + 0  = 200, interface age = 0 -> 200
  25 #   clutter 1.2.2  -> 100 * 2 + 2  = 202, interface age = 2 -> 200
  26 #   clutter 1.2.4  -> 100 * 2 + 4  = 204, interface age = 4 -> 200
  27 #   [ API addition, deprecation ]
  28 #   clutter 1.2.6  -> 100 * 2 + 6  = 206, interface age = 0 -> 206
  29 #   clutter 1.2.8  -> 100 * 2 + 8  = 208, interface age = 2 -> 206
  30 #   clutter 1.2.10 -> 100 * 2 + 10 = 210, interface age = 4 -> 206
  31 #   ...
  32 #
  33 # • for development releases: keep clutter_interface_age to 0
  34 m4_define([clutter_interface_age], [0])
  35
  36 m4_define([clutter_binary_age], [m4_eval(100 * clutter_minor_version + clutter_micro_version)])
  37
  38 m4_define([clutter_release_status],
  39           [m4_if(m4_eval(clutter_micro_version % 2), [1], [git],
  40                  [m4_if(m4_eval(clutter_minor_version % 2), [1], [snapshot],
  41                                                                  [release])])])
  42
  43 m4_define([clutter_version], [clutter_major_version.clutter_minor_version.clutter_micro_version])
  44
  45 # change this only when breaking the API
  46 m4_define([clutter_api_version], [1.0])
  47
  48 AC_PREREQ([2.63])
  49
  50 AC_INIT([clutter],
  51         [clutter_version],
  52         [http://bugzilla.gnome.org/enter_bug.cgi?product=clutter],
  53         [clutter],
  54         [http://www.clutter-project.org])
  55
  56 AC_CONFIG_SRCDIR([clutter/clutter.h])
  57 AC_CONFIG_HEADERS([config.h])
  58 AC_CONFIG_AUX_DIR([build])
  59 AC_CONFIG_MACRO_DIR([build/autotools])
  60
  61 AM_INIT_AUTOMAKE([1.11 foreign -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  62 AM_SILENT_RULES([yes])
  63
  64 AC_SUBST([CLUTTER_MAJOR_VERSION],  [clutter_major_version])
  65 AC_SUBST([CLUTTER_MINOR_VERSION],  [clutter_minor_version])
  66 AC_SUBST([CLUTTER_MICRO_VERSION],  [clutter_micro_version])
  67 AC_SUBST([CLUTTER_VERSION],        [clutter_version])
  68 AC_SUBST([CLUTTER_API_VERSION],    [clutter_api_version])
  69 AC_SUBST([CLUTTER_API_VERSION_AM], [$CLUTTER_MAJOR_VERSION\_0])
  70 AC_SUBST([CLUTTER_RELEASE_STATUS], [clutter_release_status])
  71
  72 m4_define([lt_current],  [m4_eval(100 * clutter_minor_version + clutter_micro_version - clutter_interface_age)])
  73 m4_define([lt_revision], [clutter_interface_age])
  74 m4_define([lt_age],      [m4_eval(clutter_binary_age - clutter_interface_age)])
  75 CLUTTER_LT_CURRENT=lt_current
  76 CLUTTER_LT_REV=lt_revision
  77 CLUTTER_LT_AGE=lt_age
  78 CLUTTER_LT_VERSION="$CLUTTER_LT_CURRENT:$CLUTTER_LT_REV:$CLUTTER_LT_AGE"
  79 CLUTTER_LT_LDFLAGS="-version-info $CLUTTER_LT_VERSION"
  80 AC_SUBST([CLUTTER_LT_CURRENT],  [lt_current])
  81 AC_SUBST([CLUTTER_LT_REVISION], [lt_revision])
  82 AC_SUBST([CLUTTER_LT_VERSION],  [$CLUTTER_LT_VERSION])
  83
  84 AC_PROG_SED
  85
  86 dnl = Preliminary platform checks =============================================
  87
  88 AC_CANONICAL_HOST
  89
  90 platform_win32=no
  91 platform_quartz=no
  92 platform_linux=no
  93
  94 AC_MSG_CHECKING([if building for some Win32 platform])
  95 AS_CASE([$host],
  96         [*-*-mingw*|*-*-cygwin*],
  97         [
  98           CLUTTER_LT_LDFLAGS="$CLUTTER_LT_LDFLAGS -no-undefined"
  99           platform_win32=yes
 100         ],
 101
 102         []
 103 )
 104 AC_MSG_RESULT([$platform_win32])
 105
 106 AM_CONDITIONAL(OS_WIN32, [test "$platform_win32" = "yes"])
 107
 108 AC_CHECK_HEADER([OpenGL/gl.h], [platform_quartz=yes], [platform_quartz=no])
 109 AM_CONDITIONAL(OS_QUARTZ, [test "$platform_quartz" = "yes"])
 110
 111 AC_CHECK_HEADER([GL/glx.h], [platform_glx=yes], [platform_glx=no])
 112 AC_CHECK_LIB([GL], [glXCreateContext], [platform_glx=yes], [platform_glx=no])
 113 AM_CONDITIONAL(OS_GLX, [test "$platform_glx" = "yes"])
 114
 115 AC_SUBST(CLUTTER_LT_LDFLAGS)
 116
 117 AC_CACHE_SAVE
 118
 119 dnl = Dependencies =========================================================
 120
 121 # Checks for programs.
 122 AM_PROG_CC_C_O
 123
 124 # require libtool >= 2.2
 125 LT_PREREQ([2.2.6])
 126 LT_INIT([disable-static])
 127
 128 # Checks for header files.
 129 AC_HEADER_STDC
 130
 131 # required versions for dependencies
 132 m4_define([glib_req_version],           [2.31.0])
 133 m4_define([cogl_req_version],           [1.9.1])
 134 m4_define([json_glib_req_version],      [0.12.0])
 135 m4_define([atk_req_version],            [2.1.5])
 136 m4_define([cairo_req_version],          [1.10])
 137 m4_define([pango_req_version],          [1.20])
 138 m4_define([gi_req_version],             [0.9.5])
 139 m4_define([uprof_req_version],          [0.3])
 140 m4_define([gtk_doc_req_version],        [1.15])
 141 m4_define([xfixes_req_version],         [3])
 142 m4_define([xcomposite_req_version],     [0.4])
 143 m4_define([gdk_req_version],            [3.0.0])
 144
 145 AC_SUBST([GLIB_REQ_VERSION],       [glib_req_version])
 146 AC_SUBST([COGL_REQ_VERSION],       [cogl_req_version])
 147 AC_SUBST([JSON_GLIB_REQ_VERSION],  [json_glib_req_version])
 148 AC_SUBST([ATK_REQ_VERSION],        [atk_req_version])
 149 AC_SUBST([CAIRO_REQ_VERSION],      [cairo_req_version])
 150 AC_SUBST([PANGO_REQ_VERSION],      [pango_req_version])
 151 AC_SUBST([GI_REQ_VERSION],         [gi_req_version])
 152 AC_SUBST([UPROF_REQ_VERSION],      [uprof_req_version])
 153 AC_SUBST([GTK_DOC_REQ_VERSION],    [gtk_doc_req_version])
 154 AC_SUBST([XFIXES_REQ_VERSION],     [xfixes_req_version])
 155 AC_SUBST([XCOMPOSITE_REQ_VERSION], [xcomposite_req_version])
 156 AC_SUBST([GDK_REQ_VERSION],        [gdk_req_version])
 157
 158 # Checks for typedefs, structures, and compiler characteristics.
 159 AM_PATH_GLIB_2_0([glib_req_version],
 160                  [],
 161                  [AC_MSG_ERROR([glib-2.0 is required])],
 162                  [gobject gthread gmodule-no-export])
 163
 164 # Check for -Bsymbolic-functions to avoid intra-library PLT jumps
 165 AC_ARG_ENABLE([Bsymbolic],
 166               [AS_HELP_STRING([--disable-Bsymbolic],
 167                               [Avoid linking with -Bsymbolic])],
 168               [],
 169               [
 170                 saved_LDFLAGS="${LDFLAGS}"
 171                 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 172                 LDFLAGS=-Wl,-Bsymbolic-functions
 173                 AC_TRY_LINK([], [int main (void) { return 0; }],
 174                             [
 175                               AC_MSG_RESULT([yes])
 176                               enable_Bsymbolic=yes
 177                             ],
 178                             [
 179                               AC_MSG_RESULT([no])
 180                               enable_Bsymbolic=no
 181                             ])
 182                 LDFLAGS="${saved_LDFLAGS}"
 183               ])
 184
 185 AS_IF([test "x$enable_Bsymbolic" = "xyes"], [CLUTTER_LINK_FLAGS=-Wl[,]-Bsymbolic-functions])
 186 AC_SUBST(CLUTTER_LINK_FLAGS)
 187
 188 AC_CACHE_SAVE
 189
 190 dnl ========================================================================
 191
 192 FLAVOUR_LIBS=""
 193 FLAVOUR_CFLAGS=""
 194 CLUTTER_BACKENDS=""
 195 CLUTTER_INPUT_BACKENDS=""
 196
 197 experimental_backend=no
 198 experimental_input_backend=no
 199
 200 # base dependencies for core
 201 CLUTTER_BASE_PC_FILES="cogl-1.0 >= $COGL_REQ_VERSION cairo-gobject >= $CAIRO_REQ_VERSION atk >= $ATK_REQ_VERSION pangocairo >= $PANGO_REQ_VERSION cogl-pango-1.0 json-glib-1.0 >= $JSON_GLIB_REQ_VERSION"
 202
 203 # backend specific pkg-config files
 204 BACKEND_PC_FILES=""
 205
 206 dnl === Clutter windowing system backend ======================================
 207
 208 AC_ARG_ENABLE([x11-backend],
 209               [AS_HELP_STRING([--enable-x11-backend=@<:@yes/no@:>@], [Enable the X11 backend (default=check)])],
 210               [enable_x11=$enableval],
 211               [enable_x11=check])
 212 AC_ARG_ENABLE([win32-backend],
 213               [AS_HELP_STRING([--enable-win32-backend=@<:@yes/no@:>@], [Enable the Windows backend (default=check)])],
 214               [enable_win32=$enableval],
 215               [enable_win32=check])
 216 AC_ARG_ENABLE([quartz-backend],
 217               [AS_HELP_STRING([--enable-quartz-backend=@<:@yes/no@:>@], [Enable the OS X backend (default=check)])],
 218               [enable_osx=$enableval],
 219               [enable_osx=check])
 220 AC_ARG_ENABLE([gdk-backend],
 221               [AS_HELP_STRING([--enable-gdk-backend=@<:@yes/no@:>@], [Enable the GDK backend (default=check)])],
 222               [enable_gdk=$enableval],
 223               [enable_gdk=check])
 224 AC_ARG_ENABLE([wayland-backend],
 225               [AS_HELP_STRING([--enable-wayland-backend=@<:@yes/no@:>@], [Enable the Wayland client backend (default=no)])],
 226               [enable_wayland=$enableval],
 227               [enable_wayland=no])
 228 AC_ARG_ENABLE([egl-backend],
 229               [AS_HELP_STRING([--enable-egl-backend=@<:@yes/no@:>@], [Enable the EGL framebuffer backend (default=no)])],
 230               [enable_egl=$enableval],
 231               [enable_egl=no])
 232 AC_ARG_ENABLE([cex100-backend],
 233               [AS_HELP_STRING([--enable-cex100-backend=@<:@yes/no@:>@], [Enable the CEx100 backend (default=no)])],
 234               [enable_cex100=$enableval],
 235               [enable_cex100=no])
 236
 237 dnl Define default values
 238 AS_IF([test "x$enable_x11" = "xcheck"],
 239       [
 240         AS_IF([test "x$platform_glx" = "xyes"], [enable_x11=yes], [enable_x11=no])
 241       ])
 242
 243 AS_IF([test "x$enable_win32" = "xcheck"],
 244       [
 245         AS_IF([test "x$platform_win32" = "xyes"], [enable_win32=yes], [enable_win32=no])
 246       ])
 247
 248 AS_IF([test "x$enable_osx" = "xcheck"],
 249       [
 250         AS_IF([test "x$platform_quartz" = "xyes"], [enable_osx=yes], [enable_osx=no])
 251       ])
 252
 253 AS_IF([test "x$enable_gdk" = "xcheck"],
 254       [
 255         PKG_CHECK_EXISTS([gdk-3.0 >= gdk_req_version], [enable_gdk=yes], [enable_gdk=no])
 256       ])
 257
 258 dnl Per-backend rules
 259 AS_IF([test "x$enable_x11" = "xyes"],
 260       [
 261         CLUTTER_BACKENDS="$CLUTTER_BACKENDS x11"
 262         CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS x11"
 263
 264         SUPPORT_X11=1
 265         SUPPORT_GLX=1
 266         SUPPORT_COGL=1
 267
 268         # Mesa 7.3 added a GL pkg-config file, finally, but if a pkg-config
 269         # file isn't found just add -lGL and hope for the best.
 270         PKG_CHECK_EXISTS([gl],
 271                          [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"],
 272                          [FLAVOUR_LIBS="$FLAVOUR_LIBS -lGL"])
 273
 274         # We might fall back to DRM for sync-to-vblank on GLX
 275         PKG_CHECK_EXISTS([libdrm],
 276                          [
 277                            AC_DEFINE([HAVE_DRM], [1], [Have libdrm support])
 278                            BACKEND_PC_FILES="$BACKEND_PC_FILES libdrm"
 279                          ],
 280                          [])
 281
 282         # we use fontconfig API and pango-fc when the fontconfig
 283         # configuration changes
 284         PKG_CHECK_EXISTS([pangoft2],
 285                          [
 286                            AC_DEFINE([HAVE_PANGO_FT2], [1], [Supports PangoFt2])
 287                            BACKEND_PC_FILES="$BACKEND_PC_FILES pangoft2"
 288                          ],
 289                          [])
 290
 291         AC_DEFINE([HAVE_CLUTTER_GLX], [1], [Have the GLX backend])
 292       ])
 293
 294 AS_IF([test "x$enable_gdk" = "xyes"],
 295       [
 296         CLUTTER_BACKENDS="$CLUTTER_BACKENDS gdk"
 297         CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS gdk"
 298
 299         SUPPORT_GDK=1
 300         SUPPORT_COGL=1
 301
 302         BACKEND_PC_FILES="$BACKEND_PC_FILES gdk-3.0"
 303         PKG_CHECK_EXISTS([gl], [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"], [])
 304       ])
 305
 306 AS_IF([test "x$enable_wayland" = "xyes"],
 307       [
 308         CLUTTER_BACKENDS="$CLUTTER_BACKENDS wayland"
 309         CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS wayland"
 310
 311         experimental_backend="yes"
 312
 313         SUPPORT_WAYLAND=1
 314
 315         PKG_CHECK_EXISTS([wayland-client xkbcommon],
 316                          [BACKEND_PC_FILES="$BACKEND_PC_FILES wayland-client xkbcommon"],
 317                          [])
 318
 319         AC_DEFINE([HAVE_CLUTTER_WAYLAND], [1], [Have the Wayland backend])
 320       ],
 321       [
 322         # The wayland headers introduce so much symbol shadowing that build
 323         # logs become incomprehensible with -Wshadow so we only use it for
 324         # non-wayland builds.
 325         MAINTAINER_COMPILER_FLAGS="-Wshadow"
 326       ])
 327
 328 AS_IF([test "x$enable_cex100" = "xyes"],
 329       [
 330         CLUTTER_BACKENDS="$CLUTTER_BACKENDS cex100"
 331
 332         experimental_backend="yes"
 333
 334         SUPPORT_COGL=1
 335         SUPPORT_EGL_PLATFORM_GDL=1
 336
 337         have_gdl=no
 338         AC_CHECK_HEADERS([libgdl.h], [have_gdl=yes])
 339
 340         AS_IF([test "x$have_gdl" = "xno"],
 341               [
 342                 AC_CHECK_HEADERS([CE4100/libgdl.h],
 343                                  [
 344                                    FLAVOUR_CFLAGS="-I/usr/include/CE4100"
 345                                    have_gdl=yes
 346                                    CLUTTER_CEX100_LIBGDL_PREFIX=CE4100/
 347                                  ])
 348               ])
 349
 350         AS_IF([test "x$have_gdl" = "xno"],
 351               [AC_MSG_ERROR([libgdl.h not found but the CEx100 backend has been explicitly enabled])])
 352
 353         AC_SUBST(CLUTTER_CEX100_LIBGDL_PREFIX)
 354
 355         FLAVOUR_LIBS="$FLAVOUR_LIBS -lgdl"
 356
 357         AC_DEFINE([CLUTTER_EGL_BACKEND_CEX100], [1], [Use CEX100 EGL backend])
 358         AC_DEFINE([CLUTTER_EGL_BACKEND_GENERIC], [1], [Use Generic EGL backend])
 359         AC_DEFINE([HAVE_CLUTTER_EGL], [1], [Have the EGL backend])
 360       ])
 361
 362 AS_IF([test "x$enable_egl" = "xyes"],
 363       [
 364         CLUTTER_BACKENDS="$CLUTTER_BACKENDS egl"
 365
 366         experimental_backend="yes"
 367
 368         SUPPORT_EGL=1
 369         SUPPORT_COGL=1
 370
 371         # if Mesa has support for egl, we can use it as well
 372         PKG_CHECK_EXISTS([egl],
 373                          [
 374                            BACKEND_PC_FILES="$BACKEND_PC_FILES egl"
 375                          ],
 376                          [])
 377
 378         FLAVOUR_LIBS="$FLAVOUR_LIBS $TSLIB_LIBS $EVDEV_LIBS"
 379         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $TSLIB_CFLAGS $EVDEV_CFLAGS"
 380
 381         AC_DEFINE([CLUTTER_EGL_BACKEND_GENERIC], [1], [Use Generic EGL backend])
 382
 383         AC_DEFINE([HAVE_CLUTTER_EGL], [1], [Have the EGL backend])
 384       ])
 385
 386 AS_IF([test "x$enable_osx" = "xyes"],
 387       [
 388         CLUTTER_BACKENDS="$CLUTTER_BACKENDS osx"
 389         CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS osx"
 390
 391         AC_DEFINE([HAVE_CLUTTER_OSX], [1], [Have the OSX backend])
 392
 393         FLAVOUR_LIBS="$FLAVOUR_LIBS -framework Cocoa -framework OpenGL"
 394
 395         SUPPORT_OSX=1
 396       ])
 397
 398 AS_IF([test "x$enable_win32" = "xyes"],
 399       [
 400         CLUTTER_BACKENDS="$CLUTTER_BACKENDS win32"
 401         CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS win32"
 402
 403         AC_DEFINE([HAVE_CLUTTER_WIN32], [1], [Have the Win32 backend])
 404
 405         FLAVOUR_LIBS="$FLAVOUR_LIBS -lopengl32 -lgdi32 -lwinmm"
 406         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS -D_WIN32_WINNT=0x0500"
 407
 408         AC_CHECK_TOOL(WINDRES, [windres], [AC_MSG_ERROR([*** windres is required])])
 409
 410         SUPPORT_WIN32=1
 411       ])
 412
 413 AS_IF([test "x$CLUTTER_BACKENDS" = "x"],
 414       [
 415         AC_MSG_ERROR([No backend enabled. You need to enable at least one backend.])
 416       ])
 417
 418 # additional input backends
 419
 420 AC_ARG_ENABLE([tslib-input],
 421               [AS_HELP_STRING([--enable-tslib-input=@<:@yes/no@:>@], [Enable TSLib for input events (default=no)])],
 422               [enable_tslib=$enableval],
 423               [enable_tslib=no])
 424 AC_ARG_ENABLE([evdev-input],
 425               [AS_HELP_STRING([--with-evdev=@<:@yes/no@:>@], [Enable evdev for input events (default=no)])],
 426               [enable_evdev=$enableval],
 427               [enable_evdev=no])
 428
 429 AS_IF([test "x$enable_tslib" = "xyes"],
 430       [
 431         PKG_CHECK_MODULES(TSLIB, [tslib-1.0], [have_tslib=yes], [have_tslib=no])
 432         AS_IF([test "x$have_tslib" = "xyes"],
 433               [
 434                 CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS tslib"
 435                 experimental_input_backend="yes"
 436                 AC_DEFINE([HAVE_TSLIB], [1], [Have tslib for touchscreen handling])
 437                 SUPPORT_TSLIB=1
 438               ])
 439       ])
 440
 441 AS_IF([test "x$enable_evdev" = "xyes"],
 442       [
 443         PKG_CHECK_MODULES(EVDEV, [gudev-1.0 xkbcommon], [have_evdev=yes], [have_evdev=no])
 444         AS_IF([test "x$have_evdev" = "xyes"],
 445               [
 446                 CLUTTER_INPUT_BACKENDS="$CLUTTER_INPUT_BACKENDS evdev"
 447                 experimental_input_backend="yes"
 448                 AC_DEFINE([HAVE_EVDEV], [1], [Have evdev support for input handling])
 449                 SUPPORT_EVDEV=1
 450               ])
 451       ])
 452
 453 # conditionals for use in automake files...
 454 AM_CONDITIONAL(SUPPORT_GLX,     [test "x$SUPPORT_GLX" = "x1"])
 455 AM_CONDITIONAL(SUPPORT_X11,     [test "x$SUPPORT_X11" = "x1"])
 456 AM_CONDITIONAL(SUPPORT_GDK,     [test "x$SUPPORT_GDK" = "x1"])
 457 AM_CONDITIONAL(SUPPORT_EGL,     [test "x$SUPPORT_EGL" = "x1"])
 458 AM_CONDITIONAL(SUPPORT_OSX,     [test "x$SUPPORT_OSX" = "x1"])
 459 AM_CONDITIONAL(SUPPORT_WIN32,   [test "x$SUPPORT_WIN32" = "x1"])
 460 AM_CONDITIONAL(SUPPORT_CEX100,  [test "x$SUPPORT_EGL_PLATFORM_GDL" = "x1"])
 461 AM_CONDITIONAL(SUPPORT_WAYLAND, [test "x$SUPPORT_WAYLAND" = "x1"])
 462 AM_CONDITIONAL(SUPPORT_STUB,    [test "x$SUPPORT_WIN32" = "x1" -o \
 463                                       "x$SUPPORT_OSX" = "x1"])
 464
 465 AM_CONDITIONAL(USE_COGL,  [test "x$SUPPORT_COGL" = "x1"])
 466 AM_CONDITIONAL(USE_TSLIB, [test "x$have_tslib" = "xyes"])
 467 AM_CONDITIONAL(USE_EVDEV, [test "x$have_evdev" = "xyes"])
 468 AM_CONDITIONAL(USE_GLD,   [test "x$have_gdl" = "xyes"])
 469
 470 dnl Instead of using AM_CFLAGS to ensure
 471 dnl COGL_ENABLE_EXPERIMENTAL_2_0_API is defined while compiling clutter
 472 dnl and cogl code we use a define in config.h instead. This helps ensure
 473 dnl other tools such as glib-mkenums and gir-scanner don't end up
 474 dnl using the define also.
 475 AC_DEFINE([COGL_ENABLE_EXPERIMENTAL_2_0_API], [1], [Can use Cogl 2.0 API internally])
 476
 477 dnl strip leading spaces
 478 CLUTTER_BACKENDS=${CLUTTER_BACKENDS#* }
 479 AC_SUBST(CLUTTER_BACKENDS)
 480
 481 CLUTTER_INPUT_BACKENDS=${CLUTTER_INPUT_BACKENDS#* }
 482 AC_SUBST(CLUTTER_INPUT_BACKENDS)
 483
 484 AC_CACHE_SAVE
 485
 486 dnl === Clutter configuration =================================================
 487
 488 CLUTTER_CONFIG_DEFINES=
 489
 490 # windowing systems
 491 AS_IF([test "x$SUPPORT_X11" = "x1"],
 492       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 493 #define CLUTTER_WINDOWING_X11 \"x11\"
 494 #define CLUTTER_INPUT_X11 \"x11\""])
 495 AS_IF([test "x$SUPPORT_GDK" = "x1"],
 496       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 497 #define CLUTTER_WINDOWING_GDK \"gdk\"
 498 #define CLUTTER_INPUT_GDK \"gdk\""])
 499 AS_IF([test "x$SUPPORT_GLX" = "x1"],
 500       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 501 #define CLUTTER_WINDOWING_GLX \"glx\""])
 502 AS_IF([test "x$SUPPORT_EGL" = "x1"],
 503       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 504 #define CLUTTER_WINDOWING_EGL \"eglnative\""])
 505 AS_IF([test "x$SUPPORT_WAYLAND" = "x1"],
 506       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 507 #define CLUTTER_WINDOWING_WAYLAND \"wayland\""])
 508 AS_IF([test "x$SUPPORT_OSX" = "x1"],
 509       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 510 #define CLUTTER_WINDOWING_OSX \"osx\"
 511 #define CLUTTER_INPUT_OSX \"osx\""])
 512 AS_IF([test "x$SUPPORT_WIN32" = "x1"],
 513       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 514 #define CLUTTER_WINDOWING_WIN32 \"win32\"
 515 #define CLUTTER_INPUT_WIN32 \"win32\""])
 516 AS_IF([test "x$SUPPORT_EGL_PLATFORM_GDL" = "x1"],
 517       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 518 #define CLUTTER_WINDOWING_CEX100 \"cex100\""])
 519 AS_IF([test "x$SUPPORT_EVDEV" = "x1"],
 520       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 521 #define CLUTTER_INPUT_EVDEV \"evdev\""])
 522 AS_IF([test "x$SUPPORT_TSLIB" = "x1"],
 523       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 524 #define CLUTTER_INPUT_TSLIB \"tslib\""])
 525 AS_IF([test "x$SUPPORT_WAYLAND" = "x1"],
 526       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 527 #define CLUTTER_INPUT_WAYLAND \"wayland\""])
 528
 529 # the 'null' input backend is special
 530 CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 531 #define CLUTTER_INPUT_NULL \"null\""
 532
 533 AC_SUBST([CLUTTER_CONFIG_DEFINES])
 534
 535 dnl === Clutter substitutions kept for backwards compatibility ================
 536 AC_SUBST([CLUTTER_WINSYS],       [deprecated])
 537 AC_SUBST([CLUTTER_WINSYS_BASE],  [deprecated])
 538 AC_SUBST([CLUTTER_STAGE_TYPE],   [deprecated])
 539 AC_SUBST([CLUTTER_SONAME_INFIX], [deprecated])
 540 AC_SUBST([CLUTTER_FLAVOUR],      [deprecated])
 541 AC_SUBST([CLUTTER_COGL],         [deprecated])
 542 AC_SUBST([COGL_DRIVER],          [deprecated])
 543
 544 dnl === Image loading backend =================================================
 545 IMAGE_PC_FILES=""
 546
 547 dnl === X11 checks, only for X11-based backends ===============================
 548 X11_PC_FILES=""
 549 X11_EXTS=""
 550 x11_tests=no
 551
 552 AS_IF([test "x$SUPPORT_X11" = "x1"],
 553       [
 554         # base X11 includes and libraries
 555         AC_MSG_CHECKING([for X11])
 556
 557         # start with pkg-config
 558         PKG_CHECK_EXISTS([x11], [have_x11=yes], [have_x11=no])
 559         AS_IF([test "x$have_x11" = "xyes"],
 560               [
 561                 X11_PC_FILES="x11"
 562
 563                 # we actually need to ask for CFLAGS and LIBS
 564                 X11_CFLAGS=`$PKG_CONFIG --cflags $X11_PC_FILES`
 565                 X11_LIBS=`$PKG_CONFIG --libs $X11_PC_FILES`
 566
 567                 AC_MSG_RESULT([found])
 568               ],
 569               [
 570                 # no pkg-config, let's go old school
 571                 AC_PATH_X
 572
 573                 AS_IF([test "x$no_x" = "xyes"],
 574                       [AC_MSG_ERROR([No X11 Libraries found])],
 575                       [
 576                         AS_IF([test "x$x_includes" != "xNONE" && test -n "$x_includes"],
 577                               [X11_CFLAGS=-I`echo $x_includes | sed -e "s/:/ -I/g"`])
 578
 579                         AS_IF([test "x$x_libraries" != "xNONE" && test -n "$x_libraries"],
 580                               [X11_LIBS=-L`echo $x_libraries | sed -e "s/:/ -L/g"`])
 581
 582                         AC_MSG_RESULT([found])
 583                       ]
 584                 )
 585               ]
 586         )
 587
 588         # XEXT (required)
 589         AC_MSG_CHECKING([for XEXT extension])
 590         PKG_CHECK_EXISTS([xext], [have_xext=yes], [have_xext=no])
 591         AS_IF([test "x$have_xext" = "xyes"],
 592               [
 593                 AC_DEFINE(HAVE_XEXT, [1], [Define to 1 if we have the XEXT X extension])
 594
 595                 X11_LIBS="$X11_LIBS -lXext"
 596                 X11_PC_FILES="$X11_PC_FILES xext"
 597                 X11_EXTS="$X11_EXTS xext"
 598
 599                 AC_MSG_RESULT([found])
 600               ],
 601               [AC_MSG_ERROR([Not found])]
 602         )
 603
 604         # XFIXES (required)
 605         AC_MSG_CHECKING([for XFIXES extension >= $XFIXES_REQ_VERSION])
 606         PKG_CHECK_EXISTS([xfixes >= $XFIXES_REQ_VERSION], [have_xfixes=yes], [have_xfixes=no])
 607         AS_IF([test "x$have_xfixes" = "xyes"],
 608               [
 609                 AC_DEFINE(HAVE_XFIXES, [1], [Define to 1 if we have the XFIXES X extension])
 610
 611                 X11_LIBS="$X11_LIBS -lXfixes"
 612                 X11_PC_FILES="$X11_PC_FILES xfixes >= $XFIXES_REQ_VERSION"
 613                 X11_EXTS="$X11_EXTS xfixes"
 614
 615                 AC_MSG_RESULT([found])
 616               ],
 617               [AC_MSG_ERROR([Not found])]
 618         )
 619
 620         # XDAMAGE (required)
 621         AC_MSG_CHECKING([for XDAMAGE extension])
 622         PKG_CHECK_EXISTS([xdamage], [have_xdamage=yes], [have_xdamage=no])
 623         AS_IF([test "x$have_xdamage" = "xyes"],
 624               [
 625                 AC_DEFINE(HAVE_XDAMAGE, [1], [Define to 1 if we have the XDAMAGE X extension])
 626
 627                 X11_LIBS="$X11_LIBS -lXdamage"
 628                 X11_PC_FILES="$X11_PC_FILES xdamage"
 629                 X11_EXTS="$X11_EXTS xdamage"
 630
 631                 AC_MSG_RESULT([found])
 632               ],
 633               [AC_MSG_ERROR([not found])]
 634         )
 635
 636         # XCOMPOSITE (optional)
 637         AC_MSG_CHECKING([for XCOMPOSITE extension >= $XCOMPOSITE_REQ_VERSION])
 638         PKG_CHECK_EXISTS([xcomposite >= $XCOMPOSITE_REQ_VERSION], [have_xcomposite=yes], [have_xcomposite=no])
 639         AS_IF([test "x$have_xcomposite" = "xyes"],
 640               [
 641                 AC_DEFINE(HAVE_XCOMPOSITE, [1], [Define to 1 if we have the XCOMPOSITE X extension])
 642
 643                 X11_LIBS="$X11_LIBS -lXcomposite"
 644                 X11_PC_FILES="$X11_PC_FILES xcomposite >= $XCOMPOSITE_REQ_VERSION"
 645                 X11_EXTS="$X11_EXTS xcomposite"
 646
 647                 AC_MSG_RESULT([found])
 648               ],
 649               [AC_MSG_ERROR([not found])]
 650         )
 651
 652         # X Generic Extensions (optional)
 653         clutter_save_CPPFLAGS="$CPPFLAGS"
 654         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 655
 656         clutter_save_LIBS="$LIBS"
 657         LIBS="$LIBS $X11_LIBS"
 658
 659         have_xge=no
 660         AC_CHECK_FUNC([XGetEventData],
 661                       [
 662                         AC_DEFINE([HAVE_XGE], [1], [Define to 1 if X Generic Extensions is available])
 663                         have_xge=yes
 664                         X11_EXTS="$X11_EXTS xge"
 665                       ])
 666
 667         CPPFLAGS="$clutter_save_CPPFLAGS"
 668         LIBS="$clutter_save_LIBS"
 669
 670         # XI (optional)
 671         AC_ARG_ENABLE([xinput],
 672                       [AS_HELP_STRING([--enable-xinput], [Use the XI X extension])],
 673                       [],
 674                       [enable_xinput=yes])
 675
 676         AS_IF([test "x$enable_xinput" = "xyes"],
 677               [
 678                 PKG_CHECK_EXISTS([xi], [have_xinput=yes], [have_xinput=no])
 679               ],
 680               [
 681                 have_xinput=no
 682               ])
 683
 684         AS_CASE([$have_xinput],
 685
 686                 [yes],
 687                 [
 688                   AC_CHECK_HEADERS([X11/extensions/XInput2.h],
 689                                    [
 690                                      have_xinput2=yes
 691                                      AC_DEFINE([HAVE_XINPUT_2],
 692                                                [1],
 693                                                [Define to 1 if XI2 is available])
 694                                    ],
 695                                    [
 696                                      have_xinput2=no
 697                                      AC_DEFINE([HAVE_XINPUT],
 698                                                [1],
 699                                                [Define to 1 if XInput is available])
 700                                    ])
 701
 702                   X11_LIBS="$X11_LIBS $XINPUT_LIBS"
 703                   X11_PC_FILES="$X11_PC_FILES xi"
 704                   X11_EXTS="$X11_EXTS xi"
 705                 ],
 706
 707                 [no],
 708                 [have_xinput2=no],
 709
 710                 [*],
 711                 [AC_MSG_ERROR([Invalid argument for --enable-xinput])]
 712         )
 713
 714         # XKB
 715         clutter_save_CPPFLAGS="$CPPFLAGS"
 716         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 717
 718         clutter_save_LIBS="$LIBS"
 719         LIBS="$LIBS $X11_LIBS"
 720
 721         have_xkb=no
 722         AC_CHECK_FUNC([XkbQueryExtension],
 723                       [
 724                         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
 725                         have_xkb=yes
 726
 727                         X11_EXTS="$X11_EXTS xkb"
 728                       ])
 729
 730         CPPFLAGS="$clutter_save_CPPFLAGS"
 731         LIBS="$clutter_save_LIBS"
 732
 733         x11_tests=yes
 734         BACKEND_PC_FILES="$BACKEND_PC_FILES $X11_PC_FILES"
 735         FLAVOUR_LIBS="$FLAVOUR_LIBS $X11_LIBS"
 736         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $X11_CFLAGS"
 737       ]
 738 )
 739
 740 AM_CONDITIONAL([BUILD_XI2], [test "x$have_xinput2" = "xyes"])
 741 AM_CONDITIONAL([X11_TESTS], [test "x$x11_tests" = "xyes"])
 742
 743 X11_EXTS=${X11_EXTS#* }
 744
 745 AC_CACHE_SAVE
 746
 747 dnl === Enable debug level ====================================================
 748
 749 m4_define([debug_default], [m4_if(m4_eval(clutter_minor_version % 2), [1], [yes], [minimum])])
 750 AC_ARG_ENABLE([debug],
 751               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 752                               [Control Clutter debugging level @<:@default=]debug_default[@:>@])],
 753               [],
 754               [enable_debug=debug_default])
 755
 756 AS_CASE([$enable_debug],
 757
 758         [yes],
 759         [
 760           test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 761           CLUTTER_DEBUG_CFLAGS="-DCLUTTER_ENABLE_DEBUG"
 762         ],
 763
 764         [minimum],
 765         [CLUTTER_DEBUG_CFLAGS="-DCLUTTER_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"],
 766
 767         [no],
 768         [CLUTTER_DEBUG_CFLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"],
 769
 770         [AC_MSG_ERROR([Unknown argument for --enable-debug])]
 771 )
 772
 773 AC_SUBST(CLUTTER_DEBUG_CFLAGS)
 774
 775 dnl === Enable deprecation guards ==================================================
 776
 777 m4_define([deprecated_default],
 778           [m4_if(m4_eval(clutter_minor_version % 2),
 779                  [1],
 780                  [no],
 781                  [yes])])
 782
 783 AC_ARG_ENABLE([deprecated],
 784               [AS_HELP_STRING([--enable-deprecated=@<:@no/yes@:>@],
 785                               [Whether deprecated symbols should be disabled when compiling Clutter @<:@default=]deprecated_default[@:>@])],
 786               [],
 787               [enable_deprecated=deprecated_default])
 788
 789 AS_CASE([$enable_deprecated],
 790
 791         [no],
 792         [
 793           CLUTTER_DEPRECATED_CFLAGS="-DG_DISABLE_SINGLE_INCLUDES -DCOGL_DISABLE_DEPRECATED"
 794         ],
 795
 796         [yes],
 797         [
 798           CLUTTER_DEPRECATED_CFLAGS="-DGLIB_DISABLE_DEPRECATION_WARNINGS -DCLUTTER_DISABLE_DEPRECATION_WARNINGS"
 799         ],
 800
 801         [AC_MSG_ERROR([Unknown argument for --enable-deprecated])]
 802 )
 803
 804 AC_SUBST([CLUTTER_DEPRECATED_CFLAGS])
 805
 806
 807 dnl === Conformance test suite ================================================
 808
 809 AC_ARG_ENABLE([conformance],
 810               [AS_HELP_STRING([--enable-conformance=@<:@no/yes@:>@],
 811                               [Build conformance test suite @<:@default=yes@:>@])],
 812               [],
 813               [enable_conformance=yes])
 814
 815 AM_CONDITIONAL([BUILD_TESTS], [test "x$enable_conformance" = "xyes"])
 816
 817 dnl === Profiling =============================================================
 818
 819 m4_define([profile_default], [no])
 820 AC_ARG_ENABLE(profile,
 821               AS_HELP_STRING([--enable-profile=@<:@no/yes@:>@],
 822                              [Turn on profiling support. yes; All profiling probe points are compiled in and may be runtime enabled. no; No profiling support will built into clutter.  @<:@default=no@:>@]),
 823               [],
 824               [enable_profile=profile_default])
 825
 826 AS_CASE([$enable_profile],
 827
 828         [yes],
 829         [
 830           AS_IF([test "x$GCC" = "xyes"],
 831                 [
 832                   PKG_CHECK_MODULES([PROFILE_DEP], [uprof-0.3])
 833                   CLUTTER_PROFILE_CFLAGS="-DCLUTTER_ENABLE_PROFILE $PROFILE_DEP_CFLAGS"
 834                   CLUTTER_PROFILE_LDFLAGS="$PROFILE_DEP_LIBS"
 835
 836                   AS_IF([test "x$enable_debug" = "xyes"], [CLUTTER_PROFILE_CFLAGS+=" -DUPROF_DEBUG"])
 837                 ],
 838                 [
 839                   AC_MSG_ERROR([--enable-profile is currently only supported if using GCC])
 840                 ])
 841         ],
 842
 843         [no],
 844         [
 845           CLUTTER_PROFILE_CFLAGS=""
 846           CLUTTER_PROFILE_LDFLAGS=""
 847         ],
 848
 849         [*], [AC_MSG_ERROR([Invalid value for --enable-profile])]
 850 )
 851 AM_CONDITIONAL(PROFILE, test "x$enable_profile" != "xno")
 852 AC_SUBST(CLUTTER_PROFILE_CFLAGS)
 853 AC_SUBST(CLUTTER_PROFILE_LDFLAGS)
 854
 855 dnl === Coverage report =======================================================
 856
 857 AC_PATH_PROG([GCOV], [gcov], [enable_gcov=no])
 858
 859 AC_MSG_CHECKING([whether to build with gcov testing])
 860
 861 AC_ARG_ENABLE([gcov],
 862               [AS_HELP_STRING([--enable-gcov],
 863                               [Whether to enable coverage testing (requires gcc
 864 and gcov)])],
 865               [],
 866               [enable_gcov=no])
 867
 868 AS_IF([test "x$enable_gcov" = "xyes" && test "x$GCC" = "xyes"],
 869       [
 870         AS_IF([test "x$enable_conformance" = "xno"],
 871               [AC_MSG_WARN([Conformance test suite is disabled, the coverage report will be incomplete])],
 872               [AC_MSG_RESULT([yes])]
 873         )
 874
 875         GCOV_CFLAGS="-g -O0 -fprofile-arcs -ftest-coverage"
 876         GCOV_LDFLAGS="-lgcov"
 877       ],
 878       [AC_MSG_RESULT([no])]
 879 )
 880
 881 AM_CONDITIONAL([GCOV_ENABLED], [test "x$enable_gcov" = "xyes"])
 882 AC_SUBST([GCOV_CFLAGS])
 883 AC_SUBST([GCOV_LDFLAGS])
 884
 885 dnl === Enable strict compiler flags ==========================================
 886
 887 # use strict compiler flags only when building from git; the rules for
 888 # distcheck will take care of turning this on when making a release
 889 m4_define([maintainer_flags_default], [m4_if(m4_eval(clutter_micro_version % 2), [1], [yes], [no])])
 890 AC_ARG_ENABLE([maintainer-flags],
 891               [AS_HELP_STRING([--enable-maintainer-flags=@<:@no/yes/error@:>@],
 892                               [Use strict compiler flags @<:@default=]maintainer_flags_default[@:>@])],
 893               [],
 894               [enable_maintainer_flags=maintainer_flags_default])
 895
 896 MAINTAINER_COMPILER_FLAGS="$MAINTAINER_COMPILER_FLAGS
 897                            -Wall -Wcast-align -Wuninitialized
 898                            -Wno-strict-aliasing -Wempty-body -Wformat
 899                            -Wformat-security -Winit-self
 900                            -Wdeclaration-after-statement -Wvla
 901                            -Wpointer-arith"
 902
 903 AS_CASE([$enable_maintainer_flags],
 904         [yes],
 905         [
 906           AS_COMPILER_FLAGS([MAINTAINER_CFLAGS], [$MAINTAINER_COMPILER_FLAGS])
 907         ],
 908
 909         [no],
 910         [
 911         ],
 912
 913         [error],
 914         [
 915           MAINTAINER_COMPILER_FLAGS="$MAINTAINER_COMPILER_FLAGS -Werror"
 916           AS_COMPILER_FLAGS([MAINTAINER_CFLAGS], [$MAINTAINER_COMPILER_FLAGS])
 917         ],
 918
 919         [*],
 920         [AC_MSG_ERROR([Invalid option for --enable-maintainer-flags])]
 921 )
 922
 923 # strip leading spaces
 924 MAINTAINER_CFLAGS=${MAINTAINER_CFLAGS#*  }
 925 AC_SUBST(MAINTAINER_CFLAGS)
 926
 927 dnl === Dependencies, compiler flags and linker libraries =====================
 928 # strip leading space
 929 BACKEND_PC_FILES=${BACKEND_PC_FILES#* }
 930
 931 CLUTTER_REQUIRES="$CLUTTER_BASE_PC_FILES $IMAGE_PC_FILES $BACKEND_PC_FILES"
 932 PKG_CHECK_MODULES(CLUTTER_DEPS, [$CLUTTER_REQUIRES])
 933 AC_SUBST(CLUTTER_REQUIRES)
 934
 935 CLUTTER_CFLAGS="$FLAVOUR_CFLAGS $CLUTTER_DEPS_CFLAGS $CLUTTER_PROFILE_CFLAGS $GLIB_CFLAGS"
 936 CLUTTER_LIBS="$FLAVOUR_LIBS $CLUTTER_DEPS_LIBS $CLUTTER_PROFILE_LDFLAGS $GLIB_LIBS"
 937 AC_SUBST(CLUTTER_CFLAGS)
 938 AC_SUBST(CLUTTER_LIBS)
 939
 940
 941 dnl === GObject-Introspection check ===========================================
 942
 943 GOBJECT_INTROSPECTION_CHECK([gi_req_version])
 944
 945 dnl === GTK Doc check =========================================================
 946
 947 GTK_DOC_CHECK([gtk_doc_req_version], [--flavour no-tmpl])
 948
 949 # we don't want to build the documentation from a Git clone unless we
 950 # explicitly tell configure to do so; this allows avoiding to recurse into
 951 # the documentation directory when building Clutter inside Poky for a
 952 # target device that doesn't have gtk-doc installed. for reference
 953 # see: http://bugzilla.openedhand.com/show_bug.cgi?id=1047
 954 #
 955 # we use autogen.sh as it exists only inside the Git clones, and it
 956 # is not packaged into tarballs.
 957 AM_CONDITIONAL([BUILD_GTK_DOC], [test "x$enable_gtk_doc" = "xyes" || test ! -f "autogen.sh"])
 958
 959 # prefixes for fixing gtk-doc references
 960 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
 961 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 962 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
 963 COGL_PREFIX="`$PKG_CONFIG --variable=prefix cogl-1.0`"
 964 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
 965 AC_SUBST(CAIRO_PREFIX)
 966 AC_SUBST(GLIB_PREFIX)
 967 AC_SUBST(PANGO_PREFIX)
 968 AC_SUBST(COGL_PREFIX)
 969 AC_SUBST(ATK_PREFIX)
 970
 971 dnl === Manual ================================================================
 972
 973 AC_ARG_ENABLE([docs],
 974               [AS_HELP_STRING([--enable-docs=@<:@no/yes@:>@],
 975                               [Build optional documentation; requires xsltproc and jw.])],
 976               [enable_docs=$enableval],
 977               [enable_docs=no])
 978
 979 enable_pdfs=no
 980 AS_IF([test "x$enable_docs" = "xyes"],
 981       [
 982         AC_PATH_PROG(JW, [jw], [no])
 983         AS_IF([test "x$JW" = "xno"],
 984               [
 985                 AC_MSG_WARN([jw not found; pdf generation has been disabled])
 986               ],
 987               [enable_pdfs=yes])
 988
 989         AC_PATH_PROG(XSLTPROC, [xsltproc], [no])
 990         AS_IF([test "x$XSLTPROC" = "xno"],
 991               [
 992                 AC_MSG_ERROR([xsltproc not found])
 993               ])
 994       ]
 995 )
 996
 997 AM_CONDITIONAL(ENABLE_DOCS, [test "x$enable_docs" = "xyes"])
 998 AM_CONDITIONAL(ENABLE_PDFS, [test "x$enable_pdfs" = "xyes"])
 999
1000 dnl === I18N ==================================================================
1001
1002 AM_GNU_GETTEXT_VERSION([0.17])
1003 AM_GNU_GETTEXT([external])
1004
1005 GETTEXT_PACKAGE="clutter-1.0"
1006 AC_SUBST(GETTEXT_PACKAGE)
1007 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
1008                    ["$GETTEXT_PACKAGE"],
1009                    [The prefix for our gettext translation domains.])
1010 AS_ALL_LINGUAS
1011
1012 dnl ===========================================================================
1013
1014 AC_CONFIG_FILES([
1015         Makefile
1016         config.h.win32
1017         README
1018
1019         build/Makefile
1020         build/autotools/Makefile
1021         build/mingw/Makefile
1022         build/win32/Makefile
1023         build/win32/vs9/Makefile
1024         build/win32/vs10/Makefile
1025
1026         clutter/Makefile
1027         clutter/clutter-config.h
1028         clutter/clutter-version.h
1029         clutter/clutter-version.h.win32
1030         clutter/clutter-$CLUTTER_API_VERSION.pc:clutter/clutter.pc.in
1031
1032         clutter/cally/cally-$CLUTTER_API_VERSION.pc:clutter/cally/cally.pc.in
1033
1034         clutter/cex100/clutter-cex100.h
1035
1036         tests/Makefile
1037         tests/accessibility/Makefile
1038         tests/conform/Makefile
1039         tests/conform/test-launcher.sh
1040         tests/data/Makefile
1041         tests/interactive/Makefile
1042         tests/interactive/wrapper.sh
1043         tests/micro-bench/Makefile
1044         tests/performance/Makefile
1045
1046         doc/Makefile
1047         doc/reference/Makefile
1048         doc/reference/clutter/Makefile
1049         doc/reference/clutter/clutter-docs.xml
1050         doc/reference/cally/Makefile
1051         doc/reference/cally/cally-docs.xml
1052         doc/common/Makefile
1053         doc/cookbook/Makefile
1054         doc/cookbook/clutter-cookbook.xml
1055         doc/cookbook/examples/Makefile
1056
1057         po/Makefile.in
1058 ])
1059
1060 AC_OUTPUT
1061
1062 dnl === Summary ===============================================================
1063
1064 echo ""
1065 echo "Clutter - $VERSION (${CLUTTER_RELEASE_STATUS})"
1066
1067 # Global flags
1068 echo ""
1069 echo " • Global:"
1070 echo "        Prefix: ${prefix}"
1071 echo "        Libdir: ${libdir}"
1072 echo "        Sysconfdir: ${sysconfdir}"
1073
1074 # Compiler/Debug related flags
1075 echo ""
1076 echo " • Compiler options:"
1077 echo "        Clutter debug level: ${enable_debug}"
1078 echo "        Compiler flags: ${CFLAGS} ${MAINTAINER_CFLAGS}"
1079 echo "        Profiling enabled: ${enable_profile}"
1080 echo "        Enable coverage tests: ${enable_gcov}"
1081 echo "        Enable deprecated symbols: ${enable_deprecated}"
1082
1083 # Documentation
1084 echo ""
1085 echo " • Documentation:"
1086 echo "        Build API Reference: ${enable_gtk_doc}"
1087 echo "        Build Additional Documentation: ${enable_docs} (Generate PDF: ${enable_pdfs})"
1088
1089 # Miscellaneous
1090 echo ""
1091 echo " • Extra:"
1092 echo "        Build introspection data: ${enable_introspection}"
1093 echo "        Build conformance test suite: ${enable_conformance}"
1094 echo "        Build X11-specific tests: ${x11_tests}"
1095
1096 # Clutter backend related flags
1097 echo ""
1098 echo " • Clutter Backends:"
1099
1100 if test "x$experimental_backend" = "xno"; then
1101 echo "        Windowing systems: ${CLUTTER_BACKENDS}"
1102 else
1103 echo "        Windowing systems: ${CLUTTER_BACKENDS} (WARNING: Experimental backends enabled)"
1104 fi
1105
1106 if test "x$experimental_input_backend" = "xno"; then
1107 echo "        Input backends: ${CLUTTER_INPUT_BACKENDS}"
1108 else
1109 echo "        Input backends: ${CLUTTER_INPUT_BACKENDS} (WARNING: Experimental backends enabled)"
1110 fi
1111
1112 if test "x$SUPPORT_X11" = "x1"; then
1113 echo ""
1114 echo "     - X11 backend options:"
1115 echo "        Enabled extensions: ${X11_EXTS}"
1116 echo "        Build X11-specific tests: ${x11_tests}"
1117 fi
1118
1119 if test "x$SUPPORT_CEX100" = "x1"; then
1120 echo ""
1121 echo "     - CEx100 backend options:"
1122 echo "        libGDL include prefix: ${CLUTTER_CEX100_LIBGDL_PREFIX}"
1123 fi
1124
1125 echo ""
1126
1127 # General warning about experimental features
1128 if test "x$experimental_backend" = "xyes"; then
1129 echo ""
1130 echo "☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠"
1131 echo "*WARNING* *WARNING* *WARNING* *WARNING* *WARNING* *WARNING* *WARNING*"
1132 echo ""
1133 echo "  The stability of your build might be affected by one or more"
1134 echo "  experimental backends or experimental and unsupported features"
1135 echo ""
1136 echo "*WARNING* *WARNING* *WARNING* *WARNING* *WARNING* *WARNING* *WARNING*"
1137 echo "☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠"
1138 echo ""
1139 fi