configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.62)
  24
  25 m4_define(PA_MAJOR, [0])
  26 m4_define(PA_MINOR, [9])
  27 m4_define(PA_MICRO, [12])
  28
  29 AC_INIT([pulseaudio],[PA_MAJOR.PA_MINOR.PA_MICRO],[mzchyfrnhqvb (at) 0pointer (dot) net])
  30 AC_CONFIG_SRCDIR([src/daemon/main.c])
  31 AC_CONFIG_MACRO_DIR([m4])
  32 AC_CONFIG_HEADERS([config.h])
  33 AM_INIT_AUTOMAKE([foreign 1.10 -Wall])
  34
  35 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  36 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
  37
  38 AC_SUBST(PA_API_VERSION, 12)
  39 AC_SUBST(PA_PROTOCOL_VERSION, 14)
  40
  41 # The stable ABI for client applications, for the version info x:y:z
  42 # always will hold y=z
  43 AC_SUBST(LIBPULSE_VERSION_INFO, [5:0:5])
  44
  45 # A simplified, synchronous, ABI-stable interface for client
  46 # applications, for the version info x:y:z always will hold y=z
  47 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:1:0])
  48
  49 # The ABI-stable network browsing interface for client applications,
  50 # for the version info x:y:z always will hold y=z
  51 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  52
  53 # The ABI-stable GLib adapter for client applications, for the version
  54 # info x:y:z always will hold y=z
  55 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:3:0])
  56
  57 # An internally used, ABI-unstable library that contains the
  58 # PulseAudio core, SONAMEs are bumped on every release, version info
  59 # suffix will always be 0:0
  60 AC_SUBST(LIBPULSECORE_VERSION_INFO, [6:0:0])
  61
  62 AC_CANONICAL_HOST
  63 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  64
  65 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  66    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  67    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  68 fi
  69
  70 #### Platform hacks ####
  71
  72 case $host in
  73    *-*-solaris* )
  74       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  75       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  76       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  77       ;;
  78 esac
  79
  80 #### Checks for programs. ####
  81
  82 # mkdir -p
  83
  84 AC_PROG_MKDIR_P
  85
  86 # CC
  87
  88 AC_PROG_CC
  89 AC_PROG_CC_C99
  90 AM_PROG_CC_C_O
  91 AC_PROG_GCC_TRADITIONAL
  92 AC_USE_SYSTEM_EXTENSIONS
  93
  94 # M4
  95
  96 AC_PATH_PROG([M4], [m4 gm4], [no])
  97 if test "x$M4" = xno ; then
  98    AC_MSG_ERROR([m4 missing])
  99 fi
 100
 101 dnl Compiler flags
 102 DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter -ffast-math"
 103
 104 for flag in $DESIRED_FLAGS ; do
 105   CC_CHECK_CFLAGS([$flag], [CFLAGS="$CFLAGS $flag"])
 106 done
 107
 108 # Native atomic operation support
 109 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 110     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]),
 111         [
 112             case "${enableval}" in
 113                 yes) atomic_arm_linux_helpers=yes ;;
 114                 no) atomic_arm_linux_helpers=no ;;
 115                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 116             esac
 117         ],
 118         [atomic_arm_linux_helpers=auto])
 119
 120 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 121     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]),
 122         [
 123             case "${enableval}" in
 124                 yes) AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers]) ;;
 125                 no) ;;
 126                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 127             esac
 128         ],)
 129
 130 AC_MSG_CHECKING([target operating system])
 131 case $host in
 132         *-*-linux*)
 133             AC_MSG_RESULT([linux])
 134             pulse_target_os=linux
 135         ;;
 136         *)
 137             AC_MSG_RESULT([unknown])
 138             pulse_target_os=unknown
 139         ;;
 140 esac
 141
 142 # If everything else fails use libatomic_ops
 143 need_libatomic_ops=yes
 144
 145 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 146   pulseaudio_cv_sync_bool_compare_and_swap,
 147   [AC_LINK_IFELSE(
 148      AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
 149      [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 150      [pulseaudio_cv_sync_bool_compare_and_swap=no])
 151   ])
 152
 153 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 154     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 155     need_libatomic_ops=no
 156 else
 157     # HW specific atomic ops stuff
 158     AC_MSG_CHECKING([architecture for native atomic operations])
 159     case $host_cpu in
 160         arm*)
 161             AC_MSG_RESULT([arm])
 162             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 163             # The Linux kernel helper functions have been there since 2.6.16. However
 164             # compile time checking for kernel version in cross compile environment
 165             # (which is usually the case for arm cpu) is tricky (or impossible).
 166             if test "x$pulse_target_os" = "xlinux" && test "x$atomic_arm_linux_helpers" != "xno"; then
 167                 AC_MSG_RESULT([yes])
 168                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 169                 need_libatomic_ops=no
 170             else
 171                AC_MSG_RESULT([no])
 172                AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 173                  pulseaudio_cv_support_arm_atomic_ops,
 174                  [AC_COMPILE_IFELSE(
 175                     AC_LANG_PROGRAM([],
 176                       [[volatile int a=0;
 177                         int o=0, n=1, r;
 178                         asm volatile ("ldrex    %0, [%1]\n"
 179                                          "subs  %0, %0, %2\n"
 180                                          "strexeq %0, %3, [%1]\n"
 181                                          : "=&r" (r)
 182                                          : "r" (&a), "Ir" (o), "r" (n)
 183                                          : "cc");
 184                         return (a==1 ? 0 : -1);
 185                       ]]),
 186                     [pulseaudio_cv_support_arm_atomic_ops=yes],
 187                     [pulseaudio_cv_support_arm_atomic_ops=no])
 188                  ])
 189                AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 190                    AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARMv6 instructions.])
 191                    need_libatomic_ops=no
 192                  ])
 193            fi
 194         ;;
 195         *)
 196             AC_MSG_RESULT([unknown])
 197         ;;
 198     esac
 199 fi
 200
 201 CC_CHECK_TLS
 202
 203 AC_CACHE_CHECK([whether $CC knows _Bool],
 204   pulseaudio_cv__Bool,
 205   [AC_COMPILE_IFELSE(
 206      AC_LANG_PROGRAM([], [[_Bool b;]]),
 207      [pulseaudio_cv__Bool=yes],
 208      [pulseaudio_cv__Bool=no])
 209   ])
 210
 211 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], [
 212     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 213   ])
 214
 215 #### libtool stuff ####
 216
 217 AC_LTDL_ENABLE_INSTALL
 218 AC_LIBLTDL_INSTALLABLE
 219 AC_LIBTOOL_DLOPEN
 220 AC_LIBTOOL_WIN32_DLL
 221 AC_PROG_LIBTOOL
 222 AC_SUBST(LTDLINCL)
 223 AC_SUBST(LIBLTDL)
 224 AC_CONFIG_SUBDIRS(libltdl)
 225
 226 old_LIBS=$LIBS
 227 LIBS="$LIBS $LIBLTDL"
 228 AC_CHECK_FUNCS([lt_dlmutex_register])
 229 LIBS=$old_LIBS
 230 AC_CHECK_TYPES([struct lt_user_dlloader, lt_dladvise], , , [#include <ltdl.h>])
 231
 232 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 233     AC_MSG_ERROR([[
 234
 235         *** Cannot find the libltdl development files.
 236         *** Maybe you need to install the libltdl-dev package.
 237         ]])
 238 fi
 239
 240 #### Determine build environment ####
 241
 242 os_is_win32=0
 243
 244 case "$host_os" in
 245         mingw*)
 246         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 247         os_is_win32=1
 248                 ;;
 249         esac
 250
 251 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 252
 253 ###################################
 254 #   Basic environment checks      #
 255 ###################################
 256
 257 #### Checks for header files. ####
 258
 259 # ISO
 260 AC_HEADER_STDC
 261
 262 # POSIX
 263 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 264     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 265     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 266     syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 267 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 268                  [#include <sys/types.h>
 269                   #if HAVE_NETINET_IN_H
 270                   # include <netinet/in.h>
 271                   #endif
 272                   #if HAVE_NETINET_IN_SYSTM_H
 273                   # include <netinet/in_systm.h>
 274                   #endif
 275                  ])
 276 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 277 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 278
 279 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 280 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 281
 282 # Linux
 283 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 284
 285 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 286
 287 AC_CHECK_HEADERS([sys/prctl.h])
 288
 289 # Solaris
 290 AC_CHECK_HEADERS([sys/filio.h])
 291
 292 # Windows
 293 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 294
 295 # Other
 296 AC_CHECK_HEADERS([sys/ioctl.h])
 297 AC_CHECK_HEADERS([byteswap.h])
 298 AC_CHECK_HEADERS([sys/syscall.h])
 299
 300 #### Typdefs, structures, etc. ####
 301
 302 AC_C_CONST
 303 AC_C_BIGENDIAN
 304 AC_TYPE_PID_T
 305 AC_TYPE_SIZE_T
 306 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 307     [Define ssize_t if it is not done by the standard libs.])])
 308 AC_TYPE_OFF_T
 309 AC_TYPE_SIGNAL
 310 AC_TYPE_UID_T
 311 AC_CHECK_DECLS(environ)
 312
 313 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 314 HAVE_SIGXCPU=1
 315 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 316 ], [HAVE_SIGXCPU=0])
 317 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 318
 319 # Solaris lacks this
 320 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 321     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 322         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 323
 324 #### POSIX threads ####
 325
 326 ACX_PTHREAD
 327
 328 #### Check for libs ####
 329
 330 # ISO
 331 AC_SEARCH_LIBS([pow], [m])
 332
 333 # POSIX
 334 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 335 AC_SEARCH_LIBS([dlopen], [dl])
 336 AC_SEARCH_LIBS([shm_open], [rt])
 337 AC_SEARCH_LIBS([inet_ntop], [nsl])
 338 AC_SEARCH_LIBS([timer_create], [rt])
 339
 340 # BSD
 341 AC_SEARCH_LIBS([connect], [socket])
 342
 343 # Non-standard
 344
 345 # This magic is needed so we do not needlessly add static libs to the win32
 346 # build, disabling its ability to make dlls.
 347 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 348
 349 AC_CHECK_LIB(gdbm, gdbm_open)
 350 AC_CHECK_HEADERS(gdbm.h, [], [AC_MSG_ERROR([gdbm.h not found])])
 351
 352 #### Check for functions ####
 353
 354 # ISO
 355 AC_CHECK_FUNCS([lrintf strtof])
 356
 357 # POSIX
 358 AC_FUNC_FORK
 359 AC_FUNC_GETGROUPS
 360 AC_FUNC_SELECT_ARGTYPES
 361 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r \
 362     getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 363     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 364     sigaction sleep sysconf])
 365 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 366
 367 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 368
 369 # X/OPEN
 370 AC_CHECK_FUNCS([readlink])
 371
 372 # SUSv2
 373 AC_CHECK_FUNCS([ctime_r usleep])
 374
 375 # SUSv3
 376 AC_CHECK_FUNCS([strerror_r])
 377
 378 # BSD
 379 AC_CHECK_FUNCS([lstat])
 380
 381 # Non-standard
 382
 383 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 384
 385 AC_FUNC_ALLOCA
 386
 387 AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
 388   pulseaudio_cv_PTHREAD_PRIO_INHERIT,
 389   [save_CC=$CC; CC=$PTHREAD_CC
 390    save_CFLAGS=$CFLAGS; CFLAGS=$PTHREAD_CFLAGS
 391    save_LIBS=$LIBS; LIBS=$PTHREAD_LIBS
 392    AC_LINK_IFELSE(
 393      AC_LANG_PROGRAM(
 394        [[
 395          #include <pthread.h>
 396        ]],
 397        [[int i = PTHREAD_PRIO_INHERIT;]]),
 398      [pulseaudio_cv_PTHREAD_PRIO_INHERIT=yes],
 399      [pulseaudio_cv_PTHREAD_PRIO_INHERIT=no])
 400    CC=$save_CC
 401    CFLAGS=$save_CFLAGS
 402    LIBS=$save_LIBS
 403   ])
 404
 405 AS_IF([test "$pulseaudio_cv_PTHREAD_PRIO_INHERIT" = "yes"], [
 406     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 407   ])
 408
 409 #### Large File-Support (LFS) ####
 410
 411 AC_SYS_LARGEFILE
 412
 413 # Check for open64 to know if the current system does have open64() and similar functions
 414 AC_CHECK_FUNCS([open64])
 415
 416 #### [lib]iconv ####
 417
 418 AM_ICONV
 419
 420 IT_PROG_INTLTOOL([0.35.0])
 421 GETTEXT_PACKAGE=pulseaudio
 422 AC_SUBST([GETTEXT_PACKAGE])
 423 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 424 AM_GLIB_GNU_GETTEXT
 425
 426 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 427 AC_SUBST(pulselocaledir)
 428
 429 ###################################
 430 #      External libraries         #
 431 ###################################
 432
 433 #### X11 (optional) ####
 434
 435 HAVE_X11=0
 436
 437 # The macro tests the host, not the build target
 438 if test "x$os_is_win32" != "x1" ; then
 439     AC_PATH_XTRA
 440     test "x$no_x" != "xyes" && HAVE_X11=1
 441 fi
 442
 443 AC_SUBST(HAVE_X11)
 444 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 445 if test "x$HAVE_X11" = "x1" ; then
 446     AC_DEFINE([HAVE_X11], 1, [Have X11])
 447 fi
 448
 449 #### Capabilities (optional) ####
 450
 451 CAP_LIBS=''
 452
 453 AC_ARG_WITH(
 454         [caps],
 455         AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 456
 457 if test "x${with_caps}" != "xno"; then
 458     AC_SEARCH_LIBS([cap_init], [cap], [], [
 459                     if test "x${with_caps}" = "xyes" ; then
 460                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 461                     fi])
 462     AC_CHECK_HEADERS([sys/capability.h], [], [
 463                     if test "x${with_caps}" = "xyes" ; then
 464                         AC_MSG_ERROR([*** POSIX caps headers not found])
 465                     fi])
 466 fi
 467
 468 #### Valgrind (optional) ####
 469
 470 AC_CHECK_HEADERS([valgrind/memcheck.h])
 471
 472 #### pkg-config ####
 473
 474 # Check for pkg-config manually first, as if its not installed the
 475 # PKG_PROG_PKG_CONFIG macro won't be defined.
 476 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 477
 478 if test x"$have_pkg_config" = "xno"; then
 479     AC_MSG_ERROR(pkg-config is required to install this program)
 480 fi
 481
 482 PKG_PROG_PKG_CONFIG
 483
 484 #### Sound file ####
 485
 486 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 487 AC_SUBST(LIBSNDFILE_CFLAGS)
 488 AC_SUBST(LIBSNDFILE_LIBS)
 489
 490 PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ])
 491 AC_SUBST(LIBSPEEX_CFLAGS)
 492 AC_SUBST(LIBSPEEX_LIBS)
 493
 494 #### atomic-ops ###
 495
 496 AC_MSG_CHECKING([whether we need libatomic_ops])
 497 if test "x$need_libatomic_ops" = "xyes"; then
 498    AC_MSG_RESULT([yes])
 499    AC_CHECK_HEADERS([atomic_ops.h], [], [
 500    AC_MSG_ERROR([*** libatomic-ops headers not found])
 501    ])
 502
 503    # Win32 does not need the lib and breaks horribly if we try to include it
 504    if test "x$os_is_win32" != "x1" ; then
 505        LIBS="$LIBS -latomic_ops"
 506    fi
 507 else
 508    AC_MSG_RESULT([no])
 509 fi
 510
 511 #### Libsamplerate support (optional) ####
 512
 513 AC_ARG_ENABLE([samplerate],
 514     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]),
 515         [
 516             case "${enableval}" in
 517                 yes) samplerate=yes ;;
 518                 no) samplerate=no ;;
 519                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 520             esac
 521         ],
 522         [samplerate=auto])
 523
 524 if test "x${samplerate}" != xno ; then
 525     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 526         HAVE_LIBSAMPLERATE=1,
 527         [
 528             HAVE_LIBSAMPLERATE=0
 529             if test "x$samplerate" = xyes ; then
 530                 AC_MSG_ERROR([*** Libsamplerate not found])
 531             fi
 532         ])
 533 else
 534     HAVE_LIBSAMPLERATE=0
 535 fi
 536
 537 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 538    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 539 fi
 540
 541 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 542 AC_SUBST(LIBSAMPLERATE_LIBS)
 543 AC_SUBST(HAVE_LIBSAMPLERATE)
 544 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 545
 546 #### OSS support (optional) ####
 547
 548 AC_ARG_ENABLE([oss],
 549     AS_HELP_STRING([--disable-oss],[Disable optional OSS support]),
 550         [
 551             case "${enableval}" in
 552                 yes) oss=yes ;;
 553                 no) oss=no ;;
 554                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 555             esac
 556         ],
 557         [oss=auto])
 558
 559 if test "x${oss}" != xno ; then
 560     AC_CHECK_HEADERS([sys/soundcard.h],
 561         [
 562             HAVE_OSS=1
 563             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 564         ],
 565         [
 566             HAVE_OSS=0
 567             if test "x$oss" = xyes ; then
 568                 AC_MSG_ERROR([*** OSS support not found])
 569             fi
 570         ])
 571 else
 572     HAVE_OSS=0
 573 fi
 574
 575 AC_SUBST(HAVE_OSS)
 576 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 577
 578
 579 #### ALSA support (optional) ####
 580
 581 AC_ARG_ENABLE([alsa],
 582     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]),
 583         [
 584             case "${enableval}" in
 585                 yes) alsa=yes ;;
 586                 no) alsa=no ;;
 587                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 588             esac
 589         ],
 590         [alsa=auto])
 591
 592 if test "x${alsa}" != xno ; then
 593     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.17 ],
 594         [
 595             HAVE_ALSA=1
 596             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 597         ],
 598         [
 599             HAVE_ALSA=0
 600             if test "x$alsa" = xyes ; then
 601                 AC_MSG_ERROR([*** Needed alsa >= 1.0.17 support not found])
 602             fi
 603         ])
 604 else
 605     HAVE_ALSA=0
 606 fi
 607
 608 AC_SUBST(ASOUNDLIB_CFLAGS)
 609 AC_SUBST(ASOUNDLIB_LIBS)
 610 AC_SUBST(HAVE_ALSA)
 611 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 612
 613 #### Solaris audio support (optional) ####
 614
 615 AC_ARG_ENABLE([solaris],
 616     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]),
 617         [
 618             case "${enableval}" in
 619                 yes) solaris=yes ;;
 620                 no) solaris=no ;;
 621                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 622             esac
 623         ],
 624         [solaris=auto])
 625
 626 if test "x${solaris}" != xno ; then
 627     AC_CHECK_HEADERS([sys/audio.h],
 628         [
 629             HAVE_SOLARIS=1
 630             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 631         ],
 632         [
 633             HAVE_SOLARIS=0
 634             if test "x$solaris" = xyes ; then
 635                 AC_MSG_ERROR([*** Solaris audio support not found])
 636             fi
 637         ])
 638 else
 639     HAVE_SOLARIS=0
 640 fi
 641
 642 AC_SUBST(HAVE_SOLARIS)
 643 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 644
 645 #### GLib 2 support (optional) ####
 646
 647 AC_ARG_ENABLE([glib2],
 648     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]),
 649         [
 650             case "${enableval}" in
 651                 yes) glib2=yes ;;
 652                 no) glib2=no ;;
 653                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 654             esac
 655         ],
 656         [glib2=auto])
 657
 658 if test "x${glib2}" != xno ; then
 659     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 660         HAVE_GLIB20=1,
 661         [
 662             HAVE_GLIB20=0
 663             if test "x$glib2" = xyes ; then
 664                 AC_MSG_ERROR([*** GLib 2 support not found])
 665             fi
 666         ])
 667 else
 668     HAVE_GLIB20=0
 669 fi
 670
 671 AC_SUBST(GLIB20_CFLAGS)
 672 AC_SUBST(GLIB20_LIBS)
 673 AC_SUBST(HAVE_GLIB20)
 674 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 675
 676 #### GConf support (optional) ####
 677
 678 AC_ARG_ENABLE([gconf],
 679     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]),
 680         [
 681             case "${enableval}" in
 682                 yes) gconf=yes ;;
 683                 no) gconf=no ;;
 684                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 685             esac
 686         ],
 687         [gconf=auto])
 688
 689 if test "x${gconf}" != xno ; then
 690     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 691         HAVE_GCONF=1,
 692         [
 693             HAVE_GCONF=0
 694             if test "x$gconf" = xyes ; then
 695                 AC_MSG_ERROR([*** GConf support not found])
 696             fi
 697         ])
 698 else
 699     HAVE_GCONF=0
 700 fi
 701
 702 AC_SUBST(GCONF_CFLAGS)
 703 AC_SUBST(GCONF_LIBS)
 704 AC_SUBST(HAVE_GCONF)
 705 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 706
 707 #### Avahi support (optional) ####
 708
 709 AC_ARG_ENABLE([avahi],
 710     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]),
 711         [
 712             case "${enableval}" in
 713                 yes) avahi=yes ;;
 714                 no) avahi=no ;;
 715                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 716             esac
 717         ],
 718         [avahi=auto])
 719
 720 if test "x${avahi}" != xno ; then
 721     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 722         HAVE_AVAHI=1,
 723         [
 724                 HAVE_AVAHI=0
 725                 if test "x$avahi" = xyes ; then
 726                         AC_MSG_ERROR([*** Avahi support not found])
 727                 fi
 728         ])
 729 else
 730     HAVE_AVAHI=0
 731 fi
 732
 733 AC_SUBST(AVAHI_CFLAGS)
 734 AC_SUBST(AVAHI_LIBS)
 735 AC_SUBST(HAVE_AVAHI)
 736 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 737
 738 ### LIBOIL ####
 739
 740 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 741 AC_SUBST(LIBOIL_CFLAGS)
 742 AC_SUBST(LIBOIL_LIBS)
 743
 744 ### JACK (optional) ####
 745
 746 AC_ARG_ENABLE([jack],
 747     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]),
 748         [
 749             case "${enableval}" in
 750                 yes) jack=yes ;;
 751                 no) jack=no ;;
 752                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 753             esac
 754         ],
 755         [jack=auto])
 756
 757 if test "x${jack}" != xno ; then
 758     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 759         HAVE_JACK=1,
 760         [
 761             HAVE_JACK=0
 762             if test "x$jack" = xyes ; then
 763                 AC_MSG_ERROR([*** JACK support not found])
 764             fi
 765         ])
 766 else
 767     HAVE_JACK=0
 768 fi
 769
 770 AC_SUBST(JACK_CFLAGS)
 771 AC_SUBST(JACK_LIBS)
 772 AC_SUBST(HAVE_JACK)
 773 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 774
 775 #### Async DNS support (optional) ####
 776
 777 AC_ARG_ENABLE([asyncns],
 778     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]),
 779         [
 780             case "${enableval}" in
 781                 yes) asyncns=yes ;;
 782                 no) asyncns=no ;;
 783                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 784             esac
 785         ],
 786         [asyncns=auto])
 787
 788 if test "x${asyncns}" != xno ; then
 789     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 790         HAVE_LIBASYNCNS=1,
 791         [
 792             HAVE_LIBASYNCNS=0
 793             if test "x$asyncns" = xyes ; then
 794                 AC_MSG_ERROR([*** Async DNS support not found])
 795             fi
 796         ])
 797 else
 798     HAVE_LIBASYNCNS=0
 799 fi
 800
 801 AC_SUBST(LIBASYNCNS_CFLAGS)
 802 AC_SUBST(LIBASYNCNS_LIBS)
 803 AC_SUBST(HAVE_LIBASYNCNS)
 804 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 805
 806 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 807    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 808 fi
 809
 810 #### TCP wrappers (optional) ####
 811
 812 AC_ARG_ENABLE([tcpwrap],
 813     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 814         [
 815             case "${enableval}" in
 816                 yes) tcpwrap=yes ;;
 817                 no) tcpwrap=no ;;
 818                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 819             esac
 820         ],
 821         [tcpwrap=auto])
 822
 823 if test "x${tcpwrap}" != xno ; then
 824     ACX_LIBWRAP
 825     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 826         AC_MSG_ERROR([*** TCP wrappers support not found])
 827     fi
 828 else
 829     LIBWRAP_LIBS=
 830 fi
 831
 832 AC_SUBST(LIBWRAP_LIBS)
 833
 834 #### LIRC support (optional) ####
 835
 836 AC_ARG_ENABLE([lirc],
 837     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]),
 838         [
 839             case "${enableval}" in
 840                 yes) lirc=yes ;;
 841                 no) lirc=no ;;
 842                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 843             esac
 844         ],
 845         [lirc=auto])
 846
 847 if test "x${lirc}" != xno ; then
 848     ACX_LIRC
 849     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 850         AC_MSG_ERROR([*** LIRC support not found])
 851     fi
 852 else
 853     HAVE_LIRC=0
 854 fi
 855
 856 AC_SUBST(LIRC_CFLAGS)
 857 AC_SUBST(LIRC_LIBS)
 858 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 859
 860 #### HAL support (optional) ####
 861
 862 AC_ARG_ENABLE([hal],
 863     AS_HELP_STRING([--disable-hal],[Disable optional HAL support]),
 864         [
 865             case "${enableval}" in
 866                 yes) hal=yes ;;
 867                 no) hal=no ;;
 868                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 869             esac
 870         ],
 871         [hal=auto])
 872 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 873     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 874         HAVE_HAL=1,
 875         [
 876             HAVE_HAL=0
 877             if test "x$hal" = xyes ; then
 878                 AC_MSG_ERROR([*** HAL support not found])
 879             fi
 880         ])
 881 else
 882     HAVE_HAL=0
 883 fi
 884
 885 AC_SUBST(HAL_CFLAGS)
 886 AC_SUBST(HAL_LIBS)
 887 AC_SUBST(HAVE_HAL)
 888 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 889
 890 #### BlueZ support (optional) ####
 891
 892 AC_ARG_ENABLE([bluez],
 893     AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]),
 894         [
 895             case "${enableval}" in
 896                 yes) bluez=yes ;;
 897                 no) bluez=no ;;
 898                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-bluez) ;;
 899             esac
 900         ],
 901         [bluez=auto])
 902 if test "x${bluez}" != xno ; then
 903     PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ],
 904         HAVE_BLUEZ=1,
 905         [
 906             HAVE_BLUEZ=0
 907             if test "x$bluez" = xyes ; then
 908                 AC_MSG_ERROR([*** BLUEZ support not found])
 909             fi
 910         ])
 911 else
 912     HAVE_BLUEZ=0
 913 fi
 914
 915 AC_SUBST(BLUEZ_CFLAGS)
 916 AC_SUBST(BLUEZ_LIBS)
 917 AC_SUBST(HAVE_BLUEZ)
 918 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 919
 920 #### D-Bus support (optional) ####
 921
 922 AC_ARG_ENABLE([dbus],
 923     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]),
 924         [
 925             case "${enableval}" in
 926                 yes) dbus=yes ;;
 927                 no) dbus=no ;;
 928                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 929             esac
 930         ],
 931         [dbus=auto])
 932
 933 if test "x$HAVE_HAL" = x1 ; then
 934    dbus=yes
 935 fi
 936
 937 if test "x${dbus}" != xno || test "x${bluez}" != xno || "x${hal}" != xno ; then
 938
 939     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 940         [
 941             HAVE_DBUS=1
 942             saved_LIBS="$LIBS"
 943             LIBS="$LIBS $DBUS_LIBS"
 944             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 945             LIBS="$saved_LIBS"
 946             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 947         ],
 948         [
 949             HAVE_DBUS=0
 950             if test "x$dbus" = xyes ; then
 951                 AC_MSG_ERROR([*** D-Bus support not found])
 952             fi
 953         ])
 954 else
 955     HAVE_DBUS=0
 956 fi
 957
 958 AC_SUBST(DBUS_CFLAGS)
 959 AC_SUBST(DBUS_LIBS)
 960 AC_SUBST(HAVE_DBUS)
 961 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 962
 963 #### PolicyKit support (optional) ####
 964
 965 AC_ARG_ENABLE([polkit],
 966     AS_HELP_STRING([--disable-polkit],[Disable optional PolicyKit support]),
 967         [
 968             case "${enableval}" in
 969                 yes) polkit=yes ;;
 970                 no) polkit=no ;;
 971                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-polkit) ;;
 972             esac
 973         ],
 974         [polkit=auto])
 975
 976 if test "x${polkit}" != xno ; then
 977
 978     PKG_CHECK_MODULES(POLKIT, [ polkit-dbus >= 0.7 ],
 979         [
 980             HAVE_POLKIT=1
 981             AC_DEFINE([HAVE_POLKIT], 1, [Have PolicyKit])
 982             policydir=`pkg-config polkit-dbus --variable prefix`/share/PolicyKit/policy/
 983             AC_SUBST(policydir)
 984         ],
 985         [
 986             HAVE_POLKIT=0
 987             if test "x$polkit" = xyes ; then
 988                 AC_MSG_ERROR([*** PolicyKit support not found])
 989             fi
 990         ])
 991 else
 992     HAVE_POLKIT=0
 993 fi
 994
 995 AC_SUBST(POLKIT_CFLAGS)
 996 AC_SUBST(POLKIT_LIBS)
 997 AC_SUBST(HAVE_POLKIT)
 998 AM_CONDITIONAL([HAVE_POLKIT], [test "x$HAVE_POLKIT" = x1])
 999
1000 ### Build and Install man pages ###
1001 AC_ARG_ENABLE(manpages,
1002         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
1003 [case "${enableval}" in
1004   yes) manpages=yes ;;
1005   no)  manpages=no ;;
1006   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
1007 esac],[manpages=yes])
1008
1009 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1010
1011 #### PulseAudio system group & user  #####
1012
1013 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1014 if test -z "$with_system_user" ; then
1015     PA_SYSTEM_USER=pulse
1016 else
1017     PA_SYSTEM_USER=$with_system_user
1018 fi
1019 AC_SUBST(PA_SYSTEM_USER)
1020 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1021
1022 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1023 if test -z "$with_system_group" ; then
1024     PA_SYSTEM_GROUP=pulse
1025 else
1026     PA_SYSTEM_GROUP=$with_system_group
1027 fi
1028 AC_SUBST(PA_SYSTEM_GROUP)
1029 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1030
1031 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
1032 if test -z "$with_realtime_group" ; then
1033     PA_REALTIME_GROUP=pulse-rt
1034 else
1035     PA_REALTIME_GROUP=$with_realtime_group
1036 fi
1037 AC_SUBST(PA_REALTIME_GROUP)
1038 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
1039
1040 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1041 if test -z "$with_access_group" ; then
1042     PA_ACCESS_GROUP=pulse-access
1043 else
1044     PA_ACCESS_GROUP=$with_access_group
1045 fi
1046 AC_SUBST(PA_ACCESS_GROUP)
1047 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1048
1049 AC_ARG_ENABLE(
1050         per_user_esound_socket,
1051         AS_HELP_STRING([--disable-per-user-esound-socket], [Use global esound socket directory /tmp/.esd/socket.]),
1052         [
1053             case "${enableval}" in
1054                 yes) per_user_esound_socket=1 ;;
1055                 no) per_user_esound_socket=0 ;;
1056                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-per-user-esound-socket) ;;
1057             esac
1058         ],
1059         [per_user_esound_socket=1])
1060
1061 if test "x$per_user_esound_socket" = "x1"; then
1062    AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1063 fi
1064
1065 #### PulseAudio system runtime dir ####
1066 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1067 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1068 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1069 AC_SUBST(PA_SYSTEM_CONFIG_PATH)
1070 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1071 AC_SUBST(PA_SYSTEM_STATE_PATH)
1072
1073 ###################################
1074 #            Output               #
1075 ###################################
1076
1077 AC_ARG_ENABLE(
1078         [static-bins],
1079         AS_HELP_STRING([--enable-static-bins],[Statically link executables.]),
1080         [STATIC_BINS=1], [STATIC_BINS=0])
1081 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1082
1083 AC_ARG_WITH(
1084         [preopen-mods],
1085         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1086         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1087 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1088 if test "x$PREOPEN_MODS" != "xall" ; then
1089     tmpLIBS=""
1090     for mod in $PREOPEN_MODS; do
1091         tmpLIBS="$tmpLIBS module-$mod.la"
1092     done
1093     PREOPEN_MODS="$tmpLIBS"
1094     AC_SUBST(PREOPEN_MODS)
1095 fi
1096
1097 AC_ARG_WITH(
1098         [module-dir],
1099         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
1100         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
1101
1102 AC_SUBST(modlibexecdir)
1103
1104 AC_ARG_ENABLE(
1105         [force-preopen],
1106         AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
1107         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
1108 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
1109
1110 AC_CONFIG_FILES([
1111 Makefile
1112 src/Makefile
1113 man/Makefile
1114 libpulse.pc
1115 libpulse-simple.pc
1116 libpulse-browse.pc
1117 libpulse-mainloop-glib.pc
1118 doxygen/Makefile
1119 doxygen/doxygen.conf
1120 src/pulse/version.h
1121 po/Makefile.in
1122 ])
1123 AC_OUTPUT
1124
1125 # ==========================================================================
1126 ENABLE_X11=no
1127 if test "x$HAVE_X11" = "x1" ; then
1128    ENABLE_X11=yes
1129 fi
1130
1131 ENABLE_OSS=no
1132 if test "x$HAVE_OSS" = "x1" ; then
1133    ENABLE_OSS=yes
1134 fi
1135
1136 ENABLE_ALSA=no
1137 if test "x$HAVE_ALSA" = "x1" ; then
1138    ENABLE_ALSA=yes
1139 fi
1140
1141 ENABLE_SOLARIS=no
1142 if test "x$HAVE_SOLARIS" = "x1" ; then
1143    ENABLE_SOLARIS=yes
1144 fi
1145
1146 ENABLE_GLIB20=no
1147 if test "x$HAVE_GLIB20" = "x1" ; then
1148    ENABLE_GLIB20=yes
1149 fi
1150
1151 ENABLE_GCONF=no
1152 if test "x$HAVE_GCONF" = "x1" ; then
1153    ENABLE_GCONF=yes
1154 fi
1155
1156 ENABLE_AVAHI=no
1157 if test "x$HAVE_AVAHI" = "x1" ; then
1158    ENABLE_AVAHI=yes
1159 fi
1160
1161 ENABLE_JACK=no
1162 if test "x$HAVE_JACK" = "x1" ; then
1163    ENABLE_JACK=yes
1164 fi
1165
1166 ENABLE_LIBASYNCNS=no
1167 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
1168    ENABLE_LIBASYNCNS=yes
1169 fi
1170
1171 ENABLE_LIRC=no
1172 if test "x$HAVE_LIRC" = "x1" ; then
1173    ENABLE_LIRC=yes
1174 fi
1175
1176 ENABLE_HAL=no
1177 if test "x$HAVE_HAL" = "x1" ; then
1178    ENABLE_HAL=yes
1179 fi
1180
1181 ENABLE_TCPWRAP=no
1182 if test "x${LIBWRAP_LIBS}" != x ; then
1183    ENABLE_TCPWRAP=yes
1184 fi
1185
1186 ENABLE_LIBSAMPLERATE=no
1187 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
1188    ENABLE_LIBSAMPLERATE=yes
1189 fi
1190
1191 ENABLE_BLUEZ=no
1192 if test "x${HAVE_BLUEZ}" = "x1" ; then
1193    ENABLE_BLUEZ=yes
1194 fi
1195
1196 ENABLE_POLKIT=no
1197 if test "x${HAVE_POLKIT}" = "x1" ; then
1198    ENABLE_POLKIT=yes
1199 fi
1200
1201 ENABLE_PER_USER_ESOUND_SOCKET=no
1202 if test "x$per_user_esound_socket" = "x1" ; then
1203    ENABLE_PER_USER_ESOUND_SOCKET=yes
1204 fi
1205
1206 echo "
1207  ---{ $PACKAGE_NAME $VERSION }---
1208
1209     prefix:                        ${prefix}
1210     sysconfdir:                    ${sysconfdir}
1211     localstatedir:                 ${localstatedir}
1212     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1213     System State Path:             ${PA_SYSTEM_STATE_PATH}
1214     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1215     Compiler:                      ${CC}
1216     CFLAGS:                        ${CFLAGS}
1217     Have X11:                      ${ENABLE_X11}
1218     Enable OSS:                    ${ENABLE_OSS}
1219     Enable Alsa:                   ${ENABLE_ALSA}
1220     Enable Solaris:                ${ENABLE_SOLARIS}
1221     Enable GLib 2.0:               ${ENABLE_GLIB20}
1222     Enable GConf:                  ${ENABLE_GCONF}
1223     Enable Avahi:                  ${ENABLE_AVAHI}
1224     Enable Jack:                   ${ENABLE_JACK}
1225     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1226     Enable LIRC:                   ${ENABLE_LIRC}
1227     Enable HAL:                    ${ENABLE_HAL}
1228     Enable BlueZ:                  ${ENABLE_BLUEZ}
1229     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1230     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1231     Enable PolicyKit:              ${ENABLE_POLKIT}
1232     System User:                   ${PA_SYSTEM_USER}
1233     System Group:                  ${PA_SYSTEM_GROUP}
1234     Realtime Group:                ${PA_REALTIME_GROUP}
1235     Access Group:                  ${PA_ACCESS_GROUP}
1236     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1237 "