configure.ac

   1 AC_PREREQ([2.67])
   2 AC_INIT([cryptsetup],[1.6.0-rc1])
   3
   4 dnl library version from <major>.<minor>.<release>[-<suffix>]
   5 LIBCRYPTSETUP_VERSION=$(echo $PACKAGE_VERSION | cut -f1 -d-)
   6 LIBCRYPTSETUP_VERSION_INFO=9:0:5
   7 dnl library file name for FIPS selfcheck
   8 LIBCRYPTSETUP_VERSION_FIPS="libcryptsetup.so.4"
   9
  10 AC_CONFIG_SRCDIR(src/cryptsetup.c)
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CONFIG_HEADERS([config.h:config.h.in])
  14 AM_INIT_AUTOMAKE(dist-bzip2)
  15
  16 if test "x$prefix" = "xNONE"; then
  17         sysconfdir=/etc
  18 fi
  19 AC_PREFIX_DEFAULT(/usr)
  20
  21 AC_CANONICAL_HOST
  22 AC_USE_SYSTEM_EXTENSIONS
  23 AC_PROG_CC
  24 AM_PROG_CC_C_O
  25 AC_PROG_CPP
  26 AC_PROG_INSTALL
  27 AC_PROG_MAKE_SET
  28 AC_ENABLE_STATIC(no)
  29 LT_INIT
  30 PKG_PROG_PKG_CONFIG
  31
  32 AC_HEADER_DIRENT
  33 AC_HEADER_STDC
  34 AC_CHECK_HEADERS(fcntl.h malloc.h inttypes.h sys/ioctl.h sys/mman.h \
  35         ctype.h unistd.h locale.h)
  36
  37 AC_CHECK_HEADERS(uuid/uuid.h,,[AC_MSG_ERROR([You need the uuid library.])])
  38 AC_CHECK_HEADER(libdevmapper.h,,[AC_MSG_ERROR([You need the device-mapper library.])])
  39
  40 saved_LIBS=$LIBS
  41 AC_CHECK_LIB(uuid, uuid_clear, ,[AC_MSG_ERROR([You need the uuid library.])])
  42 AC_SUBST(UUID_LIBS, $LIBS)
  43 LIBS=$saved_LIBS
  44
  45 AC_CHECK_FUNCS([posix_memalign])
  46
  47 AC_C_CONST
  48 AC_C_BIGENDIAN
  49 AC_TYPE_OFF_T
  50 AC_SYS_LARGEFILE
  51
  52 AC_PROG_GCC_TRADITIONAL
  53
  54 dnl ==========================================================================
  55
  56 AM_GNU_GETTEXT([external],[need-ngettext])
  57 AM_GNU_GETTEXT_VERSION([0.15])
  58
  59 dnl ==========================================================================
  60
  61 saved_LIBS=$LIBS
  62 AC_CHECK_LIB(popt, poptConfigFileToString,,
  63         [AC_MSG_ERROR([You need popt 1.7 or newer to compile.])])
  64 AC_SUBST(POPT_LIBS, $LIBS)
  65 LIBS=$saved_LIBS
  66
  67 dnl ==========================================================================
  68 dnl FIPS extensions
  69 AC_ARG_ENABLE([fips], AS_HELP_STRING([--enable-fips],[enable FIPS mode restrictions]),
  70 [with_fips=$enableval],
  71 [with_fips=no])
  72
  73 if test "x$with_fips" = "xyes"; then
  74         AC_DEFINE(ENABLE_FIPS, 1, [Enable FIPS mode restrictions])
  75         AC_DEFINE_UNQUOTED(LIBCRYPTSETUP_VERSION_FIPS, ["$LIBCRYPTSETUP_VERSION_FIPS"],
  76                 [library file name for FIPS selfcheck])
  77
  78         if test "x$enable_static" = "xyes" -o "x$enable_static_cryptsetup" = "xyes" ; then
  79                 AC_MSG_ERROR([Static build is not compatible with FIPS.])
  80         fi
  81
  82         saved_LIBS=$LIBS
  83         AC_CHECK_LIB(fipscheck, FIPSCHECK_verify, ,[AC_MSG_ERROR([You need the fipscheck library.])])
  84         AC_SUBST(FIPSCHECK_LIBS, $LIBS)
  85         LIBS=$saved_LIBS
  86
  87 fi
  88
  89 AC_DEFUN([NO_FIPS], [
  90         if test "x$with_fips" = "xyes"; then
  91                 AC_MSG_ERROR([This option is not compatible with FIPS.])
  92         fi
  93 ])
  94
  95 dnl ==========================================================================
  96 dnl pwquality library (cryptsetup CLI only)
  97 AC_ARG_ENABLE([pwquality], AS_HELP_STRING([--enable-pwquality],[enable password quality checking]),
  98 [with_pwquality=$enableval],
  99 [with_pwquality=no])
 100
 101 if test "x$with_pwquality" = "xyes"; then
 102         AC_DEFINE(ENABLE_PWQUALITY, 1, [Enable password quality checking])
 103         PKG_CHECK_MODULES([PWQUALITY], [pwquality >= 1.0.0],,
 104                 AC_MSG_ERROR([You need pwquality library.]))
 105
 106         dnl FIXME: this is really hack for now
 107         PWQUALITY_STATIC_LIBS="$PWQUALITY_LIBS -lcrack -lz"
 108 fi
 109
 110 dnl ==========================================================================
 111 dnl Crypto backend functions
 112
 113 AC_DEFUN([CONFIGURE_GCRYPT], [
 114         if test "x$with_fips" = "xyes"; then
 115                 GCRYPT_REQ_VERSION=1.4.5
 116         else
 117                 GCRYPT_REQ_VERSION=1.1.42
 118         fi
 119         dnl Check if we can use gcrypt PBKDF2 (1.6.0 supports empty password)
 120         AM_PATH_LIBGCRYPT([1.6.0], [use_internal_pbkdf2=0], [use_internal_pbkdf2=1])
 121         AM_PATH_LIBGCRYPT($GCRYPT_REQ_VERSION,,[AC_MSG_ERROR([You need the gcrypt library.])])
 122
 123         if test x$enable_static_cryptsetup = xyes; then
 124                 saved_LIBS=$LIBS
 125                 LIBS="$saved_LIBS $LIBGCRYPT_LIBS -static"
 126                 AC_CHECK_LIB(gcrypt, gcry_check_version,,
 127                         AC_MSG_ERROR([Cannot find static gcrypt library.]),
 128                         [-lgpg-error])
 129                 LIBGCRYPT_STATIC_LIBS="$LIBGCRYPT_LIBS -lgpg-error"
 130                 LIBS=$saved_LIBS
 131         fi
 132
 133         CRYPTO_CFLAGS=$LIBGCRYPT_CFLAGS
 134         CRYPTO_LIBS=$LIBGCRYPT_LIBS
 135         CRYPTO_STATIC_LIBS=$LIBGCRYPT_STATIC_LIBS
 136
 137         AC_DEFINE_UNQUOTED(GCRYPT_REQ_VERSION, ["$GCRYPT_REQ_VERSION"], [Requested gcrypt version])
 138 ])
 139
 140 AC_DEFUN([CONFIGURE_OPENSSL], [
 141         PKG_CHECK_MODULES([OPENSSL], [openssl >= 0.9.8],,
 142                 AC_MSG_ERROR([You need openssl library.]))
 143         CRYPTO_CFLAGS=$OPENSSL_CFLAGS
 144         CRYPTO_LIBS=$OPENSSL_LIBS
 145         use_internal_pbkdf2=0
 146
 147         if test x$enable_static_cryptsetup = xyes; then
 148                 saved_PKG_CONFIG=$PKG_CONFIG
 149                 PKG_CONFIG="$PKG_CONFIG --static"
 150                 PKG_CHECK_MODULES([OPENSSL], [openssl])
 151                 CRYPTO_STATIC_LIBS=$OPENSSL_LIBS
 152                 PKG_CONFIG=$saved_PKG_CONFIG
 153         fi
 154         NO_FIPS([])
 155 ])
 156
 157 AC_DEFUN([CONFIGURE_NSS], [
 158         if test x$enable_static_cryptsetup = xyes; then
 159                 AC_MSG_ERROR([Static build of cryptsetup is not supported with NSS.])
 160         fi
 161
 162         AC_MSG_WARN([NSS backend does NOT provide backward compatibility (missing ripemd160 hash).])
 163
 164         PKG_CHECK_MODULES([NSS], [nss],,
 165                 AC_MSG_ERROR([You need nss library.]))
 166
 167         saved_CFLAGS=$CFLAGS
 168         CFLAGS="$CFLAGS $NSS_CFLAGS"
 169         AC_CHECK_DECLS([NSS_GetVersion], [], [], [#include <nss.h>])
 170         CFLAGS=$saved_CFLAGS
 171
 172         CRYPTO_CFLAGS=$NSS_CFLAGS
 173         CRYPTO_LIBS=$NSS_LIBS
 174         use_internal_pbkdf2=1
 175         NO_FIPS([])
 176 ])
 177
 178 AC_DEFUN([CONFIGURE_KERNEL], [
 179         AC_CHECK_HEADERS(linux/if_alg.h,,
 180                 [AC_MSG_ERROR([You need Linux kernel headers with userspace crypto interface.])])
 181 #       AC_CHECK_DECLS([AF_ALG],,
 182 #               [AC_MSG_ERROR([You need Linux kernel with userspace crypto interface.])],
 183 #               [#include <sys/socket.h>])
 184         use_internal_pbkdf2=1
 185         NO_FIPS([])
 186 ])
 187
 188 AC_DEFUN([CONFIGURE_NETTLE], [
 189         AC_CHECK_HEADERS(nettle/sha.h,,
 190                 [AC_MSG_ERROR([You need Nettle cryptographic library.])])
 191
 192         saved_LIBS=$LIBS
 193         AC_CHECK_LIB(nettle, nettle_ripemd160_init,,
 194                 [AC_MSG_ERROR([You need Nettle library version 2.4 or more recent.])])
 195         CRYPTO_LIBS=$LIBS
 196         LIBS=$saved_LIBS
 197
 198         CRYPTO_STATIC_LIBS=$CRYPTO_LIBS
 199         use_internal_pbkdf2=1
 200         NO_FIPS([])
 201 ])
 202
 203 dnl ==========================================================================
 204 saved_LIBS=$LIBS
 205
 206 AC_ARG_ENABLE([static-cryptsetup],
 207         AS_HELP_STRING([--enable-static-cryptsetup],
 208         [enable build of static cryptsetup binary]))
 209 if test x$enable_static_cryptsetup = xyes; then
 210         if test x$enable_static = xno; then
 211                 AC_MSG_WARN([Requested static cryptsetup build, enabling static library.])
 212                 enable_static=yes
 213         fi
 214 fi
 215 AM_CONDITIONAL(STATIC_TOOLS, test x$enable_static_cryptsetup = xyes)
 216
 217 AC_ARG_ENABLE(veritysetup,
 218         AS_HELP_STRING([--disable-veritysetup],
 219         [disable veritysetup support]),[], [enable_veritysetup=yes])
 220 AM_CONDITIONAL(VERITYSETUP, test x$enable_veritysetup = xyes)
 221
 222 AC_ARG_ENABLE([cryptsetup-reencrypt],
 223         AS_HELP_STRING([--enable-cryptsetup-reencrypt],
 224         [enable cryptsetup-reencrypt tool]))
 225 AM_CONDITIONAL(REENCRYPT, test x$enable_cryptsetup_reencrypt = xyes)
 226
 227 AC_ARG_ENABLE(selinux,
 228         AS_HELP_STRING([--disable-selinux],
 229         [disable selinux support [default=auto]]),[], [])
 230
 231 AC_ARG_ENABLE([udev],
 232         AS_HELP_STRING([--disable-udev],
 233         [disable udev support]),[], enable_udev=yes)
 234
 235 dnl Try to use pkg-config for devmapper, but fallback to old detection
 236 PKG_CHECK_MODULES([DEVMAPPER], [devmapper >= 1.02.03],, [
 237         AC_CHECK_LIB(devmapper, dm_task_set_name,,
 238                 [AC_MSG_ERROR([You need the device-mapper library.])])
 239         AC_CHECK_LIB(devmapper, dm_task_set_message,,
 240                 [AC_MSG_ERROR([The device-mapper library on your system is too old.])])
 241         DEVMAPPER_LIBS=$LIBS
 242 ])
 243 LIBS=$saved_LIBS
 244
 245 LIBS="$LIBS $DEVMAPPER_LIBS"
 246 AC_CHECK_DECLS([dm_task_secure_data], [], [], [#include <libdevmapper.h>])
 247 AC_CHECK_DECLS([dm_task_retry_remove], [], [], [#include <libdevmapper.h>])
 248 AC_CHECK_DECLS([DM_UDEV_DISABLE_DISK_RULES_FLAG], [have_cookie=yes], [have_cookie=no], [#include <libdevmapper.h>])
 249 if test "x$enable_udev" = xyes; then
 250         if test "x$have_cookie" = xno; then
 251                 AC_MSG_WARN([The device-mapper library on your system has no udev support, udev support disabled.])
 252         else
 253                 AC_DEFINE(USE_UDEV, 1, [Try to use udev synchronisation?])
 254         fi
 255 fi
 256 LIBS=$saved_LIBS
 257
 258 dnl Crypto backend configuration.
 259 AC_ARG_WITH([crypto_backend],
 260         AS_HELP_STRING([--with-crypto_backend=BACKEND], [crypto backend (gcrypt/openssl/nss/kernel/nettle) [gcrypt]]),
 261         [], with_crypto_backend=gcrypt
 262 )
 263
 264 dnl Kernel crypto API backend needed for benchmark and tcrypt
 265 AC_ARG_ENABLE([kernel_crypto], AS_HELP_STRING([--disable-kernel_crypto],
 266         [disable kernel userspace crypto (no benchmark and tcrypt)]),
 267         [with_kernel_crypto=$enableval],
 268         [with_kernel_crypto=yes])
 269
 270 if test "x$with_kernel_crypto" = "xyes"; then
 271         AC_CHECK_HEADERS(linux/if_alg.h,,
 272                 [AC_MSG_ERROR([You need Linux kernel headers with userspace crypto interface. (Or use --disable-kernel_crypto.)])])
 273         AC_DEFINE(ENABLE_AF_ALG, 1, [Enable using of kernel userspace crypto])
 274 fi
 275
 276 case $with_crypto_backend in
 277         gcrypt)  CONFIGURE_GCRYPT([]) ;;
 278         openssl) CONFIGURE_OPENSSL([]) ;;
 279         nss)     CONFIGURE_NSS([]) ;;
 280         kernel)  CONFIGURE_KERNEL([]) ;;
 281         nettle)  CONFIGURE_NETTLE([]) ;;
 282         *) AC_MSG_ERROR([Unknown crypto backend.]) ;;
 283 esac
 284 AM_CONDITIONAL(CRYPTO_BACKEND_GCRYPT,  test $with_crypto_backend = gcrypt)
 285 AM_CONDITIONAL(CRYPTO_BACKEND_OPENSSL, test $with_crypto_backend = openssl)
 286 AM_CONDITIONAL(CRYPTO_BACKEND_NSS,     test $with_crypto_backend = nss)
 287 AM_CONDITIONAL(CRYPTO_BACKEND_KERNEL,  test $with_crypto_backend = kernel)
 288 AM_CONDITIONAL(CRYPTO_BACKEND_NETTLE,  test $with_crypto_backend = nettle)
 289
 290 AM_CONDITIONAL(CRYPTO_INTERNAL_PBKDF2, test $use_internal_pbkdf2 = 1)
 291 AC_DEFINE_UNQUOTED(USE_INTERNAL_PBKDF2, [$use_internal_pbkdf2], [Use internal PBKDF2])
 292
 293 dnl Magic for cryptsetup.static build.
 294 if test x$enable_static_cryptsetup = xyes; then
 295         saved_PKG_CONFIG=$PKG_CONFIG
 296         PKG_CONFIG="$PKG_CONFIG --static"
 297
 298         LIBS="$saved_LIBS -static"
 299         AC_CHECK_LIB(popt, poptGetContext,,
 300                 AC_MSG_ERROR([Cannot find static popt library.]))
 301
 302         dnl Try to detect needed device-mapper static libraries, try pkg-config first.
 303         LIBS="$saved_LIBS -static"
 304         PKG_CHECK_MODULES([DEVMAPPER_STATIC], [devmapper >= 1.02.27],,[
 305                 DEVMAPPER_STATIC_LIBS=$DEVMAPPER_LIBS
 306                 if test "x$enable_selinux" != xno; then
 307                         AC_CHECK_LIB(sepol, sepol_bool_set)
 308                         AC_CHECK_LIB(selinux, is_selinux_enabled)
 309                         DEVMAPPER_STATIC_LIBS="$DEVMAPPER_STATIC_LIBS $LIBS"
 310                 fi
 311         ])
 312         LIBS="$saved_LIBS $DEVMAPPER_STATIC_LIBS"
 313         AC_CHECK_LIB(devmapper, dm_task_set_uuid,,
 314                 AC_MSG_ERROR([Cannot link with static device-mapper library.]))
 315
 316         dnl Try to detect uuid static library.
 317         LIBS="$saved_LIBS -static"
 318         AC_CHECK_LIB(uuid, uuid_generate,,
 319                 AC_MSG_ERROR([Cannot find static uuid library.]))
 320
 321         LIBS=$saved_LIBS
 322         PKG_CONFIG=$saved_PKG_CONFIG
 323 fi
 324
 325 AC_SUBST([DEVMAPPER_LIBS])
 326 AC_SUBST([DEVMAPPER_STATIC_LIBS])
 327
 328 AC_SUBST([PWQUALITY_LIBS])
 329 AC_SUBST([PWQUALITY_STATIC_LIBS])
 330
 331 AC_SUBST([CRYPTO_CFLAGS])
 332 AC_SUBST([CRYPTO_LIBS])
 333 AC_SUBST([CRYPTO_STATIC_LIBS])
 334
 335 AC_SUBST([LIBCRYPTSETUP_VERSION])
 336 AC_SUBST([LIBCRYPTSETUP_VERSION_INFO])
 337 AC_SUBST([LIBCRYPTSETUP_VERSION_FIPS])
 338
 339 dnl ==========================================================================
 340 AC_ARG_ENABLE([dev-random], AS_HELP_STRING([--enable-dev-random],
 341 [use blocking /dev/random by default for key generator (otherwise use /dev/urandom)]),
 342 [default_rng=/dev/random], [default_rng=/dev/urandom])
 343 AC_DEFINE_UNQUOTED(DEFAULT_RNG, ["$default_rng"], [default RNG type for key generator])
 344
 345 dnl ==========================================================================
 346 AC_DEFUN([CS_DEFINE],
 347         [AC_DEFINE_UNQUOTED(DEFAULT_[]m4_translit([$1], [-a-z], [_A-Z]), [$2], [$3])
 348 ])
 349
 350 AC_DEFUN([CS_STR_WITH], [AC_ARG_WITH([$1],
 351         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 352         [CS_DEFINE([$1], ["$withval"], [$2])],
 353         [CS_DEFINE([$1], ["$3"], [$2])]
 354 )])
 355
 356 AC_DEFUN([CS_NUM_WITH], [AC_ARG_WITH([$1],
 357         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 358         [CS_DEFINE([$1], [$withval], [$2])],
 359         [CS_DEFINE([$1], [$3], [$2])]
 360 )])
 361
 362 dnl ==========================================================================
 363 dnl Python bindings
 364 AC_ARG_ENABLE([python], AS_HELP_STRING([--enable-python],[enable Python bindings]),
 365 [with_python=$enableval],
 366 [with_python=no])
 367
 368 if test "x$with_python" = "xyes"; then
 369         AM_PATH_PYTHON([2.4])
 370
 371         if ! test -x "$PYTHON-config" ; then
 372             AC_MSG_ERROR([Cannot find python development packages to build bindings])
 373         fi
 374
 375         PYTHON_INCLUDES=$($PYTHON-config --includes)
 376         AC_SUBST(PYTHON_INCLUDES)
 377 fi
 378 AM_CONDITIONAL([PYTHON_CRYPTSETUP], [test "x$with_python" = "xyes"])
 379
 380 dnl ==========================================================================
 381 CS_STR_WITH([plain-hash],   [password hashing function for plain mode], [ripemd160])
 382 CS_STR_WITH([plain-cipher], [cipher for plain mode], [aes])
 383 CS_STR_WITH([plain-mode],   [cipher mode for plain mode], [cbc-essiv:sha256])
 384 CS_NUM_WITH([plain-keybits],[key length in bits for plain mode], [256])
 385
 386 CS_STR_WITH([luks1-hash],   [hash function for LUKS1 header], [sha1])
 387 CS_STR_WITH([luks1-cipher], [cipher for LUKS1], [aes])
 388 CS_STR_WITH([luks1-mode],   [cipher mode for LUKS1], [cbc-essiv:sha256])
 389 CS_NUM_WITH([luks1-keybits],[key length in bits for LUKS1], [256])
 390 CS_NUM_WITH([luks1-iter-time],[PBKDF2 iteration time for LUKS1 (in ms)], [1000])
 391
 392 CS_STR_WITH([loopaes-cipher], [cipher for loop-AES mode], [aes])
 393 CS_NUM_WITH([loopaes-keybits],[key length in bits for loop-AES mode], [256])
 394
 395 CS_NUM_WITH([keyfile-size-maxkb],[maximum keyfile size (in KiB)], [8192])
 396 CS_NUM_WITH([passphrase-size-max],[maximum keyfile size (in characters)], [512])
 397
 398 CS_STR_WITH([verity-hash],       [hash function for verity mode], [sha256])
 399 CS_NUM_WITH([verity-data-block], [data block size for verity mode], [4096])
 400 CS_NUM_WITH([verity-hash-block], [hash block size for verity mode], [4096])
 401 CS_NUM_WITH([verity-salt-size],  [salt size for verity mode], [32])
 402
 403 dnl ==========================================================================
 404
 405 AC_CONFIG_FILES([ Makefile
 406 lib/Makefile
 407 lib/libcryptsetup.pc
 408 lib/crypto_backend/Makefile
 409 lib/luks1/Makefile
 410 lib/loopaes/Makefile
 411 lib/verity/Makefile
 412 lib/tcrypt/Makefile
 413 src/Makefile
 414 po/Makefile.in
 415 man/Makefile
 416 tests/Makefile
 417 python/Makefile
 418 ])
 419 AC_OUTPUT