configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [999])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([ecore], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25
  26 AC_CONFIG_HEADERS([config.h])
  27 AH_TOP([
  28 #ifndef EFL_CONFIG_H__
  29 #define EFL_CONFIG_H__
  30 ])
  31 AH_BOTTOM([
  32 #endif /* EFL_CONFIG_H__ */
  33 ])
  34
  35 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_GNU_SOURCE
  39
  40 AC_LIBTOOL_WIN32_DLL
  41 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  42 AC_PROG_LIBTOOL
  43
  44 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  45 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  46 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  47 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  48 AC_DEFINE_UNQUOTED(VERS_MAJ, [v_maj], [Major version])
  49 AC_DEFINE_UNQUOTED(VERS_MIN, [v_min], [Minor version])
  50 AC_DEFINE_UNQUOTED(VERS_MIC, [v_mic], [Micro version])
  51 AC_DEFINE_UNQUOTED(VERS_REV, [v_rev], [Revison])
  52 version_info="lt_cur:lt_rev:lt_age"
  53 release_info="v_rel"
  54 AC_SUBST(version_info)
  55 AC_SUBST(release_info)
  56 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  57 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  58 VMAJ=v_maj
  59 AC_SUBST(VMAJ)
  60
  61 m4_ifdef([AM_GNU_GETTEXT_VERSION], [
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 ])
  64
  65 m4_ifdef([AM_GNU_GETTEXT], [
  66 AM_GNU_GETTEXT([external])
  67 po_makefile_in=po/Makefile.in
  68 have_po="yes"
  69 ],[
  70 have_po="no"
  71 ])
  72 AC_SUBST(LTLIBINTL)
  73
  74 if test "x${POSUB}" = "x" ; then
  75    have_po="no"
  76 fi
  77
  78 AM_CONDITIONAL([HAVE_PO], [test "x${have_po}" = "xyes"])
  79
  80 with_max_log_level="<unset>"
  81 AC_ARG_WITH(internal-maximum-log-level,
  82    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
  83                    [limit ecore internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
  84    [
  85     if test "x${withval}" != "xno"; then
  86        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
  87           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
  88           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
  89           with_max_log_level="${withval}"
  90        else
  91           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
  92        fi
  93     fi
  94     ], [:])
  95
  96
  97 ### Default options with respect to host
  98
  99 AC_CANONICAL_BUILD
 100 AC_CANONICAL_HOST
 101
 102 # dependencies and options
 103 want_curl="no"
 104 want_local_sockets="yes"
 105 want_abstract_sockets="no"
 106 want_gnutls="no"
 107 want_openssl="no"
 108 want_cares="no"
 109 want_cipher="no"
 110 want_signature="no"
 111 want_poll="yes"
 112 want_inotify="no"
 113 want_notify_win32="no"
 114 want_tslib="no"
 115 want_glib="no"
 116
 117 # core modules
 118 want_ecore_con="yes"
 119 want_ecore_ipc="yes"
 120 want_ecore_file="yes"
 121 #want_ecore_config="no"
 122 want_ecore_imf="no"
 123 want_ecore_input="yes"
 124
 125 # graphic system modules
 126 want_evas_simple_x11="no"
 127 want_ecore_x_xcb="no"
 128 want_ecore_x="no"
 129 want_ecore_win32="no"
 130 want_ecore_cocoa="no"
 131 want_ecore_sdl="no"
 132 want_ecore_psl1ght="no"
 133 want_ecore_fb="no"
 134 want_ecore_directfb="no"
 135 want_ecore_wince="no"
 136
 137 # ecore_x options (both xlib and xcb)
 138 want_ecore_x_composite="yes"
 139 want_ecore_x_damage="yes"
 140 want_ecore_x_dpms="yes"
 141 want_ecore_x_randr="yes"
 142 want_ecore_x_render="yes"
 143 want_ecore_x_screensaver="yes"
 144 want_ecore_x_shape="yes"
 145 want_ecore_x_gesture="no"
 146 want_ecore_x_sync="yes"
 147 want_ecore_x_xfixes="yes"
 148 want_ecore_x_xinerama="yes"
 149 want_ecore_x_xprint="yes"
 150 want_ecore_x_xtest="yes"
 151 want_ecore_x_cursor="yes"
 152 want_ecore_x_input="yes"
 153 want_ecore_x_dri="yes"
 154
 155 # ecore_evas modules
 156 want_ecore_evas="yes"
 157 want_ecore_evas_software_buffer="yes"
 158 want_ecore_evas_software_x11="no"
 159 want_ecore_evas_opengl_x11="no"
 160 want_ecore_evas_software_16_x11="no"
 161 want_ecore_evas_software_8_x11="no"
 162 want_ecore_evas_software_xcb="no"
 163 want_ecore_evas_software_gdi="no"
 164 want_ecore_evas_software_ddraw="no"
 165 want_ecore_evas_direct3d="no"
 166 want_ecore_evas_opengl_glew="no"
 167 want_ecore_evas_software_16_ddraw="no"
 168 want_ecore_evas_software_sdl="no"
 169 want_ecore_evas_gl_sdl="no"
 170 want_ecore_evas_gl_cocoa="no"
 171 want_ecore_evas_directfb="no"
 172 want_ecore_evas_fb="no"
 173 want_ecore_evas_software_16_wince="no"
 174 want_ecore_evas_ews="yes"
 175
 176 # ecore_imf modules
 177 want_ecore_imf_xim="no"
 178
 179 case "$host_os" in
 180    mingw32ce* | cegcc*)
 181       want_ecore_con="no"
 182       want_ecore_ipc="no"
 183       want_ecore_wince="yes"
 184       want_ecore_evas_software_16_wince="yes"
 185       ;;
 186    mingw*)
 187       want_notify_win32="yes"
 188       want_curl="yes"
 189       want_glib="auto"
 190       want_gnutls="auto"
 191       want_openssl="auto"
 192       want_ecore_imf="yes"
 193       want_ecore_win32="yes"
 194       want_ecore_evas_software_gdi="yes"
 195       want_ecore_evas_software_ddraw="yes"
 196       want_ecore_evas_direct3d="yes"
 197       want_ecore_evas_opengl_glew="yes"
 198       want_ecore_evas_software_16_ddraw="auto"
 199       want_ecore_evas_software_sdl="yes"
 200       want_ecore_evas_gl_sdl="yes"
 201       ;;
 202    darwin*)
 203       want_curl="yes"
 204       want_glib="auto"
 205       want_gnutls="auto"
 206       want_openssl="auto"
 207       want_ecore_imf="yes"
 208       want_ecore_cocoa="yes"
 209       want_ecore_evas_software_sdl="yes"
 210       want_ecore_evas_gl_sdl="yes"
 211       want_ecore_evas_gl_cocoa="yes"
 212       ;;
 213    *)
 214       want_curl="yes"
 215       want_glib="auto"
 216       want_abstract_sockets="yes"
 217       want_gnutls="auto"
 218       want_openssl="auto"
 219       want_cipher="yes"
 220       want_signature="yes"
 221       want_inotify="yes"
 222       want_tslib="yes"
 223       want_ecore_fb="yes"
 224       want_ecore_imf="yes"
 225       want_ecore_x="yes"
 226       want_ecore_evas_software_x11="yes"
 227       want_ecore_evas_opengl_x11="yes"
 228       want_ecore_evas_software_16_x11="yes"
 229       want_ecore_evas_software_8_x11="yes"
 230       want_ecore_evas_software_xcb="no"
 231       want_ecore_evas_software_sdl="yes"
 232       want_ecore_evas_gl_sdl="yes"
 233       want_ecore_evas_gl_cocoa="no"
 234       want_ecore_evas_directfb="yes"
 235       want_ecore_evas_fb="yes"
 236       want_ecore_imf_xim="yes"
 237       ;;
 238 esac
 239
 240 case "$host_vendor" in
 241   ps3*)
 242       want_local_sockets="no"
 243       ;;
 244 esac
 245 requirements_ecore=""
 246 requirements_ecore_con=""
 247 #requirements_ecore_config=""
 248 requirements_ecore_directfb=""
 249 requirements_ecore_evas=""
 250 requirements_ecore_fb=""
 251 requirements_ecore_file=""
 252 requirements_ecore_imf=""
 253 requirements_ecore_imf_evas=""
 254 requirements_ecore_input=""
 255 requirements_ecore_input_evas=""
 256 requirements_ecore_ipc=""
 257 requirements_ecore_cocoa=""
 258 requirements_ecore_sdl=""
 259 requirements_ecore_psl1ght=""
 260 requirements_ecore_x=""
 261 requirements_ecore_win32=""
 262 requirements_ecore_wince=""
 263 requirements_ecore_imf_xim=""
 264
 265 AC_CHECK_DECL([MAXHOSTNAMELEN],[FOUND_MAXHOSTNAMELEN=yes])
 266
 267 if test x$FOUND_MAXHOSTNAMELEN != xyes ; then
 268   AC_MSG_CHECKING([for header that defines MAXHOSTNAMELEN])
 269
 270   FOUND_MAXHOSTNAMELEN='not found'
 271
 272   AC_COMPILE_IFELSE(
 273         AC_LANG_PROGRAM([#include <sys/param.h>],
 274                 [int h = MAXHOSTNAMELEN;]),
 275         [FOUND_MAXHOSTNAMELEN='sys/param.h'
 276            AC_DEFINE(NEED_SYS_PARAM_H,1,
 277              [Define to 1 if you need <sys/param.h> to define MAXHOSTNAMELEN])])
 278
 279         AC_COMPILE_IFELSE(
 280             AC_LANG_PROGRAM([#include <netdb.h>],
 281                             [int h = MAXHOSTNAMELEN;]),
 282             [FOUND_MAXHOSTNAMELEN='netdb.h'
 283              AC_DEFINE(NEED_NETDB_H,1,
 284                [Define to 1 if you need <netdb.h> to define MAXHOSTNAMELEN])])
 285
 286   AC_MSG_RESULT([$FOUND_MAXHOSTNAMELEN])
 287 fi
 288
 289 ### Additional options to configure
 290
 291 want_glib_integration_always=no
 292 AC_ARG_ENABLE(glib-integration-always,
 293   AC_HELP_STRING([--enable-glib-integration-always], [enable glib integration when ecore_init() is called always]),
 294   [want_glib_integration_always=$enableval])
 295
 296 if test "x${want_glib_integration_always}" = "xyes" ; then
 297   AC_DEFINE([GLIB_INTEGRATION_ALWAYS], [1], [Always integrate glib if support compiled])
 298   want_glib=yes
 299 fi
 300
 301 want_g_main_loop=no
 302 AC_ARG_ENABLE(g-main-loop,
 303   AC_HELP_STRING([--enable-g-main-loop], [ecore_main_loop based on g_main_loop]),
 304   [want_g_main_loop=$enableval])
 305
 306 if test "x${want_g_main_loop}" = "xyes" ; then
 307   AC_DEFINE([USE_G_MAIN_LOOP], [1], [Use g_main_loop in ecore])
 308   want_glib=yes
 309 fi
 310
 311 if test "x${want_glib_integration_always}" = "xyes" -a "x${want_g_main_loop}" = "xyes"; then
 312   AC_MSG_ERROR([--enable-glib-integration-always and --enable-glib-main-loop are mutually exclusive])
 313 fi
 314
 315 # local sockets (ecore_con.c)
 316 AC_ARG_ENABLE([local-sockets],
 317    [AC_HELP_STRING([--disable-local-sockets], [disable local sockets.])],
 318    [
 319     if test "x${enableval}" = "xyes" ; then
 320        want_ecore_con_local_sockets="yes"
 321     else
 322        want_ecore_con_local_sockets="no"
 323     fi
 324    ],
 325    [want_ecore_con_local_sockets=${want_local_sockets}])
 326
 327 if test "x${want_ecore_con_local_sockets}" = "xyes" ; then
 328    AC_DEFINE([HAVE_LOCAL_SOCKETS], [1], [Have local sockets support])
 329 fi
 330
 331 # abstract sockets (ecore_con.c)
 332 AC_ARG_ENABLE([abstract-sockets],
 333    [AC_HELP_STRING([--disable-abstract-sockets], [disable abstract sockets.])],
 334    [
 335     if test "x${enableval}" = "xyes" ; then
 336        want_ecore_con_abstract_sockets="yes"
 337     else
 338        want_ecore_con_abstract_sockets="no"
 339     fi
 340    ],
 341    [want_ecore_con_abstract_sockets=${want_abstract_sockets}])
 342
 343 if test "x${want_ecore_con_abstract_sockets}" = "xyes" ; then
 344    AC_DEFINE([HAVE_ABSTRACT_SOCKETS], [1], [Have abstract sockets namespace])
 345 fi
 346
 347 # Simple X11 build/link
 348
 349 AC_ARG_ENABLE(simple-x11,
 350   AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking]),
 351   [want_evas_simple_x11=$enableval])
 352
 353 # XIM
 354 AC_ARG_ENABLE([xim],
 355    [AC_HELP_STRING([--disable-xim], [disable X Input Method.])],
 356    [
 357     if test "x${enableval}" = "xyes" ; then
 358        want_xim="yes"
 359     else
 360        want_xim="no"
 361     fi
 362    ],
 363    [want_xim="yes"])
 364
 365 if test "x${want_xim}" = "xyes" ; then
 366    AC_DEFINE([ENABLE_XIM], [1], [Enable X Input Method])
 367 fi
 368
 369 # Unit tests
 370
 371 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 372
 373 ### Checks for programs
 374
 375 m4_ifdef([AC_PROG_OBJC],
 376    [
 377     AC_PROG_OBJC
 378     _AM_DEPENDENCIES(OBJC)
 379    ],
 380    [
 381     AC_CHECK_TOOL([OBJC], [gcc])
 382     AC_SUBST([OBJC])
 383     AC_SUBST([OBJCFLAGS])
 384    ])
 385 m4_ifndef([am__fastdepOBJC], [
 386     AM_CONDITIONAL([am__fastdepOBJC], [false])
 387     AC_SUBST([cocoa_ldflags])
 388 ])
 389
 390 AC_PROG_CXX
 391 AC_PROG_CC
 392
 393 have_gnu_objc=${ac_cv_objc_compiler_gnu}
 394
 395 # doxygen program for documentation building
 396
 397 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 398
 399 m4_ifdef([v_mic],
 400    [
 401     EFL_COMPILER_FLAG([-Wall])
 402     EFL_COMPILER_FLAG([-W])
 403    ])
 404
 405 # The first call to PKG_CHECK_MODULES is done conditionally,
 406 # so we should include this here:
 407 PKG_PROG_PKG_CONFIG
 408
 409 # Check whether pkg-config supports Requires.private
 410 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 411    pkgconfig_requires_private="Requires.private"
 412 else
 413    pkgconfig_requires_private="Requires"
 414 fi
 415 AC_SUBST(pkgconfig_requires_private)
 416
 417 ### Checks for some build time option
 418 have_backtrace="no"
 419 AC_CHECK_FUNCS([backtrace], [have_backtrace="yes"], [])
 420
 421 want_ecore_timer_dump="yes"
 422
 423 AC_ARG_ENABLE([ecore-timer-dump],
 424    [AC_HELP_STRING([--disable-ecore-timer-dump], [disable tracking of timer allocation. @<:@default=enable@:>@])],
 425    [want_ecore_timer_dump=$enableval], [])
 426
 427 if test "x$want_ecore_timer_dump" = "xyes" -a "x$have_backtrace" = "xyes"; then
 428    AC_DEFINE(WANT_ECORE_TIMER_DUMP, [1], [Want Ecore_Timer dump infrastructure])
 429 fi
 430
 431 ### Checks for libraries
 432
 433 # Evil library for compilation on Windows
 434
 435 case "$host_os" in
 436    mingw* | cegcc*)
 437       PKG_CHECK_MODULES([EVIL], [evil])
 438       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 439       requirements_ecore="evil ${requirements_ecore}"
 440       requirements_ecore_evas="evil ${requirements_ecore_evas}"
 441       requirements_ecore_file="evil ${requirements_ecore_file}"
 442       requirements_ecore_imf="evil ${requirements_ecore_imf}"
 443       requirements_ecore_imf_evas="evil ${requirements_ecore_imf_evas}"
 444       EFL_ECORE_BUILD="-DEFL_ECORE_BUILD"
 445       EFL_ECORE_CON_BUILD="-DEFL_ECORE_CON_BUILD"
 446       EFL_ECORE_EVAS_BUILD="-DEFL_ECORE_EVAS_BUILD"
 447       EFL_ECORE_FILE_BUILD="-DEFL_ECORE_FILE_BUILD"
 448       EFL_ECORE_IMF_BUILD="-DEFL_ECORE_IMF_BUILD"
 449       EFL_ECORE_IMF_EVAS_BUILD="-DEFL_ECORE_IMF_EVAS_BUILD"
 450       EFL_ECORE_INPUT_BUILD="-DEFL_ECORE_INPUT_BUILD"
 451       EFL_ECORE_INPUT_EVAS_BUILD="-DEFL_ECORE_INPUT_EVAS_BUILD"
 452       EFL_ECORE_IPC_BUILD="-DEFL_ECORE_IPC_BUILD"
 453       ;;
 454 esac
 455
 456 have_win32=""
 457 have_wince=""
 458 case "$host_os" in
 459    mingw32ce* | cegcc*)
 460       EFL_ECORE_WINCE_BUILD="-DEFL_ECORE_WINCE_BUILD"
 461       requirements_ecore_wince="evil ${requirements_ecore_wince}"
 462       have_wince="yes"
 463       ;;
 464    mingw*)
 465       EFL_ECORE_WIN32_BUILD="-DEFL_ECORE_WIN32_BUILD"
 466       EFL_ECORE_SDL_BUILD="-DEFL_ECORE_SDL_BUILD"
 467       requirements_ecore_win32="evil ${requirements_ecore_win32}"
 468       requirements_ecore_sdl="evil ${requirements_ecore_sdl}"
 469       have_win32="yes"
 470       ;;
 471 esac
 472
 473 have_ps3=""
 474 case "$host_vendor" in
 475   ps3*)
 476       have_ps3="yes"
 477       PKG_CHECK_MODULES([ESCAPE], [escape])
 478       CFLAGS="$CFLAGS $ESCAPE_CFLAGS"
 479       AC_DEFINE(HAVE_ESCAPE, 1, [Set to 1 if Escape library is installed])
 480       EFL_ECORE_PSL1GHT_BUILD="-DEFL_ECORE_PSL1GHT_BUILD"
 481       requirements_ecore="escape ${requirements_ecore}"
 482       requirements_ecore_evas="escape ${requirements_ecore_evas}"
 483       requirements_ecore_file="escape ${requirements_ecore_file}"
 484       requirements_ecore_imf="escape ${requirements_ecore_imf}"
 485       requirements_ecore_imf_evas="escape ${requirements_ecore_imf_evas}"
 486       requirements_ecore_sdl="escape ${requirements_ecore_sdl}"
 487       want_ecore_psl1ght="yes"
 488       ;;
 489 esac
 490
 491 AC_SUBST(EFL_ECORE_BUILD)
 492 AC_SUBST(EFL_ECORE_CON_BUILD)
 493 AC_SUBST(EFL_ECORE_EVAS_BUILD)
 494 AC_SUBST(EFL_ECORE_FILE_BUILD)
 495 AC_SUBST(EFL_ECORE_IMF_BUILD)
 496 AC_SUBST(EFL_ECORE_IMF_EVAS_BUILD)
 497 AC_SUBST(EFL_ECORE_INPUT_BUILD)
 498 AC_SUBST(EFL_ECORE_INPUT_EVAS_BUILD)
 499 AC_SUBST(EFL_ECORE_IPC_BUILD)
 500 AC_SUBST(EFL_ECORE_WINCE_BUILD)
 501 AC_SUBST(EFL_ECORE_WIN32_BUILD)
 502 AC_SUBST(EFL_ECORE_SDL_BUILD)
 503 AC_SUBST(EFL_ECORE_PSL1GHT_BUILD)
 504
 505 AM_CONDITIONAL(ECORE_HAVE_WINCE, test "x${have_wince}" = "xyes")
 506 AM_CONDITIONAL(ECORE_HAVE_WIN32, test "x${have_win32}" = "xyes")
 507 AM_CONDITIONAL(ECORE_HAVE_PS3, test "x${have_ps3}" = "xyes")
 508
 509 WIN32_LIBS=""
 510 case "$host_os" in
 511    mingw32ce* | cegcc*)
 512       WIN32_LIBS="-lws2"
 513       dlopen_libs="-ldl"
 514       ;;
 515    mingw*)
 516       WIN32_LIBS="-lws2_32"
 517       dlopen_libs="-ldl"
 518       ;;
 519    *)
 520       AC_CHECK_LIB([c], [dlopen],
 521          [],
 522          [AC_CHECK_LIB([dl], [dlopen],
 523              [dlopen_libs=-ldl])
 524          ])
 525       AC_CHECK_LIB([c], [clock_gettime],
 526          [AC_DEFINE(HAVE_CLOCK_GETTIME, [1], [Have clock_gettime()])],
 527          [AC_CHECK_LIB([rt], [clock_gettime],
 528              [
 529               rt_libs=-lrt
 530               AC_DEFINE(HAVE_CLOCK_GETTIME, [1], [Have clock_gettime()])
 531              ])
 532          ])
 533       ;;
 534 esac
 535 AC_SUBST(WIN32_LIBS)
 536 AC_SUBST(dlopen_libs)
 537 AC_SUBST(rt_libs)
 538
 539 # Eina library
 540
 541 PKG_CHECK_MODULES(EINA, [eina >= 1.0.0])
 542 #FIXME check all the requirements when the eina move will be finished
 543 requirements_ecore="eina >= 1.0.0 ${requirements_ecore}"
 544 requirements_ecore_con="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_con}"
 545 #requirements_ecore_config="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_config}"
 546 requirements_ecore_directfb="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_directfb}"
 547 requirements_ecore_evas="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_evas}"
 548 requirements_ecore_fb="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_fb}"
 549 requirements_ecore_file="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_file}"
 550 requirements_ecore_imf="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_imf}"
 551 requirements_ecore_imf_evas="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_imf_evas}"
 552 requirements_ecore_input="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_input}"
 553 requirements_ecore_input_evas="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_input_evas}"
 554 requirements_ecore_ipc="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_ipc}"
 555 requirements_ecore_cocoa="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_cocoa}"
 556 requirements_ecore_sdl="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_sdl}"
 557 requirements_ecore_psl1ght="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_sdl}"
 558 requirements_ecore_win32="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_win32}"
 559 requirements_ecore_wince="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_wince}"
 560 requirements_ecore_x="ecore >= 1.0.0 eina >= 1.0.0 ${requirements_ecore_x}"
 561
 562
 563 # glib support (main loop integration)
 564 AC_ARG_ENABLE([glib],
 565    [AC_HELP_STRING([--disable-glib], [disable glib support. @<:@default=detect@:>@])],
 566    [want_glib=$enableval], [])
 567
 568 if test "x$want_glib" != "xno"; then
 569    PKG_CHECK_MODULES([GLIB], [glib-2.0], [have_glib="yes"], [have_glib="no"])
 570 else
 571    have_glib="no"
 572 fi
 573 if test "x$want_glib" = "xyes" -a "x$have_glib" = "xno"; then
 574    AC_MSG_ERROR([GLib support requested, but no GLib found by pkg-config.])
 575 elif test "x$have_glib" = "xyes"; then
 576    AC_DEFINE(HAVE_GLIB, [1], [Have GLib])
 577    requirements_ecore="glib-2.0 ${requirements_ecore}"
 578 fi
 579
 580
 581 # SDL library (ecore_sdl)
 582
 583 have_sdl="no"
 584 PKG_CHECK_MODULES([SDL], [sdl >= 1.2.0], [have_sdl="yes"], [have_sdl="no"])
 585 if test "x${have_sdl}" != "xyes" ; then
 586    SDL_CONFIG="sdl-config"
 587    AC_ARG_WITH([sdl-config],
 588       [AC_HELP_STRING([--with-sdl-config=PATH], [use sdl-config specified])],
 589       [
 590        SDL_CONFIG=$withval
 591        AC_MSG_NOTICE([using ${SDL_CONFIG} for sdl-config])
 592       ])
 593
 594    AC_PATH_PROG([SDL_CONFIG], ["sdl-config"], [""], [$PATH])
 595
 596    if test -n "$SDL_CONFIG" ; then
 597       SDL_CFLAGS=`$SDL_CONFIG --cflags`
 598       SDL_LIBS=`$SDL_CONFIG --libs`
 599       AC_SUBST(SDL_CFLAGS)
 600       AC_SUBST(SDL_LIBS)
 601       have_sdl="yes"
 602    fi
 603 fi
 604
 605 if test "x${have_sdl}" = "xyes" ; then
 606    PKG_CHECK_EXISTS([sdl >= 1.3.0],
 607       [AC_DEFINE(BUILD_ECORE_EVAS_SDL_130, 1, [Support for SVN SDL])])
 608 fi
 609
 610
 611 # DirectFB library (ecore_directfb)
 612
 613 PKG_CHECK_MODULES([DIRECTFB],
 614    [directfb >= 0.9.16],
 615    [have_directfb="yes"],
 616    [have_directfb="no"])
 617
 618
 619 # Eet library (ecore_config)
 620
 621 #PKG_CHECK_MODULES([EET],
 622 #   [eet >= 1.4.0],
 623 #   [have_eet="yes"],
 624 #   [have_eet="no"])
 625
 626
 627 # Xlib and XCB (ecore_x)
 628
 629 have_x="no"
 630 have_ecore_x="no"
 631 have_ecore_x_xlib="no"
 632 have_ecore_x_xcb="no"
 633
 634 x_dir="";
 635 x_includes="";
 636 x_cflags="";
 637 x_libs="";
 638
 639 ecore_x_libs_private=""
 640
 641 AC_ARG_ENABLE(ecore-x-composite,
 642    [AC_HELP_STRING([--disable-ecore-x-composite],
 643        [disable the ecore_x support for Xcomposite extension.
 644         @<:@default=detect@:>@])],
 645    [want_ecore_x_composite=$enableval])
 646
 647 AC_ARG_ENABLE(ecore-x-damage,
 648    [AC_HELP_STRING([--disable-ecore-x-damage],
 649        [disable the ecore_x support for Xdamage extension.
 650         @<:@default=detect@:>@])],
 651    [want_ecore_x_damage=$enableval])
 652
 653 AC_ARG_ENABLE(ecore-x-dpms,
 654    [AC_HELP_STRING([--disable-ecore-x-dpms],
 655        [disable the ecore_x support for Xdpms extension.
 656         @<:@default=detect@:>@])],
 657    [want_ecore_x_dpms=$enableval])
 658
 659 AC_ARG_ENABLE(ecore-x-randr,
 660    [AC_HELP_STRING([--disable-ecore-x-randr],
 661        [disable the ecore_x support for Xrandr extension.
 662         @<:@default=detect@:>@])],
 663    [want_ecore_x_randr=$enableval])
 664
 665 AC_ARG_ENABLE(ecore-x-render,
 666    [AC_HELP_STRING([--disable-ecore-x-render],
 667        [disable the ecore_x support for Xrender extension.
 668         @<:@default=detect@:>@])],
 669    [want_ecore_x_render=$enableval])
 670
 671 AC_ARG_ENABLE(ecore-x-screensaver,
 672    [AC_HELP_STRING([--disable-ecore-x-screensaver],
 673        [disable the ecore_x support for Xscreensaver extension.
 674         @<:@default=detect@:>@])],
 675    [want_ecore_x_screensaver=$enableval])
 676
 677 AC_ARG_ENABLE(ecore-x-shape,
 678    [AC_HELP_STRING([--disable-ecore-x-shape],
 679        [disable the ecore_x support for Xshape extension.
 680         @<:@default=detect@:>@])],
 681    [want_ecore_x_shape=$enableval])
 682
 683 AC_ARG_ENABLE(ecore-x-gesture,
 684    [AC_HELP_STRING([--enable-ecore-x-gesture],
 685        [enable the ecore_x support for Xgesture extension.
 686         @<:@default=detect@:>@])],
 687    [want_ecore_x_gesture=$enableval])
 688
 689 AC_ARG_ENABLE(ecore-x-sync,
 690    [AC_HELP_STRING([--disable-ecore-x-sync],
 691        [disable the ecore_x support for Xsync extension.
 692         @<:@default=detect@:>@])],
 693    [want_ecore_x_sync=$enableval])
 694
 695 AC_ARG_ENABLE(ecore-x-xfixes,
 696    [AC_HELP_STRING([--disable-ecore-x-xfixes],
 697        [disable the ecore_x support for Xfixes extension.
 698         @<:@default=detect@:>@])],
 699    [want_ecore_x_xfixes=$enableval])
 700
 701 AC_ARG_ENABLE(ecore-x-xinerama,
 702    [AC_HELP_STRING([--disable-ecore-x-xinerama],
 703        [disable the ecore_x support for Xinerama extension.
 704         @<:@default=detect@:>@])],
 705    [want_ecore_x_xinerama=$enableval])
 706
 707 AC_ARG_ENABLE(ecore-x-xprint,
 708    [AC_HELP_STRING([--disable-ecore-x-xprint],
 709        [disable the ecore_x support for Xprint extension.
 710         @<:@default=detect@:>@])],
 711    [want_ecore_x_xprint=$enableval])
 712
 713 AC_ARG_ENABLE(ecore-x-xtest,
 714    [AC_HELP_STRING([--disable-ecore-x-xtest],
 715        [disable the ecore_x support for Xtest extension.
 716         @<:@default=detect@:>@])],
 717    [want_ecore_x_xtest=$enableval])
 718
 719 AC_ARG_ENABLE(ecore-x-cursor,
 720    [AC_HELP_STRING([--disable-ecore-x-cursor],
 721        [disable the ecore_x support for Xcursor extension.
 722         @<:@default=detect@:>@])],
 723    [want_ecore_x_cursor=$enableval])
 724
 725 AC_ARG_ENABLE(ecore-x-input,
 726    [AC_HELP_STRING([--disable-ecore-x-input],
 727        [disable the ecore_x support for Xinput/Xinput2 extension.
 728         @<:@default=detect@:>@])],
 729    [want_ecore_x_input=$enableval])
 730
 731 AC_ARG_ENABLE(ecore-x-dri,
 732    [AC_HELP_STRING([--disable-ecore-x-dri],
 733        [disable the ecore_x support for DRI extension.
 734         @<:@default=detect@:>@])],
 735    [want_ecore_x_dri=$enableval])
 736
 737 AC_ARG_ENABLE(ecore-x-xcb,
 738    [AC_HELP_STRING([--enable-ecore-x-xcb],
 739        [enable the ecore_x module with XCB backend. @<:@default=disabled@:>@])],
 740    [want_ecore_x_xcb=$enableval])
 741
 742 AC_MSG_CHECKING(whether ecore_x with XCB backend is to be built)
 743 AC_MSG_RESULT($want_ecore_x_xcb)
 744
 745 if test "x$want_ecore_x_xcb" = "xyes" ; then
 746
 747   AC_MSG_CHECKING([keysym definitions])
 748   KEYSYMDEFDIR=`$PKG_CONFIG --variable=includedir xproto`/X11
 749   FILES="keysymdef.h XF86keysym.h Sunkeysym.h DECkeysym.h HPkeysym.h"
 750   for i in $FILES; do
 751       if test -f "$KEYSYMDEFDIR/$i"; then
 752         KEYSYMDEFS="$KEYSYMDEFS $KEYSYMDEFDIR/$i"
 753       elif test "x$i" = "xkeysymdef.h"; then
 754         AC_MSG_ERROR([Cannot find keysymdef.h])
 755       fi
 756   done
 757   AC_MSG_RESULT([$KEYSYMDEFS])
 758   AC_SUBST(KEYSYMDEFS)
 759
 760   have_iconv="no"
 761   AC_ARG_WITH([iconv-link],
 762     AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 763       [
 764         LIBS="$withval $LIBS"
 765         have_iconv="yes"
 766       ])
 767
 768   AC_MSG_CHECKING(for explicit iconv link options)
 769   if test "x${iconv_libs}" = "x" ; then
 770     AC_MSG_RESULT([no explicit iconv link option])
 771   else
 772     AC_MSG_RESULT([$iconv_libs])
 773   fi
 774
 775   if test "x${have_iconv}" = "xno" ; then
 776     AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 777
 778     if test "x${have_iconv}" = "xyes" ; then
 779       AC_MSG_CHECKING([whether iconv() is in libc])
 780
 781       AC_LINK_IFELSE(
 782         [AC_LANG_PROGRAM(
 783         [[
 784           #include <stdlib.h>
 785           #include <iconv.h>
 786         ]],
 787         [[
 788           iconv_t ic;
 789           size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 790         ]])],
 791         [have_iconv="yes"],
 792         [have_iconv="no"])
 793
 794       AC_MSG_RESULT([${have_iconv}])
 795     fi
 796
 797     if test "x${have_iconv}" = "xno" ; then
 798       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 799
 800       LIBS_save="${LIBS}"
 801       LIBS="-liconv $LIBS"
 802       AC_LINK_IFELSE(
 803       [AC_LANG_PROGRAM(
 804         [[
 805           #include <stdlib.h>
 806           #include <iconv.h>
 807         ]],
 808         [[
 809           iconv_t ic;
 810           size_t count;
 811           count = iconv(ic, NULL, NULL, NULL, NULL);
 812         ]])],
 813         [have_iconv="yes"],
 814         [
 815           have_iconv="no"
 816           LIBS=${LIBS_save}
 817         ])
 818
 819       AC_MSG_RESULT([${have_iconv}])
 820     fi
 821
 822     if test "x${have_iconv}" = "xno" ; then
 823       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 824
 825       LIBS_save="${LIBS}"
 826       LIBS="-liconv_plug $LIBS"
 827       AC_LINK_IFELSE(
 828       [AC_LANG_PROGRAM(
 829       [[
 830         #include <stdlib.h>
 831         #include <iconv.h>
 832       ]],
 833       [[
 834         iconv_t ic;
 835         size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 836       ]])],
 837       [have_iconv="yes"],
 838       [
 839         have_iconv="no"
 840         LIBS=${LIBS_save}
 841       ])
 842
 843       AC_MSG_RESULT([${have_iconv}])
 844     fi
 845
 846     if test "x${have_iconv}" = "xyes" ; then
 847       AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 848     fi
 849   fi
 850
 851   PKG_CHECK_MODULES(ECORE_XCB, x11-xcb xcb xcb-shm xcb-event xcb-icccm >= 0.3.8 xcb-util >= 0.3.8 xcb-image xcb-keysyms >= 0.3.8,
 852     [ have_ecore_x_xcb="yes"
 853       requirements_ecore_x="x11-xcb xcb xcb-shm xcb-event xcb-icccm xcb-util xcb-image xcb-keysyms ${requirements_ecore_x}"
 854     ],
 855     [
 856         PKG_CHECK_MODULES(ECORE_XCB, x11-xcb xcb xcb-event xcb-shm xcb-icccm xcb-image xcb-keysyms,
 857           [ have_ecore_x_xcb="yes"
 858             AC_DEFINE(OLD_XCB_VERSION, 1, [xcb version])
 859             requirements_ecore_x="x11-xcb xcb xcb-event xcb-shm xcb-icccm xcb-image xcb-keysyms ${requirements_ecore_x}" ],
 860           [ have_ecore_x_xcb="no" ])
 861     ],
 862     [have_ecore_x_xcb="no" ])
 863
 864   if test "x$have_ecore_x_xcb" = "xyes" ; then
 865
 866    PKG_CHECK_MODULES([PIXMAN],
 867       [pixman-1],
 868       [
 869        have_pixman="yes"
 870        AC_DEFINE(HAVE_PIXMAN, 1, [have pixman for rendering])
 871        requirements_ecore_x="pixman-1 ${requirements_ecore_x}"
 872       ],
 873       [
 874        if test "x${want_pixman}" = "xyes" -a "x${use_strict}" = "xyes" ; then
 875           AC_MSG_ERROR([Pixman not found (strict dependencies checking)])
 876        fi
 877       ])
 878
 879     if test "x$want_ecore_x_composite" != "xno"; then
 880       PKG_CHECK_MODULES(XCB_COMPOSITE, xcb-composite,
 881         [ have_ecore_x_xcb_composite="yes"
 882           requirements_ecore_x="xcb-composite ${requirements_ecore_x}"
 883           AC_DEFINE(ECORE_XCB_COMPOSITE, 1, [Build support for XCB composite]) ],
 884         [ have_ecore_x_xcb_composite="no" ])
 885     else
 886       have_ecore_x_xcb_composite="no"
 887       AC_MSG_NOTICE("composite extension explicitly disabled")
 888     fi
 889
 890     if test "x$want_ecore_x_damage" != "xno"; then
 891       PKG_CHECK_MODULES(XCB_DAMAGE, xcb-damage,
 892         [ have_ecore_x_xcb_damage="yes"
 893           requirements_ecore_x="xcb-damage ${requirements_ecore_x}"
 894           AC_DEFINE(ECORE_XCB_DAMAGE, 1, [Build support for XCB damage]) ],
 895         [ have_ecore_x_xcb_damage="no" ])
 896     else
 897       have_ecore_x_xcb_damage="no"
 898       AC_MSG_NOTICE("damage extension explicitly disabled")
 899     fi
 900
 901     if test "x$want_ecore_x_dpms" != "xno"; then
 902       PKG_CHECK_MODULES(XCB_DPMS, xcb-dpms,
 903         [ have_ecore_x_xcb_dpms="yes"
 904           requirements_ecore_x="xcb-dpms ${requirements_ecore_x}"
 905           AC_DEFINE(ECORE_XCB_DPMS, 1, [Build support for XCB dpms]) ],
 906         [ have_ecore_x_xcb_dpms="no" ])
 907     else
 908       have_ecore_x_xcb_dpms="no"
 909       AC_MSG_NOTICE("dpms extension explicitly disabled")
 910     fi
 911
 912     if test "x$want_ecore_x_randr" != "xno"; then
 913       PKG_CHECK_MODULES(XCB_RANDR, xcb-randr,
 914         [ have_ecore_x_xcb_randr="yes"
 915           requirements_ecore_x="xcb-randr ${requirements_ecore_x}"
 916           AC_DEFINE(ECORE_XCB_RANDR, 1, [Build support for XCB randr]) ],
 917         [ have_ecore_x_xcb_randr="no" ])
 918     else
 919       have_ecore_x_xcb_randr="no"
 920       AC_MSG_NOTICE("randr extension explicitly disabled")
 921     fi
 922
 923     if test "x$want_ecore_x_render" != "xno"; then
 924       PKG_CHECK_MODULES(XCB_RENDER, xcb-render xcb-renderutil,
 925         [ have_ecore_x_xcb_render="yes"
 926           requirements_ecore_x="xcb-render xcb-renderutil ${requirements_ecore_x}"
 927           AC_DEFINE(ECORE_XCB_RENDER, 1, [Build support for XCB render]) ],
 928         [ have_ecore_x_xcb_render="no" ])
 929     else
 930       have_ecore_x_xcb_render="no"
 931       AC_MSG_NOTICE("render extension explicitly disabled")
 932     fi
 933
 934     if test "x$want_ecore_x_screensaver" != "xno"; then
 935       PKG_CHECK_MODULES(XCB_SCREENSAVER, xcb-screensaver,
 936         [ have_ecore_x_xcb_screensaver="yes"
 937           requirements_ecore_x="xcb-screensaver ${requirements_ecore_x}"
 938           AC_DEFINE(ECORE_XCB_SCREENSAVER, 1, [Build support for XCB screensaver]) ],
 939         [ have_ecore_x_xcb_screensaver="no" ])
 940     else
 941       have_ecore_x_xcb_screensaver="no"
 942       AC_MSG_NOTICE("screensaver extension explicitly disabled")
 943     fi
 944
 945     if test "x$want_ecore_x_shape" != "xno"; then
 946       PKG_CHECK_MODULES(XCB_SHAPE, xcb-shape,
 947         [ have_ecore_x_xcb_shape="yes"
 948           requirements_ecore_x="xcb-shape ${requirements_ecore_x}"
 949           AC_DEFINE(ECORE_XCB_SHAPE, 1, [Build support for XCB shape]) ],
 950         [ have_ecore_x_xcb_shape="no" ])
 951     else
 952       have_ecore_x_xcb_shape="no"
 953       AC_MSG_NOTICE("shape extension explicitly disabled")
 954     fi
 955
 956     if test "x$want_ecore_x_gesture" != "xno"; then
 957       PKG_CHECK_MODULES(XCB_XGESTURE, xcb-gesture,
 958         [ have_ecore_x_xcb_gesture="yes"
 959           requirements_ecore_x="xcb-gesture ${requirements_ecore_x}"
 960           AC_DEFINE(ECORE_XCB_XGESTURE, 1, [Build support for XCB gesture]) ],
 961         [ have_ecore_x_xcb_gesture="no" ])
 962     else
 963       have_ecore_x_xcb_gesture="no"
 964       AC_MSG_NOTICE("gesture extension explicitly disabled")
 965     fi
 966
 967     if test "x$want_ecore_x_sync" != "xno"; then
 968       PKG_CHECK_MODULES(XCB_SYNC, xcb-sync,
 969         [ have_ecore_x_xcb_sync="yes"
 970           requirements_ecore_x="xcb-sync ${requirements_ecore_x}"
 971           AC_DEFINE(ECORE_XCB_SYNC, 1, [Build support for XCB sync]) ],
 972         [ have_ecore_x_xcb_sync="no" ])
 973     else
 974       have_ecore_x_xcb_sync="no"
 975       AC_MSG_NOTICE("sync extension explicitly disabled")
 976     fi
 977
 978     if test "x$want_ecore_x_xfixes" != "xno"; then
 979       PKG_CHECK_MODULES(XCB_XFIXES, xcb-xfixes,
 980         [ have_ecore_x_xcb_xfixes="yes"
 981           requirements_ecore_x="xcb-xfixes ${requirements_ecore_x}"
 982           AC_DEFINE(ECORE_XCB_XFIXES, 1, [Build support for XCB xfixes]) ],
 983         [ have_ecore_x_xcb_xfixes="no" ])
 984     else
 985       have_ecore_x_xcb_xfixes="no"
 986       AC_MSG_NOTICE("xfixes extension explicitly disabled")
 987     fi
 988
 989     if test "x$want_ecore_x_xinerama" != "xno"; then
 990       PKG_CHECK_MODULES(XCB_XINERAMA, xcb-xinerama,
 991         [ have_ecore_x_xcb_xinerama="yes"
 992           requirements_ecore_x="xcb-xinerama ${requirements_ecore_x}"
 993           AC_DEFINE(ECORE_XCB_XINERAMA, 1, [Build support for XCB xinerama]) ],
 994         [ have_ecore_x_xcb_xinerama="no" ])
 995     else
 996       have_ecore_x_xcb_xinerama="no"
 997       AC_MSG_NOTICE("xinerama extension explicitly disabled")
 998     fi
 999
1000     if test "x$want_ecore_x_xprint" != "xno"; then
1001       PKG_CHECK_MODULES(XCB_XPRINT, xcb-xprint,
1002         [ have_ecore_x_xcb_xprint="yes"
1003           requirements_ecore_x="xcb-xprint ${requirements_ecore_x}"
1004           AC_DEFINE(ECORE_XCB_XPRINT, 1, [Build support for XCB xprint]) ],
1005         [ have_ecore_x_xcb_xprint="no" ])
1006     else
1007       have_ecore_x_xcb_xprint="no"
1008       AC_MSG_NOTICE("xprint extension explicitly disabled")
1009     fi
1010
1011     if test "x$want_ecore_x_xtest" != "xno"; then
1012       PKG_CHECK_MODULES(XCB_XTEST, xcb-xtest,
1013         [ have_ecore_x_xcb_xtest="yes"
1014           requirements_ecore_x="xcb-xtest ${requirements_ecore_x}"
1015           AC_DEFINE(ECORE_XCB_XTEST, 1, [Build support for XCB xtest]) ],
1016         [ have_ecore_x_xcb_xtest="no" ])
1017     else
1018       have_ecore_x_xcb_xtest="no"
1019       AC_MSG_NOTICE("xtest extension explicitly disabled")
1020     fi
1021
1022 # input extension disabled currently in xcb as xcb-input has some issues
1023     want_ecore_x_input="no"
1024     if test "x$want_ecore_x_input" != "xno"; then
1025       PKG_CHECK_MODULES(XCB_XINPUT, xcb-xinput,
1026         [ have_ecore_x_xcb_xinput="yes"
1027           requirements_ecore_x="xcb-xinput ${requirements_ecore_x}"
1028           AC_DEFINE(ECORE_XCB_XINPUT, 1, [Build support for XCB xinput]) ],
1029         [ have_ecore_x_xcb_xinput="no" ])
1030     else
1031       have_ecore_x_xcb_xinput="no"
1032       AC_MSG_NOTICE("xinput extension explicitly disabled")
1033     fi
1034
1035     if test "x$want_ecore_x_cursor" != "xno"; then
1036       PKG_CHECK_MODULES(XCB_CURSOR, xcb-render xcb-renderutil,
1037         [ have_ecore_x_xcb_cursor="yes"
1038           requirements_ecore_x="xcb-render xcb-renderutil ${requirements_ecore_x}"
1039           AC_DEFINE(ECORE_XCB_CURSOR, 1, [Build support for XCB cursor]) ],
1040         [ have_ecore_x_xcb_cursor="no" ])
1041     else
1042       have_ecore_x_xcb_cursor="no"
1043       AC_MSG_NOTICE("cursor extension explicitly disabled")
1044     fi
1045
1046 #    if test "x$want_ecore_x_dri" != "xno"; then
1047 #      PKG_CHECK_MODULES(XCB_DRI, xcb-dri2,
1048 #        [ have_ecore_x_xcb_dri="yes"
1049 #          requirements_ecore_x="xcb-dri2 ${requirements_ecore_x}"
1050 #          AC_DEFINE(ECORE_XCB_DRI, 1, [Build support for XCB dri/dri2]) ],
1051 #        [ have_ecore_x_xcb_dri="no" ])
1052 #    else
1053 #      have_ecore_x_xcb_dri="no"
1054 #      AC_MSG_NOTICE("dri extension explicitly disabled")
1055 #    fi
1056
1057     AC_DEFINE(HAVE_ECORE_X_XCB, 1, [Defined to 1 if XCB is enabled.])
1058
1059     x_cflags=$ECORE_XCB_CFLAGS
1060     x_libs=$ECORE_XCB_LIBS
1061     have_x="yes"
1062
1063     have_ecore_x_xcb_define="-DHAVE_ECORE_X_XCB"
1064     AC_SUBST(have_ecore_x_xcb_define)
1065   fi
1066 fi
1067
1068 if ! test "x$have_ecore_x_xcb" = "xyes" ; then
1069   AC_PATH_XTRA
1070   AC_CHECK_HEADER(X11/X.h,
1071     [
1072      if test "x$want_evas_simple_x11" = "xyes"; then
1073        x_libs="${x_libs} -lX11 -lXext"
1074      else
1075        x_dir=${x_dir:-/usr/X11R6}
1076        x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
1077        x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
1078      fi
1079      have_ecore_x_xlib="yes"
1080     ]
1081   )
1082
1083   if test "x$have_ecore_x_xlib" = "xyes"; then
1084     Xcursor_libs=""
1085     Xcursor_cflags=""
1086     use_Xcursor="no"
1087     PCFLAGS=$CFLAGS
1088     CFLAGS="$x_cflags $x_includes"
1089
1090     if test "x$want_ecore_x_cursor" = "xyes"; then
1091       AC_CHECK_HEADER(X11/Xcursor/Xcursor.h,
1092         [
1093           AC_CHECK_LIB(Xcursor, XcursorImageLoadCursor,
1094             [
1095               AC_DEFINE(ECORE_XCURSOR, 1, [Build support for Xcursor])
1096               Xcursor_cflags=""
1097               Xcursor_libs="-lXcursor"
1098               use_Xcursor="yes"
1099             ], [
1100               Xcursor_cflags=""
1101               Xcursor_libs=""
1102               use_Xcursor="no"
1103             ], [
1104               $x_libs -lXrender
1105             ]
1106           )
1107         ], [
1108           Xcursor_cflags=""
1109           Xcursor_libs=""
1110           use_Xcursor="no"
1111         ], [
1112           #include <X11/Xlib.h>
1113         ]
1114       )
1115       CFLAGS=$PCFLAGS
1116     else
1117       Xcursor_cflags=""
1118       Xcursor_libs=""
1119       use_Xcursor="no"
1120       AC_MSG_NOTICE("Xcursor explicitly disabled")
1121     fi
1122
1123     AC_SUBST(Xcursor_cflags)
1124     AC_SUBST(Xcursor_libs)
1125
1126     ECORE_CHECK_X_EXTENSION([Xkb], [XKB.h], [X11], [XkbSetDetectableAutoRepeat], [$want_ecore_x_xkb])
1127     ECORE_CHECK_X_EXTENSION([Xcomposite], [Xcomposite.h], [Xcomposite], [XCompositeQueryExtension], [$want_ecore_x_composite])
1128     ECORE_CHECK_X_EXTENSION([Xdamage], [Xdamage.h], [Xdamage], [XDamageSubtract], [$want_ecore_x_damage])
1129     ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xdpms], [DPMSQueryExtension], [$want_ecore_x_dpms])
1130     if test "x$use_xdpms" = "xno" ; then
1131       ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xext], [DPMSQueryExtension], [$want_ecore_x_dpms])
1132     fi
1133     ECORE_CHECK_X_EXTENSION([Xfixes], [Xfixes.h], [Xfixes], [XFixesExpandRegion], [$want_ecore_x_xfixes])
1134     ECORE_CHECK_X_EXTENSION([Xinerama], [Xinerama.h], [Xinerama], [XineramaQueryScreens], [$want_ecore_x_xinerama])
1135     ECORE_CHECK_X_EXTENSION([Xprint], [Print.h], [Xp], [XpQueryScreens], [$want_ecore_x_xprint])
1136     ECORE_CHECK_X_EXTENSION([Xrandr], [Xrandr.h], [Xrandr], [XRRGetScreenResourcesCurrent], [$want_ecore_x_randr])
1137     ECORE_CHECK_X_EXTENSION([Xgesture], [gesture.h], [Xgesture], [XGestureQueryExtension], [$want_ecore_x_gesture])
1138     ECORE_CHECK_X_EXTENSION([Xrender], [Xrender.h], [Xrender], [XRenderFindVisualFormat], [$want_ecore_x_render])
1139     ECORE_CHECK_X_EXTENSION([Xtest], [XTest.h], [Xtst], [XTestFakeKeyEvent], [$want_ecore_x_xtest])
1140     ECORE_CHECK_X_EXTENSION([Xss], [scrnsaver.h], [Xss], [XScreenSaverSelectInput], [$want_ecore_x_screensaver])
1141     ECORE_CHECK_X_EXTENSION([Xi2], [XInput2.h], [Xi], [XIQueryDevice], [$want_ecore_x_input])
1142
1143     ecore_x_libs_private="${Xcursor_libs} ${XKB_LIBS} ${XCOMPOSITE_LIBS} ${XGESTURE_LIBS} ${XDAMAGE_LIBS} ${XDPMS_LIBS} ${XFIXES_LIBS} ${XINERAMA_LIBS} ${XPRINT_LIBS} ${XRANDR_LIBS} ${XRENDER_LIBS} ${XTEST_LIBS} ${XSS_LIBS} ${XI2_LIBS}"
1144
1145     AC_DEFINE(HAVE_ECORE_X_XLIB, 1, [Defined to 1 if Xlib is enabled.])
1146     have_x="yes"
1147
1148     have_ecore_x_xlib="yes"
1149   fi
1150 fi
1151
1152 AC_SUBST(x_cflags)
1153 AC_SUBST(x_includes)
1154 AC_SUBST(x_libs)
1155 AC_SUBST(ecore_x_libs_private)
1156
1157 AM_CONDITIONAL(BUILD_ECORE_X_XLIB, test $have_ecore_x_xlib = yes)
1158 AM_CONDITIONAL(BUILD_ECORE_X_XCB, test $have_ecore_x_xcb = yes)
1159
1160
1161 # Evas library (ecore_config, ecore_input_evas, ecore_imf_evas and ecore_evas)
1162
1163 PKG_CHECK_MODULES([EVAS], [evas >= 1.0.0],
1164    [have_evas="yes"],
1165    [have_evas="no"])
1166
1167
1168 ### Checks for header files
1169
1170 AC_CHECK_HEADERS([sys/select.h sys/prctl.h])
1171
1172 EFL_CHECK_PATH_MAX
1173
1174 AC_HEADER_SYS_WAIT
1175 AC_SYS_LARGEFILE
1176
1177 have_addrinfo="no"
1178 case "$host_os" in
1179    mingw* | cegcc*)
1180       AC_DEFINE(HAVE_DLFCN_H, 1, [Define to 1 if you have the <dlfcn.h> header file.])
1181       AC_DEFINE(HAVE_SYS_MMAN_H, 1, [Define to 1 if you have the <sys/mman.h> header file.])
1182       AC_DEFINE(HAVE_SYS_TIME_H, 1, [Define to 1 if you have the <sys/time.h> header file.])
1183       have_addrinfo="yes"
1184       ;;
1185    *)
1186       AC_CHECK_HEADERS([dlfcn.h features.h langinfo.h locale.h sys/time.h sys/mman.h signal.h sys/resource.h])
1187       ;;
1188 esac
1189
1190 # ecore_con
1191
1192 AC_CHECK_HEADERS([arpa/inet.h arpa/nameser.h netinet/tcp.h netinet/in.h sys/socket.h sys/un.h ws2tcpip.h netdb.h])
1193
1194 if test "x${ac_cv_header_netdb_h}" = "xyes" ; then
1195    have_addrinfo="yes"
1196 fi
1197
1198 # Framebuffer (ecore_fb)
1199 have_fb="no"
1200 AC_CHECK_HEADER([linux/fb.h],
1201    [AC_CHECK_HEADER([linux/input.h], [have_fb="yes"])])
1202
1203 # Cocoa header files (ecore_cocoa)
1204
1205 cocoa_ldflags=""
1206 have_cocoa="no"
1207 m4_ifdef([AC_PROG_OBJC], [
1208     if test "x${have_gnu_objc}" = "xyes" ; then
1209        AC_LANG_PUSH([Objective C])
1210        LIBS_save="$LIBS"
1211        LIBS="$LIBS -framework Cocoa"
1212        AC_LINK_IFELSE(
1213           [AC_LANG_PROGRAM(
1214               [[
1215 #include <Cocoa/Cocoa.h>
1216               ]],
1217               [[
1218 NSWindow *window;
1219 window = [[NSWindow alloc]
1220            initWithContentRect:NSMakeRect(0, 0, 1, 1)
1221            styleMask:(NSTitledWindowMask)
1222            backing:NSBackingStoreBuffered
1223            defer:NO
1224            screen:nil
1225          ];
1226               ]])],
1227           [
1228            have_cocoa="yes"
1229            cocoa_ldflags="-framework Cocoa"
1230           ],
1231           [have_cocoa="no"])
1232        LIBS="$LIBS_save"
1233        AC_MSG_CHECKING([whether Cocoa framework is supported])
1234        AC_MSG_RESULT([${have_cocoa}])
1235        AC_LANG_POP([Objective C])
1236     fi
1237 ])
1238 AC_SUBST(cocoa_ldflags)
1239
1240 want_epoll=yes
1241 AC_ARG_ENABLE(epoll,
1242   AC_HELP_STRING([--enable-epoll], [enable or disable epoll support]),
1243   [want_epoll=$enableval])
1244
1245 if test "x${want_epoll}" = "xyes" ; then
1246   # check for epoll support
1247   AC_CHECK_HEADERS([sys/epoll.h])
1248 fi
1249
1250 # timerfd_create
1251 AC_CHECK_HEADERS([sys/timerfd.h])
1252 AC_CHECK_FUNCS(timerfd_create)
1253
1254 # thread support
1255
1256 EFL_CHECK_THREADS(
1257    [
1258     if test "x${_efl_have_posix_threads}" = "xyes" ; then
1259        have_threads="POSIX"
1260     else
1261        if test "x${_efl_have_win32_threads}" = "xyes" ; then
1262           have_threads="Win32"
1263        else
1264           have_threads="no"
1265        fi
1266     fi
1267    ],
1268    [have_threads="no"])
1269
1270 ### enable thread safety if we have threads, unless specifically asked not to
1271 if test "x${have_threads}" = "xno"
1272 then
1273   want_thread_safety="no"
1274 else
1275   want_thread_safety="no"  # to be changed to yes when ready
1276   AC_ARG_ENABLE(thread-safety,
1277     AC_HELP_STRING([--enable-thread-safety], [enable or disable thread safety]),
1278     [want_thread_safety=$enableval])
1279 fi
1280
1281 if test "x${want_thread_safety}" = "xyes"
1282 then
1283    AC_DEFINE([HAVE_THREAD_SAFETY], [1], [Define to enable thread safety])
1284 fi
1285
1286 ### Checks for types
1287 AC_CHECK_SIZEOF(int, 4)
1288 AC_CHECK_SIZEOF(long, 4)
1289
1290
1291 ### Checks for structures
1292
1293
1294 ### Checks for compiler characteristics
1295 AC_PROG_CC_STDC
1296 AC_C_CONST
1297 AC_C_BIGENDIAN
1298 AC_HEADER_STDC
1299 AC_C___ATTRIBUTE__
1300
1301 WIN32_CPPFLAGS=""
1302 WIN32_CFLAGS=""
1303 case "$host_os" in
1304    mingw32ce*)
1305       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
1306       ;;
1307    cegcc*)
1308       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
1309       WIN32_CFLAGS="-mwin32"
1310       ;;
1311    mingw*)
1312       WIN32_CPPFLAGS="-D_WIN32_WINNT=0x0501"
1313       ;;
1314 esac
1315 AC_SUBST(WIN32_CPPFLAGS)
1316 AC_SUBST(WIN32_CFLAGS)
1317
1318
1319 ### Checks for linker characteristics
1320
1321 # use --enable-auto-import on Windows
1322
1323 lt_enable_auto_import=""
1324 case "$host_os" in
1325    mingw* | cegcc*)
1326       lt_enable_auto_import="-Wl,--enable-auto-import"
1327       ;;
1328 esac
1329 AC_SUBST(lt_enable_auto_import)
1330
1331 ### Checks for library functions
1332 AC_ISC_POSIX
1333 AC_FUNC_ALLOCA
1334 AC_CHECK_FUNCS([gettimeofday strlcpy execvp])
1335
1336 AC_COMPILE_IFELSE(
1337    [AC_LANG_PROGRAM(
1338        [[
1339 #include <math.h>
1340        ]],
1341        [[
1342 int i = isfinite(0);
1343        ]])],
1344    [
1345     AC_DEFINE(HAVE_ISFINITE, 1, [Define to 1 if you have `isfinite', as a function or macro.])
1346     have_isfinite="yes"
1347    ],
1348    [have_isfinite="no"])
1349
1350 AC_MSG_CHECKING([for isfinite])
1351 AC_MSG_RESULT([${have_isfinite}])
1352
1353 have_atfile_source=auto
1354 AC_ARG_ENABLE([atfile-source],
1355    [AC_HELP_STRING([--disable-atfile-source],
1356        [disable use of atfile source functions as openat and mkdirat @<:@default=detect@:>@])],
1357    [
1358     if test "x${enableval}" = "xyes" ; then
1359        have_atfile_source="yes"
1360     else
1361        have_atfile_source="no"
1362     fi],
1363    [have_atfile_source=auto])
1364
1365 if ! test "x${have_atfile_source}" = "xno" ; then
1366    AC_CHECK_FUNCS(mkdirat,
1367       [
1368        have_atfile_source="yes"
1369        AC_DEFINE(HAVE_ATFILE_SOURCE, 1, [mkdirat exists])
1370       ],
1371       [
1372        if test "x${have_atfile_source}" = "xyes" ; then
1373           AC_MSG_ERROR([required atfile-source but no mkdirat()])
1374        fi
1375        have_atfile_source="no"
1376       ])
1377 fi
1378
1379 ### Checks for optionnal feature
1380 AC_CHECK_FUNC([mallinfo],
1381    [
1382     have_mallinfo="yes"
1383     AC_DEFINE(HAVE_MALLINFO, 1, [Gather memory statistic])
1384    ],
1385    [have_mallinfo="no"])
1386
1387 ### Ecore modules
1388
1389 ## Core modules
1390
1391 # ecore_con
1392 ECORE_CHECK_MODULE([con], [${want_ecore_con}], [Con], [${have_addrinfo}])
1393
1394 have_curl="no"
1395 have_gnutls="no"
1396 have_openssl="no"
1397 have_cares="no"
1398 want_ipv6="yes"
1399 have_ipv6="no"
1400
1401 AC_ARG_ENABLE([ipv6],
1402    [AC_HELP_STRING([--disable-ipv6],
1403        [disable ipv6 functionality @<:@default=detect@:>@])],
1404    [
1405     if test "x${enableval}" = "xyes" ; then
1406        want_ipv6="yes"
1407     else
1408        want_ipv6="no"
1409     fi],
1410    [want_ipv6="auto"])
1411
1412 if test "x${have_ecore_con}" = "xyes" ; then
1413
1414    # Verify IPV6 availability in headers
1415    if test "x${want_ipv6}" != "xno" ; then
1416       AC_CHECK_TYPES([struct ipv6_mreq],
1417          [have_ipv6="yes"],
1418          [have_ipv6="no"],
1419          [[
1420 #ifdef HAVE_NETINET_IN_H
1421 # include <netinet/in.h>
1422 #endif
1423 #ifdef HAVE_WS2TCPIP_H
1424 # include <ws2tcpip.h>
1425 #endif
1426          ]])
1427    fi
1428
1429    if test "x${have_ipv6}" = "xyes" ; then
1430       AC_DEFINE(HAVE_IPV6, 1, [Define if IPV6 is supported])
1431    fi
1432
1433    ECORE_CHECK_CURL([${want_curl}],
1434       [
1435        have_curl="yes"
1436        requirements_ecore_con="libcurl ${requirements_ecore_con}"
1437       ],
1438       [have_curl="no"])
1439
1440    ECORE_CHECK_GNUTLS([${want_gnutls}],
1441       [have_gnutls="yes"],
1442       [have_gnutls="no"])
1443
1444    ECORE_CHECK_OPENSSL([${want_openssl}],
1445       [have_openssl="yes"],
1446       [have_openssl="no"])
1447
1448    if test "x${have_gnutls}" = "xyes" ; then
1449       requirements_ecore_con="gnutls ${requirements_ecore_con}"
1450       # no need to add it to req_ecore_ipc, since they
1451       # depends on ecore_con anyway.
1452    else
1453       if test "x${have_openssl}" = "xyes" ; then
1454          requirements_ecore_con="openssl ${requirements_ecore_con}"
1455          # no need to add it to req_ecore_ipc, since they
1456          # depends on ecore_con anyway.
1457       fi
1458    fi
1459
1460    ECORE_CHECK_CARES([${want_cares}],
1461       [
1462        have_cares="yes"
1463        requirements_ecore_con="libcares ${requirements_ecore_con}"
1464       ],
1465       [have_cares="no"])
1466
1467 fi
1468
1469 AM_CONDITIONAL([HAVE_CARES], [test "x${have_cares}" = "xyes"])
1470
1471 # ecore_ipc
1472 ECORE_CHECK_MODULE([ipc], [${want_ecore_ipc}], [Ipc], [${have_ecore_con}],
1473    [requirements_ecore_ipc="ecore-con >= 1.0.0 ${requirements_ecore_ipc}"])
1474
1475 # ecore_file
1476 ECORE_CHECK_MODULE([file], [${want_ecore_file}], [File])
1477
1478 have_poll="no"
1479 have_inotify="no"
1480 have_notify_win32="no"
1481 if test "x${have_ecore_file}" = "xyes" ; then
1482    ECORE_CHECK_POLL([${want_poll}], [have_poll="yes"], [have_poll="no"])
1483    ECORE_CHECK_INOTIFY([${want_inotify}], [have_inotify="yes"], [have_inotify="no"])
1484    ECORE_CHECK_NOTIFY_WIN32([${want_notify_win32}], [have_notify_win32="yes"], [have_notify_win32="no"])
1485
1486    if test "x${have_ecore_con}" = "xyes" ; then
1487       requirements_ecore_file="ecore-con >= 1.0.0 ${requirements_ecore_file}"
1488    else
1489       ECORE_CHECK_CURL([${want_curl}],
1490          [
1491           have_curl="yes"
1492           requirements_ecore_file="libcurl ${requirements_ecore_file}"
1493          ],
1494          [have_curl="no"])
1495    fi
1496
1497 fi
1498
1499 # ecore_config
1500 #ecore_config_deps="no"
1501 #if test "x${have_eet}" = "xyes" -a "x${have_evas}"  -a "x${have_ecore_ipc}" ; then
1502 #   ecore_config_deps="yes"
1503 #fi
1504
1505 #ECORE_CHECK_MODULE([config], [${want_ecore_config}], [Config], [${ecore_config_deps}],
1506 #   [requirements_ecore_config="ecore-ipc >= 1.0.0 evas >= 1.0.0 eet >= 1.4.0 ${requirements_ecore_config}"])
1507
1508 AM_CONDITIONAL(BUILD_ECORE_CONFIG, false)
1509
1510 # ecore_imf
1511
1512 ECORE_CHECK_MODULE([imf], [${want_ecore_imf}], [Imf])
1513
1514 # ecore_imf_evas
1515
1516 ecore_imf_evas_deps="no"
1517 if test "x${have_ecore_imf}" = "xyes" -a "x${have_evas}" = "xyes" ; then
1518    ecore_imf_evas_deps="yes"
1519 fi
1520
1521 ECORE_CHECK_MODULE([imf-evas], [${want_ecore_imf}], [Imf_Evas], [${ecore_imf_evas_deps}],
1522    [requirements_ecore_imf_evas="ecore-imf >= 1.0.0 evas >= 1.0.0 ${requirements_ecore_imf_evas}"])
1523
1524 # ecore_input{_evas}
1525 ECORE_CHECK_MODULE([input], [${want_ecore_input}], [Input])
1526 ECORE_CHECK_MODULE([input-evas], [${want_ecore_input}], [Input_Evas], [${have_evas}],
1527    [requirements_ecore_input_evas="ecore-input >= 1.0.0 evas >= 1.0.0 ${requirements_ecore_input}"])
1528
1529 # ecore_imf_xim
1530 AM_CONDITIONAL(BUILD_ECORE_IMF_XIM, false)
1531 ecore_imf_xim_deps="no"
1532 echo "have_ecore_x_xlib: ${have_ecore_x_xlib}"
1533 if test    "x${have_ecore_imf}" = "xyes" \
1534         -a "x${have_ecore_x_xlib}" = "xyes" \
1535         -a "x${have_ecore_input}" = "xyes" ; then
1536    ecore_imf_xim_deps="yes"
1537    AC_DEFINE(BUILD_ECORE_IMF_XIM, 1, [Ecore Imf XIM Support])
1538 fi
1539
1540 ECORE_CHECK_MODULE([imf-xim], [${want_ecore_imf}], [Imf_XIM], [${ecore_imf_xim_deps}],
1541    [requirements_ecore_imf_xim="ecore-imf >= 1.0.0 ecore-x >= 1.0.0 ecore-input >= 1.0.0 ${requirements_ecore_imf_xim}"])
1542
1543 ## Graphic systems
1544
1545 # ecore_x{cb}
1546
1547 ecore_x_deps="no"
1548 if test "x${have_x}" = "xyes" -a \
1549         "x${have_ecore_input}" = "xyes" ; then
1550    ecore_x_deps="yes"
1551 fi
1552
1553 ECORE_CHECK_MODULE([x], [${want_ecore_x}], [X], [${ecore_x_deps}],
1554   [
1555    ecore_x_libs="$ecore_x_libs $x_libs"
1556    requirements_ecore_x="ecore-input >= 1.0.0 ${requirements_ecore_x}"
1557   ])
1558
1559 # ecore_win32
1560
1561 ECORE_CHECK_MODULE([win32], [${want_ecore_win32}], [Win32], [${have_ecore_input}],
1562    [
1563     ecore_win32_libs="-lole32 -lgdi32"
1564     requirements_ecore_win32="ecore-input >= 1.0.0 ${requirements_ecore_win32}"
1565    ])
1566 AC_SUBST(ecore_win32_libs)
1567
1568 # ecore_cocoa
1569
1570 ecore_cocoa_deps="no"
1571 if test "x${have_ecore_input}" = "xyes" -a "x${have_cocoa}" = "xyes" ; then
1572    ecore_cocoa_deps="yes"
1573 fi
1574
1575 ECORE_CHECK_MODULE([cocoa], [${want_ecore_cocoa}], [Cocoa], [${ecore_cocoa_deps}],
1576    [requirements_ecore_cocoa="ecore-input >= 1.0.0 ${requirements_ecore_cocoa}"])
1577
1578 # ecore_sdl
1579
1580 ecore_sdl_deps="no"
1581 if test "x${have_sdl}" = "xyes" -a "x${have_ecore_input}" = "xyes" ; then
1582    ecore_sdl_deps="yes"
1583 fi
1584
1585 ECORE_CHECK_MODULE([sdl], [${want_ecore_sdl}], [Sdl], [${ecore_sdl_deps}],
1586    [requirements_ecore_sdl="ecore-input >= 1.0.0 ${requirements_ecore_sdl}"])
1587
1588 ECORE_CHECK_MODULE([psl1ght], [${want_ecore_psl1ght}], [psl1ght], [${ecore_psl1ght_deps}],
1589    [requirements_ecore_psl1ght="ecore-input >= 1.0.0 ${requirements_ecore_psl1ght}"])
1590
1591 # ecore_fb
1592 ECORE_CHECK_MODULE([fb], [${want_ecore_fb}], [FB], [$have_fb])
1593
1594 if test "x${have_ecore_fb}" = "xyes" ; then
1595    ECORE_CHECK_TSLIB([${want_tslib}],
1596       [
1597        have_tslib="yes"
1598        requirements_ecore_fb="${_tslib_requirement} ${requirements_ecore_fb}"
1599       ],
1600       [have_tslib="no"])
1601 fi
1602
1603 # ecore_directfb
1604
1605 ECORE_CHECK_MODULE([directfb], [${want_ecore_directfb}], [DirectFB], [${have_directfb}],
1606    [requirements_ecore_directfb="directfb ${requirements_ecore_directfb}"])
1607
1608 # ecore_wince
1609
1610 ECORE_CHECK_MODULE([wince], [${want_ecore_wince}], [WinCE], [${have_ecore_input}],
1611    [requirements_ecore_win32="ecore-input >= 1.0.0 ${requirements_ecore_win32}"])
1612
1613 ## Ecore Evas
1614
1615 # ecore_evas
1616
1617 ecore_evas_deps="no"
1618 if test "x${have_evas}" = "xyes" -a "x${have_ecore_input}" = "xyes" -a "x${have_ecore_input_evas}" = "xyes" ; then
1619    ecore_evas_deps="yes"
1620 fi
1621
1622 ECORE_CHECK_MODULE([evas], [${want_ecore_evas}], [Evas], [${ecore_evas_deps}],
1623   [requirements_ecore_evas="ecore-input >= 1.0.0 ecore-input-evas >= 1.0.0 evas >= 1.0.0 ${requirements_ecore_evas}"])
1624
1625 # ecore_evas_buffer
1626
1627 ECORE_EVAS_CHECK_MODULE([software-buffer],
1628    [${want_ecore_evas_software_buffer}],
1629    [Software Buffer],
1630    [yes])
1631
1632 # ecore_evas_x11
1633
1634 # ecore_evas_software_x11
1635
1636 ECORE_EVAS_CHECK_MODULE([software-x11],
1637    [${want_ecore_evas_software_x11}],
1638    [Software X11],
1639    [${have_ecore_x}])
1640
1641 have_ecore_evas_software_xlib="no"
1642 have_ecore_evas_software_xcb="no"
1643 if test "x$have_ecore_evas_software_x11" = "xyes" ; then
1644    have_ecore_evas_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
1645    if test "x${have_ecore_evas_software_xlib}" = "xstatic"; then
1646       have_ecore_evas_software_xlib="yes"
1647    fi
1648    if test "x${have_ecore_evas_software_xlib}" = "xyes" -a "x${have_ecore_x_xlib}" = "xyes" ; then
1649       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
1650    fi
1651    have_ecore_evas_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
1652    if test "x$have_ecore_evas_software_xcb" = "xstatic"; then
1653       have_ecore_evas_software_xcb="yes"
1654    fi
1655    if test "x$have_ecore_evas_software_xcb" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1656       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
1657    fi
1658 fi
1659
1660 # ecore_evas_opengl_x11
1661
1662 ECORE_EVAS_CHECK_MODULE([opengl-x11],
1663    [${want_ecore_evas_opengl_x11}],
1664    [OpenGL Xlib],
1665    [${have_ecore_x}])
1666
1667 have_ecore_evas_opengl_xlib="no"
1668 have_ecore_evas_opengl_xcb="no"
1669 if test "x${have_ecore_evas_opengl_x11}" = "xyes" -o "x${have_ecore_evas_opengl_x11}" = "xstatic" ; then
1670    have_ecore_evas_opengl_xlib=`${PKG_CONFIG} --variable=Xlib evas-opengl-x11`
1671    if test "x${have_ecore_evas_opengl_xlib}" = "xyes" ; then
1672       AC_DEFINE(BUILD_ECORE_EVAS_OPENGL_XLIB, 1, [OpenGL Xlib rendering backend])
1673    fi
1674
1675 # opengl does not work with xcb (yet)
1676    have_ecore_evas_opengl_xcb=`${PKG_CONFIG} --variable=XCB evas-opengl-x11`
1677    if test "x${have_ecore_evas_opengl_xcb}" = "xstatic"; then
1678       have_ecore_evas_opengl_xcb="yes"
1679    fi
1680    if test "x${have_ecore_evas_opengl_xcb}" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1681       PKG_CHECK_MODULES(XCB_X11, x11-xcb,
1682         [ have_ecore_x_opengl_xcb="yes"
1683           requirements_ecore_x="x11-xcb ${requirements_ecore_x}"
1684           AC_DEFINE(BUILD_ECORE_X_OPENGL_XCB, 1, [Build support for XCB-based OpenGL])
1685           AC_DEFINE(BUILD_ECORE_EVAS_OPENGL_XCB, 1, [OpenGL XCB rendering backend])
1686         ],
1687         [ have_ecore_x_opengl_xcb="no" ])
1688     else
1689       have_ecore_x_opengl_xcb="no"
1690       AC_MSG_NOTICE("XCB-based OpenGL explicitly disabled")
1691     fi
1692 fi
1693
1694 # ecore_evas_software_x11 16 bits
1695
1696 ECORE_EVAS_CHECK_MODULE([software-16-x11],
1697    [${want_ecore_evas_software_16_x11}],
1698    [Software Xlib 16 bits],
1699    [${have_ecore_x_xlib}])
1700
1701 ECORE_EVAS_CHECK_MODULE([software-8-x11],
1702     [$want_ecore_evas_software_8_x11],
1703     [Software 8bit X11],
1704     $have_ecore_x_xcb)
1705
1706
1707 if test "x$have_ecore_evas_software_x11" = "xyes" -o \
1708         "x$have_ecore_evas_opengl_x11" = "xyes" -o \
1709         "x$have_ecore_evas_software_8_x11" = "xyes" -o \
1710         "x$have_ecore_evas_software_16_x11" = "xyes" -o \
1711         "x$have_ecore_evas_software_xcb" = "xyes"; then
1712    AC_DEFINE(BUILD_ECORE_EVAS_X11, 1, [Support for X Window Engines in Ecore_Evas])
1713    requirements_ecore_evas="ecore-x >= 1.0.0 ${requirements_ecore_evas}"
1714 fi
1715
1716 # ecore_evas_win32
1717
1718 ECORE_EVAS_CHECK_MODULE([software-gdi],
1719    [${want_ecore_evas_software_gdi}],
1720    [Software GDI],
1721    [${have_ecore_win32}])
1722
1723 ECORE_EVAS_CHECK_MODULE([software-ddraw],
1724    [${want_ecore_evas_software_ddraw}],
1725    [Software DirectDraw],
1726    [${have_ecore_win32}])
1727
1728 ECORE_EVAS_CHECK_MODULE([direct3d],
1729    [${want_ecore_evas_direct3d}],
1730    [Direct3d],
1731    [${have_ecore_win32}])
1732
1733 ECORE_EVAS_CHECK_MODULE([opengl-glew],
1734    [${want_ecore_evas_opengl_glew}],
1735    [Glew OpenGL],
1736    [${have_ecore_win32}])
1737
1738 ECORE_EVAS_CHECK_MODULE([software-16-ddraw],
1739    [${want_ecore_evas_software_16_ddraw}],
1740    [16 bpp Software DirectDraw],
1741    [${have_ecore_win32}])
1742
1743 if test "x${have_ecore_evas_software_gdi}" = "xyes" -o \
1744         "x${have_ecore_evas_software_ddraw}" = "xyes" -o \
1745         "x${have_ecore_evas_direct3d}" = "xyes" -o \
1746         "x${have_ecore_evas_opengl_glew}" = "xyes" -o \
1747         "x${have_ecore_evas_software_16_ddraw}" = "xyes" ; then
1748    AC_DEFINE(BUILD_ECORE_EVAS_WIN32, 1, [Support for Win32 Engine in Ecore_Evas])
1749    requirements_ecore_evas="ecore-win32 >= 1.0.0 ${requirements_ecore_evas}"
1750 fi
1751
1752 # ecore_evas_software_sdl
1753
1754 ECORE_EVAS_CHECK_MODULE([software-sdl],
1755    [${want_ecore_evas_software_sdl}],
1756    [Software SDL],
1757    [${have_ecore_sdl}],
1758    [requirements_ecore_evas="ecore-sdl >= 1.0.0 ${requirements_ecore_evas}"])
1759
1760 # ecore_evas_gl_sdl
1761
1762 ECORE_EVAS_CHECK_MODULE([opengl-sdl],
1763    [${want_ecore_evas_gl_sdl}],
1764    [OpenGL SDL],
1765    [${have_ecore_sdl}],
1766    [requirements_ecore_evas="ecore-sdl >= 1.0.0 ${requirements_ecore_evas}"])
1767
1768 # ecore_evas_cocoa
1769
1770 ECORE_EVAS_CHECK_MODULE([opengl-cocoa],
1771    [${want_ecore_evas_gl_cocoa}],
1772    [OpenGL Cocoa],
1773    [${have_ecore_cocoa}],
1774    [requirements_ecore_evas="ecore-cocoa >= 1.0.0 ${requirements_ecore_evas}"])
1775
1776 # ecore_evas_directfb
1777
1778 ECORE_EVAS_CHECK_MODULE([directfb],
1779    [${want_ecore_evas_directfb}],
1780    [DirectFB],
1781    [${have_ecore_directfb}],
1782    [requirements_ecore_evas="ecore-directfb >= 1.0.0 ${requirements_ecore_evas}"])
1783
1784 # ecore_evas_fb
1785
1786 ECORE_EVAS_CHECK_MODULE([fb],
1787    [${want_ecore_evas_fb}],
1788    [Linux Framebuffer],
1789    [${have_ecore_fb}],
1790    [requirements_ecore_evas="ecore-fb >= 1.0.0 ${requirements_ecore_evas}"])
1791
1792 # ecore_evas_wince
1793
1794 ECORE_EVAS_CHECK_MODULE([software-16-wince],
1795    [${want_ecore_evas_software_16_wince}],
1796    [16 bpp Software Windows CE],
1797    [${have_ecore_wince}],
1798    [requirements_ecore_evas="ecore-wince >= 1.0.0 ${requirements_ecore_evas}"])
1799
1800 # ecore_evas_ews
1801
1802 ECORE_EVAS_CHECK_MODULE_FULL([ews], [software-buffer],
1803    [${want_ecore_evas_ews}],
1804    [Ecore Evas Single Process Windowing System],
1805    [yes], [])
1806
1807 ### install and build examples
1808
1809 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
1810 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
1811
1812 ### requirements
1813
1814 AC_SUBST(requirements_ecore)
1815 AC_SUBST(requirements_ecore_con)
1816 #AC_SUBST(requirements_ecore_config)
1817 AC_SUBST(requirements_ecore_directfb)
1818 AC_SUBST(requirements_ecore_evas)
1819 AC_SUBST(requirements_ecore_fb)
1820 AC_SUBST(requirements_ecore_file)
1821 AC_SUBST(requirements_ecore_imf)
1822 AC_SUBST(requirements_ecore_imf_evas)
1823 AC_SUBST(requirements_ecore_input)
1824 AC_SUBST(requirements_ecore_input_evas)
1825 AC_SUBST(requirements_ecore_ipc)
1826 AC_SUBST(requirements_ecore_cocoa)
1827 AC_SUBST(requirements_ecore_sdl)
1828 AC_SUBST(requirements_ecore_psl1ght)
1829 AC_SUBST(requirements_ecore_x)
1830 AC_SUBST(requirements_ecore_win32)
1831 AC_SUBST(requirements_ecore_wince)
1832 AC_SUBST(requirements_ecore_imf_xim)
1833
1834 AC_CONFIG_FILES([
1835 Makefile
1836 ecore-con.pc
1837 ecore-config.pc
1838 ecore-directfb.pc
1839 ecore-evas.pc
1840 ecore-fb.pc
1841 ecore-file.pc
1842 ecore-imf.pc
1843 ecore-imf-evas.pc
1844 ecore-ipc.pc
1845 ecore-x.pc
1846 ecore-input.pc
1847 ecore-input-evas.pc
1848 ecore-win32.pc
1849 ecore-sdl.pc
1850 ecore-cocoa.pc
1851 ecore-psl1ght.pc
1852 ecore-wince.pc
1853 ecore.pc
1854 doc/ecore.dox
1855 doc/Makefile
1856 doc/Doxyfile
1857 src/Makefile
1858 src/util/Makefile
1859 src/bin/Makefile
1860 src/lib/Makefile
1861 src/lib/ecore/Makefile
1862 src/lib/ecore_con/Makefile
1863 src/lib/ecore_config/Makefile
1864 src/lib/ecore_directfb/Makefile
1865 src/lib/ecore_evas/Makefile
1866 src/lib/ecore_fb/Makefile
1867 src/lib/ecore_file/Makefile
1868 src/lib/ecore_cocoa/Makefile
1869 src/lib/ecore_sdl/Makefile
1870 src/lib/ecore_psl1ght/Makefile
1871 src/lib/ecore_imf/Makefile
1872 src/lib/ecore_imf_evas/Makefile
1873 src/lib/ecore_input/Makefile
1874 src/lib/ecore_input_evas/Makefile
1875 src/lib/ecore_ipc/Makefile
1876 src/lib/ecore_win32/Makefile
1877 src/lib/ecore_wince/Makefile
1878 src/lib/ecore_x/Makefile
1879 src/lib/ecore_x/xlib/Makefile
1880 src/lib/ecore_x/xcb/Makefile
1881 src/examples/Makefile
1882 src/tests/Makefile
1883 src/modules/Makefile
1884 src/modules/immodules/Makefile
1885 src/modules/immodules/xim/Makefile
1886 README
1887 ecore.spec
1888 $po_makefile_in
1889 ])
1890
1891 AC_OUTPUT
1892
1893 echo
1894 echo "$PACKAGE $VERSION"
1895 echo
1896 echo "Optional Modules:"
1897 echo
1898 echo " Core:"
1899 echo
1900 echo "  Ecore........................: always"
1901 echo "    Thread support.............: $have_threads"
1902 echo "    Thread safety..............: $want_thread_safety"
1903 echo "    GLib support...............: $have_glib"
1904 echo "    Always integrate GLib......: $want_glib_integration_always"
1905 echo "    Use g_main_loop............: $want_g_main_loop"
1906 echo "    Gathering memory statistic.: $have_mallinfo"
1907 echo "    Gathering timer allocation.: $want_ecore_timer_dump"
1908 echo "  Ecore_Con....................: $have_ecore_con"
1909 if test "x$have_ecore_con" = "xyes" ; then
1910   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1911 if test "x$have_gnutls" = "xyes" ; then
1912   echo " (disabled)"
1913 else
1914   echo
1915 fi
1916   echo "    IPv6.......................: $have_ipv6"
1917   echo "    GnuTLS.....................: $have_gnutls"
1918   echo "    CURL.......................: $have_curl"
1919   echo "    Local Sockets..............: $want_ecore_con_local_sockets"
1920 if test "x$want_ecore_con_local_sockets" = "xyes" ; then
1921   echo "      Abstract Sockets.........: $want_ecore_con_abstract_sockets"
1922 fi
1923   echo "    c-ares.....................: $have_cares"
1924 fi
1925 echo "  Ecore_Ipc....................: $have_ecore_ipc"
1926 if test "x$have_ecore_ipc" = "xyes" ; then
1927   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1928 if test "x$have_gnutls" = "xyes" ; then
1929   echo " (disabled)"
1930 else
1931   echo
1932 fi
1933   echo "    GnuTLS.....................: $have_gnutls"
1934 fi
1935 echo "  Ecore_File...................: $have_ecore_file"
1936 if test "x$have_ecore_file" = "xyes" ; then
1937   echo "    Inotify....................: $have_inotify"
1938   echo "    Windows notification.......: $have_notify_win32"
1939   echo "    Poll.......................: $have_poll"
1940   echo "    CURL.......................: $have_curl"
1941 fi
1942 #echo "  Ecore_Config.................: $have_ecore_config (deprecated)"
1943 echo "  Ecore_IMF....................: $have_ecore_imf"
1944 echo "    XIM........................: $have_ecore_imf_xim"
1945 echo "  Ecore_IMF_Evas...............: $have_ecore_imf_evas"
1946 echo "  Ecore_Input..................: $have_ecore_input"
1947 echo "  Ecore_Input_Evas.............: $have_ecore_input_evas"
1948
1949 echo
1950 echo " Graphic systems:"
1951 echo
1952
1953 if test "x$have_ecore_x" = "xyes" ; then
1954   if test "x$have_ecore_x_xcb" = "xyes" ; then
1955     echo "  Ecore_X (XCB backend)........: $have_ecore_x_xcb"
1956     echo "    Xprint.....................: $have_ecore_x_xcb_xprint"
1957     echo "    Xinerama...................: $have_ecore_x_xcb_xinerama"
1958     echo "    Xrandr.....................: $have_ecore_x_xcb_randr"
1959     echo "    Xscreensaver...............: $have_ecore_x_xcb_screensaver"
1960     echo "    Xshape.....................: $have_ecore_x_xcb_shape"
1961     echo "    Xgesture...................: $have_ecore_x_xcb_gesture"
1962     echo "    Xsync......................: $have_ecore_x_xcb_sync"
1963     echo "    Xrender....................: $have_ecore_x_xcb_render"
1964     echo "    Xcomposite.................: $have_ecore_x_xcb_composite"
1965     echo "    Xfixes.....................: $have_ecore_x_xcb_xfixes"
1966     echo "    Xdamage....................: $have_ecore_x_xcb_damage"
1967     echo "    Xdpms......................: $have_ecore_x_xcb_dpms"
1968     echo "    Xtest......................: $have_ecore_x_xcb_xtest"
1969   else
1970     echo "  Ecore_X (Xlib backend).......: $have_ecore_x"
1971     echo "    Xcursor....................: $use_Xcursor"
1972     echo "    Xkb........................: $use_xkb"
1973     echo "    Xprint.....................: $use_xprint"
1974     echo "    Xinerama...................: $use_xinerama"
1975     echo "    Xrandr.....................: $use_xrandr"
1976     echo "    Xgesture...................: $use_xgesture"
1977     echo "    Xscreensaver...............: $use_xss"
1978     echo "    Xrender....................: $use_xrender"
1979     echo "    Xcomposite.................: $use_xcomposite"
1980     echo "    Xfixes.....................: $use_xfixes"
1981     echo "    Xdamage....................: $use_xdamage"
1982     echo "    Xdpms......................: $use_xdpms"
1983     echo "    Xtest......................: $use_xtest"
1984     echo "    XIM........................: $want_xim"
1985     echo "    Xi2........................: $use_xi2"
1986   fi
1987 else
1988   echo "  Ecore_X......................: $have_ecore_x"
1989 fi
1990 echo "  Ecore_Win32..................: $have_ecore_win32"
1991 echo "  Ecore_Cocoa..................: $have_ecore_cocoa"
1992 echo "  Ecore_SDL....................: $have_ecore_sdl"
1993 echo "  Ecore_FB.....................: $have_ecore_fb"
1994 if test "x${have_ecore_fb}" = "xyes" ; then
1995   echo "    Touchscreen................: $have_tslib"
1996 fi
1997 echo "  Ecore_DirectFB...............: $have_ecore_directfb"
1998 echo "  Ecore_WinCE..................: $have_ecore_wince"
1999 echo "  Ecore_PSL1GHT................: $have_ecore_psl1ght"
2000
2001 echo
2002 echo " Ecore Evas:"
2003 echo
2004
2005 echo "  Ecore_Evas...................: $have_ecore_evas"
2006 if test "x${have_ecore_evas}" = "xyes" ; then
2007   echo "    Software Memory Buffer.....: $have_ecore_evas_software_buffer"
2008   if test "x${have_ecore_evas_software_x11}" = "xyes" ; then
2009     echo "    Software X11...............: $have_ecore_evas_software_x11 (Xlib=${have_ecore_evas_software_xlib}) (XCB=${have_ecore_evas_software_xcb})"
2010   else
2011     echo "    Software X11...............: $have_ecore_evas_software_x11"
2012   fi
2013   if test "x${have_ecore_evas_opengl_x11}" = "xyes" ; then
2014     echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11 (Xlib=${have_ecore_evas_opengl_xlib}) (XCB=${have_ecore_evas_opengl_xcb})"
2015   else
2016     echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11"
2017   fi
2018   echo "    Software GDI...............: $have_ecore_evas_software_gdi"
2019   echo "    Software DirectDraw........: $have_ecore_evas_software_ddraw"
2020   echo "    Direct3D...................: $have_ecore_evas_direct3d"
2021   echo "    OpenGL Glew................: $have_ecore_evas_opengl_glew"
2022   echo "    Software SDL...............: $have_ecore_evas_software_sdl"
2023   echo "    OpenGL SDL.................: $have_ecore_evas_opengl_sdl"
2024   echo "    OpenGL Cocoa...............: $have_ecore_evas_opengl_cocoa"
2025   echo "    DirectFB...................: $have_ecore_evas_directfb"
2026   echo "    Software Framebuffer.......: $have_ecore_evas_fb"
2027   echo "    Software 8bit grayscale XCB: $have_ecore_evas_software_8_x11"
2028   echo "    Software 16bit X11.........: $have_ecore_evas_software_16_x11"
2029   echo "    Software 16bit DirectDraw..: $have_ecore_evas_software_16_ddraw"
2030   echo "    Software 16bit WinCE.......: $have_ecore_evas_software_16_wince"
2031   echo "    Sing.Proc. Windowing System: $have_ecore_evas_ews"
2032 fi
2033 echo
2034 echo "  Tests................: ${enable_tests}"
2035 echo "  Maximum log level....: ${with_max_log_level}"
2036 echo "Documentation..........: ${build_doc}"
2037 echo
2038 echo "Compilation............: make (or gmake)"
2039 echo "  CPPFLAGS.............: $CPPFLAGS"
2040 echo "  CFLAGS...............: $CFLAGS"
2041 echo "  CXXFLAGS.............: $CXXFLAGS"
2042 echo "  LDFLAGS..............: $LDFLAGS"
2043 echo
2044 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
2045 echo "  prefix...............: $prefix"
2046 echo