configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [37])
  34 m4_define([glib_micro_version], [0])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153
 154     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 155     ;;
 156   *)
 157     glib_native_win32=no
 158     glib_pid_type=int
 159     ;;
 160 esac
 161 case $host in
 162   *-*-linux*)
 163     glib_os_linux=yes
 164     ;;
 165 esac
 166
 167 AC_MSG_RESULT([$glib_native_win32])
 168
 169 AC_MSG_CHECKING([for the Android])
 170 case $host in
 171   *android*)
 172     glib_native_android="yes"
 173     ;;
 174   *)
 175     glib_native_android="no"
 176     ;;
 177 esac
 178 AC_MSG_RESULT([$glib_native_android])
 179
 180 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 181
 182 glib_have_carbon=no
 183 AC_MSG_CHECKING([for Mac OS X Carbon support])
 184 AC_TRY_CPP([
 185 #include <Carbon/Carbon.h>
 186 #include <CoreServices/CoreServices.h>
 187 ], glib_have_carbon=yes)
 188
 189 AC_MSG_RESULT([$glib_have_carbon])
 190
 191 glib_have_cocoa=no
 192 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 193 AC_TRY_CPP([
 194 #include <Cocoa/Cocoa.h>
 195 #ifdef GNUSTEP_BASE_VERSION
 196 #error "Detected GNUstep, not Cocoa"
 197 #endif
 198 ], glib_have_cocoa=yes)
 199
 200 AC_MSG_RESULT([$glib_have_cocoa])
 201
 202 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 203 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 204 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 205 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 206 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 207 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 208
 209 AS_IF([test "$glib_native_win32" = "yes"], [
 210   AC_CHECK_TOOL(WINDRES, windres, no)
 211   if test "$WINDRES" = no; then
 212     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 213   fi
 214   AC_CHECK_TOOL(NM, nm, no)
 215   if test "$NM" = no; then
 216     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 217   fi
 218   AC_CHECK_TOOL(RANLIB, ranlib, :)
 219   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 220   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 221 ])
 222 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 223
 224 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 225   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 226   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 227 ])
 228
 229 if test "x$glib_have_cocoa" = "xyes"; then
 230   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 231   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 232 fi
 233
 234 gl_GLIBC21
 235 AS_IF([test "x$GLIBC21" = "xyes"], [
 236   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 237 ])
 238
 239 dnl declare --enable-* args and collect ac_help strings
 240 AC_ARG_ENABLE(debug,
 241               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 242                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 243               enable_debug=glib_debug_default)
 244
 245 AC_ARG_ENABLE(gc_friendly,
 246               [AS_HELP_STRING([--enable-gc-friendly],
 247                               [turn on garbage collector friendliness [default=no]])],,
 248               [enable_gc_friendly=no])
 249 AC_ARG_ENABLE(mem_pools,
 250               [AS_HELP_STRING([--disable-mem-pools],
 251                               [disable all glib memory pools])],,
 252               [disable_mem_pools=no])
 253 AC_ARG_ENABLE(rebuilds,
 254               [AS_HELP_STRING([--disable-rebuilds],
 255                               [disable all source autogeneration rules])],,
 256               [enable_rebuilds=yes])
 257 AC_ARG_ENABLE(modular_tests,
 258               AS_HELP_STRING([--disable-modular-tests],
 259                              [Disable build of test programs (default: no)]),,
 260               [enable_modular_tests=yes])
 261 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 262
 263 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 264 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 265   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 266   AC_MSG_RESULT([yes])
 267 ], [ AC_MSG_RESULT([no]) ])
 268
 269 AC_MSG_CHECKING([whether to disable memory pools])
 270 AS_IF([test "x$disable_mem_pools" = "xno"], [
 271   AC_MSG_RESULT([no])
 272 ], [
 273   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 274   AC_MSG_RESULT([yes])
 275 ])
 276
 277 dnl location to install runtime libraries, e.g. ../../lib to install
 278 dnl to /lib if libdir is /usr/lib
 279 AC_ARG_WITH(runtime-libdir,
 280            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 281                            [install runtime libraries relative to libdir])],
 282            [],
 283            [with_runtime_libdir=""])
 284 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 285 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 286 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 287 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 288 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 289
 290 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 291 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 292 AC_LANG_SAVE
 293 AC_LANG_CPLUSPLUS
 294 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 295 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 296 AC_LANG_RESTORE
 297
 298 AM_PROG_CC_C_O
 299 AC_PROG_INSTALL
 300
 301 AC_SYS_LARGEFILE
 302
 303 PKG_PROG_PKG_CONFIG(0.16)
 304
 305 if test "x$enable_debug" = "xyes"; then
 306   if test x$cflags_set != xset ; then
 307       case " $CFLAGS " in
 308       *[[\ \    ]]-g[[\ \       ]]*) ;;
 309       *) CFLAGS="$CFLAGS -g" ;;
 310       esac
 311   fi
 312   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 313 else
 314   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 315
 316   if test "x$enable_debug" = "xno"; then
 317     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 318   fi
 319 fi
 320
 321 # Ensure MSVC-compatible struct packing convention is used when
 322 # compiling for Win32 with gcc.
 323 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 324 # gcc2 uses "-fnative-struct".
 325 if test x"$glib_native_win32" = xyes; then
 326   if test x"$GCC" = xyes; then
 327     msnative_struct=''
 328     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 329     if test -z "$ac_cv_prog_CC"; then
 330       our_gcc="$CC"
 331     else
 332       our_gcc="$ac_cv_prog_CC"
 333     fi
 334     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 335       2.)
 336         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 337           msnative_struct='-fnative-struct'
 338         fi
 339         ;;
 340       *)
 341         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 342           msnative_struct='-mms-bitfields'
 343         fi
 344         ;;
 345     esac
 346     if test x"$msnative_struct" = x ; then
 347       AC_MSG_RESULT([no way])
 348       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 349     else
 350       CFLAGS="$CFLAGS $msnative_struct"
 351       AC_MSG_RESULT([${msnative_struct}])
 352     fi
 353   fi
 354 fi
 355 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 356 AC_SUBST(GLIB_EXTRA_CFLAGS)
 357
 358 AC_EXEEXT
 359
 360 # define a MAINT-like variable REBUILD which is set if Perl
 361 # and awk are found, so autogenerated sources can be rebuilt
 362 AC_PROG_AWK
 363 AC_CHECK_PROGS(PERL, [perl5 perl])
 364 # We would like indent, but don't require it.
 365 AC_CHECK_PROG(INDENT, indent, indent)
 366 REBUILD=\#
 367 if test "x$enable_rebuilds" = "xyes" && \
 368      test -n "$PERL" && \
 369      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 370      test -n "$AWK" ; then
 371   REBUILD=
 372 fi
 373 AC_SUBST(REBUILD)
 374
 375 # Need full path to Perl for glib-mkenums
 376 #
 377 if test "x$PERL" != x ; then
 378   AC_PATH_PROG(PERL_PATH, [$PERL])
 379 fi
 380 if test "x$PERL_PATH" = x ; then
 381   PERL_PATH="/usr/bin/env perl"
 382 fi
 383 AC_SUBST(PERL_PATH)
 384
 385 # option to specify python interpreter to use; this just sets $PYTHON, so that
 386 # we will fallback to reading $PYTHON if --with-python is not given, and
 387 # python.m4 will get the expected input
 388 AC_ARG_WITH(python,
 389             AS_HELP_STRING([--with-python=PATH],
 390                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 391             [PYTHON="$withval"], [])
 392 if test x"$PYTHON" = xyes; then
 393   AC_MSG_ERROR([--with-python option requires a path or program argument])
 394 fi
 395 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 396
 397
 398 dnl ***********************
 399 dnl *** Tests for iconv ***
 400 dnl ***********************
 401 dnl
 402 dnl We do this before the gettext checks, to avoid distortion
 403
 404 dnl On Windows we use a native implementation
 405
 406 AS_IF([ test x"$glib_native_win32" = xyes], [
 407   with_libiconv=native
 408 ], [
 409   AC_ARG_WITH(libiconv,
 410               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 411                               [use the libiconv library])],,
 412               [with_libiconv=maybe])
 413
 414   found_iconv=no
 415   case $with_libiconv in
 416     maybe)
 417       # Check in the C library first
 418       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 419       # Check if we have GNU libiconv
 420       if test $found_iconv = "no"; then
 421         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 422       fi
 423       # Check if we have a iconv in -liconv, possibly from vendor
 424       if test $found_iconv = "no"; then
 425         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 426       fi
 427       ;;
 428     no)
 429       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 430       ;;
 431     gnu|yes)
 432       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 433       ;;
 434     native)
 435       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 436       ;;
 437   esac
 438
 439   if test "x$found_iconv" = "xno" ; then
 440      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 441   fi
 442 ])
 443
 444 AC_ARG_ENABLE(iconv-cache,
 445               [AS_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 446                               [cache iconv descriptors [default=auto]])],,
 447               [enable_iconv_cache=auto])
 448
 449 AC_MSG_CHECKING([whether to cache iconv descriptors])
 450 case $enable_iconv_cache in
 451   auto)
 452     if test $ac_cv_gnu_library_2_1 = yes; then
 453       enable_iconv_cache=no
 454     else
 455       enable_iconv_cache=yes
 456     fi
 457   ;;
 458   yes|no)
 459   ;;
 460   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 461   ;;
 462 esac
 463
 464 if test $enable_iconv_cache = yes; then
 465    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 466 fi
 467
 468 AC_MSG_RESULT($enable_iconv_cache)
 469
 470
 471 dnl
 472 dnl zlib support
 473 dnl
 474 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 475 AS_IF([test "x$found_zlib" = "xno"], [
 476   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 477   if test "x$found_zlib" = "xno" ; then
 478     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 479   fi
 480   ZLIB_LIBS='-lz'
 481   AC_SUBST(ZLIB_LIBS)
 482 ])
 483
 484 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 485 AC_SUBST(LIBFFI_CFLAGS)
 486 AC_SUBST(LIBFFI_LIBS)
 487
 488 dnl
 489 dnl gettext support
 490 dnl
 491
 492 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 493 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 494 GLIB_GNU_GETTEXT
 495
 496 if test "$gt_cv_have_gettext" != "yes" ; then
 497   AC_MSG_ERROR([
 498 *** You must have either have gettext support in your C library, or use the
 499 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 500 ])
 501 fi
 502
 503 LIBS="$INTLLIBS $LIBS"
 504
 505 GETTEXT_PACKAGE=glib20
 506 AC_SUBST(GETTEXT_PACKAGE)
 507 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 508   [Define the gettext package to be used])
 509
 510 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 511
 512 dnl
 513 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 514 dnl
 515
 516 AS_IF([test x"$glib_native_win32" != xyes], [
 517   if test x$with_libiconv != xno ; then
 518     case " $INTLLIBS " in
 519     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 520     *) ICONV_LIBS="-liconv" ;;
 521     esac
 522   fi
 523 ])
 524 AC_SUBST(ICONV_LIBS)
 525
 526 case $with_libiconv in
 527   gnu)
 528     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 529     ;;
 530   native)
 531     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 532     ;;
 533 esac
 534
 535 dnl Initialize libtool
 536 LT_PREREQ([2.2])
 537 LT_INIT([disable-static win32-dll])
 538 dnl when using libtool 2.x create libtool early, because it's used in configure
 539 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 540
 541
 542 AS_IF([test "$glib_native_win32" = "yes"], [
 543   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 544     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 545   fi
 546   if test x$enable_static = xyes; then
 547     glib_win32_static_compilation=yes
 548     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 549 #define GOBJECT_STATIC_COMPILATION 1"
 550     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 551   fi
 552 ])
 553 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 554
 555 dnl
 556 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 557 dnl
 558 AS_IF([test $cross_compiling != yes], [
 559     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 560     glib_save_LIBS=$LIBS
 561     LIBS="$LIBS -lm"
 562     AC_TRY_RUN([#include <math.h>
 563                  int main (void) { return (log(1) != log(1.)); }],
 564          AC_MSG_RESULT(none needed),
 565          glib_save_CFLAGS=$CFLAGS
 566          CFLAGS="$CFLAGS -std1"
 567          AC_TRY_RUN([#include <math.h>
 568                      int main (void) { return (log(1) != log(1.)); }],
 569              AC_MSG_RESULT(-std1),
 570              AC_MSG_RESULT()
 571              CFLAGS=$glib_save_CFLAGS
 572              AC_MSG_WARN(
 573                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 574          )
 575     )
 576     LIBS=$glib_save_LIBS
 577 ])
 578
 579 dnl NeXTStep cc seems to need this
 580 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 581 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 582   AC_MSG_RESULT(none needed),
 583   glib_save_CFLAGS=$CFLAGS
 584   CFLAGS="$CFLAGS -posix"
 585   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 586     AC_MSG_RESULT(-posix),
 587     AC_MSG_RESULT()
 588     CFLAGS=$glib_save_CFLAGS
 589     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 590
 591 # Checks for library functions.
 592 AC_FUNC_VPRINTF
 593 AC_FUNC_ALLOCA
 594 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 595 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 596
 597 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 598   [AC_TRY_LINK([#include <unistd.h>
 599     extern int __libc_enable_secure;],
 600     [return __libc_enable_secure;],
 601    glib_cv_have_libc_enable_secure=yes,
 602    glib_cv_have_libc_enable_secure=no)])
 603 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 604    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 605      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 606 ])
 607
 608 AC_CHECK_SIZEOF(char)
 609 AC_CHECK_SIZEOF(short)
 610 AC_CHECK_SIZEOF(long)
 611 AC_CHECK_SIZEOF(int)
 612 AC_CHECK_SIZEOF(void *)
 613 AC_CHECK_SIZEOF(long long)
 614 AC_CHECK_SIZEOF(__int64)
 615
 616 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 617   [AC_TRY_LINK([#include <signal.h>
 618      #include <sys/types.h>
 619      sig_atomic_t val = 42;],
 620     [return val == 42 ? 0 : 1],
 621    ac_cv_type_sig_atomic_t=yes,
 622    ac_cv_type_sig_atomic_t=no)])
 623 if test x$ac_cv_type_sig_atomic_t = xyes; then
 624    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 625      [Define if you have the 'sig_atomic_t' type.])
 626 fi
 627
 628 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 629   :
 630 else
 631   AC_MSG_ERROR([
 632 *** GLib requires a 64 bit type. You might want to consider
 633 *** using the GNU C compiler.
 634 ])
 635 fi
 636
 637 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 638         # long long is a 64 bit integer.
 639         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 640         AC_CACHE_VAL(glib_cv_long_long_format,[
 641                 for format in ll q I64; do
 642                   AC_TRY_RUN([#include <stdio.h>
 643                         int main()
 644                         {
 645                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 646                           char buffer[1000];
 647                           sprintf (buffer, "%${format}u", a);
 648                           sscanf (buffer, "%${format}u", &b);
 649                           exit (b!=a);
 650                         }
 651                         ],
 652                         [glib_cv_long_long_format=${format}
 653                         break],
 654                         [],[:])
 655                 done])
 656         AS_IF([ test -n "$glib_cv_long_long_format"], [
 657           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 658           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 659           if test x"$glib_cv_long_long_format" = xI64; then
 660             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 661           fi
 662         ], [AC_MSG_RESULT(none)])
 663 ],[ test x$ac_cv_sizeof___int64 = x8], [
 664         # __int64 is a 64 bit integer.
 665         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 666         # We know this is MSVCRT.DLL, and what the formats are
 667         glib_cv_long_long_format=I64
 668         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 669         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 670         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 671 ])
 672
 673 AC_C_CONST
 674
 675 dnl ok, here we try to check whether the systems prototypes for
 676 dnl malloc and friends actually match the prototypes provided
 677 dnl by gmem.h (keep in sync). i currently only know how to check
 678 dnl this reliably with gcc (-Werror), improvements for other
 679 dnl compilers are apprechiated.
 680 SANE_MALLOC_PROTOS=no
 681 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 682 glib_save_CFLAGS=$CFLAGS
 683 AS_IF([test "x$GCC" = "xyes"], [
 684   CFLAGS="$CFLAGS -Werror"
 685   AC_TRY_COMPILE([#include <stdlib.h>], [
 686     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 687     void* (*my_malloc_p)  (size_t)         = malloc;
 688     void  (*my_free_p)    (void*)          = free;
 689     void* (*my_realloc_p) (void*, size_t)  = realloc;
 690     my_calloc_p = 0;
 691     my_malloc_p = 0;
 692     my_free_p = 0;
 693     my_realloc_p = 0;
 694   ],
 695     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 696       [Define if you have correct malloc prototypes])
 697     SANE_MALLOC_PROTOS=yes)
 698 ])
 699 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 700 CFLAGS=$glib_save_CFLAGS
 701
 702 dnl
 703 dnl check in which direction the stack grows
 704 dnl
 705 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 706         AC_TRY_RUN([
 707         volatile int *a = 0, *b = 0;
 708         void foo (void);
 709         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 710         void foo (void) { volatile int x = 5; b = &x; }
 711         ],
 712         glib_cv_stack_grows=no
 713         ,
 714         glib_cv_stack_grows=yes
 715         ,)
 716 ])
 717
 718 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 719 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 720 dnl actually supported.
 721 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 722         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 723         __inline int foo () { return 0; }
 724         int main () { return foo (); }
 725         ]])],
 726         glib_cv_has__inline=yes
 727         ,
 728         glib_cv_has__inline=no
 729         ,)
 730 ])
 731 case x$glib_cv_has__inline in
 732 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 733 esac
 734 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 735         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 736         __inline__ int foo () { return 0; }
 737         int main () { return foo (); }
 738         ]])],
 739         glib_cv_has__inline__=yes
 740         ,
 741         glib_cv_has__inline__=no
 742         ,)
 743 ])
 744 case x$glib_cv_has__inline__ in
 745 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 746 esac
 747 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 748         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 749         #undef inline
 750         inline int foo () { return 0; }
 751         int main () { return foo (); }
 752         ]])],
 753         glib_cv_hasinline=yes
 754         ,
 755         glib_cv_hasinline=no
 756         ,)
 757 ])
 758 case x$glib_cv_hasinline in
 759 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 760 esac
 761
 762 # if we can use inline functions in headers
 763 AC_MSG_CHECKING(if inline functions in headers work)
 764 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 765 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 766 #  undef inline
 767 #  define inline __inline__
 768 #elif !defined (G_HAVE_INLINE)
 769 #  undef inline
 770 #  if defined (G_HAVE___INLINE__)
 771 #    define inline __inline__
 772 #  elif defined (G_HAVE___INLINE)
 773 #    define inline __inline
 774 #  endif
 775 #endif
 776
 777 int glib_test_func2 (int);
 778
 779 static inline int
 780 glib_test_func1 (void) {
 781   return glib_test_func2 (1);
 782 }
 783
 784 int
 785 main (void) {
 786   int i = 1;
 787 }]])],[g_can_inline=yes],[g_can_inline=no])
 788 AC_MSG_RESULT($g_can_inline)
 789
 790 dnl *** check for working do while(0) macros ***
 791 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 792         AC_TRY_COMPILE([],[
 793         #define STMT_START do
 794         #define STMT_END while(0)
 795         #define STMT_TEST STMT_START { i = 0; } STMT_END
 796         int main(void) { int i = 1; STMT_TEST; return i; }],
 797         [g_cv_support_dowhile_macros=yes],
 798         [g_cv_support_dowhile_macros=no],
 799         [g_cv_support_dowhile_macros=yes])
 800 ])
 801 if test x$g_cv_support_dowhile_macros = xyes; then
 802   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 803 fi
 804
 805 # check for flavours of varargs macros
 806 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 807 AC_TRY_COMPILE([],[
 808 int a(int p1, int p2, int p3);
 809 #define call_a(...) a(1,__VA_ARGS__)
 810 call_a(2,3);
 811 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 812 AC_MSG_RESULT($g_have_iso_c_varargs)
 813
 814 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 815 AS_IF([test "$CXX" = ""], [
 816 dnl No C++ compiler
 817   g_have_iso_cxx_varargs=no
 818 else
 819   AC_LANG_CPLUSPLUS
 820   AC_TRY_COMPILE([],[
 821 int a(int p1, int p2, int p3);
 822 #define call_a(...) a(1,__VA_ARGS__)
 823 call_a(2,3);
 824 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 825   AC_LANG_C
 826 ])
 827 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 828
 829 AC_MSG_CHECKING(for GNUC varargs macros)
 830 AC_TRY_COMPILE([],[
 831 int a(int p1, int p2, int p3);
 832 #define call_a(params...) a(1,params)
 833 call_a(2,3);
 834 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 835 AC_MSG_RESULT($g_have_gnuc_varargs)
 836
 837 # check for GNUC visibility support
 838 AC_MSG_CHECKING(for GNUC visibility attribute)
 839 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 840 void
 841 __attribute__ ((visibility ("hidden")))
 842      f_hidden (void)
 843 {
 844 }
 845 void
 846 __attribute__ ((visibility ("internal")))
 847      f_internal (void)
 848 {
 849 }
 850 void
 851 __attribute__ ((visibility ("protected")))
 852      f_protected (void)
 853 {
 854 }
 855 void
 856 __attribute__ ((visibility ("default")))
 857      f_default (void)
 858 {
 859 }
 860 int main (void)
 861 {
 862         f_hidden();
 863         f_internal();
 864         f_protected();
 865         f_default();
 866         return 0;
 867 }
 868 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 869 AC_MSG_RESULT($g_have_gnuc_visibility)
 870 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 871
 872 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 873 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 874 #else
 875 # include "error: this is not Sun Studio."
 876 #endif
 877 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 878 AC_MSG_RESULT($g_have_sunstudio_visibility)
 879 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 880
 881 # check for bytesex stuff
 882 AC_C_BIGENDIAN
 883 if test x$ac_cv_c_bigendian = xuniversal ; then
 884 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 885 #else
 886 #error Not a big endian.
 887 #endif],
 888     ac_cv_c_bigendian=yes
 889     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 890 #else
 891 #error Not a little endian.
 892 #endif],
 893     ac_cv_c_bigendian=no
 894     ,AC_MSG_WARN([Could not determine endianness.])))
 895 fi
 896
 897
 898 # check for header files
 899 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 900 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 901 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 902 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 903 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 904 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 905 AC_CHECK_HEADERS([linux/magic.h])
 906 AC_CHECK_HEADERS([sys/prctl.h])
 907
 908 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 909 [#if HAVE_SYS_PARAM_H
 910  #include <sys/param.h>
 911  #endif
 912 ])
 913 AC_CHECK_FUNCS(sysctlbyname)
 914
 915 AC_CHECK_HEADERS([xlocale.h])
 916
 917 # check for structure fields
 918 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 919 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 920 #include <sys/stat.h>
 921 #include <unistd.h>
 922 #ifdef HAVE_SYS_STATFS_H
 923 #include <sys/statfs.h>
 924 #endif
 925 #ifdef HAVE_SYS_PARAM_H
 926 #include <sys/param.h>
 927 #endif
 928 #ifdef HAVE_SYS_MOUNT_H
 929 #include <sys/mount.h>
 930 #endif])
 931 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 932 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 933 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 934 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 935
 936 AC_STRUCT_DIRENT_D_TYPE
 937
 938 # Checks for libcharset
 939 AM_LANGINFO_CODESET
 940 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 941 AC_CHECK_FUNCS(setlocale)
 942
 943 # check additional type sizes
 944 AC_CHECK_SIZEOF(size_t)
 945
 946 dnl Try to figure out whether gsize should be long or int
 947 AC_MSG_CHECKING([for the appropriate definition for size_t])
 948
 949 case $ac_cv_sizeof_size_t in
 950   $ac_cv_sizeof_short)
 951       glib_size_type=short
 952       ;;
 953   $ac_cv_sizeof_int)
 954       glib_size_type=int
 955       ;;
 956   $ac_cv_sizeof_long)
 957       glib_size_type=long
 958       ;;
 959   $ac_cv_sizeof_long_long)
 960       glib_size_type='long long'
 961       ;;
 962   $ac_cv_sizeof__int64)
 963       glib_size_type='__int64'
 964       ;;
 965   *)  AC_MSG_ERROR([No type matching size_t in size])
 966       ;;
 967 esac
 968
 969 dnl If int/long are the same size, we see which one produces
 970 dnl warnings when used in the location as size_t. (This matters
 971 dnl on AIX with xlc)
 972 dnl
 973 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 974        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 975   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 976 #if defined(_AIX) && !defined(__GNUC__)
 977 #pragma options langlvl=stdc89
 978 #endif
 979 #include <stddef.h>
 980 int main ()
 981 {
 982   size_t s = 1;
 983   unsigned int *size_int = &s;
 984   return (int)*size_int;
 985 }
 986     ]])],glib_size_type=int,
 987       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 988 #if defined(_AIX) && !defined(__GNUC__)
 989 #pragma options langlvl=stdc89
 990 #endif
 991 #include <stddef.h>
 992 int main ()
 993 {
 994    size_t s = 1;
 995    unsigned long *size_long = &s;
 996    return (int)*size_long;
 997 }
 998         ]])],glib_size_type=long)])
 999 ])
1000
1001 AC_MSG_RESULT(unsigned $glib_size_type)
1002
1003 AC_CHECK_SIZEOF(ssize_t)
1004
1005 dnl Try to figure out whether gssize should be long or int
1006 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
1007
1008 case $ac_cv_sizeof_ssize_t in
1009   $ac_cv_sizeof_short)
1010       glib_ssize_type=short
1011       ;;
1012   $ac_cv_sizeof_int)
1013       glib_ssize_type=int
1014       ;;
1015   $ac_cv_sizeof_long)
1016       glib_ssize_type=long
1017       ;;
1018   $ac_cv_sizeof_long_long)
1019       glib_ssize_type='long long'
1020       ;;
1021   $ac_cv_sizeof__int64)
1022       glib_ssize_type='__int64'
1023       ;;
1024   *)  AC_MSG_ERROR([No type matching ssize_t in size])
1025       ;;
1026 esac
1027
1028 dnl If int/long are the same size, we see which one produces
1029 dnl warnings when used in the location as ssize_t. (This matters
1030 dnl on Android where ssize_t is long and size_t is unsigned int)
1031 dnl
1032 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
1033        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
1034   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
1035 #if defined(_AIX) && !defined(__GNUC__)
1036 #pragma options langlvl=stdc89
1037 #endif
1038 #include <stddef.h>
1039 #ifdef HAVE_INTTYPES_H
1040 # include <inttypes.h>
1041 #endif
1042 #ifdef HAVE_STDINT_H
1043 # include <stdint.h>
1044 #endif
1045 #ifdef HAVE_UNISTD_H
1046 # include <unistd.h>
1047 #endif
1048 #ifdef HAVE_SYS_TYPES_H
1049 # include <sys/types.h>
1050 #endif
1051 int main ()
1052 {
1053   ssize_t s = 1;
1054   int *size_int = &s;
1055   return (int)*size_int;
1056 }
1057     ]])],glib_ssize_type=int,
1058       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
1059 #if defined(_AIX) && !defined(__GNUC__)
1060 #pragma options langlvl=stdc89
1061 #endif
1062 #include <stddef.h>
1063 #ifdef HAVE_INTTYPES_H
1064 # include <inttypes.h>
1065 #endif
1066 #ifdef HAVE_STDINT_H
1067 # include <stdint.h>
1068 #endif
1069 #ifdef HAVE_UNISTD_H
1070 # include <unistd.h>
1071 #endif
1072 #ifdef HAVE_SYS_TYPES_H
1073 # include <sys/types.h>
1074 #endif
1075 int main ()
1076 {
1077    ssize_t s = 1;
1078    long *size_long = &s;
1079    return (int)*size_long;
1080 }
1081         ]])],glib_ssize_type=long)])
1082 ])
1083
1084 AC_MSG_RESULT($glib_ssize_type)
1085
1086 # Check for some functions
1087 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1088 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
1089 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1090 # Check for high-resolution sleep functions
1091 AC_CHECK_FUNCS(splice)
1092 AC_CHECK_FUNCS(prlimit)
1093
1094 # To avoid finding a compatibility unusable statfs, which typically
1095 # successfully compiles, but warns to use the newer statvfs interface:
1096 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1097 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1098
1099 AC_MSG_CHECKING([whether to use statfs or statvfs])
1100 # Some systems have both statfs and statvfs, pick the most "native" for these
1101 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1102    [
1103    # on solaris and irix, statfs doesn't even have the f_bavail field
1104    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1105       [ac_cv_func_statfs=no],
1106    # else, at least on linux, statfs is the actual syscall
1107       [ac_cv_func_statvfs=no])
1108    ])
1109
1110 AS_IF([test x$ac_cv_func_statfs = xyes],
1111       [
1112          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1113          AC_MSG_RESULT([statfs])
1114       ],
1115       [test x$ac_cv_func_statvfs = xyes],
1116       [
1117          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1118          AC_MSG_RESULT([statvfs])
1119       ],
1120       [  AC_MSG_RESULT([neither])])
1121
1122 AC_CHECK_HEADERS(crt_externs.h)
1123 AC_CHECK_FUNCS(_NSGetEnviron)
1124
1125 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1126
1127 AC_FUNC_VSNPRINTF_C99
1128 AC_FUNC_PRINTF_UNIX98
1129
1130 # Internet address families
1131 if test $glib_native_win32 = yes; then
1132   glib_inet_includes=["
1133 #include <winsock2.h>
1134   "]
1135 else
1136   glib_inet_includes=["
1137 #include <sys/types.h>
1138 #include <sys/socket.h>
1139   "]
1140 fi
1141
1142 glib_failed=false
1143 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1144 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1145 # winsock defines this even though it doesn't support it
1146 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1147 if $glib_failed ; then
1148   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1149 fi
1150
1151 glib_failed=false
1152 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1153 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1154 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1155 if $glib_failed ; then
1156   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1157 fi
1158
1159 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1160
1161 AS_IF([test $glib_native_win32 = yes], [
1162   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1163   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1164   # they aren't present at run-time (on Windows 2000).
1165   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1166   AC_SUBST(WSPIAPI_INCLUDE)
1167 ], [
1168   # Android does not have C_IN in public headers, we define it wherever necessary
1169   AS_IF([test $glib_native_android != yes], [
1170     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1171     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1172                                         #include <arpa/nameser.h>],
1173                                        [int qclass = C_IN;])],
1174                       [AC_MSG_RESULT([no])],
1175                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1176                                                            #include <arpa/nameser.h>
1177                                                            #include <arpa/nameser_compat.h>],
1178                                                           [int qclass = C_IN;])],
1179                                          [AC_MSG_RESULT([yes])
1180                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1181                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1182   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1183
1184   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1185   NETWORK_LIBS=""
1186   AC_MSG_CHECKING([for res_query])
1187   AC_TRY_LINK([#include <sys/types.h>
1188                #include <netinet/in.h>
1189                #include <arpa/nameser.h>
1190                #include <resolv.h>
1191               ],[
1192                res_query("test", 0, 0, (void *)0, 0);
1193               ],[AC_MSG_RESULT([yes])],
1194               [save_libs="$LIBS"
1195                LIBS="-lresolv $LIBS"
1196                AC_TRY_LINK([#include <sys/types.h>
1197                             #include <netinet/in.h>
1198                             #include <arpa/nameser.h>
1199                             #include <resolv.h>
1200                            ],[
1201                             res_query("test", 0, 0, (void *)0, 0);
1202                            ],[AC_MSG_RESULT([in -lresolv])
1203                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1204                            [LIBS="-lbind $save_libs"
1205                             AC_TRY_LINK([#include <resolv.h>],
1206                                         [res_query("test", 0, 0, (void *)0, 0);],
1207                                         [AC_MSG_RESULT([in -lbind])
1208                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1209                                         [AC_MSG_ERROR(not found)])])
1210                LIBS="$save_libs"])
1211   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1212                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1213                                         [AC_MSG_ERROR(Could not find socket())]))
1214   save_libs="$LIBS"
1215   LIBS="$LIBS $NETWORK_LIBS"
1216   AC_MSG_CHECKING([for res_init])
1217   AC_TRY_LINK([#include <sys/types.h>
1218                #include <netinet/in.h>
1219                #include <arpa/nameser.h>
1220                #include <resolv.h>
1221               ],[
1222                res_init();
1223               ],[AC_MSG_RESULT([yes])
1224                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1225               ],[AC_MSG_RESULT([no])])
1226   LIBS="$save_libs"
1227 ])
1228 AC_SUBST(NETWORK_LIBS)
1229
1230 AC_CHECK_HEADER([linux/netlink.h],
1231                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1232                 [#include <sys/socket.h>])
1233 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1234
1235 AC_CHECK_TYPE([struct ip_mreqn], [
1236               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1237               [#include <netinet/in.h>])
1238
1239 case $host in
1240   *-*-solaris* )
1241      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1242      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1243      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1244      ;;
1245 esac
1246
1247 dnl
1248 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1249 dnl
1250 AS_IF([test "$ac_cv_func_statfs" = yes], [
1251   AC_MSG_CHECKING([number of arguments to statfs()])
1252   AC_TRY_COMPILE([#include <unistd.h>
1253   #ifdef HAVE_SYS_PARAM_H
1254   #include <sys/param.h>
1255   #endif
1256   #ifdef HAVE_SYS_VFS_H
1257   #include <sys/vfs.h>
1258   #endif
1259   #ifdef HAVE_SYS_MOUNT_H
1260   #include <sys/mount.h>
1261   #endif
1262   #ifdef HAVE_SYS_STATFS_H
1263   #include <sys/statfs.h>
1264   #endif], [struct statfs st;
1265   statfs(NULL, &st);],[
1266     AC_MSG_RESULT([2])
1267     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1268     AC_TRY_COMPILE([#include <unistd.h>
1269   #ifdef HAVE_SYS_PARAM_H
1270   #include <sys/param.h>
1271   #endif
1272   #ifdef HAVE_SYS_VFS_H
1273   #include <sys/vfs.h>
1274   #endif
1275   #ifdef HAVE_SYS_MOUNT_H
1276   #include <sys/mount.h>
1277   #endif
1278   #ifdef HAVE_SYS_STATFS_H
1279   #include <sys/statfs.h>
1280   #endif], [struct statfs st;
1281   statfs(NULL, &st, sizeof (st), 0);],[
1282       AC_MSG_RESULT([4])
1283       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1284       AC_MSG_RESULT(unknown)
1285       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1286 ])
1287
1288 #
1289 # Check whether to use an included printf
1290 #
1291
1292 AC_ARG_ENABLE(included-printf,
1293               [AS_HELP_STRING([--enable-included-printf],
1294                               [use included printf [default=auto]])],
1295               enable_included_printf="$enableval")
1296
1297 need_included_printf=no
1298 if test "x$enable_included_printf" = "xyes" ; then
1299   need_included_printf=yes
1300 fi
1301 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1302   need_included_printf=yes
1303 fi
1304 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1305   need_included_printf=yes
1306 fi
1307 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1308    test -z "$glib_cv_long_long_format" ; then
1309   need_included_printf=yes
1310 fi
1311
1312 if test "x$enable_included_printf" = "xno" &&
1313    test "x$need_included_printf" = "xyes" ; then
1314   AC_MSG_ERROR([
1315 *** Your C library's printf doesn't appear to have the features that
1316 *** GLib needs, but you specified --enable-included-printf=no.])
1317 fi
1318
1319 enable_included_printf=$need_included_printf
1320
1321 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1322 AS_IF([test "$enable_included_printf" != "yes"], [
1323   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1324 ], [
1325   if test -z "$glib_cv_long_long_format" ; then
1326     glib_cv_long_long_format="ll"
1327   fi
1328   AC_DEFINE(HAVE_VASPRINTF,1)
1329 ])
1330
1331 # Checks needed for gnulib vasnprintf
1332 bh_C_SIGNED
1333 jm_AC_TYPE_LONG_LONG
1334 gt_TYPE_LONGDOUBLE
1335 gt_TYPE_WCHAR_T
1336 gt_TYPE_WINT_T
1337 AC_TYPE_SIZE_T
1338 AC_CHECK_TYPES(ptrdiff_t)
1339 jm_AC_TYPE_INTMAX_T
1340 AC_CHECK_FUNCS([snprintf wcslen])
1341 AC_FUNC_SNPRINTF_C99
1342
1343 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1344 # The check is borrowed from the PERL Configure script.
1345 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1346   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1347     glib_cv_working_bcopy,[AC_TRY_RUN([
1348       int main() {
1349         char buf[128], abc[128], *b;
1350         int len, off, align;
1351         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1352         for (align = 7; align >= 0; align--) {
1353           for (len = 36; len; len--) {
1354             b = buf+align; bcopy(abc, b, len);
1355             for (off = 1; off <= len; off++) {
1356               bcopy(b, b+off, len); bcopy(b+off, b, len);
1357                 if (bcmp(b, abc, len)) return(1);
1358             }
1359           }
1360         }
1361         return(0);
1362       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1363
1364   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1365   if test "$glib_cv_working_bcopy" = "yes"; then
1366     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1367   fi
1368 ])
1369
1370 # Check if <sys/select.h> needs to be included for fd_set
1371 AC_MSG_CHECKING([for fd_set])
1372 AC_TRY_COMPILE([#include <sys/types.h>],
1373         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1374 AS_IF([test "$gtk_ok" = "yes"], [
1375     AC_MSG_RESULT([yes, found in sys/types.h])
1376 ], [
1377     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1378     if test "$gtk_ok" = "yes"; then
1379         # *** FIXME: give it a different name
1380         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1381         AC_MSG_RESULT([yes, found in sys/select.h])
1382     else
1383         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1384         AC_MSG_RESULT(no)
1385     fi
1386 ])
1387
1388 dnl *** check for sane realloc() ***
1389 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1390         AC_TRY_RUN([#include <stdlib.h>
1391         int main() {
1392           return realloc (0, sizeof (int)) == 0;
1393         }],
1394         [glib_cv_sane_realloc=yes],
1395         [glib_cv_sane_realloc=no],
1396         [glib_cv_sane_realloc=yes])
1397 ])
1398 AS_IF([test x$glib_cv_sane_realloc = xyes], [
1399   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1400 ])
1401
1402 dnl Check for nl_langinfo and CODESET
1403 AC_LANG_SAVE
1404 AC_LANG_C
1405 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1406         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1407                        [char *codeset = nl_langinfo (CODESET);])],
1408                 [glib_cv_langinfo_codeset=yes],
1409                 [glib_cv_langinfo_codeset=no])])
1410 if test x$glib_cv_langinfo_codeset = xyes; then
1411   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1412 fi
1413
1414 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1415 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1416         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1417                  [char *str;
1418                  str = nl_langinfo (PM_STR);
1419                  str = nl_langinfo (D_T_FMT);
1420                  str = nl_langinfo (D_FMT);
1421                  str = nl_langinfo (T_FMT);
1422                  str = nl_langinfo (T_FMT_AMPM);
1423                  str = nl_langinfo (MON_1);
1424                  str = nl_langinfo (ABMON_12);
1425                  str = nl_langinfo (DAY_1);
1426                  str = nl_langinfo (ABDAY_7);])],
1427                 [glib_cv_langinfo_time=yes],
1428                 [glib_cv_langinfo_time=no])])
1429 if test x$glib_cv_langinfo_time = xyes; then
1430   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1431 fi
1432
1433 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1434 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1435         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1436                 [char *str;
1437                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1438                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1439                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1440                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1441                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1442                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1443                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1444                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1445                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1446                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1447                 [glib_cv_langinfo_outdigit=yes],
1448                 [glib_cv_langinfo_outdigit=no])])
1449 if test x$glib_cv_langinfo_outdigit = xyes; then
1450   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1451 fi
1452 AC_LANG_RESTORE
1453
1454 dnl ****************************************
1455 dnl *** posix_memalign                   ***
1456 dnl ****************************************
1457 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1458 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1459     glib_cv_compliant_posix_memalign=0
1460     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1461         AC_TRY_RUN([
1462                 #define _XOPEN_SOURCE 600
1463                 #include <stdlib.h> /* posix_memalign() should be defined here */
1464                 /* some systems break if #include <malloc.h> used */
1465                 static void test_memalign (size_t boundary, size_t size) {
1466                     void *mem = 0;
1467                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1468                         exit (1);
1469                     else
1470                       free (mem);
1471                 }
1472                 int main() {
1473                     test_memalign (  128,   128 - 2 * sizeof (void*));
1474                     test_memalign (  256,   256 - 2 * sizeof (void*));
1475                     test_memalign (  512,   512 - 2 * sizeof (void*));
1476                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1477                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1478                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1479                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1480                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1481                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1482                     exit (0); /* success */
1483                 }
1484                 ],
1485             [glib_cv_compliant_posix_memalign=1], [], [:])
1486       :
1487     fi
1488     ])
1489 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1490     AC_MSG_RESULT(yes)
1491     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1492 ], [
1493     AC_MSG_RESULT(no)
1494 ])
1495
1496
1497 dnl ****************************************
1498 dnl *** strlcpy/strlcat                  ***
1499 dnl ****************************************
1500 # Check for strlcpy
1501 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1502 AC_TRY_RUN([#include <stdlib.h>
1503 #include <string.h>
1504 int main() {
1505   char p[10];
1506   (void) strlcpy (p, "hi", 10);
1507   if (strlcat (p, "bye", 0) != 3)
1508     return 1;
1509   return 0;
1510 }], glib_cv_have_strlcpy=yes,
1511     glib_cv_have_strlcpy=no,
1512     glib_cv_have_strlcpy=no)])
1513 if test "$glib_cv_have_strlcpy" = "yes"; then
1514     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1515 fi
1516
1517
1518 dnl **********************
1519 dnl *** va_copy checks ***
1520 dnl **********************
1521 dnl we currently check for all three va_copy possibilities, so we get
1522 dnl all results in config.log for bug reports.
1523 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1524         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1525 #include <stdlib.h>
1526         void f (int i, ...) {
1527         va_list args1, args2;
1528         va_start (args1, i);
1529         va_copy (args2, args1);
1530         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1531           exit (1);
1532         va_end (args1); va_end (args2);
1533         }
1534         int main() {
1535           f (0, 42);
1536           return 0;
1537         }]])],
1538         [glib_cv_va_copy=yes],
1539         [glib_cv_va_copy=no])
1540 ])
1541 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1542         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1543 #include <stdlib.h>
1544         void f (int i, ...) {
1545         va_list args1, args2;
1546         va_start (args1, i);
1547         __va_copy (args2, args1);
1548         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1549           exit (1);
1550         va_end (args1); va_end (args2);
1551         }
1552         int main() {
1553           f (0, 42);
1554           return 0;
1555         }]])],
1556         [glib_cv___va_copy=yes],
1557         [glib_cv___va_copy=no])
1558 ])
1559
1560 if test "x$glib_cv_va_copy" = "xyes"; then
1561   g_va_copy_func=va_copy
1562 else if test "x$glib_cv___va_copy" = "xyes"; then
1563   g_va_copy_func=__va_copy
1564 fi
1565 fi
1566
1567 if test -n "$g_va_copy_func"; then
1568   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1569 fi
1570
1571 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1572         AC_TRY_RUN([#include <stdarg.h>
1573 #include <stdlib.h>
1574         void f (int i, ...) {
1575         va_list args1, args2;
1576         va_start (args1, i);
1577         args2 = args1;
1578         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1579           exit (1);
1580         va_end (args1); va_end (args2);
1581         }
1582         int main() {
1583           f (0, 42);
1584           return 0;
1585         }],
1586         [glib_cv_va_val_copy=yes],
1587         [glib_cv_va_val_copy=no],
1588         [glib_cv_va_val_copy=yes])
1589 ])
1590
1591 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1592   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1593 ])
1594
1595 dnl ***********************
1596 dnl *** g_module checks ***
1597 dnl ***********************
1598 G_MODULE_LIBS=
1599 G_MODULE_LIBS_EXTRA=
1600 G_MODULE_PLUGIN_LIBS=
1601 if test x"$glib_native_win32" = xyes; then
1602   dnl No use for this on Win32
1603   G_MODULE_LDFLAGS=
1604 else
1605   export SED
1606   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1607 fi
1608 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1609 G_MODULE_NEED_USCORE=0
1610 G_MODULE_BROKEN_RTLD_GLOBAL=0
1611 G_MODULE_HAVE_DLERROR=0
1612 dnl *** force native WIN32 shared lib loader
1613 if test -z "$G_MODULE_IMPL"; then
1614   case "$host" in
1615   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1616   esac
1617 fi
1618 dnl *** force native AIX library loader
1619 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1620 if test -z "$G_MODULE_IMPL"; then
1621   case "$host" in
1622   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1623   esac
1624 fi
1625 dnl *** dlopen() and dlsym() in system libraries
1626 AS_IF([ test -z "$G_MODULE_IMPL"], [
1627         AC_CHECK_FUNC(dlopen,
1628                       [AC_CHECK_FUNC(dlsym,
1629                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1630                       [])
1631 ])
1632 dnl *** load_image (BeOS)
1633 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1634   AC_CHECK_LIB(root, load_image,
1635       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1636       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1637       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1638       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1639       [])
1640 ])
1641 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1642 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1643         AC_CHECK_FUNC(NSLinkModule,
1644                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1645                        G_MODULE_NEED_USCORE=1],
1646                       [])
1647 ])
1648 dnl *** dlopen() and dlsym() in libdl
1649 AS_IF([ test -z "$G_MODULE_IMPL"], [
1650         AC_CHECK_LIB(dl, dlopen,
1651                      [AC_CHECK_LIB(dl, dlsym,
1652                                    [G_MODULE_LIBS=-ldl
1653                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1654                      [])
1655 ])
1656 dnl *** shl_load() in libdld (HP-UX)
1657 AS_IF([ test -z "$G_MODULE_IMPL"], [
1658         AC_CHECK_LIB(dld, shl_load,
1659                 [G_MODULE_LIBS=-ldld
1660                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1661                 [])
1662 ])
1663 dnl *** additional checks for G_MODULE_IMPL_DL
1664 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1665         LIBS_orig="$LIBS"
1666         LDFLAGS_orig="$LDFLAGS"
1667         LIBS="$G_MODULE_LIBS $LIBS"
1668         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1669 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1670         echo "void glib_plugin_test(void) { }" > plugin.c
1671         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1672                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1673         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1674                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1675                 -shrext ".o" -avoid-version plugin.lo \
1676                 -rpath /dont/care >/dev/null 2>&1
1677         eval `./libtool --config | grep ^objdir`
1678         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1679                 glib_cv_rtldglobal_broken,[
1680                 AC_TRY_RUN([
1681 #include <dlfcn.h>
1682 #ifndef RTLD_GLOBAL
1683 #  define RTLD_GLOBAL 0
1684 #endif
1685 #ifndef RTLD_LAZY
1686 #  define RTLD_LAZY 0
1687 #endif
1688 int glib_plugin_test;
1689 int main () {
1690     void *handle, *global, *local;
1691     global = &glib_plugin_test;
1692     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1693     if (!handle) return 0;
1694     local = dlsym (handle, "glib_plugin_test");
1695     return global == local;
1696 }                       ],
1697                         [glib_cv_rtldglobal_broken=no],
1698                         [glib_cv_rtldglobal_broken=yes],
1699                         [glib_cv_rtldglobal_broken=no])
1700                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1701                 rmdir ${objdir} 2>/dev/null
1702         ])
1703         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1704                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1705         else
1706                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1707         fi
1708 dnl *** check whether we need preceeding underscores
1709         AC_CACHE_CHECK([for preceeding underscore in symbols],
1710                 glib_cv_uscore,[
1711                 AC_TRY_RUN([#include <dlfcn.h>
1712                 int glib_underscore_test (void) { return 42; }
1713                 int main() {
1714                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1715                   handle = dlopen ((void*)0, 0);
1716                   if (handle) {
1717                     f1 = dlsym (handle, "glib_underscore_test");
1718                     f2 = dlsym (handle, "_glib_underscore_test");
1719                   } return (!f2 || f1);
1720                 }],
1721                         [glib_cv_uscore=yes],
1722                         [glib_cv_uscore=no],
1723                         [])
1724                 rm -f plugin.c plugin.$ac_objext plugin.lo
1725         ])
1726         GLIB_ASSERT_SET(glib_cv_uscore)
1727         if test "x$glib_cv_uscore" = "xyes"; then
1728                 G_MODULE_NEED_USCORE=1
1729         else
1730                 G_MODULE_NEED_USCORE=0
1731         fi
1732
1733         LDFLAGS="$LDFLAGS_orig"
1734 dnl *** check for having dlerror()
1735         AC_CHECK_FUNC(dlerror,
1736                 [G_MODULE_HAVE_DLERROR=1],
1737                 [G_MODULE_HAVE_DLERROR=0])
1738         LIBS="$LIBS_orig"
1739 ])
1740 dnl *** done, have we got an implementation?
1741 if test -z "$G_MODULE_IMPL"; then
1742         G_MODULE_IMPL=0
1743         G_MODULE_SUPPORTED=false
1744 else
1745         G_MODULE_SUPPORTED=true
1746 fi
1747
1748 AC_MSG_CHECKING(for the suffix of module shared libraries)
1749 export SED
1750 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1751 eval $shrext_cmds
1752 module=yes eval std_shrext=$shrext_cmds
1753 # chop the initial dot
1754 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1755 AC_MSG_RESULT(.$glib_gmodule_suffix)
1756 # any reason it may fail?
1757 if test "x$glib_gmodule_suffix" = x; then
1758         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1759 fi
1760
1761 AC_SUBST(G_MODULE_SUPPORTED)
1762 AC_SUBST(G_MODULE_IMPL)
1763 AC_SUBST(G_MODULE_LIBS)
1764 AC_SUBST(G_MODULE_LIBS_EXTRA)
1765 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1766 AC_SUBST(G_MODULE_LDFLAGS)
1767 AC_SUBST(G_MODULE_HAVE_DLERROR)
1768 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1769 AC_SUBST(G_MODULE_NEED_USCORE)
1770 AC_SUBST(GLIB_DEBUG_FLAGS)
1771
1772 dnl **********************
1773 dnl *** g_spawn checks ***
1774 dnl **********************
1775
1776 AC_MSG_CHECKING(for gspawn implementation)
1777 case "$host" in
1778   *-*-mingw*)
1779     GSPAWN=gspawn-win32.lo
1780     ;;
1781   *)
1782     GSPAWN=gspawn.lo
1783     ;;
1784 esac
1785 AC_MSG_RESULT($GSPAWN)
1786 AC_SUBST(GSPAWN)
1787
1788 dnl *************************
1789 dnl *** GIOChannel checks ***
1790 dnl *************************
1791
1792 AC_MSG_CHECKING(for GIOChannel implementation)
1793 case "$host" in
1794   *-*-mingw*)
1795     GIO=giowin32.lo
1796     ;;
1797   *)
1798     GIO=giounix.lo
1799     ;;
1800 esac
1801 AC_MSG_RESULT($GIO)
1802 AC_SUBST(GIO)
1803
1804 dnl *********************************
1805 dnl *** Directory for GIO modules ***
1806 dnl *********************************
1807
1808 AC_ARG_WITH(gio-module-dir,
1809            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1810                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1811            [],
1812            [with_gio_module_dir='${libdir}/gio/modules'])
1813 GIO_MODULE_DIR=$with_gio_module_dir
1814 AC_SUBST(GIO_MODULE_DIR)
1815
1816 dnl **********************************
1817 dnl *** Check for libselinux (GIO) ***
1818 dnl **********************************
1819 AC_ARG_ENABLE(selinux,
1820               AS_HELP_STRING([--disable-selinux],
1821                              [build without selinux support]))
1822 msg_selinux=no
1823 SELINUX_LIBS=
1824 AS_IF([ test "x$enable_selinux" != "xno"], [
1825
1826  AC_CHECK_LIB(selinux, is_selinux_enabled,
1827    [AC_CHECK_HEADERS(selinux/selinux.h,
1828      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1829        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1830         SELINUX_LIBS="-lselinux"
1831         msg_selinux=yes])
1832      ])
1833    ])
1834 ])
1835 AC_SUBST(SELINUX_LIBS)
1836
1837 dnl *****************************
1838 dnl ** Check for inotify (GIO) **
1839 dnl *****************************
1840 inotify_support=no
1841 AC_CHECK_HEADERS([sys/inotify.h],
1842 [
1843         inotify_support=yes
1844         AC_CHECK_FUNCS(inotify_init1)
1845 ])
1846
1847 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1848
1849 dnl ****************************
1850 dnl ** Check for kqueue (GIO) **
1851 dnl ****************************
1852 kqueue_support=no
1853 AC_CHECK_HEADERS([sys/event.h],
1854 [
1855         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1856 ])
1857
1858 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1859
1860 dnl *********************************
1861 dnl ** Check for Solaris FEN (GIO) **
1862 dnl *********************************
1863 fen_support=no
1864 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1865 #include <port.h>
1866 #ifndef PORT_SOURCE_FILE
1867 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1868 #endif
1869 int main() { return 0; } ]])],
1870 [
1871         fen_support=yes
1872 ],)
1873
1874 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1875
1876 dnl ****************************
1877 dnl *** Checks for FAM (GIO) ***
1878 dnl ****************************
1879
1880 should_disable_fam=no
1881
1882 AC_ARG_ENABLE(fam,
1883               AS_HELP_STRING([--disable-fam],
1884                              [don't use fam for file system monitoring]),
1885                          [
1886                                 if test "x$enable_fam" = "xno"; then
1887                                         should_disable_fam=yes
1888                                 fi
1889                          ]
1890                          )
1891 fam_support=no
1892 FAM_LIBS=
1893 if test "x$should_disable_fam" = "xno"; then
1894 AC_CHECK_LIB(fam, FAMOpen,
1895   [AC_CHECK_HEADERS(fam.h,
1896     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1897      AC_CHECK_LIB(fam, FAMNoExists,
1898                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1899      FAM_LIBS="-lfam"]
1900      fam_support=yes,
1901     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1902   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1903 AC_SUBST(FAM_LIBS)
1904 fi
1905 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1906
1907
1908 dnl *****************************
1909 dnl *** Check for xattr (GIO) ***
1910 dnl *****************************
1911 AC_ARG_ENABLE(xattr,
1912               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1913 msg_xattr=no
1914 XATTR_LIBS=
1915 AS_IF([ test "x$enable_xattr" != "xno"], [
1916
1917 dnl either glibc or libattr can provide xattr support
1918
1919 dnl for both of them, we check for getxattr being in
1920 dnl the library and a valid xattr header.
1921
1922 dnl try glibc
1923  AC_CHECK_LIB(c, getxattr,
1924    [AC_CHECK_HEADERS(sys/xattr.h,
1925      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1926       msg_xattr=yes])
1927    ])
1928
1929   AS_IF([ test "x$msg_xattr" != "xyes"], [
1930 dnl   failure. try libattr
1931    AC_CHECK_LIB(attr, getxattr,
1932       [AC_CHECK_HEADERS(attr/xattr.h,
1933        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1934         XATTR_LIBS="-lattr"
1935         msg_xattr=yes])
1936       ])
1937   ])
1938
1939   AS_IF([ test "x$msg_xattr" = "xyes"], [
1940     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1941     AC_TRY_COMPILE([
1942       #include <stdio.h>
1943       #ifdef HAVE_SYS_TYPES_H
1944       #include <sys/types.h>
1945       #endif
1946       #ifdef HAVE_SYS_XATTR_H
1947       #include <sys/xattr.h>
1948       #elif HAVE_ATTR_XATTR_H
1949       #include <attr/xattr.h>
1950       #endif
1951     ],
1952     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1953     [
1954       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1955       AC_MSG_RESULT([yes])
1956     ],
1957     [AC_MSG_RESULT([no])]
1958     )
1959   ])
1960 ])
1961 AC_SUBST(XATTR_LIBS)
1962
1963 dnl ************************
1964 dnl *** check for libelf ***
1965 dnl ************************
1966 AC_ARG_ENABLE(libelf,
1967               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1968 AS_IF([ test "x$enable_libelf" != "xno"],[
1969 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1970 AS_IF([ test $have_libelf = maybe ], [
1971   glib_save_LIBS=$LIBS
1972   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1973   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1974   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1975   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1976   LIBS=$glib_save_LIBS
1977
1978   if test $have_libelf != no; then
1979     LIBELF_LIBS=-lelf
1980     have_libelf=yes
1981   fi
1982 ])
1983 ])
1984
1985 if test x$have_libelf = xyes; then
1986   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1987 fi
1988
1989 dnl ****************************************
1990 dnl *** platform dependent source checks ***
1991 dnl ****************************************
1992
1993 AC_MSG_CHECKING(for platform-dependent source)
1994 case "$host" in
1995   *-*-cygwin*|*-*-mingw*)
1996     PLATFORMDEP=gwin32.lo
1997     ;;
1998   *)
1999     PLATFORMDEP=
2000     ;;
2001 esac
2002 AC_MSG_RESULT($PLATFORMDEP)
2003 AC_SUBST(PLATFORMDEP)
2004
2005 AC_MSG_CHECKING([whether to compile timeloop])
2006 case "$host" in
2007   *-*-cygwin*|*-*-mingw*|*-*-minix)
2008     enable_timeloop=no
2009     ;;
2010   *)
2011     enable_timeloop=yes
2012     ;;
2013 esac
2014 AC_MSG_RESULT($enable_timeloop)
2015 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
2016
2017 AC_MSG_CHECKING([if building for some Win32 platform])
2018 case "$host" in
2019   *-*-mingw*|*-*-cygwin*)
2020     platform_win32=yes
2021     ;;
2022   *)
2023     platform_win32=no
2024     ;;
2025 esac
2026 AC_MSG_RESULT($platform_win32)
2027 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
2028
2029 dnl ***********************
2030 dnl *** g_thread checks ***
2031 dnl ***********************
2032
2033 AC_ARG_WITH(threads,
2034            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
2035                            [specify a thread implementation to use])],
2036            [],
2037            [with_threads=yes])
2038
2039 dnl error and warning message
2040 dnl *************************
2041
2042 THREAD_NO_IMPLEMENTATION="No thread implementation found."
2043
2044 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
2045                 platform (normally it's "_REENTRANT"). I'll not use any flag on
2046                 compilation now, but then your programs might not work.
2047                 Please provide information on how it is done on your system."
2048
2049 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
2050                  "
2051
2052 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
2053                   provide information on your thread implementation."
2054
2055 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
2056                 functions will not be MT-safe during their first call because
2057                 there is no working 'getpwuid_r' on your system."
2058
2059 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
2060                 because there is no 'localtime_r' on your system."
2061
2062 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
2063                 linking threaded applications. As GLib cannot do that
2064                 automatically, you will get an linkg error everytime you are
2065                 not using the right compiler. In that case you have to relink
2066                 with the right compiler. Ususally just '_r' is appended
2067                 to the compiler name."
2068
2069 dnl determination of thread implementation
2070 dnl ***************************************
2071
2072 AC_MSG_CHECKING(for thread implementation)
2073
2074 have_threads=no
2075 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
2076         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
2077         # -U_OSF_SOURCE is for Digital UNIX 4.0d
2078         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
2079         glib_save_CPPFLAGS="$CPPFLAGS"
2080         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2081         AS_IF([ test "x$have_threads" = xno], [
2082                 AC_TRY_COMPILE([#include <pthread.h>],
2083                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
2084                         have_threads=posix)
2085         ])
2086         # Tru64Unix requires -pthread to find pthread.h. See #103020
2087         CPPFLAGS="$CPPFLAGS -pthread"
2088         if test "x$have_threads" = xno; then
2089         AC_TRY_COMPILE([#include <pthread.h>],
2090                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
2091                        have_threads=posix)
2092         fi
2093         CPPFLAGS="$glib_save_CPPFLAGS"
2094 ])
2095 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
2096         case $host in
2097                 *-*-mingw*)
2098                 have_threads=win32
2099                 ;;
2100         esac
2101 fi
2102
2103 if test "x$have_threads" = xno; then
2104         AC_MSG_RESULT(none available)
2105         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
2106 else
2107         AC_MSG_RESULT($have_threads)
2108 fi
2109
2110
2111 dnl determination of G_THREAD_CFLAGS
2112 dnl ********************************
2113
2114 G_THREAD_LIBS=
2115 G_THREAD_LIBS_EXTRA=
2116 G_THREAD_CFLAGS=
2117
2118 dnl
2119 dnl Test program for basic POSIX threads functionality
2120 dnl
2121 m4_define([glib_thread_test],[
2122 #include <pthread.h>
2123 int check_me = 0;
2124 void* func(void* data) {check_me = 42; return &check_me;}
2125 int main()
2126  { pthread_t t;
2127    void *ret;
2128    pthread_create (&t, $1, func, 0);
2129    pthread_join (t, &ret);
2130    return (check_me != 42 || ret != &check_me);
2131 }])
2132
2133 AS_IF([ test x"$have_threads" = xposix], [
2134   # First we test for posix, whether -pthread or -pthreads do the trick as
2135   # both CPPFLAG and LIBS.
2136   # One of them does for most gcc versions and some other platforms/compilers
2137   # too and could be considered as the canonical way to go.
2138   case $host in
2139     *-*-cygwin*|*-*-darwin*)
2140        # skip cygwin and darwin -pthread or -pthreads test
2141        ;;
2142     *-solaris*)
2143       # These compiler/linker flags work with both Sun Studio and gcc
2144       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2145       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2146       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2147       G_THREAD_LIBS="-lpthread -lthread"
2148       ;;
2149     *)
2150       for flag in pthread pthreads mt; do
2151         glib_save_CFLAGS="$CFLAGS"
2152         CFLAGS="$CFLAGS -$flag"
2153         AC_TRY_RUN(glib_thread_test(0),
2154                    glib_flag_works=yes,
2155                    glib_flag_works=no,
2156                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2157                                    glib_flag_works=yes,
2158                                    glib_flag_works=no)])
2159         CFLAGS="$glib_save_CFLAGS"
2160         if test $glib_flag_works = yes ; then
2161            G_THREAD_CFLAGS=-$flag
2162         G_THREAD_LIBS=-$flag
2163         break;
2164         fi
2165       done
2166        ;;
2167   esac
2168 ])
2169
2170 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2171
2172   # The canonical -pthread[s] does not work. Try something different.
2173
2174   case $host in
2175         *-aix*)
2176                 if test x"$GCC" = xyes; then
2177                         # GCC 3.0 and above needs -pthread.
2178                         # Should be coverd by the case above.
2179                         # GCC 2.x and below needs -mthreads
2180                         G_THREAD_CFLAGS="-mthreads"
2181                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2182                 else
2183                         # We are probably using the aix compiler. Normaly a
2184                         # program would have to be compiled with the _r variant
2185                         # of the corresponding compiler, but we as GLib cannot
2186                         # do that: but the good news is that for compiling the
2187                         # only difference is the added -D_THREAD_SAFE compile
2188                         # option. This is according to the "C for AIX User's
2189                         # Guide".
2190                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2191                 fi
2192                 ;;
2193         *-dg-dgux*)  # DG/UX
2194                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2195                 ;;
2196         *-sysv5uw7*) # UnixWare 7
2197                 # We are not using gcc with -pthread. Catched above.
2198                 G_THREAD_CFLAGS="-Kthread"
2199                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2200                 ;;
2201         *-mingw*)
2202                 # No flag needed when using MSVCRT.DLL
2203                 G_THREAD_CFLAGS=""
2204                 ;;
2205         *)
2206                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2207                 ;;
2208   esac
2209 ])
2210
2211 # if we are not finding the localtime_r function, then we probably are
2212 # not using the proper multithread flag
2213
2214 glib_save_CPPFLAGS="$CPPFLAGS"
2215 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2216
2217 # First we test, whether localtime_r is declared in time.h
2218 # directly. Then we test whether a macro localtime_r exists, in
2219 # which case localtime_r in the test program is replaced and thus
2220 # if we still find localtime_r in the output, it is not defined as
2221 # a macro.
2222
2223 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2224   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2225                                                            localtime_r(a,b)],
2226                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2227
2228 CPPFLAGS="$glib_save_CPPFLAGS"
2229
2230 AC_MSG_CHECKING(thread related cflags)
2231 AC_MSG_RESULT($G_THREAD_CFLAGS)
2232 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2233
2234 dnl determination of G_THREAD_LIBS
2235 dnl ******************************
2236
2237 AS_IF([test x$have_threads = xposix], [
2238           glib_save_CPPFLAGS="$CPPFLAGS"
2239           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2240           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2241             case $host in
2242               *-aix*)
2243                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2244                 # probably using the aix compiler.
2245                 AC_MSG_WARN($AIX_COMPILE_INFO)
2246                 ;;
2247               *)
2248                 G_THREAD_LIBS=error
2249                 glib_save_LIBS="$LIBS"
2250                 for thread_lib in "" pthread pthread32 pthreads thread; do
2251                         if test x"$thread_lib" = x; then
2252                                 add_thread_lib=""
2253                                 IN=""
2254                         else
2255                                 add_thread_lib="-l$thread_lib"
2256                                 IN=" in -l$thread_lib"
2257                         fi
2258                         if test x"$have_threads" = xposix; then
2259                                 defattr=0
2260                         else
2261                                 defattr=pthread_attr_default
2262                         fi
2263
2264                         LIBS="$add_thread_lib $glib_save_LIBS"
2265
2266                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2267                         AC_TRY_RUN(glib_thread_test($defattr),
2268                                    glib_result=yes,
2269                                    glib_result=no,
2270                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2271                                                    glib_result=yes,
2272                                                    glib_result=no)])
2273                         AC_MSG_RESULT($glib_result)
2274
2275                         if test "$glib_result" = "yes" ; then
2276                           G_THREAD_LIBS="$add_thread_lib"
2277                           break
2278                         fi
2279                 done
2280                 if test "x$G_THREAD_LIBS" = xerror; then
2281                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2282                 fi
2283                 LIBS="$glib_save_LIBS"
2284                 ;;
2285             esac
2286           ])
2287
2288           g_threads_impl="POSIX"
2289           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2290           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2291           CPPFLAGS="$glib_save_CPPFLAGS"
2292 ], [test x$have_threads = xwin32], [
2293            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2294            g_threads_impl="WIN32"
2295 ], [
2296            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2297            g_threads_impl="NONE"
2298            G_THREAD_LIBS=error
2299 ])
2300 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2301 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2302 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2303
2304 if test "x$G_THREAD_LIBS" = xerror; then
2305         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2306 fi
2307
2308 case $host in
2309   *-*-beos*)
2310     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2311     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2312     ;;
2313   *)
2314     ;;
2315 esac
2316
2317 AC_MSG_CHECKING(thread related libraries)
2318 AC_MSG_RESULT($G_THREAD_LIBS)
2319
2320 dnl check for mt safe function variants and some posix functions
2321 dnl ************************************************************
2322
2323 glib_save_LIBS="$LIBS"
2324 # we are not doing the following for now, as this might require glib
2325 # to always be linked with the thread libs on some platforms.
2326 # LIBS="$LIBS $G_THREAD_LIBS"
2327 AC_CHECK_FUNCS(localtime_r gmtime_r)
2328 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2329         AC_CACHE_CHECK([for posix getpwuid_r],
2330                 ac_cv_func_posix_getpwuid_r,
2331                 [AC_TRY_RUN([
2332 #include <errno.h>
2333 #include <pwd.h>
2334 int main () {
2335     char buffer[10000];
2336     struct passwd pwd, *pwptr = &pwd;
2337     int error;
2338     errno = 0;
2339     error = getpwuid_r (0, &pwd, buffer,
2340                         sizeof (buffer), &pwptr);
2341    return (error < 0 && errno == ENOSYS)
2342            || error == ENOSYS;
2343 }                               ],
2344                         [ac_cv_func_posix_getpwuid_r=yes],
2345                         [ac_cv_func_posix_getpwuid_r=no])])
2346         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2347         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2348                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2349                         [Have POSIX function getpwuid_r])
2350         else
2351                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2352                         ac_cv_func_nonposix_getpwuid_r,
2353                         [AC_TRY_LINK([#include <pwd.h>],
2354                                 [char buffer[10000];
2355                                 struct passwd pwd;
2356                                 getpwuid_r (0, &pwd, buffer,
2357                                                 sizeof (buffer));],
2358                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2359                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2360                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2361                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2362                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2363                                 [Have non-POSIX function getpwuid_r])
2364                 fi
2365         fi
2366 ])
2367 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2368         AC_CACHE_CHECK([for posix getgrgid_r],
2369                 ac_cv_func_posix_getgrgid_r,
2370                 [AC_TRY_RUN([
2371 #include <errno.h>
2372 #include <grp.h>
2373 int main () {
2374     char buffer[10000];
2375     struct group grp, *grpptr = &grp;
2376     int error;
2377     errno = 0;
2378     error = getgrgid_r (0, &grp, buffer,
2379                         sizeof (buffer), &grpptr);
2380    return (error < 0 && errno == ENOSYS)
2381            || error == ENOSYS;
2382 }                              ],
2383                        [ac_cv_func_posix_getgrgid_r=yes],
2384                        [ac_cv_func_posix_getgrgid_r=no])])
2385         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2386         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2387                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2388                         [Have POSIX function getgrgid_r])
2389         ], [
2390                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2391                         ac_cv_func_nonposix_getgrgid_r,
2392                         [AC_TRY_LINK([#include <grp.h>],
2393                                 [char buffer[10000];
2394                                 struct group grp;
2395                                 getgrgid_r (0, &grp, buffer,
2396                                 sizeof (buffer));],
2397                         [ac_cv_func_nonposix_getgrgid_r=yes],
2398                         [ac_cv_func_nonposix_getgrgid_r=no])])
2399                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2400                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2401                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2402                                 [Have non-POSIX function getgrgid_r])
2403                 fi
2404         ])
2405 ])
2406 LIBS="$G_THREAD_LIBS $LIBS"
2407 AS_IF([ test x"$have_threads" = xposix], [
2408         glib_save_CPPFLAGS="$CPPFLAGS"
2409         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2410         # This is not AC_CHECK_FUNC to also work with function
2411         # name mangling in header files.
2412         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2413         AC_LINK_IFELSE(
2414             [AC_LANG_PROGRAM(
2415                 [#include <pthread.h>],
2416                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2417             [AC_MSG_RESULT(yes)
2418              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2419                 [Have function pthread_attr_setstacksize])],
2420             [AC_MSG_RESULT(no)])
2421         AC_MSG_CHECKING(for pthread_condattr_setclock)
2422         AC_LINK_IFELSE(
2423             [AC_LANG_PROGRAM(
2424                 [#include <pthread.h>],
2425                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2426             [AC_MSG_RESULT(yes)
2427              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2428                 [Have function pthread_condattr_setclock])],
2429             [AC_MSG_RESULT(no)])
2430         CPPFLAGS="$glib_save_CPPFLAGS"
2431 ])
2432
2433 LIBS="$glib_save_LIBS"
2434
2435 # now spit out all the warnings.
2436 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2437    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2438         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2439 fi
2440 if test "$ac_cv_func_localtime_r" != "yes"; then
2441         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2442 fi
2443
2444 #
2445 # Hack to deal with:
2446 #
2447 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2448 #     building shared libraries with linux.
2449 #  b) FreeBSD doesn't do this either.
2450 #
2451 case $host in
2452   *android*)
2453     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2454     ;;
2455   *-*-freebsd*|*-*-linux*)
2456     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2457     ;;
2458   *-*-openbsd*)
2459     LDFLAGS="$LDFLAGS -pthread"
2460     ;;
2461   *)
2462     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2463     ;;
2464 esac
2465
2466 AC_SUBST(G_THREAD_CFLAGS)
2467 AC_SUBST(G_THREAD_LIBS)
2468 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2469 AC_SUBST(G_THREAD_LIBS_EXTRA)
2470
2471 AC_CHECK_FUNCS(clock_gettime, [], [
2472   AC_CHECK_LIB(rt, clock_gettime, [
2473     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2474     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2475     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2476   ])
2477 ])
2478
2479
2480 dnl ************************
2481 dnl *** g_atomic_* tests ***
2482 dnl ************************
2483
2484 dnl We need to decide at configure time if GLib will use real atomic
2485 dnl operations ("lock free") or emulated ones with a mutex.  This is
2486 dnl because we must put this information in glibconfig.h so we know if
2487 dnl it is safe or not to inline using compiler intrinsics directly from
2488 dnl the header.
2489 dnl
2490 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2491 dnl user is interested in knowing if they can use the atomic ops across
2492 dnl processes.
2493 dnl
2494 dnl We can currently support the atomic ops natively when building GLib
2495 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2496 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2497 dnl we are using GCC (and not mingw*).
2498 dnl
2499 dnl Note that the atomic ops are only available with GCC on x86 when
2500 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2501 dnl not available but would be available given the right flags, we want
2502 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2503 dnl that then to silently fall back on emulated atomic ops just because
2504 dnl the user had the wrong build environment.
2505
2506 dnl We may add other compilers here in the future...
2507
2508 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2509   case $host in
2510     *-*-mingw*)
2511       glib_cv_g_atomic_lock_free=yes
2512       ;;
2513     *)
2514       AC_TRY_COMPILE([],
2515                      [volatile int atomic = 2;\
2516                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2517                      [glib_cv_g_atomic_lock_free=yes],
2518                      [glib_cv_g_atomic_lock_free=no])
2519       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2520         SAVE_CFLAGS="${CFLAGS}"
2521         CFLAGS="-march=i486"
2522         AC_TRY_COMPILE([],
2523                        [volatile int atomic = 2;\
2524                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2525                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2526                        [])
2527         CFLAGS="${SAVE_CFLAGS}"
2528       fi
2529       ;;
2530   esac])
2531
2532
2533 case $host in
2534   *-*-mingw*)
2535     ;;
2536   *)
2537     # Some compilers support atomic operations but do not define
2538     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2539     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2540       AC_TRY_COMPILE([],
2541                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2542                      [],
2543                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2544     fi
2545     ;;
2546  esac
2547
2548 dnl We need a more robust approach here...
2549 case $host_cpu in
2550   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2551     glib_memory_barrier_needed=no
2552     ;;
2553   sparc*|alpha*|powerpc*|ia64)
2554     glib_memory_barrier_needed=yes
2555     ;;
2556   *)
2557     glib_memory_barrier_needed=yes
2558     ;;
2559 esac
2560
2561 dnl ************************
2562 dnl ** Check for futex(2) **
2563 dnl ************************
2564 AC_CACHE_CHECK(for futex(2) system call,
2565     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2566 #include <linux/futex.h>
2567 #include <sys/syscall.h>
2568 #include <unistd.h>
2569 ],[
2570 int
2571 main (void)
2572 {
2573   /* it is not like this actually runs or anything... */
2574   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2575   return 0;
2576 }
2577 ])],glib_cv_futex=yes,glib_cv_futex=no))
2578 if test x"$glib_cv_futex" = xyes; then
2579   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2580 fi
2581
2582 AC_CACHE_CHECK(for eventfd(2) system call,
2583     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2584 #include <sys/eventfd.h>
2585 #include <unistd.h>
2586 ],[
2587 int
2588 main (void)
2589 {
2590   eventfd (0, EFD_CLOEXEC);
2591   return 0;
2592 }
2593 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2594 if test x"$glib_cv_eventfd" = x"yes"; then
2595   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2596 fi
2597 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2598
2599 dnl ****************************************
2600 dnl *** GLib POLL* compatibility defines ***
2601 dnl ****************************************
2602
2603 glib_poll_includes=["
2604 #include <sys/types.h>
2605 #include <sys/poll.h>
2606 "]
2607
2608 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2609    test $ac_cv_header_sys_poll_h = yes ], [
2610   glib_failed=false
2611   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2612   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2613   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2614   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2615   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2616   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2617   if $glib_failed ; then
2618     AC_MSG_ERROR([Could not determine values for POLL* constants])
2619   fi
2620 ], [
2621   glib_cv_value_POLLIN=1
2622   glib_cv_value_POLLOUT=4
2623   glib_cv_value_POLLPRI=2
2624   glib_cv_value_POLLERR=8
2625   glib_cv_value_POLLHUP=16
2626   glib_cv_value_POLLNVAL=32
2627 ])
2628
2629 AC_MSG_CHECKING([for broken poll])
2630 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2631         #include <stdlib.h>
2632         #include <fcntl.h>
2633         #include <poll.h>
2634         #ifdef HAVE_SYS_POLL_H
2635         #include <sys/poll.h>
2636         #endif
2637         int main(void) {
2638           struct pollfd fds[1];
2639           int fd;
2640           fd = open("/dev/null", 1);
2641           fds[0].fd = fd;
2642           fds[0].events = POLLIN;
2643           fds[0].revents = 0;
2644           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2645                 exit(1);  /* Does not work for devices -- fail */
2646           }
2647           exit(0);
2648         }]])],
2649   [broken_poll=no],
2650   [broken_poll=yes
2651    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2652   [broken_poll="no (cross compiling)"])
2653 AC_MSG_RESULT($broken_poll)
2654
2655 dnl *********************
2656 dnl *** GRegex checks ***
2657 dnl *********************
2658
2659 PCRE_REQUIRED_VERSION=8.13
2660
2661 # Check if we should use the internal or the system-supplied pcre
2662 AC_ARG_WITH(pcre,
2663             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2664                             [whether to use system PCRE [default=internal]])])
2665
2666 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2667
2668 AS_IF([ test "x$with_pcre" = xsystem], [
2669   PKG_CHECK_MODULES(PCRE,
2670                     libpcre >= $PCRE_REQUIRED_VERSION)
2671   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2672                   glib_save_CFLAGS="$CFLAGS"
2673                   glib_save_LIBS="$LIBS"
2674                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2675                   AC_TRY_RUN([#include <pcre.h>
2676                               int main () {
2677                                 int support;
2678                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2679                                 if (!support)
2680                                   return 1;
2681                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2682                                 if (!support)
2683                                   return 1;
2684                                 return 0;
2685                               }],
2686                   glib_cv_pcre_has_unicode=yes,
2687                   glib_cv_pcre_has_unicode=no,
2688                   glib_cv_pcre_has_unicode=yes)
2689                   CFLAGS="$glib_save_CFLAGS"
2690                   LIBS="$glib_save_LIBS"
2691       ])
2692   if test "$glib_cv_pcre_has_unicode" = "no"; then
2693     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2694   fi
2695   AC_SUBST(PCRE_CFLAGS)
2696   AC_SUBST(PCRE_LIBS)
2697   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2698   PCRE_REQUIRES=libpcre
2699   AC_SUBST(PCRE_REQUIRES)
2700 ], [
2701   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2702   AS_IF([ test x"$GCC" = xyes], [
2703     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2704     save_CFLAGS="$CFLAGS"
2705     CFLAGS="$CFLAGS -Wno-pointer-sign"
2706     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2707                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2708     CFLAGS="$save_CFLAGS"
2709   ])
2710 ])
2711 AC_SUBST(PCRE_WARN_CFLAGS)
2712
2713 dnl **********************
2714 dnl *** Win32 API libs ***
2715 dnl **********************
2716
2717 case $host in
2718   *-*-cygwin*)
2719         G_LIBS_EXTRA="-luser32 -lkernel32"
2720     ;;
2721   *-*-mingw*)
2722         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2723     ;;
2724   *)
2725         G_LIBS_EXTRA=""
2726     ;;
2727 esac
2728 AC_SUBST(G_LIBS_EXTRA)
2729
2730 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2731 dnl since we need it for g_iconv()
2732
2733 AC_MSG_CHECKING([for EILSEQ])
2734 AC_TRY_COMPILE([
2735 #include <errno.h>
2736 ],
2737 [
2738 int error = EILSEQ;
2739 ], have_eilseq=yes, have_eilseq=no);
2740 AC_MSG_RESULT($have_eilseq)
2741
2742 dnl ******************************************************************
2743 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2744 dnl *** glib-compile-schemas in PATH                               ***
2745 dnl ******************************************************************
2746
2747 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2748
2749 AS_IF([ test $cross_compiling = yes && test x$enable_modular_tests = xyes], [
2750   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2751   if test x$GLIB_GENMARSHAL = xno; then
2752     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2753   fi
2754
2755   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2756   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2757     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2758   fi
2759
2760   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2761   if test x$GLIB_COMPILE_RESOURCES = xno; then
2762     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2763   fi
2764 ])
2765
2766 dnl **************************
2767 dnl *** Checks for gtk-doc ***
2768 dnl **************************
2769 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2770 # it on it's own line.
2771 m4_ifdef([GTK_DOC_CHECK], [
2772 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2773 ],[
2774 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2775 ])
2776
2777 AC_ARG_ENABLE(man,
2778               [AS_HELP_STRING([--enable-man],
2779                               [generate man pages [default=auto]])],,
2780               enable_man=maybe)
2781
2782 AS_IF([test "$enable_man" != no], [
2783   AC_PATH_PROG([XSLTPROC], [xsltproc])
2784   AS_IF([test -z "$XSLTPROC"], [
2785     AS_IF([test "$enable_man" = yes], [
2786       AC_MSG_ERROR([xsltproc is required for --enable-man])
2787     ])
2788     enable_man=no
2789   ])
2790 ])
2791
2792 AS_IF([ test "$enable_man" != no ], [
2793   dnl check for DocBook DTD in the local catalog
2794   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2795      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2796   AS_IF([test "$have_docbook_dtd" != yes], [
2797     AS_IF([test "$enable_man" = yes ], [
2798       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2799     ])
2800     enable_man=no
2801   ])
2802 ])
2803
2804 AS_IF([test "$enable_man" != no], [
2805   dnl check for DocBook XSL stylesheets in the local catalog
2806   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2807      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2808   AS_IF([ test "$have_docbook_dtd" != yes ], [
2809     AS_IF([ test "$enable_man" = yes ], [
2810       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2811     ])
2812     enable_man=no
2813   ])
2814 ])
2815
2816 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2817
2818 AC_MSG_CHECKING([whether to generate man pages])
2819 AS_IF([ test "$enable_man" != no ], [
2820   AC_MSG_RESULT([yes])
2821 ], [
2822   AC_MSG_RESULT([no])
2823 ])
2824
2825 dnl
2826 dnl Tracing
2827 dnl
2828
2829 AC_ARG_ENABLE([dtrace],
2830              [AS_HELP_STRING([--enable-dtrace],
2831                               [include tracing support for dtrace])])
2832 have_dtrace=no
2833 AC_MSG_CHECKING([whether to include dtrace tracing support])
2834 AS_IF([ test "x$enable_dtrace" != xno], [
2835   if test x$glib_have_carbon = xyes; then
2836     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2837   else
2838     AC_MSG_RESULT([yes])
2839     AC_CHECK_PROGS(DTRACE, dtrace)
2840     if test -z "$DTRACE"; then
2841       if test "x$enable_dtrace" = xyes; then
2842         AC_MSG_ERROR([dtrace not found])
2843       fi
2844     else
2845       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2846                       [if test "x$enable_dtrace" = xyes; then
2847                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2848                        fi])
2849     fi
2850   fi
2851 ], [
2852   AC_MSG_RESULT([no])
2853 ])
2854 if test "x$have_dtrace" = xyes; then
2855   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2856 fi
2857 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2858
2859 AC_MSG_CHECKING([whether to include systemtap tracing support])
2860 AC_ARG_ENABLE([systemtap],
2861              [AS_HELP_STRING([--enable-systemtap],
2862                               [include tracing support for systemtap])])
2863 have_systemtap=no
2864 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2865   have_systemtap=yes
2866 fi
2867 AC_MSG_RESULT(${have_systemtap})
2868
2869 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2870
2871 AC_ARG_WITH([tapset-install-dir],
2872             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2873                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2874             [if test "x${withval}" = x; then
2875                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2876              else
2877                ABS_TAPSET_DIR="${withval}"
2878               fi],
2879             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2880 AC_SUBST(ABS_TAPSET_DIR)
2881
2882 dnl ************************************
2883 dnl *** Enable lcov coverage reports ***
2884 dnl ************************************
2885
2886 AC_ARG_ENABLE(gcov,
2887   AS_HELP_STRING([--enable-gcov],
2888                  [enable coverage testing with gcov]),
2889   [use_gcov=$enableval], [use_gcov=no])
2890
2891 AS_IF([ test "x$use_gcov" = "xyes"], [
2892   dnl we need gcc:
2893   if test "$GCC" != "yes"; then
2894     AC_MSG_ERROR([GCC is required for --enable-gcov])
2895   fi
2896
2897   dnl Check if ccache is being used
2898   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2899   case `$SHTOOL path $CC` in
2900     *ccache*[)] gcc_ccache=yes;;
2901     *[)] gcc_ccache=no;;
2902   esac
2903
2904   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2905     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2906   fi
2907
2908   ltp_version_list="1.6 1.7 1.8 1.9"
2909   AC_CHECK_PROG(LTP, lcov, lcov)
2910   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2911
2912   AS_IF([ test "$LTP" ], [
2913     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2914       glib_cv_ltp_version=invalid
2915       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2916       for ltp_check_version in $ltp_version_list; do
2917         if test "$ltp_version" = "$ltp_check_version"; then
2918           glib_cv_ltp_version="$ltp_check_version (ok)"
2919         fi
2920       done
2921     ])
2922   ], [
2923     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2924     AC_MSG_ERROR([$ltp_msg])
2925   ])
2926
2927   case $glib_cv_ltp_version in
2928     ""|invalid[)]
2929       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2930       AC_MSG_ERROR([$ltp_msg])
2931       LTP="exit 0;"
2932       ;;
2933   esac
2934
2935   if test -z "$LTP_GENHTML"; then
2936     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2937   fi
2938
2939   dnl Remove all optimization flags from CFLAGS
2940   changequote({,})
2941   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2942   changequote([,])
2943
2944   dnl Add the special gcc flags
2945   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2946   LDFLAGS="$LDFLAGS -lgcov"
2947 ])
2948
2949 dnl ******************************
2950 dnl *** output the whole stuff ***
2951 dnl ******************************
2952
2953 dnl this section will only be run if config.status is invoked with no
2954 dnl arguments, or with "glib/glibconfig.h" as an argument.
2955 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2956 [
2957         outfile=glib/glibconfig.h-tmp
2958         cat > $outfile <<\_______EOF
2959 /* glibconfig.h
2960  *
2961  * This is a generated file.  Please modify 'configure.ac'
2962  */
2963
2964 #ifndef __GLIBCONFIG_H__
2965 #define __GLIBCONFIG_H__
2966
2967 #include <glib/gmacros.h>
2968
2969 _______EOF
2970
2971         if test x$glib_limits_h = xyes; then
2972           echo '#include <limits.h>' >> $outfile
2973         fi
2974         if test x$glib_float_h = xyes; then
2975           echo '#include <float.h>' >> $outfile
2976         fi
2977         if test x$glib_values_h = xyes; then
2978           echo '#include <values.h>' >> $outfile
2979         fi
2980         if test "$glib_header_alloca_h" = "yes"; then
2981           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2982         fi
2983         if test x$glib_sys_poll_h = xyes; then
2984           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2985         fi
2986         if test x$glib_included_printf != xyes; then
2987           echo "
2988 /* Specifies that GLib's g_print*() functions wrap the
2989  * system printf functions.  This is useful to know, for example,
2990  * when using glibc's register_printf_function().
2991  */" >> $outfile
2992           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2993         fi
2994
2995         cat >> $outfile <<_______EOF
2996
2997 G_BEGIN_DECLS
2998
2999 #define G_MINFLOAT      $glib_mf
3000 #define G_MAXFLOAT      $glib_Mf
3001 #define G_MINDOUBLE     $glib_md
3002 #define G_MAXDOUBLE     $glib_Md
3003 #define G_MINSHORT      $glib_ms
3004 #define G_MAXSHORT      $glib_Ms
3005 #define G_MAXUSHORT     $glib_Mus
3006 #define G_MININT        $glib_mi
3007 #define G_MAXINT        $glib_Mi
3008 #define G_MAXUINT       $glib_Mui
3009 #define G_MINLONG       $glib_ml
3010 #define G_MAXLONG       $glib_Ml
3011 #define G_MAXULONG      $glib_Mul
3012
3013 _______EOF
3014
3015
3016         ### this should always be true in a modern C/C++ compiler
3017         cat >>$outfile <<_______EOF
3018 typedef signed char gint8;
3019 typedef unsigned char guint8;
3020 _______EOF
3021
3022
3023         if test -n "$gint16"; then
3024           cat >>$outfile <<_______EOF
3025 typedef signed $gint16 gint16;
3026 typedef unsigned $gint16 guint16;
3027 #define G_GINT16_MODIFIER $gint16_modifier
3028 #define G_GINT16_FORMAT $gint16_format
3029 #define G_GUINT16_FORMAT $guint16_format
3030 _______EOF
3031         fi
3032
3033
3034         if test -n "$gint32"; then
3035           cat >>$outfile <<_______EOF
3036 typedef signed $gint32 gint32;
3037 typedef unsigned $gint32 guint32;
3038 #define G_GINT32_MODIFIER $gint32_modifier
3039 #define G_GINT32_FORMAT $gint32_format
3040 #define G_GUINT32_FORMAT $guint32_format
3041 _______EOF
3042         fi
3043
3044         cat >>$outfile <<_______EOF
3045 #define G_HAVE_GINT64 1          /* deprecated, always true */
3046
3047 ${glib_extension}typedef signed $gint64 gint64;
3048 ${glib_extension}typedef unsigned $gint64 guint64;
3049
3050 #define G_GINT64_CONSTANT(val)  $gint64_constant
3051 #define G_GUINT64_CONSTANT(val) $guint64_constant
3052 _______EOF
3053
3054         if test x$gint64_format != x ; then
3055           cat >>$outfile <<_______EOF
3056 #define G_GINT64_MODIFIER $gint64_modifier
3057 #define G_GINT64_FORMAT $gint64_format
3058 #define G_GUINT64_FORMAT $guint64_format
3059 _______EOF
3060         else
3061           cat >>$outfile <<_______EOF
3062 #undef G_GINT64_MODIFIER
3063 #undef G_GINT64_FORMAT
3064 #undef G_GUINT64_FORMAT
3065 _______EOF
3066         fi
3067
3068         cat >>$outfile <<_______EOF
3069
3070 #define GLIB_SIZEOF_VOID_P $glib_void_p
3071 #define GLIB_SIZEOF_LONG   $glib_long
3072 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3073 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
3074
3075 _______EOF
3076
3077         cat >>$outfile <<_______EOF
3078 typedef signed $glib_ssize_type_define gssize;
3079 typedef unsigned $glib_size_type_define gsize;
3080 #define G_GSIZE_MODIFIER $gsize_modifier
3081 #define G_GSSIZE_MODIFIER $gssize_modifier
3082 #define G_GSIZE_FORMAT $gsize_format
3083 #define G_GSSIZE_FORMAT $gssize_format
3084
3085 #define G_MAXSIZE       G_MAXU$glib_msize_type
3086 #define G_MINSSIZE      G_MIN$glib_mssize_type
3087 #define G_MAXSSIZE      G_MAX$glib_mssize_type
3088
3089 typedef gint64 goffset;
3090 #define G_MINOFFSET     G_MININT64
3091 #define G_MAXOFFSET     G_MAXINT64
3092
3093 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3094 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3095 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3096
3097 _______EOF
3098
3099         if test -z "$glib_unknown_void_p"; then
3100           cat >>$outfile <<_______EOF
3101
3102 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3103 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3104
3105 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3106 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3107
3108 typedef signed $glib_intptr_type_define gintptr;
3109 typedef unsigned $glib_intptr_type_define guintptr;
3110
3111 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3112 #define G_GINTPTR_FORMAT        $gintptr_format
3113 #define G_GUINTPTR_FORMAT       $guintptr_format
3114 _______EOF
3115         else
3116           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3117         fi
3118
3119
3120
3121         cat >>$outfile <<_______EOF
3122 $glib_atexit
3123 $glib_memmove
3124 $glib_defines
3125 $glib_os
3126 $glib_static_compilation
3127
3128 $glib_vacopy
3129
3130 #ifdef  __cplusplus
3131 #define G_HAVE_INLINE   1
3132 #else   /* !__cplusplus */
3133 $glib_inline
3134 #endif  /* !__cplusplus */
3135
3136 #ifdef  __cplusplus
3137 #define G_CAN_INLINE    1
3138 _______EOF
3139
3140         if test x$g_can_inline = xyes ; then
3141                 cat >>$outfile <<_______EOF
3142 #else   /* !__cplusplus */
3143 #define G_CAN_INLINE    1
3144 _______EOF
3145         fi
3146
3147         cat >>$outfile <<_______EOF
3148 #endif
3149
3150 _______EOF
3151
3152         if test x$g_have_iso_c_varargs = xyes ; then
3153                 cat >>$outfile <<_______EOF
3154 #ifndef __cplusplus
3155 # define G_HAVE_ISO_VARARGS 1
3156 #endif
3157 _______EOF
3158         fi
3159         if test x$g_have_iso_cxx_varargs = xyes ; then
3160                 cat >>$outfile <<_______EOF
3161 #ifdef __cplusplus
3162 # define G_HAVE_ISO_VARARGS 1
3163 #endif
3164 _______EOF
3165         fi
3166         if test x$g_have_gnuc_varargs = xyes ; then
3167                 cat >>$outfile <<_______EOF
3168
3169 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3170  * is passed ISO vararg support is turned off, and there is no work
3171  * around to turn it on, so we unconditionally turn it off.
3172  */
3173 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3174 #  undef G_HAVE_ISO_VARARGS
3175 #endif
3176
3177 #define G_HAVE_GNUC_VARARGS 1
3178 _______EOF
3179         fi
3180
3181         case x$g_stack_grows in
3182         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3183         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3184         esac
3185
3186
3187         echo >>$outfile
3188         if test x$g_have_eilseq = xno; then
3189                 cat >>$outfile <<_______EOF
3190 #ifndef EILSEQ
3191 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3192  * The correspondence between this and the corresponding definition
3193  * in libiconv is essential.
3194  */
3195 #  define EILSEQ ENOENT
3196 #endif
3197 _______EOF
3198
3199         fi
3200
3201         if test x$g_have_gnuc_visibility = xyes; then
3202                 cat >>$outfile <<_______EOF
3203 #define G_HAVE_GNUC_VISIBILITY 1
3204 _______EOF
3205         fi
3206                 cat >>$outfile <<_______EOF
3207 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3208 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3209 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3210 #define G_GNUC_INTERNAL __hidden
3211 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3212 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3213 #else
3214 #define G_GNUC_INTERNAL
3215 #endif
3216 _______EOF
3217
3218         echo >>$outfile
3219         cat >>$outfile <<_______EOF
3220 #define G_THREADS_ENABLED
3221 #define G_THREADS_IMPL_$g_threads_impl_def
3222 _______EOF
3223
3224         if test x"$g_memory_barrier_needed" != xno; then
3225           echo >>$outfile
3226           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3227         fi
3228         if test x"$g_atomic_lock_free" = xyes; then
3229           echo >>$outfile
3230           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3231         fi
3232         echo >>$outfile
3233         g_bit_sizes="16 32 64"
3234         for bits in $g_bit_sizes; do
3235           cat >>$outfile <<_______EOF
3236 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3237 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3238 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3239 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3240 _______EOF
3241         done
3242
3243         cat >>$outfile <<_______EOF
3244 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3245 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3246 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3247 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3248 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3249 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3250 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3251 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3252 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3253 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3254 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3255 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3256 #define G_BYTE_ORDER $g_byte_order
3257
3258 #define GLIB_SYSDEF_POLLIN =$g_pollin
3259 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3260 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3261 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3262 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3263 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3264
3265 #define G_MODULE_SUFFIX "$g_module_suffix"
3266
3267 typedef $g_pid_type GPid;
3268
3269 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3270 #define GLIB_SYSDEF_AF_INET $g_af_inet
3271 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3272
3273 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3274 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3275 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3276
3277 G_END_DECLS
3278
3279 #endif /* __GLIBCONFIG_H__ */
3280 _______EOF
3281
3282
3283         if cmp -s $outfile glib/glibconfig.h; then
3284           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3285           rm -f $outfile
3286         else
3287           mv $outfile glib/glibconfig.h
3288         fi
3289 ],[
3290
3291 # Note that if two cases are the same, case goes with the first one.
3292 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3293 # on variable expansion in case labels.  Look at the generated config.status
3294 # for a hint.
3295
3296 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3297   glib_header_alloca_h="$ac_cv_working_alloca_h"
3298 else
3299   glib_header_alloca_h="$ac_cv_header_alloca_h"
3300 fi
3301
3302 case xyes in
3303 x$ac_cv_header_float_h)
3304   glib_float_h=yes
3305   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3306   glib_md=DBL_MIN glib_Md=DBL_MAX
3307   ;;
3308 x$ac_cv_header_values_h)
3309   glib_values_h=yes
3310   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3311   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3312   ;;
3313 esac
3314
3315 case xyes in
3316 x$ac_cv_header_limits_h)
3317   glib_limits_h=yes
3318   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3319   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3320   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3321   ;;
3322 x$ac_cv_header_values_h)
3323   glib_values_h=yes
3324   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3325   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3326   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3327   ;;
3328 esac
3329
3330 if test x$ac_cv_header_sys_poll_h = xyes ; then
3331   glib_sys_poll_h=yes
3332 fi
3333
3334 if test x$enable_included_printf = xyes ; then
3335   glib_included_printf=yes
3336 fi
3337
3338 case 2 in
3339 $ac_cv_sizeof_short)
3340   gint16=short
3341   gint16_modifier='"h"'
3342   gint16_format='"hi"'
3343   guint16_format='"hu"'
3344   ;;
3345 $ac_cv_sizeof_int)
3346   gint16=int
3347   gint16_modifier='""'
3348   gint16_format='"i"'
3349   guint16_format='"u"'
3350   ;;
3351 esac
3352 case 4 in
3353 $ac_cv_sizeof_short)
3354   gint32=short
3355   gint32_modifier='"h"'
3356   gint32_format='"hi"'
3357   guint32_format='"hu"'
3358   ;;
3359 $ac_cv_sizeof_int)
3360   gint32=int
3361   gint32_modifier='""'
3362   gint32_format='"i"'
3363   guint32_format='"u"'
3364   ;;
3365 $ac_cv_sizeof_long)
3366   gint32=long
3367   gint32_modifier='"l"'
3368   gint32_format='"li"'
3369   guint32_format='"lu"'
3370   ;;
3371 esac
3372 case 8 in
3373 $ac_cv_sizeof_int)
3374   gint64=int
3375   gint64_modifier='""'
3376   gint64_format='"i"'
3377   guint64_format='"u"'
3378   glib_extension=
3379   gint64_constant='(val)'
3380   guint64_constant='(val)'
3381   ;;
3382 $ac_cv_sizeof_long)
3383   gint64=long
3384   gint64_modifier='"l"'
3385   gint64_format='"li"'
3386   guint64_format='"lu"'
3387   glib_extension=
3388   gint64_constant='(val##L)'
3389   guint64_constant='(val##UL)'
3390   ;;
3391 $ac_cv_sizeof_long_long)
3392   gint64='long long'
3393   if test -n "$glib_cv_long_long_format"; then
3394     gint64_modifier='"'$glib_cv_long_long_format'"'
3395     gint64_format='"'$glib_cv_long_long_format'i"'
3396     guint64_format='"'$glib_cv_long_long_format'u"'
3397   fi
3398   glib_extension='G_GNUC_EXTENSION '
3399   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3400   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3401   ;;
3402 $ac_cv_sizeof___int64)
3403   gint64='__int64'
3404   if test -n "$glib_cv_long_long_format"; then
3405     gint64_modifier='"'$glib_cv_long_long_format'"'
3406     gint64_format='"'$glib_cv_long_long_format'i"'
3407     guint64_format='"'$glib_cv_long_long_format'u"'
3408   fi
3409   glib_extension=
3410   gint64_constant='(val##i64)'
3411   guint64_constant='(val##ui64)'
3412   ;;
3413 esac
3414 glib_size_t=$ac_cv_sizeof_size_t
3415 glib_ssize_t=$ac_cv_sizeof_ssize_t
3416 glib_size_type_define="$glib_size_type"
3417 glib_ssize_type_define="$glib_ssize_type"
3418 glib_void_p=$ac_cv_sizeof_void_p
3419 glib_long=$ac_cv_sizeof_long
3420
3421 case "$glib_size_type" in
3422 short)
3423   gsize_modifier='"h"'
3424   gsize_format='"hu"'
3425   glib_msize_type='SHRT'
3426   ;;
3427 int)
3428   gsize_modifier='""'
3429   gsize_format='"u"'
3430   glib_msize_type='INT'
3431   ;;
3432 long)
3433   gsize_modifier='"l"'
3434   gsize_format='"lu"'
3435   glib_msize_type='LONG'
3436   ;;
3437 "long long"|__int64)
3438   gsize_modifier='"I64"'
3439   gsize_format='"I64u"'
3440   glib_msize_type='INT64'
3441   ;;
3442 esac
3443
3444 case "$glib_ssize_type" in
3445 short)
3446   gssize_modifier='"h"'
3447   gssize_format='"hi"'
3448   glib_mssize_type='SHRT'
3449   ;;
3450 int)
3451   gssize_modifier='""'
3452   gssize_format='"i"'
3453   glib_mssize_type='INT'
3454   ;;
3455 long)
3456   gssize_modifier='"l"'
3457   gssize_format='"li"'
3458   glib_mssize_type='LONG'
3459   ;;
3460 "long long"|__int64)
3461   gssize_modifier='"I64"'
3462   gssize_format='"I64i"'
3463   glib_mssize_type='INT64'
3464   ;;
3465 esac
3466
3467 gintbits=`expr $ac_cv_sizeof_int \* 8`
3468 glongbits=`expr $ac_cv_sizeof_long \* 8`
3469 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3470 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3471
3472 case $ac_cv_sizeof_void_p in
3473 $ac_cv_sizeof_int)
3474   glib_intptr_type_define=int
3475   gintptr_modifier='""'
3476   gintptr_format='"i"'
3477   guintptr_format='"u"'
3478   glib_gpi_cast='(gint)'
3479   glib_gpui_cast='(guint)'
3480   ;;
3481 $ac_cv_sizeof_long)
3482   glib_intptr_type_define=long
3483   gintptr_modifier='"l"'
3484   gintptr_format='"li"'
3485   guintptr_format='"lu"'
3486   glib_gpi_cast='(glong)'
3487   glib_gpui_cast='(gulong)'
3488   ;;
3489 $ac_cv_sizeof_long_long)
3490   glib_intptr_type_define='long long'
3491   gintptr_modifier='"I64"'
3492   gintptr_format='"I64i"'
3493   guintptr_format='"I64u"'
3494   glib_gpi_cast='(gint64)'
3495   glib_gpui_cast='(guint64)'
3496   ;;
3497 $ac_cv_sizeof___int64)
3498   glib_intptr_type_define=__int64
3499   gintptr_modifier='"I64"'
3500   gintptr_format='"I64i"'
3501   guintptr_format='"I64u"'
3502   glib_gpi_cast='(gint64)'
3503   glib_gpui_cast='(guint64)'
3504   ;;
3505 *)
3506   glib_unknown_void_p=yes
3507   ;;
3508 esac
3509
3510
3511 case xyes in
3512 x$ac_cv_func_atexit)
3513   glib_atexit="
3514 #ifdef NeXT /* @#%@! NeXTStep */
3515 # define g_ATEXIT(proc) (!atexit (proc))
3516 #else
3517 # define g_ATEXIT(proc) (atexit (proc))
3518 #endif"
3519   ;;
3520 x$ac_cv_func_on_exit)
3521   glib_atexit="
3522 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3523   ;;
3524 esac
3525
3526 case xyes in
3527 x$ac_cv_func_memmove)
3528   glib_memmove='
3529 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3530   ;;
3531 x$glib_cv_working_bcopy)
3532   glib_memmove="
3533 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3534 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3535   ;;
3536 *)
3537   glib_memmove="
3538 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3539  * so we have to roll our own copy routine. */
3540 void g_memmove (void* dest, const void * src, unsigned long len);"
3541   ;;
3542 esac
3543
3544 glib_defines="
3545 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3546 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3547 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3548 "
3549
3550 case xyes in
3551 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3552 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3553 *)                      glib_vacopy=''
3554 esac
3555
3556 if test x$glib_cv_va_val_copy = xno; then
3557   glib_vacopy="\$glib_vacopy
3558 #define G_VA_COPY_AS_ARRAY 1"
3559 fi
3560
3561 if test x$glib_cv_hasinline = xyes; then
3562     glib_inline='#define G_HAVE_INLINE 1'
3563 fi
3564 if test x$glib_cv_has__inline = xyes; then
3565     glib_inline="\$glib_inline
3566 #define G_HAVE___INLINE 1"
3567 fi
3568 if test x$glib_cv_has__inline__ = xyes; then
3569     glib_inline="\$glib_inline
3570 #define G_HAVE___INLINE__ 1"
3571 fi
3572
3573 g_have_gnuc_varargs=$g_have_gnuc_varargs
3574 g_have_iso_c_varargs=$g_have_iso_c_varargs
3575 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3576
3577 g_can_inline=$g_can_inline
3578 g_have_gnuc_visibility=$g_have_gnuc_visibility
3579 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3580
3581 if test x$ac_cv_c_bigendian = xyes; then
3582   g_byte_order=G_BIG_ENDIAN
3583   g_bs_native=BE
3584   g_bs_alien=LE
3585 else
3586   g_byte_order=G_LITTLE_ENDIAN
3587   g_bs_native=LE
3588   g_bs_alien=BE
3589 fi
3590
3591 g_pollin=$glib_cv_value_POLLIN
3592 g_pollout=$glib_cv_value_POLLOUT
3593 g_pollpri=$glib_cv_value_POLLPRI
3594 g_pollhup=$glib_cv_value_POLLHUP
3595 g_pollerr=$glib_cv_value_POLLERR
3596 g_pollnval=$glib_cv_value_POLLNVAL
3597
3598 # If a family is not found on the system, define that family to
3599 # a negative value, picking a different one for each undefined
3600 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3601 # This is needed because glib-mkenums doesn't handle optional
3602 # values in enums, and thus we have to have all existing values
3603 # defined in the enum.
3604 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3605   g_af_unix=$glib_cv_value_AF_UNIX
3606 else
3607   g_af_unix=-1
3608 fi
3609 g_af_inet=$glib_cv_value_AF_INET
3610 g_af_inet6=$glib_cv_value_AF_INET6
3611
3612 g_msg_peek=$glib_cv_value_MSG_PEEK
3613 g_msg_oob=$glib_cv_value_MSG_OOB
3614 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3615
3616 g_stack_grows=$glib_cv_stack_grows
3617
3618 g_have_eilseq=$have_eilseq
3619
3620 g_threads_impl_def=$g_threads_impl
3621
3622 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3623 g_memory_barrier_needed="$glib_memory_barrier_needed"
3624 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3625
3626 g_module_suffix="$glib_gmodule_suffix"
3627
3628 g_pid_type="$glib_pid_type"
3629 case $host in
3630   *-*-beos*)
3631     glib_os="#define G_OS_BEOS"
3632     ;;
3633   *-*-cygwin*)
3634     glib_os="#define G_OS_UNIX
3635 #define G_PLATFORM_WIN32
3636 #define G_WITH_CYGWIN"
3637     ;;
3638   *-*-mingw*)
3639     glib_os="#define G_OS_WIN32
3640 #define G_PLATFORM_WIN32"
3641     ;;
3642   *)
3643     glib_os="#define G_OS_UNIX"
3644     ;;
3645 esac
3646 glib_static_compilation=""
3647 if test x$glib_win32_static_compilation = xyes; then
3648   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3649 #define GOBJECT_STATIC_COMPILATION 1"
3650 fi
3651 ])
3652
3653 # Redo enough to get guint32 and guint64 for the alignment checks below
3654 case 4 in
3655 $ac_cv_sizeof_short)
3656   gint32=short
3657   ;;
3658 $ac_cv_sizeof_int)
3659   gint32=int
3660   ;;
3661 $ac_cv_sizeof_long)
3662   gint32=long
3663   ;;
3664 esac
3665 case 8 in
3666 $ac_cv_sizeof_int)
3667   gint64=int
3668   ;;
3669 $ac_cv_sizeof_long)
3670   gint64=long
3671   ;;
3672 $ac_cv_sizeof_long_long)
3673   gint64='long long'
3674   ;;
3675 $ac_cv_sizeof___int64)
3676   gint64='__int64'
3677   ;;
3678 esac
3679
3680 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3681 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3682 typedef unsigned $gint32 guint32;])
3683 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3684 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3685 typedef unsigned $gint64 guint64;])
3686 AC_CHECK_TYPE([unsigned long])
3687 AC_CHECK_ALIGNOF([unsigned long])
3688
3689 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3690 #
3691 # 1.2.14 required for dbus_message_set_serial
3692 AS_IF([ test x$enable_modular_tests = xyes], [
3693    PKG_CHECK_MODULES(DBUS1,
3694                      dbus-1 >= 1.2.14,
3695                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3696                      have_dbus1=no)
3697    AC_SUBST(DBUS1_CFLAGS)
3698    AC_SUBST(DBUS1_LIBS)
3699 ])
3700 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3701
3702 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3703 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3704
3705 dnl
3706 dnl Check for -Bsymbolic-functions linker flag used to avoid
3707 dnl intra-library PLT jumps, if available.
3708 dnl
3709
3710 AC_ARG_ENABLE(Bsymbolic,
3711               [AS_HELP_STRING([--disable-Bsymbolic],
3712                               [avoid linking with -Bsymbolic])],,
3713               [SAVED_LDFLAGS="${LDFLAGS}"
3714                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3715                LDFLAGS=-Wl,-Bsymbolic-functions
3716                AC_TRY_LINK([], [int main (void) { return 0; }],
3717                            AC_MSG_RESULT(yes)
3718                            enable_Bsymbolic=yes,
3719                            AC_MSG_RESULT(no)
3720                            enable_Bsymbolic=no)
3721                LDFLAGS="${SAVED_LDFLAGS}"])
3722
3723 if test "x${enable_Bsymbolic}" = "xyes"; then
3724   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3725 fi
3726
3727 AC_SUBST(GLIB_LINK_FLAGS)
3728
3729 dnl
3730 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3731 dnl visibility attributes for symbol export control
3732 dnl
3733 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3734 case "$host" in
3735   *-*-mingw*)
3736     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3737     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3738               [defines how to decorate public symbols while building])
3739     CFLAGS="${CFLAGS} -fvisibility=hidden"
3740     ;;
3741   *)
3742     dnl on other compilers, check if we can do -fvisibility=hidden
3743     SAVED_CFLAGS="${CFLAGS}"
3744     CFLAGS="-fvisibility=hidden"
3745     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3746     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3747                    AC_MSG_RESULT(yes)
3748                    enable_fvisibility_hidden=yes,
3749                    AC_MSG_RESULT(no)
3750                    enable_fvisibility_hidden=no)
3751     CFLAGS="${SAVED_CFLAGS}"
3752
3753     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3754       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3755                 [defines how to decorate public symbols while building])
3756       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3757     ])
3758     ;;
3759 esac
3760 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3761
3762 dnl Compiler flags; macro originates from systemd
3763 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3764 AC_ARG_ENABLE(compile-warnings,
3765               [AS_HELP_STRING([--disable-compile-warnings],
3766                               [Don't use builtin compiler warnings])],,
3767                               enable_compile_warnings=yes)
3768 AS_IF([test "x$enable_compile_warnings" = xyes], [
3769   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3770    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3771    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3772    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3773    -Werror=format=2 -Werror=missing-include-dirs])
3774 ])
3775 AC_SUBST(GLIB_WARN_CFLAGS)
3776
3777 #
3778 # Define variables corresponding to the correct include paths to use for
3779 # in-tree building.
3780 #
3781
3782 # for config.h:
3783 config_h_INCLUDES='-I$(top_builddir)'
3784 AC_SUBST(config_h_INCLUDES)
3785
3786 # glib:
3787 #   config.h
3788 #   $(top_builddir)/glib: for glibconfig.h
3789 #   $(top_srcdir)/glib:   for glib.h
3790 #   $(top_srcdir):        for everything
3791 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3792 AC_SUBST(glib_INCLUDES)
3793
3794 # gobject:
3795 #   same as glib
3796 gobject_INCLUDES='$(glib_INCLUDES)'
3797 AC_SUBST(gobject_INCLUDES)
3798
3799 # gmodule:
3800 #   glib includes
3801 #   $(top_srcdir)/gmodule: for gmodule.h
3802 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3803 AC_SUBST(gmodule_INCLUDES)
3804
3805 # gio:
3806 #   same as gmodule
3807 gio_INCLUDES='$(gmodule_INCLUDES)'
3808 AC_SUBST(gio_INCLUDES)
3809
3810
3811 AC_CONFIG_FILES([
3812 glib-2.0.pc
3813 gmodule-2.0.pc
3814 gmodule-export-2.0.pc
3815 gmodule-no-export-2.0.pc
3816 gthread-2.0.pc
3817 gobject-2.0.pc
3818 gio-2.0.pc
3819 gio-unix-2.0.pc
3820 gio-windows-2.0.pc
3821 glib-zip
3822 glib-gettextize
3823 Makefile
3824 build/Makefile
3825 build/win32/Makefile
3826 build/win32/dirent/Makefile
3827 build/win32/vs9/Makefile
3828 build/win32/vs10/Makefile
3829 build/win32/vs11/Makefile
3830 glib/Makefile
3831 glib/glib.stp
3832 glib/libcharset/Makefile
3833 glib/gnulib/Makefile
3834 glib/pcre/Makefile
3835 glib/update-pcre/Makefile
3836 glib/tests/Makefile
3837 gmodule/Makefile
3838 gmodule/gmoduleconf.h
3839 gobject/Makefile
3840 gobject/gobject.stp
3841 gobject/glib-mkenums
3842 gobject/tests/Makefile
3843 gthread/Makefile
3844 gio/Makefile
3845 gio/gdbus-2.0/codegen/Makefile
3846 gio/gdbus-2.0/codegen/config.py
3847 gio/gnetworking.h
3848 gio/xdgmime/Makefile
3849 gio/inotify/Makefile
3850 gio/kqueue/Makefile
3851 gio/fen/Makefile
3852 gio/fam/Makefile
3853 gio/win32/Makefile
3854 gio/tests/Makefile
3855 gio/tests/gdbus-object-manager-example/Makefile
3856 gio/tests/services/Makefile
3857 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3858 po/Makefile.in
3859 docs/Makefile
3860 docs/reference/Makefile
3861 docs/reference/glib/Makefile
3862 docs/reference/glib/version.xml
3863 docs/reference/gobject/Makefile
3864 docs/reference/gobject/version.xml
3865 docs/reference/gio/Makefile
3866 docs/reference/gio/gdbus-object-manager-example/Makefile
3867 docs/reference/gio/version.xml
3868 tests/Makefile
3869 tests/gobject/Makefile
3870 tests/refcount/Makefile
3871 m4macros/Makefile
3872 ])
3873
3874 AC_CONFIG_COMMANDS([chmod-scripts],
3875 [chmod 0755 glib-zip
3876 chmod 0755 glib-gettextize
3877 chmod 0755 gobject/glib-mkenums])
3878
3879 # we want to invoke this macro solely so that the config.status script
3880 # and automake generated makefiles know about these generated files.
3881 # They are only needed to distcheck the package
3882 if false; then
3883   AC_CONFIG_FILES([
3884     INSTALL
3885     README
3886     config.h.win32
3887     glib/glibconfig.h.win32
3888     glib/makefile.msc
3889     glib/glib.rc
3890     gmodule/makefile.msc
3891     gmodule/gmodule.rc
3892     gobject/makefile.msc
3893     gobject/gobject.rc
3894     gthread/makefile.msc
3895     gthread/gthread.rc
3896     gio/gio.rc
3897     tests/makefile.msc
3898   ])
3899 fi
3900
3901 AC_OUTPUT