configure.ac

   1 dnl These m4 macros are whitespace sensitive and break if moved around much.
   2 m4_define([LU_VERSION_H], m4_include([libusb/version.h]))
   3 m4_define([LU_DEFINE_VERSION_ATOM],
   4         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   5         [^#define\s*$1\s*\([0-9]*\).*], [\1]))])
   6 m4_define([LU_DEFINE_VERSION_RC_ATOM],
   7         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   8         [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))])
   9 dnl The m4_bregexp() returns (only) the numbers following the #define named
  10 dnl in the first macro parameter. m4_define() then defines the name for use
  11 dnl in AC_INIT().
  12
  13 LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR])
  14 LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR])
  15 LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO])
  16 LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC])
  17
  18 AC_INIT([libusb], LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC, [libusb-devel@lists.sourceforge.net], [libusb], [http://www.libusb.org/])
  19
  20 # Library versioning
  21 # These numbers should be tweaked on every release. Read carefully:
  22 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  23 # http://sourceware.org/autobook/autobook/autobook_91.html
  24 lt_current="1"
  25 lt_revision="0"
  26 lt_age="1"
  27 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_CONFIG_SRCDIR([libusb/core.c])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 AM_CONFIG_HEADER([config.h])
  35 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  36
  37 AC_PREREQ([2.50])
  38 AC_PROG_CC
  39 AC_PROG_LIBTOOL
  40 LT_LANG([Windows Resource])
  41 AC_C_INLINE
  42 AM_PROG_CC_C_O
  43 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  44
  45 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  46
  47 AC_MSG_CHECKING([operating system])
  48 case $host in
  49 *-linux*)
  50         AC_MSG_RESULT([Linux])
  51         backend="linux"
  52         ;;
  53 *-darwin*)
  54         AC_MSG_RESULT([Darwin/Mac OS X])
  55         backend="darwin"
  56         ;;
  57 *-openbsd*)
  58         AC_MSG_RESULT([OpenBSD])
  59         backend="openbsd"
  60         ;;
  61 *-netbsd*)
  62         AC_MSG_RESULT([NetBSD (using OpenBSD backend)])
  63         backend="openbsd"
  64         ;;
  65 *-mingw*)
  66         AC_MSG_RESULT([Windows])
  67         backend="windows"
  68         ;;
  69 *-cygwin*)
  70         AC_MSG_RESULT([Cygwin (using Windows backend)])
  71         backend="windows"
  72         threads="posix"
  73         ;;
  74 *)
  75         AC_MSG_ERROR([unsupported operating system])
  76 esac
  77 case $backend in
  78 linux)
  79         AC_DEFINE(OS_LINUX, 1, [Linux backend])
  80         AC_SUBST(OS_LINUX)
  81         AC_CHECK_LIB(rt, clock_gettime, PC_LIBS_PRIVATE="-lrt")
  82         threads="posix"
  83         THREAD_CFLAGS="-pthread"
  84         PC_LIBS_PRIVATE="${PC_LIBS_PRIVATE} -pthread"
  85         AC_CHECK_HEADERS([poll.h])
  86         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
  87         ;;
  88 darwin)
  89         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
  90         AC_SUBST(OS_DARWIN)
  91         threads="posix"
  92         PC_LIBS_PRIVATE="-lobjc -Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
  93         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
  94         AC_CHECK_HEADERS([poll.h])
  95         AC_CHECK_TYPE([nfds_t],
  96                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
  97                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
  98                 [#include <poll.h>])
  99         ;;
 100 openbsd)
 101         AC_DEFINE(OS_OPENBSD, 1, [OpenBSD backend])
 102         AC_SUBST(OS_OPENBSD)
 103         threads="posix"
 104         THREAD_CFLAGS="-pthread"
 105         PC_LIBS_PRIVATE="-pthread"
 106         AC_CHECK_HEADERS([poll.h])
 107         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 108         ;;
 109 windows)
 110         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
 111         AC_SUBST(OS_WINDOWS)
 112         PC_LIBS_PRIVATE=""
 113         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
 114         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
 115         ;;
 116 esac
 117 AC_SUBST(THREAD_CFLAGS)
 118 AC_SUBST(PC_LIBS_PRIVATE)
 119 LIBS="${LIBS} ${PC_LIBS_PRIVATE}"
 120
 121 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
 122 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
 123 AM_CONDITIONAL(OS_OPENBSD, test "x$backend" = xopenbsd)
 124 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
 125 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
 126 if test "$threads" = posix; then
 127         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
 128 fi
 129
 130 # timerfd
 131 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 132 AC_ARG_ENABLE([timerfd],
 133         [AS_HELP_STRING([--enable-timerfd],
 134                 [use timerfd for timing (default auto)])],
 135         [use_timerfd=$enableval], [use_timerfd='auto'])
 136
 137 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 138         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 139 fi
 140
 141 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 142 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 143         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 144 fi
 145
 146 AC_MSG_CHECKING([whether to use timerfd for timing])
 147 if test "x$use_timerfd" = "xno"; then
 148         AC_MSG_RESULT([no (disabled by user)])
 149 else
 150         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 151                 AC_MSG_RESULT([yes])
 152                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 153         else
 154                 AC_MSG_RESULT([no (header not available)])
 155         fi
 156 fi
 157
 158 AC_CHECK_TYPES(struct timespec)
 159
 160 # Message logging
 161 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 162         [log_enabled=$enableval],
 163         [log_enabled='yes'])
 164 if test "x$log_enabled" != "xno"; then
 165         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 166 fi
 167
 168 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 169         [enable debug logging (default n)])],
 170         [debug_log_enabled=$enableval],
 171         [debug_log_enabled='no'])
 172 if test "x$debug_log_enabled" != "xno"; then
 173         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
 174 fi
 175
 176 # Examples build
 177 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 178         [build example applications (default n)])],
 179         [build_examples=$enableval],
 180         [build_examples='no'])
 181 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 182
 183 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 184 saved_cflags="$CFLAGS"
 185 # -Werror required for cygwin
 186 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 187 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 188         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 189          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 190         [ VISIBILITY_CFLAGS=""
 191          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 192         ])
 193 CFLAGS="$saved_cflags"
 194
 195 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 196 saved_cflags="$CFLAGS"
 197 CFLAGS="$CFLAGS -Wno-pointer-sign"
 198 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 199         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 200 CFLAGS="$saved_cflags"
 201
 202 # sigaction not available on MinGW
 203 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 204 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 205
 206 # headers not available on all platforms but required on others
 207 AC_CHECK_HEADERS([sys/time.h])
 208 AC_CHECK_FUNCS(gettimeofday)
 209
 210 AM_CFLAGS="-std=gnu99 -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
 211
 212 AC_SUBST(VISIBILITY_CFLAGS)
 213 AC_SUBST(AM_CFLAGS)
 214 AC_SUBST(LTLDFLAGS)
 215
 216 AC_CONFIG_FILES([libusb-1.0.pc])
 217 AC_CONFIG_FILES([Makefile])
 218 AC_CONFIG_FILES([libusb/Makefile])
 219 AC_CONFIG_FILES([examples/Makefile])
 220 AC_CONFIG_FILES([doc/Makefile])
 221 AC_CONFIG_FILES([doc/doxygen.cfg])
 222 AC_OUTPUT