configure.ac

   1 #
   2 #  This file is part of gummiboot.
   3 #
   4 #  Copyright (C) 2013 Karel Zak <kzak@redhat.com>
   5 #
   6 #  gummiboot is free software; you can redistribute it and/or modify it
   7 #  under the terms of the GNU Lesser General Public License as published by
   8 #  the Free Software Foundation; either version 2.1 of the License, or
   9 #  (at your option) any later version.
  10 #
  11 #  gummiboot is distributed in the hope that it will be useful, but
  12 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14 #  Lesser General Public License for more details.
  15 #
  16 #  You should have received a copy of the GNU Lesser General Public License
  17 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_INIT([gummiboot],
  20         [39],
  21         [systemd-devel@lists.freedesktop.org],
  22         [gummiboot],
  23         [http://freedesktop.org/wiki/Software/gummiboot])
  24
  25 AC_CONFIG_SRCDIR([src/setup/setup.c])
  26 AC_CONFIG_MACRO_DIR([m4])
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_AUX_DIR([build-aux])
  29 AC_PREFIX_DEFAULT([/usr])
  30
  31 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects])
  32 AM_SILENT_RULES([yes])
  33
  34 AC_CANONICAL_HOST
  35 AC_SYS_LARGEFILE
  36
  37 AC_PROG_CC
  38
  39 dnl Don't try to use things like -std=c99 for efi compilation
  40 EFI_CC=$CC
  41 AC_SUBST([EFI_CC])
  42
  43 AC_PROG_CC_C99
  44 AM_PROG_CC_C_O
  45 AC_PROG_GCC_TRADITIONAL
  46
  47 AC_PROG_MKDIR_P
  48 AC_PATH_PROG([XSLTPROC], [xsltproc])
  49
  50 dnl Define ARCH_<NAME> conditionals
  51 SET_ARCH(IA32, i*86*)
  52 SET_ARCH(X86_64, x86_64*)
  53 SET_ARCH(IA64, ia64*)
  54
  55 ARCH=`echo $host | sed "s/\(-\).*$//"`
  56
  57 AM_COND_IF(ARCH_IA32, [
  58         ARCH=ia32
  59         MACHINE_TYPE_NAME=ia32])
  60
  61 AM_COND_IF(ARCH_X86_64, [
  62         MACHINE_TYPE_NAME=x64])
  63
  64 AC_SUBST([ARCH])
  65 AC_SUBST([MACHINE_TYPE_NAME])
  66
  67 # QEMU and OVMF UEFI firmware
  68 AS_IF([test x"$cross_compiling" = "xyes"], [], [
  69         AC_PATH_PROG([QEMU], [qemu-kvm])
  70         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin])
  71         AC_CHECK_FILE([/usr/share/qemu-ovmf/bios],     [QEMU_BIOS=/usr/share/qemu-ovmf/bios/bios.bin])
  72         AC_SUBST([QEMU_BIOS])
  73 ])
  74
  75 # ------------------------------------------------------------------------------
  76 dnl GNU EFI doesn't use relative paths: efi.h includes efibind.h which is in
  77 dnl ${ARCH} relative to efi.h. I can't find a way to get AC_CHECK_HEADERS to
  78 dnl add -I/usr/include/efi/${ARCH} to the conftest.c build. So, just test for
  79 dnl efibind.h as the chances of efi.h not existing if it does are very low.
  80 AC_CHECK_HEADER(efi/${ARCH}/efibind.h, [],
  81         [AC_MSG_ERROR([*** GNU EFI header efibind.h not found])])
  82
  83 efiroot=$(echo $(cd /usr/lib/$(gcc -print-multi-os-directory); pwd))
  84 EFI_LIB_DIR="$efiroot"
  85 AC_ARG_WITH(efi-libdir,
  86         AS_HELP_STRING([--with-efi-libdir=PATH], [Path to efi lib directory]),
  87         [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
  88 )
  89 AC_SUBST([EFI_LIB_DIR])
  90
  91 dnl extra objects and linker scripts
  92 AC_ARG_WITH(efi-ldsdir,
  93         AS_HELP_STRING([--with-efi-ldsdir=PATH], [Path to efi lds directory]),
  94         [EFI_LDS_DIR="$withval"],
  95         [
  96                 for EFI_LDS_DIR in "${efiroot}/gnuefi" "${efiroot}"; do
  97                     for lds in ${EFI_LDS_DIR}/elf_${ARCH}_efi.lds; do
  98                             test -f ${lds} && break 2
  99                     done
 100                 done
 101         ]
 102 )
 103 AC_SUBST([EFI_LDS_DIR])
 104
 105 AC_ARG_WITH(efi-includedir,
 106         AS_HELP_STRING([--with-efi-includedir=PATH], [Path to efi include directory]),
 107         [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
 108 )
 109 AC_SUBST([EFI_INC_DIR])
 110
 111 # ------------------------------------------------------------------------------
 112 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 113 if test "x$enable_blkid" != "xno"; then
 114         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 115                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 116         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 117                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 118         fi
 119 fi
 120 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 121
 122 # ------------------------------------------------------------------------------
 123 have_manpages=no
 124 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 125 AS_IF([test "x$enable_manpages" != xno], [
 126         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 127                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 128         ])
 129         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 130 ])
 131 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 132
 133 # ------------------------------------------------------------------------------
 134 AC_CONFIG_FILES([
 135         Makefile
 136 ])
 137
 138 AC_OUTPUT
 139 AC_MSG_RESULT([
 140         $PACKAGE_NAME $VERSION
 141
 142         prefix:                  ${prefix}
 143         arch:                    $ARCH
 144         EFI machine type:        $MACHINE_TYPE_NAME
 145
 146         EFI libdir:              ${EFI_LIB_DIR}
 147         EFI ldsdir:              ${EFI_LDS_DIR}
 148         EFI includedir:          ${EFI_INC_DIR}
 149
 150         blkid:                   ${have_blkid}
 151         man pages:               ${have_manpages}
 152
 153         QEMU:                    ${QEMU}
 154         QEMU OVMF:               ${QEMU_BIOS}
 155 ])