configure.ac

   1 dnl  Copyright © 2008 Dan Nicholson
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Keith Packard not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Keith Packard makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  DAN NICHOLSON DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 # Initialize Autoconf
  24 AC_PREREQ([2.63])
  25 AC_INIT([libxkbcommon], [0.8.2],
  26         [https://bugs.freedesktop.org/enter_bug.cgi?product=libxkbcommon],
  27         [libxkbcommon], [https://xkbcommon.org])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_HEADERS([src/config.h])
  30 AC_CONFIG_MACRO_DIR([m4])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 # Initialize Automake
  34 AM_INIT_AUTOMAKE([foreign dist-xz no-dist-gzip subdir-objects color-tests parallel-tests check-news])
  35 AM_MAINTAINER_MODE([enable])
  36
  37 # Get _GNU_SOURCE and friends
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 # Initialize libtool
  41 LT_INIT
  42
  43 # Add xorg-macros stuff
  44 m4_ifndef([XORG_MACROS_VERSION],
  45           [m4_fatal([must install xorg-macros 1.16 or later before running autoconf/autogen])])
  46 XORG_MACROS_VERSION(1.16)
  47 XORG_DEFAULT_OPTIONS
  48 XORG_MEMORY_CHECK_FLAGS
  49 XORG_ENABLE_DOCS
  50 XORG_WITH_DOXYGEN
  51
  52 # Needed in older Automakes for subdir-objects
  53 AM_PROG_CC_C_O
  54
  55 # Check for compiler features
  56 AC_C_INLINE
  57
  58 # Check for programs
  59 AC_PROG_MKDIR_P
  60 PKG_PROG_PKG_CONFIG
  61
  62 # Note: we use some yacc extensions, which work with either GNU bison
  63 # (preferred) or byacc. Other yacc's may or may not work.
  64 AC_PROG_YACC
  65 AC_PATH_PROG([YACC_INST], [$YACC])
  66 AS_IF([test ! -f "src/xkbcomp/parser.c" -a "x$YACC_INST" = x], [
  67     AC_MSG_ERROR([yacc not found - unable to compile src/xkbcomp/parser.y])
  68 ])
  69
  70 # Checks for library functions.
  71 AC_CHECK_FUNCS([eaccess euidaccess mmap mkostemp posix_fallocate])
  72
  73 AC_CHECK_FUNCS([secure_getenv __secure_getenv])
  74 AS_IF([test "x$ac_cv_func_secure_getenv" = xno -a \
  75             "x$ac_cv_func___secure_getenv" = xno], [
  76     AC_MSG_WARN([C library does not support secure_getenv, using getenv instead])
  77 ])
  78
  79 AX_GCC_BUILTIN(__builtin_expect)
  80 AX_GCC_BUILTIN(__builtin_popcount)
  81
  82 # Some tests use Linux-specific headers
  83 AC_CHECK_HEADER([linux/input.h])
  84 AM_CONDITIONAL(BUILD_LINUX_TESTS, [test "x$ac_cv_header_linux_input_h" = xyes])
  85
  86 XORG_TESTSET_CFLAG([BASE_CFLAGS], [-fvisibility=hidden -fno-strict-aliasing -fsanitize-undefined-trap-on-error])
  87 XORG_TESTSET_CFLAG([BASE_CFLAGS], [-Wextra -Wno-unused-parameter -Wno-missing-field-initializers])
  88 XORG_TESTSET_CFLAG([BASE_CFLAGS], [-Wdocumentation -Wno-documentation-deprecated-sync])
  89
  90 # OpenBSD does not have DT_NEEDED entries for libc by design
  91 # so when these flags are passed to ld via libtool the checks will fail
  92 case "$host_os" in
  93 openbsd*)
  94     ;;
  95 *)
  96     XORG_CHECK_LINKER_FLAGS([-Wl,--no-undefined], [have_no_undefined=yes]) ;;
  97 esac
  98 AM_CONDITIONAL([HAVE_NO_UNDEFINED], [test "x$have_no_undefined" = xyes])
  99
 100 XORG_CHECK_LINKER_FLAGS([-Wl,--version-script="$srcdir/xkbcommon.map"], [have_version_script=yes])
 101 AM_CONDITIONAL([HAVE_VERSION_SCRIPT], [test "x$have_version_script" = xyes])
 102
 103 # Define a configuration option for the XKB config root
 104 xkb_base=`$PKG_CONFIG --variable=xkb_base xkeyboard-config`
 105 AS_IF([test "x$xkb_base" = x], [
 106     xkb_base="$datadir/X11/xkb"
 107 ])
 108 AC_ARG_WITH([xkb_config_root],
 109     [AS_HELP_STRING([--with-xkb-config-root=<path>],
 110         [Set default XKB config root (default: xkeyboard-config install path)])],
 111     [XKBCONFIGROOT="$withval"],
 112     [XKBCONFIGROOT="$xkb_base"])
 113 AC_SUBST([XKBCONFIGROOT])
 114
 115 # Define a configuration option for the X locale directory for compose
 116 AC_ARG_WITH([x_locale_root],
 117     [AS_HELP_STRING([--with-x-locale-root=<path>],
 118         [Set X locale root (default: $datadir/X11/locale)])],
 119     [XLOCALEDIR="$withval"],
 120     [XLOCALEDIR="$datadir/X11/locale"])
 121 AC_SUBST([XLOCALEDIR])
 122
 123 AC_ARG_WITH([default_rules],
 124     [AS_HELP_STRING([--with-default-rules=<path>],
 125         [Default XKB ruleset (default: evdev)])],
 126     [DEFAULT_XKB_RULES="$withval"],
 127     [DEFAULT_XKB_RULES="evdev"])
 128 AC_DEFINE_UNQUOTED([DEFAULT_XKB_RULES], ["$DEFAULT_XKB_RULES"],
 129                    [Default XKB ruleset])
 130
 131 AC_ARG_WITH([default_model],
 132     [AS_HELP_STRING([--with-default-model=<path>],
 133         [Default XKB model (default: pc105)])],
 134     [DEFAULT_XKB_MODEL="$withval"],
 135     [DEFAULT_XKB_MODEL="pc105"])
 136 AC_DEFINE_UNQUOTED([DEFAULT_XKB_MODEL], ["$DEFAULT_XKB_MODEL"],
 137                    [Default XKB model])
 138
 139 AC_ARG_WITH([default_layout],
 140     [AS_HELP_STRING([--with-default-layout=<path>],
 141         [Default XKB layout (default: us)])],
 142     [DEFAULT_XKB_LAYOUT="$withval"],
 143     [DEFAULT_XKB_LAYOUT="us"])
 144 AC_DEFINE_UNQUOTED([DEFAULT_XKB_LAYOUT], ["$DEFAULT_XKB_LAYOUT"],
 145                    [Default XKB layout])
 146
 147 AC_ARG_WITH([default_variant],
 148     [AS_HELP_STRING([--with-default-variant=<path>],
 149         [Default XKB variant (default: (none))])],
 150     [DEFAULT_XKB_VARIANT="$withval"],
 151     [DEFAULT_XKB_VARIANT=])
 152 AS_IF([test "x$DEFAULT_XKB_VARIANT" != x], [
 153     AC_DEFINE_UNQUOTED([DEFAULT_XKB_VARIANT], ["$DEFAULT_XKB_VARIANT"],
 154                        [Default XKB variant])
 155 ])
 156
 157 AC_ARG_WITH([default_options],
 158     [AS_HELP_STRING([--with-default-options=<path>],
 159         [Default XKB options (default: (none))])],
 160     [DEFAULT_XKB_OPTIONS="$withval"],
 161     [DEFAULT_XKB_OPTIONS=])
 162 AS_IF([test "x$DEFAULT_XKB_OPTIONS" != x], [
 163     AC_DEFINE_UNQUOTED([DEFAULT_XKB_OPTIONS], ["$DEFAULT_XKB_OPTIONS"],
 164                        [Default XKB options])
 165 ])
 166
 167 AC_ARG_ENABLE([x11],
 168     [AS_HELP_STRING([--disable-x11],
 169         [Disable support for creating keymaps with the X11 protocol (default: enabled)])],
 170     [], [enable_x11=yes])
 171 AS_IF([test "x$enable_x11" = xyes], [
 172     PKG_CHECK_MODULES([XCB_XKB], [xcb xcb-xkb >= 1.10], [],
 173         [AC_MSG_ERROR([xkbcommon-x11 requires xcb-xkb >= 1.10 which was not found. \
 174 You can disable X11 support with --disable-x11.])])
 175 ], [enable_x11=no])
 176 AM_CONDITIONAL([ENABLE_X11], [test "x$enable_x11" = xyes])
 177
 178 WAYLAND_PKGS="wayland-client >= 1.2.0 wayland-protocols >= 1.7 wayland-scanner"
 179 AC_ARG_ENABLE([wayland],
 180     [AS_HELP_STRING([--disable-wayland],
 181         [Disable support for Wayland utility programs (default: auto)])],
 182     [], [enable_wayland=auto])
 183 AS_IF([test "x$enable_wayland" = xauto], [
 184     PKG_CHECK_EXISTS($WAYLAND_PKGS, [enable_wayland=yes], [enable_wayland=no])],
 185     [])
 186 AS_IF([test "x$enable_wayland" = xyes], [
 187     PKG_CHECK_MODULES([WAYLAND], $WAYLAND_PKGS, [],
 188         [AC_MSG_ERROR([Wayland utilities require libwayland-client >= 1.2 which was not found. \
 189 You can disable Wayland support with --disable-wayland.])])
 190     AC_PATH_PROG([wayland_scanner], [wayland-scanner])
 191     wayland_scanner=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`
 192     ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
 193     AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
 194 ], [enable_wayland=no])
 195 AM_CONDITIONAL([ENABLE_WAYLAND], [test "x$enable_wayland" = xyes])
 196
 197 AC_CONFIG_FILES([
 198     Makefile
 199     xkbcommon.pc
 200     xkbcommon-x11.pc
 201     doc/Doxyfile
 202 ])
 203 AC_OUTPUT
 204
 205 AC_MSG_RESULT([
 206         $PACKAGE_NAME $VERSION
 207
 208         libxkbcommon:            yes
 209         libxkbcommon-x11:        ${enable_x11}
 210         Wayland utilities:       ${enable_wayland}
 211         documentation:           ${build_docs}
 212
 213         default XKB rules:       ${DEFAULT_XKB_RULES}
 214         default XKB model:       ${DEFAULT_XKB_MODEL}
 215         default XKB layout:      ${DEFAULT_XKB_LAYOUT}
 216         default XKB variant:     ${DEFAULT_XKB_VARIANT}
 217         default XKB options:     ${DEFAULT_XKB_OPTIONS}
 218
 219         prefix:                  ${prefix}
 220         includedir:              ${includedir}
 221         lib dir:                 ${libdir}
 222         datarootdir:             ${datarootdir}
 223         XKB config root:         ${XKBCONFIGROOT}
 224         X11 locale root:         ${XLOCALEDIR}
 225 ])