configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_rev], m4_eval(v_maj + v_min))
  16 m4_define([lt_cur], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver.beta], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_ISC_POSIX
  28 AC_GNU_SOURCE
  29
  30 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  31 AM_CONFIG_HEADER([config.h])
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33
  34 AC_LIBTOOL_WIN32_DLL
  35 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  36 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  37 AC_PROG_LIBTOOL
  38
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  41 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  42 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  43 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  44 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  45 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  46 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  47 version_info="lt_rev:lt_cur:lt_age"
  48 release_info="v_rel"
  49 AC_SUBST(version_info)
  50 AC_SUBST(release_info)
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  53 VMAJ=v_maj
  54 AC_SUBST(VMAJ)
  55
  56 ### Needed information
  57
  58 requirement_eina=""
  59
  60 case "$host_os" in
  61    mingw32ce*)
  62       MODULE_ARCH="$host_os-$host_cpu"
  63       ;;
  64    *)
  65       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  66       ;;
  67 esac
  68 AC_SUBST(MODULE_ARCH)
  69 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  70
  71 case "$host_os" in
  72    mingw*)
  73       MODULE_EXT=".dll"
  74       ;;
  75    *)
  76       MODULE_EXT=".so"
  77       ;;
  78 esac
  79
  80 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "${MODULE_EXT}", [Suffix for shared objects])
  81
  82 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  83 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  84 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  85 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
  86
  87 EFL_CHECK_THREADS(
  88    [
  89     if test "x${_efl_have_posix_threads}" = "xyes" ; then
  90        have_threads="POSIX"
  91     else
  92        if test "x${_efl_have_win32_threads}" = "xyes" ; then
  93           have_threads="Win32"
  94        else
  95           have_threads="no"
  96        fi
  97     fi
  98    ],
  99    [have_threads="no"])
 100 EFL_CHECK_SPINLOCK([have_posix_threads_spinlock="yes"], [have_posix_threads_spinlock="no"])
 101
 102 ### Additional options to configure
 103
 104 # Magic debug
 105 AC_ARG_ENABLE([magic-debug],
 106    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 107    [
 108     if test "x${enableval}" = "xyes" ; then
 109        have_magic_debug="yes"
 110     else
 111        have_magic_debug="no"
 112     fi
 113    ],
 114    [have_magic_debug="yes"])
 115
 116 AC_MSG_CHECKING([whether magic debug is enable])
 117 AC_MSG_RESULT([${have_magic_debug}])
 118
 119 if test "x${have_magic_debug}" = "xyes" ; then
 120    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 121 fi
 122 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 123
 124 # Safety checks (avoid crashes on wrong api usage)
 125 AC_ARG_ENABLE(safety-checks,
 126    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 127    [
 128     if test "x${enableval}" = "xyes" ; then
 129        have_safety_checks="yes"
 130     else
 131        have_safety_checks="no"
 132     fi
 133    ],
 134    [have_safety_checks="yes"])
 135
 136 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 137 AC_MSG_RESULT($have_safety_checks)
 138
 139 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 140 if test "x$have_safety_checks" = "xyes"; then
 141   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 142   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 143 fi
 144 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 145
 146 with_max_log_level="<unset>"
 147 AC_ARG_WITH(internal-maximum-log-level,
 148    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 149                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 150    [
 151     if test "x${withval}" != "xno"; then
 152        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
 153           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 154           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 155           with_max_log_level="${withval}"
 156        else
 157           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 158        fi
 159     fi
 160     ], [:])
 161
 162 AC_ARG_ENABLE([amalgamation],
 163    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 164    [if test "x${enableval}" = "xyes"; then
 165        do_amalgamation="yes"
 166     else
 167        do_amalgamation="no"
 168     fi
 169    ],
 170    [do_amalgamation="no"]
 171 )
 172 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 173
 174 # Choose best memory pool
 175 AC_ARG_ENABLE([default-mempool],
 176    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 177    [
 178     if test "x${enableval}" = "xyes"; then
 179        have_default_mempool="yes"
 180     else
 181        have_default_mempool="no"
 182     fi
 183    ],
 184    [have_default_mempool="no"]
 185 )
 186 AC_MSG_CHECKING([whether to use default mempool allocator])
 187 AC_MSG_RESULT([${have_default_mempool}])
 188
 189 if test "x${have_default_mempool}" = "xyes" ; then
 190    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 191 fi
 192 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 193
 194 # Report stringshare usage
 195 AC_ARG_ENABLE([stringshare-usage],
 196    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 197    [
 198     if test "x${enableval}" = "xyes"; then
 199        have_stringshare_usage="yes"
 200     else
 201        have_stringshare_usage="no"
 202     fi
 203    ],
 204    [have_stringshare_usage="no"]
 205 )
 206 AC_MSG_CHECKING([whether to report stringshare usage])
 207 AC_MSG_RESULT([${have_stringshare_usage}])
 208
 209 if test "x${have_stringshare_usage}" = "xyes"; then
 210    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 211 fi
 212
 213 # Check if we want to benchmark on real data
 214 enable_benchmark_e17="no"
 215 AC_ARG_ENABLE([e17],
 216    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 217    [
 218     if test "x${enableval}" = "xyes" ; then
 219        enable_benchmark_e17="yes"
 220     else
 221        enable_benchmark_e17="no"
 222     fi
 223    ],
 224    [enable_benchmark_e17="no"])
 225
 226 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 227 AC_MSG_RESULT([${enable_benchmark_e17}])
 228
 229 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 230
 231
 232 ### Checks for programs
 233 AC_PROG_CC
 234
 235 # pkg-config
 236 PKG_PROG_PKG_CONFIG
 237
 238 # Check whether pkg-config supports Requires.private
 239 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 240    pkgconfig_requires_private="Requires.private"
 241 else
 242    pkgconfig_requires_private="Requires"
 243 fi
 244 AC_SUBST(pkgconfig_requires_private)
 245
 246 # doxygen program for documentation building
 247
 248 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 249
 250
 251 ### Checks for libraries
 252
 253 # Evil library for compilation on Windows CE
 254
 255 EFL_EINA_BUILD=""
 256 case "$host_os" in
 257    mingw*)
 258       PKG_CHECK_MODULES([EVIL], [evil])
 259       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if evil package is installed])
 260       requirement_eina="evil"
 261       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 262    ;;
 263 esac
 264 AC_SUBST(EFL_EINA_BUILD)
 265
 266 # Check ememoa memory pool library
 267
 268 AC_ARG_ENABLE([ememoa],
 269    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 270    [
 271     if test "x${enableval}" = "xyes" ; then
 272        enable_ememoa="yes"
 273     else
 274        enable_ememoa="no"
 275     fi
 276    ],
 277    [enable_ememoa="yes"]
 278 )
 279 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 280 AC_MSG_RESULT([$enable_ememoa])
 281
 282 if test "x${enable_ememoa}" = "xyes" ; then
 283    PKG_CHECK_MODULES([EMEMOA],
 284       [ememoa >= 0.0.26 ],
 285       [enable_ememoa="yes"],
 286       [enable_ememoa="no"]
 287    )
 288 fi
 289
 290
 291 ### Checks for header files
 292 AC_HEADER_ASSERT
 293 AC_HEADER_DIRENT
 294 AC_HEADER_TIME
 295
 296
 297 ### Checks for types
 298 AC_CHECK_HEADER([inttypes.h],
 299                 [EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"])
 300 AC_SUBST(EINA_CONFIGURE_HAVE_INTTYPES_H)
 301
 302 AC_CHECK_HEADER([stdint.h],
 303                 [EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"])
 304 AC_SUBST(EINA_CONFIGURE_HAVE_STDINT_H)
 305
 306 AC_CHECK_SIZEOF(wchar_t)
 307 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 308 AC_SUBST(EINA_SIZEOF_WCHAR_T)
 309
 310 ### Checks for structures
 311
 312
 313 ### Checks for compiler characteristics
 314 AC_C_CONST
 315 AC_C_BIGENDIAN
 316 AC_C_INLINE
 317 AC_C___ATTRIBUTE__
 318 AC_PROG_CC_STDC
 319
 320 EINA_CPPFLAGS=""
 321 EINA_CFLAGS=""
 322 case "$host_os" in
 323    mingw32ce*)
 324       EINA_CPPFLAGS="-D_WIN32_WCE=0x0420"
 325       EINA_CFLAGS="${EVIL_CFLAGS}"
 326       ;;
 327    mingw*)
 328       EINA_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 329       EINA_CFLAGS="${EVIL_CFLAGS}"
 330       ;;
 331 esac
 332
 333 m4_ifdef([v_mic],
 334    [
 335     EFL_COMPILER_FLAG([-Wall])
 336     EFL_COMPILER_FLAG([-W])
 337    ])
 338
 339 EFL_COMPILER_FLAG([-Wshadow])
 340
 341 AC_SUBST(EINA_CPPFLAGS)
 342 AC_SUBST(EINA_CFLAGS)
 343
 344
 345 ### Checks for linker characteristics
 346 EINA_LIBS=
 347 lt_enable_auto_import=""
 348 case "${host_os}" in
 349    mingw*)
 350       EINA_LIBS="-ldl ${EVIL_LIBS} -lm"
 351       lt_enable_auto_import="-Wl,--enable-auto-import"
 352    ;;
 353    dragonfly*|openbsd*)
 354       EINA_LIBS="-lm"
 355    ;;
 356    freebsd*|netbsd*)
 357       EINA_LIBS="-lrt -lm"
 358    ;;
 359    darwin*)
 360       EINA_LIBS="-lm"
 361    ;;
 362    cygwin*)
 363       EINA_LIBS="-ldl -lm"
 364    ;;
 365    *)
 366       EINA_LIBS="-ldl -lrt -lm"
 367    ;;
 368 esac
 369 AC_SUBST(EINA_LIBS)
 370 AC_SUBST(lt_enable_auto_import)
 371
 372 EFL_LINKER_FLAG([-fno-strict-aliasing])
 373
 374
 375 ### Checks for library functions
 376 AC_FUNC_ALLOCA
 377 AC_CHECK_FUNCS(strlcpy)
 378
 379 #dlopen and dladdr
 380 dlopen_libs=""
 381 case "$host_os" in
 382    mingw*)
 383 # managed by evil
 384       AC_DEFINE(HAVE_DLADDR)
 385       ;;
 386    *)
 387       AC_CHECK_FUNCS([dlopen], [res="yes"], [res="no"])
 388       if test "x${res}" = "xyes" ; then
 389          AC_CHECK_FUNCS([dladdr], [AC_DEFINE(HAVE_DLADDR)])
 390       else
 391          AC_CHECK_LIB([dl], [dlopen], [res="yes"], [res="no"])
 392          if test "x${res}" = "xyes" ; then
 393             AC_CHECK_LIB([dl], [dladdr], [AC_DEFINE(HAVE_DLADDR)])
 394             dlopen_libs="-ldl"
 395          else
 396             AC_MSG_ERROR([Cannot find dlopen])
 397          fi
 398       fi
 399       ;;
 400 esac
 401 AC_SUBST(dlopen_libs)
 402
 403 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 404
 405 # iconv library
 406 have_iconv="no"
 407 AC_ARG_WITH([iconv-link],
 408    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 409    [
 410     LIBS="$withval $LIBS"
 411     have_iconv="yes"
 412    ])
 413
 414 AC_MSG_CHECKING(for explicit iconv link options)
 415 if test "x${iconv_libs}" = "x" ; then
 416    AC_MSG_RESULT([no explicit iconv link option])
 417 else
 418    AC_MSG_RESULT([$iconv_libs])
 419 fi
 420
 421 if test "x${have_iconv}" = "xno" ; then
 422    AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 423
 424    if test "x${have_iconv}" = "xyes" ; then
 425       AC_MSG_CHECKING([whether iconv() is in libc])
 426
 427       AC_LINK_IFELSE(
 428          [AC_LANG_PROGRAM(
 429              [[
 430 #include <stdlib.h>
 431 #include <iconv.h>
 432              ]],
 433              [[
 434 iconv_t ic;
 435 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 436              ]])],
 437          [have_iconv="yes"],
 438          [have_iconv="no"])
 439
 440       AC_MSG_RESULT([${have_iconv}])
 441    fi
 442
 443    if test "x${have_iconv}" = "xno" ; then
 444       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 445
 446       LIBS_save="${LIBS}"
 447       LIBS="-liconv $LIBS"
 448       AC_LINK_IFELSE(
 449          [AC_LANG_PROGRAM(
 450              [[
 451 #include <stdlib.h>
 452 #include <iconv.h>
 453              ]],
 454              [[
 455 iconv_t ic;
 456 size_t count;
 457 count = iconv(ic, NULL, NULL, NULL, NULL);
 458              ]])],
 459          [have_iconv="yes"],
 460          [
 461           have_iconv="no"
 462           LIBS=${LIBS_save}
 463          ])
 464
 465       AC_MSG_RESULT([${have_iconv}])
 466    fi
 467
 468    if test "x${have_iconv}" = "xno" ; then
 469       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 470
 471       LIBS_save="${LIBS}"
 472       LIBS="-liconv_plug $LIBS"
 473       AC_LINK_IFELSE(
 474          [AC_LANG_PROGRAM(
 475              [[
 476 #include <stdlib.h>
 477 #include <iconv.h>
 478              ]],
 479              [[
 480 iconv_t ic;
 481 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 482              ]])],
 483          [have_iconv="yes"],
 484          [
 485           have_iconv="no"
 486           LIBS=${LIBS_save}
 487          ])
 488
 489       AC_MSG_RESULT([${have_iconv}])
 490    fi
 491 fi
 492
 493 if test "x${have_iconv}" = "xyes" ; then
 494    AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 495 fi
 496
 497
 498 ### Modules
 499
 500 if test "x${have_default_mempool}" = "xyes" ; then
 501    enable_chained_pool="no"
 502    enable_pass_through="static"
 503 else
 504    enable_chained_pool="static"
 505    enable_pass_through="no"
 506 fi
 507
 508 enable_one_big="static"
 509
 510 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 511 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 512 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 513 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 514 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 515 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 516 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 517
 518 ### Make the debug preprocessor configurable
 519
 520 ### Unit tests, coverage and benchmarking
 521
 522 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 523
 524 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 525 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 526 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 527 if test "x$enable_coverage" = "xyes" ; then
 528    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 529 fi
 530
 531 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 532 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 533
 534 AC_SUBST(requirement_eina)
 535
 536 ### Create the .pc.in file according to the major version
 537 #cat > ${srcdir}/eina-${VMAJ}.pc.in << EOF
 538 #prefix=@prefix@
 539 #exec_prefix=@exec_prefix@
 540 #libdir=@libdir@
 541 #includedir=@includedir@
 542 #
 543 #Name: Eina
 544 #Description: A Library that implements fast data types and miscellaneous tools
 545 #Requires:
 546 #Version: @VERSION@
 547 #Libs: -L${libdir} -leina
 548 #Libs.private: -ldl
 549 #Cflags: -I${includedir}/eina-@VMAJ@ -I${includedir}/eina-@VMAJ@/eina
 550 #EOF
 551
 552 AC_CONFIG_FILES([
 553 Makefile
 554 eina.pc
 555 eina.spec
 556 doc/Makefile
 557 src/Makefile
 558 src/include/Makefile
 559 src/include/eina_config.h
 560 src/lib/Makefile
 561 src/modules/Makefile
 562 src/modules/mp/Makefile
 563 src/modules/mp/chained_pool/Makefile
 564 src/modules/mp/ememoa_fixed/Makefile
 565 src/modules/mp/ememoa_unknown/Makefile
 566 src/modules/mp/pass_through/Makefile
 567 src/modules/mp/fixed_bitmap/Makefile
 568 src/modules/mp/buddy/Makefile
 569 src/modules/mp/one_big/Makefile
 570 src/tests/Makefile
 571 ])
 572
 573 AC_OUTPUT
 574
 575 #####################################################################
 576 ## Info
 577
 578 echo
 579 echo
 580 echo
 581 echo "------------------------------------------------------------------------"
 582 echo "$PACKAGE $VERSION"
 583 echo "------------------------------------------------------------------------"
 584 echo
 585 echo
 586 echo "Configuration Options Summary:"
 587 echo
 588 echo "  Magic debug..........: ${have_magic_debug}"
 589 echo "  Safety checks........: ${have_safety_checks}"
 590 echo "  Maximum log level....: ${with_max_log_level}"
 591 echo "  Report string usage..: ${have_stringshare_usage}"
 592 echo "  Default mempool......: ${have_default_mempool}"
 593 echo "  Thread Support.......: ${have_threads}"
 594 if test "${have_threads}" = "POSIX" ; then
 595 echo "    spinlock...........: ${have_posix_threads_spinlock}"
 596 echo "    debug usage........: ${have_debug_threads}"
 597 fi
 598 echo "  Amalgamation.........: ${do_amalgamation}"
 599 echo "  Iconv support........: ${have_iconv}"
 600 echo
 601 echo "  Documentation........: ${build_doc}"
 602 echo "  Tests................: ${enable_tests}"
 603 echo "  Coverage.............: ${enable_coverage}"
 604 echo "  Benchmark............: ${enable_benchmark}"
 605 if test "x${enable_benchmark}" = "xyes" ; then
 606 echo "    Glib...............: ${enable_benchmark_glib}"
 607 echo "    E17 real data......: ${enable_benchmark_e17}"
 608 fi
 609 echo
 610 echo "  CPU Specific Extensions:"
 611 echo "    MMX................: ${have_mmx}"
 612 echo "    SSE................: ${have_sse}"
 613 echo "    SSE2...............: ${have_sse2}"
 614 echo "    ALTIVEC............: ${have_altivec}"
 615 echo
 616 echo "  Memory pools:"
 617 echo "    Chained pool.......: ${enable_chained_pool}"
 618 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 619 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 620 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 621 echo "    Pass through.......: ${enable_pass_through}"
 622 echo "    Buddy..............: ${enable_buddy}"
 623 echo "    One big............: ${enable_one_big}"
 624 echo
 625 echo "Compilation............: make (or gmake)"
 626 echo "  CPPFLAGS.............: $CPPFLAGS"
 627 echo "  CFLAGS...............: $CFLAGS"
 628 echo "  LDFLAGS..............: $LDFLAGS"
 629 echo
 630 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 631 echo "  prefix...............: $prefix"
 632 echo
 633 EFL_FORM_VOLTRON