configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.15.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AM_PROG_LIBTOOL
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=0.10.23.1
  51 GSTPB_REQ=0.10.23.1
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION([0.17])
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101
 102 dnl determine c++ compiler
 103 AC_PROG_CXX
 104 dnl determine if c++ is available on this system
 105 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 106
 107 dnl determine c++ preprocessor
 108 dnl FIXME: do we need this ?
 109 AC_PROG_CXXCPP
 110
 111 AS_PROG_OBJC
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 dnl find an assembler
 117 AM_PROG_AS
 118
 119 dnl check if the compiler supports do while(0) macros
 120 AG_GST_CHECK_DOWHILE_MACROS
 121
 122 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 123 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 124
 125 dnl check for gconftool-2
 126 dnl this macro defines an am conditional, so it needs to be run always
 127 AM_GCONF_SOURCE_2
 128
 129 dnl check for documentation tools
 130 GTK_DOC_CHECK([1.3])
 131 AS_PATH_PYTHON([2.1])
 132 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 AC_CHECK_LIBM
 138 AC_SUBST(LIBM)
 139
 140 dnl *** checks for header files ***
 141
 142 dnl check if we have ANSI C header files
 143 AC_HEADER_STDC
 144
 145 dnl used by ext/wavpack
 146 AX_CREATE_STDINT_H
 147
 148 dnl used in gst/rtp/gstasteriskh263.c
 149 AC_CHECK_HEADERS([netinet/in.h])
 150 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 151 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl *** checks for types/defines ***
 157
 158 dnl Check for FIONREAD ioctl declaration.  This check is needed
 159 dnl for the UDP plugin to build on Solaris
 160 GST_CHECK_FIONREAD
 161
 162 dnl *** checks for structures ***
 163
 164 dnl *** checks for compiler characteristics ***
 165
 166 dnl check if we have GCC inline-asm
 167 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 168 if test x$HAVE_GCC_ASM = xyes ; then
 169   AC_DEFINE(HAVE_GCC_ASM, 1,
 170     [Define if compiler supports gcc inline assembly])
 171 fi
 172 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 173
 174 dnl *** checks for library functions ***
 175
 176 LIBS_SAVE=$LIBS
 177 LIBS="$LIBS $LIBM"
 178 AC_CHECK_FUNCS(rint sinh cosh asinh)
 179 LIBS=$LIBS_SAVE
 180
 181 dnl Check for mmap (needed by electricfence plugin)
 182 AC_FUNC_MMAP
 183 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 184
 185 dnl Check for mmap (needed by electricfence plugin)
 186
 187 AC_CHECK_TYPE([struct ip_mreqn], [
 188               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 189               [#include <netinet/in.h>])
 190
 191 dnl *** checks for dependency libraries ***
 192
 193 dnl GLib is required
 194 AG_GST_GLIB_CHECK([2.12])
 195
 196 dnl liboil is required
 197 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 198 if test "x$HAVE_LIBOIL" != "xyes"; then
 199   AC_ERROR([liboil-0.3.8 or later is required])
 200 fi
 201
 202 dnl checks for gstreamer
 203 dnl uninstalled is selected preferentially -- see pkg-config(1)
 204 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 205 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 206 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 207 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 208 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 209 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 210
 211 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 212 if test -z $GST_TOOLS_DIR; then
 213   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 214 fi
 215 AC_SUBST(GST_TOOLS_DIR)
 216
 217 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 218 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 219
 220 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 221
 222 dnl Check for documentation xrefs
 223 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 224 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 225 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 226 AC_SUBST(GLIB_PREFIX)
 227 AC_SUBST(GST_PREFIX)
 228 AC_SUBST(GSTPB_PREFIX)
 229
 230 dnl GTK is optional and used in examples
 231 if test "x$BUILD_EXAMPLES" = "xyes"; then
 232   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, HAVE_GTK=yes, HAVE_GTK=no)
 233   AC_SUBST(GTK_LIBS)
 234   AC_SUBST(GTK_CFLAGS)
 235 fi
 236 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 237
 238 dnl should we install schemas ?
 239 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 240 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 241   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 242   if test x$GCONFTOOL = xno; then
 243     AC_MSG_WARN(Not installing GConf schemas)
 244     HAVE_GCONFTOOL="no"
 245   else
 246     HAVE_GCONFTOOL="yes"
 247   fi
 248   AC_SUBST(HAVE_GCONFTOOL)
 249 ])
 250
 251 dnl *** set variables based on configure arguments ***
 252
 253 dnl set license and copyright notice
 254 GST_LICENSE="LGPL"
 255 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 256 AC_SUBST(GST_LICENSE)
 257
 258 dnl set location of plugin directory
 259 AG_GST_SET_PLUGINDIR
 260
 261 dnl define an ERROR_CFLAGS Makefile variable
 262 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 263
 264 dnl define an ERROR_CXXFLAGS Makefile variable
 265 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 266
 267 dnl define correct level for debugging messages
 268 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 269
 270 dnl used in examples
 271 AG_GST_DEFAULT_ELEMENTS
 272
 273 dnl *** plug-ins to include ***
 274
 275 dnl these are all the gst plug-ins, compilable without additional libs
 276 dnl videofilter is at the top because others depend on it
 277 AG_GST_CHECK_PLUGIN(videofilter)
 278 AG_GST_CHECK_PLUGIN(alpha)
 279 AG_GST_CHECK_PLUGIN(apetag)
 280 AG_GST_CHECK_PLUGIN(audiofx)
 281 AG_GST_CHECK_PLUGIN(auparse)
 282 AG_GST_CHECK_PLUGIN(autodetect)
 283 AG_GST_CHECK_PLUGIN(avi)
 284 AG_GST_CHECK_PLUGIN(cutter)
 285 AG_GST_CHECK_PLUGIN(debugutils)
 286 AG_GST_CHECK_PLUGIN(deinterlace)
 287 AG_GST_CHECK_PLUGIN(effectv)
 288 AG_GST_CHECK_PLUGIN(equalizer)
 289 AG_GST_CHECK_PLUGIN(flv)
 290 AG_GST_CHECK_PLUGIN(id3demux)
 291 AG_GST_CHECK_PLUGIN(icydemux)
 292 AG_GST_CHECK_PLUGIN(interleave)
 293 AG_GST_CHECK_PLUGIN(flx)
 294 AG_GST_CHECK_PLUGIN(goom)
 295 AG_GST_CHECK_PLUGIN(goom2k1)
 296 AG_GST_CHECK_PLUGIN(law)
 297 AG_GST_CHECK_PLUGIN(level)
 298 AG_GST_CHECK_PLUGIN(matroska)
 299 AG_GST_CHECK_PLUGIN(monoscope)
 300 AG_GST_CHECK_PLUGIN(multifile)
 301 AG_GST_CHECK_PLUGIN(multipart)
 302 AG_GST_CHECK_PLUGIN(qtdemux)
 303 AG_GST_CHECK_PLUGIN(replaygain)
 304 AG_GST_CHECK_PLUGIN(rtp)
 305 AG_GST_CHECK_PLUGIN(rtsp)
 306 AG_GST_CHECK_PLUGIN(smpte)
 307 AG_GST_CHECK_PLUGIN(spectrum)
 308 AG_GST_CHECK_PLUGIN(udp)
 309 AG_GST_CHECK_PLUGIN(videobox)
 310 AG_GST_CHECK_PLUGIN(videocrop)
 311 AG_GST_CHECK_PLUGIN(videomixer)
 312 AG_GST_CHECK_PLUGIN(wavenc)
 313 AG_GST_CHECK_PLUGIN(wavparse)
 314 AG_GST_CHECK_PLUGIN(y4m)
 315
 316 dnl *** checks for socket and nsl libraries ***
 317 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 318
 319 dnl disable gst plugins we might not be able to build on this
 320 dnl platform: udp and rtsp (ugly but minimally invasive)
 321 dnl FIXME: maybe move to sys
 322 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 323 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 324
 325 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 326   AG_GST_DISABLE_PLUGIN(udp)
 327   AG_GST_DISABLE_PLUGIN(rtsp)
 328 fi
 329
 330 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 331   WIN32_LIBS="-lws2_32"
 332   AC_SUBST(WIN32_LIBS)
 333 fi
 334
 335 dnl disable experimental plug-ins
 336 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 337   AG_GST_DISABLE_PLUGIN(monoscope)
 338 fi
 339
 340 dnl *** sys plug-ins ***
 341
 342 echo
 343 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 344 echo
 345
 346 dnl DirectSound
 347 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 348 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 349   HAVE_DIRECTSOUND="no"
 350   save_CFLAGS="$CFLAGS"
 351   save_LDFLAGS="$LDFLAGS"
 352   save_LIBS="$LIBS"
 353   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 354   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 355   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 356   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 357   AC_LINK_IFELSE([
 358 #include <windows.h>
 359 #include <dxerr9.h>
 360 #include <dsound.h>
 361
 362 int main ()
 363 {
 364   DXGetErrorString9 (0);
 365   DirectSoundCreate(NULL, NULL, NULL);
 366
 367   return 0;
 368 }
 369 ],
 370     [HAVE_DIRECTSOUND="yes"],
 371     [HAVE_DIRECTSOUND="no"])
 372   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 373   CFLAGS=$save_CFLAGS
 374   LDFLAGS=$save_LDFLAGS
 375   LIBS=$save_LIBS
 376
 377   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 378     dnl this is much more than we want
 379     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 380     AC_SUBST(DIRECTSOUND_CFLAGS)
 381     AC_SUBST(DIRECTSOUND_LDFLAGS)
 382     AC_SUBST(DIRECTSOUND_LIBS)
 383   fi
 384   AC_SUBST(HAVE_DIRECTSOUND)
 385 ])
 386
 387 dnl *** OSS audio *** (Linux, *BSD)
 388 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 389 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 390  HAVE_OSS="yes"
 391 dnl Linux and newer BSD versions :
 392  AC_CHECK_HEADER(sys/soundcard.h, [
 393    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 394    ] , [
 395 dnl Some old BSD versions and also newer OpenBSD versions :
 396    AC_CHECK_HEADER(soundcard.h, [
 397      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 398      ], [
 399   dnl Some old BSD versions :
 400      AC_CHECK_HEADER(machine/soundcard.h, [
 401        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 402          [Define if OSS includes are in /machine/])
 403        ], [
 404        HAVE_OSS="no"
 405      ])
 406    ])
 407  ])
 408 ])
 409
 410 dnl *** Sun Audio ***
 411 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 412 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 413   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 414 ])
 415
 416 dnl *** OSX Audio ***
 417 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 418 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 419   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 420 ])
 421
 422 dnl *** OS X video ***
 423 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 424 HAVE_OSX_VIDEO="no"
 425 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 426   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 427 ])
 428 dnl in case header OpenGL/gl.h is found on other platforms
 429 case "$host" in
 430   *-*darwin*)
 431     dnl do nothing
 432     ;;
 433   *)
 434     HAVE_OSX_VIDEO="no"
 435     ;;
 436 esac
 437
 438
 439 dnl *** Video 4 Linux 2 ***
 440 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 441 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 442 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 443 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 444   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 445   AC_TRY_COMPILE([
 446 #include <sys/types.h>
 447 #ifdef __sun /* Solaris */
 448 #include <sys/types.h>
 449 #include <sys/videodev2.h>
 450 #else /* Linux */
 451 #include <linux/types.h>
 452 #define _LINUX_TIME_H
 453 #define __user
 454 #include <linux/videodev2.h>
 455 #endif
 456 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 457 #error too early v4l2 version or no v4l2 at all
 458 #endif
 459     ], [
 460 return 0;
 461     ], [
 462       HAVE_GST_V4L2="yes"
 463       AC_MSG_RESULT(yes)
 464     ], [
 465       HAVE_GST_V4L2="no"
 466       AC_MSG_RESULT(no)
 467
 468       HAVE_VIDEODEV=no
 469       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 470       [
 471         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 472       ])
 473
 474       if test "x$HAVE_VIDEODEV" = "xyes"; then
 475         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 476         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 477       else
 478         AC_MSG_WARN([video4linux2 was not found])
 479       fi
 480     ])
 481
 482   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 483     dnl check for missing v4l2_buffer declaration (see #135919)
 484     MISSING_DECL=0
 485     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 486     AC_TRY_COMPILE([
 487 #include <sys/types.h>
 488 #ifdef __sun /* Solaris */
 489 #include <sys/types.h>
 490 #include <sys/videodev2.h>
 491 #else /* Linux */
 492 #include <linux/types.h>
 493 #define _LINUX_TIME_H
 494 #define __user
 495 #include <linux/videodev2.h>
 496 #endif
 497     ],[
 498 struct v4l2_buffer buf;
 499 buf.index = 0;
 500 return 0;
 501     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 502     if [ test x$MISSING_DECL = x1 ]; then
 503       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 504     fi
 505
 506     dnl check for XOverlay libraries
 507     AG_GST_CHECK_XV
 508   fi
 509 ])
 510
 511 # Make libv4l2 non-automagic
 512 AC_ARG_WITH([libv4l2],
 513   AC_HELP_STRING([--with-libv4l2],
 514     [support video buffer conversion using libv4l2]),
 515   [],
 516   [with_libv4l2=check])
 517 if test x$HAVE_GST_V4L2 = xyes; then
 518   if test x$with_libv4l2 != xno; then
 519       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 520           [ have_libv4l2=yes
 521             AC_DEFINE(HAVE_LIBV4L2, 1,
 522                 [Whether libv4l2 is available for video buffer conversion])
 523           ], [
 524           have_libv4l2=no
 525           ])
 526   else
 527     have_libv4l2=no
 528   fi
 529 fi
 530
 531 dnl Check for X11
 532 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 533 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 534                   [ximagesrc], [
 535   AC_PATH_XTRA
 536
 537   dnl now try to find the HEADER
 538   ac_cflags_save="$CFLAGS"
 539   ac_cppflags_save="$CPPFLAGS"
 540   CFLAGS="$CFLAGS $X_CFLAGS"
 541   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 542   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 543
 544   if test "x$HAVE_X" = "xno"
 545   then
 546     AC_MSG_NOTICE([cannot find X11 development files])
 547   else
 548     dnl this is much more than we want
 549     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 550     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 551     dnl it does not add the libs; therefore we add them here
 552     X_LIBS="$X_LIBS -lX11"
 553     AC_SUBST(X_CFLAGS)
 554     AC_SUBST(X_LIBS)
 555
 556     dnl check for Xfixes
 557     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 558     if test "x$HAVE_XFIXES" = "xyes"
 559     then
 560         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 561     fi
 562     AC_SUBST(XFIXES_LIBS)
 563     AC_SUBST(XFIXES_CFLAGS)
 564
 565     dnl check for Xdamage
 566     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 567     if test "x$HAVE_XDAMAGE" = "xyes"
 568     then
 569         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 570     fi
 571     AC_SUBST(XDAMAGE_LIBS)
 572     AC_SUBST(XDAMAGE_CFLAGS)
 573   fi
 574   AC_SUBST(HAVE_X)
 575   CFLAGS="$ac_cflags_save"
 576   CPPFLAGS="$ac_cppflags_save"
 577 ])
 578
 579 dnl FIXME: this should be rolled into the test above, it's just an additional
 580 dnl feature of the ximagesrc plug-in
 581 dnl This is the same as in gst-plugins-base
 582 dnl check for X Shm
 583 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 584 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 585   if test x$HAVE_X = xyes; then
 586     AC_CHECK_LIB(Xext, XShmAttach,
 587                  HAVE_XSHM="yes", HAVE_XSHM="no",
 588                  $X_LIBS)
 589     if test "x$HAVE_XSHM" = "xyes"; then
 590       XSHM_LIBS="-lXext"
 591     else
 592       dnl On AIX, it is in XextSam instead, but we still need -lXext
 593       AC_CHECK_LIB(XextSam, XShmAttach,
 594                    HAVE_XSHM="yes", HAVE_XSHM="no",
 595                    $X_LIBS)
 596       if test "x$HAVE_XSHM" = "xyes"; then
 597         XSHM_LIBS="-lXext -lXextSam"
 598       fi
 599     fi
 600   fi
 601 ], ,[
 602   AC_SUBST(HAVE_XSHM)
 603   AC_SUBST(XSHM_LIBS)
 604 ])
 605
 606 dnl for V4L2, we also need to know if we have XVIDEO
 607 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 608 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 609                   [], [
 610   AG_GST_CHECK_XV
 611 ])
 612
 613 dnl *** ext plug-ins ***
 614 dnl keep this list sorted alphabetically !
 615
 616 if test "x$BUILD_EXTERNAL" = "xyes"; then
 617
 618 echo
 619 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 620 echo
 621
 622 dnl *** aalib ***
 623 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 624 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 625   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 626   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 627 ])
 628
 629 dnl *** annodex ***
 630 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 631 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 632   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 633 ])
 634
 635 dnl *** cairo ***
 636 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 637 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 638   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 639 ])
 640
 641 dnl **** ESound ****
 642 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 643 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 644   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 645   if test $HAVE_ESD = no
 646   then
 647     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 648     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 649   fi
 650 ])
 651
 652 dnl *** FLAC ***
 653 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 654 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 655   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 656 ])
 657
 658 dnl *** GConf ***
 659 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 660 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 661   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 662 ])
 663
 664 dnl *** GDK pixbuf ***
 665 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 666 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 667   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 668 ])
 669
 670 dnl *** HAL ***
 671 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 672 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 673   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 674 ])
 675
 676 dnl *** jpeg ***
 677 dnl FIXME: we could use header checks here as well IMO
 678 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 679 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 680   AC_ARG_WITH(jpeg-mmx,
 681     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 682   OLD_LIBS="$LIBS"
 683   if test x$with_jpeg_mmx != x; then
 684     LIBS="$LIBS -L$with_jpeg_mmx"
 685   fi
 686   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 687   JPEG_LIBS="$LIBS -ljpeg-mmx"
 688   LIBS="$OLD_LIBS"
 689   if test x$HAVE_JPEG != xyes; then
 690     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 691     JPEG_LIBS="-ljpeg"
 692   fi
 693   AC_SUBST(JPEG_LIBS)
 694 ])
 695
 696 dnl *** libcaca ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 698 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 699   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 700   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 701   if test "x$HAVE_LIBCACA" != "xyes"; then
 702     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 703     dnl see if it compilation works too, might not if we are cross-compiling
 704     if test "x$HAVE_LIBCACA" = "xyes"; then
 705       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 706                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 707     fi
 708   fi
 709 ])
 710
 711 dnl *** libdv ***
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 713 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 714   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 715 ])
 716
 717 dnl *** libpng ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 719 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 720   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 721 ])
 722
 723 dnl *** pulseaudio ***
 724 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 725 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 726   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.8)
 727   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 728   if test x$HAVE_PULSE_0_9_11 = xyes; then
 729     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 730   fi
 731   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 732   if test x$HAVE_PULSE_0_9_12 = xyes; then
 733     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 734   fi
 735   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 736   if test x$HAVE_PULSE_0_9_13 = xyes; then
 737     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 738   fi
 739 ])
 740
 741 dnl *** dv1394 ***
 742 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 743 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 744   dnl first test for libraw1394 >= 1.2.1
 745   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 746   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 747   dnl now see how far we got
 748   if test x$HAVE_RAW1394 = xyes && \
 749      test x$HAVE_LIBIEC61883 = xyes; then
 750        AG_GST_CHECK_LIBHEADER(AVC1394,
 751         avc1394, avc1394_send_command, $RAW1394_LIBS,
 752         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 753        AG_GST_CHECK_LIBHEADER(ROM1394,
 754         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 755         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 756        if test x$HAVE_AVC1394 = xyes && \
 757           test x$HAVE_AVC1394 = xyes && \
 758           test x$HAVE_ROM1394 = xyes; then
 759           HAVE_DV1394=yes
 760           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 761           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 762           AC_SUBST(DV1394_CFLAGS)
 763           AC_SUBST(DV1394_LIBS)
 764         fi
 765   else
 766        if test x$HAVE_RAW1394 = xno; then
 767           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 768           AG_GST_CHECK_LIBHEADER(AVC1394,
 769            avc1394, avc1394_send_command, $RAW1394_LIBS,
 770            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 771           AG_GST_CHECK_LIBHEADER(ROM1394,
 772            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 773            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 774           if test x$HAVE_RAW1394 = xyes && \
 775              test x$HAVE_AVC1394 = xyes && \
 776              test x$HAVE_ROM1394 = xyes; then
 777              HAVE_DV1394=yes
 778              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 779              DV1394_CFLAGS="$RAW1394_CFLAGS"
 780              if test x$HAVE_LIBIEC61883 = xyes; then
 781                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 782                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 783              fi
 784              AC_SUBST(DV1394_CFLAGS)
 785              AC_SUBST(DV1394_LIBS)
 786            fi
 787          fi
 788   fi
 789 ])
 790
 791 dnl *** shout2 ***
 792 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 793 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 794   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 795   if test $HAVE_SHOUT2 = no
 796   then
 797     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 798     AC_SUBST(SHOUT2_CFLAGS)
 799     AC_SUBST(SHOUT2_LIBS)
 800   fi
 801 ])
 802
 803 dnl *** soup ***
 804 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 805 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 806   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 807     HAVE_SOUP="yes"
 808     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 809   ],[
 810     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 811       HAVE_SOUP="no"
 812       AC_MSG_RESULT(no)
 813     ])
 814   ])
 815   AC_SUBST(SOUP_CFLAGS)
 816   AC_SUBST(SOUP_LIBS)
 817 ])
 818
 819 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 820 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 821 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 822 dnl   speex_jitter.h is 1.1.x only
 823 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 824 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 825   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 826   if test $HAVE_SPEEX = no
 827   then
 828     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 829       AC_CHECK_HEADER(speex/speex_jitter.h, [
 830         dnl speex 1.1.x :
 831         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 832           dnl speex 1.1.5 or + :
 833           HAVE_SPEEX="yes"
 834           SPEEX_LIBS="-lspeex"
 835           AC_SUBST(SPEEX_CFLAGS)
 836           AC_SUBST(SPEEX_LIBS)
 837         ],[
 838           HAVE_SPEEX="no"
 839         ])
 840       ],[
 841         dnl speex 1.0.x :
 842           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 843             dnl speex 1.0.4
 844             HAVE_SPEEX="yes"
 845             SPEEX_LIBS="-lspeex"
 846             AC_SUBST(SPEEX_CFLAGS)
 847             AC_SUBST(SPEEX_LIBS)
 848
 849             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 850               [defined if speex 1.0.x API detected])
 851         ],[
 852             HAVE_SPEEX="no"
 853             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 854         ], [
 855 #include <speex/speex.h>
 856         ])
 857       ])
 858     ])
 859   fi
 860 ])
 861
 862 dnl *** taglib ***
 863 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 864 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 865   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 866   if test "x$HAVE_CXX" != "xyes"; then
 867     USE_TAGLIB=false
 868     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 869   else
 870     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 871     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 872         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 873       ], [
 874         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 875     ])
 876     AC_SUBST(TAGLIB_CXXFLAGS)
 877   fi
 878 ])
 879
 880 dnl *** wavpack ***
 881 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 882 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 883   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 884     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 885       HAVE_WAVPACK=yes
 886       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 887     ],[
 888       HAVE_WAVPACK=no
 889       AC_MSG_RESULT(no)
 890     ])
 891   ])
 892   AC_SUBST(WAVPACK_CFLAGS)
 893   AC_SUBST(WAVPACK_LIBS)
 894 ])
 895
 896 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 897 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 898 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 899   AG_GST_CHECK_LIBHEADER(ZLIB,
 900     z, uncompress,, zlib.h, [
 901     HAVE_ZLIB="yes"
 902     ZLIB_LIBS="-lz"
 903     AC_SUBST(ZLIB_LIBS)
 904   ])
 905 ])
 906
 907 dnl *** matroska prefers to have bz2 ***
 908 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 909 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 910   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 911   AC_SUBST(BZ2_LIBS)
 912 ])
 913
 914 else
 915
 916 dnl not building plugins with external dependencies,
 917 dnl but we still need to set the conditionals
 918 AM_CONDITIONAL(USE_AALIB, false)
 919 AM_CONDITIONAL(USE_ANNODEX, false)
 920 AM_CONDITIONAL(USE_BZ2, false)
 921 AM_CONDITIONAL(USE_CAIRO, false)
 922 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 923 AM_CONDITIONAL(USE_DV1394, false)
 924 AM_CONDITIONAL(USE_ESD, false)
 925 AM_CONDITIONAL(USE_FLAC, false)
 926 AM_CONDITIONAL(USE_GCONF, false)
 927 AM_CONDITIONAL(USE_GCONFTOOL, false)
 928 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 929 AM_CONDITIONAL(USE_GST_V4L2, false)
 930 AM_CONDITIONAL(USE_HAL, false)
 931 AM_CONDITIONAL(USE_JPEG, false)
 932 AM_CONDITIONAL(USE_LIBCACA, false)
 933 AM_CONDITIONAL(USE_LIBDV, false)
 934 AM_CONDITIONAL(USE_LIBPNG, false)
 935 AM_CONDITIONAL(USE_OSS, false)
 936 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 937 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 938 AM_CONDITIONAL(USE_PULSE, false)
 939 AM_CONDITIONAL(USE_SHOUT2, false)
 940 AM_CONDITIONAL(USE_SOUP, false)
 941 AM_CONDITIONAL(USE_SPEEX, false)
 942 AM_CONDITIONAL(USE_SUNAUDIO, false)
 943 AM_CONDITIONAL(USE_TAGLIB, false)
 944 AM_CONDITIONAL(USE_WAVPACK, false)
 945 AM_CONDITIONAL(USE_X, false)
 946 AM_CONDITIONAL(USE_XSHM, false)
 947 AM_CONDITIONAL(USE_XVIDEO, false)
 948 AM_CONDITIONAL(USE_ZLIB, false)
 949
 950 fi dnl of EXT plugins
 951
 952 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 953
 954 dnl Overview:
 955 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 956 dnl GST_*:              flags shared by all built objects
 957 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 958 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 959 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 960 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 961
 962 dnl GST_OPTION_CFLAGS
 963 if test "x$USE_DEBUG" = xyes; then
 964    PROFILE_CFLAGS="-g"
 965 fi
 966 AC_SUBST(PROFILE_CFLAGS)
 967
 968 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 969   dnl Define _only_ during CVS (not pre-releases or releases)
 970   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 971 else
 972   DEPRECATED_CFLAGS=""
 973 fi
 974 AC_SUBST(DEPRECATED_CFLAGS)
 975
 976 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 977 dnl at make time with e.g. make ERROR_CFLAGS=""
 978 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 979 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 980 AC_SUBST(GST_OPTION_CFLAGS)
 981 AC_SUBST(GST_OPTION_CXXFLAGS)
 982
 983 dnl our libraries need to be versioned correctly
 984 AC_SUBST(GST_LT_LDFLAGS)
 985
 986 dnl FIXME: do we want to rename to GST_ALL_* ?
 987 dnl prefer internal headers to already installed ones
 988 dnl also add builddir include for enumtypes and marshal
 989 dnl add ERROR_CFLAGS, but overridable
 990 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 991 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CXXFLAGS \$(GST_OPTION_CXXFLAGS)"
 992 AC_SUBST(GST_CFLAGS)
 993 AC_SUBST(GST_CXXFLAGS)
 994 AC_SUBST(GST_LIBS)
 995
 996 dnl LDFLAGS really should only contain flags, not libs - they get added before
 997 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 998 GST_ALL_LDFLAGS="-no-undefined"
 999 AC_SUBST(GST_ALL_LDFLAGS)
1000
1001 dnl this really should only contain flags, not libs - they get added before
1002 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1003 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1004 AC_SUBST(GST_PLUGIN_LDFLAGS)
1005
1006 SHAVE_INIT([common],[enable])
1007 dnl *** output files ***
1008
1009 dnl keep this alphabetic per directory, please
1010 AC_CONFIG_FILES(
1011 Makefile
1012 common/shave
1013 common/shave-libtool
1014 gst/Makefile
1015 gst/alpha/Makefile
1016 gst/apetag/Makefile
1017 gst/audiofx/Makefile
1018 gst/auparse/Makefile
1019 gst/autodetect/Makefile
1020 gst/avi/Makefile
1021 gst/cutter/Makefile
1022 gst/deinterlace/Makefile
1023 gst/debugutils/Makefile
1024 gst/effectv/Makefile
1025 gst/equalizer/Makefile
1026 gst/flv/Makefile
1027 gst/id3demux/Makefile
1028 gst/icydemux/Makefile
1029 gst/interleave/Makefile
1030 gst/goom/Makefile
1031 gst/goom2k1/Makefile
1032 gst/law/Makefile
1033 gst/level/Makefile
1034 gst/matroska/Makefile
1035 gst/monoscope/Makefile
1036 gst/multifile/Makefile
1037 gst/multipart/Makefile
1038 gst/qtdemux/Makefile
1039 gst/replaygain/Makefile
1040 gst/rtp/Makefile
1041 gst/rtsp/Makefile
1042 gst/smpte/Makefile
1043 gst/spectrum/Makefile
1044 gst/udp/Makefile
1045 gst/videobox/Makefile
1046 gst/videocrop/Makefile
1047 gst/videofilter/Makefile
1048 gst/videomixer/Makefile
1049 gst/wavenc/Makefile
1050 gst/wavparse/Makefile
1051 gst/flx/Makefile
1052 gst/y4m/Makefile
1053 ext/jpeg/Makefile
1054 ext/Makefile
1055 ext/aalib/Makefile
1056 ext/annodex/Makefile
1057 ext/cairo/Makefile
1058 ext/dv/Makefile
1059 ext/esd/Makefile
1060 ext/flac/Makefile
1061 ext/gconf/Makefile
1062 ext/gdk_pixbuf/Makefile
1063 ext/hal/Makefile
1064 ext/ladspa/Makefile
1065 ext/libcaca/Makefile
1066 ext/libpng/Makefile
1067 ext/pulse/Makefile
1068 ext/raw1394/Makefile
1069 ext/shout2/Makefile
1070 ext/soup/Makefile
1071 ext/speex/Makefile
1072 ext/taglib/Makefile
1073 ext/wavpack/Makefile
1074 sys/Makefile
1075 sys/directsound/Makefile
1076 sys/oss/Makefile
1077 sys/sunaudio/Makefile
1078 sys/osxaudio/Makefile
1079 sys/osxvideo/Makefile
1080 sys/v4l2/Makefile
1081 sys/waveform/Makefile
1082 sys/ximage/Makefile
1083 po/Makefile.in
1084 tests/Makefile
1085 tests/check/Makefile
1086 tests/examples/Makefile
1087 tests/examples/audiofx/Makefile
1088 tests/examples/equalizer/Makefile
1089 tests/examples/level/Makefile
1090 tests/examples/rtp/Makefile
1091 tests/examples/spectrum/Makefile
1092 tests/files/Makefile
1093 tests/icles/Makefile
1094 gconf/Makefile
1095 gconf/gstreamer.schemas
1096 common/Makefile
1097 common/m4/Makefile
1098 m4/Makefile
1099 docs/Makefile
1100 docs/plugins/Makefile
1101 docs/version.entities
1102 pkgconfig/Makefile
1103 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1104 gst-plugins-good.spec
1105 )
1106
1107 dnl Create the config.h file for Visual Studio builds
1108 dnl Beware of spaces and /'s in some of the shell variable contents.
1109 sed \
1110     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1111     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1112     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1113     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1114     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1115     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1116     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1117     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1118     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1119     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1120     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1121     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1122     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1123     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1124     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1125     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1126     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1127     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1128     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1129     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1130     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1131     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1132     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1133     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1134     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1135     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1136     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1137     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1138     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1139     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1140     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1141     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1142     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1143     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1144     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1145     config.h.in >win32/common/config.h-new
1146
1147 AC_OUTPUT
1148
1149 AG_GST_OUTPUT_PLUGINS