configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [5])
   4 m4_define([gst_vaapi_micro_version], [0])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # glib version number
  13 m4_define([glib_major_version], [2])
  14 m4_define([glib_minor_version], [28])
  15 m4_define([glib_micro_version], [0])
  16 m4_define([glib_major_minor_version],
  17           [glib_major_version.glib_minor_version])
  18 m4_define([glib_version],
  19           [glib_major_version.glib_minor_version.glib_micro_version])
  20
  21 # gst version number
  22 m4_define([gst_major_version], [0])
  23 m4_define([gst_minor_version], [10])
  24 m4_define([gst_micro_version], [36])
  25 m4_define([gst_major_minor_version],
  26           [gst_major_version.gst_minor_version])
  27 m4_define([gst_version],
  28           [gst_major_version.gst_minor_version.gst_micro_version])
  29
  30 # gst plugins-base version number
  31 m4_define([gst_plugins_base_major_version], [0])
  32 m4_define([gst_plugins_base_minor_version], [10])
  33 m4_define([gst_plugins_base_micro_version], [31])
  34 m4_define([gst_plugins_base_version],
  35           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  36
  37 # gst plugins-bad version number
  38 m4_define([gst_plugins_bad_major_version], [0])
  39 m4_define([gst_plugins_bad_minor_version], [10])
  40 m4_define([gst_plugins_bad_micro_version], [22])
  41 m4_define([gst_plugins_bad_version],
  42           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
  43
  44 # Wayland minimum version number
  45 m4_define([wayland_api_version], [0.95.0])
  46
  47 # VA-API minimum version number
  48 m4_define([va_api_version],     [0.30.4])
  49 m4_define([va_api_drm_version], [0.33.0])
  50 m4_define([va_api_x11_version], [0.31.0])
  51 m4_define([va_api_glx_version], [0.32.0])
  52 m4_define([va_api_wld_version], [0.33.0])
  53
  54 # libva package version number
  55 m4_define([libva_drm_package_version], [1.1.0])
  56 m4_define([libva_x11_package_version], [1.0.3])
  57 m4_define([libva_glx_package_version], [1.0.9])
  58 m4_define([libva_wld_package_version], [1.1.0])
  59
  60 # gtk-doc version number
  61 # XXX: introspection annotations require gtk-doc >= 1.12
  62 m4_define([gtkdoc_major_version], [1])
  63 m4_define([gtkdoc_minor_version], [9])
  64 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  65
  66 AC_PREREQ([2.58])
  67 AC_INIT([gst_vaapi], [gst_vaapi_version],
  68     [gwenole.beauchesne@intel.com],
  69     [gstreamer-vaapi])
  70
  71 AC_CONFIG_HEADERS([config.h])
  72 AC_CONFIG_SRCDIR([Makefile.am])
  73 AC_CONFIG_MACRO_DIR([m4])
  74 AC_CONFIG_AUX_DIR([build-aux])
  75
  76 AC_CANONICAL_TARGET
  77
  78 AM_INIT_AUTOMAKE
  79
  80 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  81 AC_SUBST(TODAY)
  82
  83 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
  84 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  85
  86 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  87 AC_SUBST(LIBVA_PACKAGE_VERSION)
  88
  89 WAYLAND_API_VERSION=wayland_api_version
  90 AC_SUBST(WAYLAND_API_VERSION)
  91
  92 dnl Versions for GStreamer and plugins-base
  93 GST_MAJORMINOR=gst_major_minor_version
  94 GST_VERSION_REQUIRED=gst_version
  95 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
  96 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
  97 AC_SUBST(GST_MAJORMINOR)
  98 AC_SUBST(GST_VERSION_REQUIRED)
  99 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
 100 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
 101
 102 dnl Use pretty build output with automake >= 1.11
 103 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
 104   AM_DEFAULT_VERBOSITY=1
 105   AC_SUBST(AM_DEFAULT_VERBOSITY)
 106 ])
 107
 108 dnl Check for tools
 109 AC_PROG_CC
 110 AM_PROG_CC_C_O
 111
 112 dnl Initialize libtool
 113 LT_PREREQ([2.2])
 114 LT_INIT
 115
 116 AC_ARG_ENABLE(drm,
 117     AS_HELP_STRING([--enable-drm],
 118                    [enable DRM backend @<:@default=yes@:>@]),
 119     [], [enable_drm="yes"])
 120
 121 AC_ARG_ENABLE(x11,
 122     AS_HELP_STRING([--enable-x11],
 123                    [enable X11 output @<:@default=yes@:>@]),
 124     [], [enable_x11="yes"])
 125
 126 AC_ARG_ENABLE(glx,
 127     AS_HELP_STRING([--enable-glx],
 128                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
 129     [], [enable_glx="yes"])
 130
 131 AC_ARG_ENABLE(wayland,
 132     AC_HELP_STRING([--enable-wayland],
 133                    [enable Wayland output @<:@default=yes@:>@]),
 134     [], [enable_wayland="yes"])
 135
 136 dnl Check for basic libraries
 137 AC_CHECK_LIB(m, tan)
 138
 139 dnl Check for Gtk doc
 140 GTKDOC_VERSION=gtkdoc_version
 141 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 142 m4_ifdef([GTK_DOC_CHECK], [
 143 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 144 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 145 AC_SUBST(GTKDOC_VERSION)
 146
 147 dnl Check for GLib
 148 GLIB_VERSION_REQUIRED=glib_version
 149 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 150 AC_SUBST(GLIB_VERSION_REQUIRED)
 151
 152 dnl ---------------------------------------------------------------------------
 153 dnl -- GStreamer                                                             --
 154 dnl ---------------------------------------------------------------------------
 155
 156 dnl GStreamer Core
 157 PKG_CHECK_MODULES([GST],      [gstreamer-$GST_MAJORMINOR >= gst_version])
 158 PKG_CHECK_MODULES([GST_BASE], [gstreamer-base-$GST_MAJORMINOR >= gst_version])
 159
 160 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 161     saved_CFLAGS="$CFLAGS"
 162     CFLAGS="$CFLAGS $GST_BASE_CFLAGS"
 163     saved_LIBS="$LIBS"
 164     LIBS="$LIBS $GST_BASE_LIBS"
 165     AC_COMPILE_IFELSE(
 166         [AC_LANG_PROGRAM(
 167             [[#include <gst/base/gstbasesink.h>]],
 168             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 169         [ac_cv_have_gst_base_sink_query="yes"],
 170         [ac_cv_have_gst_base_sink_query="no"]
 171     )
 172     CFLAGS="$saved_CFLAGS"
 173     LIBS="$saved_LIBS"
 174 ])
 175 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 176     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 177 fi
 178
 179 dnl GStreamer -base plugins
 180 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 181     [gstreamer-plugins-base-$GST_MAJORMINOR >= gst_plugins_base_version])
 182 PKG_CHECK_MODULES([GST_INTERFACES],
 183     [gstreamer-interfaces-$GST_MAJORMINOR >= gst_plugins_base_version])
 184
 185 dnl ... GstVideoOverlayComposition (gstreamer-video)
 186 PKG_CHECK_MODULES([GST_VIDEO],
 187     [gstreamer-video-$GST_MAJORMINOR >= gst_plugins_base_version])
 188
 189 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 190     ac_cv_have_gst_video_overlay_composition, [
 191     saved_CFLAGS="$CFLAGS"
 192     CFLAGS="$CFLAGS $GST_CFLAGS"
 193     saved_LIBS="$LIBS"
 194     LIBS="$LIBS $GST_LIBS"
 195     AC_COMPILE_IFELSE(
 196         [AC_LANG_PROGRAM(
 197             [[#include <gst/video/video-overlay-composition.h>]],
 198             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
 199         [ac_cv_have_gst_video_overlay_composition="yes"],
 200         [ac_cv_have_gst_video_overlay_composition="no"]
 201     )
 202     CFLAGS="$saved_CFLAGS"
 203     LIBS="$saved_LIBS"
 204 ])
 205 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 206     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 207 fi
 208
 209 dnl GStreamer -bad plugins
 210 PKG_CHECK_MODULES([GST_BASEVIDEO],
 211     [gstreamer-basevideo-$GST_MAJORMINOR >= gst_plugins_bad_version])
 212
 213 dnl ... bitstream parsers
 214 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 215     [gstreamer-codecparsers-$GST_MAJORMINOR >= gst_plugins_bad_version])
 216
 217 dnl ... H.264 parser, with the required extensions
 218 AC_CACHE_CHECK([for H.264 parser],
 219     ac_cv_have_gst_h264_parser, [
 220     saved_CPPFLAGS="$CPPFLAGS"
 221     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 222     saved_LIBS="$LIBS"
 223     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 224     AC_COMPILE_IFELSE(
 225         [AC_LANG_PROGRAM(
 226             [[#include <gst/codecparsers/gsth264parser.h>]],
 227             [[GstH264SliceHdr slice_hdr;
 228               GstH264VUIParams vui_params;
 229               slice_hdr.n_emulation_prevention_bytes = 0;
 230               vui_params.par_n = 0;
 231               vui_params.par_d = 0;]])],
 232         [ac_cv_have_gst_h264_parser="yes"],
 233         [ac_cv_have_gst_h264_parser="no"]
 234     )
 235     CPPFLAGS="$saved_CPPFLAGS"
 236     LIBS="$saved_LIBS"
 237 ])
 238 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_H264],
 239     [test "$ac_cv_have_gst_h264_parser" != "yes"])
 240
 241 dnl ... JPEG parser, not upstream yet
 242 AC_CACHE_CHECK([for JPEG parser],
 243     ac_cv_have_gst_jpeg_parser, [
 244     saved_CPPFLAGS="$CPPFLAGS"
 245     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 246     saved_LIBS="$LIBS"
 247     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 248     AC_COMPILE_IFELSE(
 249         [AC_LANG_PROGRAM(
 250             [[#include <gst/codecparsers/gstjpegparser.h>]],
 251             [[GstJpegImage jpeg_image;]])],
 252         [ac_cv_have_gst_jpeg_parser="yes"],
 253         [ac_cv_have_gst_jpeg_parser="no"]
 254     )
 255     CPPFLAGS="$saved_CPPFLAGS"
 256     LIBS="$saved_LIBS"
 257 ])
 258 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_JPEG],
 259     [test "$ac_cv_have_gst_jpeg_parser" != "yes"])
 260
 261 dnl GST_ALL_LDFLAGS:
 262 dnl LDFLAGS really should only contain flags, not libs - they get added before
 263 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 264 GST_ALL_LDFLAGS="-no-undefined"
 265 AC_SUBST(GST_ALL_LDFLAGS)
 266
 267 dnl GST_PLUGIN_LDFLAGS:
 268 dnl this really should only contain flags, not libs - they get added before
 269 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 270 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 271 AC_SUBST(GST_PLUGIN_LDFLAGS)
 272
 273 dnl Check for the GStreamer plugins directory
 274 AC_MSG_CHECKING([for GStreamer plugins directory])
 275 GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 276 if test -z "$GST_PLUGINS_DIR"; then
 277     echo "FAIL FAIL FAIL"
 278     GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 279 fi
 280 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 281 plugindir="$GST_PLUGINS_DIR"
 282 AC_SUBST(plugindir)
 283
 284 dnl ---------------------------------------------------------------------------
 285 dnl -- Renderers                                                             --
 286 dnl ---------------------------------------------------------------------------
 287
 288 dnl Check for DRM/libudev
 289 USE_DRM=0
 290 if test "$enable_drm" = "yes"; then
 291     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
 292     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
 293
 294     if test $USE_DRM -eq 1; then
 295         saved_CPPFLAGS="$CPPFLAGS"
 296         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 297         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
 298         CPPFLAGS="$saved_CPPFLAGS"
 299     fi
 300 fi
 301
 302 dnl Check for X11
 303 USE_X11=0
 304 if test "$enable_x11" = "yes"; then
 305     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 306     if test $USE_X11 -eq 1; then
 307         saved_CPPFLAGS="$CPPFLAGS"
 308         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 309         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 310         CPPFLAGS="$saved_CPPFLAGS"
 311     fi
 312 fi
 313
 314 dnl Check for XRandR
 315 HAVE_XRANDR=0
 316 if test $USE_X11 -eq 1; then
 317     HAVE_XRANDR=1
 318     PKG_CHECK_MODULES([XRANDR], [xrandr], [:], [HAVE_XRANDR=0])
 319     if test $HAVE_XRANDR -eq 1; then
 320         saved_CPPFLAGS="$CPPFLAGS"
 321         CPPFLAGS="$CPPFLAGS $XRANDR_CFLAGS"
 322         AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [:], [HAVE_XRANDR=0])
 323         CPPFLAGS="$saved_CPPFLAGS"
 324     fi
 325 fi
 326 if test $HAVE_XRANDR -eq 1; then
 327     AC_DEFINE_UNQUOTED(HAVE_XRANDR, 1,
 328         [Defined to 1 if the XRandR extension exists.])
 329 fi
 330
 331 dnl OpenGL
 332 enable_opengl="no"
 333 if test "$enable_glx" = "yes"; then
 334     enable_opengl="yes"
 335 fi
 336
 337 HAVE_GL=0
 338 if test "$enable_opengl" = "yes"; then
 339     HAVE_GL=1
 340     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 341     saved_CPPFLAGS="$CPPFLAGS"
 342     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 343     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 344 #ifdef HAVE_GL_GL_H
 345 # include <GL/gl.h>
 346 #endif
 347     ])
 348     CPPFLAGS="$saved_CPPFLAGS"
 349 fi
 350
 351 dnl ... GLX
 352 USE_GLX=0
 353 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 354     USE_GLX=1
 355     saved_CPPFLAGS="$CPPFLAGS"
 356     saved_LIBS="$LIBS"
 357     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 358     LIBS="$LIBS $GL_LIBS"
 359     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 360 #ifdef HAVE_GL_GL_H
 361 # include <GL/gl.h>
 362 #endif
 363     ])
 364     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 365     CPPFLAGS="$saved_CPPFLAGS"
 366     LIBS="$saved_LIBS"
 367 fi
 368
 369 dnl Check for Wayland
 370 USE_WAYLAND=0
 371 if test "$enable_wayland" = "yes"; then
 372     PKG_CHECK_MODULES(WAYLAND, [wayland-client >= wayland_api_version],
 373         [USE_WAYLAND=1], [USE_WAYLAND=0])
 374
 375     if test $USE_WAYLAND -eq 1; then
 376         saved_CPPFLAGS="$CPPFLAGS"
 377         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 378         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
 379         CPPFLAGS="$saved_CPPFLAGS"
 380     fi
 381 fi
 382
 383 dnl ---------------------------------------------------------------------------
 384 dnl -- VA-API                                                                --
 385 dnl ---------------------------------------------------------------------------
 386
 387 dnl Core API
 388 LIBVA_PKGNAME="libva"
 389 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 390 AC_SUBST(LIBVA_PKGNAME)
 391
 392 VA_VERSION=`$PKG_CONFIG --modversion libva`
 393 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 394 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 395 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 396 VA_VERSION_STR="$VA_VERSION"
 397
 398 dnl VA/DRM API
 399 HAVE_VA_DRM=0
 400 if test $USE_DRM -eq 1; then
 401     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
 402         [HAVE_VA_DRM=1], [USE_DRM=0])
 403
 404     if test $HAVE_VA_DRM -eq 1; then
 405         saved_CPPFLAGS="$CPPFLAGS"
 406         CPPFLAGS="$LIBVA_DRM_CFLAGS"
 407         AC_CHECK_HEADERS([va/va_drm.h], [:], [HAVE_VA_DRM=0 USE_DRM=0])
 408         CPPFLAGS="$saved_CPPFLAGS"
 409     fi
 410 fi
 411
 412 dnl VA/X11 API
 413 HAVE_VA_X11=0
 414 LIBVA_X11_PKGNAME="libva-x11"
 415 if test $USE_X11 -eq 1; then
 416     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 417         [HAVE_VA_X11=1], [USE_X11=0])
 418 fi
 419 AC_SUBST(LIBVA_X11_PKGNAME)
 420
 421 dnl VA/GLX API
 422 HAVE_VA_GLX=0
 423 LIBVA_GLX_PKGNAME="libva-glx"
 424 if test $USE_GLX -eq 1; then
 425     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
 426         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
 427
 428     if test $HAVE_VA_GLX -eq 1; then
 429         saved_CPPFLAGS="$CPPFLAGS"
 430         CPPFLAGS="$LIBVA_GLX_CFLAGS"
 431         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
 432         CPPFLAGS="$saved_CPPFLAGS"
 433     fi
 434 fi
 435 AC_SUBST(LIBVA_GLX_PKGNAME)
 436
 437 dnl Check for JPEG decoding API (0.32.1+)
 438 USE_JPEG_DECODER=0
 439 AC_CACHE_CHECK([for JPEG decoding API],
 440     ac_cv_have_jpeg_decoding_api, [
 441     saved_CFLAGS="$CFLAGS"
 442     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 443     saved_LIBS="$LIBS"
 444     LIBS="$CFLAGS $LIBVA_LIBS"
 445     AC_COMPILE_IFELSE(
 446         [AC_LANG_PROGRAM(
 447             [[#include <va/va.h>]],
 448             [[VAPictureParameterBufferJPEGBaseline pic_param;
 449               VASliceParameterBufferJPEGBaseline slice_param;
 450               VAHuffmanTableBufferJPEGBaseline huffman_table;
 451               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
 452         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 453         [ac_cv_have_jpeg_decoding_api="no"]
 454     )
 455     CFLAGS="$saved_CFLAGS"
 456     LIBS="$saved_LIBS"
 457 ])
 458
 459 dnl VA/Wayland API
 460 if test "$enable_wayland" = "yes"; then
 461     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
 462         [:], [USE_WAYLAND=0])
 463 fi
 464
 465 dnl ---------------------------------------------------------------------------
 466 dnl -- Generate files and summary                                            --
 467 dnl ---------------------------------------------------------------------------
 468
 469 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
 470 *:1:*)
 471     ;;
 472 *)
 473     AC_MSG_ERROR([No renderer is enabled])
 474     ;;
 475 esac
 476
 477 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 478     [Defined to 1 if JPEG decoder is used])
 479 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 480
 481 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
 482     [Defined to 1 if DRM is enabled])
 483 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
 484
 485 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 486     [Defined to 1 if X11 is enabled])
 487 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 488
 489 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 490     [Defined to 1 if GLX is enabled])
 491 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 492
 493 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
 494     [Defined to 1 if WAYLAND is enabled])
 495 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
 496
 497 pkgconfigdir=${libdir}/pkgconfig
 498 AC_SUBST(pkgconfigdir)
 499
 500 AC_CONFIG_FILES([
 501     Makefile
 502     debian.upstream/Makefile
 503     debian.upstream/changelog
 504     debian.upstream/control
 505     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 506 debian.upstream/gstreamer-vaapi-doc.install.in
 507     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 508 debian.upstream/gstreamer-vaapi.install.in
 509     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 510 debian.upstream/libgstvaapi.install.in
 511     debian.upstream/libgstvaapi-dev.install
 512     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
 513 debian.upstream/libgstvaapi-drm.install.in
 514     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 515 debian.upstream/libgstvaapi-glx.install.in
 516     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
 517 debian.upstream/libgstvaapi-wayland.install.in
 518     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 519 debian.upstream/libgstvaapi-x11.install.in
 520     docs/Makefile
 521     docs/reference/Makefile
 522     docs/reference/libs/Makefile
 523     docs/reference/libs/libs-docs.xml
 524     docs/reference/plugins/Makefile
 525     docs/reference/plugins/plugins-docs.xml
 526     ext/Makefile
 527     gst-libs/Makefile
 528     gst-libs/gst/Makefile
 529     gst-libs/gst/codecparsers/Makefile
 530     gst-libs/gst/vaapi/Makefile
 531     gst/Makefile
 532     gst/vaapi/Makefile
 533     pkgconfig/Makefile
 534     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 535 pkgconfig/gstreamer-vaapi.pc.in
 536     pkgconfig/gstreamer-vaapi-drm-$GST_MAJORMINOR.pc:\
 537 pkgconfig/gstreamer-vaapi-drm.pc.in
 538     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 539 pkgconfig/gstreamer-vaapi-glx.pc.in
 540     pkgconfig/gstreamer-vaapi-wayland-$GST_MAJORMINOR.pc:\
 541 pkgconfig/gstreamer-vaapi-wayland.pc.in
 542     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 543 pkgconfig/gstreamer-vaapi-x11.pc.in
 544     tests/Makefile
 545 ])
 546 AC_OUTPUT
 547
 548 dnl Print summary
 549 yesno() {
 550     test $1 -eq 1 && echo yes || echo no
 551 }
 552
 553 VIDEO_OUTPUTS=""
 554 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
 555 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
 556 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
 557 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
 558
 559 echo
 560 echo $PACKAGE configuration summary:
 561 echo
 562 echo VA-API version ................... : $VA_VERSION_STR
 563 echo Video outputs .................... : $VIDEO_OUTPUTS
 564 echo