configure.ac

   1 AC_INIT([btrfs-progs],
   2         m4_esyscmd([./version.sh --configure]),
   3         [linux-btrfs@vger.kernel.org],,
   4         [http://btrfs.wiki.kernel.org])
   5
   6 dnl library version
   7 LIBBTRFS_MAJOR=0
   8 LIBBTRFS_MINOR=1
   9 LIBBTRFS_PATCHLEVEL=1
  10
  11 AC_PREREQ([2.60])
  12
  13 AC_CONFIG_AUX_DIR([config])
  14 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  15 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  16 AC_USE_SYSTEM_EXTENSIONS
  17
  18 AC_CONFIG_SRCDIR([btrfs.c])
  19 AC_PREFIX_DEFAULT([/usr])
  20
  21 AC_PROG_CC
  22 AC_CANONICAL_HOST
  23 AC_C_CONST
  24 AC_C_VOLATILE
  25 AC_C_BIGENDIAN
  26
  27 AC_SYS_LARGEFILE
  28
  29 AC_PROG_INSTALL
  30
  31 AC_CHECK_FUNCS([openat], [],
  32         [AC_MSG_ERROR([cannot find openat() function])])
  33
  34 m4_ifndef([PKG_PROG_PKG_CONFIG],
  35   [m4_fatal([Could not locate the pkg-config autoconf
  36     macros. These are usually located in /usr/share/aclocal/pkg.m4.
  37     If your macros are in a different location, try setting the
  38     environment variable AL_OPTS="-I/other/macro/dir" before running
  39     ./autogen.sh or autoreconf again.])])
  40 PKG_PROG_PKG_CONFIG
  41
  42
  43 dnl
  44 dnl Calls pkg-config --static
  45 dnl
  46 AC_DEFUN([PKG_STATIC], [
  47   if AC_RUN_LOG([pkg-config --exists --print-errors "$2"]); then
  48     $1=`pkg-config --libs --static "$2"`
  49     AC_SUBST([$1])
  50   else
  51     AC_MSG_ERROR([pkg-config description of $2, needed for static build, is not available])
  52   fi
  53 ])
  54
  55 dnl Define <NAME>_LIBS= and <NAME>_CFLAGS= by pkg-config
  56 dnl
  57 dnl The default PKG_CHECK_MODULES() action-if-not-found is end the
  58 dnl execution with error. The static libs are optional.
  59
  60 PKG_CHECK_MODULES(BLKID, [blkid])
  61 PKG_STATIC(BLKID_LIBS_STATIC, [blkid])
  62
  63 PKG_CHECK_MODULES(UUID, [uuid])
  64 PKG_STATIC(UUID_LIBS_STATIC, [uuid])
  65
  66 PKG_CHECK_MODULES(ZLIB, [zlib])
  67 PKG_STATIC(ZLIB_LIBS_STATIC, [zlib])
  68
  69 dnl lzo library does not provide pkg-config, let use classic way
  70 AC_CHECK_LIB([lzo2], [lzo_version], [
  71         LZO2_LIBS="-llzo2"
  72         LZO2_CFLAGS=""
  73         LZO2_LIBS_STATIC="-llzo2"],[
  74         AC_MSG_ERROR([cannot find lzo2 library])
  75 ])
  76 AC_SUBST([LZO2_LIBS])
  77 AC_SUBST([LZO2_LIBS_STATIC])
  78 AC_SUBST([LZO2_CFLAGS])
  79
  80
  81 dnl library stuff
  82 AC_SUBST([LIBBTRFS_MAJOR])
  83 AC_SUBST([LIBBTRFS_MINOR])
  84 AC_SUBST([LIBBTRFS_PATCHLEVEL])
  85
  86 AC_CONFIG_HEADERS([config.h])
  87
  88 AC_CONFIG_FILES([
  89 Makefile
  90 version.h
  91 ])
  92
  93 AC_OUTPUT
  94
  95 AC_MSG_RESULT([
  96         ${PACKAGE_NAME} ${PACKAGE_VERSION}
  97
  98         prefix:            ${prefix}
  99         exec prefix:       ${exec_prefix}
 100
 101         bindir:            ${bindir}
 102         libdir:            ${libdir}
 103         includedir:        ${includedir}
 104
 105         compiler:          ${CC}
 106         cflags:            ${CFLAGS}
 107         ldflags:           ${LDFLAGS}
 108
 109         Type 'make' to compile.
 110 ])
 111