configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release ver-pre-svn-07])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_rev], m4_eval(v_maj + v_min))
  16 m4_define([lt_cur], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([embryo], [v_ver.beta2], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_ISC_POSIX
  28
  29 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  30 AM_CONFIG_HEADER([config.h])
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32
  33 AC_LIBTOOL_WIN32_DLL
  34 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  35 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  36 AC_PROG_LIBTOOL
  37
  38 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  41 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  42 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  43 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  44 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  45 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  46 version_info="lt_rev:lt_cur:lt_age"
  47 release_info="v_rel"
  48 AC_SUBST(version_info)
  49 AC_SUBST(release_info)
  50 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 VMAJ=v_maj
  53 AC_SUBST(VMAJ)
  54
  55 EFL_CHECK_PATH_MAX
  56
  57 ### Default options with respect to host
  58
  59 requirement_embryo=""
  60 embryoincludedir="${datadir}/include"
  61
  62
  63 ### Additional options to configure
  64
  65 EFL_ENABLE_BIN([embryo-cc])
  66
  67
  68 ### Checks for programs
  69 AC_PROG_CC
  70
  71 # doxygen program for documentation building
  72
  73 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
  74
  75 # pkg-config
  76
  77 PKG_PROG_PKG_CONFIG
  78
  79 # Check whether pkg-config supports Requires.private
  80 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
  81    pkgconfig_requires_private="Requires.private"
  82 else
  83    pkgconfig_requires_private="Requires"
  84 fi
  85 AC_SUBST(pkgconfig_requires_private)
  86
  87
  88 ### Checks for libraries
  89
  90 # Evil library for compilation on Windows
  91
  92 EFL_EMBRYO_BUILD=""
  93 case "$host_os" in
  94    mingw* | cegcc*)
  95    PKG_CHECK_MODULES([EVIL], [evil])
  96    AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
  97    requirement_embryo="evil ${requirement_embryo}"
  98    EFL_EMBRYO_BUILD="-DEFL_EMBRYO_BUILD"
  99    ;;
 100 esac
 101 AC_SUBST(EFL_EMBRYO_BUILD)
 102
 103
 104 ### Checks for header files
 105
 106
 107 ### Checks for types
 108
 109
 110 ### Checks for structures
 111
 112
 113 ### Checks for compiler characteristics
 114 AC_C_BIGENDIAN
 115 AM_PROG_CC_C_O
 116 AC_C_CONST
 117 AC_C_INLINE
 118 AC_PROG_CC_STDC
 119 AC_HEADER_STDC
 120 AC_C___ATTRIBUTE__
 121
 122 EMBRYO_CPPFLAGS=""
 123 EMBRYO_CFLAGS=""
 124 case "$host_os" in
 125    mingw32ce*)
 126       EMBRYO_CPPFLAGS="-D_WIN32_WCE=0x0420"
 127       ;;
 128    cegcc*)
 129       EMBRYO_CPPFLAGS="-D_WIN32_WCE=0x0420"
 130       EMBRYO_CFLAGS="-mwin32"
 131       ;;
 132 esac
 133 AC_SUBST(EMBRYO_CPPFLAGS)
 134 AC_SUBST(EMBRYO_CFLAGS)
 135
 136
 137 ### Checks for linker characteristics
 138
 139 lt_enable_auto_import=""
 140 case "$host_os" in
 141    mingw* | cegcc*)
 142       lt_enable_auto_import="-Wl,--enable-auto-import"
 143       ;;
 144 esac
 145 AC_SUBST(lt_enable_auto_import)
 146
 147
 148 ### Checks for library functions
 149
 150 # alloca
 151 AC_FUNC_ALLOCA
 152
 153 # fnmatch
 154 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 155
 156 case "$host_os" in
 157    mingw* | cegcc*)
 158       AC_DEFINE(HAVE_GETTIMEOFDAY, 1, [Defined to 1 (MinGW / CeGCC platform)])
 159       ;;
 160    *)
 161       AC_CHECK_FUNCS(gettimeofday)
 162       ;;
 163 esac
 164
 165
 166 AC_SUBST(requirement_embryo)
 167 AC_SUBST(embryoincludedir)
 168
 169 AC_OUTPUT([
 170 Makefile
 171 doc/Makefile
 172 doc/embryo.dox
 173 embryo.pc
 174 include/Makefile
 175 src/Makefile
 176 src/lib/Makefile
 177 src/bin/Makefile
 178 README
 179 embryo.spec
 180 ])
 181
 182
 183 #####################################################################
 184 ## Info
 185
 186 echo
 187 echo
 188 echo
 189 echo "------------------------------------------------------------------------"
 190 echo "$PACKAGE $VERSION"
 191 echo "------------------------------------------------------------------------"
 192 echo
 193 echo "Configuration Options Summary:"
 194 echo
 195 echo "  Build embryo_cc......: $have_embryo_cc"
 196 echo
 197 echo "  Documentation........: ${build_doc}"
 198 echo
 199 echo "Compilation............: make (or gmake)"
 200 echo "  CPPFLAGS.............: $CPPFLAGS"
 201 echo "  CFLAGS...............: $CFLAGS"
 202 echo "  LDFLAGS..............: $LDFLAGS"
 203 echo
 204 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 205 echo "  prefix...............: $prefix"
 206 echo