configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  30 USER_CFLAGS="$CFLAGS"
  31 USER_CXXFLAGS="$CXXFLAGS"
  32
  33 dnl Versions for external dependencies
  34 LIBDRM_REQUIRED=2.4.24
  35 LIBDRM_RADEON_REQUIRED=2.4.31
  36 LIBDRM_INTEL_REQUIRED=2.4.37
  37 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  38 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  39 DRI2PROTO_REQUIRED=2.6
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBDRM_XORG_REQUIRED=2.4.24
  42 LIBKMS_XORG_REQUIRED=1.0.0
  43
  44 dnl Check for progs
  45 AC_PROG_CPP
  46 AC_PROG_CC
  47 AC_PROG_CXX
  48 AM_PROG_CC_C_O
  49 AM_PROG_AS
  50 AC_CHECK_PROGS([MAKE], [gmake make])
  51 AC_CHECK_PROGS([PYTHON2], [python2 python])
  52 AC_PROG_SED
  53 AC_PROG_MKDIR_P
  54 AC_PATH_PROG([MKDEP], [makedepend])
  55
  56 if test "x$MKDEP" = "x"; then
  57     AC_MSG_ERROR([makedepend is required to build Mesa])
  58 fi
  59
  60 AC_PROG_YACC
  61 AC_PATH_PROG([YACC_INST], $YACC)
  62 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  63     if test -z "$YACC_INST"; then
  64         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  65     fi
  66 fi
  67 AC_PROG_LEX
  68
  69 AC_PATH_PROG([PERL], [perl])
  70
  71 AC_CHECK_PROG(INDENT, indent, indent, cat)
  72 if test "x$INDENT" != "xcat"; then
  73     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  74 fi
  75
  76 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  77 dnl configuration in that case.
  78 AC_PROG_INSTALL
  79 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  80
  81 dnl We need a POSIX shell for parts of the build. Assume we have one
  82 dnl in most cases.
  83 case "$host_os" in
  84 solaris*)
  85     # Solaris /bin/sh is too old/non-POSIX compliant
  86     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  87     SHELL="$POSIX_SHELL"
  88     ;;
  89 esac
  90
  91 dnl clang is mostly GCC-compatible, but its version is much lower,
  92 dnl so we have to check for it.
  93 AC_MSG_CHECKING([if compiling with clang])
  94
  95 AC_COMPILE_IFELSE(
  96 [AC_LANG_PROGRAM([], [[
  97 #ifndef __clang__
  98        not clang
  99 #endif
 100 ]])],
 101 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 102
 103 AC_MSG_RESULT([$acv_mesa_CLANG])
 104
 105 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 106 dnl versions are explictly not supported.
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124 fi
 125
 126
 127 MKDEP_OPTIONS=-fdepend
 128 dnl Ask gcc where it's keeping its secret headers
 129 if test "x$GCC" = xyes; then
 130     for dir in include include-fixed; do
 131         GCC_INCLUDES=`$CC -print-file-name=$dir`
 132         if test "x$GCC_INCLUDES" != x && \
 133            test "$GCC_INCLUDES" != "$dir" && \
 134            test -d "$GCC_INCLUDES"; then
 135             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 136         fi
 137     done
 138 fi
 139 AC_SUBST([MKDEP_OPTIONS])
 140
 141 dnl Make sure the pkg-config macros are defined
 142 m4_ifndef([PKG_PROG_PKG_CONFIG],
 143     [m4_fatal([Could not locate the pkg-config autoconf macros.
 144   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 145   are in a different location, try setting the environment variable
 146   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 147 PKG_PROG_PKG_CONFIG()
 148
 149 dnl LIB_DIR - library basename
 150 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 151 AC_SUBST([LIB_DIR])
 152
 153 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 154 _SAVE_LDFLAGS="$LDFLAGS"
 155 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 156 AC_SUBST([EXTRA_LIB_PATH])
 157
 158 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 159 _SAVE_CPPFLAGS="$CPPFLAGS"
 160 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 161 AC_SUBST([X11_INCLUDES])
 162
 163 dnl Compiler macros
 164 DEFINES=""
 165 AC_SUBST([DEFINES])
 166 case "$host_os" in
 167 linux*|*-gnu*|gnu*)
 168     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 169     ;;
 170 solaris*)
 171     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 172     ;;
 173 cygwin*)
 174     DEFINES="$DEFINES -DPTHREADS"
 175     ;;
 176 esac
 177
 178 dnl Add flags for gcc and g++
 179 if test "x$GCC" = xyes; then
 180     CFLAGS="$CFLAGS -Wall -std=c99"
 181
 182     # Enable -Werror=implicit-function-declaration and
 183     # -Werror=missing-prototypes, if available, or otherwise, just
 184     # -Wmissing-prototypes.  This is particularly useful to avoid
 185     # generating a loadable driver module that has undefined symbols.
 186     save_CFLAGS="$CFLAGS"
 187     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 188     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 189     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 190     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 191                    AC_MSG_RESULT([yes]),
 192                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 193                     AC_MSG_RESULT([no])]);
 194
 195     # Enable -fvisibility=hidden if using a gcc that supports it
 196     save_CFLAGS="$CFLAGS"
 197     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 198     VISIBILITY_CFLAGS="-fvisibility=hidden"
 199     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 200     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 201                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 202
 203     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 204     CFLAGS=$save_CFLAGS
 205
 206     # Work around aliasing bugs - developers should comment this out
 207     CFLAGS="$CFLAGS -fno-strict-aliasing"
 208
 209     # gcc's builtin memcmp is slower than glibc's
 210     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 211     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 212 fi
 213 if test "x$GXX" = xyes; then
 214     CXXFLAGS="$CXXFLAGS -Wall"
 215
 216     # Enable -fvisibility=hidden if using a gcc that supports it
 217     save_CXXFLAGS="$CXXFLAGS"
 218     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 219     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 220     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 221     AC_LANG_PUSH([C++])
 222     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 223                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 224     AC_LANG_POP([C++])
 225
 226     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 227     CXXFLAGS=$save_CXXFLAGS
 228
 229     # Work around aliasing bugs - developers should comment this out
 230     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 231
 232     # gcc's builtin memcmp is slower than glibc's
 233     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 234     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 235 fi
 236
 237 dnl even if the compiler appears to support it, using visibility attributes isn't
 238 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 239 case "$host_os" in
 240 cygwin*)
 241     VISIBILITY_CFLAGS=""
 242     VISIBILITY_CXXFLAGS=""
 243     ;;
 244 esac
 245
 246 AC_SUBST([VISIBILITY_CFLAGS])
 247 AC_SUBST([VISIBILITY_CXXFLAGS])
 248
 249 dnl These should be unnecessary, but let the user set them if they want
 250 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 251     Default is to use CFLAGS.])
 252 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 253     compiler. Default is to use CFLAGS.])
 254 AC_SUBST([OPT_FLAGS])
 255 AC_SUBST([ARCH_FLAGS])
 256
 257 dnl
 258 dnl Hacks to enable 32 or 64 bit build
 259 dnl
 260 AC_ARG_ENABLE([32-bit],
 261     [AS_HELP_STRING([--enable-32-bit],
 262         [build 32-bit libraries @<:@default=auto@:>@])],
 263     [enable_32bit="$enableval"],
 264     [enable_32bit=auto]
 265 )
 266 if test "x$enable_32bit" = xyes; then
 267     if test "x$GCC" = xyes; then
 268         CFLAGS="$CFLAGS -m32"
 269         ARCH_FLAGS="$ARCH_FLAGS -m32"
 270         CCASFLAGS="$CCASFLAGS -m32"
 271     fi
 272     if test "x$GXX" = xyes; then
 273         CXXFLAGS="$CXXFLAGS -m32"
 274     fi
 275 fi
 276 AC_ARG_ENABLE([64-bit],
 277     [AS_HELP_STRING([--enable-64-bit],
 278         [build 64-bit libraries @<:@default=auto@:>@])],
 279     [enable_64bit="$enableval"],
 280     [enable_64bit=auto]
 281 )
 282 if test "x$enable_64bit" = xyes; then
 283     if test "x$GCC" = xyes; then
 284         CFLAGS="$CFLAGS -m64"
 285     fi
 286     if test "x$GXX" = xyes; then
 287         CXXFLAGS="$CXXFLAGS -m64"
 288     fi
 289 fi
 290
 291 dnl Can't have static and shared libraries, default to static if user
 292 dnl explicitly requested. If both disabled, set to static since shared
 293 dnl was explicitly requested.
 294 case "x$enable_static$enable_shared" in
 295 xyesyes )
 296     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 297     enable_shared=no
 298     ;;
 299 xnono )
 300     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 301     enable_static=yes
 302     ;;
 303 esac
 304
 305 dnl
 306 dnl mklib options
 307 dnl
 308 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 309 if test "$enable_static" = yes; then
 310     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 311 fi
 312 AC_SUBST([MKLIB_OPTIONS])
 313
 314 dnl
 315 dnl other compiler options
 316 dnl
 317 AC_ARG_ENABLE([debug],
 318     [AS_HELP_STRING([--enable-debug],
 319         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 320     [enable_debug="$enableval"],
 321     [enable_debug=no]
 322 )
 323 if test "x$enable_debug" = xyes; then
 324     DEFINES="$DEFINES -DDEBUG"
 325     if test "x$GCC" = xyes; then
 326         CFLAGS="$CFLAGS -g"
 327     fi
 328     if test "x$GXX" = xyes; then
 329         CXXFLAGS="$CXXFLAGS -g"
 330     fi
 331 fi
 332
 333 dnl
 334 dnl library names
 335 dnl
 336 LIB_PREFIX_GLOB='lib'
 337 LIB_VERSION_SEPARATOR='.'
 338 if test "$enable_static" = yes; then
 339     LIB_EXTENSION='a'
 340 else
 341     case "$host_os" in
 342     darwin* )
 343         LIB_EXTENSION='dylib' ;;
 344     cygwin* )
 345         dnl prefix can be 'cyg' or 'lib'
 346         LIB_PREFIX_GLOB='???'
 347         LIB_VERSION_SEPARATOR='-'
 348         LIB_EXTENSION='dll' ;;
 349     aix* )
 350         LIB_EXTENSION='a' ;;
 351     * )
 352         LIB_EXTENSION='so' ;;
 353     esac
 354 fi
 355 AC_ARG_WITH([gl-lib-name],
 356   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 357     [specify GL library name @<:@default=GL@:>@])],
 358   [GL_LIB=$withval],
 359   [GL_LIB=GL])
 360 AC_ARG_WITH([glu-lib-name],
 361   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 362     [specify GLU library name @<:@default=GLU@:>@])],
 363   [GLU_LIB=$withval],
 364   [GLU_LIB=GLU])
 365 AC_ARG_WITH([osmesa-lib-name],
 366   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 367     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 368   [OSMESA_LIB=$withval],
 369   [OSMESA_LIB=OSMesa])
 370 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 371 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 372 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 373
 374 dnl
 375 dnl Mangled Mesa support
 376 dnl
 377 AC_ARG_ENABLE([mangling],
 378   [AS_HELP_STRING([--enable-mangling],
 379     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 380   [enable_mangling="${enableval}"],
 381   [enable_mangling=no]
 382 )
 383 if test "x${enable_mangling}" = "xyes" ; then
 384   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 385   GL_LIB="Mangled${GL_LIB}"
 386   GLU_LIB="Mangled${GLU_LIB}"
 387   OSMESA_LIB="Mangled${OSMESA_LIB}"
 388 fi
 389 AC_SUBST([GL_LIB])
 390 AC_SUBST([GLU_LIB])
 391 AC_SUBST([OSMESA_LIB])
 392 AM_CONDITIONAL(HAVE_MANGLED_GL, test "x${enable_mangling}" = "xyes")
 393
 394 dnl
 395 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 396 dnl
 397 AC_ARG_ENABLE([texture-float],
 398     [AS_HELP_STRING([--enable-texture-float],
 399         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 400     [enable_texture_float="$enableval"],
 401     [enable_texture_float=no]
 402 )
 403 if test "x$enable_texture_float" = xyes; then
 404     AC_MSG_WARN([Floating-point textures enabled.])
 405     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 406     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 407 fi
 408
 409 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 410 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 411 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 412 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 413 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 414 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 415 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 416 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 417
 418 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 419 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 420 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 421 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 422 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 423 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 424 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 425 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 426 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 427
 428 AC_SUBST([GL_LIB_NAME])
 429 AC_SUBST([GLU_LIB_NAME])
 430 AC_SUBST([OSMESA_LIB_NAME])
 431 AC_SUBST([EGL_LIB_NAME])
 432 AC_SUBST([GLESv1_CM_LIB_NAME])
 433 AC_SUBST([GLESv2_LIB_NAME])
 434 AC_SUBST([VG_LIB_NAME])
 435 AC_SUBST([GLAPI_LIB_NAME])
 436
 437 AC_SUBST([GL_LIB_GLOB])
 438 AC_SUBST([GLU_LIB_GLOB])
 439 AC_SUBST([OSMESA_LIB_GLOB])
 440 AC_SUBST([EGL_LIB_GLOB])
 441 AC_SUBST([GLESv1_CM_LIB_GLOB])
 442 AC_SUBST([GLESv2_LIB_GLOB])
 443 AC_SUBST([VG_LIB_GLOB])
 444 AC_SUBST([GLAPI_LIB_GLOB])
 445
 446 dnl
 447 dnl Arch/platform-specific settings
 448 dnl
 449 AC_ARG_ENABLE([asm],
 450     [AS_HELP_STRING([--disable-asm],
 451         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 452     [enable_asm="$enableval"],
 453     [enable_asm=yes]
 454 )
 455 asm_arch=""
 456 MESA_ASM_FILES=""
 457 AC_MSG_CHECKING([whether to enable assembly])
 458 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 459 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 460 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 461     case "$host_cpu" in
 462     i?86 | x86_64)
 463         enable_asm=no
 464         AC_MSG_RESULT([no, cross compiling])
 465         ;;
 466     esac
 467 fi
 468 # check for supported arches
 469 if test "x$enable_asm" = xyes; then
 470     case "$host_cpu" in
 471     i?86)
 472         case "$host_os" in
 473         linux* | *freebsd* | dragonfly* | *netbsd*)
 474             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 475             ;;
 476         esac
 477         ;;
 478     x86_64)
 479         case "$host_os" in
 480         linux* | *freebsd* | dragonfly* | *netbsd*)
 481             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 482             ;;
 483         esac
 484         ;;
 485     powerpc)
 486         case "$host_os" in
 487         linux*)
 488             asm_arch=ppc
 489             ;;
 490         esac
 491         ;;
 492     sparc*)
 493         case "$host_os" in
 494         linux*)
 495             asm_arch=sparc
 496             ;;
 497         esac
 498         ;;
 499     esac
 500
 501     case "$asm_arch" in
 502     x86)
 503         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 504         MESA_ASM_FILES='$(X86_FILES)'
 505         AC_MSG_RESULT([yes, x86])
 506         ;;
 507     x86_64)
 508         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 509         MESA_ASM_FILES='$(X86_64_FILES)'
 510         AC_MSG_RESULT([yes, x86_64])
 511         ;;
 512     sparc)
 513         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 514         MESA_ASM_FILES='$(SPARC_FILES)'
 515         AC_MSG_RESULT([yes, sparc])
 516         ;;
 517     *)
 518         AC_MSG_RESULT([no, platform not supported])
 519         ;;
 520     esac
 521 fi
 522 AC_SUBST([MESA_ASM_FILES])
 523
 524 dnl PIC code macro
 525 MESA_PIC_FLAGS
 526
 527 dnl Check to see if dlopen is in default libraries (like Solaris, which
 528 dnl has it in libc), or if libdl is needed to get it.
 529 AC_CHECK_FUNC([dlopen], [],
 530     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 531 AC_SUBST([DLOPEN_LIBS])
 532
 533 dnl See if posix_memalign is available
 534 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 535
 536 dnl SELinux awareness.
 537 AC_ARG_ENABLE([selinux],
 538     [AS_HELP_STRING([--enable-selinux],
 539         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 540     [MESA_SELINUX="$enableval"],
 541     [MESA_SELINUX=no])
 542 if test "x$enable_selinux" = "xyes"; then
 543     AC_CHECK_HEADER([selinux/selinux.h],[],
 544                     [AC_MSG_ERROR([SELinux headers not found])])
 545     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 546                  [AC_MSG_ERROR([SELinux library not found])])
 547     SELINUX_LIBS="-lselinux"
 548     DEFINES="$DEFINES -DMESA_SELINUX"
 549 fi
 550
 551 dnl Options for APIs
 552 AC_ARG_ENABLE([opengl],
 553     [AS_HELP_STRING([--disable-opengl],
 554         [disable support for standard OpenGL API @<:@default=no@:>@])],
 555     [enable_opengl="$enableval"],
 556     [enable_opengl=yes])
 557 AC_ARG_ENABLE([gles1],
 558     [AS_HELP_STRING([--enable-gles1],
 559         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 560     [enable_gles1="$enableval"],
 561     [enable_gles1=no])
 562 AC_ARG_ENABLE([gles2],
 563     [AS_HELP_STRING([--enable-gles2],
 564         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 565     [enable_gles2="$enableval"],
 566     [enable_gles2=no])
 567 AC_ARG_ENABLE([openvg],
 568     [AS_HELP_STRING([--enable-openvg],
 569         [enable support for OpenVG API @<:@default=no@:>@])],
 570     [enable_openvg="$enableval"],
 571     [enable_openvg=no])
 572
 573 AC_ARG_ENABLE([dri],
 574     [AS_HELP_STRING([--enable-dri],
 575         [enable DRI modules @<:@default=auto@:>@])],
 576     [enable_dri="$enableval"],
 577     [enable_dri=auto])
 578 AC_ARG_ENABLE([glx],
 579     [AS_HELP_STRING([--enable-glx],
 580         [enable GLX library @<:@default=auto@:>@])],
 581     [enable_glx="$enableval"],
 582     [enable_glx=auto])
 583 AC_ARG_ENABLE([osmesa],
 584     [AS_HELP_STRING([--enable-osmesa],
 585         [enable OSMesa library @<:@default=auto@:>@])],
 586     [enable_osmesa="$enableval"],
 587     [enable_osmesa=auto])
 588 AC_ARG_ENABLE([egl],
 589     [AS_HELP_STRING([--disable-egl],
 590         [disable EGL library @<:@default=enabled@:>@])],
 591     [enable_egl="$enableval"],
 592     [enable_egl=yes])
 593
 594 AC_ARG_ENABLE([xorg],
 595     [AS_HELP_STRING([--enable-xorg],
 596         [enable support for X.Org DDX API @<:@default=no@:>@])],
 597     [enable_xorg="$enableval"],
 598     [enable_xorg=no])
 599 AC_ARG_ENABLE([xa],
 600     [AS_HELP_STRING([--enable-xa],
 601         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 602     [enable_xa="$enableval"],
 603     [enable_xa=no])
 604 AC_ARG_ENABLE([d3d1x],
 605     [AS_HELP_STRING([--enable-d3d1x],
 606         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 607     [enable_d3d1x="$enableval"],
 608     [enable_d3d1x=no])
 609 AC_ARG_ENABLE([gbm],
 610    [AS_HELP_STRING([--enable-gbm],
 611          [enable gbm library @<:@default=auto@:>@])],
 612    [enable_gbm="$enableval"],
 613    [enable_gbm=auto])
 614
 615 AC_ARG_ENABLE([xvmc],
 616    [AS_HELP_STRING([--enable-xvmc],
 617          [enable xvmc library @<:@default=auto@:>@])],
 618    [enable_xvmc="$enableval"],
 619    [enable_xvmc=auto])
 620 AC_ARG_ENABLE([vdpau],
 621    [AS_HELP_STRING([--enable-vdpau],
 622          [enable vdpau library @<:@default=auto@:>@])],
 623    [enable_vdpau="$enableval"],
 624    [enable_vdpau=auto])
 625 AC_ARG_ENABLE([va],
 626    [AS_HELP_STRING([--enable-va],
 627          [enable va library @<:@default=auto@:>@])],
 628    [enable_va="$enableval"],
 629    [enable_va=auto])
 630 AC_ARG_ENABLE([opencl],
 631    [AS_HELP_STRING([--enable-opencl],
 632          [enable OpenCL library @<:@default=no@:>@])],
 633    [enable_opencl="$enableval"],
 634    [enable_opencl=no])
 635 AC_ARG_ENABLE([xlib_glx],
 636     [AS_HELP_STRING([--enable-xlib-glx],
 637         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 638     [enable_xlib_glx="$enableval"],
 639     [enable_xlib_glx=auto])
 640 AC_ARG_ENABLE([gallium_egl],
 641     [AS_HELP_STRING([--enable-gallium-egl],
 642         [enable optional EGL state tracker (not required
 643          for EGL support in Gallium with OpenGL and OpenGL ES)
 644          @<:@default=disable@:>@])],
 645     [enable_gallium_egl="$enableval"],
 646     [enable_gallium_egl=no])
 647 AC_ARG_ENABLE([gallium_gbm],
 648     [AS_HELP_STRING([--enable-gallium-gbm],
 649         [enable optional gbm state tracker (not required for
 650          gbm support in Gallium)
 651          @<:@default=auto@:>@])],
 652     [enable_gallium_gbm="$enableval"],
 653     [enable_gallium_gbm=auto])
 654
 655 AC_ARG_ENABLE([r600-llvm-compiler],
 656     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 657         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 658     [enable_r600_llvm="$enableval"],
 659     [enable_r600_llvm=no])
 660
 661 AC_ARG_ENABLE([gallium_tests],
 662     [AS_HELP_STRING([--enable-gallium-tests],
 663         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 664     [enable_gallium_tests="$enableval"],
 665     [enable_gallium_tests=no])
 666
 667 # Option for Gallium drivers
 668 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 669
 670 AC_ARG_WITH([gallium-drivers],
 671     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 672         [comma delimited Gallium drivers list, e.g.
 673         "i915,nouveau,r300,r600,svga,swrast"
 674         @<:@default=r300,r600,swrast@:>@])],
 675     [with_gallium_drivers="$withval"],
 676     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 677
 678 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 679 # here so that the script doesn't choke on an unknown driver name later.
 680 case "$with_gallium_drivers" in
 681     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 682     no) with_gallium_drivers='' ;;
 683 esac
 684
 685 if test "x$enable_opengl" = xno -a \
 686         "x$enable_gles1" = xno -a \
 687         "x$enable_gles2" = xno -a \
 688         "x$enable_openvg" = xno -a \
 689         "x$enable_xorg" = xno -a \
 690         "x$enable_xa" = xno -a \
 691         "x$enable_d3d1x" = xno -a \
 692         "x$enable_xvmc" = xno -a \
 693         "x$enable_vdpau" = xno -a \
 694         "x$enable_va" = xno -a \
 695         "x$enable_opencl" = xno; then
 696     AC_MSG_ERROR([at least one API should be enabled])
 697 fi
 698
 699 API_DEFINES=""
 700 if test "x$enable_opengl" = xno; then
 701     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 702 else
 703     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 704 fi
 705 if test "x$enable_gles1" = xyes; then
 706     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 707 fi
 708 if test "x$enable_gles2" = xyes; then
 709     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 710 fi
 711 AC_SUBST([API_DEFINES])
 712
 713 AC_ARG_ENABLE([shared-glapi],
 714     [AS_HELP_STRING([--enable-shared-glapi],
 715         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 716     [enable_shared_glapi="$enableval"],
 717     [enable_shared_glapi=no])
 718
 719 SHARED_GLAPI="0"
 720 if test "x$enable_shared_glapi" = xyes; then
 721     SHARED_GLAPI="1"
 722     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 723     # the remap table)
 724     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 725     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 726 fi
 727 AC_SUBST([SHARED_GLAPI])
 728 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 729
 730 dnl
 731 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 732 dnl More later: fbdev, ...
 733 dnl
 734 default_driver="xlib"
 735
 736 case "$host_os" in
 737 linux*)
 738     case "$host_cpu" in
 739     i*86|x86_64|powerpc*|sparc*|ia64*) default_driver="dri";;
 740     esac
 741     ;;
 742 *freebsd* | dragonfly* | *netbsd*)
 743     case "$host_cpu" in
 744     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 745     esac
 746     ;;
 747 esac
 748
 749 if test "x$enable_opengl" = xno; then
 750     default_driver="no"
 751 fi
 752
 753 AC_ARG_WITH([driver],
 754     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 755     [mesa_driver="$withval"],
 756     [mesa_driver=auto])
 757 dnl Check for valid option
 758 case "x$mesa_driver" in
 759 xxlib|xdri|xosmesa|xno)
 760     if test "x$enable_dri" != xauto -o \
 761             "x$enable_glx" != xauto -o \
 762             "x$enable_osmesa" != xauto -o \
 763             "x$enable_xlib_glx" != xauto; then
 764         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 765     fi
 766     ;;
 767 xauto)
 768     mesa_driver="$default_driver"
 769     ;;
 770 *)
 771     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 772     ;;
 773 esac
 774
 775 # map $mesa_driver to APIs
 776 if test "x$enable_dri" = xauto; then
 777     case "x$mesa_driver" in
 778     xdri) enable_dri=yes ;;
 779     *)    enable_dri=no ;;
 780     esac
 781 fi
 782
 783 if test "x$enable_glx" = xauto; then
 784     case "x$mesa_driver" in
 785     xdri|xxlib) enable_glx=yes ;;
 786     *)          enable_glx=no ;;
 787     esac
 788 fi
 789
 790 if test "x$enable_osmesa" = xauto; then
 791     case "x$mesa_driver" in
 792     xxlib|xosmesa) enable_osmesa=yes ;;
 793     *)             enable_osmesa=no ;;
 794     esac
 795 fi
 796
 797 if test "x$enable_xlib_glx" = xauto; then
 798     case "x$mesa_driver" in
 799     xxlib) enable_xlib_glx=yes ;;
 800     *)     enable_xlib_glx=no ;;
 801     esac
 802 fi
 803
 804 if test "x$enable_glx" = xno; then
 805     enable_xlib_glx=no
 806 fi
 807
 808 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 809
 810 dnl
 811 dnl Driver specific build directories
 812 dnl
 813
 814 dnl this variable will be prepended to SRC_DIRS and is not exported
 815 CORE_DIRS=""
 816
 817 SRC_DIRS="gtest"
 818 GLU_DIRS="sgi"
 819 GALLIUM_DIRS="auxiliary drivers state_trackers"
 820 GALLIUM_TARGET_DIRS=""
 821 GALLIUM_WINSYS_DIRS="sw"
 822 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 823 GALLIUM_STATE_TRACKERS_DIRS=""
 824
 825 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 826 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 827 x*yes*)
 828     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 829     ;;
 830 esac
 831
 832 # build glapi if OpenGL is enabled
 833 if test "x$enable_opengl" = xyes; then
 834     CORE_DIRS="$CORE_DIRS mapi/glapi"
 835 fi
 836
 837 # build es1api if OpenGL ES 1.x is enabled
 838 if test "x$enable_gles1" = xyes; then
 839     CORE_DIRS="$CORE_DIRS mapi/es1api"
 840 fi
 841
 842 # build es2api if OpenGL ES 2.x is enabled
 843 if test "x$enable_gles2" = xyes; then
 844     CORE_DIRS="$CORE_DIRS mapi/es2api"
 845 fi
 846
 847 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 848 case "x$enable_opengl$enable_gles1$enable_gles2" in
 849 x*yes*)
 850     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 851     ;;
 852 esac
 853
 854 case "x$enable_glx$enable_xlib_glx" in
 855 xyesyes)
 856     DRIVER_DIRS="$DRIVER_DIRS x11"
 857     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 858     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 859     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 860     HAVE_WINSYS_XLIB="yes"
 861     ;;
 862 xyesno)
 863     # DRI-based GLX
 864     SRC_DIRS="$SRC_DIRS glx"
 865     ;;
 866 esac
 867
 868 if test "x$enable_dri" = xyes; then
 869     DRIVER_DIRS="$DRIVER_DIRS dri"
 870
 871     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 872     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 873     HAVE_ST_DRI="yes"
 874 fi
 875
 876 if test "x$enable_osmesa" = xyes; then
 877     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 878 fi
 879
 880 AC_SUBST([SRC_DIRS])
 881 AC_SUBST([GLU_DIRS])
 882 AC_SUBST([DRIVER_DIRS])
 883 AC_SUBST([GALLIUM_DIRS])
 884 AC_SUBST([GALLIUM_TARGET_DIRS])
 885 AC_SUBST([GALLIUM_WINSYS_DIRS])
 886 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 887 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 888 AC_SUBST([MESA_LLVM])
 889
 890 # Check for libdrm
 891 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 892                   [have_libdrm=yes], [have_libdrm=no])
 893
 894 if test "x$enable_dri" = xyes; then
 895     # DRI must be shared, I think
 896     if test "$enable_static" = yes; then
 897         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 898     fi
 899
 900     # not a hard requirement as swrast does not depend on it
 901     if test "x$have_libdrm" = xyes; then
 902         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 903     fi
 904 fi
 905
 906 dnl
 907 dnl Find out if X is available. The variable have_x is set if libX11 is
 908 dnl found to mimic AC_PATH_XTRA.
 909 dnl
 910 if test -n "$PKG_CONFIG"; then
 911     AC_MSG_CHECKING([pkg-config files for X11 are available])
 912     PKG_CHECK_EXISTS([x11],[
 913         x11_pkgconfig=yes
 914         have_x=yes
 915         ],[
 916         x11_pkgconfig=no
 917     ])
 918     AC_MSG_RESULT([$x11_pkgconfig])
 919 else
 920     x11_pkgconfig=no
 921 fi
 922 dnl Use the autoconf macro if no pkg-config files
 923 if test "$x11_pkgconfig" = yes; then
 924     PKG_CHECK_MODULES([X11], [x11])
 925 else
 926     AC_PATH_XTRA
 927     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 928     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 929     AC_SUBST([X11_CFLAGS])
 930     AC_SUBST([X11_LIBS])
 931 fi
 932
 933 dnl Try to tell the user that the --x-* options are only used when
 934 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 935 m4_divert_once([HELP_BEGIN],
 936 [These options are only used when the X libraries cannot be found by the
 937 pkg-config utility.])
 938
 939 dnl We need X for xlib and dri, so bomb now if it's not found
 940 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 941     AC_MSG_ERROR([X11 development libraries needed for GLX])
 942 fi
 943
 944 if test "x$enable_glx" = xyes; then
 945     DEFINES="$DEFINES -DUSE_XCB"
 946 fi
 947
 948 dnl Direct rendering or just indirect rendering
 949 case "$host_os" in
 950 gnu*)
 951     dnl Disable by default on GNU/Hurd
 952     driglx_direct_default="no"
 953     ;;
 954 cygwin*)
 955     dnl Disable by default on cygwin
 956     driglx_direct_default="no"
 957     ;;
 958 *)
 959     driglx_direct_default="yes"
 960     ;;
 961 esac
 962 AC_ARG_ENABLE([driglx-direct],
 963     [AS_HELP_STRING([--disable-driglx-direct],
 964         [enable direct rendering in GLX and EGL for DRI \
 965             @<:@default=auto@:>@])],
 966     [driglx_direct="$enableval"],
 967     [driglx_direct="$driglx_direct_default"])
 968
 969 dnl
 970 dnl libGL configuration per driver
 971 dnl
 972 case "x$enable_glx$enable_xlib_glx" in
 973 xyesyes)
 974     # Xlib-based GLX
 975     if test "$x11_pkgconfig" = yes; then
 976         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 977         GL_PC_REQ_PRIV="x11 xext"
 978         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 979         GL_LIB_DEPS="$XLIBGL_LIBS"
 980     else
 981         # should check these...
 982         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 983         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 984         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 985         GL_PC_CFLAGS="$X11_INCLUDES"
 986     fi
 987     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 988     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 989     ;;
 990 xyesno)
 991     # DRI-based GLX
 992     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 993     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 994     if test x"$driglx_direct" = xyes; then
 995         if test "x$have_libdrm" != xyes; then
 996             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 997         fi
 998         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 999         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
1000     fi
1001
1002     # find the DRI deps for libGL
1003     if test "$x11_pkgconfig" = yes; then
1004         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
1005
1006         # add xf86vidmode if available
1007         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1008         if test "$HAVE_XF86VIDMODE" = yes ; then
1009             dri_modules="$dri_modules xxf86vm"
1010         fi
1011
1012         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1013         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1014         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1015         GL_LIB_DEPS="$DRIGL_LIBS"
1016     else
1017         # should check these...
1018         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
1019         if test "x$HAVE_XF86VIDMODE" == xyes; then
1020            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
1021         else
1022            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1023         fi
1024         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1025         GL_PC_CFLAGS="$X11_INCLUDES"
1026
1027         # XCB can only be used from pkg-config
1028         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx >= 1.8.1])
1029         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1030         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1031         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1032     fi
1033
1034     # need DRM libs, -lpthread, etc.
1035     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1036     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1037     ;;
1038 esac
1039
1040 # This is outside the case (above) so that it is invoked even for non-GLX
1041 # builds.
1042 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1043
1044 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1045 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1046 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1047 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1048
1049 AC_SUBST([GL_LIB_DEPS])
1050 AC_SUBST([GL_PC_REQ_PRIV])
1051 AC_SUBST([GL_PC_LIB_PRIV])
1052 AC_SUBST([GL_PC_CFLAGS])
1053 AC_SUBST([DRI_PC_REQ_PRIV])
1054 AC_SUBST([GLESv1_CM_LIB_DEPS])
1055 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1056 AC_SUBST([GLESv2_LIB_DEPS])
1057 AC_SUBST([GLESv2_PC_LIB_PRIV])
1058
1059 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1060 AC_SUBST([GLAPI_LIB_DEPS])
1061
1062
1063 dnl dri libraries are linking with mesa
1064 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.la'
1065 GALLIUM_DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1066
1067 dnl ... or dricore?
1068 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1069     DRI_LIB_DEPS="\$(TOP)/src/mesa/libdricore/libdricore${VERSION}.la"
1070     GALLIUM_DRI_LIB_DEPS="\$(TOP)/\$(LIB_DIR)/libdricore${VERSION}.so"
1071     HAVE_DRICORE=yes
1072 fi
1073 AM_CONDITIONAL(HAVE_DRICORE, test x$HAVE_DRICORE = xyes)
1074
1075 AC_SUBST([HAVE_XF86VIDMODE])
1076
1077 dnl
1078 dnl More GLX setup
1079 dnl
1080 case "x$enable_glx$enable_xlib_glx" in
1081 xyesyes)
1082     DEFINES="$DEFINES -DUSE_XSHM"
1083     ;;
1084 xyesno)
1085     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1086     if test "x$driglx_direct" = xyes; then
1087         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1088     fi
1089     ;;
1090 esac
1091
1092 dnl
1093 dnl TLS detection
1094 dnl
1095
1096 AC_ARG_ENABLE([glx-tls],
1097     [AS_HELP_STRING([--enable-glx-tls],
1098         [enable TLS support in GLX @<:@default=disabled@:>@])],
1099     [GLX_USE_TLS="$enableval"],
1100     [GLX_USE_TLS=no])
1101 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1102
1103 AS_IF([test "x$GLX_USE_TLS" = xyes],
1104       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1105
1106 dnl
1107 dnl More DRI setup
1108 dnl
1109 dnl Directory for DRI drivers
1110 AC_ARG_WITH([dri-driverdir],
1111     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1112         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1113     [DRI_DRIVER_INSTALL_DIR="$withval"],
1114     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1115 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1116 dnl Extra search path for DRI drivers
1117 AC_ARG_WITH([dri-searchpath],
1118     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1119         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1120     [DRI_DRIVER_SEARCH_DIR="$withval"],
1121     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1122 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1123 dnl Which drivers to build - default is chosen by platform
1124 AC_ARG_WITH([dri-drivers],
1125     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1126         [comma delimited DRI drivers list, e.g.
1127         "swrast,i965,radeon" @<:@default=auto@:>@])],
1128     [with_dri_drivers="$withval"],
1129     [with_dri_drivers=yes])
1130 if test "x$with_dri_drivers" = x; then
1131     with_dri_drivers=no
1132 fi
1133
1134 dnl If $with_dri_drivers is yes, directories will be added through
1135 dnl platform checks
1136 DRI_DIRS=""
1137 case "$with_dri_drivers" in
1138 no) ;;
1139 yes)
1140     # classic DRI drivers require FEATURE_GL to build
1141     if test "x$enable_opengl" = xyes; then
1142         DRI_DIRS="yes"
1143     fi
1144     ;;
1145 *)
1146     # verify the requested driver directories exist
1147     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1148     for driver in $dri_drivers; do
1149         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1150             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1151     done
1152     DRI_DIRS="$dri_drivers"
1153     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1154         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1155     fi
1156     ;;
1157 esac
1158
1159 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1160 if test "x$enable_dri" = xyes; then
1161     # Platform specific settings and drivers to build
1162     case "$host_os" in
1163     linux*)
1164         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1165         DEFINES="$DEFINES -DHAVE_ALIAS"
1166
1167         case "$host_cpu" in
1168         x86_64)
1169             if test "x$DRI_DIRS" = "xyes"; then
1170                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1171             fi
1172             ;;
1173         powerpc*)
1174             # Build only the drivers for cards that exist on PowerPC.
1175             if test "x$DRI_DIRS" = "xyes"; then
1176                 DRI_DIRS="r200 radeon swrast"
1177             fi
1178             ;;
1179         sparc*)
1180             # Build only the drivers for cards that exist on sparc
1181             if test "x$DRI_DIRS" = "xyes"; then
1182                 DRI_DIRS="r200 radeon swrast"
1183             fi
1184             ;;
1185         esac
1186         ;;
1187     freebsd* | dragonfly* | *netbsd*)
1188         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1189         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1190
1191         if test "x$DRI_DIRS" = "xyes"; then
1192             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1193         fi
1194         ;;
1195     gnu*)
1196         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1197         DEFINES="$DEFINES -DHAVE_ALIAS"
1198         ;;
1199     solaris*)
1200         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1201         ;;
1202     cygwin*)
1203         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1204         if test "x$DRI_DIRS" = "xyes"; then
1205             DRI_DIRS="swrast"
1206         fi
1207         ;;
1208     esac
1209
1210     # default drivers
1211     if test "x$DRI_DIRS" = "xyes"; then
1212         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1213     fi
1214
1215     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1216
1217     # Check for expat
1218     if test "x$enable_dri" = xyes; then
1219         EXPAT_INCLUDES=""
1220         EXPAT_LIB=-lexpat
1221         AC_ARG_WITH([expat],
1222             [AS_HELP_STRING([--with-expat=DIR],
1223                 [expat install directory])],[
1224             EXPAT_INCLUDES="-I$withval/include"
1225             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1226             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1227             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1228             ])
1229         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1230         save_LIBS="$LIBS"
1231         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1232             [AC_MSG_ERROR([Expat required for DRI.])])
1233         LIBS="$save_LIBS"
1234     fi
1235
1236     # if we are building any dri driver other than swrast ...
1237     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1238         # ... libdrm is required
1239         if test "x$have_libdrm" != xyes; then
1240             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1241         fi
1242         # ... and build dricommon
1243         HAVE_COMMON_DRI=yes
1244     fi
1245
1246     # put all the necessary libs together
1247     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1248     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1249 fi
1250 AC_SUBST([DRI_DIRS])
1251 AC_SUBST([EXPAT_INCLUDES])
1252 AC_SUBST([DRI_LIB_DEPS])
1253 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1254
1255 case $DRI_DIRS in
1256 *i915*|*i965*)
1257     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1258
1259     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1260         case $d in
1261         i915)
1262             HAVE_I915_DRI=yes;
1263             ;;
1264         i965)
1265             HAVE_I965_DRI=yes;
1266             ;;
1267         esac
1268     done
1269
1270     ;;
1271 esac
1272
1273 case $DRI_DIRS in
1274 *nouveau*)
1275     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1276     HAVE_NOUVEAU_DRI=yes;
1277     ;;
1278 esac
1279
1280 case $DRI_DIRS in
1281 *radeon*|*r200*)
1282     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1283
1284     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1285         case $d in
1286         radeon)
1287             HAVE_RADEON_DRI=yes;
1288             ;;
1289         r200)
1290             HAVE_R200_DRI=yes;
1291             ;;
1292         esac
1293     done
1294
1295     ;;
1296 esac
1297
1298 case $DRI_DIRS in
1299 *swrast*)
1300     HAVE_SWRAST_DRI=yes;
1301     ;;
1302 esac
1303
1304 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1305 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1306 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1307 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1308 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1309 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1310 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1311
1312 dnl
1313 dnl OSMesa configuration
1314 dnl
1315
1316 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1317 AC_ARG_WITH([osmesa-bits],
1318     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1319         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1320     [osmesa_bits="$withval"],
1321     [osmesa_bits=8])
1322 if test "x$osmesa_bits" != x8; then
1323     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1324         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1325         osmesa_bits=8
1326     fi
1327 fi
1328 case "x$osmesa_bits" in
1329 x8)
1330     OSMESA_LIB="${OSMESA_LIB}"
1331     ;;
1332 x16|x32)
1333     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1334     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1335     ;;
1336 *)
1337     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1338     ;;
1339 esac
1340
1341 if test "x$enable_osmesa" = xyes; then
1342     # only link libraries with osmesa if shared
1343     if test "$enable_static" = no; then
1344         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1345     else
1346         OSMESA_LIB_DEPS=""
1347     fi
1348     OSMESA_MESA_DEPS=""
1349     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1350 fi
1351
1352 OSMESA_VERSION=`echo "$VERSION" | $SED 's/\./:/g'`
1353
1354 AC_SUBST([OSMESA_LIB_DEPS])
1355 AC_SUBST([OSMESA_MESA_DEPS])
1356 AC_SUBST([OSMESA_PC_REQ])
1357 AC_SUBST([OSMESA_PC_LIB_PRIV])
1358 AC_SUBST([OSMESA_VERSION])
1359
1360 dnl
1361 dnl gbm configuration
1362 dnl
1363 if test "x$enable_gbm" = xauto; then
1364     case "$with_egl_platforms" in
1365         *drm*)
1366             enable_gbm=yes ;;
1367          *)
1368             enable_gbm=no ;;
1369     esac
1370 fi
1371 if test "x$enable_gbm" = xyes; then
1372     SRC_DIRS="$SRC_DIRS gbm"
1373
1374     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1375                       AC_MSG_ERROR([gbm needs udev]))
1376
1377     if test "x$enable_dri" = xyes; then
1378         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1379         if test "$SHARED_GLAPI" -eq 0; then
1380             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1381         fi
1382     fi
1383 fi
1384 GBM_PC_REQ_PRIV="libudev"
1385 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1386 AC_SUBST([GBM_PC_REQ_PRIV])
1387 AC_SUBST([GBM_PC_LIB_PRIV])
1388
1389 dnl
1390 dnl EGL configuration
1391 dnl
1392 EGL_CLIENT_APIS=""
1393
1394 if test "x$enable_egl" = xyes; then
1395     SRC_DIRS="$SRC_DIRS egl"
1396     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1397
1398     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1399
1400     if test "$enable_static" != yes; then
1401         # build egl_glx when libGL is built
1402         if test "x$enable_glx" = xyes; then
1403             HAVE_EGL_DRIVER_GLX=1
1404         fi
1405
1406         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1407                           [have_libudev=yes],[have_libudev=no])
1408         if test "$have_libudev" = yes; then
1409             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1410         fi
1411
1412         if test "x$enable_dri" = xyes; then
1413             HAVE_EGL_DRIVER_DRI2=1
1414         fi
1415
1416     fi
1417 fi
1418 AC_SUBST([EGL_LIB_DEPS])
1419
1420 dnl
1421 dnl EGL Gallium configuration
1422 dnl
1423 if test "x$enable_gallium_egl" = xyes; then
1424     if test "x$with_gallium_drivers" = x; then
1425         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1426     fi
1427     if test "x$enable_egl" = xno; then
1428         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1429     fi
1430     if test "x$have_libdrm" != xyes; then
1431         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1432     fi
1433
1434     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1435     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1436     HAVE_ST_EGL="yes"
1437 fi
1438
1439 dnl
1440 dnl gbm Gallium configuration
1441 dnl
1442 if test "x$enable_gallium_gbm" = xauto; then
1443     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1444         yesyesyes*drm*)
1445             enable_gallium_gbm=yes ;;
1446          *)
1447             enable_gallium_gbm=no ;;
1448     esac
1449 fi
1450 if test "x$enable_gallium_gbm" = xyes; then
1451     if test "x$with_gallium_drivers" = x; then
1452         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1453     fi
1454     if test "x$enable_gbm" = xno; then
1455         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1456     fi
1457     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1458     if test "x$enable_dri" = xno; then
1459         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1460     fi
1461
1462     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1463     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1464     HAVE_ST_GBM="yes"
1465     enable_gallium_loader=yes
1466 fi
1467
1468 dnl
1469 dnl X.Org DDX configuration
1470 dnl
1471 if test "x$enable_xorg" = xyes; then
1472     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1473     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1474     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1475     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1476         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1477         HAVE_XEXTPROTO_71="no")
1478     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1479     HAVE_ST_XORG=yes
1480 fi
1481
1482 dnl
1483 dnl XA configuration
1484 dnl
1485 if test "x$enable_xa" = xyes; then
1486 AC_PROG_AWK
1487 AC_PROG_GREP
1488 AC_CHECK_PROG(NM, nm, "nm")
1489 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1490 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1491 enable_xa=no
1492 fi
1493 fi
1494 if test "x$enable_xa" = xyes; then
1495     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1496     HAVE_ST_XA=yes
1497     AC_SUBST(AWK)
1498     AC_SUBST(GREP)
1499     AC_SUBST(NM)
1500 fi
1501
1502 dnl
1503 dnl OpenVG configuration
1504 dnl
1505 VG_LIB_DEPS=""
1506
1507 if test "x$enable_openvg" = xyes; then
1508     if test "x$enable_egl" = xno; then
1509         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1510     fi
1511     if test "x$with_gallium_drivers" = x; then
1512         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1513     fi
1514     if test "x$enable_gallium_egl" = xno; then
1515         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1516     fi
1517
1518     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1519     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1520     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1521     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1522     HAVE_ST_VEGA=yes
1523 fi
1524
1525 dnl
1526 dnl D3D1X configuration
1527 dnl
1528
1529 if test "x$enable_d3d1x" = xyes; then
1530     if test "x$with_gallium_drivers" = x; then
1531         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1532     fi
1533
1534     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1535     HAVE_ST_D3D1X=yes
1536 fi
1537
1538 dnl
1539 dnl Gallium G3DVL configuration
1540 dnl
1541 AC_ARG_ENABLE([gallium-g3dvl],
1542     [AS_HELP_STRING([--enable-gallium-g3dvl],
1543         [build gallium g3dvl @<:@default=disabled@:>@])],
1544     [enable_gallium_g3dvl="$enableval"],
1545     [enable_gallium_g3dvl=no])
1546 if test "x$enable_gallium_g3dvl" = xyes; then
1547     if test "x$with_gallium_drivers" = x; then
1548         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1549     fi
1550
1551     if test "x$enable_xvmc" = xauto; then
1552         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1553     fi
1554
1555     if test "x$enable_vdpau" = xauto; then
1556         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1557     fi
1558
1559     if test "x$enable_va" = xauto; then
1560         #don't enable vaapi state tracker even if package exists
1561         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1562         enable_va=no
1563     fi
1564 fi
1565
1566 if test "x$enable_xvmc" = xyes; then
1567     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1568     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1569     HAVE_ST_XVMC="yes"
1570 fi
1571
1572 if test "x$enable_vdpau" = xyes; then
1573     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1574     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1575     HAVE_ST_VDPAU="yes"
1576 fi
1577
1578 if test "x$enable_va" = xyes; then
1579     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1580     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1581     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1582     HAVE_ST_VA="yes"
1583 fi
1584
1585 dnl
1586 dnl OpenCL configuration
1587 dnl
1588
1589 AC_ARG_WITH([libclc-path],
1590    [AS_HELP_STRING([--with-libclc-path],
1591          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1592    [LIBCLC_PATH="$withval"],
1593    [LIBCLC_PATH=""])
1594
1595 AC_ARG_WITH([clang-libdir],
1596    [AS_HELP_STRING([--with-clang-libdir],
1597          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1598    [CLANG_LIBDIR="$withval"],
1599    [CLANG_LIBDIR=""])
1600
1601 AC_SUBST([LIBCLC_PATH])
1602
1603 if test "x$enable_opencl" = xyes; then
1604     if test "x$with_gallium_drivers" = x; then
1605         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1606     fi
1607
1608     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1609         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1610     fi
1611
1612     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1613     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1614     enable_gallium_loader=yes
1615 fi
1616
1617 dnl
1618 dnl GLU configuration
1619 dnl
1620 AC_ARG_ENABLE([glu],
1621     [AS_HELP_STRING([--disable-glu],
1622         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1623     [enable_glu="$enableval"],
1624     [enable_glu=yes])
1625
1626 if test "x$enable_glu" = xyes; then
1627     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1628         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1629         enable_glu=no
1630     fi
1631 fi
1632
1633 if test "x$enable_glu" = xyes; then
1634     SRC_DIRS="$SRC_DIRS glu"
1635
1636     if test "x$enable_glx" = xno; then
1637         # Link libGLU to libOSMesa instead of libGL
1638         GLU_LIB_DEPS=""
1639         GLU_PC_REQ="osmesa"
1640         if test "$enable_static" = no; then
1641             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1642         else
1643             GLU_MESA_DEPS=""
1644         fi
1645     else
1646         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1647         GLU_PC_REQ="gl"
1648         GLU_PC_LIB_PRIV="-lm"
1649         if test "$enable_static" = no; then
1650             GLU_LIB_DEPS="-lm"
1651             GLU_MESA_DEPS='-l$(GL_LIB)'
1652         else
1653             GLU_LIB_DEPS=""
1654             GLU_MESA_DEPS=""
1655         fi
1656     fi
1657 fi
1658 if test "$enable_static" = no; then
1659     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1660 fi
1661 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1662 AC_SUBST([GLU_LIB_DEPS])
1663 AC_SUBST([GLU_MESA_DEPS])
1664 AC_SUBST([GLU_PC_REQ])
1665 AC_SUBST([GLU_PC_REQ_PRIV])
1666 AC_SUBST([GLU_PC_LIB_PRIV])
1667 AC_SUBST([GLU_PC_CFLAGS])
1668
1669 AC_SUBST([PROGRAM_DIRS])
1670
1671 dnl
1672 dnl Gallium configuration
1673 dnl
1674 if test "x$with_gallium_drivers" != x; then
1675     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1676 fi
1677
1678 AC_SUBST([LLVM_BINDIR])
1679 AC_SUBST([LLVM_CFLAGS])
1680 AC_SUBST([LLVM_CPPFLAGS])
1681 AC_SUBST([LLVM_CXXFLAGS])
1682 AC_SUBST([LLVM_LIBDIR])
1683 AC_SUBST([LLVM_LIBS])
1684 AC_SUBST([LLVM_LDFLAGS])
1685 AC_SUBST([LLVM_INCLUDEDIR])
1686 AC_SUBST([LLVM_VERSION])
1687 AC_SUBST([CLANG_RESOURCE_DIR])
1688
1689 case "x$enable_opengl$enable_gles1$enable_gles2" in
1690 x*yes*)
1691     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1692     ;;
1693 esac
1694
1695 AC_SUBST([VG_LIB_DEPS])
1696 AC_SUBST([EGL_CLIENT_APIS])
1697
1698 dnl
1699 dnl EGL Platforms configuration
1700 dnl
1701 AC_ARG_WITH([egl-platforms],
1702     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1703         [comma delimited native platforms libEGL supports, e.g.
1704         "x11,drm" @<:@default=auto@:>@])],
1705     [with_egl_platforms="$withval"],
1706     [if test "x$enable_egl" = xyes; then
1707         with_egl_platforms="x11"
1708     else
1709         with_egl_platforms=""
1710     fi])
1711
1712 EGL_PLATFORMS=""
1713
1714 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1715     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1716 fi
1717
1718 # Do per-EGL platform setups and checks
1719 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1720 for plat in $egl_platforms; do
1721         case "$plat" in
1722         fbdev|null)
1723                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1724                 ;;
1725
1726         wayland)
1727                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1728                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1729                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1730
1731                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1732                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1733                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1734                 ;;
1735
1736         x11)
1737                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1738                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1739                 save_LIBS="$LIBS"
1740                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1741                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1742                 LIBS="$save_LIBS"
1743                 ;;
1744
1745         drm)
1746                 test "x$enable_gbm" = "xno" &&
1747                         AC_MSG_ERROR([EGL platform drm needs gbm])
1748                 ;;
1749
1750         android|gdi)
1751                 ;;
1752
1753         *)
1754                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1755                 ;;
1756         esac
1757
1758         case "$plat$have_libudev" in
1759                 waylandno|drmno)
1760                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1761         esac
1762 done
1763
1764 # libEGL wants to default to the first platform specified in
1765 # ./configure.  parse that here.
1766 if test "x$egl_platforms" != "x"; then
1767     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1768     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1769 else
1770     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1771 fi
1772
1773 EGL_PLATFORMS="$egl_platforms"
1774
1775 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1776 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1777 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1778 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1779 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1780
1781 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1782 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1783
1784 AC_SUBST([EGL_NATIVE_PLATFORM])
1785 AC_SUBST([EGL_PLATFORMS])
1786 AC_SUBST([EGL_CFLAGS])
1787
1788 AC_ARG_WITH([egl-driver-dir],
1789     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1790                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1791     [EGL_DRIVER_INSTALL_DIR="$withval"],
1792     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1793 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1794
1795 AC_ARG_WITH([xorg-driver-dir],
1796     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1797                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1798     [XORG_DRIVER_INSTALL_DIR="$withval"],
1799     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1800 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1801
1802 AC_ARG_WITH([max-width],
1803     [AS_HELP_STRING([--with-max-width=N],
1804                     [Maximum framebuffer width (4096)])],
1805     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1806      AS_IF([test "${withval}" -gt "4096"],
1807            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1808 )
1809 AC_ARG_WITH([max-height],
1810     [AS_HELP_STRING([--with-max-height=N],
1811                     [Maximum framebuffer height (4096)])],
1812     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1813      AS_IF([test "${withval}" -gt "4096"],
1814            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1815 )
1816
1817 dnl
1818 dnl Gallium LLVM
1819 dnl
1820 AC_ARG_ENABLE([gallium-llvm],
1821     [AS_HELP_STRING([--enable-gallium-llvm],
1822         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1823     [enable_gallium_llvm="$enableval"],
1824     [enable_gallium_llvm=auto])
1825
1826 AC_ARG_WITH([llvm-shared-libs],
1827     [AS_HELP_STRING([--with-llvm-shared-libs],
1828         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1829     [with_llvm_shared_libs=yes],
1830     [with_llvm_shared_libs=no])
1831
1832 AC_ARG_WITH([llvm-prefix],
1833     [AS_HELP_STRING([--with-llvm-prefix],
1834         [Prefix for LLVM installations in non-standard locations])],
1835     [llvm_prefix="$withval"],
1836     [llvm_prefix=""])
1837
1838
1839 if test "x$with_gallium_drivers" = x; then
1840     enable_gallium_llvm=no
1841 fi
1842 if test "x$enable_gallium_llvm" = xauto; then
1843     case "$host_cpu" in
1844     i*86|x86_64) enable_gallium_llvm=yes;;
1845     esac
1846 fi
1847 if test "x$enable_gallium_llvm" = xyes; then
1848     if test "x$llvm_prefix" != x; then
1849         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1850     else
1851         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1852     fi
1853
1854     if test "x$LLVM_CONFIG" != xno; then
1855         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1856         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1857         if test "x$with_llvm_shared_libs" = xyes; then
1858             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1859             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1860         else
1861             LLVM_COMPONENTS="engine bitwriter"
1862             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1863                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1864             fi
1865             if test "x$enable_opencl" = xyes; then
1866                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1867             fi
1868             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1869         fi
1870         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1871         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1872         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1873         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1874         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1875         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1876         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1877         MESA_LLVM=1
1878
1879         dnl Check for Clang interanl headers
1880         if test "x$enable_opencl" = xyes; then
1881             if test "x$CLANG_LIBDIR" = x; then
1882                 CLANG_LIBDIR=${LLVM_LIBDIR}
1883             fi
1884             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1885             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1886                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1887         fi
1888     else
1889         MESA_LLVM=0
1890     fi
1891 else
1892     MESA_LLVM=0
1893 fi
1894
1895 dnl Directory for XVMC libs
1896 AC_ARG_WITH([xvmc-libdir],
1897     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1898         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1899     [XVMC_LIB_INSTALL_DIR="$withval"],
1900     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1901 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1902
1903 dnl
1904 dnl Gallium Tests
1905 dnl
1906 if test "x$enable_gallium_tests" = xyes; then
1907     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1908     enable_gallium_loader=yes
1909 fi
1910
1911 dnl Directory for VDPAU libs
1912 AC_ARG_WITH([vdpau-libdir],
1913     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1914         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1915     [VDPAU_LIB_INSTALL_DIR="$withval"],
1916     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1917 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1918
1919 dnl Directory for VA libs
1920 AC_ARG_WITH([va-libdir],
1921     [AS_HELP_STRING([--with-va-libdir=DIR],
1922         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1923     [VA_LIB_INSTALL_DIR="$withval"],
1924     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1925 AC_SUBST([VA_LIB_INSTALL_DIR])
1926
1927 dnl Directory for OpenCL libs
1928 AC_ARG_WITH([opencl-libdir],
1929     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1930         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1931     [OPENCL_LIB_INSTALL_DIR="$withval"],
1932     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1933 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1934
1935 dnl
1936 dnl Gallium helper functions
1937 dnl
1938 gallium_check_st() {
1939     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1940          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1941          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1942          if test "x$have_libdrm" != xyes; then
1943             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1944          fi
1945          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1946     fi
1947     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1948          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1949     fi
1950     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1951          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1952     fi
1953     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1954          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1955     fi
1956     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1957          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1958     fi
1959     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1960          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1961     fi
1962     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1963          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1964     fi
1965 }
1966
1967 gallium_require_llvm() {
1968     if test "x$MESA_LLVM" = x0; then
1969         case "$host_cpu" in
1970         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1971         esac
1972     fi
1973 }
1974
1975 gallium_require_drm_loader() {
1976     if test "x$enable_gallium_loader" = xyes; then
1977         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1978                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1979         if test "x$have_libdrm" != xyes; then
1980             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1981         fi
1982         enable_gallium_drm_loader=yes
1983     fi
1984 }
1985
1986 dnl Gallium drivers
1987 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1988 if test "x$with_gallium_drivers" != x; then
1989     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1990     for driver in $gallium_drivers; do
1991         case "x$driver" in
1992         xsvga)
1993             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1994             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1995             ;;
1996         xi915)
1997             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1998             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1999             if test "x$MESA_LLVM" = x1; then
2000                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2001             fi
2002             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
2003             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
2004             ;;
2005         xr300)
2006             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2007             gallium_require_llvm "Gallium R300"
2008             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
2009             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
2010             ;;
2011         xr600)
2012             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2013             gallium_require_drm_loader
2014             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
2015             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2016                 if test "x$LLVM_VERSION" != "x3.1"; then
2017                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
2018                 fi
2019                 NEED_RADEON_GALLIUM=yes;
2020             fi
2021             if test "x$enable_r600_llvm" = xyes; then
2022                 USE_R600_LLVM_COMPILER=yes;
2023             fi
2024             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
2025                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
2026             fi
2027             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
2028             ;;
2029         xradeonsi)
2030             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2031             gallium_require_drm_loader
2032             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
2033             if test "x$LLVM_VERSION" != "x3.1"; then
2034                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
2035             fi
2036             NEED_RADEON_GALLIUM=yes;
2037             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi"
2038             ;;
2039         xnouveau)
2040             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2041             gallium_require_drm_loader
2042             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
2043             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
2044             ;;
2045         xswrast)
2046             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
2047             if test "x$MESA_LLVM" = x1; then
2048                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2049             fi
2050
2051             if test "x$HAVE_ST_DRI" = xyes; then
2052                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
2053             fi
2054             if test "x$HAVE_ST_VDPAU" = xyes; then
2055                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
2056             fi
2057             if test "x$HAVE_ST_XVMC" = xyes; then
2058                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
2059             fi
2060             if test "x$HAVE_ST_VA" = xyes; then
2061                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
2062             fi
2063             if test "x$HAVE_ST_VDPAU" = xyes ||
2064                test "x$HAVE_ST_XVMC" = xyes ||
2065                test "x$HAVE_ST_VA" = xyes; then
2066                if test "x$HAVE_WINSYS_XLIB" != xyes; then
2067                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
2068                fi
2069             fi
2070             ;;
2071         *)
2072             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2073             ;;
2074         esac
2075     done
2076 fi
2077
2078 if test "x$enable_gallium_loader" = xyes; then
2079     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2080     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
2081     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
2082     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
2083
2084     if test "x$HAVE_WINSYS_XLIB" = xyes; then
2085         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2086         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
2087     fi
2088
2089     if test "x$enable_gallium_drm_loader" = xyes; then
2090         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2091         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2092                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2093         if test "x$pipe_loader_have_xcb" = xyes; then
2094             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
2095             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2096         fi
2097     fi
2098
2099     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2100     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2101 fi
2102
2103 dnl Tell Automake which drivers to build
2104 for driver in $GALLIUM_DRIVERS_DIRS; do
2105     case "x$driver" in
2106         xgalahad)
2107             HAVE_GALAHAD_GALLIUM=yes;
2108             ;;
2109         xidentity)
2110             HAVE_IDENTITY_GALLIUM=yes;
2111             ;;
2112         xnoop)
2113             HAVE_NOOP_GALLIUM=yes;
2114             ;;
2115         *)
2116             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
2117             ;;
2118     esac
2119 done
2120
2121 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
2122 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2123 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2124 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2125 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2126 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2127 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2128 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2129 AC_SUBST([GALLIUM_MAKE_DIRS])
2130
2131 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2132 AM_CONDITIONAL(HAVE_DRI_DRIVER, echo "$DRIVER_DIRS" | grep 'dri' >/dev/null 2>&1)
2133 AM_CONDITIONAL(HAVE_OSMESA_DRIVER, echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1)
2134
2135 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2136 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2137 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2138
2139 dnl prepend CORE_DIRS to SRC_DIRS
2140 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2141
2142 dnl Restore LDFLAGS and CPPFLAGS
2143 LDFLAGS="$_SAVE_LDFLAGS"
2144 CPPFLAGS="$_SAVE_CPPFLAGS"
2145
2146 dnl Add user CFLAGS and CXXFLAGS
2147 CFLAGS="$CFLAGS $USER_CFLAGS"
2148 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2149
2150 dnl Substitute the config
2151 AC_CONFIG_FILES([configs/current
2152                 Makefile
2153                 src/Makefile
2154                 src/gallium/Makefile
2155                 src/gallium/auxiliary/pipe-loader/Makefile
2156                 src/gallium/state_trackers/clover/Makefile
2157                 src/gallium/drivers/Makefile
2158                 src/gallium/drivers/r300/Makefile
2159                 src/gallium/drivers/r600/Makefile
2160                 src/gallium/targets/opencl/Makefile
2161                 src/gbm/Makefile
2162                 src/gbm/main/gbm.pc
2163                 src/egl/drivers/Makefile
2164                 src/egl/drivers/dri2/Makefile
2165                 src/egl/drivers/glx/Makefile
2166                 src/egl/Makefile
2167                 src/egl/main/Makefile
2168                 src/egl/main/egl.pc
2169                 src/egl/wayland/Makefile
2170                 src/egl/wayland/wayland-egl/Makefile
2171                 src/egl/wayland/wayland-egl/wayland-egl.pc
2172                 src/egl/wayland/wayland-drm/Makefile
2173                 src/glsl/Makefile
2174                 src/glsl/glcpp/Makefile
2175                 src/glsl/tests/Makefile
2176                 src/glx/Makefile
2177                 src/glx/tests/Makefile
2178                 src/mapi/glapi/Makefile
2179                 src/mapi/glapi/gen/Makefile
2180                 src/mapi/shared-glapi/Makefile
2181                 src/mapi/glapi/tests/Makefile
2182                 src/gtest/Makefile
2183                 src/mesa/Makefile
2184                 src/mesa/libdricore/Makefile
2185                 src/mesa/main/tests/Makefile
2186                 src/mesa/x86/Makefile
2187                 src/mesa/x86-64/Makefile
2188                 src/mesa/drivers/Makefile
2189                 src/mesa/drivers/dri/dri.pc
2190                 src/mesa/drivers/dri/Makefile
2191                 src/mesa/drivers/dri/common/Makefile
2192                 src/mesa/drivers/dri/i915/Makefile
2193                 src/mesa/drivers/dri/i965/Makefile
2194                 src/mesa/drivers/dri/nouveau/Makefile
2195                 src/mesa/drivers/dri/r200/Makefile
2196                 src/mesa/drivers/dri/radeon/Makefile
2197                 src/mesa/drivers/dri/swrast/Makefile
2198                 src/mesa/drivers/osmesa/Makefile
2199                 src/mesa/drivers/x11/Makefile
2200                 src/mesa/gl.pc
2201                 src/mesa/osmesa.pc])
2202
2203 dnl Sort the dirs alphabetically
2204 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2205 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2206 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2207 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2208 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2209
2210 AC_OUTPUT
2211
2212 dnl
2213 dnl Output some configuration info for the user
2214 dnl
2215 echo ""
2216 echo "        prefix:          $prefix"
2217 echo "        exec_prefix:     $exec_prefix"
2218 echo "        libdir:          $libdir"
2219 echo "        includedir:      $includedir"
2220
2221 dnl API info
2222 echo ""
2223 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2224 echo "        OpenVG:          $enable_openvg"
2225
2226 dnl Driver info
2227 echo ""
2228 if test "x$enable_osmesa" != xno; then
2229         echo "        OSMesa:          lib$OSMESA_LIB"
2230 else
2231         echo "        OSMesa:          no"
2232 fi
2233
2234 if test "x$enable_dri" != xno; then
2235         # cleanup the drivers var
2236         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2237         if test "x$DRI_DIRS" = x; then
2238             echo "        DRI drivers:     no"
2239         else
2240             echo "        DRI drivers:     $dri_dirs"
2241         fi
2242         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2243 fi
2244
2245 case "x$enable_glx$enable_xlib_glx" in
2246 xyesyes)
2247     echo "        GLX:             Xlib-based"
2248     ;;
2249 xyesno)
2250     echo "        GLX:             DRI-based"
2251     ;;
2252 *)
2253     echo "        GLX:             $enable_glx"
2254     ;;
2255 esac
2256
2257 echo ""
2258 echo "        GLU:             $enable_glu"
2259
2260 dnl EGL
2261 echo ""
2262 echo "        EGL:             $enable_egl"
2263 if test "$enable_egl" = yes; then
2264     echo "        EGL platforms:   $EGL_PLATFORMS"
2265
2266     egl_drivers=""
2267     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2268         egl_drivers="$egl_drivers builtin:egl_glx"
2269     fi
2270     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2271         egl_drivers="$egl_drivers builtin:egl_dri2"
2272     fi
2273
2274     if test "x$HAVE_ST_EGL" = xyes; then
2275         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2276         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2277     else
2278         echo "        EGL drivers:    $egl_drivers"
2279     fi
2280 fi
2281
2282 echo ""
2283 if test "x$MESA_LLVM" = x1; then
2284     echo "        llvm:            yes"
2285     echo "        llvm-config:     $LLVM_CONFIG"
2286     echo "        llvm-version:    $LLVM_VERSION"
2287 else
2288     echo "        llvm:            no"
2289 fi
2290
2291 echo ""
2292 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2293     echo "        Gallium:         yes"
2294     echo "        Gallium dirs:    $GALLIUM_DIRS"
2295     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2296     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2297     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2298     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2299 else
2300     echo "        Gallium:         no"
2301 fi
2302
2303
2304 dnl Libraries
2305 echo ""
2306 echo "        Shared libs:     $enable_shared"
2307 echo "        Static libs:     $enable_static"
2308
2309 dnl Compiler options
2310 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2311 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2312     $SED 's/^ *//;s/  */ /;s/ *$//'`
2313 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2314     $SED 's/^ *//;s/  */ /;s/ *$//'`
2315 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2316 echo ""
2317 echo "        CFLAGS:          $cflags"
2318 echo "        CXXFLAGS:        $cxxflags"
2319 echo "        Macros:          $defines"
2320 echo ""
2321 echo "        PYTHON2:         $PYTHON2"
2322
2323 echo ""
2324 echo "        Run '${MAKE-make}' to build Mesa"
2325 echo ""