configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.30.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 AG_GST_LIBTOOL_PREPARE
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** required versions of GStreamer stuff ***
  57 GST_REQ=0.10.35.1
  58 GSTPB_REQ=0.10.35.1
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 AG_GST_ARG_WITH_PLUGINS
  88
  89 AG_GST_ARG_ENABLE_EXTERNAL
  90
  91 AG_GST_ARG_ENABLE_EXPERIMENTAL
  92
  93 dnl *** checks for platform ***
  94
  95 dnl * hardware/architecture *
  96
  97 dnl common/m4/gst-arch.m4
  98 dnl check CPU type
  99 AG_GST_ARCH
 100
 101 dnl Determine endianness
 102 AC_C_BIGENDIAN
 103
 104 dnl *** checks for programs ***
 105
 106 dnl find a compiler
 107 AC_PROG_CC
 108 AC_PROG_CC_STDC
 109
 110 dnl determine c++ compiler
 111 AC_PROG_CXX
 112 dnl determine if c++ is available on this system
 113 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 114
 115 dnl determine c++ preprocessor
 116 dnl FIXME: do we need this ?
 117 AC_PROG_CXXCPP
 118
 119 AS_PROG_OBJC
 120
 121 dnl check if the compiler supports '-c' and '-o' options
 122 AM_PROG_CC_C_O
 123
 124 dnl find an assembler
 125 AM_PROG_AS
 126
 127 dnl check if the compiler supports do while(0) macros
 128 AG_GST_CHECK_DOWHILE_MACROS
 129
 130 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 131 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 132
 133 dnl check for gconftool-2
 134 dnl this macro defines an am conditional, so it needs to be run always
 135 AM_GCONF_SOURCE_2
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl check for libm, for sin()
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used by ext/wavpack
 154 AX_CREATE_STDINT_H
 155
 156 dnl used in gst/rtp/gstasteriskh263.c
 157 AC_CHECK_HEADERS([netinet/in.h])
 158 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 159 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 160
 161 dnl used in gst/udp
 162 AC_CHECK_HEADERS([sys/time.h])
 163
 164 dnl *** checks for types/defines ***
 165
 166 dnl Check for FIONREAD ioctl declaration.  This check is needed
 167 dnl for the UDP plugin to build on Solaris
 168 GST_CHECK_FIONREAD
 169
 170 dnl *** checks for structures ***
 171
 172 dnl *** checks for compiler characteristics ***
 173
 174 dnl check if we have GCC inline-asm
 175 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 176 if test x$HAVE_GCC_ASM = xyes ; then
 177   AC_DEFINE(HAVE_GCC_ASM, 1,
 178     [Define if compiler supports gcc inline assembly])
 179 fi
 180 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 181
 182 dnl *** checks for library functions ***
 183
 184 LIBS_SAVE=$LIBS
 185 LIBS="$LIBS $LIBM"
 186 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 187 LIBS=$LIBS_SAVE
 188
 189 dnl Check whether isinf() is defined by math.h
 190 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 191     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 192 if test "$ac_cv_have_isinf" = "yes"
 193 then
 194     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 195 fi
 196
 197 dnl Check for mmap (needed by electricfence plugin)
 198 AC_FUNC_MMAP
 199 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 200
 201 dnl Check for mmap (needed by electricfence plugin)
 202
 203 AC_CHECK_TYPE([struct ip_mreqn], [
 204               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 205               [#include <netinet/in.h>])
 206
 207 dnl *** checks for dependency libraries ***
 208
 209 dnl GLib is required
 210 AG_GST_GLIB_CHECK([2.20])
 211 PKG_CHECK_MODULES(GIO, [ gio-2.0 >= 2.20 ], , AC_MSG_ERROR([gio is required]))
 212
 213 dnl Orc
 214 ORC_CHECK([0.4.11])
 215
 216 dnl checks for gstreamer
 217 dnl uninstalled is selected preferentially -- see pkg-config(1)
 218 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 222 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 223 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 224
 225 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 226 if test -z $GST_TOOLS_DIR; then
 227   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 228 fi
 229 AC_SUBST(GST_TOOLS_DIR)
 230
 231 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 232 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 233
 234 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 235
 236 dnl Check for documentation xrefs
 237 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 238 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 239 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 240 AC_SUBST(GLIB_PREFIX)
 241 AC_SUBST(GST_PREFIX)
 242 AC_SUBST(GSTPB_PREFIX)
 243
 244 dnl GTK is optional and used in examples
 245 HAVE_GTK=no
 246 GTK2_REQ=2.14.0
 247 GTK3_REQ=2.91.3
 248 if test "x$BUILD_EXAMPLES" = "xyes"; then
 249   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 250   AC_ARG_WITH([gtk],
 251     AC_HELP_STRING([--with-gtk=3.0|2.0],
 252                    [which gtk+ version to compile against (default: 2.0)]),
 253     [case "$with_gtk" in
 254         2.0) GTK_REQ=$GTK2_REQ ;;
 255         3.0) GTK_REQ=$GTK3_REQ ;;
 256         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 257     esac],
 258     [with_gtk=2.0
 259      GTK_REQ=$GTK2_REQ])
 260   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 261   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 262   dnl some examples need gtk+-x11
 263   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 264   AC_SUBST(GTK_LIBS)
 265   AC_SUBST(GTK_CFLAGS)
 266 fi
 267 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 268 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 269
 270 dnl should we install schemas ?
 271 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 272 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 273   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 274   if test x$GCONFTOOL = xno; then
 275     AC_MSG_WARN(Not installing GConf schemas)
 276     HAVE_GCONFTOOL="no"
 277   else
 278     HAVE_GCONFTOOL="yes"
 279   fi
 280   AC_SUBST(HAVE_GCONFTOOL)
 281 ])
 282
 283 dnl *** set variables based on configure arguments ***
 284
 285 dnl set license and copyright notice
 286 GST_LICENSE="LGPL"
 287 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 288 AC_SUBST(GST_LICENSE)
 289
 290 dnl set location of plugin directory
 291 AG_GST_SET_PLUGINDIR
 292
 293 dnl set release date/time
 294 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 295   ["${srcdir}/gst-plugins-good.doap"],
 296   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 297
 298 dnl define an ERROR_CFLAGS Makefile variable
 299 dnl -Wundef: too many broken headers
 300 if test "x$HAVE_OSX_VIDEO" != "xyes"; then
 301   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 302         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 303         -Wwrite-strings -Wold-style-definition -Waggregate-return
 304         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 305         -Wnested-externs ])
 306 else
 307   dnl work-around for us passing GST_CFLAGS to the ObjC-compiler, which
 308   dnl doesn't understand all warning flags that the C compiler knows about
 309   dnl (e.g. -Waddress) or causes problems with some flags (-Waggregate-return)
 310   AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 311         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 312         -Wwrite-strings -Wold-style-definition
 313         -Winit-self -Wmissing-include-dirs -Wno-multichar
 314         -Wnested-externs ])
 315 fi
 316
 317 dnl define an ERROR_CXXFLAGS Makefile variable
 318 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 319         -Wmissing-declarations -Wredundant-decls
 320         -Wwrite-strings
 321         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 322
 323 dnl define correct level for debugging messages
 324 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 325
 326 dnl used in examples
 327 AG_GST_DEFAULT_ELEMENTS
 328
 329 dnl *** plug-ins to include ***
 330
 331 dnl these are all the gst plug-ins, compilable without additional libs
 332 dnl videofilter is at the top because others depend on it
 333 AG_GST_CHECK_PLUGIN(videofilter)
 334 AG_GST_CHECK_PLUGIN(alpha)
 335 AG_GST_CHECK_PLUGIN(apetag)
 336 AG_GST_CHECK_PLUGIN(audiofx)
 337 AG_GST_CHECK_PLUGIN(audioparsers)
 338 AG_GST_CHECK_PLUGIN(auparse)
 339 AG_GST_CHECK_PLUGIN(autodetect)
 340 AG_GST_CHECK_PLUGIN(avi)
 341 AG_GST_CHECK_PLUGIN(cutter)
 342 AG_GST_CHECK_PLUGIN(debugutils)
 343 AG_GST_CHECK_PLUGIN(deinterlace)
 344 AG_GST_CHECK_PLUGIN(effectv)
 345 AG_GST_CHECK_PLUGIN(equalizer)
 346 AG_GST_CHECK_PLUGIN(flv)
 347 AG_GST_CHECK_PLUGIN(id3demux)
 348 AG_GST_CHECK_PLUGIN(icydemux)
 349 AG_GST_CHECK_PLUGIN(interleave)
 350 AG_GST_CHECK_PLUGIN(flx)
 351 AG_GST_CHECK_PLUGIN(goom)
 352 AG_GST_CHECK_PLUGIN(goom2k1)
 353 AG_GST_CHECK_PLUGIN(imagefreeze)
 354 AG_GST_CHECK_PLUGIN(isomp4)
 355 AG_GST_CHECK_PLUGIN(law)
 356 AG_GST_CHECK_PLUGIN(level)
 357 AG_GST_CHECK_PLUGIN(matroska)
 358 AG_GST_CHECK_PLUGIN(monoscope)
 359 AG_GST_CHECK_PLUGIN(multifile)
 360 AG_GST_CHECK_PLUGIN(multipart)
 361 AG_GST_CHECK_PLUGIN(replaygain)
 362 AG_GST_CHECK_PLUGIN(rtp)
 363 AG_GST_CHECK_PLUGIN(rtpmanager)
 364 AG_GST_CHECK_PLUGIN(rtsp)
 365 AG_GST_CHECK_PLUGIN(shapewipe)
 366 AG_GST_CHECK_PLUGIN(smpte)
 367 AG_GST_CHECK_PLUGIN(spectrum)
 368 AG_GST_CHECK_PLUGIN(udp)
 369 AG_GST_CHECK_PLUGIN(videobox)
 370 AG_GST_CHECK_PLUGIN(videocrop)
 371 AG_GST_CHECK_PLUGIN(videomixer)
 372 AG_GST_CHECK_PLUGIN(wavenc)
 373 AG_GST_CHECK_PLUGIN(wavparse)
 374 AG_GST_CHECK_PLUGIN(y4m)
 375
 376 dnl *** checks for socket and nsl libraries ***
 377 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 378
 379 dnl disable gst plugins we might not be able to build on this
 380 dnl platform: udp and rtsp (ugly but minimally invasive)
 381 dnl FIXME: maybe move to sys
 382 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 383 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 384
 385 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 386   AG_GST_DISABLE_PLUGIN(udp)
 387   AG_GST_DISABLE_PLUGIN(rtsp)
 388 fi
 389
 390 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 391   WIN32_LIBS="-lws2_32"
 392   AC_SUBST(WIN32_LIBS)
 393 fi
 394
 395 dnl disable experimental plug-ins
 396 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 397   AG_GST_DISABLE_PLUGIN(monoscope)
 398 fi
 399
 400 dnl *** sys plug-ins ***
 401
 402 echo
 403 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 404 echo
 405
 406 dnl DirectSound
 407 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 408 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 409   HAVE_DIRECTSOUND="no"
 410   save_CFLAGS="$CFLAGS"
 411   save_LDFLAGS="$LDFLAGS"
 412   save_LIBS="$LIBS"
 413   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 414   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 415   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 416   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 417   AC_LINK_IFELSE([
 418 #include <windows.h>
 419 #include <dxerr9.h>
 420 #include <dsound.h>
 421
 422 int main ()
 423 {
 424   DXGetErrorString9 (0);
 425   DirectSoundCreate(NULL, NULL, NULL);
 426
 427   return 0;
 428 }
 429 ],
 430     [HAVE_DIRECTSOUND="yes"],
 431     [HAVE_DIRECTSOUND="no"])
 432   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 433   CFLAGS=$save_CFLAGS
 434   LDFLAGS=$save_LDFLAGS
 435   LIBS=$save_LIBS
 436
 437   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 438     dnl this is much more than we want
 439     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 440     AC_SUBST(DIRECTSOUND_CFLAGS)
 441     AC_SUBST(DIRECTSOUND_LDFLAGS)
 442     AC_SUBST(DIRECTSOUND_LIBS)
 443   fi
 444   AC_SUBST(HAVE_DIRECTSOUND)
 445 ])
 446
 447 dnl *** OSS audio *** (Linux, *BSD)
 448 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 449 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 450  HAVE_OSS="yes"
 451 dnl Linux and newer BSD versions :
 452  AC_CHECK_HEADER(sys/soundcard.h, [
 453    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 454    ] , [
 455 dnl Some old BSD versions and also newer OpenBSD versions :
 456    AC_CHECK_HEADER(soundcard.h, [
 457      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 458      ], [
 459   dnl Some old BSD versions :
 460      AC_CHECK_HEADER(machine/soundcard.h, [
 461        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 462          [Define if OSS includes are in /machine/])
 463        ], [
 464        HAVE_OSS="no"
 465      ])
 466    ])
 467  ])
 468 ])
 469
 470 dnl *** oss4 ***
 471 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 472 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 473   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 474   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 475       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 476       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 477 ])
 478
 479 dnl *** Sun Audio ***
 480 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 481 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 482   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 483 ])
 484
 485 dnl *** OSX Audio ***
 486 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 487 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 488   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 489 ])
 490
 491 dnl *** OS X video ***
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 493 HAVE_OSX_VIDEO="no"
 494 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 495   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 496 ])
 497 dnl in case header OpenGL/gl.h is found on other platforms
 498 case "$host" in
 499   *-*darwin*)
 500     dnl do nothing
 501     ;;
 502   *)
 503     HAVE_OSX_VIDEO="no"
 504     ;;
 505 esac
 506
 507
 508 dnl *** Video 4 Linux 2 ***
 509 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 510 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 511 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 512 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 513   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 514   AC_TRY_COMPILE([
 515 #include <sys/types.h>
 516 #ifdef __sun /* Solaris */
 517 #include <sys/types.h>
 518 #include <sys/videodev2.h>
 519 #else /* Linux */
 520 #include <linux/types.h>
 521 #define _LINUX_TIME_H
 522 #define __user
 523 #include <linux/videodev2.h>
 524 #endif
 525 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 526 #error too early v4l2 version or no v4l2 at all
 527 #endif
 528     ], [
 529 return 0;
 530     ], [
 531       HAVE_GST_V4L2="yes"
 532       AC_MSG_RESULT(yes)
 533     ], [
 534       HAVE_GST_V4L2="no"
 535       AC_MSG_RESULT(no)
 536
 537       HAVE_VIDEODEV=no
 538       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 539       [
 540         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 541       ])
 542
 543       if test "x$HAVE_VIDEODEV" = "xyes"; then
 544         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 545         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 546       else
 547         AC_MSG_WARN([video4linux2 was not found])
 548       fi
 549     ])
 550
 551   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 552     dnl check for missing v4l2_buffer declaration (see #135919)
 553     MISSING_DECL=0
 554     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 555     AC_TRY_COMPILE([
 556 #include <sys/types.h>
 557 #ifdef __sun /* Solaris */
 558 #include <sys/types.h>
 559 #include <sys/videodev2.h>
 560 #else /* Linux */
 561 #include <linux/types.h>
 562 #define _LINUX_TIME_H
 563 #define __user
 564 #include <linux/videodev2.h>
 565 #endif
 566     ],[
 567 struct v4l2_buffer buf;
 568 buf.index = 0;
 569 return 0;
 570     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 571     if [ test x$MISSING_DECL = x1 ]; then
 572       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 573     fi
 574
 575     dnl check for XOverlay libraries
 576     AG_GST_CHECK_XV
 577   fi
 578 ])
 579
 580 # Optional gudev for device probing
 581 AC_ARG_WITH([gudev],
 582   AC_HELP_STRING([--with-gudev],
 583     [device detection with gudev]),
 584   [],
 585   [with_gudev=check])
 586 if test x$HAVE_GST_V4L2 = xyes; then
 587   if test x$with_gudev != xno; then
 588       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 589           [ have_gudev=yes
 590             AC_DEFINE(HAVE_GUDEV, 1,
 591                [Whether gudev is available for device detection])
 592             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 593           ], [
 594           have_gudev=no
 595           ])
 596   else
 597     have_gudev=no
 598   fi
 599 fi
 600 AC_SUBST(GUDEV_CFLAGS)
 601 AC_SUBST(GUDEV_LIBS)
 602
 603 # Make libv4l2 non-automagic
 604 AC_ARG_WITH([libv4l2],
 605   AC_HELP_STRING([--with-libv4l2],
 606     [support video buffer conversion using libv4l2]),
 607   [],
 608   [with_libv4l2=check])
 609 if test x$HAVE_GST_V4L2 = xyes; then
 610   if test x$with_libv4l2 != xno; then
 611       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 612           [ have_libv4l2=yes
 613             AC_DEFINE(HAVE_LIBV4L2, 1,
 614                 [Whether libv4l2 is available for video buffer conversion])
 615           ], [
 616           have_libv4l2=no
 617           ])
 618   else
 619     have_libv4l2=no
 620   fi
 621 fi
 622
 623 dnl Check for X11
 624 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 625 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 626                   [ximagesrc], [
 627   AC_PATH_XTRA
 628
 629   dnl now try to find the HEADER
 630   ac_cflags_save="$CFLAGS"
 631   ac_cppflags_save="$CPPFLAGS"
 632   CFLAGS="$CFLAGS $X_CFLAGS"
 633   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 634   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 635
 636   if test "x$HAVE_X" = "xno"
 637   then
 638     AC_MSG_NOTICE([cannot find X11 development files])
 639   else
 640     dnl this is much more than we want
 641     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 642     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 643     dnl it does not add the libs; therefore we add them here
 644     X_LIBS="$X_LIBS -lX11"
 645     AC_SUBST(X_CFLAGS)
 646     AC_SUBST(X_LIBS)
 647
 648     dnl check for Xfixes
 649     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 650     if test "x$HAVE_XFIXES" = "xyes"
 651     then
 652         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 653     fi
 654     AC_SUBST(XFIXES_LIBS)
 655     AC_SUBST(XFIXES_CFLAGS)
 656
 657     dnl check for Xdamage
 658     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 659     if test "x$HAVE_XDAMAGE" = "xyes"
 660     then
 661         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 662     fi
 663     AC_SUBST(XDAMAGE_LIBS)
 664     AC_SUBST(XDAMAGE_CFLAGS)
 665   fi
 666   AC_SUBST(HAVE_X)
 667   CFLAGS="$ac_cflags_save"
 668   CPPFLAGS="$ac_cppflags_save"
 669 ])
 670
 671 dnl FIXME: this should be rolled into the test above, it's just an additional
 672 dnl feature of the ximagesrc plug-in
 673 dnl This is the same as in gst-plugins-base
 674 dnl check for X Shm
 675 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 676 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 677   if test x$HAVE_X = xyes; then
 678     AC_CHECK_LIB(Xext, XShmAttach,
 679                  HAVE_XSHM="yes", HAVE_XSHM="no",
 680                  $X_LIBS)
 681     if test "x$HAVE_XSHM" = "xyes"; then
 682       XSHM_LIBS="-lXext"
 683     else
 684       dnl On AIX, it is in XextSam instead, but we still need -lXext
 685       AC_CHECK_LIB(XextSam, XShmAttach,
 686                    HAVE_XSHM="yes", HAVE_XSHM="no",
 687                    $X_LIBS)
 688       if test "x$HAVE_XSHM" = "xyes"; then
 689         XSHM_LIBS="-lXext -lXextSam"
 690       fi
 691     fi
 692   fi
 693 ], ,[
 694   AC_SUBST(HAVE_XSHM)
 695   AC_SUBST(XSHM_LIBS)
 696 ])
 697
 698 dnl for V4L2, we also need to know if we have XVIDEO
 699 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 700 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 701                   [], [
 702   AG_GST_CHECK_XV
 703 ])
 704
 705 dnl *** ext plug-ins ***
 706 dnl keep this list sorted alphabetically !
 707
 708 if test "x$BUILD_EXTERNAL" = "xyes"; then
 709
 710 echo
 711 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 712 echo
 713
 714 dnl *** aalib ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 716 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 717   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 718   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 719 ])
 720
 721 dnl *** annodex ***
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 723 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 724   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 725 ])
 726
 727 dnl *** cairo ***
 728 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 729 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 730   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 731 ])
 732
 733 dnl *** cairo-gobject ***
 734 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 735 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 736   [Cairo graphics rendering gobject bindings], cairooverlay, [
 737   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 738 ])
 739
 740 dnl **** ESound ****
 741 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 742 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 743   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 744   if test $HAVE_ESD = no
 745   then
 746     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 747     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 748   fi
 749 ])
 750
 751 dnl *** FLAC ***
 752 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 753 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 754   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 755 ])
 756
 757 dnl *** GConf ***
 758 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 759 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 760   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 761 ])
 762
 763 dnl *** GDK pixbuf ***
 764 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 765 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 766   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 767 ])
 768
 769 dnl *** HAL ***
 770 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 771 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 772   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 773 ])
 774
 775 dnl *** Jack ***
 776 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 777 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 778   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 779   AC_SUBST(JACK_CFLAGS)
 780   AC_SUBST(JACK_LIBS)
 781
 782   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 783   if test x$HAVE_JACK_0_120_1 = xyes; then
 784     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 785   fi
 786   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 787   if test x$HAVE_JACK_1_9_7 = xyes; then
 788     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 789   fi
 790
 791 ])
 792
 793 dnl *** jpeg ***
 794 dnl FIXME: we could use header checks here as well IMO
 795 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 796 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 797   AC_ARG_WITH(jpeg-mmx,
 798     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 799   OLD_LIBS="$LIBS"
 800   if test x$with_jpeg_mmx != x; then
 801     LIBS="$LIBS -L$with_jpeg_mmx"
 802   fi
 803   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 804   JPEG_LIBS="$LIBS -ljpeg-mmx"
 805   LIBS="$OLD_LIBS"
 806   if test x$HAVE_JPEG != xyes; then
 807     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 808     JPEG_LIBS="-ljpeg"
 809   fi
 810   AC_SUBST(JPEG_LIBS)
 811 ])
 812
 813 dnl *** libcaca ***
 814 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 815 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 816   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 817 ])
 818
 819 dnl *** libdv ***
 820 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 821 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 822   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 823 ])
 824
 825 dnl *** libpng ***
 826 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 827 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 828   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 829 ])
 830
 831 dnl *** pulseaudio ***
 832 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 833 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 834
 835   dnl used in ext/pulse/pulseutil.c
 836   AC_CHECK_HEADERS([process.h])
 837
 838   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.16)
 839   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 840   if test x$HAVE_PULSE_0_9_20 = xyes; then
 841     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 842   fi
 843   AG_GST_PKG_CHECK_MODULES(PULSE_1_0, libpulse >= 0.98)
 844   if test x$HAVE_PULSE_1_0 = xyes; then
 845     AC_DEFINE(HAVE_PULSE_1_0, 1, [defined if pulseaudio >= 1.0 is available])
 846   fi
 847 ])
 848
 849 dnl *** dv1394 ***
 850 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 851 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 852   dnl first test for libraw1394 >= 2.0.0
 853   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 854   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 855   dnl now see how far we got
 856   if test x$HAVE_RAW1394 = xyes && \
 857      test x$HAVE_LIBIEC61883 = xyes; then
 858        AG_GST_CHECK_LIBHEADER(AVC1394,
 859         avc1394, avc1394_send_command, $RAW1394_LIBS,
 860         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 861        AG_GST_CHECK_LIBHEADER(ROM1394,
 862         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 863         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 864        if test x$HAVE_AVC1394 = xyes && \
 865           test x$HAVE_AVC1394 = xyes && \
 866           test x$HAVE_ROM1394 = xyes; then
 867           HAVE_DV1394=yes
 868           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 869           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 870           AC_SUBST(DV1394_CFLAGS)
 871           AC_SUBST(DV1394_LIBS)
 872         fi
 873   else
 874        if test x$HAVE_RAW1394 = xno; then
 875           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 876           AG_GST_CHECK_LIBHEADER(AVC1394,
 877            avc1394, avc1394_send_command, $RAW1394_LIBS,
 878            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 879           AG_GST_CHECK_LIBHEADER(ROM1394,
 880            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 881            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 882           if test x$HAVE_RAW1394 = xyes && \
 883              test x$HAVE_AVC1394 = xyes && \
 884              test x$HAVE_ROM1394 = xyes; then
 885              HAVE_DV1394=yes
 886              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 887              DV1394_CFLAGS="$RAW1394_CFLAGS"
 888              if test x$HAVE_LIBIEC61883 = xyes; then
 889                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 890                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 891              fi
 892              AC_SUBST(DV1394_CFLAGS)
 893              AC_SUBST(DV1394_LIBS)
 894            fi
 895          fi
 896   fi
 897 ])
 898 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 899
 900 dnl *** shout2 ***
 901 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 902 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 903   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 904 ])
 905
 906 dnl *** soup ***
 907 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 908 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 909   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 910     HAVE_SOUP="yes"
 911     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 912   ],[
 913     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 914       HAVE_SOUP="no"
 915     ])
 916   ])
 917   AC_SUBST(SOUP_CFLAGS)
 918   AC_SUBST(SOUP_LIBS)
 919 ])
 920
 921 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 922 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 923 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 924 dnl   speex_jitter.h is 1.1.x only
 925 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 926 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 927   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 928   if test $HAVE_SPEEX = no
 929   then
 930     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 931       AC_CHECK_HEADER(speex/speex_jitter.h, [
 932         dnl speex 1.1.x :
 933         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 934           dnl speex 1.1.5 or + :
 935           HAVE_SPEEX="yes"
 936           SPEEX_LIBS="-lspeex"
 937           AC_SUBST(SPEEX_CFLAGS)
 938           AC_SUBST(SPEEX_LIBS)
 939         ],[
 940           HAVE_SPEEX="no"
 941         ])
 942       ],[
 943         dnl speex 1.0.x :
 944           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 945             dnl speex 1.0.4
 946             HAVE_SPEEX="yes"
 947             SPEEX_LIBS="-lspeex"
 948             AC_SUBST(SPEEX_CFLAGS)
 949             AC_SUBST(SPEEX_LIBS)
 950
 951             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 952               [defined if speex 1.0.x API detected])
 953         ],[
 954             HAVE_SPEEX="no"
 955             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 956         ], [
 957 #include <speex/speex.h>
 958         ])
 959       ])
 960     ])
 961   fi
 962 ])
 963
 964 dnl *** taglib ***
 965 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 966 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 967   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 968   if test "x$HAVE_CXX" != "xyes"; then
 969     USE_TAGLIB=false
 970     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 971   else
 972     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 973     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 974         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 975       ], [
 976         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 977     ])
 978     AC_SUBST(TAGLIB_CXXFLAGS)
 979   fi
 980 ])
 981
 982 dnl *** wavpack ***
 983 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 984 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 985   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 986     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 987       HAVE_WAVPACK=yes
 988       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 989     ],[
 990       HAVE_WAVPACK=no
 991     ])
 992   ])
 993   AC_SUBST(WAVPACK_CFLAGS)
 994   AC_SUBST(WAVPACK_LIBS)
 995 ])
 996
 997 dnl *** qtdemux & matroska prefer to have zlib ***
 998 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 999 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
1000   AG_GST_CHECK_LIBHEADER(ZLIB,
1001     z, uncompress,, zlib.h, [
1002     HAVE_ZLIB="yes"
1003     ZLIB_LIBS="-lz"
1004     AC_SUBST(ZLIB_LIBS)
1005   ])
1006 ])
1007
1008 dnl *** matroska prefers to have bz2 ***
1009 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
1010 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
1011   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
1012   AC_SUBST(BZ2_LIBS)
1013 ])
1014
1015 else
1016
1017 dnl not building plugins with external dependencies,
1018 dnl but we still need to set the conditionals
1019 AM_CONDITIONAL(USE_AALIB, false)
1020 AM_CONDITIONAL(USE_ANNODEX, false)
1021 AM_CONDITIONAL(USE_BZ2, false)
1022 AM_CONDITIONAL(USE_CAIRO, false)
1023 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
1024 AM_CONDITIONAL(USE_DIRECTSOUND, false)
1025 AM_CONDITIONAL(USE_DV1394, false)
1026 AM_CONDITIONAL(USE_ESD, false)
1027 AM_CONDITIONAL(USE_FLAC, false)
1028 AM_CONDITIONAL(USE_GCONF, false)
1029 AM_CONDITIONAL(USE_GCONFTOOL, false)
1030 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1031 AM_CONDITIONAL(USE_GST_V4L2, false)
1032 AM_CONDITIONAL(USE_HAL, false)
1033 AM_CONDITIONAL(USE_JACK, false)
1034 AM_CONDITIONAL(USE_JPEG, false)
1035 AM_CONDITIONAL(USE_LIBCACA, false)
1036 AM_CONDITIONAL(USE_LIBDV, false)
1037 AM_CONDITIONAL(USE_LIBIEC61883, false)
1038 AM_CONDITIONAL(USE_LIBPNG, false)
1039 AM_CONDITIONAL(USE_OSS, false)
1040 AM_CONDITIONAL(USE_OSS4, false)
1041 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1042 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1043 AM_CONDITIONAL(USE_PULSE, false)
1044 AM_CONDITIONAL(USE_SHOUT2, false)
1045 AM_CONDITIONAL(USE_SOUP, false)
1046 AM_CONDITIONAL(USE_SPEEX, false)
1047 AM_CONDITIONAL(USE_SUNAUDIO, false)
1048 AM_CONDITIONAL(USE_TAGLIB, false)
1049 AM_CONDITIONAL(USE_WAVPACK, false)
1050 AM_CONDITIONAL(USE_X, false)
1051 AM_CONDITIONAL(USE_XSHM, false)
1052 AM_CONDITIONAL(USE_XVIDEO, false)
1053 AM_CONDITIONAL(USE_ZLIB, false)
1054
1055 fi dnl of EXT plugins
1056
1057 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1058
1059 dnl Overview:
1060 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1061 dnl GST_*:              flags shared by all built objects
1062 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1063 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1064 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1065 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1066
1067 dnl GST_OPTION_CFLAGS
1068 if test "x$USE_DEBUG" = xyes; then
1069    PROFILE_CFLAGS="-g"
1070 fi
1071 AC_SUBST(PROFILE_CFLAGS)
1072
1073 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1074   dnl Define _only_ for git (not pre-releases or releases)
1075   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1076 else
1077   DEPRECATED_CFLAGS=""
1078 fi
1079 AC_SUBST(DEPRECATED_CFLAGS)
1080
1081 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1082 dnl at make time with e.g. make ERROR_CFLAGS=""
1083 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1084 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1085 AC_SUBST(GST_OPTION_CFLAGS)
1086 AC_SUBST(GST_OPTION_CXXFLAGS)
1087
1088 dnl our libraries need to be versioned correctly
1089 AC_SUBST(GST_LT_LDFLAGS)
1090
1091 dnl FIXME: do we want to rename to GST_ALL_* ?
1092 dnl prefer internal headers to already installed ones
1093 dnl also add builddir include for enumtypes and marshal
1094 dnl add ERROR_CFLAGS, but overridable
1095 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1096 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1097 AC_SUBST(GST_CFLAGS)
1098 AC_SUBST(GST_CXXFLAGS)
1099 AC_SUBST(GST_LIBS)
1100
1101 dnl LDFLAGS really should only contain flags, not libs - they get added before
1102 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1103 GST_ALL_LDFLAGS="-no-undefined"
1104 AC_SUBST(GST_ALL_LDFLAGS)
1105
1106 dnl this really should only contain flags, not libs - they get added before
1107 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1108 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1109 AC_SUBST(GST_PLUGIN_LDFLAGS)
1110
1111 dnl *** output files ***
1112
1113 dnl keep this alphabetic per directory, please
1114 AC_CONFIG_FILES(
1115 Makefile
1116 gst/Makefile
1117 gst/alpha/Makefile
1118 gst/apetag/Makefile
1119 gst/audiofx/Makefile
1120 gst/audioparsers/Makefile
1121 gst/auparse/Makefile
1122 gst/autodetect/Makefile
1123 gst/avi/Makefile
1124 gst/cutter/Makefile
1125 gst/deinterlace/Makefile
1126 gst/debugutils/Makefile
1127 gst/effectv/Makefile
1128 gst/equalizer/Makefile
1129 gst/flv/Makefile
1130 gst/goom/Makefile
1131 gst/goom2k1/Makefile
1132 gst/id3demux/Makefile
1133 gst/icydemux/Makefile
1134 gst/imagefreeze/Makefile
1135 gst/interleave/Makefile
1136 gst/isomp4/Makefile
1137 gst/law/Makefile
1138 gst/level/Makefile
1139 gst/matroska/Makefile
1140 gst/monoscope/Makefile
1141 gst/multifile/Makefile
1142 gst/multipart/Makefile
1143 gst/replaygain/Makefile
1144 gst/rtp/Makefile
1145 gst/rtpmanager/Makefile
1146 gst/rtsp/Makefile
1147 gst/shapewipe/Makefile
1148 gst/smpte/Makefile
1149 gst/spectrum/Makefile
1150 gst/udp/Makefile
1151 gst/videobox/Makefile
1152 gst/videocrop/Makefile
1153 gst/videofilter/Makefile
1154 gst/videomixer/Makefile
1155 gst/wavenc/Makefile
1156 gst/wavparse/Makefile
1157 gst/flx/Makefile
1158 gst/y4m/Makefile
1159 ext/Makefile
1160 ext/aalib/Makefile
1161 ext/annodex/Makefile
1162 ext/cairo/Makefile
1163 ext/dv/Makefile
1164 ext/esd/Makefile
1165 ext/flac/Makefile
1166 ext/gconf/Makefile
1167 ext/gdk_pixbuf/Makefile
1168 ext/hal/Makefile
1169 ext/jack/Makefile
1170 ext/jpeg/Makefile
1171 ext/libcaca/Makefile
1172 ext/libpng/Makefile
1173 ext/pulse/Makefile
1174 ext/raw1394/Makefile
1175 ext/shout2/Makefile
1176 ext/soup/Makefile
1177 ext/speex/Makefile
1178 ext/taglib/Makefile
1179 ext/wavpack/Makefile
1180 sys/Makefile
1181 sys/directsound/Makefile
1182 sys/oss/Makefile
1183 sys/oss4/Makefile
1184 sys/osxaudio/Makefile
1185 sys/osxvideo/Makefile
1186 sys/sunaudio/Makefile
1187 sys/v4l2/Makefile
1188 sys/waveform/Makefile
1189 sys/ximage/Makefile
1190 po/Makefile.in
1191 tests/Makefile
1192 tests/check/Makefile
1193 tests/examples/Makefile
1194 tests/examples/audiofx/Makefile
1195 tests/examples/cairo/Makefile
1196 tests/examples/equalizer/Makefile
1197 tests/examples/jack/Makefile
1198 tests/examples/level/Makefile
1199 tests/examples/pulse/Makefile
1200 tests/examples/rtp/Makefile
1201 tests/examples/shapewipe/Makefile
1202 tests/examples/spectrum/Makefile
1203 tests/examples/v4l2/Makefile
1204 tests/files/Makefile
1205 tests/icles/Makefile
1206 gconf/Makefile
1207 gconf/gstreamer.schemas
1208 common/Makefile
1209 common/m4/Makefile
1210 m4/Makefile
1211 docs/Makefile
1212 docs/plugins/Makefile
1213 docs/version.entities
1214 pkgconfig/Makefile
1215 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1216 gst-plugins-good.spec
1217 )
1218
1219 dnl Create the config.h file for Visual Studio builds
1220 dnl Beware of spaces and /'s in some of the shell variable contents.
1221 sed \
1222     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1223     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1224     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1225     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1226     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1227     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1228     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1229     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1230     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1231     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1232     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1233     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1234     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1235     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1236     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1237     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1238     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1239     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1240     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1241     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1242     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1243     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1244     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1245     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1246     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1247     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1248     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1249     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1250     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1251     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1252     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1253     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1254     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1255     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1256     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1257     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1258     config.h.in >win32/common/config.h-new
1259
1260 AC_OUTPUT
1261
1262 AG_GST_OUTPUT_PLUGINS
1263 ORC_OUTPUT
1264