configure.ac

   1 dnl autoconf configuration file for gst-plugins
   2 AC_INIT
   3 AC_CANONICAL_TARGET
   4
   5 dnl We disable static building for development, for time savings
   6 dnl this goes before AS_LIBTOOL to appease autoconf
   7 dnl *NOTE*: dnl this line before release, so release does static too
   8 AM_DISABLE_STATIC
   9
  10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  11 AM_MAINTAINER_MODE
  12
  13 dnl when going to/from release please set the nano (fourth number) right !
  14 dnl releases only do Wall, cvs and prerelease does Werror too
  15 AS_VERSION(gst-plugins, GST_PLUGINS_VERSION, 0, 9, 0, 1, GST_CVS="no", GST_CVS="yes")
  16
  17 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  18
  19 dnl our libraries and install dirs use major.minor as a version
  20 GST_MAJORMINOR=$GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR
  21 dnl we override it here if we need to for the release candidate of new series
  22 GST_MAJORMINOR=0.9
  23 AC_SUBST(GST_MAJORMINOR)
  24
  25 dnl CURRENT, REVISION, AGE
  26 dnl - library source changed -> increment REVISION
  27 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  28 dnl - interfaces added -> increment AGE
  29 dnl - interfaces removed -> AGE = 0
  30 dnl for 0.8.3 release, gst_play_get_all_by_interface was added, so update
  31 AS_LIBTOOL(GST_PLUGINS, 1, 0, 1)
  32 AS_LIBTOOL_TAGS([CXX])
  33 AM_PROG_LIBTOOL
  34
  35 dnl FIXME take something else ?
  36 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  37 AM_CONFIG_HEADER(config.h)
  38
  39 dnl Add parameters for aclocal
  40 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  41 ACLOCAL_FLAGS="-I m4 -I common/m4"
  42 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
  43
  44 AC_PROG_CC
  45 AM_PROG_CC_STDC
  46 AM_PROG_AS
  47 AS="${CC}"
  48 AS_PROG_OBJC
  49
  50 dnl the gettext stuff needed
  51 AM_GNU_GETTEXT_VERSION(0.11.5)
  52 AM_GNU_GETTEXT([external])
  53
  54 GETTEXT_PACKAGE=gst-plugins-$GST_MAJORMINOR
  55 AC_SUBST(GETTEXT_PACKAGE)
  56 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  57                   [gettext package name])
  58
  59 dnl define LOCALEDIR in config.h
  60 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  61 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  62                    [gettext locale dir])
  63
  64 dnl decide on error flags
  65 AS_COMPILER_FLAG(-Wall, GST_WALL="yes", GST_WALL="no")
  66
  67 if test "x$GST_WALL" = "xyes"; then
  68    GST_ERROR="$GST_ERROR -Wall"
  69
  70    if test "x$GST_CVS" = "xyes"; then
  71      AS_COMPILER_FLAG(-Werror,GST_ERROR="$GST_ERROR -Werror",GST_ERROR="$GST_ERROR")
  72    fi
  73 fi
  74
  75 dnl determine c++ compiler
  76 AC_PROG_CXX
  77 dnl determine if c++ is available on this system
  78 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
  79 dnl determine c++ preprocessor
  80 AC_PROG_CXXCPP
  81 AC_ISC_POSIX
  82
  83 AC_HEADER_STDC([])
  84 AC_C_INLINE
  85 AX_CREATE_STDINT_H
  86
  87 dnl Check for malloc.h
  88 AC_CHECK_HEADER(malloc.h,[
  89   AC_DEFINE(HAVE_MALLOC_H, 1, [whether malloc.h available])
  90 ])
  91
  92 dnl Check for a way to display the function name in debug output
  93 GST_CHECK_FUNCTION()
  94
  95 dnl define correct errorlevel for debugging messages. We want to have GST_ERROR
  96 dnl messages printed when running cvs builds
  97 if test "x$GST_CVS" = "xyes"; then
  98   AC_DEFINE(GST_LEVEL_DEFAULT, GST_LEVEL_ERROR, [Default errorlevel to use])
  99 fi
 100
 101 dnl Check for FIONREAD ioctl declaration :
 102 GST_CHECK_FIONREAD()
 103
 104 DEFAULT_AUDIOSINK="autoaudiosink"
 105 DEFAULT_VIDEOSINK="autovideosink"
 106 DEFAULT_AUDIOSRC="alsasrc"
 107 DEFAULT_VIDEOSRC="v4lsrc"
 108 DEFAULT_VISUALIZER="goom"
 109 case "$host" in
 110   *-sun-* | *pc-solaris* )
 111     DEFAULT_AUDIOSRC="sunaudiosrc"
 112     ;;
 113   *-darwin* )
 114     DEFAULT_AUDIOSRC="osxaudiosrc"
 115     ;;
 116 esac
 117
 118 AC_SUBST(DEFAULT_AUDIOSINK)
 119 AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSINK,"$DEFAULT_AUDIOSINK",[Default audio sink])
 120 AC_SUBST(DEFAULT_AUDIOSRC)
 121 AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSRC,"$DEFAULT_AUDIOSRC",[Default audio source])
 122 AC_SUBST(DEFAULT_VIDEOSINK)
 123 AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSINK,"$DEFAULT_VIDEOSINK",[Default video sink])
 124 AC_SUBST(DEFAULT_VIDEOSRC)
 125 AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSRC,"$DEFAULT_VIDEOSRC",[Default video source])
 126 AC_SUBST(DEFAULT_VISUALIZER)
 127 AC_DEFINE_UNQUOTED(DEFAULT_VISUALIZER,"$DEFAULT_VISUALIZER",[Default visualizer])
 128
 129 dnl ############################################
 130 dnl # Super Duper options for plug-in building #
 131 dnl ############################################
 132
 133 dnl ext plug-ins; plug-ins that have external dependencies
 134 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 135 [HAVE_EXTERNAL=yes],enabled,
 136 [
 137   AC_MSG_WARN(building external plug-ins)
 138   BUILD_EXTERNAL="yes"
 139 ],[
 140   AC_MSG_WARN(all plug-ins with external dependencies will not be built)
 141   BUILD_EXTERNAL="no"
 142 ])
 143 # make BUILD_EXTERNAL available to Makefile.am
 144 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 145
 146 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
 147 dnl read 'builds, but might not work'UTO
 148 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
 149 [HAVE_EXPERIMENTAL=yes],disabled,
 150 [
 151   AC_MSG_WARN(building experimental plug-ins)
 152   USE_TARKIN="yes"
 153 ],[
 154   AC_MSG_NOTICE(not building experimental plug-ins)
 155   USE_TARKIN="no"
 156 ])
 157
 158 dnl broken plug-ins; stuff that doesn't seem to build at the moment
 159 GST_CHECK_FEATURE(BROKEN, [enable building of broken plug-ins],,
 160 HAVE_BROKEN=yes,disabled,
 161 [
 162   AC_MSG_WARN([building broken plug-ins -- no bug reports on these, only patches :)])
 163 ],[
 164   AC_MSG_NOTICE([not building broken plug-ins])
 165 ])
 166
 167 dnl ##############################
 168 dnl # Do automated configuration #
 169 dnl ##############################
 170
 171 dnl Check for tools:
 172 dnl ================
 173
 174 dnl allow for different autotools
 175 AS_AUTOTOOLS_ALTERNATE()
 176
 177 dnl modify pkg-config path
 178 AC_ARG_WITH(pkg-config-path,
 179    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 180    [export PKG_CONFIG_PATH=${withval}])
 181
 182 GST_DOC()
 183 dnl check architecture
 184 GST_ARCH()
 185
 186 dnl check for gconftool-2
 187
 188 dnl this macro defines an am conditional, so it needs to be run always
 189 AM_GCONF_SOURCE_2
 190
 191 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 192 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 193   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 194   if test x$GCONFTOOL = xno; then
 195     AC_MSG_WARN(Not installing GConf schemas)
 196     HAVE_GCONFTOOL="no"
 197   else
 198     HAVE_GCONFTOOL="yes"
 199   fi
 200   AC_SUBST(HAVE_GCONFTOOL)
 201 ])
 202
 203 dnl check for GConf libraries
 204 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 205 GST_CHECK_FEATURE(GCONF, [GConf libraries], , [
 206   PKG_CHECK_MODULES(GCONF, gconf-2.0, HAVE_GCONF="yes", HAVE_GCONF="no")
 207   AC_SUBST(GCONF_CFLAGS)
 208   AC_SUBST(GCONF_LIBS)
 209 ])
 210
 211 dnl check for gstreamer
 212 dnl uninstalled is selected preferentially -- see pkg-config(1)
 213 GST_REQ=0.9.0.1
 214 PKG_CHECK_MODULES(GST, gstreamer-$GST_MAJORMINOR >= $GST_REQ,
 215   HAVE_GST="yes", HAVE_GST="no")
 216
 217 if test "x$HAVE_GST" = "xno"; then
 218   AC_MSG_ERROR(no GStreamer found)
 219 fi
 220
 221 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 dnl check for gstreamer-base; uninstalled is selected preferentially
 228 PKG_CHECK_MODULES(GST_BASE, gstreamer-base-$GST_MAJORMINOR >= $GST_REQ,
 229   HAVE_GST_BASE="yes", HAVE_GST_BASE="no")
 230
 231 if test "x$HAVE_GST_BASE" = "xno"; then
 232   AC_MSG_ERROR(no GStreamer Base Libs found)
 233 fi
 234
 235 AC_SUBST(GST_BASE_LIBS)
 236 AC_SUBST(GST_BASE_CFLAGS)
 237
 238 dnl check for gstreamer-plugins-base; uinstalled is selected preferentially
 239 PKG_CHECK_MODULES(GST_PLUGINS_BASE,
 240   gstreamer-plugins-base-$GST_MAJORMINOR >= $GST_REQ,
 241   HAVE_GST_PLUGINS_BASE="yes", HAVE_GST_PLUGINS_BASE="no")
 242
 243 if test "x$HAVE_GST_PLUGINS_BASE" = "xno"; then
 244   AC_MSG_ERROR(no GStreamer Base Plugins development files found)
 245 fi
 246
 247 AC_SUBST(GST_PLUGINS_BASE_LIBS)
 248 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 249
 250 dnl Determine endianness
 251 AC_C_BIGENDIAN
 252
 253 dnl Check for fast float to int casting as defined in C99
 254 AC_C99_FUNC_LRINT()
 255 AC_C99_FUNC_LRINTF()
 256
 257 dnl Check for essential libraries first:
 258 dnl ====================================
 259
 260 GST_GLIB2_CHECK()
 261
 262 dnl Check for additional libraries that we might use:
 263 dnl =================================================
 264
 265 # we set the defaults always to make sure we have non-empty variables
 266 # for the Makefile
 267
 268 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.0, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 269 AC_SUBST(LIBOIL_CFLAGS)
 270 AC_SUBST(LIBOIL_LIBS)
 271 if test "x${HAVE_LIBOIL}" = xyes ; then
 272   #AC_DEFINE_UNQUOTED(HAVE_LIBOIL, 1, [Define if liboil is being used])
 273   true
 274 fi
 275
 276 dnl ===========================================================================
 277 dnl ============================= gst plug-ins ================================
 278 dnl ===========================================================================
 279
 280 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 281 AC_SUBST(plugindir)
 282
 283 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '[_]*(gst_|Gst|GST_).*' $GST_LIBS"
 284 AC_SUBST(GST_PLUGIN_LDFLAGS)
 285
 286 dnl these are all the gst plug-ins, compilable without additional libs
 287 GST_PLUGINS_ALL="\
 288                 videofilter \
 289                 alpha \
 290                 autodetect \
 291                 avi \
 292                 effectv \
 293                 fdsrc \
 294                 goom \
 295                 law \
 296                 level \
 297                 mpegaudioparse \
 298                 qtdemux \
 299                 realmedia \
 300                 rtp     \
 301                 rtsp    \
 302                 smpte   \
 303                 silence \
 304                 udp     \
 305                 videobox \
 306                 wavparse \
 307                 mpegaudioparse \
 308                 "
 309
 310 dnl see if we can build C++ plug-ins
 311 if test "x$HAVE_CXX" = "xyes"; then
 312   GST_PLUGINS_ALL="$GST_PLUGINS_ALL"
 313 else
 314   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 315 fi
 316
 317 AC_SUBST(GST_PLUGINS_ALL)
 318
 319 GST_PLUGINS_SELECTED=""
 320
 321 AC_ARG_WITH(plugins,
 322     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
 323     [for i in `echo $withval | tr , ' '`; do
 324         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 325         then
 326             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 327         else
 328             echo "plug-in $i not recognized, ignoring..."
 329         fi
 330     done],
 331     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 332
 333 AC_SUBST(GST_PLUGINS_SELECTED)
 334
 335 dnl ==========================================================================
 336 dnl ============================= sys plug-ins ================================
 337 dnl ==========================================================================
 338
 339 dnl *** OSS audio *** (Linux, *BSD)
 340 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 341 GST_CHECK_FEATURE(OSS, [OSS audio], osssrc osssink, [
 342  HAVE_OSS="yes"
 343 dnl Linux and newer BSD versions :
 344  AC_CHECK_HEADER(sys/soundcard.h, [
 345    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 346    ] , [
 347 dnl Some old BSD versions :
 348    AC_CHECK_HEADER(soundcard.h, [
 349      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 350      ], [
 351   dnl Some old BSD versions :
 352      AC_CHECK_HEADER(machine/soundcard.h, [
 353        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,, [Define if OSS includes are in /machine/])
 354        ], [
 355        HAVE_OSS="no"
 356      ])
 357    ])
 358  ])
 359 ])
 360
 361 dnl ###########################
 362 dnl # Configure external libs #
 363 dnl ###########################
 364
 365 dnl *** aalib ***
 366 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 367 GST_CHECK_FEATURE(AALIB, [aasink plug-in], aasink, [
 368   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 369   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 370 ])
 371
 372 dnl *** AMR-NB ***
 373 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 374 GST_CHECK_FEATURE(AMRNB, [AMR-NB], amrnbdec amrnbenc, [
 375   GST_CHECK_LIBHEADER(AMRNB, amrnb,
 376                       Decoder_Interface_init, -lm,
 377                       amrnb/interf_dec.h,
 378                       AMRNB_LIBS="-lamrnb -lm"
 379                       AC_SUBST(AMRNB_LIBS))
 380 ])
 381
 382 dnl **** Free AAC Decoder (FAAD) ****
 383 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAD, true)
 384 GST_CHECK_FEATURE(FAAD, [AAC decoder plug-in], faad, [
 385   HAVE_FAAD="yes"
 386   GST_CHECK_LIBHEADER(FAAD, faad, faacDecOpen, -lm, faad.h, FAAD_LIBS="-lfaad -lm", HAVE_FAAD="no")
 387   if test $HAVE_FAAD = "yes"; then
 388     AC_MSG_CHECKING([Checking for FAAD >= 2])
 389     AC_TRY_RUN([
 390
 391 #include <faad.h>
 392 #if !defined(FAAD2_VERSION) || !defined(FAAD_FMT_DOUBLE)
 393 #error Not faad2
 394 #else
 395 #include <string.h>
 396
 397 int main()
 398 {
 399 char version[9] = FAAD2_VERSION;
 400 // a release candidate of 2.0 is not enought for us
 401 if ( strstr( version, "2.0 RC" ) ) { return 1; }
 402
 403 return 0;
 404 }
 405
 406 #endif
 407     ],
 408        [ HAVE_FAAD="yes" && AC_MSG_RESULT(yes)],
 409        [ HAVE_FAAD="no"  && AC_MSG_RESULT(no)])
 410   fi;
 411   AS_SCRUB_INCLUDE(FAAD_CFLAGS)
 412   AC_SUBST(FAAD_LIBS)
 413 ])
 414
 415 dnl *** FLAC ***
 416 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 417 GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flacenc flacdec, [
 418   GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 419   dnl API change in FLAC 1.1.1, so require that...
 420   if test x$HAVE_FLAC = xyes; then
 421     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 422                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 423 #include <FLAC/seekable_stream_encoder.h>
 424                   ])
 425   fi
 426   AC_SUBST(FLAC_LIBS)
 427 ])
 428
 429 dnl *** lame ***
 430 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 431 GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 432   GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h,
 433   [
 434     HAVE_LAME="yes"
 435     LAME_LIBS="-lmp3lame -lm"
 436     dnl is lame presets available
 437     LAME_CFLAGS=""
 438     AC_TRY_RUN([
 439 #include <lame/lame.h>
 440 int main (int argc, char *argv[])
 441 {
 442   printf("%d\n", MEDIUM);
 443   return 0;
 444 }
 445       ],
 446       [LAME_CFLAGS="-DGSTLAME_PRESET"],
 447       [LAME_CFLAGS=""]
 448     )
 449   AC_SUBST(LAME_CFLAGS)
 450   AC_SUBST(LAME_LIBS)
 451   ])
 452 ])
 453
 454 dnl *** libcaca ***
 455 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 456 GST_CHECK_FEATURE(LIBCACA, [libcaca], libcaca, [
 457   GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 458   AC_SUBST(LIBCACA_CFLAGS)
 459   AC_SUBST(LIBCACA_LIBS)
 460 ])
 461
 462 dnl *** libdv ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 464 GST_CHECK_FEATURE(LIBDV, [libdv DV/video decoder], dvdec, [
 465   PKG_CHECK_MODULES(LIBDV, libdv >= 0.100, HAVE_LIBDV="yes", HAVE_LIBDV="no")
 466   AC_SUBST(LIBDV_CFLAGS)
 467   AC_SUBST(LIBDV_LIBS)
 468 ])
 469
 470 dnl *** shout2 ***
 471 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 472 GST_CHECK_FEATURE(SHOUT2, [shout2 plug-in], shout2send, [
 473   PKG_CHECK_MODULES(SHOUT2, shout >= 2.0, [
 474     HAVE_SHOUT2="yes"
 475     AC_SUBST(SHOUT2_CFLAGS)
 476     AC_SUBST(SHOUT2_LIBS)
 477   ], [
 478     AM_PATH_SHOUT2(HAVE_SHOUT2="yes", HAVE_SHOUT2="no")
 479     AC_SUBST(SHOUT2_CFLAGS)
 480     AC_SUBST(SHOUT2_LIBS)
 481   ])
 482 ])
 483
 484 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 486 GST_CHECK_FEATURE(SIDPLAY, [sidplay plug-in], sidplay, [
 487   GST_PATH_SIDPLAY()
 488 ])
 489
 490 dnl *** jpeg ***
 491 dnl FIXME: we could use header checks here as well IMO
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 493 GST_CHECK_FEATURE(JPEG, [jpeg], jpegenc jpegdec, [
 494   AC_ARG_WITH(jpeg-mmx,
 495     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 496   OLD_LIBS="$LIBS"
 497   if test x$with_jpeg_mmx != x; then
 498     LIBS="$LIBS -L$with_jpeg_mmx"
 499   fi
 500   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 501   JPEG_LIBS="$LIBS -ljpeg-mmx"
 502   LIBS="$OLD_LIBS"
 503   if test x$HAVE_JPEG != xyes; then
 504     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 505     JPEG_LIBS="-ljpeg"
 506   fi
 507   AC_SUBST(JPEG_LIBS)
 508 ])
 509
 510
 511 dnl *** mad ***
 512 dnl FIXME: we could use header checks here as well IMO
 513 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 514 GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 515   dnl check with pkg-config first
 516   PKG_CHECK_MODULES(MAD, mad >= 0.15 id3tag >= 0.15, HAVE_MAD="yes", HAVE_MAD="no")
 517   if test "x$HAVE_MAD" = "xno"; then
 518     dnl fall back to oldskool detection
 519     AC_CHECK_LIB(mad, mad_decoder_finish, HAVE_MAD="yes" MAD_LIBS="-lmad")
 520     if test "x$HAVE_MAD" = "xyes"; then
 521       HAVE_MAD="no"
 522       save_LIBS=$LIBS
 523       LIBS="-lz"
 524       AC_CHECK_LIB(id3tag, id3_tag_options, HAVE_MAD="yes" MAD_LIBS="-lmad -lid3tag -lz")
 525       LIBS=$save_LIBS
 526     fi
 527   fi
 528 ])
 529 AC_SUBST(MAD_LIBS)
 530
 531 dnl *** mpeg2dec ***
 532 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 533 GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 534   PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0,
 535       HAVE_MPEG2DEC="yes", HAVE_MPEG2DEC="no")
 536   AC_SUBST(MPEG2DEC_CFLAGS)
 537   AC_SUBST(MPEG2DEC_LIBS)
 538 ])
 539
 540 dnl *** dv1394 ***
 541 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 542 GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], dv1394src, [
 543   dnl we need to test three headers and three libs
 544   GST_CHECK_LIBHEADER(RAW1394,
 545     raw1394, raw1394_new_handle,,
 546     libraw1394/raw1394.h, RAW1394_LIBS="-lraw1394")
 547   GST_CHECK_LIBHEADER(AVC1394,
 548     avc1394, avc1394_send_command, $RAW1394_LIBS,
 549     libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 550   GST_CHECK_LIBHEADER(ROM1394,
 551     rom1394, rom1394_free_directory, $RAW1394_LIBS,
 552     libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 553
 554   dnl now see how far we got
 555   if test x$HAVE_RAW1394 = xyes && \
 556      test x$HAVE_AVC1394 = xyes && \
 557      test x$HAVE_ROM1394 = xyes; then
 558        HAVE_DV1394=yes
 559        DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 560        AC_SUBST(DV1394_LIBS)
 561   else
 562        HAVE_DV1394=no
 563   fi
 564 ])
 565
 566 dnl **** ESound ****
 567 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 568 GST_CHECK_FEATURE(ESD, [esound plug-ins], esdsink, [
 569   PKG_CHECK_MODULES(ESD, esound >= 0.2.12, [
 570     HAVE_ESD="yes"
 571     AC_SUBST(ESD_CFLAGS)
 572     AC_SUBST(ESD_LIBS)
 573   ], [
 574     AM_PATH_ESD(0.2.12, HAVE_ESD="yes", HAVE_ESD="no")
 575     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 576   ])
 577 ])
 578
 579 dnl *** libpng ***
 580 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 581 GST_CHECK_FEATURE(LIBPNG, [libpng PNG encoder], pngenc, [
 582   PKG_CHECK_MODULES(LIBPNG, libpng12, HAVE_LIBPNG="yes", HAVE_LIBPNG="no")
 583   AC_SUBST(LIBPNG_CFLAGS)
 584   AC_SUBST(LIBPNG_LIBS)
 585 ])
 586
 587 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 588 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 589 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 590 dnl   speex_jitter.h is 1.1.x only
 591 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 592 GST_CHECK_FEATURE(SPEEX, [speex plug-in], speex, [
 593   PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, [
 594     HAVE_SPEEX="yes"
 595     AC_SUBST(SPEEX_CFLAGS)
 596     AC_SUBST(SPEEX_LIBS)
 597   ], [
 598     GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 599       AC_CHECK_HEADER(speex/speex_jitter.h, [
 600         dnl speex 1.1.x :
 601         GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 602           dnl speex 1.1.5 or + :
 603           HAVE_SPEEX="yes"
 604           SPEEX_LIBS="-lspeex"
 605           AC_SUBST(SPEEX_CFLAGS)
 606           AC_SUBST(SPEEX_LIBS)
 607         ],[
 608           HAVE_SPEEX="no"
 609         ])
 610       ],[
 611         dnl speex 1.0.x :
 612           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 613             dnl speex 1.0.4
 614             HAVE_SPEEX="yes"
 615             SPEEX_LIBS="-lspeex"
 616             AC_SUBST(SPEEX_CFLAGS)
 617             AC_SUBST(SPEEX_LIBS)
 618
 619             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 620               [defined if speex 1.0.x API detected])
 621         ],[
 622             HAVE_SPEEX="no"
 623             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 624         ], [
 625 #include <speex/speex.h>
 626         ])
 627       ])
 628     ])
 629   ])
 630 ])
 631
 632 dnl also add builddir include for enumtypes and marshal
 633 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GST_ERROR"
 634
 635 AC_SUBST(GST_LIBS)
 636 AC_SUBST(GST_CFLAGS)
 637
 638 dnl ############################
 639 dnl # Set up some more defines #
 640 dnl ############################
 641
 642 dnl set license and copyright notice
 643 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
 644
 645 dnl package name in plugins
 646 AC_ARG_WITH(package-name,
 647 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
 648 [case "${withval}" in
 649   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 650   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 651   *) GST_PACKAGE="${withval}" ;;
 652 esac],
 653 [
 654 dnl default value
 655 if test "x$GST_CVS" = "xyes"
 656 then
 657   dnl nano >= 1
 658   GST_PACKAGE="GStreamer CVS/prerelease"
 659 else
 660   GST_PACKAGE="GStreamer source release"
 661 fi
 662 ]
 663 )
 664 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
 665 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
 666
 667 dnl package origin URL
 668 AC_ARG_WITH(package-origin,
 669 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
 670 [case "${withval}" in
 671   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 672   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 673   *) GST_ORIGIN="${withval}" ;;
 674 esac],
 675 [GST_ORIGIN="http://gstreamer.freedesktop.org/"]) dnl Default value
 676 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
 677 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
 678
 679 dnl #########################
 680 dnl # Make the output files #
 681 dnl #########################
 682
 683 AC_CONFIG_FILES(
 684 Makefile
 685 gst-plugins.spec
 686 gst/Makefile
 687 gst/alpha/Makefile
 688 gst/autodetect/Makefile
 689 gst/avi/Makefile
 690 gst/effectv/Makefile
 691 gst/fdsrc/Makefile
 692 gst/goom/Makefile
 693 gst/law/Makefile
 694 gst/level/Makefile
 695 gst/mpegaudioparse/Makefile
 696 gst/realmedia/Makefile
 697 gst/rtp/Makefile
 698 gst/rtsp/Makefile
 699 gst/smpte/Makefile
 700 gst/silence/Makefile
 701 gst/udp/Makefile
 702 gst/videobox/Makefile
 703 gst/videofilter/Makefile
 704 ext/jpeg/Makefile
 705 gst/qtdemux/Makefile
 706 gst/wavparse/Makefile
 707 gst-libs/Makefile
 708 gst-libs/gst/Makefile
 709 sys/Makefile
 710 sys/oss/Makefile
 711 ext/Makefile
 712 ext/aalib/Makefile
 713 ext/dv/Makefile
 714 ext/flac/Makefile
 715 ext/gconf/Makefile
 716 ext/lame/Makefile
 717 ext/libcaca/Makefile
 718 ext/libpng/Makefile
 719 ext/mad/Makefile
 720 ext/raw1394/Makefile
 721 ext/shout2/Makefile
 722 ext/sidplay/Makefile
 723 ext/speex/Makefile
 724 ext/esd/Makefile
 725 ext/mpeg2dec/Makefile
 726 ext/faad/Makefile
 727 ext/amrnb/Makefile
 728 po/Makefile.in
 729 common/Makefile
 730 common/m4/Makefile
 731 m4/Makefile
 732 )
 733 AC_OUTPUT
 734
 735 echo -n "configure: *** Plug-ins that will be built :"
 736 echo -e "$GST_PLUGINS_YES" | sort
 737 echo
 738 echo -n "configure: *** Plug-ins that will not be built :"
 739 echo -e "$GST_PLUGINS_NO" | sort
 740 echo
 741 if test "x$BUILD_EXTERNAL" = "xno"; then
 742   echo "configure: *** No external plug-ins will be built"
 743 fi