configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.5.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AM_PROG_LIBTOOL
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=0.10.13
  50 GSTPB_REQ=0.10.13
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.11.5])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DEBUG
  69 AG_GST_ARG_PROFILING
  70 AG_GST_ARG_VALGRIND
  71 AG_GST_ARG_GCOV
  72
  73 AG_GST_ARG_EXAMPLES
  74
  75 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  76 AG_GST_ARG_WITH_PACKAGE_NAME
  77 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  78
  79 dnl these are all the gst plug-ins, compilable without additional libs
  80 dnl videofilter is at the top because others depend on it
  81 GST_PLUGINS_ALL="\
  82                 videofilter \
  83                 alpha \
  84                 apetag \
  85                 audiofx \
  86                 auparse \
  87                 autodetect \
  88                 avi \
  89                 cutter \
  90                 debug \
  91                 effectv \
  92                 id3demux \
  93                 icydemux \
  94                 flx \
  95                 goom \
  96                 law \
  97                 level \
  98                 matroska \
  99                 monoscope \
 100                 multipart \
 101                 qtdemux \
 102                 rtp     \
 103                 rtsp    \
 104                 smpte   \
 105                 udp     \
 106                 videobox \
 107                 videocrop \
 108                 videomixer \
 109                 wavenc \
 110                 wavparse \
 111                 "
 112 AC_SUBST(GST_PLUGINS_ALL)
 113
 114 GST_PLUGINS_SELECTED=""
 115
 116 AC_ARG_WITH(plugins,
 117     AC_HELP_STRING([--with-plugins],
 118       [comma-separated list of plug-ins to compile]),
 119     [for i in `echo $withval | tr , ' '`; do
 120         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 121         then
 122             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 123         else
 124             echo "plug-in $i not recognized, ignoring..."
 125         fi
 126     done],
 127     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 128
 129 dnl disable gst plugins we might not be able to build on this
 130 dnl platform: udp and rtsp (ugly but minimally invasive)
 131 dnl FIXME: maybe move to sys
 132 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 133 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 134
 135 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 136   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/udp//`
 137   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/rtsp//`
 138 fi
 139
 140 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 141   WIN32_LIBS="-lws2_32"
 142   AC_SUBST(WIN32_LIBS)
 143 fi
 144
 145 dnl ext plug-ins; plug-ins that have external dependencies
 146 AG_GST_CHECK_FEATURE(EXTERNAL, [building of plug-ins with external deps],,
 147   [HAVE_EXTERNAL=yes], enabled,
 148   [
 149     AC_MSG_NOTICE(building external plug-ins)
 150     BUILD_EXTERNAL="yes"
 151   ],[
 152     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 153     BUILD_EXTERNAL="no"
 154   ])
 155 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 156
 157 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
 158 AG_GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
 159 [HAVE_EXPERIMENTAL=yes],disabled,
 160 [
 161   AC_MSG_WARN(building experimental plug-ins)
 162   USE_GST_V4L2="yes"
 163 ],[
 164   AC_MSG_NOTICE(not building experimental plug-ins)
 165   USE_GST_V4L2="no"
 166   GST_PLUGINS_SELECTED=`echo $GST_PLUGINS_SELECTED | $SED -e s/monoscope//`
 167 ])
 168
 169 AC_SUBST(GST_PLUGINS_SELECTED)
 170
 171 dnl *** checks for platform ***
 172
 173 dnl * hardware/architecture *
 174
 175 dnl common/m4/gst-arch.m4
 176 dnl check CPU type
 177 AG_GST_ARCH
 178
 179 dnl Determine endianness
 180 AC_C_BIGENDIAN
 181
 182 dnl *** checks for programs ***
 183
 184 dnl find a compiler
 185 AC_PROG_CC
 186
 187 dnl determine c++ compiler
 188 AC_PROG_CXX
 189 dnl determine if c++ is available on this system
 190 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 191
 192 dnl determine c++ preprocessor
 193 dnl FIXME: do we need this ?
 194 AC_PROG_CXXCPP
 195
 196 AS_PROG_OBJC
 197
 198 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 199 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 200
 201 dnl check for gconftool-2
 202 dnl this macro defines an am conditional, so it needs to be run always
 203 AM_GCONF_SOURCE_2
 204
 205 dnl check for documentation tools
 206 GTK_DOC_CHECK([1.3])
 207 AS_PATH_PYTHON([2.1])
 208 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 209
 210 dnl *** checks for libraries ***
 211
 212 dnl check for libm, for sin()
 213 AC_CHECK_LIBM
 214 AC_SUBST(LIBM)
 215
 216 dnl *** checks for header files ***
 217
 218 dnl check if we have ANSI C header files
 219 AC_HEADER_STDC
 220
 221 dnl used by ext/wavpack
 222 AX_CREATE_STDINT_H
 223
 224 dnl used in gst/rtp/gstasteriskh263.c
 225 AC_CHECK_HEADERS([netinet/in.h])
 226 AC_CHECK_HEADERS([winsock2.h])
 227 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 228
 229 dnl *** checks for types/defines ***
 230
 231 dnl Check for FIONREAD ioctl declaration.  This check is needed
 232 dnl for the UDP plugin to build on Solaris
 233 GST_CHECK_FIONREAD
 234
 235 dnl *** checks for structures ***
 236
 237 dnl *** checks for compiler characteristics ***
 238
 239 dnl FIXME: check if this is used; was used for floatcast.h in base
 240 dnl Check for fast float to int casting as defined in C99
 241 AC_C99_FUNC_LRINT
 242 AC_C99_FUNC_LRINTF
 243
 244 dnl *** checks for library functions ***
 245
 246 dnl Check for mmap (needed by electricfence plugin)
 247 AC_FUNC_MMAP
 248 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 249
 250 dnl *** checks for dependency libraries ***
 251
 252 dnl GLib is required
 253 AG_GST_GLIB_CHECK([2.6])
 254
 255 dnl liboil is required
 256 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.2, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 257 if test "x${HAVE_LIBOIL}" != xyes ; then
 258   AC_ERROR([liboil-0.3 is required])
 259 fi
 260
 261 dnl checks for gstreamer
 262 dnl uninstalled is selected preferentially -- see pkg-config(1)
 263 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 264 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 265 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 266 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 267 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 268 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ])
 269
 270 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 271 if test -z $GST_TOOLS_DIR; then
 272   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 273 fi
 274 AC_SUBST(GST_TOOLS_DIR)
 275
 276 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 277 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 278
 279 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 280 dnl check for "check", unit testing library/header
 281 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 282 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 283
 284 dnl Check for documentation xrefs
 285 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 286 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 287 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 288 AC_SUBST(GLIB_PREFIX)
 289 AC_SUBST(GST_PREFIX)
 290 AC_SUBST(GSTPB_PREFIX)
 291
 292 dnl GTK is optional and used in examples
 293 HAVE_GTK=NO
 294 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 295 if test "x$HAVE_GTK_22" = "xyes"; then
 296   HAVE_GTK=yes
 297   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 298   AC_SUBST(GTK_VERSION)
 299   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 300   AC_SUBST(GTK_BASE_DIR)
 301   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 302   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 303   AC_SUBST(GTK_BASE_DIR)
 304 else
 305   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 306 fi
 307 if test "x$HAVE_GTK_20" = "xyes"; then
 308   HAVE_GTK=yes
 309 fi
 310 GTK_CFLAGS=$GTK2_CFLAGS
 311 GTK_LIBS=$GTK2_LIBS
 312 AC_SUBST(GTK_LIBS)
 313 AC_SUBST(GTK_CFLAGS)
 314 AC_SUBST(HAVE_GTK)
 315 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 316
 317 dnl should we install schemas ?
 318 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 319 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 320   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 321   if test x$GCONFTOOL = xno; then
 322     AC_MSG_WARN(Not installing GConf schemas)
 323     HAVE_GCONFTOOL="no"
 324   else
 325     HAVE_GCONFTOOL="yes"
 326   fi
 327   AC_SUBST(HAVE_GCONFTOOL)
 328 ])
 329
 330 dnl *** set variables based on configure arguments ***
 331
 332 dnl set license and copyright notice
 333 GST_LICENSE="LGPL"
 334 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 335 AC_SUBST(GST_LICENSE)
 336
 337 dnl set location of plugin directory
 338 AG_GST_SET_PLUGINDIR
 339
 340 dnl define an ERROR_CFLAGS Makefile variable
 341 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 342
 343 dnl define correct level for debugging messages
 344 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 345
 346 dnl used in examples
 347 AG_GST_DEFAULT_ELEMENTS
 348
 349 dnl *** sys plug-ins ***
 350
 351 echo
 352 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 353 echo
 354
 355 dnl DirectDraw
 356 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTDRAW, true)
 357 AG_GST_CHECK_FEATURE(DIRECTDRAW, [DirectDraw plug-in], directdrawsink, [
 358   HAVE_DIRECTDRAW="no"
 359   save_CFLAGS="$CFLAGS"
 360   save_LDFLAGS="$LDFLAGS"
 361   save_LIBS="$LIBS"
 362   CFLAGS="$CFLAGS $DIRECTDRAW_CFLAGS"
 363   LDFLAGS="$LDFLAGS $DIRECTDRAW_LDFLAGS"
 364   LIBS="$LIBS -lddraw -lgdi32"
 365   AC_MSG_CHECKING(for DirectDraw LDFLAGS)
 366   AC_LINK_IFELSE([
 367 #include <windows.h>
 368 #include <ddraw.h>
 369
 370 int main ()
 371 {
 372   GetStockObject(0);
 373   DirectDrawCreate(NULL, NULL, NULL);
 374
 375   return 0;
 376 }
 377 ],
 378     [HAVE_DIRECTDRAW="yes"],
 379     [HAVE_DIRECTDRAW="no"])
 380   AC_MSG_RESULT($HAVE_DIRECTDRAW)
 381   CFLAGS=$save_CFLAGS
 382   LDFLAGS=$save_LDFLAGS
 383   LIBS=$save_LIBS
 384
 385   if test "x$HAVE_DIRECTDRAW" = "xyes";  then
 386     dnl this is much more than we want
 387     DIRECTDRAW_LIBS="-lddraw -ldxguid -lgdi32"
 388     AC_SUBST(DIRECTDRAW_CFLAGS)
 389     AC_SUBST(DIRECTDRAW_LDFLAGS)
 390     AC_SUBST(DIRECTDRAW_LIBS)
 391   fi
 392   AC_SUBST(HAVE_DIRECTDRAW)
 393 ])
 394
 395 dnl DirectSound
 396 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 397 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 398   HAVE_DIRECTSOUND="no"
 399   save_CFLAGS="$CFLAGS"
 400   save_LDFLAGS="$LDFLAGS"
 401   save_LIBS="$LIBS"
 402   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 403   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 404   LIBS="$LIBS -ldsound -ldxerr9"
 405   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 406   AC_LINK_IFELSE([
 407 #include <windows.h>
 408 #include <dxerr9.h>
 409 #include <dsound.h>
 410
 411 int main ()
 412 {
 413   DXGetErrorString9 (0);
 414   DirectSoundCreate(NULL, NULL, NULL);
 415
 416   return 0;
 417 }
 418 ],
 419     [HAVE_DIRECTSOUND="yes"],
 420     [HAVE_DIRECTSOUND="no"])
 421   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 422   CFLAGS=$save_CFLAGS
 423   LDFLAGS=$save_LDFLAGS
 424   LIBS=$save_LIBS
 425
 426   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 427     dnl this is much more than we want
 428     DIRECTSOUND_LIBS="-ldsound -ldxerr9"
 429     AC_SUBST(DIRECTSOUND_CFLAGS)
 430     AC_SUBST(DIRECTSOUND_LDFLAGS)
 431     AC_SUBST(DIRECTSOUND_LIBS)
 432   fi
 433   AC_SUBST(HAVE_DIRECTSOUND)
 434 ])
 435
 436 dnl *** OSS audio *** (Linux, *BSD)
 437 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 438 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 439  HAVE_OSS="yes"
 440 dnl Linux and newer BSD versions :
 441  AC_CHECK_HEADER(sys/soundcard.h, [
 442    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 443    ] , [
 444 dnl Some old BSD versions and also newer OpenBSD versions :
 445    AC_CHECK_HEADER(soundcard.h, [
 446      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 447      ], [
 448   dnl Some old BSD versions :
 449      AC_CHECK_HEADER(machine/soundcard.h, [
 450        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 451          [Define if OSS includes are in /machine/])
 452        ], [
 453        HAVE_OSS="no"
 454      ])
 455    ])
 456  ])
 457 ])
 458
 459 dnl *** Sun Audio ***
 460 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 461 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 462   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 463 ])
 464
 465 dnl *** OSX Audio ***
 466 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 467 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 468   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 469 ])
 470
 471 dnl *** OS X video ***
 472 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 473 HAVE_OSX_VIDEO="no"
 474 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 475   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 476 ])
 477 dnl in case header OpenGL/gl.h is found on other platforms
 478 case "$host" in
 479   *-*darwin*)
 480     dnl do nothing
 481     ;;
 482   *)
 483     HAVE_OSX_VIDEO="no"
 484     ;;
 485 esac
 486
 487
 488 dnl *** Video 4 Linux 2 ***
 489 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 490 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 491 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 492 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 493   AC_MSG_CHECKING([Checking for uptodate v4l2 installation])
 494   AC_TRY_COMPILE([
 495 #include <sys/types.h>
 496 #include <linux/types.h>
 497 #define _LINUX_TIME_H
 498 #define __user
 499 #include <linux/videodev2.h>
 500 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 501 #error too early v4l2 version or no v4l2 at all
 502 #endif
 503     ], [
 504 return 0;
 505     ], [
 506       HAVE_GST_V4L2="yes"
 507       AC_MSG_RESULT(yes)
 508     ], [
 509       HAVE_GST_V4L2="no"
 510       AC_MSG_RESULT(no)
 511       AC_CHECK_HEADER(linux/videodev2.h,
 512       [
 513         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 514         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 515       ], [
 516         AC_MSG_WARN([video4linux2 was not found])
 517       ])
 518     ])
 519
 520   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 521     dnl check for missing v4l2_buffer declaration (see #135919)
 522     MISSING_DECL=0
 523     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 524     AC_TRY_COMPILE([
 525 #include <sys/types.h>
 526 #include <linux/types.h>
 527 #define _LINUX_TIME_H
 528 #define __user
 529 #include <linux/videodev2.h>
 530     ],[
 531 struct v4l2_buffer buf;
 532 buf.index = 0;
 533 return 0;
 534     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 535     if [ test x$MISSING_DECL = x1 ]; then
 536       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 537     fi
 538
 539     dnl check for XOverlay libraries
 540     AG_GST_CHECK_XV
 541   fi
 542 ])
 543
 544 dnl Check for X11
 545 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 546 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 547                   [ximagesrc], [
 548   AC_PATH_XTRA
 549
 550   dnl now try to find the HEADER
 551   ac_cflags_save="$CFLAGS"
 552   ac_cppflags_save="$CPPFLAGS"
 553   CFLAGS="$CFLAGS $X_CFLAGS"
 554   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 555   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 556
 557   if test "x$HAVE_X" = "xno"
 558   then
 559     AC_MSG_NOTICE([cannot find X11 development files])
 560   else
 561     dnl this is much more than we want
 562     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 563     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 564     dnl it does not add the libs; therefore we add them here
 565     X_LIBS="$X_LIBS -lX11"
 566     AC_SUBST(X_CFLAGS)
 567     AC_SUBST(X_LIBS)
 568
 569     dnl check for Xfixes
 570     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 571     if test "x$HAVE_XFIXES" = "xyes"
 572     then
 573         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 574     fi
 575     AC_SUBST(XFIXES_LIBS)
 576     AC_SUBST(XFIXES_CFLAGS)
 577
 578     dnl check for Xdamage
 579     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 580     if test "x$HAVE_XDAMAGE" = "xyes"
 581     then
 582         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 583     fi
 584     AC_SUBST(XDAMAGE_LIBS)
 585     AC_SUBST(XDAMAGE_CFLAGS)
 586   fi
 587   AC_SUBST(HAVE_X)
 588   CFLAGS="$ac_cflags_save"
 589   CPPFLAGS="$ac_cppflags_save"
 590 ])
 591
 592 dnl FIXME: this should be rolled into the test above, it's just an additional
 593 dnl feature of the ximagesrc plug-in
 594 dnl This is the same as in gst-plugins-base
 595 dnl check for X Shm
 596 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 597 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 598   if test x$HAVE_X = xyes; then
 599     AC_CHECK_LIB(Xext, XShmAttach,
 600                  HAVE_XSHM="yes", HAVE_XSHM="no",
 601                  $X_LIBS)
 602     if test "x$HAVE_XSHM" = "xyes"; then
 603       XSHM_LIBS="-lXext"
 604     else
 605       dnl On AIX, it is in XextSam instead, but we still need -lXext
 606       AC_CHECK_LIB(XextSam, XShmAttach,
 607                    HAVE_XSHM="yes", HAVE_XSHM="no",
 608                    $X_LIBS)
 609       if test "x$HAVE_XSHM" = "xyes"; then
 610         XSHM_LIBS="-lXext -lXextSam"
 611       fi
 612     fi
 613   fi
 614 ], ,[
 615   AC_SUBST(HAVE_XSHM)
 616   AC_SUBST(XSHM_LIBS)
 617 ])
 618
 619 dnl for V4L2, we also need to know if we have XVIDEO
 620 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 621 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 622                   [], [
 623   AG_GST_CHECK_XV
 624 ])
 625
 626 dnl *** ext plug-ins ***
 627 dnl keep this list sorted alphabetically !
 628
 629 if test "x$BUILD_EXTERNAL" = "xyes"; then
 630
 631 echo
 632 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 633 echo
 634
 635 dnl *** aalib ***
 636 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 637 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 638   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 639   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 640 ])
 641
 642 dnl *** annodex ***
 643 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 644 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 645   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 646 ])
 647
 648 dnl *** cairo ***
 649 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 650 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 651   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 652 ])
 653
 654 dnl *** cdio ***
 655 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 656 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 657   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.71)
 658 ])
 659
 660 dnl **** ESound ****
 661 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 662 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 663   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 664   if test $HAVE_ESD = no
 665   then
 666     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 667     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 668   fi
 669 ])
 670
 671 dnl *** FLAC ***
 672 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 673 AC_TRY_RUN([
 674 #include <FLAC/export.h>
 675 int main () { return FLAC_API_VERSION_CURRENT<8; }
 676 ],legacy_flac=no,legacy_flac=yes,legacy_flac=no)
 677
 678 if test "x$legacy_flac" = "xyes"; then
 679 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 680   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 681   dnl API change in FLAC 1.1.1, so require that...
 682   dnl (this check will also fail with FLAC 1.1.3 which changed API again)
 683   if test x$HAVE_FLAC = xyes; then
 684     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 685                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 686 #include <FLAC/seekable_stream_encoder.h>
 687                   ])
 688   fi
 689   AC_SUBST(FLAC_LIBS)
 690 ])
 691 else
 692 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 693   AG_GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 694   dnl API change in FLAC 1.1.3, so require that...
 695   if test x$HAVE_FLAC = xyes; then
 696     AC_CHECK_DECL(FLAC__STREAM_ENCODER_TELL_STATUS_ERROR,
 697                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 698 #include <FLAC/stream_encoder.h>
 699                   ])
 700   fi
 701   AC_SUBST(FLAC_LIBS)
 702 ])
 703 fi
 704
 705 dnl *** GConf ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 707 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 708   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 709 ])
 710
 711 dnl *** GDK pixbuf ***
 712 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 713 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 714   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 715 ])
 716
 717 dnl *** HAL ***
 718 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 719 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 720   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 721 ])
 722
 723 dnl *** jpeg ***
 724 dnl FIXME: we could use header checks here as well IMO
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 726 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 727   AC_ARG_WITH(jpeg-mmx,
 728     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 729   OLD_LIBS="$LIBS"
 730   if test x$with_jpeg_mmx != x; then
 731     LIBS="$LIBS -L$with_jpeg_mmx"
 732   fi
 733   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 734   JPEG_LIBS="$LIBS -ljpeg-mmx"
 735   LIBS="$OLD_LIBS"
 736   if test x$HAVE_JPEG != xyes; then
 737     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 738     JPEG_LIBS="-ljpeg"
 739   fi
 740   AC_SUBST(JPEG_LIBS)
 741 ])
 742
 743 dnl *** ladspa ***
 744 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 745 AG_GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 746   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 747 ], disabled)
 748
 749 dnl *** libcaca ***
 750 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 751 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 752   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 753   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 754   if test "x$HAVE_LIBCACA" != "xyes"; then
 755     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 756     dnl see if it compilation works too, might not if we are cross-compiling
 757     if test "x$HAVE_LIBCACA" = "xyes"; then
 758       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 759                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 760     fi
 761   fi
 762 ])
 763
 764 dnl *** libdv ***
 765 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 766 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 767   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 768 ])
 769
 770 dnl *** libpng ***
 771 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 772 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 773   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 774 ])
 775
 776 dnl *** dv1394 ***
 777 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 778 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 779   dnl first test for libraw1394 >= 1.2.1
 780   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 781   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 782   dnl now see how far we got
 783   if test x$HAVE_RAW1394 = xyes && \
 784      test x$HAVE_LIBIEC61883 = xyes; then
 785        AG_GST_CHECK_LIBHEADER(AVC1394,
 786         avc1394, avc1394_send_command, $RAW1394_LIBS,
 787         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 788        AG_GST_CHECK_LIBHEADER(ROM1394,
 789         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 790         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 791        if test x$HAVE_AVC1394 = xyes && \
 792           test x$HAVE_AVC1394 = xyes && \
 793           test x$HAVE_ROM1394 = xyes; then
 794           HAVE_DV1394=yes
 795           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 796           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 797           AC_SUBST(DV1394_CFLAGS)
 798           AC_SUBST(DV1394_LIBS)
 799         fi
 800   else
 801        if test x$HAVE_RAW1394 = xno; then
 802           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 803           AG_GST_CHECK_LIBHEADER(AVC1394,
 804            avc1394, avc1394_send_command, $RAW1394_LIBS,
 805            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 806           AG_GST_CHECK_LIBHEADER(ROM1394,
 807            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 808            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 809           if test x$HAVE_RAW1394 = xyes && \
 810              test x$HAVE_AVC1394 = xyes && \
 811              test x$HAVE_ROM1394 = xyes; then
 812              HAVE_DV1394=yes
 813              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 814              DV1394_CFLAGS="$RAW1394_CFLAGS"
 815              if test x$HAVE_LIBIEC61883 = xyes; then
 816                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 817                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 818              fi
 819              AC_SUBST(DV1394_CFLAGS)
 820              AC_SUBST(DV1394_LIBS)
 821            fi
 822          fi
 823   fi
 824 ])
 825
 826 dnl *** shout2 ***
 827 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 828 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 829   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 830   if test $HAVE_SHOUT2 = no
 831   then
 832     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 833     AC_SUBST(SHOUT2_CFLAGS)
 834     AC_SUBST(SHOUT2_LIBS)
 835   fi
 836 ])
 837
 838 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 839 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 840 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 841 dnl   speex_jitter.h is 1.1.x only
 842 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 843 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 844   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 845   if test $HAVE_SPEEX = no
 846   then
 847     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 848       AC_CHECK_HEADER(speex/speex_jitter.h, [
 849         dnl speex 1.1.x :
 850         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 851           dnl speex 1.1.5 or + :
 852           HAVE_SPEEX="yes"
 853           SPEEX_LIBS="-lspeex"
 854           AC_SUBST(SPEEX_CFLAGS)
 855           AC_SUBST(SPEEX_LIBS)
 856         ],[
 857           HAVE_SPEEX="no"
 858         ])
 859       ],[
 860         dnl speex 1.0.x :
 861           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 862             dnl speex 1.0.4
 863             HAVE_SPEEX="yes"
 864             SPEEX_LIBS="-lspeex"
 865             AC_SUBST(SPEEX_CFLAGS)
 866             AC_SUBST(SPEEX_LIBS)
 867
 868             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 869               [defined if speex 1.0.x API detected])
 870         ],[
 871             HAVE_SPEEX="no"
 872             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 873         ], [
 874 #include <speex/speex.h>
 875         ])
 876       ])
 877     ])
 878   fi
 879 ])
 880
 881 dnl *** taglib ***
 882 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 883 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 884   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.4)
 885   if test "x$HAVE_CXX" != "xyes"; then
 886     USE_TAGLIB=false
 887     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 888   fi
 889 ])
 890
 891 dnl *** wavpack ***
 892 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 893 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 894   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 895     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 896       HAVE_WAVPACK=yes
 897       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 898     ],[
 899       HAVE_WAVPACK=no
 900       AC_MSG_RESULT(no)
 901     ])
 902   ])
 903   AC_SUBST(WAVPACK_CFLAGS)
 904   AC_SUBST(WAVPACK_LIBS)
 905 ])
 906
 907 dnl *** qtdemux & id3demux prefer to have zlib ***
 908 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 909 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux],, [
 910   AG_GST_CHECK_LIBHEADER(ZLIB,
 911     z, uncompress,, zlib.h, [
 912     HAVE_ZLIB="yes"
 913     ZLIB_LIBS="-lz"
 914     AC_SUBST(ZLIB_LIBS)
 915   ])
 916 ])
 917
 918 else
 919
 920 dnl not building plugins with external dependencies,
 921 dnl but we still need to set the conditionals
 922 AM_CONDITIONAL(USE_GCONFTOOL, false)
 923 AM_CONDITIONAL(USE_DIRECTDRAW, false)
 924 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 925 AM_CONDITIONAL(USE_OSS, false)
 926 AM_CONDITIONAL(USE_SUNAUDIO, false)
 927 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 928 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 929 AM_CONDITIONAL(USE_X, false)
 930 AM_CONDITIONAL(USE_XSHM, false)
 931 AM_CONDITIONAL(USE_AALIB, false)
 932 AM_CONDITIONAL(USE_ANNODEX, false)
 933 AM_CONDITIONAL(USE_CAIRO, false)
 934 AM_CONDITIONAL(USE_CDIO, false)
 935 AM_CONDITIONAL(USE_ESD, false)
 936 AM_CONDITIONAL(USE_FLAC, false)
 937 AM_CONDITIONAL(USE_GCONF, false)
 938 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 939 AM_CONDITIONAL(USE_HAL, false)
 940 AM_CONDITIONAL(USE_JPEG, false)
 941 AM_CONDITIONAL(USE_LADSPA, false)
 942 AM_CONDITIONAL(USE_LIBCACA, false)
 943 AM_CONDITIONAL(USE_LIBDV, false)
 944 AM_CONDITIONAL(USE_LIBPNG, false)
 945 AM_CONDITIONAL(USE_DV1394, false)
 946 AM_CONDITIONAL(USE_SHOUT2, false)
 947 AM_CONDITIONAL(USE_SPEEX, false)
 948 AM_CONDITIONAL(USE_TAGLIB, false)
 949 AM_CONDITIONAL(USE_WAVPACK, false)
 950 AM_CONDITIONAL(USE_ZLIB, false)
 951
 952 fi dnl of EXT plugins
 953
 954 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 955
 956 dnl Overview:
 957 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 958 dnl GST_*:              flags shared by all built objects
 959 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 960 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 961 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 962 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 963
 964 dnl GST_OPTION_CFLAGS
 965 if test "x$USE_DEBUG" = xyes; then
 966    PROFILE_CFLAGS="-g"
 967 fi
 968 AC_SUBST(PROFILE_CFLAGS)
 969
 970 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 971 AC_SUBST(DEPRECATED_CFLAGS)
 972
 973 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 974 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 975 AC_SUBST(GST_OPTION_CFLAGS)
 976
 977 dnl our libraries need to be versioned correctly
 978 AC_SUBST(GST_LT_LDFLAGS)
 979
 980 dnl FIXME: do we want to rename to GST_ALL_* ?
 981 dnl prefer internal headers to already installed ones
 982 dnl also add builddir include for enumtypes and marshal
 983 dnl add ERROR_CFLAGS, but overridable
 984 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 985 AC_SUBST(GST_CFLAGS)
 986 AC_SUBST(GST_LIBS)
 987
 988 dnl LDFLAGS really should only contain flags, not libs - they get added before
 989 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 990 GST_ALL_LDFLAGS="-no-undefined"
 991 AC_SUBST(GST_ALL_LDFLAGS)
 992
 993 dnl this really should only contain flags, not libs - they get added before
 994 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 995 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 996 AC_SUBST(GST_PLUGIN_LDFLAGS)
 997
 998 dnl *** output files ***
 999
1000 dnl keep this alphabetic per directory, please
1001 AC_CONFIG_FILES(
1002 Makefile
1003 gst/Makefile
1004 gst/alpha/Makefile
1005 gst/apetag/Makefile
1006 gst/audiofx/Makefile
1007 gst/auparse/Makefile
1008 gst/autodetect/Makefile
1009 gst/avi/Makefile
1010 gst/cutter/Makefile
1011 gst/debug/Makefile
1012 gst/effectv/Makefile
1013 gst/id3demux/Makefile
1014 gst/icydemux/Makefile
1015 gst/goom/Makefile
1016 gst/law/Makefile
1017 gst/level/Makefile
1018 gst/matroska/Makefile
1019 gst/monoscope/Makefile
1020 gst/multipart/Makefile
1021 gst/qtdemux/Makefile
1022 gst/rtp/Makefile
1023 gst/rtsp/Makefile
1024 gst/smpte/Makefile
1025 gst/udp/Makefile
1026 gst/videobox/Makefile
1027 gst/videocrop/Makefile
1028 gst/videofilter/Makefile
1029 gst/videomixer/Makefile
1030 gst/wavenc/Makefile
1031 gst/wavparse/Makefile
1032 gst/flx/Makefile
1033 ext/jpeg/Makefile
1034 ext/Makefile
1035 ext/aalib/Makefile
1036 ext/annodex/Makefile
1037 ext/cairo/Makefile
1038 ext/cdio/Makefile
1039 ext/dv/Makefile
1040 ext/esd/Makefile
1041 ext/flac/Makefile
1042 ext/gconf/Makefile
1043 ext/gdk_pixbuf/Makefile
1044 ext/hal/Makefile
1045 ext/ladspa/Makefile
1046 ext/libcaca/Makefile
1047 ext/libpng/Makefile
1048 ext/raw1394/Makefile
1049 ext/shout2/Makefile
1050 ext/speex/Makefile
1051 ext/taglib/Makefile
1052 ext/wavpack/Makefile
1053 sys/Makefile
1054 sys/directdraw/Makefile
1055 sys/directsound/Makefile
1056 sys/oss/Makefile
1057 sys/sunaudio/Makefile
1058 sys/osxaudio/Makefile
1059 sys/osxvideo/Makefile
1060 sys/v4l2/Makefile
1061 sys/ximage/Makefile
1062 po/Makefile.in
1063 tests/Makefile
1064 tests/check/Makefile
1065 tests/examples/Makefile
1066 tests/examples/level/Makefile
1067 tests/files/Makefile
1068 tests/icles/Makefile
1069 gconf/Makefile
1070 gconf/gstreamer.schemas
1071 common/Makefile
1072 common/m4/Makefile
1073 m4/Makefile
1074 docs/Makefile
1075 docs/plugins/Makefile
1076 docs/version.entities
1077 win32/common/config.h
1078 pkgconfig/Makefile
1079 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1080 gst-plugins-good.spec
1081 )
1082 AC_OUTPUT
1083
1084 AG_GST_OUTPUT_PLUGINS