configure.ac

   1 -*- mode: m4 -*-
   2 AC_PREREQ([2.68])
   3
   4 # The version of python used is determined by the executable pointed to by the
   5 # --with-python switch, or if that's not set, by the PYTHON environment
   6 # variable.  For instance if your system installs Python 3 as python3 to
   7 # configure to compile pygobject under Python 3 you would do this:
   8 #   $ ./configure --with-python=python3
   9 # or
  10 #   $ PYTHON=python3 ./configure
  11 #
  12 # You can also build against a full interpreter path, such as
  13 #   $ ./configure --with-python=~/my-patched-python/python
  14
  15 m4_define(python_min_ver, 2.7)
  16 m4_define(python3_min_ver, 3.1)
  17
  18 dnl the pygobject version number
  19 m4_define(pygobject_major_version, 3)
  20 m4_define(pygobject_minor_version, 9)
  21 m4_define(pygobject_micro_version, 91)
  22 m4_define(pygobject_version, pygobject_major_version.pygobject_minor_version.pygobject_micro_version)
  23
  24 dnl versions of packages we require ...
  25 m4_define(introspection_required_version, 1.35.9)
  26 m4_define(py2cairo_required_version, 1.2.0)
  27 m4_define(py3cairo_required_version, 1.10.0)
  28 m4_define(glib_required_version, 2.35.9)
  29 m4_define(gio_required_version, 2.35.9)
  30
  31 AC_INIT([pygobject],[pygobject_version],
  32         [http://bugzilla.gnome.org/enter_bug.cgi?product=pygobject],
  33         [pygobject],[https://live.gnome.org/PyGObject/])
  34 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I .")
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR([gi/gimodule.c])
  37
  38 AC_DEFINE(PYGOBJECT_MAJOR_VERSION, pygobject_major_version, [pygobject major version])
  39 AC_SUBST(PYGOBJECT_MAJOR_VERSION, pygobject_major_version)
  40 AC_DEFINE(PYGOBJECT_MINOR_VERSION, pygobject_minor_version, [pygobject minor version])
  41 AC_SUBST(PYGOBJECT_MINOR_VERSION, pygobject_minor_version)
  42 AC_DEFINE(PYGOBJECT_MICRO_VERSION, pygobject_micro_version, [pygobject micro version])
  43 AC_SUBST(PYGOBJECT_MICRO_VERSION, pygobject_micro_version)
  44
  45 AC_CONFIG_HEADERS(config.h)
  46 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
  47 AM_INIT_AUTOMAKE([1.11.1 foreign no-dist-gzip dist-xz])
  48
  49 dnl put the ACLOCAL flags in the makefile
  50 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
  51
  52 AC_CANONICAL_BUILD
  53 AC_CANONICAL_HOST
  54 AC_MSG_CHECKING([for some Win32 platform])
  55 case "$host" in
  56   *-*-mingw*|*-*-cygwin*)
  57     platform_win32=yes
  58     ;;
  59   *)
  60     platform_win32=no
  61     ;;
  62 esac
  63 AC_MSG_RESULT([$platform_win32])
  64 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
  65
  66 AC_MSG_CHECKING([for native Win32])
  67 case "$host" in
  68   *-*-mingw*)
  69     os_win32=yes
  70     ;;
  71   *)
  72     os_win32=no
  73     ;;
  74 esac
  75 AC_MSG_RESULT([$os_win32])
  76 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  77
  78 LT_PREREQ([2.2.6])
  79 LT_INIT([dlopen win32-dll disable-static])
  80
  81 AC_SEARCH_LIBS([strerror],[cposix])
  82 AC_PROG_CC
  83 AM_PROG_CC_C_O
  84
  85 # option to specify python interpreter to use; this just sets $PYTHON, so that
  86 # we will fallback to reading $PYTHON if --with-python is not given, and
  87 # python.m4 will get the expected input
  88 AC_ARG_WITH(python,
  89   AS_HELP_STRING([--with-python=PATH],[Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
  90   [PYTHON="$withval"], [])
  91 if test x"$PYTHON" = xyes; then
  92         AC_MSG_ERROR([--with-python option requires a path or program argument])
  93 fi
  94 if test -n "$PYTHON" && ! which "$PYTHON"; then
  95         AC_MSG_ERROR([Python interpreter $PYTHON does not exist])
  96 fi
  97
  98 # check that we have the minimum version of python necessary to build
  99 JD_PATH_PYTHON(python_min_ver)
 100
 101 # check if we are building for python 3
 102 JD_PYTHON_CHECK_VERSION([$PYTHON], [3.0],
 103                          build_py3k=true,
 104                          build_py3k=false)
 105
 106 # if building for python 3 make sure we have the minimum version supported
 107 if test $build_py3k = true ; then
 108   AC_MSG_CHECKING([for $PYTHON >=] python3_min_ver)
 109   JD_PYTHON_CHECK_VERSION([$PYTHON], python3_min_ver,
 110                           [AC_MSG_RESULT(yes)],
 111                           [AC_MSG_ERROR(too old)])
 112 fi
 113
 114 # - 'SO' for PyPy, CPython 2.7-3.2
 115 # - 'EXT_SUFFIX' for CPython3.3+ (http://bugs.python.org/issue16754)
 116 # - fallback to '.so'
 117 PYTHON_SO=`$PYTHON -c "import distutils.sysconfig, sys; get = distutils.sysconfig.get_config_var; sys.stdout.write(get('EXT_SUFFIX') or get('SO') or '.so');"`
 118 AC_SUBST(PYTHON_SO)
 119
 120 AM_CHECK_PYTHON_HEADERS(, AC_MSG_ERROR([Python headers not found]))
 121 if test "x$os_win32" = "xyes"; then
 122   AM_CHECK_PYTHON_LIBS(, AC_MSG_ERROR([Python libs not found. Windows requires Python modules to be explicitly linked to libpython.]))
 123 fi
 124
 125 AC_MSG_CHECKING([for PySignal_SetWakeupFd in Python.h])
 126 old_CPPFLAGS=$CPPFLAGS
 127 CPPFLAGS="-Wall -Werror $PYTHON_INCLUDES"
 128 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Python.h>]], [[PySignal_SetWakeupFd(0);]])],
 129                   [setwakeupfd_ok=yes],[setwakeupfd_ok=no])
 130 AC_MSG_RESULT($setwakeupfd_ok)
 131 if test "x$setwakeupfd_ok" != xno; then
 132   AC_DEFINE(HAVE_PYSIGNAL_SETWAKEUPFD, 1,
 133                 [Define to 1 if PySignal_SetWakeupFd is available])
 134 fi
 135 CPPFLAGS=$old_CPPFLAGS
 136
 137 PLATFORM=`$PYTHON -c "import sys; from distutils import util; sys.stdout.write(util.get_platform())"`
 138 AC_SUBST(PLATFORM)
 139
 140 AC_ARG_ENABLE(thread,
 141   AS_HELP_STRING([--disable-thread],[Disable pygobject threading support]),,
 142   enable_thread=yes)
 143
 144 AM_CHECK_PYMOD(thread,,,enable_thread=check_for_py3_module)
 145 if test "x$enable_thread" = xcheck_for_py3_module; then
 146   dnl Python 3 uses the _thread module so check for that
 147   AM_CHECK_PYMOD(_thread,,enable_thread=yes,enable_thread=no)
 148 fi
 149
 150 AC_MSG_CHECKING(whether to enable threading in pygobject)
 151 if test "x$enable_thread" != xno; then
 152   extra_mods=gthread
 153   THREADING_CFLAGS=
 154   AC_MSG_RESULT(yes)
 155 else
 156   extra_mods=
 157   THREADING_CFLAGS="-DDISABLE_THREADING"
 158   AC_MSG_RESULT(no)
 159 fi
 160 AC_SUBST(THREADING_CFLAGS)
 161 CPPFLAGS="${CPPFLAGS} $THREADING_CFLAGS"
 162
 163 dnl get rid of the -export-dynamic stuff from the configure flags ...
 164 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
 165
 166 dnl glib
 167 AM_PATH_GLIB_2_0(glib_required_version,,[AC_MSG_ERROR(maybe you want the pygobject-2-4 branch?)],gobject $extra_mods)
 168 if test -n "$export_dynamic"; then
 169   GLIB_LIBS=`echo $GLIB_LIBS | sed -e "s/$export_dynamic//"`
 170 fi
 171 PYTHON_BASENAME=`basename $PYTHON`
 172 AC_SUBST([PYTHON_BASENAME])
 173
 174 AS_AC_EXPAND(DATADIR, $datadir)
 175
 176 dnl libffi
 177 AC_MSG_CHECKING(for ffi)
 178 AC_ARG_WITH(ffi,
 179   AS_HELP_STRING([--without-ffi],[Disable libffi support]),
 180   with_libffi=$withval,
 181   with_libffi=auto)
 182 if test x"$with_libffi" = xno ; then
 183   have_libffi=false
 184 else
 185   PKG_CHECK_MODULES(FFI, libffi >= 3.0, have_libffi=yes, have_libffi=no)
 186 fi
 187 if test x"$with_libffi" = xyes && test x"$have_libffi" = xno ; then
 188   AC_MSG_ERROR([ffi requested, but not found])
 189 fi
 190 if test x"$have_libffi" = xyes; then
 191   LIBFFI_PC=libffi
 192 fi
 193 AM_CONDITIONAL(HAVE_LIBFFI, test "$have_libffi" = "yes")
 194 AC_SUBST(FFI_CFLAGS)
 195 AC_SUBST(FFI_LIBS)
 196 AC_SUBST(LIBFFI_PC)
 197
 198 dnl gio
 199 PKG_CHECK_MODULES(GIO, gio-2.0 >= gio_required_version)
 200
 201 AC_ARG_ENABLE(cairo,
 202     AS_HELP_STRING([--enable-cairo],[Enable Cairo bindings using introspection information]),
 203     enable_cairo=$enableval,
 204     enable_cairo=yes)
 205
 206 PKG_CHECK_MODULES(GI,
 207     glib-2.0 >= glib_required_version
 208     gobject-introspection-1.0 >= introspection_required_version
 209 )
 210
 211 GI_DATADIR=$($PKG_CONFIG --variable=gidatadir gobject-introspection-1.0)
 212 AC_SUBST(GI_DATADIR)
 213
 214 if test "$enable_cairo" != no; then
 215     PKG_CHECK_MODULES(CAIRO, cairo cairo-gobject)
 216
 217     if test $build_py3k = true; then
 218         PKG_CHECK_MODULES(PYCAIRO,
 219             py3cairo >= py3cairo_required_version
 220         )
 221     else
 222         PKG_CHECK_MODULES(PYCAIRO,
 223             pycairo >= py2cairo_required_version
 224         )
 225     fi
 226 fi
 227 AM_CONDITIONAL(ENABLE_CAIRO, test "$enable_cairo" = "yes")
 228
 229 INTROSPECTION_SCANNER=`$PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0`
 230 INTROSPECTION_COMPILER=`$PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0`
 231
 232 AC_SUBST(INTROSPECTION_SCANNER)
 233 AC_SUBST(INTROSPECTION_COMPILER)
 234
 235 # compiler warnings, errors, required cflags, and code coverage support
 236 GNOME_COMPILE_WARNINGS([maximum])
 237 AC_MSG_CHECKING(for Gnome code coverage support)
 238 m4_ifdef([GNOME_CODE_COVERAGE],
 239          [AC_MSG_RESULT(yes)
 240           GNOME_CODE_COVERAGE],
 241          [AC_MSG_RESULT(no)
 242           GNOME_CODE_COVERAGE_RULES=''
 243           AC_SUBST([GNOME_CODE_COVERAGE_RULES])
 244           enable_code_coverage="no"])
 245
 246 if test "x$GCC" = "xyes"; then
 247   JH_ADD_CFLAG([-Wall])
 248   JH_ADD_CFLAG([-Werror=unused-variable])
 249   JH_ADD_CFLAG([-fno-strict-aliasing])
 250
 251   case $host_os in
 252   solaris*)
 253     ;;
 254   *)
 255     JH_ADD_CFLAG([-std=c9x])
 256     ;;
 257   esac
 258
 259 fi
 260
 261 CFLAGS="$CFLAGS $WARN_CFLAGS $CODE_COVERAGE_CFLAGS"
 262 LDFLAGS="$LDFLAGS $CODE_COVERAGE_CFLAGS"
 263
 264 AC_CONFIG_FILES(
 265   Makefile
 266   pygobject-3.0.pc
 267   pygobject-3.0-uninstalled.pc
 268   gi/Makefile
 269   gi/repository/Makefile
 270   gi/overrides/Makefile
 271   gi/_glib/Makefile
 272   gi/_gobject/Makefile
 273   examples/Makefile
 274   tests/Makefile
 275   pygtkcompat/Makefile
 276   PKG-INFO)
 277 AC_OUTPUT
 278
 279 AC_MSG_RESULT([
 280         pygobject $VERSION
 281
 282         Using python interpreter:       $PYTHON
 283         libffi support:                 $have_libffi
 284         cairo support:                  $enable_cairo
 285         thread support:                 $enable_thread
 286         code coverage support:          $enable_code_coverage
 287 ])
 288