configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.38
  32 LIBDRM_INTEL_REQUIRED=2.4.37
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  35 DRI2PROTO_REQUIRED=2.6
  36 GLPROTO_REQUIRED=1.4.14
  37 LIBDRM_XORG_REQUIRED=2.4.24
  38 LIBKMS_XORG_REQUIRED=1.0.0
  39
  40 dnl Check for progs
  41 AC_PROG_CPP
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44 AM_PROG_CC_C_O
  45 AM_PROG_AS
  46 AC_CHECK_PROGS([MAKE], [gmake make])
  47 AC_CHECK_PROGS([PYTHON2], [python2 python])
  48 AC_PROG_SED
  49 AC_PROG_MKDIR_P
  50 AC_PATH_PROG([MKDEP], [makedepend])
  51
  52 if test "x$MKDEP" = "x"; then
  53     AC_MSG_ERROR([makedepend is required to build Mesa])
  54 fi
  55
  56 AC_PROG_YACC
  57 AC_PATH_PROG([YACC_INST], $YACC)
  58 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  59     if test -z "$YACC_INST"; then
  60         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  61     fi
  62 fi
  63 AC_PROG_LEX
  64
  65 AC_PATH_PROG([PERL], [perl])
  66
  67 AC_CHECK_PROG(INDENT, indent, indent, cat)
  68 if test "x$INDENT" != "xcat"; then
  69     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  70 fi
  71
  72 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  73 dnl configuration in that case.
  74 AC_PROG_INSTALL
  75 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  76
  77 dnl We need a POSIX shell for parts of the build. Assume we have one
  78 dnl in most cases.
  79 case "$host_os" in
  80 solaris*)
  81     # Solaris /bin/sh is too old/non-POSIX compliant
  82     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  83     SHELL="$POSIX_SHELL"
  84     ;;
  85 esac
  86
  87 dnl clang is mostly GCC-compatible, but its version is much lower,
  88 dnl so we have to check for it.
  89 AC_MSG_CHECKING([if compiling with clang])
  90
  91 AC_COMPILE_IFELSE(
  92 [AC_LANG_PROGRAM([], [[
  93 #ifndef __clang__
  94        not clang
  95 #endif
  96 ]])],
  97 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  98
  99 AC_MSG_RESULT([$acv_mesa_CLANG])
 100
 101 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 102 dnl versions are explictly not supported.
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120 fi
 121
 122
 123 MKDEP_OPTIONS=-fdepend
 124 dnl Ask gcc where it's keeping its secret headers
 125 if test "x$GCC" = xyes; then
 126     for dir in include include-fixed; do
 127         GCC_INCLUDES=`$CC -print-file-name=$dir`
 128         if test "x$GCC_INCLUDES" != x && \
 129            test "$GCC_INCLUDES" != "$dir" && \
 130            test -d "$GCC_INCLUDES"; then
 131             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 132         fi
 133     done
 134 fi
 135 AC_SUBST([MKDEP_OPTIONS])
 136
 137 dnl Make sure the pkg-config macros are defined
 138 m4_ifndef([PKG_PROG_PKG_CONFIG],
 139     [m4_fatal([Could not locate the pkg-config autoconf macros.
 140   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 141   are in a different location, try setting the environment variable
 142   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 143 PKG_PROG_PKG_CONFIG()
 144
 145 dnl LIB_DIR - library basename
 146 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 147 AC_SUBST([LIB_DIR])
 148
 149 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 150 _SAVE_LDFLAGS="$LDFLAGS"
 151 _SAVE_CPPFLAGS="$CPPFLAGS"
 152
 153 dnl Compiler macros
 154 DEFINES=""
 155 AC_SUBST([DEFINES])
 156 case "$host_os" in
 157 linux*|*-gnu*|gnu*)
 158     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 159     ;;
 160 solaris*)
 161     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 162     ;;
 163 cygwin*)
 164     DEFINES="$DEFINES -DPTHREADS"
 165     ;;
 166 esac
 167
 168 dnl Add flags for gcc and g++
 169 if test "x$GCC" = xyes; then
 170     CFLAGS="$CFLAGS -Wall -std=c99"
 171
 172     # Enable -Werror=implicit-function-declaration and
 173     # -Werror=missing-prototypes, if available, or otherwise, just
 174     # -Wmissing-prototypes.  This is particularly useful to avoid
 175     # generating a loadable driver module that has undefined symbols.
 176     save_CFLAGS="$CFLAGS"
 177     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 178     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 179     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 180     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 181                    AC_MSG_RESULT([yes]),
 182                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 183                     AC_MSG_RESULT([no])]);
 184
 185     # Enable -fvisibility=hidden if using a gcc that supports it
 186     save_CFLAGS="$CFLAGS"
 187     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 188     VISIBILITY_CFLAGS="-fvisibility=hidden"
 189     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 190     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 191                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 192
 193     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 194     CFLAGS=$save_CFLAGS
 195
 196     # Work around aliasing bugs - developers should comment this out
 197     CFLAGS="$CFLAGS -fno-strict-aliasing"
 198
 199     # gcc's builtin memcmp is slower than glibc's
 200     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 201     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 202 fi
 203 if test "x$GXX" = xyes; then
 204     CXXFLAGS="$CXXFLAGS -Wall"
 205
 206     # Enable -fvisibility=hidden if using a gcc that supports it
 207     save_CXXFLAGS="$CXXFLAGS"
 208     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 209     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 210     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 211     AC_LANG_PUSH([C++])
 212     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 213                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 214     AC_LANG_POP([C++])
 215
 216     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 217     CXXFLAGS=$save_CXXFLAGS
 218
 219     # Work around aliasing bugs - developers should comment this out
 220     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 221
 222     # gcc's builtin memcmp is slower than glibc's
 223     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 224     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 225 fi
 226
 227 dnl even if the compiler appears to support it, using visibility attributes isn't
 228 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 229 case "$host_os" in
 230 cygwin*)
 231     VISIBILITY_CFLAGS=""
 232     VISIBILITY_CXXFLAGS=""
 233     ;;
 234 esac
 235
 236 AC_SUBST([VISIBILITY_CFLAGS])
 237 AC_SUBST([VISIBILITY_CXXFLAGS])
 238
 239 dnl
 240 dnl Hacks to enable 32 or 64 bit build
 241 dnl
 242 AC_ARG_ENABLE([32-bit],
 243     [AS_HELP_STRING([--enable-32-bit],
 244         [build 32-bit libraries @<:@default=auto@:>@])],
 245     [enable_32bit="$enableval"],
 246     [enable_32bit=auto]
 247 )
 248 if test "x$enable_32bit" = xyes; then
 249     if test "x$GCC" = xyes; then
 250         CFLAGS="$CFLAGS -m32"
 251         CCASFLAGS="$CCASFLAGS -m32"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -m32"
 255     fi
 256 fi
 257 AC_ARG_ENABLE([64-bit],
 258     [AS_HELP_STRING([--enable-64-bit],
 259         [build 64-bit libraries @<:@default=auto@:>@])],
 260     [enable_64bit="$enableval"],
 261     [enable_64bit=auto]
 262 )
 263 if test "x$enable_64bit" = xyes; then
 264     if test "x$GCC" = xyes; then
 265         CFLAGS="$CFLAGS -m64"
 266     fi
 267     if test "x$GXX" = xyes; then
 268         CXXFLAGS="$CXXFLAGS -m64"
 269     fi
 270 fi
 271
 272 dnl Can't have static and shared libraries, default to static if user
 273 dnl explicitly requested. If both disabled, set to static since shared
 274 dnl was explicitly requested.
 275 case "x$enable_static$enable_shared" in
 276 xyesyes )
 277     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 278     enable_shared=no
 279     ;;
 280 xnono )
 281     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 282     enable_static=yes
 283     ;;
 284 esac
 285
 286 dnl
 287 dnl mklib options
 288 dnl
 289 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 290 if test "$enable_static" = yes; then
 291     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 292 fi
 293 AC_SUBST([MKLIB_OPTIONS])
 294
 295 dnl
 296 dnl other compiler options
 297 dnl
 298 AC_ARG_ENABLE([debug],
 299     [AS_HELP_STRING([--enable-debug],
 300         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 301     [enable_debug="$enableval"],
 302     [enable_debug=no]
 303 )
 304 if test "x$enable_debug" = xyes; then
 305     DEFINES="$DEFINES -DDEBUG"
 306     if test "x$GCC" = xyes; then
 307         CFLAGS="$CFLAGS -g"
 308     fi
 309     if test "x$GXX" = xyes; then
 310         CXXFLAGS="$CXXFLAGS -g"
 311     fi
 312 fi
 313
 314 dnl
 315 dnl library names
 316 dnl
 317 LIB_PREFIX_GLOB='lib'
 318 LIB_VERSION_SEPARATOR='.'
 319 if test "$enable_static" = yes; then
 320     LIB_EXTENSION='a'
 321 else
 322     case "$host_os" in
 323     darwin* )
 324         LIB_EXTENSION='dylib' ;;
 325     cygwin* )
 326         dnl prefix can be 'cyg' or 'lib'
 327         LIB_PREFIX_GLOB='???'
 328         LIB_VERSION_SEPARATOR='-'
 329         LIB_EXTENSION='dll' ;;
 330     aix* )
 331         LIB_EXTENSION='a' ;;
 332     * )
 333         LIB_EXTENSION='so' ;;
 334     esac
 335 fi
 336 AC_ARG_WITH([gl-lib-name],
 337   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 338     [specify GL library name @<:@default=GL@:>@])],
 339   [GL_LIB=$withval],
 340   [GL_LIB=GL])
 341 AC_ARG_WITH([glu-lib-name],
 342   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 343     [specify GLU library name @<:@default=GLU@:>@])],
 344   [GLU_LIB=$withval],
 345   [GLU_LIB=GLU])
 346 AC_ARG_WITH([osmesa-lib-name],
 347   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 348     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 349   [OSMESA_LIB=$withval],
 350   [OSMESA_LIB=OSMesa])
 351 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 352 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 353 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 354
 355 dnl
 356 dnl Mangled Mesa support
 357 dnl
 358 AC_ARG_ENABLE([mangling],
 359   [AS_HELP_STRING([--enable-mangling],
 360     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 361   [enable_mangling="${enableval}"],
 362   [enable_mangling=no]
 363 )
 364 if test "x${enable_mangling}" = "xyes" ; then
 365   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 366   GL_LIB="Mangled${GL_LIB}"
 367   GLU_LIB="Mangled${GLU_LIB}"
 368   OSMESA_LIB="Mangled${OSMESA_LIB}"
 369 fi
 370 AC_SUBST([GL_LIB])
 371 AC_SUBST([GLU_LIB])
 372 AC_SUBST([OSMESA_LIB])
 373
 374 dnl
 375 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 376 dnl
 377 AC_ARG_ENABLE([texture-float],
 378     [AS_HELP_STRING([--enable-texture-float],
 379         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 380     [enable_texture_float="$enableval"],
 381     [enable_texture_float=no]
 382 )
 383 if test "x$enable_texture_float" = xyes; then
 384     AC_MSG_WARN([Floating-point textures enabled.])
 385     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 386     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 387 fi
 388
 389 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 390 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 391 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 392 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 393 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 394 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 395 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 396 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 397
 398 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 399 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 400 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406
 407 AC_SUBST([GL_LIB_NAME])
 408 AC_SUBST([GLU_LIB_NAME])
 409 AC_SUBST([OSMESA_LIB_NAME])
 410 AC_SUBST([EGL_LIB_NAME])
 411 AC_SUBST([GLESv1_CM_LIB_NAME])
 412 AC_SUBST([GLESv2_LIB_NAME])
 413 AC_SUBST([VG_LIB_NAME])
 414 AC_SUBST([GLAPI_LIB_NAME])
 415
 416 AC_SUBST([GL_LIB_GLOB])
 417 AC_SUBST([GLU_LIB_GLOB])
 418 AC_SUBST([EGL_LIB_GLOB])
 419 AC_SUBST([GLESv1_CM_LIB_GLOB])
 420 AC_SUBST([GLESv2_LIB_GLOB])
 421 AC_SUBST([VG_LIB_GLOB])
 422 AC_SUBST([GLAPI_LIB_GLOB])
 423
 424 dnl
 425 dnl Arch/platform-specific settings
 426 dnl
 427 AC_ARG_ENABLE([asm],
 428     [AS_HELP_STRING([--disable-asm],
 429         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 430     [enable_asm="$enableval"],
 431     [enable_asm=yes]
 432 )
 433 asm_arch=""
 434 MESA_ASM_FILES=""
 435 AC_MSG_CHECKING([whether to enable assembly])
 436 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 437 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 438 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 439     case "$host_cpu" in
 440     i?86 | x86_64)
 441         enable_asm=no
 442         AC_MSG_RESULT([no, cross compiling])
 443         ;;
 444     esac
 445 fi
 446 # check for supported arches
 447 if test "x$enable_asm" = xyes; then
 448     case "$host_cpu" in
 449     i?86)
 450         case "$host_os" in
 451         linux* | *freebsd* | dragonfly* | *netbsd*)
 452             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 453             ;;
 454         esac
 455         ;;
 456     x86_64)
 457         case "$host_os" in
 458         linux* | *freebsd* | dragonfly* | *netbsd*)
 459             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 460             ;;
 461         esac
 462         ;;
 463     sparc*)
 464         case "$host_os" in
 465         linux*)
 466             asm_arch=sparc
 467             ;;
 468         esac
 469         ;;
 470     esac
 471
 472     case "$asm_arch" in
 473     x86)
 474         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 475         MESA_ASM_FILES='$(X86_FILES)'
 476         AC_MSG_RESULT([yes, x86])
 477         ;;
 478     x86_64)
 479         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 480         MESA_ASM_FILES='$(X86_64_FILES)'
 481         AC_MSG_RESULT([yes, x86_64])
 482         ;;
 483     sparc)
 484         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 485         MESA_ASM_FILES='$(SPARC_FILES)'
 486         AC_MSG_RESULT([yes, sparc])
 487         ;;
 488     *)
 489         AC_MSG_RESULT([no, platform not supported])
 490         ;;
 491     esac
 492 fi
 493 AC_SUBST([MESA_ASM_FILES])
 494
 495 dnl PIC code macro
 496 MESA_PIC_FLAGS
 497
 498 dnl Check to see if dlopen is in default libraries (like Solaris, which
 499 dnl has it in libc), or if libdl is needed to get it.
 500 AC_CHECK_FUNC([dlopen], [],
 501     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 502 AC_SUBST([DLOPEN_LIBS])
 503
 504 dnl See if posix_memalign is available
 505 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 506
 507 dnl SELinux awareness.
 508 AC_ARG_ENABLE([selinux],
 509     [AS_HELP_STRING([--enable-selinux],
 510         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 511     [MESA_SELINUX="$enableval"],
 512     [MESA_SELINUX=no])
 513 if test "x$enable_selinux" = "xyes"; then
 514     AC_CHECK_HEADER([selinux/selinux.h],[],
 515                     [AC_MSG_ERROR([SELinux headers not found])])
 516     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 517                  [AC_MSG_ERROR([SELinux library not found])])
 518     SELINUX_LIBS="-lselinux"
 519     DEFINES="$DEFINES -DMESA_SELINUX"
 520 fi
 521
 522 dnl Options for APIs
 523 AC_ARG_ENABLE([opengl],
 524     [AS_HELP_STRING([--disable-opengl],
 525         [disable support for standard OpenGL API @<:@default=no@:>@])],
 526     [enable_opengl="$enableval"],
 527     [enable_opengl=yes])
 528 AC_ARG_ENABLE([gles1],
 529     [AS_HELP_STRING([--enable-gles1],
 530         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 531     [enable_gles1="$enableval"],
 532     [enable_gles1=no])
 533 AC_ARG_ENABLE([gles2],
 534     [AS_HELP_STRING([--enable-gles2],
 535         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 536     [enable_gles2="$enableval"],
 537     [enable_gles2=no])
 538 AC_ARG_ENABLE([openvg],
 539     [AS_HELP_STRING([--enable-openvg],
 540         [enable support for OpenVG API @<:@default=no@:>@])],
 541     [enable_openvg="$enableval"],
 542     [enable_openvg=no])
 543
 544 AC_ARG_ENABLE([dri],
 545     [AS_HELP_STRING([--enable-dri],
 546         [enable DRI modules @<:@default=enabled@:>@])],
 547     [enable_dri="$enableval"],
 548     [enable_dri=yes])
 549 AC_ARG_ENABLE([glx],
 550     [AS_HELP_STRING([--enable-glx],
 551         [enable GLX library @<:@default=enabled@:>@])],
 552     [enable_glx="$enableval"],
 553     [enable_glx=yes])
 554 AC_ARG_ENABLE([osmesa],
 555     [AS_HELP_STRING([--enable-osmesa],
 556         [enable OSMesa library @<:@default=disabled@:>@])],
 557     [enable_osmesa="$enableval"],
 558     [enable_osmesa=no])
 559 AC_ARG_ENABLE([egl],
 560     [AS_HELP_STRING([--disable-egl],
 561         [disable EGL library @<:@default=enabled@:>@])],
 562     [enable_egl="$enableval"],
 563     [enable_egl=yes])
 564
 565 AC_ARG_ENABLE([xorg],
 566     [AS_HELP_STRING([--enable-xorg],
 567         [enable support for X.Org DDX API @<:@default=no@:>@])],
 568     [enable_xorg="$enableval"],
 569     [enable_xorg=no])
 570 AC_ARG_ENABLE([xa],
 571     [AS_HELP_STRING([--enable-xa],
 572         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 573     [enable_xa="$enableval"],
 574     [enable_xa=no])
 575 AC_ARG_ENABLE([d3d1x],
 576     [AS_HELP_STRING([--enable-d3d1x],
 577         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 578     [enable_d3d1x="$enableval"],
 579     [enable_d3d1x=no])
 580 AC_ARG_ENABLE([gbm],
 581    [AS_HELP_STRING([--enable-gbm],
 582          [enable gbm library @<:@default=auto@:>@])],
 583    [enable_gbm="$enableval"],
 584    [enable_gbm=auto])
 585
 586 AC_ARG_ENABLE([xvmc],
 587    [AS_HELP_STRING([--enable-xvmc],
 588          [enable xvmc library @<:@default=auto@:>@])],
 589    [enable_xvmc="$enableval"],
 590    [enable_xvmc=auto])
 591 AC_ARG_ENABLE([vdpau],
 592    [AS_HELP_STRING([--enable-vdpau],
 593          [enable vdpau library @<:@default=auto@:>@])],
 594    [enable_vdpau="$enableval"],
 595    [enable_vdpau=auto])
 596 AC_ARG_ENABLE([va],
 597    [AS_HELP_STRING([--enable-va],
 598          [enable va library @<:@default=auto@:>@])],
 599    [enable_va="$enableval"],
 600    [enable_va=auto])
 601 AC_ARG_ENABLE([opencl],
 602    [AS_HELP_STRING([--enable-opencl],
 603          [enable OpenCL library @<:@default=no@:>@])],
 604    [enable_opencl="$enableval"],
 605    [enable_opencl=no])
 606 AC_ARG_ENABLE([xlib_glx],
 607     [AS_HELP_STRING([--enable-xlib-glx],
 608         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 609     [enable_xlib_glx="$enableval"],
 610     [enable_xlib_glx=no])
 611 AC_ARG_ENABLE([gallium_egl],
 612     [AS_HELP_STRING([--enable-gallium-egl],
 613         [enable optional EGL state tracker (not required
 614          for EGL support in Gallium with OpenGL and OpenGL ES)
 615          @<:@default=disable@:>@])],
 616     [enable_gallium_egl="$enableval"],
 617     [enable_gallium_egl=no])
 618 AC_ARG_ENABLE([gallium_gbm],
 619     [AS_HELP_STRING([--enable-gallium-gbm],
 620         [enable optional gbm state tracker (not required for
 621          gbm support in Gallium)
 622          @<:@default=auto@:>@])],
 623     [enable_gallium_gbm="$enableval"],
 624     [enable_gallium_gbm=auto])
 625
 626 AC_ARG_ENABLE([r600-llvm-compiler],
 627     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 628         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 629     [enable_r600_llvm="$enableval"],
 630     [enable_r600_llvm=no])
 631
 632 AC_ARG_ENABLE([gallium_tests],
 633     [AS_HELP_STRING([--enable-gallium-tests],
 634         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 635     [enable_gallium_tests="$enableval"],
 636     [enable_gallium_tests=no])
 637
 638 # Option for Gallium drivers
 639 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 640
 641 AC_ARG_WITH([gallium-drivers],
 642     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 643         [comma delimited Gallium drivers list, e.g.
 644         "i915,nouveau,r300,r600,svga,swrast"
 645         @<:@default=r300,r600,swrast@:>@])],
 646     [with_gallium_drivers="$withval"],
 647     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 648
 649 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 650 # here so that the script doesn't choke on an unknown driver name later.
 651 case "$with_gallium_drivers" in
 652     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 653     no) with_gallium_drivers='' ;;
 654 esac
 655
 656 if test "x$enable_opengl" = xno -a \
 657         "x$enable_gles1" = xno -a \
 658         "x$enable_gles2" = xno -a \
 659         "x$enable_openvg" = xno -a \
 660         "x$enable_xorg" = xno -a \
 661         "x$enable_xa" = xno -a \
 662         "x$enable_d3d1x" = xno -a \
 663         "x$enable_xvmc" = xno -a \
 664         "x$enable_vdpau" = xno -a \
 665         "x$enable_va" = xno -a \
 666         "x$enable_opencl" = xno; then
 667     AC_MSG_ERROR([at least one API should be enabled])
 668 fi
 669
 670 API_DEFINES=""
 671 if test "x$enable_opengl" = xno; then
 672     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 673 else
 674     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 675 fi
 676 if test "x$enable_gles1" = xyes; then
 677     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 678 fi
 679 if test "x$enable_gles2" = xyes; then
 680     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 681 fi
 682 AC_SUBST([API_DEFINES])
 683
 684 if test "x$enable_glx" = xno; then
 685     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 686     enable_xlib_glx=no
 687 fi
 688
 689 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 690     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 691 fi
 692
 693 # Disable GLX if DRI and Xlib-GLX are not enabled
 694 if test "x$enable_glx" = xyes -a \
 695         "x$enable_dri" = xno -a \
 696         "x$enable_xlib_glx" = xno; then
 697     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 698     enable_glx=no
 699 fi
 700
 701 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 702
 703 AC_ARG_ENABLE([shared-glapi],
 704     [AS_HELP_STRING([--enable-shared-glapi],
 705         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 706     [enable_shared_glapi="$enableval"],
 707     [enable_shared_glapi="$enable_dri"])
 708
 709 # Shared GLAPI is only useful for DRI
 710 if test "x$enable_dri" = xno; then
 711     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 712     enable_shared_glapi=no
 713 fi
 714
 715 # TODO: Get rid of SHARED_GLAPI variable
 716 SHARED_GLAPI="0"
 717 if test "x$enable_shared_glapi" = xyes; then
 718     SHARED_GLAPI="1"
 719     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 720     # the remap table)
 721     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 722     CORE_DIRS="mapi/shared-glapi"
 723 fi
 724 AC_SUBST([SHARED_GLAPI])
 725 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 726
 727 dnl
 728 dnl Driver specific build directories
 729 dnl
 730 SRC_DIRS="gtest"
 731 GALLIUM_DIRS="auxiliary drivers state_trackers"
 732 GALLIUM_TARGET_DIRS=""
 733 GALLIUM_WINSYS_DIRS="sw"
 734 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 735 GALLIUM_STATE_TRACKERS_DIRS=""
 736
 737 # build glapi if OpenGL is enabled
 738 if test "x$enable_opengl" = xyes; then
 739     CORE_DIRS="$CORE_DIRS mapi/glapi"
 740 fi
 741
 742 # build es1api if OpenGL ES 1.x is enabled
 743 if test "x$enable_gles1" = xyes; then
 744     CORE_DIRS="$CORE_DIRS mapi/es1api"
 745 fi
 746
 747 # build es2api if OpenGL ES 2.x is enabled
 748 if test "x$enable_gles2" = xyes; then
 749     CORE_DIRS="$CORE_DIRS mapi/es2api"
 750 fi
 751
 752 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 753 case "x$enable_opengl$enable_gles1$enable_gles2" in
 754 x*yes*)
 755     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 756     ;;
 757 esac
 758
 759 case "x$enable_glx$enable_xlib_glx" in
 760 xyesyes)
 761     DRIVER_DIRS="$DRIVER_DIRS x11"
 762     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 763     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 764     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 765     HAVE_WINSYS_XLIB="yes"
 766     ;;
 767 xyesno)
 768     # DRI-based GLX
 769     SRC_DIRS="$SRC_DIRS glx"
 770     ;;
 771 esac
 772
 773 if test "x$enable_dri" = xyes; then
 774     DRIVER_DIRS="$DRIVER_DIRS dri"
 775
 776     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 777     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 778     HAVE_ST_DRI="yes"
 779 fi
 780
 781 if test "x$enable_osmesa" = xyes; then
 782     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 783 fi
 784
 785 AC_SUBST([SRC_DIRS])
 786 AC_SUBST([DRIVER_DIRS])
 787 AC_SUBST([GALLIUM_DIRS])
 788 AC_SUBST([GALLIUM_TARGET_DIRS])
 789 AC_SUBST([GALLIUM_WINSYS_DIRS])
 790 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 791 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 792 AC_SUBST([MESA_LLVM])
 793
 794 # Check for libdrm
 795 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 796                   [have_libdrm=yes], [have_libdrm=no])
 797
 798 if test "x$enable_dri" = xyes; then
 799     # DRI must be shared, I think
 800     if test "$enable_static" = yes; then
 801         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 802     fi
 803
 804     # not a hard requirement as swrast does not depend on it
 805     if test "x$have_libdrm" = xyes; then
 806         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 807     fi
 808 fi
 809
 810 dnl Find out if X is available.
 811 PKG_CHECK_MODULES([X11], [x11])
 812
 813 dnl Try to tell the user that the --x-* options are only used when
 814 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 815 m4_divert_once([HELP_BEGIN],
 816 [These options are only used when the X libraries cannot be found by the
 817 pkg-config utility.])
 818
 819 dnl We need X for xlib and dri, so bomb now if it's not found
 820 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 821     AC_MSG_ERROR([X11 development libraries needed for GLX])
 822 fi
 823
 824 if test "x$enable_glx" = xyes; then
 825     DEFINES="$DEFINES -DUSE_XCB"
 826 fi
 827
 828 dnl Direct rendering or just indirect rendering
 829 case "$host_os" in
 830 gnu*)
 831     dnl Disable by default on GNU/Hurd
 832     driglx_direct_default="no"
 833     ;;
 834 cygwin*)
 835     dnl Disable by default on cygwin
 836     driglx_direct_default="no"
 837     ;;
 838 *)
 839     driglx_direct_default="yes"
 840     ;;
 841 esac
 842 AC_ARG_ENABLE([driglx-direct],
 843     [AS_HELP_STRING([--disable-driglx-direct],
 844         [enable direct rendering in GLX and EGL for DRI \
 845             @<:@default=auto@:>@])],
 846     [driglx_direct="$enableval"],
 847     [driglx_direct="$driglx_direct_default"])
 848
 849 dnl
 850 dnl libGL configuration per driver
 851 dnl
 852 case "x$enable_glx$enable_xlib_glx" in
 853 xyesyes)
 854     # Xlib-based GLX
 855     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 856     GL_PC_REQ_PRIV="x11 xext"
 857     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 858     GL_LIB_DEPS="$XLIBGL_LIBS"
 859     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 860     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 861     ;;
 862 xyesno)
 863     # DRI-based GLX
 864     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 865     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 866     if test x"$driglx_direct" = xyes; then
 867         if test "x$have_libdrm" != xyes; then
 868             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 869         fi
 870         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 871         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 872     fi
 873
 874     # find the DRI deps for libGL
 875     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1"
 876
 877     # add xf86vidmode if available
 878     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 879     if test "$HAVE_XF86VIDMODE" = yes ; then
 880         dri_modules="$dri_modules xxf86vm"
 881     fi
 882
 883     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 884     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 885     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 886     GL_LIB_DEPS="$DRIGL_LIBS"
 887
 888     # need DRM libs, -lpthread, etc.
 889     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 890     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 891     ;;
 892 esac
 893
 894 # This is outside the case (above) so that it is invoked even for non-GLX
 895 # builds.
 896 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 897
 898 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 899 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 900 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 901 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 902
 903 AC_SUBST([GL_LIB_DEPS])
 904 AC_SUBST([GL_PC_REQ_PRIV])
 905 AC_SUBST([GL_PC_LIB_PRIV])
 906 AC_SUBST([GL_PC_CFLAGS])
 907 AC_SUBST([DRI_PC_REQ_PRIV])
 908 AC_SUBST([GLESv1_CM_LIB_DEPS])
 909 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 910 AC_SUBST([GLESv2_LIB_DEPS])
 911 AC_SUBST([GLESv2_PC_LIB_PRIV])
 912
 913 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
 914 AC_SUBST([GLAPI_LIB_DEPS])
 915
 916
 917 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 918 GALLIUM_DRI_LIB_DEPS="\$(TOP)/\$(LIB_DIR)/libdricore${VERSION}.so"
 919
 920 AC_SUBST([HAVE_XF86VIDMODE])
 921
 922 dnl
 923 dnl More GLX setup
 924 dnl
 925 case "x$enable_glx$enable_xlib_glx" in
 926 xyesyes)
 927     DEFINES="$DEFINES -DUSE_XSHM"
 928     ;;
 929 xyesno)
 930     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 931     if test "x$driglx_direct" = xyes; then
 932         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 933     fi
 934     ;;
 935 esac
 936
 937 dnl
 938 dnl TLS detection
 939 dnl
 940
 941 AC_ARG_ENABLE([glx-tls],
 942     [AS_HELP_STRING([--enable-glx-tls],
 943         [enable TLS support in GLX @<:@default=disabled@:>@])],
 944     [GLX_USE_TLS="$enableval"],
 945     [GLX_USE_TLS=no])
 946 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 947
 948 AS_IF([test "x$GLX_USE_TLS" = xyes],
 949       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
 950
 951 dnl
 952 dnl More DRI setup
 953 dnl
 954 dnl Directory for DRI drivers
 955 AC_ARG_WITH([dri-driverdir],
 956     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 957         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 958     [DRI_DRIVER_INSTALL_DIR="$withval"],
 959     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 960 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 961 dnl Extra search path for DRI drivers
 962 AC_ARG_WITH([dri-searchpath],
 963     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 964         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 965     [DRI_DRIVER_SEARCH_DIR="$withval"],
 966     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 967 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 968 dnl Which drivers to build - default is chosen by platform
 969 AC_ARG_WITH([dri-drivers],
 970     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 971         [comma delimited DRI drivers list, e.g.
 972         "swrast,i965,radeon" @<:@default=auto@:>@])],
 973     [with_dri_drivers="$withval"],
 974     [with_dri_drivers=yes])
 975 if test "x$with_dri_drivers" = x; then
 976     with_dri_drivers=no
 977 fi
 978
 979 dnl If $with_dri_drivers is yes, directories will be added through
 980 dnl platform checks
 981 DRI_DIRS=""
 982 case "$with_dri_drivers" in
 983 no) ;;
 984 yes)
 985     # classic DRI drivers require FEATURE_GL to build
 986     if test "x$enable_opengl" = xyes; then
 987         DRI_DIRS="yes"
 988     fi
 989     ;;
 990 *)
 991     # verify the requested driver directories exist
 992     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 993     for driver in $dri_drivers; do
 994         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 995             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 996     done
 997     DRI_DIRS="$dri_drivers"
 998     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 999         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1000     fi
1001     ;;
1002 esac
1003
1004 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1005 if test "x$enable_dri" = xyes; then
1006     # Platform specific settings and drivers to build
1007     case "$host_os" in
1008     linux*)
1009         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1010         DEFINES="$DEFINES -DHAVE_ALIAS"
1011
1012         case "$host_cpu" in
1013         x86_64)
1014             if test "x$DRI_DIRS" = "xyes"; then
1015                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1016             fi
1017             ;;
1018         powerpc*)
1019             # Build only the drivers for cards that exist on PowerPC.
1020             if test "x$DRI_DIRS" = "xyes"; then
1021                 DRI_DIRS="r200 radeon swrast"
1022             fi
1023             ;;
1024         sparc*)
1025             # Build only the drivers for cards that exist on sparc
1026             if test "x$DRI_DIRS" = "xyes"; then
1027                 DRI_DIRS="r200 radeon swrast"
1028             fi
1029             ;;
1030         esac
1031         ;;
1032     freebsd* | dragonfly* | *netbsd*)
1033         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1034         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1035
1036         if test "x$DRI_DIRS" = "xyes"; then
1037             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1038         fi
1039         ;;
1040     gnu*)
1041         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1042         DEFINES="$DEFINES -DHAVE_ALIAS"
1043         ;;
1044     solaris*)
1045         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1046         ;;
1047     cygwin*)
1048         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1049         if test "x$DRI_DIRS" = "xyes"; then
1050             DRI_DIRS="swrast"
1051         fi
1052         ;;
1053     esac
1054
1055     # default drivers
1056     if test "x$DRI_DIRS" = "xyes"; then
1057         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1058     fi
1059
1060     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1061
1062     # Check for expat
1063     if test "x$enable_dri" = xyes; then
1064         EXPAT_INCLUDES=""
1065         EXPAT_LIB=-lexpat
1066         AC_ARG_WITH([expat],
1067             [AS_HELP_STRING([--with-expat=DIR],
1068                 [expat install directory])],[
1069             EXPAT_INCLUDES="-I$withval/include"
1070             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1071             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1072             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1073             ])
1074         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1075         save_LIBS="$LIBS"
1076         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1077             [AC_MSG_ERROR([Expat required for DRI.])])
1078         LIBS="$save_LIBS"
1079     fi
1080
1081     # if we are building any dri driver other than swrast ...
1082     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1083         # ... libdrm is required
1084         if test "x$have_libdrm" != xyes; then
1085             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1086         fi
1087         # ... and build dricommon
1088         HAVE_COMMON_DRI=yes
1089     fi
1090
1091     # put all the necessary libs together
1092     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1093     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1094 fi
1095 AC_SUBST([DRI_DIRS])
1096 AC_SUBST([EXPAT_INCLUDES])
1097 AC_SUBST([DRI_LIB_DEPS])
1098 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1099
1100 case $DRI_DIRS in
1101 *i915*|*i965*)
1102     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1103
1104     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1105         case $d in
1106         i915)
1107             HAVE_I915_DRI=yes;
1108             ;;
1109         i965)
1110             HAVE_I965_DRI=yes;
1111             ;;
1112         esac
1113     done
1114
1115     ;;
1116 esac
1117
1118 case $DRI_DIRS in
1119 *nouveau*)
1120     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1121     HAVE_NOUVEAU_DRI=yes;
1122     ;;
1123 esac
1124
1125 case $DRI_DIRS in
1126 *radeon*|*r200*)
1127     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1128
1129     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1130         case $d in
1131         radeon)
1132             HAVE_RADEON_DRI=yes;
1133             ;;
1134         r200)
1135             HAVE_R200_DRI=yes;
1136             ;;
1137         esac
1138     done
1139
1140     ;;
1141 esac
1142
1143 case $DRI_DIRS in
1144 *swrast*)
1145     HAVE_SWRAST_DRI=yes;
1146     ;;
1147 esac
1148
1149 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1150 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1151 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1152 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1153 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1154 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1155 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1156
1157 dnl
1158 dnl OSMesa configuration
1159 dnl
1160
1161 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1162 AC_ARG_WITH([osmesa-bits],
1163     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1164         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1165     [osmesa_bits="$withval"],
1166     [osmesa_bits=8])
1167 if test "x$osmesa_bits" != x8; then
1168     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1169         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1170         osmesa_bits=8
1171     fi
1172 fi
1173 case "x$osmesa_bits" in
1174 x8)
1175     OSMESA_LIB="${OSMESA_LIB}"
1176     ;;
1177 x16|x32)
1178     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1179     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1180     ;;
1181 *)
1182     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1183     ;;
1184 esac
1185
1186 if test "x$enable_osmesa" = xyes; then
1187     # only link libraries with osmesa if shared
1188     if test "$enable_static" = no; then
1189         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1190     else
1191         OSMESA_LIB_DEPS=""
1192     fi
1193     OSMESA_MESA_DEPS=""
1194     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1195 fi
1196
1197 OSMESA_VERSION=`echo "$VERSION" | $SED 's/\./:/g'`
1198
1199 AC_SUBST([OSMESA_LIB_DEPS])
1200 AC_SUBST([OSMESA_MESA_DEPS])
1201 AC_SUBST([OSMESA_PC_REQ])
1202 AC_SUBST([OSMESA_PC_LIB_PRIV])
1203 AC_SUBST([OSMESA_VERSION])
1204
1205 dnl
1206 dnl gbm configuration
1207 dnl
1208 if test "x$enable_gbm" = xauto; then
1209     case "$with_egl_platforms" in
1210         *drm*)
1211             enable_gbm=yes ;;
1212          *)
1213             enable_gbm=no ;;
1214     esac
1215 fi
1216 if test "x$enable_gbm" = xyes; then
1217     SRC_DIRS="$SRC_DIRS gbm"
1218
1219     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1220                       AC_MSG_ERROR([gbm needs udev]))
1221
1222     if test "x$enable_dri" = xyes; then
1223         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1224         if test "x$enable_shared_glapi" = xno; then
1225             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1226         fi
1227     fi
1228 fi
1229 GBM_PC_REQ_PRIV="libudev"
1230 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1231 AC_SUBST([GBM_PC_REQ_PRIV])
1232 AC_SUBST([GBM_PC_LIB_PRIV])
1233
1234 dnl
1235 dnl EGL configuration
1236 dnl
1237 EGL_CLIENT_APIS=""
1238
1239 if test "x$enable_egl" = xyes; then
1240     SRC_DIRS="$SRC_DIRS egl"
1241     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1242
1243     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1244
1245     if test "$enable_static" != yes; then
1246         # build egl_glx when libGL is built
1247         if test "x$enable_glx" = xyes; then
1248             HAVE_EGL_DRIVER_GLX=1
1249         fi
1250
1251         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1252                           [have_libudev=yes],[have_libudev=no])
1253         if test "$have_libudev" = yes; then
1254             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1255         fi
1256
1257         if test "x$enable_dri" = xyes; then
1258             HAVE_EGL_DRIVER_DRI2=1
1259         fi
1260
1261     fi
1262 fi
1263 AC_SUBST([EGL_LIB_DEPS])
1264
1265 dnl
1266 dnl EGL Gallium configuration
1267 dnl
1268 if test "x$enable_gallium_egl" = xyes; then
1269     if test "x$with_gallium_drivers" = x; then
1270         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1271     fi
1272     if test "x$enable_egl" = xno; then
1273         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1274     fi
1275     if test "x$have_libdrm" != xyes; then
1276         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1277     fi
1278
1279     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1280     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1281     HAVE_ST_EGL="yes"
1282 fi
1283
1284 dnl
1285 dnl gbm Gallium configuration
1286 dnl
1287 if test "x$enable_gallium_gbm" = xauto; then
1288     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1289         yesyesyes*drm*)
1290             enable_gallium_gbm=yes ;;
1291          *)
1292             enable_gallium_gbm=no ;;
1293     esac
1294 fi
1295 if test "x$enable_gallium_gbm" = xyes; then
1296     if test "x$with_gallium_drivers" = x; then
1297         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1298     fi
1299     if test "x$enable_gbm" = xno; then
1300         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1301     fi
1302     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1303     if test "x$enable_dri" = xno; then
1304         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1305     fi
1306
1307     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1308     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1309     HAVE_ST_GBM="yes"
1310     enable_gallium_loader=yes
1311 fi
1312
1313 dnl
1314 dnl X.Org DDX configuration
1315 dnl
1316 if test "x$enable_xorg" = xyes; then
1317     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1318     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1319     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1320     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1321         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1322         HAVE_XEXTPROTO_71="no")
1323     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1324     HAVE_ST_XORG=yes
1325 fi
1326
1327 dnl
1328 dnl XA configuration
1329 dnl
1330 if test "x$enable_xa" = xyes; then
1331 AC_PROG_AWK
1332 AC_PROG_GREP
1333 AC_CHECK_PROG(NM, nm, "nm")
1334 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1335 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1336 enable_xa=no
1337 fi
1338 fi
1339 if test "x$enable_xa" = xyes; then
1340     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1341     HAVE_ST_XA=yes
1342     AC_SUBST(AWK)
1343     AC_SUBST(GREP)
1344     AC_SUBST(NM)
1345 fi
1346
1347 dnl
1348 dnl OpenVG configuration
1349 dnl
1350 VG_LIB_DEPS=""
1351
1352 if test "x$enable_openvg" = xyes; then
1353     if test "x$enable_egl" = xno; then
1354         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1355     fi
1356     if test "x$with_gallium_drivers" = x; then
1357         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1358     fi
1359     if test "x$enable_gallium_egl" = xno; then
1360         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1361     fi
1362
1363     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1364     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1365     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1366     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1367     HAVE_ST_VEGA=yes
1368 fi
1369
1370 dnl
1371 dnl D3D1X configuration
1372 dnl
1373
1374 if test "x$enable_d3d1x" = xyes; then
1375     if test "x$with_gallium_drivers" = x; then
1376         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1377     fi
1378
1379     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1380     HAVE_ST_D3D1X=yes
1381 fi
1382
1383 dnl
1384 dnl Gallium G3DVL configuration
1385 dnl
1386 AC_ARG_ENABLE([gallium-g3dvl],
1387     [AS_HELP_STRING([--enable-gallium-g3dvl],
1388         [build gallium g3dvl @<:@default=disabled@:>@])],
1389     [enable_gallium_g3dvl="$enableval"],
1390     [enable_gallium_g3dvl=no])
1391 if test "x$enable_gallium_g3dvl" = xyes; then
1392     if test "x$with_gallium_drivers" = x; then
1393         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1394     fi
1395
1396     if test "x$enable_xvmc" = xauto; then
1397         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1398     fi
1399
1400     if test "x$enable_vdpau" = xauto; then
1401         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1402     fi
1403
1404     if test "x$enable_va" = xauto; then
1405         #don't enable vaapi state tracker even if package exists
1406         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1407         enable_va=no
1408     fi
1409 fi
1410
1411 if test "x$enable_xvmc" = xyes; then
1412     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1413     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1414     HAVE_ST_XVMC="yes"
1415 fi
1416
1417 if test "x$enable_vdpau" = xyes; then
1418     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1419     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1420     HAVE_ST_VDPAU="yes"
1421 fi
1422
1423 if test "x$enable_va" = xyes; then
1424     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1425     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1426     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1427     HAVE_ST_VA="yes"
1428 fi
1429
1430 dnl
1431 dnl OpenCL configuration
1432 dnl
1433
1434 AC_ARG_WITH([libclc-path],
1435    [AS_HELP_STRING([--with-libclc-path],
1436          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1437    [LIBCLC_PATH="$withval"],
1438    [LIBCLC_PATH=""])
1439
1440 AC_ARG_WITH([clang-libdir],
1441    [AS_HELP_STRING([--with-clang-libdir],
1442          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1443    [CLANG_LIBDIR="$withval"],
1444    [CLANG_LIBDIR=""])
1445
1446 AC_SUBST([LIBCLC_PATH])
1447
1448 if test "x$enable_opencl" = xyes; then
1449     if test "x$with_gallium_drivers" = x; then
1450         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1451     fi
1452
1453     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1454         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1455     fi
1456
1457     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1458     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1459     enable_gallium_loader=yes
1460 fi
1461
1462 dnl
1463 dnl GLU configuration
1464 dnl
1465 AC_ARG_ENABLE([glu],
1466     [AS_HELP_STRING([--disable-glu],
1467         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1468     [enable_glu="$enableval"],
1469     [enable_glu=yes])
1470
1471 if test "x$enable_glu" = xyes; then
1472     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1473         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1474         enable_glu=no
1475     fi
1476 fi
1477
1478 if test "x$enable_glu" = xyes; then
1479     SRC_DIRS="$SRC_DIRS glu"
1480
1481     if test "x$enable_glx" = xno; then
1482         # Link libGLU to libOSMesa instead of libGL
1483         GLU_LIB_DEPS=""
1484         GLU_PC_REQ="osmesa"
1485         if test "$enable_static" = no; then
1486             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1487         else
1488             GLU_MESA_DEPS=""
1489         fi
1490     else
1491         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1492         GLU_PC_REQ="gl"
1493         GLU_PC_LIB_PRIV="-lm"
1494         if test "$enable_static" = no; then
1495             GLU_LIB_DEPS="-lm"
1496             GLU_MESA_DEPS='-l$(GL_LIB)'
1497         else
1498             GLU_LIB_DEPS=""
1499             GLU_MESA_DEPS=""
1500         fi
1501     fi
1502 fi
1503 if test "$enable_static" = no; then
1504     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1505 fi
1506 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1507 AC_SUBST([GLU_LIB_DEPS])
1508 AC_SUBST([GLU_MESA_DEPS])
1509 AC_SUBST([GLU_PC_REQ])
1510 AC_SUBST([GLU_PC_REQ_PRIV])
1511 AC_SUBST([GLU_PC_LIB_PRIV])
1512 AC_SUBST([GLU_PC_CFLAGS])
1513
1514 AC_SUBST([PROGRAM_DIRS])
1515
1516 dnl
1517 dnl Gallium configuration
1518 dnl
1519 if test "x$with_gallium_drivers" != x; then
1520     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1521 fi
1522 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1523
1524 AC_SUBST([LLVM_BINDIR])
1525 AC_SUBST([LLVM_CFLAGS])
1526 AC_SUBST([LLVM_CPPFLAGS])
1527 AC_SUBST([LLVM_CXXFLAGS])
1528 AC_SUBST([LLVM_LIBDIR])
1529 AC_SUBST([LLVM_LIBS])
1530 AC_SUBST([LLVM_LDFLAGS])
1531 AC_SUBST([LLVM_INCLUDEDIR])
1532 AC_SUBST([LLVM_VERSION])
1533 AC_SUBST([CLANG_RESOURCE_DIR])
1534
1535 case "x$enable_opengl$enable_gles1$enable_gles2" in
1536 x*yes*)
1537     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1538     ;;
1539 esac
1540
1541 AC_SUBST([VG_LIB_DEPS])
1542 AC_SUBST([EGL_CLIENT_APIS])
1543
1544 dnl
1545 dnl EGL Platforms configuration
1546 dnl
1547 AC_ARG_WITH([egl-platforms],
1548     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1549         [comma delimited native platforms libEGL supports, e.g.
1550         "x11,drm" @<:@default=auto@:>@])],
1551     [with_egl_platforms="$withval"],
1552     [if test "x$enable_egl" = xyes; then
1553         with_egl_platforms="x11"
1554     else
1555         with_egl_platforms=""
1556     fi])
1557
1558 EGL_PLATFORMS=""
1559
1560 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1561     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1562 fi
1563
1564 # Do per-EGL platform setups and checks
1565 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1566 for plat in $egl_platforms; do
1567         case "$plat" in
1568         fbdev|null)
1569                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1570                 ;;
1571
1572         wayland)
1573                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1574                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1575                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1576
1577                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1578                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1579                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1580                 ;;
1581
1582         x11)
1583                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1584                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1585                 save_LIBS="$LIBS"
1586                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1587                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1588                 LIBS="$save_LIBS"
1589                 ;;
1590
1591         drm)
1592                 test "x$enable_gbm" = "xno" &&
1593                         AC_MSG_ERROR([EGL platform drm needs gbm])
1594                 ;;
1595
1596         android|gdi)
1597                 ;;
1598
1599         *)
1600                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1601                 ;;
1602         esac
1603
1604         case "$plat$have_libudev" in
1605                 waylandno|drmno)
1606                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1607         esac
1608 done
1609
1610 # libEGL wants to default to the first platform specified in
1611 # ./configure.  parse that here.
1612 if test "x$egl_platforms" != "x"; then
1613     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1614     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1615 else
1616     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1617 fi
1618
1619 EGL_PLATFORMS="$egl_platforms"
1620
1621 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1622 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1623 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1624 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1625 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1626
1627 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1628 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1629
1630 AC_SUBST([EGL_NATIVE_PLATFORM])
1631 AC_SUBST([EGL_PLATFORMS])
1632 AC_SUBST([EGL_CFLAGS])
1633
1634 AC_ARG_WITH([egl-driver-dir],
1635     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1636                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1637     [EGL_DRIVER_INSTALL_DIR="$withval"],
1638     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1639 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1640
1641 AC_ARG_WITH([xorg-driver-dir],
1642     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1643                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1644     [XORG_DRIVER_INSTALL_DIR="$withval"],
1645     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1646 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1647
1648 AC_ARG_WITH([max-width],
1649     [AS_HELP_STRING([--with-max-width=N],
1650                     [Maximum framebuffer width (4096)])],
1651     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1652      AS_IF([test "${withval}" -gt "4096"],
1653            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1654 )
1655 AC_ARG_WITH([max-height],
1656     [AS_HELP_STRING([--with-max-height=N],
1657                     [Maximum framebuffer height (4096)])],
1658     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1659      AS_IF([test "${withval}" -gt "4096"],
1660            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1661 )
1662
1663 dnl
1664 dnl Gallium LLVM
1665 dnl
1666 AC_ARG_ENABLE([gallium-llvm],
1667     [AS_HELP_STRING([--enable-gallium-llvm],
1668         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1669     [enable_gallium_llvm="$enableval"],
1670     [enable_gallium_llvm=auto])
1671
1672 AC_ARG_WITH([llvm-shared-libs],
1673     [AS_HELP_STRING([--with-llvm-shared-libs],
1674         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1675     [with_llvm_shared_libs=yes],
1676     [with_llvm_shared_libs=no])
1677
1678 AC_ARG_WITH([llvm-prefix],
1679     [AS_HELP_STRING([--with-llvm-prefix],
1680         [Prefix for LLVM installations in non-standard locations])],
1681     [llvm_prefix="$withval"],
1682     [llvm_prefix=""])
1683
1684
1685 if test "x$with_gallium_drivers" = x; then
1686     enable_gallium_llvm=no
1687 fi
1688 if test "x$enable_gallium_llvm" = xauto; then
1689     case "$host_cpu" in
1690     i*86|x86_64) enable_gallium_llvm=yes;;
1691     esac
1692 fi
1693 if test "x$enable_gallium_llvm" = xyes; then
1694     if test "x$llvm_prefix" != x; then
1695         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1696     else
1697         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1698     fi
1699
1700     if test "x$LLVM_CONFIG" != xno; then
1701         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1702         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1703         if test "x$with_llvm_shared_libs" = xyes; then
1704             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1705             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1706         else
1707             LLVM_COMPONENTS="engine bitwriter"
1708             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1709                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1710             fi
1711             if test "x$enable_opencl" = xyes; then
1712                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1713             fi
1714             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1715         fi
1716         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1717         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1718         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1719         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1720         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1721         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1722         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1723         MESA_LLVM=1
1724
1725         dnl Check for Clang interanl headers
1726         if test "x$enable_opencl" = xyes; then
1727             if test "x$CLANG_LIBDIR" = x; then
1728                 CLANG_LIBDIR=${LLVM_LIBDIR}
1729             fi
1730             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1731             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1732                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1733         fi
1734     else
1735         MESA_LLVM=0
1736     fi
1737 else
1738     MESA_LLVM=0
1739 fi
1740
1741 dnl Directory for XVMC libs
1742 AC_ARG_WITH([xvmc-libdir],
1743     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1744         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1745     [XVMC_LIB_INSTALL_DIR="$withval"],
1746     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1747 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1748
1749 dnl
1750 dnl Gallium Tests
1751 dnl
1752 if test "x$enable_gallium_tests" = xyes; then
1753     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1754     enable_gallium_loader=yes
1755 fi
1756
1757 dnl Directory for VDPAU libs
1758 AC_ARG_WITH([vdpau-libdir],
1759     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1760         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1761     [VDPAU_LIB_INSTALL_DIR="$withval"],
1762     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1763 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1764
1765 dnl Directory for VA libs
1766 AC_ARG_WITH([va-libdir],
1767     [AS_HELP_STRING([--with-va-libdir=DIR],
1768         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1769     [VA_LIB_INSTALL_DIR="$withval"],
1770     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1771 AC_SUBST([VA_LIB_INSTALL_DIR])
1772
1773 dnl Directory for OpenCL libs
1774 AC_ARG_WITH([opencl-libdir],
1775     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1776         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1777     [OPENCL_LIB_INSTALL_DIR="$withval"],
1778     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1779 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1780
1781 dnl
1782 dnl Gallium helper functions
1783 dnl
1784 gallium_check_st() {
1785     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1786          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1787          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1788          if test "x$have_libdrm" != xyes; then
1789             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1790          fi
1791          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1792     fi
1793     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1794          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1795     fi
1796     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1797          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1798     fi
1799     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1800          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1801     fi
1802     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1803          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1804     fi
1805     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1806          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1807     fi
1808     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1809          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1810     fi
1811 }
1812
1813 gallium_require_llvm() {
1814     if test "x$MESA_LLVM" = x0; then
1815         case "$host_cpu" in
1816         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1817         esac
1818     fi
1819 }
1820
1821 gallium_require_drm_loader() {
1822     if test "x$enable_gallium_loader" = xyes; then
1823         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1824                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1825         if test "x$have_libdrm" != xyes; then
1826             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1827         fi
1828         enable_gallium_drm_loader=yes
1829     fi
1830 }
1831
1832 dnl Gallium drivers
1833 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1834 if test "x$with_gallium_drivers" != x; then
1835     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1836     for driver in $gallium_drivers; do
1837         case "x$driver" in
1838         xsvga)
1839             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1840             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1841             ;;
1842         xi915)
1843             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1844             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1845             if test "x$MESA_LLVM" = x1; then
1846                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1847             fi
1848             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1849             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1850             ;;
1851         xr300)
1852             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1853             gallium_require_llvm "Gallium R300"
1854             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1855             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1856             ;;
1857         xr600)
1858             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1859             gallium_require_drm_loader
1860             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1861             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1862                 if test "x$LLVM_VERSION" != "x3.1"; then
1863                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1864                 fi
1865                 NEED_RADEON_GALLIUM=yes;
1866             fi
1867             if test "x$enable_r600_llvm" = xyes; then
1868                 USE_R600_LLVM_COMPILER=yes;
1869             fi
1870             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1871                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1872             fi
1873             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1874             ;;
1875         xradeonsi)
1876             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1877             gallium_require_drm_loader
1878             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1879             if test "x$LLVM_VERSION" != "x3.1"; then
1880                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1881             fi
1882             NEED_RADEON_GALLIUM=yes;
1883             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1884             ;;
1885         xnouveau)
1886             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1887             gallium_require_drm_loader
1888             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1889             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1890             ;;
1891         xswrast)
1892             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1893             if test "x$MESA_LLVM" = x1; then
1894                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1895             fi
1896
1897             if test "x$HAVE_ST_DRI" = xyes; then
1898                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1899             fi
1900             if test "x$HAVE_ST_VDPAU" = xyes; then
1901                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1902             fi
1903             if test "x$HAVE_ST_XVMC" = xyes; then
1904                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1905             fi
1906             if test "x$HAVE_ST_VA" = xyes; then
1907                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1908             fi
1909             if test "x$HAVE_ST_VDPAU" = xyes ||
1910                test "x$HAVE_ST_XVMC" = xyes ||
1911                test "x$HAVE_ST_VA" = xyes; then
1912                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1913                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1914                fi
1915             fi
1916             ;;
1917         *)
1918             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1919             ;;
1920         esac
1921     done
1922 fi
1923
1924 if test "x$enable_gallium_loader" = xyes; then
1925     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1926     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1927     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1928     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1929
1930     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1931         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1932         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1933     fi
1934
1935     if test "x$enable_gallium_drm_loader" = xyes; then
1936         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1937         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1938                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1939         if test "x$pipe_loader_have_xcb" = xyes; then
1940             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1941             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1942         fi
1943     fi
1944
1945     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1946     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1947 fi
1948
1949 dnl Tell Automake which drivers to build
1950 for driver in $GALLIUM_DRIVERS_DIRS; do
1951     case "x$driver" in
1952         xgalahad)
1953             HAVE_GALAHAD_GALLIUM=yes;
1954             ;;
1955         xidentity)
1956             HAVE_IDENTITY_GALLIUM=yes;
1957             ;;
1958         xnoop)
1959             HAVE_NOOP_GALLIUM=yes;
1960             ;;
1961         *)
1962             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1963             ;;
1964     esac
1965 done
1966
1967 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1968 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1969 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1970 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1971 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1972 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1973 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1974 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1975 AC_SUBST([GALLIUM_MAKE_DIRS])
1976
1977 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
1978
1979 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1980 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1981 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1982
1983 dnl prepend CORE_DIRS to SRC_DIRS
1984 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1985
1986 dnl Restore LDFLAGS and CPPFLAGS
1987 LDFLAGS="$_SAVE_LDFLAGS"
1988 CPPFLAGS="$_SAVE_CPPFLAGS"
1989
1990 dnl Add user CFLAGS and CXXFLAGS
1991 CFLAGS="$CFLAGS $USER_CFLAGS"
1992 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1993
1994 dnl Substitute the config
1995 AC_CONFIG_FILES([configs/current
1996                 Makefile
1997                 src/Makefile
1998                 src/gallium/Makefile
1999                 src/gallium/auxiliary/pipe-loader/Makefile
2000                 src/gallium/state_trackers/clover/Makefile
2001                 src/gallium/drivers/Makefile
2002                 src/gallium/drivers/r300/Makefile
2003                 src/gallium/drivers/r600/Makefile
2004                 src/gallium/targets/opencl/Makefile
2005                 src/gbm/Makefile
2006                 src/gbm/main/gbm.pc
2007                 src/egl/drivers/Makefile
2008                 src/egl/drivers/dri2/Makefile
2009                 src/egl/drivers/glx/Makefile
2010                 src/egl/Makefile
2011                 src/egl/main/Makefile
2012                 src/egl/main/egl.pc
2013                 src/egl/wayland/Makefile
2014                 src/egl/wayland/wayland-egl/Makefile
2015                 src/egl/wayland/wayland-egl/wayland-egl.pc
2016                 src/egl/wayland/wayland-drm/Makefile
2017                 src/glsl/Makefile
2018                 src/glsl/glcpp/Makefile
2019                 src/glsl/tests/Makefile
2020                 src/glx/Makefile
2021                 src/glx/tests/Makefile
2022                 src/mapi/es1api/Makefile
2023                 src/mapi/es1api/glesv1_cm.pc
2024                 src/mapi/es2api/Makefile
2025                 src/mapi/es2api/glesv2.pc
2026                 src/mapi/glapi/Makefile
2027                 src/mapi/glapi/gen/Makefile
2028                 src/mapi/shared-glapi/Makefile
2029                 src/mapi/glapi/tests/Makefile
2030                 src/mapi/shared-glapi/tests/Makefile
2031                 src/gtest/Makefile
2032                 src/mesa/Makefile
2033                 src/mesa/libdricore/Makefile
2034                 src/mesa/main/tests/Makefile
2035                 src/mesa/x86/Makefile
2036                 src/mesa/x86-64/Makefile
2037                 src/mesa/drivers/Makefile
2038                 src/mesa/drivers/dri/dri.pc
2039                 src/mesa/drivers/dri/Makefile
2040                 src/mesa/drivers/dri/common/Makefile
2041                 src/mesa/drivers/dri/i915/Makefile
2042                 src/mesa/drivers/dri/i965/Makefile
2043                 src/mesa/drivers/dri/nouveau/Makefile
2044                 src/mesa/drivers/dri/r200/Makefile
2045                 src/mesa/drivers/dri/radeon/Makefile
2046                 src/mesa/drivers/dri/swrast/Makefile
2047                 src/mesa/drivers/osmesa/Makefile
2048                 src/mesa/drivers/x11/Makefile
2049                 src/mesa/gl.pc
2050                 src/mesa/drivers/osmesa/osmesa.pc])
2051
2052 dnl Sort the dirs alphabetically
2053 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2054 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2055 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2056 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2057 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2058
2059 AC_OUTPUT
2060
2061 dnl
2062 dnl Output some configuration info for the user
2063 dnl
2064 echo ""
2065 echo "        prefix:          $prefix"
2066 echo "        exec_prefix:     $exec_prefix"
2067 echo "        libdir:          $libdir"
2068 echo "        includedir:      $includedir"
2069
2070 dnl API info
2071 echo ""
2072 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2073 echo "        OpenVG:          $enable_openvg"
2074
2075 dnl Driver info
2076 echo ""
2077 if test "x$enable_osmesa" != xno; then
2078         echo "        OSMesa:          lib$OSMESA_LIB"
2079 else
2080         echo "        OSMesa:          no"
2081 fi
2082
2083 if test "x$enable_dri" != xno; then
2084         # cleanup the drivers var
2085         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2086         if test "x$DRI_DIRS" = x; then
2087             echo "        DRI drivers:     no"
2088         else
2089             echo "        DRI drivers:     $dri_dirs"
2090         fi
2091         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2092 fi
2093
2094 case "x$enable_glx$enable_xlib_glx" in
2095 xyesyes)
2096     echo "        GLX:             Xlib-based"
2097     ;;
2098 xyesno)
2099     echo "        GLX:             DRI-based"
2100     ;;
2101 *)
2102     echo "        GLX:             $enable_glx"
2103     ;;
2104 esac
2105
2106 echo ""
2107 echo "        GLU:             $enable_glu"
2108
2109 dnl EGL
2110 echo ""
2111 echo "        EGL:             $enable_egl"
2112 if test "$enable_egl" = yes; then
2113     echo "        EGL platforms:   $EGL_PLATFORMS"
2114
2115     egl_drivers=""
2116     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2117         egl_drivers="$egl_drivers builtin:egl_glx"
2118     fi
2119     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2120         egl_drivers="$egl_drivers builtin:egl_dri2"
2121     fi
2122
2123     if test "x$HAVE_ST_EGL" = xyes; then
2124         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2125         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2126     else
2127         echo "        EGL drivers:    $egl_drivers"
2128     fi
2129 fi
2130
2131 echo ""
2132 if test "x$MESA_LLVM" = x1; then
2133     echo "        llvm:            yes"
2134     echo "        llvm-config:     $LLVM_CONFIG"
2135     echo "        llvm-version:    $LLVM_VERSION"
2136 else
2137     echo "        llvm:            no"
2138 fi
2139
2140 echo ""
2141 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2142     echo "        Gallium:         yes"
2143     echo "        Gallium dirs:    $GALLIUM_DIRS"
2144     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2145     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2146     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2147     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2148 else
2149     echo "        Gallium:         no"
2150 fi
2151
2152
2153 dnl Libraries
2154 echo ""
2155 echo "        Shared libs:     $enable_shared"
2156 echo "        Static libs:     $enable_static"
2157 echo "        Shared-glapi:    $enable_shared_glapi"
2158
2159 dnl Compiler options
2160 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2161 cflags=`echo $CFLAGS $PIC_FLAGS | \
2162     $SED 's/^ *//;s/  */ /;s/ *$//'`
2163 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2164     $SED 's/^ *//;s/  */ /;s/ *$//'`
2165 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2166 echo ""
2167 echo "        CFLAGS:          $cflags"
2168 echo "        CXXFLAGS:        $cxxflags"
2169 echo "        Macros:          $defines"
2170 echo ""
2171 echo "        PYTHON2:         $PYTHON2"
2172
2173 echo ""
2174 echo "        Run '${MAKE-make}' to build Mesa"
2175 echo ""