configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.19.3,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 13, 0, 13)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AC_LIBTOOL_WIN32_DLL
  55 AM_PROG_LIBTOOL
  56
  57 dnl *** required versions of GStreamer stuff ***
  58 GST_REQ=0.10.19.1
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.11.5])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 dnl let distro override plugin install helper path
  88 AC_ARG_WITH(install-plugins-helper,
  89   AC_HELP_STRING([--with-install-plugins-helper],
  90     [specify path of helper script to call to install plugins]),
  91   [
  92     case "${withval}" in
  93       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  95       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  96     esac
  97   ],
  98   [
  99     dnl Default value
 100     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 101   ]
 102 )
 103 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 104 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 105     [plugin install helper script])
 106 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 107
 108 AG_GST_ARG_WITH_PLUGINS
 109
 110 AG_GST_ARG_ENABLE_EXTERNAL
 111
 112 AG_GST_ARG_ENABLE_EXPERIMENTAL
 113
 114 dnl *** checks for platform ***
 115
 116 dnl * hardware/architecture *
 117
 118 dnl common/m4/gst-arch.m4
 119 dnl check CPU type
 120 AG_GST_ARCH
 121
 122 dnl check for large file support
 123 dnl affected plugins must include config.h
 124 AC_SYS_LARGEFILE
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130
 131 dnl check if the compiler supports '-c' and '-o' options
 132 AM_PROG_CC_C_O
 133
 134 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 135 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl For interactive UNIX (a Sun thing)
 145 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 146 AC_ISC_POSIX
 147
 148 dnl libm, for sin() etc.
 149 AC_CHECK_LIBM
 150 AC_SUBST(LIBM)
 151
 152 dnl *** checks for header files ***
 153
 154 dnl check if we have ANSI C header files
 155 AC_HEADER_STDC
 156
 157 dnl used in gst/ffmpegcolorspace/mem.c
 158 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 159 AC_CHECK_HEADERS([malloc.h])
 160
 161 dnl used in gst/subparse/gstsubparse.c
 162 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 163 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 164
 165 if test "x$HAVE_REGEX_H" = "xyes"; then
 166   ac_cppflags_save="$CPPFLAGS"
 167   CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 168   AC_COMPILE_IFELSE(
 169     AC_LANG_PROGRAM([
 170 #include <libxml/HTMLparser.h>
 171                      ],[
 172 #ifndef LIBXML_HTML_ENABLED
 173 #error libxml2 has no HTML support
 174 #endif /* LIBXML_HTML_ENABLED */
 175                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 176   CPPFLAGS="$ac_cppflags_save"
 177 else
 178   HAVE_LIBXML_HTML="no"
 179 fi
 180 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 181
 182 dnl used in gst/tcp
 183 AC_CHECK_HEADERS([sys/socket.h],
 184   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 185 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 186
 187 dnl used in gst-libs/gst/rtsp
 188 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 189 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 190   WIN32_LIBS="-lws2_32"
 191   AC_SUBST(WIN32_LIBS)
 192 fi
 193
 194 dnl check for hstrerror, for gst-libs/gst/rtsp
 195 save_libs="$LIBS"
 196 AC_CHECK_FUNC(hstrerror, ,
 197     AC_CHECK_LIB(resolv, hstrerror, ,
 198         [AC_DEFINE(NO_HSTRERROR, 1,
 199              [Define if you have no native hstrerror() function.])]))
 200 HSTRERROR_LIBS=$LIBS
 201 AC_SUBST(HSTRERROR_LIBS)
 202 LIBS="$save_libs"
 203
 204 dnl used in gst-libs/gst/pbutils and associated unit test
 205 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 206
 207 dnl ffmpegcolorspace includes _stdint.h
 208 dnl also, Windows does not have long long
 209 AX_CREATE_STDINT_H
 210
 211 dnl *** checks for functions ***
 212 AC_CHECK_FUNCS([localtime_r gmtime_r])
 213
 214 dnl *** checks for types/defines ***
 215
 216 dnl Check for FIONREAD ioctl declaration
 217 dnl used in gst/tcp
 218 GST_CHECK_FIONREAD
 219
 220 dnl *** checks for structures ***
 221
 222 dnl *** checks for compiler characteristics ***
 223
 224 dnl make sure we can use "inline" from C code
 225 AC_C_INLINE
 226
 227 dnl *** checks for library functions ***
 228
 229 dnl check for fseeko()
 230 AC_FUNC_FSEEKO
 231
 232 dnl Check for fast float to int casting as defined in C99
 233 dnl used in gst-libs/gst/floatcast/floatcast.h
 234 save_libs=$LIBS
 235 LIBS="$LIBS $LIBM"
 236 AC_C99_FUNC_LRINT
 237 AC_C99_FUNC_LRINTF
 238 LIBS=$save_libs
 239
 240 dnl Check for a way to display the function name in debug output
 241 AG_GST_CHECK_FUNCTION
 242
 243 dnl *** checks for dependency libraries ***
 244
 245 dnl GLib is required
 246 AG_GST_GLIB_CHECK([2.12])
 247
 248 dnl liboil is required
 249 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 250 if test "x$HAVE_LIBOIL" != "xyes"; then
 251   AC_ERROR([liboil-0.3.14 or later is required])
 252 fi
 253
 254 dnl checks for gstreamer
 255 dnl uninstalled is selected preferentially -- see pkg-config(1)
 256 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 257 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 258 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 259 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 260 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 261 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 262
 263 dnl Check for documentation xrefs
 264 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 265 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 266 AC_SUBST(GLIB_PREFIX)
 267 AC_SUBST(GST_PREFIX)
 268
 269 dnl GTK is optional and only used in examples
 270 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.12.0, HAVE_GTK=yes, HAVE_GTK=no)
 271 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 272
 273 dnl *** set variables based on configure arguments ***
 274
 275 dnl set license and copyright notice
 276 GST_LICENSE="LGPL"
 277 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 278 AC_SUBST(GST_LICENSE)
 279
 280 dnl set location of plugin directory
 281 AG_GST_SET_PLUGINDIR
 282
 283 dnl define an ERROR_CFLAGS Makefile variable
 284 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 285
 286 dnl define correct level for debugging messages
 287 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 288
 289 dnl used in examples
 290 AG_GST_DEFAULT_ELEMENTS
 291
 292 dnl *** plug-ins to include ***
 293
 294 dnl these are all the gst plug-ins, compilable without additional libs
 295 AG_GST_CHECK_PLUGIN(adder)
 296 AG_GST_CHECK_PLUGIN(audioconvert)
 297 AG_GST_CHECK_PLUGIN(audiorate)
 298 AG_GST_CHECK_PLUGIN(audioresample)
 299 AG_GST_CHECK_PLUGIN(audiotestsrc)
 300 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 301 AG_GST_CHECK_PLUGIN(gdp)
 302 AG_GST_CHECK_PLUGIN(playback)
 303 AG_GST_CHECK_PLUGIN(subparse)
 304 AG_GST_CHECK_PLUGIN(tcp)
 305 AG_GST_CHECK_PLUGIN(typefind)
 306 AG_GST_CHECK_PLUGIN(videotestsrc)
 307 AG_GST_CHECK_PLUGIN(videorate)
 308 AG_GST_CHECK_PLUGIN(videoscale)
 309 AG_GST_CHECK_PLUGIN(volume)
 310
 311 dnl disable plug-ins that require libxml2's HTML support if it is not available
 312 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 313   AG_GST_DISABLE_PLUGIN(subparse)
 314 fi
 315
 316 dnl disable plug-ins that require sys/socket.h if it is not available
 317 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 318   AG_GST_DISABLE_PLUGIN(tcp)
 319 fi
 320
 321 dnl *** sys plug-ins ***
 322
 323 echo
 324 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 325 echo
 326
 327 dnl *** X11 ***
 328 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 329 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 330                   [ximagesink], [
 331   AC_PATH_XTRA
 332   ac_cflags_save="$CFLAGS"
 333   ac_cppflags_save="$CPPFLAGS"
 334   CFLAGS="$CFLAGS $X_CFLAGS"
 335   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 336
 337   dnl now try to find the HEADER
 338   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 339
 340   if test "x$HAVE_X" = "xno"
 341   then
 342     AC_MSG_NOTICE([cannot find X11 development files])
 343   else
 344     dnl this is much more than we want
 345     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 346     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 347     dnl it does not add the libs; therefore we add them here
 348     X_LIBS="$X_LIBS -lX11"
 349     AC_SUBST(X_CFLAGS)
 350     AC_SUBST(X_LIBS)
 351   fi
 352   AC_SUBST(HAVE_X)
 353   CFLAGS="$ac_cflags_save"
 354   CPPFLAGS="$ac_cppflags_save"
 355 ])
 356
 357 dnl Check for Xv extension
 358 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 359 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 360                   [xvimagesink], [
 361   AG_GST_CHECK_XV
 362 ])
 363
 364 dnl check for X Shm
 365 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 366 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 367   if test x$HAVE_X = xyes; then
 368     AC_CHECK_LIB(Xext, XShmAttach,
 369                  HAVE_XSHM="yes", HAVE_XSHM="no",
 370                  $X_LIBS)
 371     if test "x$HAVE_XSHM" = "xyes"; then
 372       XSHM_LIBS="-lXext"
 373     else
 374       dnl On AIX, it is in XextSam instead, but we still need -lXext
 375       AC_CHECK_LIB(XextSam, XShmAttach,
 376                    HAVE_XSHM="yes", HAVE_XSHM="no",
 377                    $X_LIBS)
 378       if test "x$HAVE_XSHM" = "xyes"; then
 379         XSHM_LIBS="-lXext -lXextSam"
 380       fi
 381     fi
 382   fi
 383 ], , [
 384   AC_SUBST(HAVE_XSHM)
 385   AC_SUBST(XSHM_LIBS)
 386 ])
 387
 388 dnl v4l/v4l2 checks have been moved down because they require X
 389
 390 dnl *** Video 4 Linux ***
 391 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 392 dnl renamed to GST_V4L in accordance with V4L2 below
 393 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 394 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 395   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 396 #include <sys/types.h>
 397 #define _LINUX_TIME_H
 398 #define __user
 399 #include <linux/videodev.h>
 400   ])
 401
 402   dnl we can build v4l without Xv, but then we won't have XOverlay support
 403   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 404   then
 405     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 406     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 407   fi
 408 ])
 409
 410 dnl *** ext plug-ins ***
 411 dnl keep this list sorted alphabetically !
 412
 413 if test "x$BUILD_EXTERNAL" = "xyes"; then
 414
 415 echo
 416 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 417 echo
 418
 419 dnl *** alsa ***
 420 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 421 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 422   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 423     HAVE_ALSA="yes"
 424     AC_SUBST(ALSA_CFLAGS)
 425     AC_SUBST(ALSA_LIBS)
 426   ], [
 427     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 428   ])
 429 ])
 430
 431 dnl *** CDParanoia ***
 432 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 433 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 434   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 435                       cdda_open, -lm,
 436                       cdda_interface.h,
 437                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 438                       HEADER_DIR="no"
 439                       FOUND_CDPARANOIA="yes")
 440   if test "x$FOUND_CDPARANOIA" != "xyes";
 441   then
 442     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 443                         cdda_open, -lm,
 444                         cdda/cdda_interface.h,
 445                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 446                         HEADER_DIR="yes"
 447                         FOUND_CDPARANOIA="yes")
 448   fi
 449   if test "x$HEADER_DIR" = "xyes";
 450   then
 451     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 452                        defined if cdda headers are in a cdda/ directory)
 453   fi
 454   AC_SUBST(CDPARANOIA_LIBS)
 455 ])
 456 dnl FIXME : add second check somehow if that is necessary
 457 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 458 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 459
 460 dnl *** GNOME VFS ***
 461 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 462 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 463   AG_GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 464 ])
 465
 466 dnl *** libgio ***
 467 USE_GIO=$BUILD_EXPERIMENTAL
 468 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 469 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 470   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, HAVE_GIO="yes", [
 471     HAVE_GIO="no"
 472     AC_MSG_RESULT(no)
 473   ])
 474   AC_SUBST(GIO_CFLAGS)
 475   AC_SUBST(GIO_LIBS)
 476   AC_SUBST(GIO_LDFLAGS)
 477 ])
 478
 479 dnl *** libvisual ***
 480 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 481 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 482   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 483   if test $HAVE_LIBVISUAL = no
 484   then
 485     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 486   fi
 487 ])
 488
 489 dnl *** ogg ***
 490 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 491 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 492   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 493   if test $HAVE_OGG = no
 494   then
 495     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 496     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 497   fi
 498 ])
 499
 500 dnl *** pango ***
 501 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 502 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 503   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 504 ])
 505
 506 dnl *** theora ***
 507 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 508 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 509   dnl this check will work as long as theora uses 1.0.x or similar for the
 510   dnl first post-alpha release and not just 1.0
 511   AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 512 ])
 513
 514 dnl *** vorbis ***
 515 dnl AM_PATH_VORBIS only takes two options
 516 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 517 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 518   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 519   if test $HAVE_VORBIS = no
 520   then
 521     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 522     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 523   fi
 524 ])
 525
 526 if test "x$HAVE_VORBIS" = "xyes"; then
 527   ac_cflags_save="$CFLAGS"
 528   AC_COMPILE_IFELSE(
 529     AC_LANG_PROGRAM([
 530 #include <vorbis/codec.h>
 531                      ],[
 532 vorbis_dsp_state *v;
 533
 534 vorbis_synthesis_restart (v);
 535                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 536   if test "x$HAVE_VSR" = "xyes"; then
 537     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 538                        [defined if vorbis_synthesis_restart is present])
 539   fi
 540   CFLAGS="$ac_cflags_save"
 541 fi
 542
 543 else
 544
 545 dnl not building plugins with external dependencies,
 546 dnl but we still need to set the conditionals
 547 AM_CONDITIONAL(USE_ALSA, false)
 548 AM_CONDITIONAL(USE_CDPARANOIA, false)
 549 AM_CONDITIONAL(USE_GNOME_VFS, false)
 550 AM_CONDITIONAL(USE_GIO, false)
 551 AM_CONDITIONAL(USE_LIBVISUAL, false)
 552 AM_CONDITIONAL(USE_OGG, false)
 553 AM_CONDITIONAL(USE_PANGO, false)
 554 AM_CONDITIONAL(USE_THEORA, false)
 555 AM_CONDITIONAL(USE_VORBIS, false)
 556
 557 fi dnl of EXT plugins
 558
 559 dnl seeking needs freetype, so check for it here
 560 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 561   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 562 ])
 563 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 564 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 565 AC_SUBST(FT2_CFLAGS)
 566 AC_SUBST(FT2_LIBS)
 567
 568 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 569
 570 dnl Overview:
 571 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 572 dnl GST_*:              flags shared by built objects to link against GStreamer
 573 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 574 dnl                          (compare to other modules) or for i18n
 575 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 576 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 577 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 578 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 579
 580 dnl GST_OPTION_CFLAGS
 581 if test "x$USE_DEBUG" = xyes; then
 582    PROFILE_CFLAGS="-g"
 583 fi
 584 AC_SUBST(PROFILE_CFLAGS)
 585
 586 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 587   dnl Define _only_ during CVS (not pre-releases or releases)
 588   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 589 else
 590   DEPRECATED_CFLAGS=""
 591 fi
 592 AC_SUBST(DEPRECATED_CFLAGS)
 593
 594 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 595 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 596 AC_SUBST(GST_OPTION_CFLAGS)
 597
 598 dnl our libraries need to be versioned correctly
 599 AC_SUBST(GST_LT_LDFLAGS)
 600
 601 dnl GST_PLUGINS_BASE_CFLAGS
 602 dnl prefer internal headers to already installed ones
 603 dnl also add builddir include for enumtypes and marshal
 604 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 605 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 606
 607 dnl FIXME: do we want to rename to GST_ALL_* ?
 608 dnl add GST_OPTION_CFLAGS, but overridable
 609 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 610 AC_SUBST(GST_CFLAGS)
 611 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 612 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 613 AC_SUBST(GST_LIBS)
 614
 615 dnl LDFLAGS really should only contain flags, not libs - they get added before
 616 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 617 GST_ALL_LDFLAGS="-no-undefined"
 618 AC_SUBST(GST_ALL_LDFLAGS)
 619
 620 dnl GST_LIB_LDFLAGS
 621 dnl linker flags shared by all libraries
 622 dnl LDFLAGS modifier defining exported symbols from built libraries
 623 dnl (export _gst_foo but not __gst_foo)
 624 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 625 AC_SUBST(GST_LIB_LDFLAGS)
 626
 627 dnl this really should only contain flags, not libs - they get added before
 628 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 629 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 630 AC_SUBST(GST_PLUGIN_LDFLAGS)
 631
 632 dnl *** output files ***
 633
 634 AC_CONFIG_FILES(
 635 Makefile
 636 gst-plugins-base.spec
 637 gst/Makefile
 638 gst/adder/Makefile
 639 gst/audioconvert/Makefile
 640 gst/audiorate/Makefile
 641 gst/audioresample/Makefile
 642 gst/audiotestsrc/Makefile
 643 gst/ffmpegcolorspace/Makefile
 644 gst/gdp/Makefile
 645 gst/playback/Makefile
 646 gst/subparse/Makefile
 647 gst/tcp/Makefile
 648 gst/typefind/Makefile
 649 gst/videotestsrc/Makefile
 650 gst/videorate/Makefile
 651 gst/videoscale/Makefile
 652 gst/volume/Makefile
 653 sys/Makefile
 654 sys/ximage/Makefile
 655 sys/xvimage/Makefile
 656 sys/v4l/Makefile
 657 ext/Makefile
 658 ext/alsa/Makefile
 659 ext/cdparanoia/Makefile
 660 ext/gnomevfs/Makefile
 661 ext/gio/Makefile
 662 ext/libvisual/Makefile
 663 ext/ogg/Makefile
 664 ext/pango/Makefile
 665 ext/theora/Makefile
 666 ext/vorbis/Makefile
 667 gst-libs/Makefile
 668 gst-libs/gst/Makefile
 669 gst-libs/gst/audio/Makefile
 670 gst-libs/gst/cdda/Makefile
 671 gst-libs/gst/fft/Makefile
 672 gst-libs/gst/floatcast/Makefile
 673 gst-libs/gst/interfaces/Makefile
 674 gst-libs/gst/netbuffer/Makefile
 675 gst-libs/gst/riff/Makefile
 676 gst-libs/gst/rtp/Makefile
 677 gst-libs/gst/rtsp/Makefile
 678 gst-libs/gst/sdp/Makefile
 679 gst-libs/gst/tag/Makefile
 680 gst-libs/gst/pbutils/Makefile
 681 gst-libs/gst/video/Makefile
 682 tools/Makefile
 683 win32/common/config.h
 684 pkgconfig/Makefile
 685 pkgconfig/gstreamer-audio.pc
 686 pkgconfig/gstreamer-audio-uninstalled.pc
 687 pkgconfig/gstreamer-cdda.pc
 688 pkgconfig/gstreamer-cdda-uninstalled.pc
 689 pkgconfig/gstreamer-fft.pc
 690 pkgconfig/gstreamer-fft-uninstalled.pc
 691 pkgconfig/gstreamer-floatcast.pc
 692 pkgconfig/gstreamer-floatcast-uninstalled.pc
 693 pkgconfig/gstreamer-interfaces.pc
 694 pkgconfig/gstreamer-interfaces-uninstalled.pc
 695 pkgconfig/gstreamer-netbuffer.pc
 696 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 697 pkgconfig/gstreamer-pbutils.pc
 698 pkgconfig/gstreamer-pbutils-uninstalled.pc
 699 pkgconfig/gstreamer-riff.pc
 700 pkgconfig/gstreamer-riff-uninstalled.pc
 701 pkgconfig/gstreamer-rtp.pc
 702 pkgconfig/gstreamer-rtp-uninstalled.pc
 703 pkgconfig/gstreamer-rtsp.pc
 704 pkgconfig/gstreamer-rtsp-uninstalled.pc
 705 pkgconfig/gstreamer-sdp.pc
 706 pkgconfig/gstreamer-sdp-uninstalled.pc
 707 pkgconfig/gstreamer-tag.pc
 708 pkgconfig/gstreamer-tag-uninstalled.pc
 709 pkgconfig/gstreamer-video.pc
 710 pkgconfig/gstreamer-video-uninstalled.pc
 711 pkgconfig/gstreamer-plugins-base.pc
 712 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 713 tests/Makefile
 714 tests/check/Makefile
 715 tests/examples/Makefile
 716 tests/examples/dynamic/Makefile
 717 tests/examples/seek/Makefile
 718 tests/examples/volume/Makefile
 719 tests/examples/snapshot/Makefile
 720 tests/icles/Makefile
 721 docs/Makefile
 722 docs/design/Makefile
 723 docs/libs/Makefile
 724 docs/plugins/Makefile
 725 docs/version.entities
 726 po/Makefile.in
 727 common/Makefile
 728 common/m4/Makefile
 729 m4/Makefile
 730 )
 731 AC_OUTPUT
 732
 733 AG_GST_OUTPUT_PLUGINS