configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ(2.60)
  22 AC_INIT([libdrm], 2.4.18, [dri-devel@lists.sourceforge.net], libdrm)
  23 AC_USE_SYSTEM_EXTENSIONS
  24 AC_CONFIG_SRCDIR([Makefile.am])
  25 AM_INIT_AUTOMAKE([dist-bzip2])
  26
  27 AM_CONFIG_HEADER([config.h])
  28
  29 AC_DISABLE_STATIC
  30 AC_PROG_LIBTOOL
  31 AC_PROG_CC
  32
  33 AC_HEADER_STDC
  34 AC_SYS_LARGEFILE
  35 AC_FUNC_ALLOCA
  36
  37 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  38 AC_SUBST(PTHREADSTUBS_CFLAGS)
  39 AC_SUBST(PTHREADSTUBS_LIBS)
  40
  41 pkgconfigdir=${libdir}/pkgconfig
  42 AC_SUBST(pkgconfigdir)
  43 AC_ARG_ENABLE(udev,     AS_HELP_STRING([--enable-udev],
  44                                 [Enable support for using udev instead of mknod (default: disabled)]),
  45                                 [UDEV=$enableval], [UDEV=no])
  46
  47 AC_ARG_ENABLE(libkms,
  48               AS_HELP_STRING([--disable-libkms],
  49               [Disable KMS mm abstraction library (default: enabled)]),
  50               [LIBKMS=$enableval], [LIBKMS=yes])
  51
  52 AC_ARG_ENABLE(intel,
  53               AS_HELP_STRING([--disable-intel],
  54               [Enable support for intel's KMS API (default: auto)]),
  55               [INTEL=$enableval], [INTEL=auto])
  56
  57 AC_ARG_ENABLE(radeon,
  58               AS_HELP_STRING([--disable-radeon],
  59               [Enable support for radeon's KMS API (default: enabled)]),
  60               [RADEON=$enableval], [RADEON=yes])
  61
  62 AC_ARG_ENABLE(vmwgfx-experimental-api,
  63               AS_HELP_STRING([--enable-vmwgfx-experimental-api],
  64               [Install vmwgfx's experimental kernel API header (default: disabled)]),
  65               [VMWGFX=$enableval], [VMWGFX=no])
  66
  67 AC_ARG_ENABLE(nouveau-experimental-api,
  68               AS_HELP_STRING([--enable-nouveau-experimental-api],
  69               [Enable support for nouveau's experimental API (default: disabled)]),
  70               [NOUVEAU=$enableval], [NOUVEAU=no])
  71
  72
  73 dnl ===========================================================================
  74 dnl check compiler flags
  75 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
  76   AC_MSG_CHECKING([whether $CC supports $1])
  77
  78   libdrm_save_CFLAGS="$CFLAGS"
  79   CFLAGS="$CFLAGS $1"
  80
  81   AC_COMPILE_IFELSE([ ], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
  82   CFLAGS="$libdrm_save_CFLAGS"
  83
  84   if test "x$libdrm_cc_flag" = "xyes"; then
  85     ifelse([$2], , :, [$2])
  86   else
  87     ifelse([$3], , :, [$3])
  88   fi
  89   AC_MSG_RESULT([$libdrm_cc_flag])
  90 ])
  91
  92 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
  93
  94 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
  95                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
  96                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
  97 AC_SUBST([CLOCK_LIB])
  98
  99 dnl Use lots of warning flags with with gcc and compatible compilers
 100
 101 dnl Note: if you change the following variable, the cache is automatically
 102 dnl skipped and all flags rechecked.  So there's no need to do anything
 103 dnl else.  If for any reason you need to force a recheck, just change
 104 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 105
 106 MAYBE_WARN="-Wall -Wextra \
 107 -Wsign-compare -Werror-implicit-function-declaration \
 108 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 109 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 110 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 111 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
 112 -Wdeclaration-after-statement -Wold-style-definition \
 113 -Wno-missing-field-initializers -Wno-unused-parameter \
 114 -Wno-attributes -Wno-long-long -Winline"
 115
 116 # invalidate cached value if MAYBE_WARN has changed
 117 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 118         unset libdrm_cv_warn_cflags
 119 fi
 120 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 121         echo
 122         WARN_CFLAGS=""
 123
 124         # Some warning options are not supported by all versions of
 125         # gcc, so test all desired options against the current
 126         # compiler.
 127         #
 128         # Note that there are some order dependencies
 129         # here. Specifically, an option that disables a warning will
 130         # have no net effect if a later option then enables that
 131         # warnings, (perhaps implicitly). So we put some grouped
 132         # options (-Wall and -Wextra) up front and the -Wno options
 133         # last.
 134
 135         for W in $MAYBE_WARN; do
 136                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 137         done
 138
 139         libdrm_cv_warn_cflags=$WARN_CFLAGS
 140         libdrm_cv_warn_maybe=$MAYBE_WARN
 141
 142         AC_MSG_CHECKING([which warning flags were supported])])
 143 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 144
 145 if test "x$UDEV" = xyes; then
 146         AC_DEFINE(UDEV, 1, [Have UDEV support])
 147 fi
 148
 149 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 150
 151 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 152 if test "x$VMWGFX" = xyes; then
 153         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 154 fi
 155
 156 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 157
 158 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
 159
 160 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 161 if test "x$HAVE_CAIRO" = xyes; then
 162         AC_DEFINE(HAVE_CAIRO, 1, [Have cairo support])
 163 fi
 164 AM_CONDITIONAL(HAVE_CAIRO, [test "x$HAVE_CAIRO" = xyes])
 165
 166 # For enumerating devices in test case
 167 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 168 if test "x$HAVE_LIBUDEV" = xyes; then
 169         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 170 fi
 171 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 172
 173 if test "x$INTEL" != "xno"; then
 174     # Check for atomic intrinsics
 175     AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives,
 176     [
 177             drm_cv_atomic_primitives="none"
 178
 179             AC_TRY_LINK([
 180     int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
 181     int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
 182     ], [],
 183               drm_cv_atomic_primitives="Intel"
 184               )
 185
 186             if test "x$drm_cv_atomic_primitives" = "xnone"; then
 187                     AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 188             fi
 189
 190             # atomic functions defined in <atomic.h> & libc on Solaris
 191             if test "x$drm_cv_atomic_primitives" = "xnone"; then
 192                     AC_CHECK_FUNC([atomic_cas_uint],
 193                                   drm_cv_atomic_primitives="Solaris")
 194             fi
 195
 196     ])
 197     if test "x$drm_cv_atomic_primitives" = xIntel; then
 198             AC_DEFINE(HAVE_INTEL_ATOMIC_PRIMITIVES, 1,
 199                       [Enable if your compiler supports the Intel __sync_* atomic primitives])
 200     fi
 201     if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 202             AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 203     fi
 204
 205     if test "x$drm_cv_atomic_primitives" = "xnone"; then
 206             if test "x$INTEL" != "xauto"; then
 207                     AC_MSG_ERROR([libdrm_intel depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for Intel GPUs by passing --disable-intel to ./configure])
 208            else
 209                     INTEL=no
 210            fi
 211     else
 212            INTEL=yes
 213     fi
 214 fi
 215
 216 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" != "xno"])
 217
 218 AC_ARG_WITH([kernel-source],
 219             [AS_HELP_STRING([--with-kernel-source],
 220               [specify path to linux kernel source])],
 221             [kernel_source="$with_kernel_source"])
 222 AC_SUBST(kernel_source)
 223
 224 AC_SUBST(WARN_CFLAGS)
 225 AC_OUTPUT([
 226         Makefile
 227         libkms/Makefile
 228         libkms/libkms.pc
 229         intel/Makefile
 230         intel/libdrm_intel.pc
 231         radeon/Makefile
 232         radeon/libdrm_radeon.pc
 233         nouveau/Makefile
 234         nouveau/libdrm_nouveau.pc
 235         tests/Makefile
 236         tests/modeprint/Makefile
 237         tests/modetest/Makefile
 238         tests/kmstest/Makefile
 239         include/Makefile
 240         include/drm/Makefile
 241         libdrm.pc])
 242
 243 echo ""
 244 echo "$PACKAGE_STRING will be compiled with:"
 245 echo ""
 246 echo "  libkms         $LIBKMS"
 247 echo "  Intel API      $INTEL"
 248 echo "  vmwgfx API     $VMWGFX"
 249 echo "  Radeon API     $RADEON"
 250 echo "  Nouveau API    $NOUVEAU"
 251 echo ""