configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([EXIF library], [0.6.14.cvs2], [libexif-devel@lists.sourceforge.net], [libexif])
   3 AC_CONFIG_SRCDIR([libexif/exif-data.h])
   4 AC_CONFIG_HEADERS([config.h])
   5 AC_CONFIG_MACRO_DIR([auto-m4])
   6 AM_INIT_AUTOMAKE([-Wall gnu 1.9 dist-bzip2 dist-zip check-news])
   7
   8 if test ! -d "$srcdir/m4m"; then
   9 AC_MSG_ERROR([
  10 You are missing the m4m/ directory in your top
  11 $PACKAGE_TARNAME source directory.
  12
  13 You are probably using an ill-maintained CVS tree.
  14 Running
  15
  16     cd $srcdir
  17     cvs co m4m
  18
  19 and re-running autogen.sh might help.
  20 ])
  21 fi
  22
  23 GP_CHECK_SHELL_ENVIRONMENT
  24 GP_CONFIG_MSG([Build])
  25 GP_CONFIG_MSG([Source code location],[${srcdir}])
  26
  27 dnl ---------------------------------------------------------------------------
  28 dnl Advanced information about versioning:
  29 dnl   * "Writing shared libraries" by Mike Hearn
  30 dnl         http://navi.cx/~mike/writing-shared-libraries.html
  31 dnl   * libtool.info chapter "Versioning"
  32 dnl   * libtool.info chapter "Updating library version information"
  33 dnl ---------------------------------------------------------------------------
  34 dnl Versioning:
  35 dnl  - CURRENT (Major):  Increment if the interface has changes. AGE is always
  36 dnl                      *changed* at the same time.
  37 dnl  - AGE (Micro):      Increment if any interfaces have been added; set to 0
  38 dnl                      if any interfaces have been removed. Removal has
  39 dnl                      precedence over adding, so set to 0 if both happened.
  40 dnl                      It denotes upward compatibility.
  41 dnl  - REVISION (Minor): Increment any time the source changes; set to
  42 dnl                      0 if you incremented CURRENT.
  43 dnl
  44 dnl  To summarize. Any interface *change* increment CURRENT. If that interface
  45 dnl  change does not break upward compatibility (ie it is an addition),
  46 dnl  increment AGE, Otherwise AGE is reset to 0. If CURRENT has changed,
  47 dnl  REVISION is set to 0, otherwise REVISION is incremented.
  48 dnl ---------------------------------------------------------------------------
  49 dnl C:A:R
  50 dnl 12:0:1   0.6.13
  51 dnl 13:1:0   added EXIF_DATA_OPTION_DONT_CHANGE_MAKER_NOTE (for 0.6.14)
  52 LIBEXIF_AGE=1
  53 LIBEXIF_REVISION=0
  54 LIBEXIF_CURRENT=13
  55 AC_SUBST([LIBEXIF_AGE])
  56 AC_SUBST([LIBEXIF_REVISION])
  57 AC_SUBST([LIBEXIF_CURRENT])
  58 AC_SUBST([LIBEXIF_CURRENT_MIN],[`expr $LIBEXIF_CURRENT - $LIBEXIF_AGE`])
  59 LIBEXIF_VERSION_INFO="$LIBEXIF_CURRENT:$LIBEXIF_REVISION:$LIBEXIF_AGE"
  60 AC_SUBST([LIBEXIF_VERSION_INFO])
  61
  62 AC_PROG_CC
  63 AC_C_CONST
  64 dnl FIXME: AC_LIBTOOL_WIN32_DLL
  65 AM_PROG_LIBTOOL
  66 AM_CPPFLAGS="$CPPFLAGS"
  67 GP_CONFIG_MSG([Compiler],[${CC}])
  68
  69
  70 dnl Create a stdint.h-like file containing size-specific integer definitions
  71 dnl that will always be available
  72 AX_NEED_STDINT_H([libexif/_stdint.h])
  73
  74
  75 dnl ------------------------------------------------------------------------
  76 dnl Whether we're supposed to ship binaries in the tarball
  77 dnl ------------------------------------------------------------------------
  78
  79 ship_binaries=false
  80 AC_ARG_ENABLE([ship-binaries],
  81 [AS_HELP_STRING([--enable-ship-binaries],
  82 [Whether to ship binaries in the tarball [default=no]])],[
  83         if test x$enableval = xyes; then
  84                 ship_binaries=true
  85         fi
  86 ])
  87 AM_CONDITIONAL([SHIP_BINARIES],[$ship_binaries])
  88 GP_CONFIG_MSG([Ship binaries in tarball],[$ship_binaries])
  89
  90
  91 dnl ---------------------------------------------------------------------------
  92 dnl Whether -lm is required for our math functions
  93 dnl ---------------------------------------------------------------------------
  94
  95 # we need sqrt and pow, but checking for sqrt should be sufficient
  96 AC_ARG_VAR([MATHLIBS],[The libraries required for mathematical functions, e.g. -lm])
  97 if test "x$MATHLIBS" = "x"; then
  98         # We must not compile with -Wall -Werror here:
  99         # char *sqrt() conflicts with double sin(const double xx) in any case.
 100         CFLAGS_save="$CFLAGS"
 101         CPPFLAGS_save="$CPPFLAGS"
 102         CPPFLAGS=""
 103         CFLAGS=""
 104         AC_CHECK_FUNC([sqrt],[
 105                 MATHLIBS=""
 106         ],[
 107                 AC_CHECK_LIB([m],[sqrt],[
 108                         MATHLIBS="-lm"
 109                 ],[
 110                         AC_MSG_ERROR([
 111 *** Could not find sqrt() function
 112 ])
 113                 ])
 114         ])
 115         CFLAGS="$CFLAGS_save"
 116         CPPFLAGS="$CPPFLAGS_save"
 117 fi
 118 AC_SUBST([MATHLIBS])
 119
 120
 121 # doc support
 122 GP_CHECK_DOC_DIR
 123 GP_CHECK_DOXYGEN
 124
 125 # Whether to enable the internal docs build.
 126 #
 127 # This takes quite some time due to the generation of lots of call
 128 # graphs, so it is disabled by default.
 129 set_enable_internal_docs=no
 130 AC_ARG_ENABLE([internal-docs], [dnl
 131 AS_HELP_STRING([--enable-internal-docs],
 132 [Build internal code docs if doxygen available])], [dnl
 133 dnl If either --enable-foo nor --disable-foo were given, execute this.
 134   if   test "x$enableval" = xno \
 135     || test "x$enableval" = xoff \
 136     || test "x$enableval" = xfalse;
 137   then
 138     set_enable_internal_docs=no
 139   elif test "x$enableval" = xyes \
 140     || test "x$enableval" = xon \
 141     || test "x$enableval" = xtrue
 142   then
 143     set_enable_internal_docs=yes
 144   fi
 145 ])
 146 AC_MSG_CHECKING([whether to create internal code docs])
 147 AC_MSG_RESULT([${set_enable_internal_docs}])
 148 AM_CONDITIONAL([ENABLE_INTERNAL_DOCS], [test "x${set_enable_internal_docs}" = "xyes"])
 149
 150
 151 # ---------------------------------------------------------------------------
 152 # i18n support
 153 # ---------------------------------------------------------------------------
 154 ALL_LINGUAS="cs de es fr pl ru sk vi"
 155 GP_GETTEXT_HACK([${PACKAGE}-${LIBEXIF_CURRENT_MIN}],
 156                 [Lutz Mueller and others])
 157 AM_GNU_GETTEXT_VERSION([0.14.1])
 158 AM_GNU_GETTEXT([external])
 159 AM_PO_SUBDIRS()
 160 AM_ICONV()
 161 GP_GETTEXT_FLAGS()
 162
 163 dnl We cannot use AC_DEFINE_UNQUOTED() for these definitions, as
 164 dnl we require make to do insert the proper $(datadir) value
 165 localedir="\$(datadir)/locale"
 166 AC_SUBST(localedir)
 167 AM_CPPFLAGS="$AM_CPPFLAGS -DLOCALEDIR=\\\"${localedir}\\\""
 168
 169
 170 dnl ---------------------------------------------------------------------------
 171 dnl Compiler/Linker Options and Warnings
 172 dnl ---------------------------------------------------------------------------
 173 AM_CPPFLAGS="$AM_CPPFLAGS -I\$(top_srcdir)"
 174 AM_CPPFLAGS="$AM_CPPFLAGS -I\$(top_builddir)"
 175 AM_LDFLAGS="$LDFLAGS"
 176 if test "x$GCC" = "xyes"; then
 177     AM_CFLAGS="$AM_CFLAGS -ansi -pedantic-error"
 178     AM_CXXFLAGS="$AM_CXXFLAGS -ansi -pedantic-error"
 179     AM_CPPFLAGS="$AM_CPPFLAGS -g -Wall -Wmissing-declarations -Wmissing-prototypes"
 180     AM_LDFLAGS="$AM_LDFLAGS -g -Wall"
 181 fi
 182
 183
 184
 185 AC_SUBST(AM_CPPFLAGS)
 186 AC_SUBST(AM_LDFLAGS)
 187
 188
 189 dnl ---------------------------------------------------------------------------
 190 dnl Output files
 191 dnl ---------------------------------------------------------------------------
 192 AC_CONFIG_FILES([
 193   po/Makefile.in
 194   Makefile
 195   libexif.spec
 196   libexif/Makefile
 197   libexif/canon/Makefile
 198   libexif/olympus/Makefile
 199   libexif/pentax/Makefile
 200   test/Makefile
 201   test/nls/Makefile
 202   m4m/Makefile
 203   doc/Makefile
 204   doc/Doxyfile
 205   doc/Doxyfile-internals
 206   libexif.pc
 207   libexif-uninstalled.pc
 208   binary/Makefile
 209 ])
 210 AC_OUTPUT
 211
 212 GP_CONFIG_OUTPUT