configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.11.1])
  10 AC_CONFIG_SRCDIR([src/rygel/rygel-root-device.vala])
  11 AC_CONFIG_HEADERS([config.h])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 AC_SEARCH_LIBS([strerror],[cposix])
  16 AC_PROG_CC
  17 AC_HEADER_STDC
  18 AC_FUNC_MMAP
  19
  20 # Disable generation of static libraries
  21 LT_PREREQ([2.2.6])
  22 LT_INIT([dlopen disable-static])
  23
  24 VALA_REQUIRED=0.11.6
  25 GSSDP_REQUIRED=0.9.2
  26 GUPNP_REQUIRED=0.13.4
  27 GUPNP_AV_REQUIRED=0.7.0
  28 GUPNP_DLNA_REQUIRED=0.5.0
  29 GUPNP_VALA_REQUIRED=0.7.5
  30 GSTREAMER_REQUIRED=0.10.23
  31 GSTREAMER_TAG_REQUIRED=0.10.28
  32 GSTREAMER_APP_REQUIRED=0.10.28
  33 GIO_REQUIRED=2.26
  34 GEE_REQUIRED=0.5.2
  35 UUID_REQUIRED=1.41.3
  36 LIBSOUP_REQUIRED=2.26.0
  37 LIBSQLITE3_REQUIRED=3.5
  38 GTK_REQUIRED=2.90.3
  39
  40 PKG_CHECK_MODULES(LIBGSSDP, gssdp-1.0 >= $GSSDP_REQUIRED)
  41 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED)
  42 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED)
  43 PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.0 >= $GUPNP_DLNA_REQUIRED)
  44 PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED)
  45 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  46 PKG_CHECK_MODULES(GEE, gee-1.0 >= $GEE_REQUIRED)
  47 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  48 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED)
  49
  50 # glib-genmarshal
  51 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
  52 AC_SUBST(GLIB_GENMARSHAL)
  53
  54 AC_ARG_ENABLE(sql-debugging,
  55     AS_HELP_STRING([--enable-sql-debugging],[enable SQL statement debugging]),,
  56         enable_sql_debugging=no)
  57 AS_IF([test x$enable_sql_debugging = xyes],
  58       [RYGEL_ADD_VALAFLAGS([-D RYGEL_DEBUG_SQL])])
  59
  60 dnl Add plugins
  61 RYGEL_ADD_PLUGIN([test],[Test],[no])
  62 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
  63 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
  64 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
  65 RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
  66 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
  67 RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
  68 RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
  69
  70 dnl Explicitly add stamp files for targets that are not plugins
  71 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
  72 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
  73
  74 RYGEL_CHECK_VALA([$VALA_REQUIRED],
  75                  [gupnp-1.0
  76                   gupnp-av-1.0
  77                   gupnp-dlna-1.0
  78                   gstreamer-0.10
  79                   gstreamer-pbutils-0.10
  80                   gio-2.0
  81                   gee-1.0
  82                   posix])
  83
  84 # Debugging
  85 AC_ARG_ENABLE(debug,
  86         AS_HELP_STRING([--enable-debug],[enable debugging]),,
  87         enable_debug=no)
  88 if test "x$enable_debug" = "xyes"; then
  89         CFLAGS="$CFLAGS -O0 -g"
  90 fi
  91
  92 # Strict compiler
  93 AC_ARG_ENABLE(strict-cc,
  94         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
  95         enable_strict_cc=no)
  96 if test "x$enable_strict_cc" = "xyes"; then
  97         CFLAGS="$CFLAGS -Wall -Werror"
  98 else
  99         CFLAGS="$CFLAGS -w"
 100 fi
 101
 102 # Run uninstalled
 103 AC_ARG_ENABLE(uninstalled,
 104     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 105         enable_uninstalled=no)
 106 if test "x$enable_uninstalled" = "xyes"; then
 107         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 108 fi
 109
 110 # Check wether user wants to build UIs
 111 AC_ARG_WITH( ui,
 112   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 113   try_ui=$withval, try_ui=yes )
 114
 115 HAVE_GTK=no
 116 if test x$try_ui = xyes ; then
 117     dnl check for gtk
 118     PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQUIRED,
 119       [
 120         if test x$enable_vala = xyes ; then
 121                 VALA_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 122         else
 123                 HAVE_GTK=yes
 124         fi
 125       ],
 126       [
 127         HAVE_GTK=no
 128         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 129         AC_MSG_WARN([UI applications will not be built.])
 130       ])
 131 else
 132     AC_MSG_NOTICE([UI applications disabled.])
 133 fi
 134
 135 if test x$HAVE_GTK = xno; then
 136   BUILD_UI=no
 137 else
 138   BUILD_UI=yes
 139   AC_DEFINE(HAVE_GTK, , [Build UI applications])
 140 fi
 141
 142 AC_SUBST(HAVE_GTK)
 143 AM_CONDITIONAL(BUILD_UI, test x$BUILD_UI = xyes)
 144
 145 AC_SUBST(abs_top_builddir)
 146
 147 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 148
 149 if test "x$enable_media_export_plugin" = "xyes";
 150 then
 151     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 152     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-0.10 >= $GSTREAMER_TAG_REQUIRED);
 153     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-0.10 >= $GSTREAMER_APP_REQUIRED);
 154     if test x$enable_vala = xyes ; then
 155         VALA_CHECK_PACKAGES([sqlite3
 156                              gstreamer-tag-0.10
 157                              gstreamer-app-0.10])
 158     fi
 159 fi
 160
 161 # Gettext
 162 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 163 AC_SUBST(GETTEXT_PACKAGE)
 164 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 165   [Define the gettext package to be used])
 166
 167 AM_GLIB_GNU_GETTEXT
 168 IT_PROG_INTLTOOL([0.40.0])
 169
 170 dnl Shave the output
 171 AM_SILENT_RULES([yes])
 172
 173 dnl documenation
 174 AC_PATH_PROG([XSLTPROC], [xsltproc])
 175 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 176
 177 AC_SUBST(VERSION)
 178
 179 AC_CONFIG_FILES([
 180 Makefile
 181 src/Makefile
 182 src/rygel/Makefile
 183 src/ui/Makefile
 184 src/plugins/Makefile
 185 data/Makefile
 186 data/xml/Makefile
 187 data/icons/Makefile
 188 data/icons/32x32/Makefile
 189 data/icons/48x48/Makefile
 190 data/icons/120x120/Makefile
 191 data/icons/scalable/Makefile
 192 data/rygel.desktop.in
 193 data/rygel-preferences.desktop.in
 194 doc/Makefile
 195 po/Makefile.in
 196 rygel-1.0.pc
 197 tests/Makefile
 198 ])
 199 AC_OUTPUT
 200
 201 echo "
 202
 203                     ${PACKAGE} ${VERSION}
 204                     ============
 205
 206
 207         Prefix:                 ${prefix}
 208         Source code location:   ${srcdir}
 209         Compiler:               ${CC}
 210         CFLAGS:                 ${CFLAGS}
 211         uninstalled:            ${enable_uninstalled}
 212         preferences ui:         ${BUILD_UI}
 213         SQL debugging:          ${enable_sql_debugging}
 214     Plugins:
 215         test:                   ${enable_test_plugin}
 216         tracker:                ${enable_tracker_plugin}
 217         mediathek:              ${enable_mediathek_plugin}
 218         media-export            ${enable_media_export_plugin}
 219         external:               ${enable_external_plugin}
 220         MPRIS2:                 ${enable_mpris_plugin}
 221         gst-launch:             ${enable_gst_launch_plugin}
 222         playbin:                ${enable_playbin_plugin}
 223 "