configure.ac

   1 dnl These m4 macros are whitespace sensitive and break if moved around much.
   2 m4_define([LU_VERSION_H], m4_include([libusb/version.h]))
   3 m4_define([LU_DEFINE_VERSION_ATOM],
   4         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   5         [^#define\s*$1\s*\([0-9]*\).*], [\1]))])
   6 m4_define([LU_DEFINE_VERSION_RC_ATOM],
   7         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   8         [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))])
   9 dnl The m4_bregexp() returns (only) the numbers following the #define named
  10 dnl in the first macro parameter. m4_define() then defines the name for use
  11 dnl in AC_INIT.
  12
  13 LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR])
  14 LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR])
  15 LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO])
  16 LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC])
  17
  18 AC_INIT([libusb],[LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC],[libusb-devel@lists.sourceforge.net],[libusb],[http://libusb.info])
  19
  20 # Library versioning
  21 # These numbers should be tweaked on every release. Read carefully:
  22 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  23 # http://sourceware.org/autobook/autobook/autobook_91.html
  24 lt_current="1"
  25 lt_revision="0"
  26 lt_age="1"
  27 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_CONFIG_SRCDIR([libusb/core.c])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 AC_CONFIG_HEADERS([config.h])
  35 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  36
  37 AC_PREREQ([2.50])
  38 AC_PROG_CC
  39 AC_PROG_CXX
  40 LT_INIT
  41 LT_LANG([Windows Resource])
  42 AC_C_INLINE
  43 AM_PROG_CC_C_O
  44 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  45
  46 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  47
  48 AC_MSG_CHECKING([operating system])
  49
  50 dnl on linux-android platform, some functions are in different places
  51 case $host in
  52 *-linux-android*)
  53         AC_MSG_RESULT([This is a Linux-Android system])
  54         is_backend_android="yes"
  55         ;;
  56 *)
  57         is_backend_android="no"
  58 esac
  59
  60 case $host in
  61 *-linux* | *-uclinux*)
  62         AC_MSG_RESULT([Linux])
  63         backend="linux"
  64         threads="posix"
  65         ;;
  66 *-darwin*)
  67         AC_MSG_RESULT([Darwin/Mac OS X])
  68         backend="darwin"
  69         threads="posix"
  70         ;;
  71 *-openbsd*)
  72         AC_MSG_RESULT([OpenBSD])
  73         backend="openbsd"
  74         threads="posix"
  75         ;;
  76 *-netbsd*)
  77         AC_MSG_RESULT([NetBSD])
  78         backend="netbsd"
  79         threads="posix"
  80         ;;
  81 *-mingw*)
  82         AC_MSG_RESULT([Windows])
  83         backend="windows"
  84         threads="windows"
  85         create_import_lib="yes"
  86         AM_CFLAGS="${AM_CFLAGS} -fno-omit-frame-pointer"
  87         ;;
  88 *-cygwin*)
  89         AC_MSG_RESULT([Cygwin (using Windows backend)])
  90         backend="windows"
  91         threads="posix"
  92         ;;
  93 *-haiku*)
  94         AC_MSG_RESULT([Haiku])
  95         backend="haiku"
  96         threads="posix"
  97         ;;
  98 *)
  99         AC_MSG_ERROR([unsupported operating system])
 100 esac
 101
 102 case $backend in
 103 linux)
 104         AC_DEFINE(OS_LINUX, 1, [Linux backend])
 105         AC_SUBST(OS_LINUX)
 106         AC_SEARCH_LIBS(clock_gettime, rt, [], [], -pthread)
 107         AC_ARG_ENABLE([udev],
 108                 [AC_HELP_STRING([--enable-udev], [use udev for device enumeration and hotplug support (recommended) [default=yes]])],
 109                 [], [enable_udev="yes"])
 110                 if test "x$enable_udev" = "xyes" ; then
 111                         # system has udev. use it or fail!
 112                         AC_CHECK_HEADERS([libudev.h],[],[AC_ERROR(["udev support requested but libudev not installed"])])
 113                         AC_CHECK_LIB([udev], [udev_new], [], [AC_ERROR(["udev support requested but libudev not installed"])])
 114                         AC_DEFINE(USE_UDEV, 1, [Use udev for device enumeration/hotplug])
 115                 else
 116                         AC_CHECK_HEADERS([asm/types.h sys/socket.h], [], [])
 117                         AC_CHECK_HEADERS([linux/netlink.h linux/filter.h], [], [AC_ERROR(["Linux netlink headers not found"])], [
 118 #ifdef HAVE_ASM_TYPES_H
 119 #include <asm/types.h>
 120 #endif
 121 #ifdef HAVE_SYS_SOCKET_H
 122 #include <sys/socket.h>
 123 #endif
 124 ])
 125                 fi
 126                 AC_SUBST(USE_UDEV)
 127
 128 case $is_backend_android in
 129 yes)
 130         dnl there are gettimeofday function but configure doesn't seem to be able to find it.
 131         AC_DEFINE([HAVE_GETTIMEOFDAY], [1], [Define if you have gettimeofday])
 132         ;;
 133 *)
 134         THREAD_CFLAGS="-pthread"
 135         LIBS="${LIBS} -pthread"
 136 esac
 137
 138         AC_CHECK_HEADERS([poll.h])
 139         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 140         ;;
 141 darwin)
 142         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
 143         AC_SUBST(OS_DARWIN)
 144         LIBS="-lobjc -Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
 145         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
 146         AC_CHECK_HEADERS([poll.h])
 147         AC_CHECK_TYPE([nfds_t],
 148                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
 149                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
 150                 [#include <poll.h>])
 151         ;;
 152 openbsd)
 153         AC_DEFINE(OS_OPENBSD, 1, [OpenBSD backend])
 154         AC_SUBST(OS_OPENBSD)
 155         THREAD_CFLAGS="-pthread"
 156         LIBS="-pthread"
 157         AC_CHECK_HEADERS([poll.h])
 158         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 159         ;;
 160 netbsd)
 161         AC_DEFINE(OS_NETBSD, 1, [NetBSD backend])
 162         AC_SUBST(OS_NETBSD)
 163         THREAD_CFLAGS="-pthread"
 164         LIBS="-pthread"
 165         AC_CHECK_HEADERS([poll.h])
 166         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 167         ;;
 168 windows)
 169         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
 170         AC_SUBST(OS_WINDOWS)
 171         LIBS=""
 172         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
 173         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
 174         AC_DEFINE([WINVER], 0x0501, [Oldest Windows version supported])
 175
 176         AC_ARG_ENABLE([usbdk],
 177                 [AC_HELP_STRING([--enable-usbdk], [use UsbDk Windows backend [default=no]])],
 178                 [], [enable_usbdk="no"])
 179                 if test "x$enable_usbdk" = "xyes" ; then
 180                     AC_DEFINE(USE_USBDK, 1, [Use UsbDk Windows backend])
 181                 fi
 182                 AC_SUBST(USE_USBDK)
 183         ;;
 184 haiku)
 185         AC_DEFINE(OS_HAIKU, 1, [Haiku backend])
 186         AC_SUBST(OS_HAIKU)
 187         LIBS="${LIBS} -lbe"
 188         AC_CHECK_HEADERS([poll.h])
 189         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 190         ;;
 191 esac
 192
 193 AC_SUBST(LIBS)
 194
 195 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
 196 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
 197 AM_CONDITIONAL(OS_OPENBSD, test "x$backend" = xopenbsd)
 198 AM_CONDITIONAL(OS_NETBSD, test "x$backend" = xnetbsd)
 199 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
 200 AM_CONDITIONAL(OS_HAIKU, test "x$backend" = xhaiku)
 201 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
 202 AM_CONDITIONAL(CREATE_IMPORT_LIB, test "x$create_import_lib" = "xyes")
 203 AM_CONDITIONAL(USE_UDEV, test "x$enable_udev" = xyes)
 204 AM_CONDITIONAL(USE_USBDK, test "x$enable_usbdk" = xyes)
 205 if test "$threads" = posix; then
 206         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
 207 fi
 208
 209 # timerfd
 210 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 211 AC_ARG_ENABLE([timerfd],
 212         [AS_HELP_STRING([--enable-timerfd],
 213                 [use timerfd for timing [default=auto]])],
 214         [use_timerfd=$enableval], [use_timerfd='auto'])
 215
 216 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 217         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 218 fi
 219
 220 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 221 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 222         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 223 fi
 224
 225 AC_MSG_CHECKING([whether to use timerfd for timing])
 226 if test "x$use_timerfd" = "xno"; then
 227         AC_MSG_RESULT([no (disabled by user)])
 228 else
 229         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 230                 AC_MSG_RESULT([yes])
 231                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 232         else
 233                 AC_MSG_RESULT([no (header not available)])
 234         fi
 235 fi
 236
 237 AC_CHECK_TYPES(struct timespec)
 238
 239 # Message logging
 240 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 241         [log_enabled=$enableval],
 242         [log_enabled='yes'])
 243 if test "x$log_enabled" != "xno"; then
 244         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 245 fi
 246
 247 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 248         [start with debug message logging enabled [default=no]])],
 249         [debug_log_enabled=$enableval],
 250         [debug_log_enabled='no'])
 251 if test "x$debug_log_enabled" != "xno"; then
 252         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Start with debug message logging enabled])
 253 fi
 254
 255 AC_ARG_ENABLE([system-log], [AS_HELP_STRING([--enable-system-log],
 256         [output logging messages to system wide log, if supported by the OS [default=no]])],
 257         [system_log_enabled=$enableval],
 258         [system_log_enabled='no'])
 259 if test "x$system_log_enabled" != "xno"; then
 260         AC_DEFINE([USE_SYSTEM_LOGGING_FACILITY], 1, [Enable output to system log])
 261 fi
 262
 263 # Check if syslog is available in standard C library
 264 AC_CHECK_HEADERS(syslog.h)
 265 AC_CHECK_FUNC([syslog], [have_syslog=yes], [have_syslog=no])
 266 if test "x$have_syslog" != "xno"; then
 267         AC_DEFINE([HAVE_SYSLOG_FUNC], 1, [syslog() function available])
 268 fi
 269
 270 # Examples build
 271 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 272         [build example applications [default=no]])],
 273         [build_examples=$enableval],
 274         [build_examples='no'])
 275 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 276
 277 # Tests build
 278 AC_ARG_ENABLE([tests-build], [AS_HELP_STRING([--enable-tests-build],
 279         [build test applications [default=no]])],
 280         [build_tests=$enableval],
 281         [build_tests='no'])
 282 AM_CONDITIONAL([BUILD_TESTS], [test "x$build_tests" != "xno"])
 283
 284 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 285 saved_cflags="$CFLAGS"
 286 # -Werror required for cygwin
 287 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 288 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 289         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 290          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 291         [ VISIBILITY_CFLAGS=""
 292          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 293         ])
 294 CFLAGS="$saved_cflags"
 295
 296 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 297 saved_cflags="$CFLAGS"
 298 CFLAGS="$CFLAGS -Wno-pointer-sign"
 299 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 300         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 301 CFLAGS="$saved_cflags"
 302
 303 # sigaction not available on MinGW
 304 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 305 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 306
 307 # headers not available on all platforms but required on others
 308 AC_CHECK_HEADERS([sys/time.h])
 309 AC_CHECK_FUNCS(gettimeofday)
 310 AC_CHECK_HEADERS([signal.h])
 311
 312 # check for -std=gnu99 compiler support
 313 saved_cflags="$CFLAGS"
 314 CFLAGS="-std=gnu99"
 315 AC_MSG_CHECKING([whether CC supports -std=gnu99])
 316 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 317     [AC_MSG_RESULT([yes])]
 318     [AM_CFLAGS="${AM_CFLAGS} -std=gnu99"],
 319     [AC_MSG_RESULT([no])]
 320 )
 321 CFLAGS="$saved_cflags"
 322
 323 AM_CFLAGS="${AM_CFLAGS} -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow ${THREAD_CFLAGS} ${VISIBILITY_CFLAGS}"
 324
 325 AC_SUBST(AM_CFLAGS)
 326 AC_SUBST(LTLDFLAGS)
 327
 328 AC_CONFIG_FILES([libusb-1.0.pc])
 329 AC_CONFIG_FILES([Makefile])
 330 AC_CONFIG_FILES([libusb/Makefile])
 331 AC_CONFIG_FILES([examples/Makefile])
 332 AC_CONFIG_FILES([tests/Makefile])
 333 AC_CONFIG_FILES([doc/Makefile])
 334 AC_CONFIG_FILES([doc/doxygen.cfg])
 335 AC_OUTPUT