configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Configure input file for elfutils.                     -*-autoconf-*-
   3 dnl
   4 dnl Copyright (C) 1996-2016 Red Hat, Inc.
   5 dnl
   6 dnl This file is part of elfutils.
   7 dnl
   8 dnl  This file is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 3 of the License, or
  11 dnl  (at your option) any later version.
  12 dnl
  13 dnl  elfutils is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl  GNU General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 AC_INIT([elfutils],[0.168],[https://sourceware.org/bugzilla],[elfutils],[http://elfutils.org/])
  21
  22 dnl Workaround for older autoconf < 2.64
  23 m4_ifndef([AC_PACKAGE_URL],
  24          [AC_DEFINE([PACKAGE_URL], ["http://elfutils.org/"],
  25                     [Define to home page for this package])
  26           AC_SUBST([PACKAGE_URL], ["http://elfutils.org/"])])
  27
  28 # We want eu- as default program prefix if none was given by the user.
  29 # But if the user explicitly provided --program-prefix="" then pretend
  30 # it wasn't set at all (NONE). We want to test this really early before
  31 # configure has a chance to use the value.
  32
  33 if test "x$program_prefix" = "xNONE"; then
  34   AC_MSG_NOTICE([No --program-prefix given, using "eu-"])
  35   program_prefix="eu-"
  36 elif test "x$program_prefix" = "x"; then
  37   AC_MSG_NOTICE([Using no program-prefix])
  38   program_prefix=NONE
  39 fi
  40
  41 AC_CONFIG_AUX_DIR([config])
  42 AC_CONFIG_FILES([config/Makefile])
  43
  44 AC_COPYRIGHT([Copyright (C) 1996-2016 The elfutils developers.])
  45 AC_PREREQ(2.63)                 dnl Minimum Autoconf version required.
  46
  47 dnl We use GNU make extensions; automake 1.10 defaults to -Wportability.
  48 AM_INIT_AUTOMAKE([gnits 1.11 -Wno-portability dist-bzip2 no-dist-gzip parallel-tests])
  49 AM_MAINTAINER_MODE
  50
  51 AM_SILENT_RULES([yes])
  52
  53 AC_CONFIG_SRCDIR([libelf/libelf.h])
  54 AC_CONFIG_FILES([Makefile])
  55 AC_CONFIG_HEADERS([config.h])
  56
  57 AC_CONFIG_MACRO_DIR([m4])
  58 AC_CONFIG_FILES([m4/Makefile])
  59
  60 dnl The RPM spec file.  We substitute a few values in the file.
  61 AC_CONFIG_FILES([elfutils.spec:config/elfutils.spec.in])
  62
  63
  64 AC_CANONICAL_HOST
  65
  66 AC_ARG_ENABLE(deterministic-archives,
  67 [AS_HELP_STRING([--enable-deterministic-archives],
  68                 [ar and ranlib default to -D behavior])], [
  69 if test "${enableval}" = no; then
  70   default_ar_deterministic=false
  71 else
  72   default_ar_deterministic=true
  73 fi], [default_ar_deterministic=false])
  74 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  75                    [Should ar and ranlib use -D behavior by default?])
  76
  77 AC_ARG_ENABLE([thread-safety],
  78 AS_HELP_STRING([--enable-thread-safety],
  79                [enable thread safety of libraries EXPERIMENTAL]),
  80                use_locks=$enableval, use_locks=no)
  81 AM_CONDITIONAL(USE_LOCKS, test "$use_locks" = yes)
  82 AS_IF([test "$use_locks" = yes], [AC_DEFINE(USE_LOCKS)])
  83 AS_IF([test "$use_locks" = yes],
  84       [AC_MSG_WARN([thread-safety is EXPERIMENTAL tests might fail.])])
  85
  86 AH_TEMPLATE([USE_LOCKS], [Defined if libraries should be thread-safe.])
  87
  88 AC_PROG_CC
  89 AC_PROG_RANLIB
  90 AC_PROG_YACC
  91 AM_PROG_LEX
  92 # Only available since automake 1.12
  93 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  94 AC_CHECK_TOOL([READELF], [readelf])
  95 AC_CHECK_TOOL([NM], [nm])
  96
  97 # We use -std=gnu99 but have explicit checks for some language constructs
  98 # and GNU extensions since some compilers claim GNU99 support, but don't
  99 # really support all language extensions. In particular we need
 100 # Mixed Declarations and Code
 101 # https://gcc.gnu.org/onlinedocs/gcc/Mixed-Declarations.html
 102 # Nested Functions
 103 # https://gcc.gnu.org/onlinedocs/gcc/Nested-Functions.html
 104 # Arrays of Variable Length
 105 # https://gcc.gnu.org/onlinedocs/gcc/Variable-Length.html
 106 AC_CACHE_CHECK([for gcc with GNU99 support], ac_cv_c99, [dnl
 107 old_CFLAGS="$CFLAGS"
 108 CFLAGS="$CFLAGS -std=gnu99"
 109 AC_COMPILE_IFELSE([AC_LANG_SOURCE([dnl
 110 int foo (int a)
 111 {
 112   for (int i = 0; i < a; ++i) if (i % 4) break; int s = a; return s;
 113 }
 114
 115 double bar (double a, double b)
 116 {
 117   double square (double z) { return z * z; }
 118   return square (a) + square (b);
 119 }
 120
 121 void baz (int n)
 122 {
 123   struct S { int x[[n]]; };
 124 }])],
 125                   ac_cv_c99=yes, ac_cv_c99=no)
 126 CFLAGS="$old_CFLAGS"])
 127 AS_IF([test "x$ac_cv_c99" != xyes],
 128       AC_MSG_ERROR([gcc with GNU99 support required]))
 129
 130 AC_CACHE_CHECK([for __thread support], ac_cv_tls, [dnl
 131 # Use the same flags that we use for our DSOs, so the test is representative.
 132 # Some old compiler/linker/libc combinations fail some ways and not others.
 133 save_CFLAGS="$CFLAGS"
 134 save_LDFLAGS="$LDFLAGS"
 135 CFLAGS="-fPIC $CFLAGS"
 136 LDFLAGS="-shared -Wl,-z,defs,-z,relro $LDFLAGS"
 137 AC_LINK_IFELSE([dnl
 138 AC_LANG_PROGRAM([[#include <stdlib.h>
 139 #undef __thread
 140 static __thread int a; int foo (int b) { return a + b; }]],
 141                 [[exit (foo (0));]])],
 142                ac_cv_tls=yes, ac_cv_tls=no)
 143 CFLAGS="$save_CFLAGS"
 144 LDFLAGS="$save_LDFLAGS"])
 145 AS_IF([test "x$ac_cv_tls" != xyes],
 146       AC_MSG_ERROR([__thread support required]))
 147
 148 dnl This test must come as early as possible after the compiler configuration
 149 dnl tests, because the choice of the file model can (in principle) affect
 150 dnl whether functions and headers are available, whether they work, etc.
 151 AC_SYS_LARGEFILE
 152
 153 dnl Older glibc had a broken fts that didn't work with Large File Systems.
 154 dnl We want the version that can handler LFS, but include workaround if we
 155 dnl get a bad one. Add define to CFLAGS (not AC_DEFINE it) since we need to
 156 dnl check it before including config.h (which might define _FILE_OFFSET_BITS).
 157 AC_CACHE_CHECK([whether fts.h is bad when included (with LFS)], ac_cv_bad_fts,
 158   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <fts.h>]])],
 159                      ac_cv_bad_fts=no, ac_cv_bad_fts=yes)])
 160 AS_IF([test "x$ac_cv_bad_fts" = "xyes"], [CFLAGS="$CFLAGS -DBAD_FTS=1"])
 161
 162 # See if we can add -D_FORTIFY_SOURCE=2. Don't do it if it is already
 163 # (differently) defined or if it generates warnings/errors because we
 164 # don't use the right optimisation level (string.h will warn about that).
 165 AC_MSG_CHECKING([whether to add -D_FORTIFY_SOURCE=2 to CFLAGS])
 166 case "$CFLAGS" in
 167   *-D_FORTIFY_SOURCE=2*)
 168     AC_MSG_RESULT([no, already there])
 169     ;;
 170   *)
 171     save_CFLAGS="$CFLAGS"
 172     CFLAGS="-D_FORTIFY_SOURCE=2 -Werror $CFLAGS"
 173     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 174       #include <string.h>
 175       int main() { return 0; }
 176     ]])], [ AC_MSG_RESULT([yes])
 177             CFLAGS="-D_FORTIFY_SOURCE=2 $save_CFLAGS" ],
 178           [ AC_MSG_RESULT([no])
 179             CFLAGS="$save_CFLAGS"])
 180   ;;
 181 esac
 182
 183 dnl enable debugging of branch prediction.
 184 AC_ARG_ENABLE([debugpred],
 185 AS_HELP_STRING([--enable-debugpred],[build binaries with support to debug branch prediction]),
 186 [use_debugpred=$enableval], [use_debugpred=no])
 187 case $use_debugpred in
 188  yes) use_debugpred_val=1 ;;
 189  *)   use_debugpred_val=0 ;;
 190 esac
 191 AC_SUBST([DEBUGPRED], $use_debugpred_val)
 192
 193 dnl Enable gprof suport.
 194 AC_ARG_ENABLE([gprof],
 195 AS_HELP_STRING([--enable-gprof],[build binaries with gprof support]), [use_gprof=$enableval], [use_gprof=no])
 196 if test "$use_gprof" = yes; then
 197   CFLAGS="$CFLAGS -pg"
 198   LDFLAGS="$LDFLAGS -pg"
 199 fi
 200 AM_CONDITIONAL(GPROF, test "$use_gprof" = yes)
 201
 202 # Enable gcov suport.
 203 AC_ARG_ENABLE([gcov],
 204 AS_HELP_STRING([--enable-gcov],[build binaries with gcov support]), [use_gcov=$enableval], [use_gcov=no])
 205 if test "$use_gcov" = yes; then
 206   CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 207   LDFLAGS="$LDFLAGS -fprofile-arcs"
 208 fi
 209 AM_CONDITIONAL(GCOV, test "$use_gcov" = yes)
 210
 211 AC_ARG_ENABLE([sanitize-undefined],
 212               AS_HELP_STRING([--enable-sanitize-undefined],
 213                              [Use gcc undefined behaviour sanitizer]),
 214                              [use_undefined=$enableval], [use_undefined=no])
 215 if test "$use_undefined" = yes; then
 216   old_CFLAGS="$CFLAGS"
 217   old_CXXFLAGS="$CXXFLAGS"
 218   # We explicitly use unaligned access when possible (see ALLOW_UNALIGNED)
 219   # We want to fail immediately on first error, don't try to recover.
 220   CFLAGS="$CFLAGS -fsanitize=undefined -fno-sanitize-recover"
 221   CXXFLAGS="$CXXFLAGS -fsanitize=undefined -fno-sanitize-recover"
 222   AC_LINK_IFELSE([AC_LANG_SOURCE([int main (int argc, char **argv) { return 0; }])], use_undefined=yes, use_undefined=no)
 223   AS_IF([test "x$use_undefined" != xyes],
 224         AC_MSG_WARN([gcc undefined behaviour sanitizer not available])
 225         CFLAGS="$old_CFLAGS" CXXFLAGS="$old_CXXFLAGS")
 226 fi
 227 case $use_undefined in
 228  yes) check_undefined_val=1 ;;
 229  *)   check_undefined_val=0 ;;
 230 esac
 231 AC_DEFINE_UNQUOTED(CHECK_UNDEFINED, $check_undefined_val,
 232                    [Building with -fsanitize=undefined or not])
 233
 234 AC_ARG_ENABLE([valgrind],
 235 AS_HELP_STRING([--enable-valgrind],[run all tests under valgrind]),
 236 [use_valgrind=$enableval], [use_valgrind=no])
 237 if test "$use_valgrind" = yes; then
 238   AC_CHECK_PROG(HAVE_VALGRIND, valgrind, yes, no)
 239   if test "$HAVE_VALGRIND" = "no"; then
 240     AC_MSG_ERROR([valgrind not found])
 241   fi
 242 fi
 243 AM_CONDITIONAL(USE_VALGRIND, test "$use_valgrind" = yes)
 244
 245 AM_CONDITIONAL(BUILD_STATIC, [dnl
 246 test "$use_gprof" = yes -o "$use_gcov" = yes])
 247
 248 AC_ARG_ENABLE([tests-rpath],
 249 AS_HELP_STRING([--enable-tests-rpath],[build $ORIGIN-using rpath into tests]),
 250                [tests_use_rpath=$enableval], [tests_use_rpath=no])
 251 AM_CONDITIONAL(TESTS_RPATH, test "$tests_use_rpath" = yes)
 252
 253 LIBEBL_SUBDIR="$PACKAGE"
 254 AC_ARG_ENABLE([libebl-subdir],
 255 AS_HELP_STRING([--enable-libebl-subdir=DIR],
 256 [install libebl_CPU modules in $(libdir)/DIR]), [dnl
 257 LIBEBL_SUBDIR="$enable_libebl_subdir"])
 258 AC_SUBST([LIBEBL_SUBDIR])
 259 AC_DEFINE_UNQUOTED(LIBEBL_SUBDIR, "$LIBEBL_SUBDIR")
 260 AH_TEMPLATE([LIBEBL_SUBDIR], [$libdir subdirectory containing libebl modules.])
 261
 262 dnl zlib is mandatory.
 263 save_LIBS="$LIBS"
 264 LIBS=
 265 eu_ZIPLIB(zlib,ZLIB,z,gzdirect,gzip)
 266 AS_IF([test "x$with_zlib" = xno], [AC_MSG_ERROR([zlib not found but is required])])
 267 LIBS="$save_LIBS"
 268
 269 dnl Test for bzlib and xz/lzma, gives BZLIB/LZMALIB .am
 270 dnl conditional and config.h USE_BZLIB/USE_LZMALIB #define.
 271 save_LIBS="$LIBS"
 272 LIBS=
 273 eu_ZIPLIB(bzlib,BZLIB,bz2,BZ2_bzdopen,bzip2)
 274 # We need this since bzip2 doesn't have a pkgconfig file.
 275 BZ2_LIB="$LIBS"
 276 AC_SUBST([BZ2_LIB])
 277 eu_ZIPLIB(lzma,LZMA,lzma,lzma_auto_decoder,[LZMA (xz)])
 278 AS_IF([test "x$with_lzma" = xyes], [LIBLZMA="liblzma"], [LIBLZMA=""])
 279 AC_SUBST([LIBLZMA])
 280 zip_LIBS="$LIBS"
 281 LIBS="$save_LIBS"
 282 AC_SUBST([zip_LIBS])
 283
 284 AC_CHECK_DECLS([memrchr, rawmemchr],[],[],
 285                [#define _GNU_SOURCE
 286                 #include <string.h>])
 287 AC_CHECK_DECLS([powerof2],[],[],[#include <sys/param.h>])
 288
 289 AC_CHECK_LIB([stdc++], [__cxa_demangle], [dnl
 290 AC_DEFINE([USE_DEMANGLE], [1], [Defined if demangling is enabled])])
 291 AM_CONDITIONAL(DEMANGLE, test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes")
 292 AS_IF([test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes"],
 293       [enable_demangler=yes],[enable_demangler=no])
 294
 295 AC_ARG_ENABLE([textrelcheck],
 296 AS_HELP_STRING([--disable-textrelcheck],
 297                [Disable textrelcheck being a fatal error]))
 298 AM_CONDITIONAL(FATAL_TEXTREL, [test "x$enable_textrelcheck" != "xno"])
 299 AS_IF([test "x$enable_textrelcheck" != "xno"],
 300       [enable_textrelcheck=yes],[enable_textrelcheck=no])
 301
 302 AC_ARG_ENABLE([symbol-versioning],
 303 AS_HELP_STRING([--disable-symbol-versioning],
 304                [Disable symbol versioning in shared objects]))
 305 AM_CONDITIONAL(SYMBOL_VERSIONING, [test "x$enable_symbol_versioning" != "xno"])
 306 AS_IF([test "x$enable_symbol_versioning" = "xno"],
 307       [AC_MSG_WARN([Disabling symbol versioning breaks ABI compatibility.])
 308        enable_symbol_versioning=no],[enable_symbol_versioning=yes])
 309
 310 AC_CACHE_CHECK([whether gcc accepts -Wstack-usage], ac_cv_stack_usage, [dnl
 311 old_CFLAGS="$CFLAGS"
 312 CFLAGS="$CFLAGS -Wstack-usage=262144 -Werror"
 313 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 314                   ac_cv_stack_usage=yes, ac_cv_stack_usage=no)
 315 CFLAGS="$old_CFLAGS"])
 316 AM_CONDITIONAL(ADD_STACK_USAGE_WARNING, [test "x$ac_cv_stack_usage" != "xno"])
 317
 318 # -Wlogical-op was too fragile in the past, make sure we get a sane one.
 319 AC_CACHE_CHECK([whether gcc has a sane -Wlogical-op], ac_cv_logical_op, [dnl
 320 old_CFLAGS="$CFLAGS"
 321 CFLAGS="$CFLAGS -Wlogical-op -Werror"
 322 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
 323         [#define FLAG 1
 324         int f (int r, int f) { return (r && (FLAG || (FLAG & f))); }])],
 325                   ac_cv_logical_op=yes, ac_cv_logical_op=no)
 326 CFLAGS="$old_CFLAGS"])
 327 AM_CONDITIONAL(SANE_LOGICAL_OP_WARNING,
 328                [test "x$ac_cv_logical_op" != "xno"])
 329
 330 # -Wduplicated-cond was added by GCC6
 331 AC_CACHE_CHECK([whether gcc accepts -Wduplicated-cond], ac_cv_duplicated_cond, [dnl
 332 old_CFLAGS="$CFLAGS"
 333 CFLAGS="$CFLAGS -Wduplicated-cond -Werror"
 334 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 335                   ac_cv_duplicated_cond=yes, ac_cv_duplicated_cond=no)
 336 CFLAGS="$old_CFLAGS"])
 337 AM_CONDITIONAL(HAVE_DUPLICATED_COND_WARNING,
 338                [test "x$ac_cv_duplicated_cond" != "xno"])
 339
 340 # -Wnull-dereference was added by GCC6
 341 AC_CACHE_CHECK([whether gcc accepts -Wnull-dereference], ac_cv_null_dereference, [dnl
 342 old_CFLAGS="$CFLAGS"
 343 CFLAGS="$CFLAGS -Wnull-dereference -Werror"
 344 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 345                   ac_cv_null_dereference=yes, ac_cv_null_dereference=no)
 346 CFLAGS="$old_CFLAGS"])
 347 AM_CONDITIONAL(HAVE_NULL_DEREFERENCE_WARNING,
 348                [test "x$ac_cv_null_dereference" != "xno"])
 349
 350 # -Wimplicit-fallthrough was added by GCC7
 351 AC_CACHE_CHECK([whether gcc accepts -Wimplicit-fallthrough], ac_cv_implicit_fallthrough, [dnl
 352 old_CFLAGS="$CFLAGS"
 353 CFLAGS="$CFLAGS -Wimplicit-fallthrough -Werror"
 354 AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
 355                   ac_cv_implicit_fallthrough=yes, ac_cv_implicit_fallthrough=no)
 356 CFLAGS="$old_CFLAGS"])
 357 AM_CONDITIONAL(HAVE_IMPLICIT_FALLTHROUGH_WARNING,
 358                [test "x$ac_cv_implicit_fallthrough" != "xno"])
 359
 360 dnl Check if we have argp available from our libc
 361 AC_LINK_IFELSE(
 362         [AC_LANG_PROGRAM(
 363                 [#include <argp.h>],
 364                 [int argc=1; char *argv[]={"test"}; argp_parse(0,argc,&argv,0,0,0); return 0;]
 365                 )],
 366         [libc_has_argp="true"],
 367         [libc_has_argp="false"]
 368 )
 369
 370 dnl If our libc doesn't provide argp, then test for libargp
 371 if test "$libc_has_argp" = "false" ; then
 372         AC_MSG_WARN("libc does not have argp")
 373         AC_CHECK_LIB([argp], [argp_parse], [have_argp="true"], [have_argp="false"])
 374
 375         if test "$have_argp" = "false"; then
 376                 AC_MSG_ERROR("no libargp found")
 377         else
 378                 argp_LDADD="-largp"
 379         fi
 380 else
 381         argp_LDADD=""
 382 fi
 383 AC_SUBST([argp_LDADD])
 384
 385 dnl Check if we have <linux/bpf.h> for EM_BPF disassembly.
 386 AC_CHECK_HEADERS(linux/bpf.h)
 387 AM_CONDITIONAL(HAVE_LINUX_BPF_H, [test "x$ac_cv_header_linux_bpf_h" = "xyes"])
 388
 389 dnl The directories with content.
 390
 391 dnl Documentation.
 392 dnl Commented out for now.
 393 dnl AC_CONFIG_FILES([doc/Makefile])
 394
 395 dnl Support library.
 396 AC_CONFIG_FILES([lib/Makefile])
 397
 398 dnl ELF library.
 399 AC_CONFIG_FILES([libelf/Makefile])
 400
 401 dnl Higher-level ELF support library.
 402 AC_CONFIG_FILES([libebl/Makefile])
 403
 404 dnl DWARF-ELF Lower-level Functions support library.
 405 AC_CONFIG_FILES([libdwelf/Makefile])
 406
 407 dnl DWARF library.
 408 AC_CONFIG_FILES([libdw/Makefile])
 409
 410 dnl Higher-level DWARF support library.
 411 AC_CONFIG_FILES([libdwfl/Makefile])
 412
 413 dnl CPU handling library.
 414 AC_CONFIG_FILES([libcpu/Makefile])
 415
 416 dnl Assembler library.
 417 AM_CONDITIONAL(HAVE_LIBASM, true)dnl Used in tests/Makefile.am, which see.
 418 AC_CONFIG_FILES([libasm/Makefile])
 419
 420 dnl CPU-specific backend libraries.
 421 AC_CONFIG_FILES([backends/Makefile])
 422
 423 dnl Tools.
 424 AC_CONFIG_FILES([src/Makefile po/Makefile.in])
 425
 426 dnl Test suite.
 427 AM_CONDITIONAL(STANDALONE, false)dnl Used in tests/Makefile.am, which see.
 428 AC_CONFIG_FILES([tests/Makefile])
 429
 430 dnl pkgconfig files
 431 AC_CONFIG_FILES([config/libelf.pc config/libdw.pc])
 432
 433 # Get the definitions necessary to create the Makefiles in the po
 434 # subdirectories.  This is a small subset of the gettext rules.
 435 AC_SUBST(USE_NLS, yes)
 436 AM_PO_SUBDIRS
 437
 438 dnl Appended to the config.h file.
 439 dnl We hide all kinds of configuration magic in lib/eu-config.h.
 440 AH_BOTTOM([#include <eu-config.h>])
 441
 442 dnl Version compatibility header.
 443 AC_CONFIG_FILES([version.h:config/version.h.in])
 444 AC_SUBST([eu_version])
 445
 446 # 1.234<whatever> -> 1234<whatever>
 447 case "$PACKAGE_VERSION" in
 448 [[0-9]].*) eu_version=`echo "$PACKAGE_VERSION" | sed 's@\.@@'` ;;
 449 *)         AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 450 esac
 451 case "$eu_version" in
 452 *.*)
 453   # 1234.567 -> "1234", "567"
 454   eu_extra_version="${eu_version#*.}"
 455   eu_version="${eu_version%%.*}"
 456   case "$eu_extra_version" in
 457   [[0-9]][[0-9]][[0-9]]) ;;
 458   [[0-9]][[0-9]])       eu_extra_version="${eu_extra_version}0" ;;
 459   [[0-9]])              eu_extra_version="${eu_extra_version}00" ;;
 460   *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 461   esac
 462   ;;
 463 *)
 464   eu_extra_version=000
 465   ;;
 466 esac
 467
 468 case "$eu_version" in
 469       0[[0-9]][[0-9]][[0-9]]) eu_version="${eu_version#0}$eu_extra_version" ;;
 470 [[0-9]][[0-9]][[0-9]][[0-9]]) eu_version="${eu_version}$eu_extra_version" ;;
 471 [[0-9]][[0-9]][[0-9]])        eu_version="${eu_version}0$eu_extra_version" ;;
 472 [[0-9]][[0-9]])               eu_version="${eu_version}00$eu_extra_version";;
 473 *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 474 esac
 475
 476 # Round up to the next release API (x.y) version.
 477 eu_version=$(( (eu_version + 999) / 1000 ))
 478
 479 dnl Unique ID for this build.
 480 MODVERSION="Build for ${LIBEBL_SUBDIR} ${eu_version} ${ac_cv_build}"
 481 AC_SUBST([MODVERSION])
 482 AC_DEFINE_UNQUOTED(MODVERSION, "$MODVERSION")
 483 AH_TEMPLATE([MODVERSION], [Identifier for modules in the build.])
 484
 485 AC_CHECK_SIZEOF(long)
 486
 487 # On aarch64 before glibc 2.20 we would get the kernel user_pt_regs instead
 488 # of the user_regs_struct from sys/user.h. They are structurally the same
 489 # but we get either one or the other.
 490 AC_CHECK_TYPE([struct user_regs_struct],
 491               [sys_user_has_user_regs=yes], [sys_user_has_user_regs=no],
 492               [[#include <sys/ptrace.h>]
 493                [#include <sys/time.h>]
 494                [#include <sys/user.h>]])
 495 if test "$sys_user_has_user_regs" = "yes"; then
 496   AC_DEFINE(HAVE_SYS_USER_REGS, 1,
 497             [Define to 1 if <sys/user.h> defines struct user_regs_struct])
 498 fi
 499
 500 # On a 64-bit host where can can use $CC -m32, we'll run two sets of tests.
 501 # Likewise in a 32-bit build on a host where $CC -m64 works.
 502 utrace_BIARCH
 503 # `$utrace_biarch' will be `-m64' even on an uniarch i386 machine.
 504 CC_BIARCH="$CC $utrace_biarch"
 505 AC_SUBST([CC_BIARCH])
 506
 507 # In maintainer mode we really need flex and bison.
 508 # Otherwise we really need a release dir with maintainer files generated.
 509 if test "x$enable_maintainer_mode" = xyes; then
 510   AC_CHECK_PROG(HAVE_FLEX, flex, yes, no)
 511   if test "$HAVE_FLEX" = "no"; then
 512     AC_MSG_ERROR([flex needed in maintainer mode])
 513   fi
 514   AC_CHECK_PROG(HAVE_BISON, bison, yes, no)
 515   if test "$HAVE_BISON" = "no"; then
 516     AC_MSG_ERROR([bison needed in maintainer mode])
 517   fi
 518 else
 519   if test ! -f ${srcdir}/libdw/known-dwarf.h; then
 520     AC_MSG_ERROR([No libdw/known-dwarf.h. configure --enable-maintainer-mode])
 521   fi
 522 fi
 523
 524 # The testfiles are all compressed, we need bunzip2 when running make check
 525 AC_CHECK_PROG(HAVE_BUNZIP2, bunzip2, yes, no)
 526 if test "$HAVE_BUNZIP2" = "no"; then
 527   AC_MSG_WARN([No bunzip2, needed to run make check])
 528 fi
 529
 530 AC_OUTPUT
 531
 532 AC_MSG_NOTICE([
 533 =====================================================================
 534         elfutils: ${PACKAGE_VERSION} (eu_version: ${eu_version})
 535 =====================================================================
 536
 537     Prefix                             : ${prefix}
 538     Program prefix ("eu-" recommended) : ${program_prefix}
 539     Source code location               : ${srcdir}
 540     Maintainer mode                    : ${enable_maintainer_mode}
 541     libebl modules subdirectory        : ${LIBEBL_SUBDIR}
 542     build arch                         : ${ac_cv_build}
 543
 544   RECOMMENDED FEATURES (should all be yes)
 545     gzip support                       : ${with_zlib}
 546     bzip2 support                      : ${with_bzlib}
 547     lzma/xz support                    : ${with_lzma}
 548     libstdc++ demangle support         : ${enable_demangler}
 549     File textrel check                 : ${enable_textrelcheck}
 550     Symbol versioning                  : ${enable_symbol_versioning}
 551
 552   NOT RECOMMENDED FEATURES (should all be no)
 553     Experimental thread safety         : ${use_locks}
 554
 555   OTHER FEATURES
 556     Deterministic archives by default  : ${default_ar_deterministic}
 557     Native language support            : ${USE_NLS}
 558
 559   EXTRA TEST FEATURES (used with make check)
 560     have bunzip2 installed (required)  : ${HAVE_BUNZIP2}
 561     debug branch prediction            : ${use_debugpred}
 562     gprof support                      : ${use_gprof}
 563     gcov support                       : ${use_gcov}
 564     run all tests under valgrind       : ${use_valgrind}
 565     gcc undefined behaviour sanitizer  : ${use_undefined}
 566     use rpath in tests                 : ${tests_use_rpath}
 567     test biarch                        : ${utrace_cv_cc_biarch}
 568 ])