configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.15.5,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl FIXME: this macro doesn't actually work;
  42 dnl the generated libtool script has no support for the listed tags.
  43 dnl So this needs to be fixed first if we want to use this
  44 dnl AS_LIBTOOL_TAGS
  45
  46 AC_LIBTOOL_WIN32_DLL
  47 AM_PROG_LIBTOOL
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=0.10.24
  51 GSTPB_REQ=0.10.24
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION([0.17])
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DEBUG
  70 AG_GST_ARG_PROFILING
  71 AG_GST_ARG_VALGRIND
  72 AG_GST_ARG_GCOV
  73
  74 AG_GST_ARG_EXAMPLES
  75
  76 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  77 AG_GST_ARG_WITH_PACKAGE_NAME
  78 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  79
  80 AG_GST_ARG_WITH_PLUGINS
  81
  82 AG_GST_ARG_ENABLE_EXTERNAL
  83
  84 AG_GST_ARG_ENABLE_EXPERIMENTAL
  85
  86 dnl *** checks for platform ***
  87
  88 dnl * hardware/architecture *
  89
  90 dnl common/m4/gst-arch.m4
  91 dnl check CPU type
  92 AG_GST_ARCH
  93
  94 dnl Determine endianness
  95 AC_C_BIGENDIAN
  96
  97 dnl *** checks for programs ***
  98
  99 dnl find a compiler
 100 AC_PROG_CC
 101
 102 dnl determine c++ compiler
 103 AC_PROG_CXX
 104 dnl determine if c++ is available on this system
 105 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 106
 107 dnl determine c++ preprocessor
 108 dnl FIXME: do we need this ?
 109 AC_PROG_CXXCPP
 110
 111 AS_PROG_OBJC
 112
 113 dnl check if the compiler supports '-c' and '-o' options
 114 AM_PROG_CC_C_O
 115
 116 dnl find an assembler
 117 AM_PROG_AS
 118
 119 dnl check if the compiler supports do while(0) macros
 120 AG_GST_CHECK_DOWHILE_MACROS
 121
 122 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 123 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 124
 125 dnl check for gconftool-2
 126 dnl this macro defines an am conditional, so it needs to be run always
 127 AM_GCONF_SOURCE_2
 128
 129 dnl check for documentation tools
 130 GTK_DOC_CHECK([1.3])
 131 AS_PATH_PYTHON([2.1])
 132 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 133
 134 dnl *** checks for libraries ***
 135
 136 dnl check for libm, for sin()
 137 AC_CHECK_LIBM
 138 AC_SUBST(LIBM)
 139
 140 dnl *** checks for header files ***
 141
 142 dnl check if we have ANSI C header files
 143 AC_HEADER_STDC
 144
 145 dnl used by ext/wavpack
 146 AX_CREATE_STDINT_H
 147
 148 dnl used in gst/rtp/gstasteriskh263.c
 149 AC_CHECK_HEADERS([netinet/in.h])
 150 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 151 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl *** checks for types/defines ***
 157
 158 dnl Check for FIONREAD ioctl declaration.  This check is needed
 159 dnl for the UDP plugin to build on Solaris
 160 GST_CHECK_FIONREAD
 161
 162 dnl *** checks for structures ***
 163
 164 dnl *** checks for compiler characteristics ***
 165
 166 dnl check if we have GCC inline-asm
 167 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 168 if test x$HAVE_GCC_ASM = xyes ; then
 169   AC_DEFINE(HAVE_GCC_ASM, 1,
 170     [Define if compiler supports gcc inline assembly])
 171 fi
 172 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 173
 174 dnl *** checks for library functions ***
 175
 176 LIBS_SAVE=$LIBS
 177 LIBS="$LIBS $LIBM"
 178 AC_CHECK_FUNCS(rint sinh cosh asinh)
 179 LIBS=$LIBS_SAVE
 180
 181 dnl Check for mmap (needed by electricfence plugin)
 182 AC_FUNC_MMAP
 183 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 184
 185 dnl Check for mmap (needed by electricfence plugin)
 186
 187 AC_CHECK_TYPE([struct ip_mreqn], [
 188               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 189               [#include <netinet/in.h>])
 190
 191 dnl *** checks for dependency libraries ***
 192
 193 dnl GLib is required
 194 AG_GST_GLIB_CHECK([2.16])
 195
 196 dnl liboil is required
 197 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 198 if test "x$HAVE_LIBOIL" != "xyes"; then
 199   AC_ERROR([liboil-0.3.8 or later is required])
 200 fi
 201
 202 dnl checks for gstreamer
 203 dnl uninstalled is selected preferentially -- see pkg-config(1)
 204 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 205 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 206 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 207 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 208 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 209 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 210
 211 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 212 if test -z $GST_TOOLS_DIR; then
 213   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 214 fi
 215 AC_SUBST(GST_TOOLS_DIR)
 216
 217 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 218 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 219
 220 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 221
 222 dnl Check for documentation xrefs
 223 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 224 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 225 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 226 AC_SUBST(GLIB_PREFIX)
 227 AC_SUBST(GST_PREFIX)
 228 AC_SUBST(GSTPB_PREFIX)
 229
 230 dnl GTK is optional and used in examples
 231 if test "x$BUILD_EXAMPLES" = "xyes"; then
 232   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, HAVE_GTK=yes, HAVE_GTK=no)
 233   AC_SUBST(GTK_LIBS)
 234   AC_SUBST(GTK_CFLAGS)
 235 fi
 236 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 237
 238 dnl should we install schemas ?
 239 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 240 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 241   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 242   if test x$GCONFTOOL = xno; then
 243     AC_MSG_WARN(Not installing GConf schemas)
 244     HAVE_GCONFTOOL="no"
 245   else
 246     HAVE_GCONFTOOL="yes"
 247   fi
 248   AC_SUBST(HAVE_GCONFTOOL)
 249 ])
 250
 251 dnl *** set variables based on configure arguments ***
 252
 253 dnl set license and copyright notice
 254 GST_LICENSE="LGPL"
 255 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 256 AC_SUBST(GST_LICENSE)
 257
 258 dnl set location of plugin directory
 259 AG_GST_SET_PLUGINDIR
 260
 261 dnl define an ERROR_CFLAGS Makefile variable
 262 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 263
 264 dnl define an ERROR_CXXFLAGS Makefile variable
 265 AG_GST_SET_ERROR_CXXFLAGS($GST_CVS)
 266
 267 dnl define correct level for debugging messages
 268 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 269
 270 dnl used in examples
 271 AG_GST_DEFAULT_ELEMENTS
 272
 273 dnl *** plug-ins to include ***
 274
 275 dnl these are all the gst plug-ins, compilable without additional libs
 276 dnl videofilter is at the top because others depend on it
 277 AG_GST_CHECK_PLUGIN(videofilter)
 278 AG_GST_CHECK_PLUGIN(alpha)
 279 AG_GST_CHECK_PLUGIN(apetag)
 280 AG_GST_CHECK_PLUGIN(audiofx)
 281 AG_GST_CHECK_PLUGIN(auparse)
 282 AG_GST_CHECK_PLUGIN(autodetect)
 283 AG_GST_CHECK_PLUGIN(avi)
 284 AG_GST_CHECK_PLUGIN(cutter)
 285 AG_GST_CHECK_PLUGIN(debugutils)
 286 AG_GST_CHECK_PLUGIN(deinterlace)
 287 AG_GST_CHECK_PLUGIN(effectv)
 288 AG_GST_CHECK_PLUGIN(equalizer)
 289 AG_GST_CHECK_PLUGIN(flv)
 290 AG_GST_CHECK_PLUGIN(id3demux)
 291 AG_GST_CHECK_PLUGIN(icydemux)
 292 AG_GST_CHECK_PLUGIN(interleave)
 293 AG_GST_CHECK_PLUGIN(flx)
 294 AG_GST_CHECK_PLUGIN(goom)
 295 AG_GST_CHECK_PLUGIN(goom2k1)
 296 AG_GST_CHECK_PLUGIN(law)
 297 AG_GST_CHECK_PLUGIN(level)
 298 AG_GST_CHECK_PLUGIN(matroska)
 299 AG_GST_CHECK_PLUGIN(monoscope)
 300 AG_GST_CHECK_PLUGIN(multifile)
 301 AG_GST_CHECK_PLUGIN(multipart)
 302 AG_GST_CHECK_PLUGIN(qtdemux)
 303 AG_GST_CHECK_PLUGIN(replaygain)
 304 AG_GST_CHECK_PLUGIN(rtp)
 305 AG_GST_CHECK_PLUGIN(rtpmanager)
 306 AG_GST_CHECK_PLUGIN(rtsp)
 307 AG_GST_CHECK_PLUGIN(smpte)
 308 AG_GST_CHECK_PLUGIN(spectrum)
 309 AG_GST_CHECK_PLUGIN(udp)
 310 AG_GST_CHECK_PLUGIN(videobox)
 311 AG_GST_CHECK_PLUGIN(videocrop)
 312 AG_GST_CHECK_PLUGIN(videomixer)
 313 AG_GST_CHECK_PLUGIN(wavenc)
 314 AG_GST_CHECK_PLUGIN(wavparse)
 315 AG_GST_CHECK_PLUGIN(y4m)
 316
 317 dnl *** checks for socket and nsl libraries ***
 318 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 319
 320 dnl disable gst plugins we might not be able to build on this
 321 dnl platform: udp and rtsp (ugly but minimally invasive)
 322 dnl FIXME: maybe move to sys
 323 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 324 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 325
 326 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 327   AG_GST_DISABLE_PLUGIN(udp)
 328   AG_GST_DISABLE_PLUGIN(rtsp)
 329 fi
 330
 331 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 332   WIN32_LIBS="-lws2_32"
 333   AC_SUBST(WIN32_LIBS)
 334 fi
 335
 336 dnl disable experimental plug-ins
 337 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 338   AG_GST_DISABLE_PLUGIN(monoscope)
 339 fi
 340
 341 dnl *** sys plug-ins ***
 342
 343 echo
 344 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 345 echo
 346
 347 dnl DirectSound
 348 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 349 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 350   HAVE_DIRECTSOUND="no"
 351   save_CFLAGS="$CFLAGS"
 352   save_LDFLAGS="$LDFLAGS"
 353   save_LIBS="$LIBS"
 354   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 355   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 356   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 357   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 358   AC_LINK_IFELSE([
 359 #include <windows.h>
 360 #include <dxerr9.h>
 361 #include <dsound.h>
 362
 363 int main ()
 364 {
 365   DXGetErrorString9 (0);
 366   DirectSoundCreate(NULL, NULL, NULL);
 367
 368   return 0;
 369 }
 370 ],
 371     [HAVE_DIRECTSOUND="yes"],
 372     [HAVE_DIRECTSOUND="no"])
 373   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 374   CFLAGS=$save_CFLAGS
 375   LDFLAGS=$save_LDFLAGS
 376   LIBS=$save_LIBS
 377
 378   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 379     dnl this is much more than we want
 380     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 381     AC_SUBST(DIRECTSOUND_CFLAGS)
 382     AC_SUBST(DIRECTSOUND_LDFLAGS)
 383     AC_SUBST(DIRECTSOUND_LIBS)
 384   fi
 385   AC_SUBST(HAVE_DIRECTSOUND)
 386 ])
 387
 388 dnl *** OSS audio *** (Linux, *BSD)
 389 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 390 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 391  HAVE_OSS="yes"
 392 dnl Linux and newer BSD versions :
 393  AC_CHECK_HEADER(sys/soundcard.h, [
 394    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 395    ] , [
 396 dnl Some old BSD versions and also newer OpenBSD versions :
 397    AC_CHECK_HEADER(soundcard.h, [
 398      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 399      ], [
 400   dnl Some old BSD versions :
 401      AC_CHECK_HEADER(machine/soundcard.h, [
 402        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 403          [Define if OSS includes are in /machine/])
 404        ], [
 405        HAVE_OSS="no"
 406      ])
 407    ])
 408  ])
 409 ])
 410
 411 dnl *** Sun Audio ***
 412 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 413 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 414   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 415 ])
 416
 417 dnl *** OSX Audio ***
 418 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 419 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 420   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 421 ])
 422
 423 dnl *** OS X video ***
 424 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 425 HAVE_OSX_VIDEO="no"
 426 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 427   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 428 ])
 429 dnl in case header OpenGL/gl.h is found on other platforms
 430 case "$host" in
 431   *-*darwin*)
 432     dnl do nothing
 433     ;;
 434   *)
 435     HAVE_OSX_VIDEO="no"
 436     ;;
 437 esac
 438
 439
 440 dnl *** Video 4 Linux 2 ***
 441 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 442 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 443 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 444 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 445   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 446   AC_TRY_COMPILE([
 447 #include <sys/types.h>
 448 #ifdef __sun /* Solaris */
 449 #include <sys/types.h>
 450 #include <sys/videodev2.h>
 451 #else /* Linux */
 452 #include <linux/types.h>
 453 #define _LINUX_TIME_H
 454 #define __user
 455 #include <linux/videodev2.h>
 456 #endif
 457 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 458 #error too early v4l2 version or no v4l2 at all
 459 #endif
 460     ], [
 461 return 0;
 462     ], [
 463       HAVE_GST_V4L2="yes"
 464       AC_MSG_RESULT(yes)
 465     ], [
 466       HAVE_GST_V4L2="no"
 467       AC_MSG_RESULT(no)
 468
 469       HAVE_VIDEODEV=no
 470       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 471       [
 472         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 473       ])
 474
 475       if test "x$HAVE_VIDEODEV" = "xyes"; then
 476         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 477         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 478       else
 479         AC_MSG_WARN([video4linux2 was not found])
 480       fi
 481     ])
 482
 483   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 484     dnl check for missing v4l2_buffer declaration (see #135919)
 485     MISSING_DECL=0
 486     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 487     AC_TRY_COMPILE([
 488 #include <sys/types.h>
 489 #ifdef __sun /* Solaris */
 490 #include <sys/types.h>
 491 #include <sys/videodev2.h>
 492 #else /* Linux */
 493 #include <linux/types.h>
 494 #define _LINUX_TIME_H
 495 #define __user
 496 #include <linux/videodev2.h>
 497 #endif
 498     ],[
 499 struct v4l2_buffer buf;
 500 buf.index = 0;
 501 return 0;
 502     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 503     if [ test x$MISSING_DECL = x1 ]; then
 504       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 505     fi
 506
 507     dnl check for XOverlay libraries
 508     AG_GST_CHECK_XV
 509   fi
 510 ])
 511
 512 # Optional gudev for device probing
 513 AC_ARG_WITH([gudev],
 514   AC_HELP_STRING([--with-gudev],
 515     [device detection with gudev]),
 516   [],
 517   [with_gudev=check])
 518 if test x$HAVE_GST_V4L2 = xyes; then
 519   if test x$with_gudev != xno; then
 520       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 521           [ have_gudev=yes
 522             AC_DEFINE(HAVE_GUDEV, 1,
 523                [Whether gudev is available for device detection])
 524             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 525           ], [
 526           have_gudev=no
 527           ])
 528   else
 529     have_gudev=no
 530   fi
 531 fi
 532 AC_SUBST(GUDEV_CFLAGS)
 533 AC_SUBST(GUDEV_LIBS)
 534
 535 # Make libv4l2 non-automagic
 536 AC_ARG_WITH([libv4l2],
 537   AC_HELP_STRING([--with-libv4l2],
 538     [support video buffer conversion using libv4l2]),
 539   [],
 540   [with_libv4l2=check])
 541 if test x$HAVE_GST_V4L2 = xyes; then
 542   if test x$with_libv4l2 != xno; then
 543       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 544           [ have_libv4l2=yes
 545             AC_DEFINE(HAVE_LIBV4L2, 1,
 546                 [Whether libv4l2 is available for video buffer conversion])
 547           ], [
 548           have_libv4l2=no
 549           ])
 550   else
 551     have_libv4l2=no
 552   fi
 553 fi
 554
 555 dnl Check for X11
 556 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 557 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 558                   [ximagesrc], [
 559   AC_PATH_XTRA
 560
 561   dnl now try to find the HEADER
 562   ac_cflags_save="$CFLAGS"
 563   ac_cppflags_save="$CPPFLAGS"
 564   CFLAGS="$CFLAGS $X_CFLAGS"
 565   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 566   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 567
 568   if test "x$HAVE_X" = "xno"
 569   then
 570     AC_MSG_NOTICE([cannot find X11 development files])
 571   else
 572     dnl this is much more than we want
 573     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 574     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 575     dnl it does not add the libs; therefore we add them here
 576     X_LIBS="$X_LIBS -lX11"
 577     AC_SUBST(X_CFLAGS)
 578     AC_SUBST(X_LIBS)
 579
 580     dnl check for Xfixes
 581     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 582     if test "x$HAVE_XFIXES" = "xyes"
 583     then
 584         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 585     fi
 586     AC_SUBST(XFIXES_LIBS)
 587     AC_SUBST(XFIXES_CFLAGS)
 588
 589     dnl check for Xdamage
 590     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 591     if test "x$HAVE_XDAMAGE" = "xyes"
 592     then
 593         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 594     fi
 595     AC_SUBST(XDAMAGE_LIBS)
 596     AC_SUBST(XDAMAGE_CFLAGS)
 597   fi
 598   AC_SUBST(HAVE_X)
 599   CFLAGS="$ac_cflags_save"
 600   CPPFLAGS="$ac_cppflags_save"
 601 ])
 602
 603 dnl FIXME: this should be rolled into the test above, it's just an additional
 604 dnl feature of the ximagesrc plug-in
 605 dnl This is the same as in gst-plugins-base
 606 dnl check for X Shm
 607 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 608 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 609   if test x$HAVE_X = xyes; then
 610     AC_CHECK_LIB(Xext, XShmAttach,
 611                  HAVE_XSHM="yes", HAVE_XSHM="no",
 612                  $X_LIBS)
 613     if test "x$HAVE_XSHM" = "xyes"; then
 614       XSHM_LIBS="-lXext"
 615     else
 616       dnl On AIX, it is in XextSam instead, but we still need -lXext
 617       AC_CHECK_LIB(XextSam, XShmAttach,
 618                    HAVE_XSHM="yes", HAVE_XSHM="no",
 619                    $X_LIBS)
 620       if test "x$HAVE_XSHM" = "xyes"; then
 621         XSHM_LIBS="-lXext -lXextSam"
 622       fi
 623     fi
 624   fi
 625 ], ,[
 626   AC_SUBST(HAVE_XSHM)
 627   AC_SUBST(XSHM_LIBS)
 628 ])
 629
 630 dnl for V4L2, we also need to know if we have XVIDEO
 631 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 632 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 633                   [], [
 634   AG_GST_CHECK_XV
 635 ])
 636
 637 dnl *** ext plug-ins ***
 638 dnl keep this list sorted alphabetically !
 639
 640 if test "x$BUILD_EXTERNAL" = "xyes"; then
 641
 642 echo
 643 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 644 echo
 645
 646 dnl *** aalib ***
 647 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 648 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 649   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 650   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 651 ])
 652
 653 dnl *** annodex ***
 654 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 655 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 656   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 657 ])
 658
 659 dnl *** cairo ***
 660 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 661 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 662   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 663 ])
 664
 665 dnl **** ESound ****
 666 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 667 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 668   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 669   if test $HAVE_ESD = no
 670   then
 671     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 672     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 673   fi
 674 ])
 675
 676 dnl *** FLAC ***
 677 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 678 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 679   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 680 ])
 681
 682 dnl *** GConf ***
 683 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 684 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 685   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 686 ])
 687
 688 dnl *** GDK pixbuf ***
 689 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 690 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 691   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 692 ])
 693
 694 dnl *** HAL ***
 695 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 696 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 697   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 698 ])
 699
 700 dnl *** jpeg ***
 701 dnl FIXME: we could use header checks here as well IMO
 702 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 703 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 704   AC_ARG_WITH(jpeg-mmx,
 705     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 706   OLD_LIBS="$LIBS"
 707   if test x$with_jpeg_mmx != x; then
 708     LIBS="$LIBS -L$with_jpeg_mmx"
 709   fi
 710   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 711   JPEG_LIBS="$LIBS -ljpeg-mmx"
 712   LIBS="$OLD_LIBS"
 713   if test x$HAVE_JPEG != xyes; then
 714     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 715     JPEG_LIBS="-ljpeg"
 716   fi
 717   AC_SUBST(JPEG_LIBS)
 718 ])
 719
 720 dnl *** libcaca ***
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 722 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 723   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 724   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 725   if test "x$HAVE_LIBCACA" != "xyes"; then
 726     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 727     dnl see if it compilation works too, might not if we are cross-compiling
 728     if test "x$HAVE_LIBCACA" = "xyes"; then
 729       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 730                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 731     fi
 732   fi
 733 ])
 734
 735 dnl *** libdv ***
 736 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 737 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 738   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 739 ])
 740
 741 dnl *** libpng ***
 742 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 743 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 744   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng12)
 745 ])
 746
 747 dnl *** pulseaudio ***
 748 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 749 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 750   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.8)
 751   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 752   if test x$HAVE_PULSE_0_9_11 = xyes; then
 753     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 754   fi
 755   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 756   if test x$HAVE_PULSE_0_9_12 = xyes; then
 757     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 758   fi
 759   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 760   if test x$HAVE_PULSE_0_9_13 = xyes; then
 761     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 762   fi
 763   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 764   if test x$HAVE_PULSE_0_9_15 = xyes; then
 765     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 766   fi
 767 ])
 768
 769 dnl *** dv1394 ***
 770 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 771 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 772   dnl first test for libraw1394 >= 1.2.1
 773   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 774   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 775   dnl now see how far we got
 776   if test x$HAVE_RAW1394 = xyes && \
 777      test x$HAVE_LIBIEC61883 = xyes; then
 778        AG_GST_CHECK_LIBHEADER(AVC1394,
 779         avc1394, avc1394_send_command, $RAW1394_LIBS,
 780         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 781        AG_GST_CHECK_LIBHEADER(ROM1394,
 782         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 783         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 784        if test x$HAVE_AVC1394 = xyes && \
 785           test x$HAVE_AVC1394 = xyes && \
 786           test x$HAVE_ROM1394 = xyes; then
 787           HAVE_DV1394=yes
 788           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 789           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 790           AC_SUBST(DV1394_CFLAGS)
 791           AC_SUBST(DV1394_LIBS)
 792         fi
 793   else
 794        if test x$HAVE_RAW1394 = xno; then
 795           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 796           AG_GST_CHECK_LIBHEADER(AVC1394,
 797            avc1394, avc1394_send_command, $RAW1394_LIBS,
 798            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 799           AG_GST_CHECK_LIBHEADER(ROM1394,
 800            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 801            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 802           if test x$HAVE_RAW1394 = xyes && \
 803              test x$HAVE_AVC1394 = xyes && \
 804              test x$HAVE_ROM1394 = xyes; then
 805              HAVE_DV1394=yes
 806              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 807              DV1394_CFLAGS="$RAW1394_CFLAGS"
 808              if test x$HAVE_LIBIEC61883 = xyes; then
 809                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 810                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 811              fi
 812              AC_SUBST(DV1394_CFLAGS)
 813              AC_SUBST(DV1394_LIBS)
 814            fi
 815          fi
 816   fi
 817 ])
 818
 819 dnl *** shout2 ***
 820 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 821 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 822   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 823   if test $HAVE_SHOUT2 = no
 824   then
 825     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 826     AC_SUBST(SHOUT2_CFLAGS)
 827     AC_SUBST(SHOUT2_LIBS)
 828   fi
 829 ])
 830
 831 dnl *** soup ***
 832 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 833 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 834   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 835     HAVE_SOUP="yes"
 836     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 837   ],[
 838     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 839       HAVE_SOUP="no"
 840       AC_MSG_RESULT(no)
 841     ])
 842   ])
 843   AC_SUBST(SOUP_CFLAGS)
 844   AC_SUBST(SOUP_LIBS)
 845 ])
 846
 847 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 848 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 849 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 850 dnl   speex_jitter.h is 1.1.x only
 851 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 852 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 853   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 854   if test $HAVE_SPEEX = no
 855   then
 856     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 857       AC_CHECK_HEADER(speex/speex_jitter.h, [
 858         dnl speex 1.1.x :
 859         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 860           dnl speex 1.1.5 or + :
 861           HAVE_SPEEX="yes"
 862           SPEEX_LIBS="-lspeex"
 863           AC_SUBST(SPEEX_CFLAGS)
 864           AC_SUBST(SPEEX_LIBS)
 865         ],[
 866           HAVE_SPEEX="no"
 867         ])
 868       ],[
 869         dnl speex 1.0.x :
 870           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 871             dnl speex 1.0.4
 872             HAVE_SPEEX="yes"
 873             SPEEX_LIBS="-lspeex"
 874             AC_SUBST(SPEEX_CFLAGS)
 875             AC_SUBST(SPEEX_LIBS)
 876
 877             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 878               [defined if speex 1.0.x API detected])
 879         ],[
 880             HAVE_SPEEX="no"
 881             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 882         ], [
 883 #include <speex/speex.h>
 884         ])
 885       ])
 886     ])
 887   fi
 888 ])
 889
 890 dnl *** taglib ***
 891 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 892 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 893   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 894   if test "x$HAVE_CXX" != "xyes"; then
 895     USE_TAGLIB=false
 896     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 897   else
 898     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 899     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 900         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 901       ], [
 902         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 903     ])
 904     AC_SUBST(TAGLIB_CXXFLAGS)
 905   fi
 906 ])
 907
 908 dnl *** wavpack ***
 909 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 910 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 911   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 912     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 913       HAVE_WAVPACK=yes
 914       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 915     ],[
 916       HAVE_WAVPACK=no
 917       AC_MSG_RESULT(no)
 918     ])
 919   ])
 920   AC_SUBST(WAVPACK_CFLAGS)
 921   AC_SUBST(WAVPACK_LIBS)
 922 ])
 923
 924 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 925 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 926 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 927   AG_GST_CHECK_LIBHEADER(ZLIB,
 928     z, uncompress,, zlib.h, [
 929     HAVE_ZLIB="yes"
 930     ZLIB_LIBS="-lz"
 931     AC_SUBST(ZLIB_LIBS)
 932   ])
 933 ])
 934
 935 dnl *** matroska prefers to have bz2 ***
 936 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 937 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 938   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 939   AC_SUBST(BZ2_LIBS)
 940 ])
 941
 942 else
 943
 944 dnl not building plugins with external dependencies,
 945 dnl but we still need to set the conditionals
 946 AM_CONDITIONAL(USE_AALIB, false)
 947 AM_CONDITIONAL(USE_ANNODEX, false)
 948 AM_CONDITIONAL(USE_BZ2, false)
 949 AM_CONDITIONAL(USE_CAIRO, false)
 950 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 951 AM_CONDITIONAL(USE_DV1394, false)
 952 AM_CONDITIONAL(USE_ESD, false)
 953 AM_CONDITIONAL(USE_FLAC, false)
 954 AM_CONDITIONAL(USE_GCONF, false)
 955 AM_CONDITIONAL(USE_GCONFTOOL, false)
 956 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 957 AM_CONDITIONAL(USE_GST_V4L2, false)
 958 AM_CONDITIONAL(USE_HAL, false)
 959 AM_CONDITIONAL(USE_JPEG, false)
 960 AM_CONDITIONAL(USE_LIBCACA, false)
 961 AM_CONDITIONAL(USE_LIBDV, false)
 962 AM_CONDITIONAL(USE_LIBPNG, false)
 963 AM_CONDITIONAL(USE_OSS, false)
 964 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 965 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 966 AM_CONDITIONAL(USE_PULSE, false)
 967 AM_CONDITIONAL(USE_SHOUT2, false)
 968 AM_CONDITIONAL(USE_SOUP, false)
 969 AM_CONDITIONAL(USE_SPEEX, false)
 970 AM_CONDITIONAL(USE_SUNAUDIO, false)
 971 AM_CONDITIONAL(USE_TAGLIB, false)
 972 AM_CONDITIONAL(USE_WAVPACK, false)
 973 AM_CONDITIONAL(USE_X, false)
 974 AM_CONDITIONAL(USE_XSHM, false)
 975 AM_CONDITIONAL(USE_XVIDEO, false)
 976 AM_CONDITIONAL(USE_ZLIB, false)
 977
 978 fi dnl of EXT plugins
 979
 980 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 981
 982 dnl Overview:
 983 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 984 dnl GST_*:              flags shared by all built objects
 985 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 986 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 987 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 988 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 989
 990 dnl GST_OPTION_CFLAGS
 991 if test "x$USE_DEBUG" = xyes; then
 992    PROFILE_CFLAGS="-g"
 993 fi
 994 AC_SUBST(PROFILE_CFLAGS)
 995
 996 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 997   dnl Define _only_ during CVS (not pre-releases or releases)
 998   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 999 else
1000   DEPRECATED_CFLAGS=""
1001 fi
1002 AC_SUBST(DEPRECATED_CFLAGS)
1003
1004 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1005 dnl at make time with e.g. make ERROR_CFLAGS=""
1006 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1007 GST_OPTION_CXXFLAGS="\$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1008 AC_SUBST(GST_OPTION_CFLAGS)
1009 AC_SUBST(GST_OPTION_CXXFLAGS)
1010
1011 dnl our libraries need to be versioned correctly
1012 AC_SUBST(GST_LT_LDFLAGS)
1013
1014 dnl FIXME: do we want to rename to GST_ALL_* ?
1015 dnl prefer internal headers to already installed ones
1016 dnl also add builddir include for enumtypes and marshal
1017 dnl add ERROR_CFLAGS, but overridable
1018 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1019 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CXXFLAGS \$(GST_OPTION_CXXFLAGS)"
1020 AC_SUBST(GST_CFLAGS)
1021 AC_SUBST(GST_CXXFLAGS)
1022 AC_SUBST(GST_LIBS)
1023
1024 dnl LDFLAGS really should only contain flags, not libs - they get added before
1025 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1026 GST_ALL_LDFLAGS="-no-undefined"
1027 AC_SUBST(GST_ALL_LDFLAGS)
1028
1029 dnl this really should only contain flags, not libs - they get added before
1030 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1031 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1032 AC_SUBST(GST_PLUGIN_LDFLAGS)
1033
1034 SHAVE_INIT([common],[enable])
1035 dnl *** output files ***
1036
1037 dnl keep this alphabetic per directory, please
1038 AC_CONFIG_FILES(
1039 Makefile
1040 common/shave
1041 common/shave-libtool
1042 gst/Makefile
1043 gst/alpha/Makefile
1044 gst/apetag/Makefile
1045 gst/audiofx/Makefile
1046 gst/auparse/Makefile
1047 gst/autodetect/Makefile
1048 gst/avi/Makefile
1049 gst/cutter/Makefile
1050 gst/deinterlace/Makefile
1051 gst/debugutils/Makefile
1052 gst/effectv/Makefile
1053 gst/equalizer/Makefile
1054 gst/flv/Makefile
1055 gst/id3demux/Makefile
1056 gst/icydemux/Makefile
1057 gst/interleave/Makefile
1058 gst/goom/Makefile
1059 gst/goom2k1/Makefile
1060 gst/law/Makefile
1061 gst/level/Makefile
1062 gst/matroska/Makefile
1063 gst/monoscope/Makefile
1064 gst/multifile/Makefile
1065 gst/multipart/Makefile
1066 gst/qtdemux/Makefile
1067 gst/replaygain/Makefile
1068 gst/rtp/Makefile
1069 gst/rtpmanager/Makefile
1070 gst/rtsp/Makefile
1071 gst/smpte/Makefile
1072 gst/spectrum/Makefile
1073 gst/udp/Makefile
1074 gst/videobox/Makefile
1075 gst/videocrop/Makefile
1076 gst/videofilter/Makefile
1077 gst/videomixer/Makefile
1078 gst/wavenc/Makefile
1079 gst/wavparse/Makefile
1080 gst/flx/Makefile
1081 gst/y4m/Makefile
1082 ext/jpeg/Makefile
1083 ext/Makefile
1084 ext/aalib/Makefile
1085 ext/annodex/Makefile
1086 ext/cairo/Makefile
1087 ext/dv/Makefile
1088 ext/esd/Makefile
1089 ext/flac/Makefile
1090 ext/gconf/Makefile
1091 ext/gdk_pixbuf/Makefile
1092 ext/hal/Makefile
1093 ext/ladspa/Makefile
1094 ext/libcaca/Makefile
1095 ext/libpng/Makefile
1096 ext/pulse/Makefile
1097 ext/raw1394/Makefile
1098 ext/shout2/Makefile
1099 ext/soup/Makefile
1100 ext/speex/Makefile
1101 ext/taglib/Makefile
1102 ext/wavpack/Makefile
1103 sys/Makefile
1104 sys/directsound/Makefile
1105 sys/oss/Makefile
1106 sys/sunaudio/Makefile
1107 sys/osxaudio/Makefile
1108 sys/osxvideo/Makefile
1109 sys/v4l2/Makefile
1110 sys/waveform/Makefile
1111 sys/ximage/Makefile
1112 po/Makefile.in
1113 tests/Makefile
1114 tests/check/Makefile
1115 tests/examples/Makefile
1116 tests/examples/audiofx/Makefile
1117 tests/examples/equalizer/Makefile
1118 tests/examples/level/Makefile
1119 tests/examples/rtp/Makefile
1120 tests/examples/spectrum/Makefile
1121 tests/examples/v4l2/Makefile
1122 tests/files/Makefile
1123 tests/icles/Makefile
1124 gconf/Makefile
1125 gconf/gstreamer.schemas
1126 common/Makefile
1127 common/m4/Makefile
1128 m4/Makefile
1129 docs/Makefile
1130 docs/plugins/Makefile
1131 docs/version.entities
1132 pkgconfig/Makefile
1133 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1134 gst-plugins-good.spec
1135 )
1136
1137 dnl Create the config.h file for Visual Studio builds
1138 dnl Beware of spaces and /'s in some of the shell variable contents.
1139 sed \
1140     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1141     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1142     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1143     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1144     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1145     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1146     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1147     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1148     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1149     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1150     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1151     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1152     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1153     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1154     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1155     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1156     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1157     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1158     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1159     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1160     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1161     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1162     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1163     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1164     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1165     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1166     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1167     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1168     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1169     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1170     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1171     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1172     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1173     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1174     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1175     config.h.in >win32/common/config.h-new
1176
1177 AC_OUTPUT
1178
1179 AG_GST_OUTPUT_PLUGINS