configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.6.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 601, 0, 601)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.6.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_PROFILING
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86
  87 AG_GST_ARG_EXAMPLES
  88
  89 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  90 AG_GST_ARG_WITH_PACKAGE_NAME
  91 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 dnl let distro override plugin install helper path
  96 AC_ARG_WITH(install-plugins-helper,
  97   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156 dnl check for tbm buffer
 157
 158 AC_ARG_ENABLE(tbmbuf, AC_HELP_STRING([--enable-use-tbmbuf], [use tbm buf]),
 159         [
 160           case "${enableval}" in
 161            yes) BOARD_USE_TBM_BUF=yes ;;
 162            no)  BOARD_USE_TBM_BUF=no ;;
 163            *)   AC_MSG_ERROR(bad value ${enableval} for --enable-use-tbmbuf) ;;
 164           esac
 165         ],
 166         [BOARD_USE_TBM_BUF=yes])
 167 AM_CONDITIONAL([BOARD_USE_TBM_BUF], [test "x$BOARD_USE_TBM_BUF" = "xyes"])
 168
 169 dnl check for gobject-introspection
 170 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 171
 172 dnl check for documentation tools
 173 GTK_DOC_CHECK([1.12])
 174 AG_GST_PLUGIN_DOCS([1.12])
 175
 176 dnl *** checks for libraries ***
 177
 178 dnl libm, for sin() etc.
 179 LT_LIB_M
 180 AC_SUBST(LIBM)
 181
 182 dnl *** checks for header files ***
 183
 184 dnl check if we have ANSI C header files
 185 AC_HEADER_STDC
 186
 187 dnl check for GCC specific SSE headers
 188 dnl these are used by the speex resampler code
 189 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 190
 191 dnl used in gst/tcp
 192 AC_CHECK_HEADERS([sys/socket.h],
 193   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 194 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 195
 196 dnl used in gst-libs/gst/rtsp
 197 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 198 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 199 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 200   WIN32_LIBS="-lws2_32"
 201   AC_SUBST(WIN32_LIBS)
 202 fi
 203
 204 dnl used in gst-libs/gst/pbutils and associated unit test
 205 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 206
 207 dnl checks for ARM NEON support
 208 dnl this instruction set is used by the speex resampler code
 209 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 210 AC_LINK_IFELSE([
 211 AC_LANG_PROGRAM([[
 212   #include <arm_neon.h>
 213   int32x4_t testfunc(int16_t *a, int16_t *b) {
 214       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 215       return vmull_s16(vld1_s16(a), vld1_s16(b));
 216   }
 217 ]])],
 218 [
 219   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 220   AC_MSG_RESULT(yes)
 221 ],
 222 [
 223   AC_MSG_RESULT(no)
 224 ])
 225
 226 dnl also, Windows does not have long long
 227 AX_CREATE_STDINT_H
 228
 229 dnl *** checks for functions ***
 230 AC_CHECK_FUNCS([localtime_r gmtime_r])
 231
 232 dnl *** checks for math functions ***
 233 LIBS_SAVE=$LIBS
 234 LIBS="$LIBS $LIBM"
 235 AC_CHECK_FUNCS(log2)
 236 LIBS=$LIBS_SAVE
 237
 238 dnl *** checks for types/defines ***
 239
 240 dnl *** checks for structures ***
 241
 242 dnl *** checks for compiler characteristics ***
 243
 244 dnl *** checks for library functions ***
 245
 246 dnl check for fseeko()
 247 AC_FUNC_FSEEKO
 248
 249 dnl Check for fast float to int casting as defined in C99
 250 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 251 save_libs=$LIBS
 252 LIBS="$LIBS $LIBM"
 253 #AC_C99_FUNC_LRINT
 254 #AC_C99_FUNC_LRINTF
 255 LIBS=$save_libs
 256
 257 dnl Check for a way to display the function name in debug output
 258 AG_GST_CHECK_FUNCTION
 259
 260 dnl *** checks for dependency libraries ***
 261
 262 dnl GLib
 263 GLIB_REQ=2.32
 264 AG_GST_GLIB_CHECK([$GLIB_REQ])
 265
 266 ORC_CHECK([0.4.23])
 267
 268 dnl checks for gstreamer
 269 dnl uninstalled is selected preferentially -- see pkg-config(1)
 270 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 271 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 272 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 273 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 274 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 275 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 276
 277 dnl Check for documentation xrefs
 278 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 279 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 280 AC_SUBST(GLIB_PREFIX)
 281 AC_SUBST(GST_PREFIX)
 282
 283 dnl GTK is optional and only used in examples
 284 HAVE_GTK=no
 285 HAVE_GTK_X11=no
 286 GTK_REQ=3.10
 287 if test "x$BUILD_EXAMPLES" = "xyes"; then
 288   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 289   dnl some examples need gtk+-x11
 290   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 291   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 292   AC_SUBST(GTK_LIBS)
 293   AC_SUBST(GTK_CFLAGS)
 294 fi
 295 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 296 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 297 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 298
 299 HAVE_QT=no
 300 HAVE_QT_MOC=no
 301 dnl QT is optional and only used in examples
 302 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 303   HAVE_QT=yes
 304 ], [
 305   HAVE_QT=no
 306 ])
 307 if test "x$HAVE_QT" = "xyes"; then
 308   AC_CHECK_TOOL(QT_MOC, moc)
 309   AC_MSG_CHECKING([for Qt5 moc])
 310   mocversion=`$QT_MOC -v 2>&1`
 311   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 312   if test x"$mocversiongrep" != x"$mocversion"; then
 313     AC_MSG_RESULT([no])
 314     # moc was not the qt5 one, try with moc-qt5
 315     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 316     AC_MSG_CHECKING([for Qt5 moc-qt5])
 317     mocversion=`$QT_MOC -v 2>&1`
 318     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 319     if test x"$mocversiongrep" != x"$mocversion"; then
 320       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 321       AC_MSG_CHECKING([for qtchooser])
 322       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 323       mocversion=`$qt5tooldir/moc -v 2>&1`
 324       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 325       if test x"$mocversiongrep" != x"$mocversion"; then
 326         # no valid moc found
 327         QT_MOC="no"
 328       else
 329         QT_MOC=$qt5tooldir/moc
 330       fi
 331     else
 332       QT_MOC=$QT_MOC
 333     fi
 334   fi
 335   AC_SUBST(QT_MOC)
 336   AC_MSG_RESULT([$QT_MOC])
 337 fi
 338 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 339 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 340
 341 dnl chck for linux headers needed by the joystick seek example
 342 AC_COMPILE_IFELSE(
 343 [
 344   AC_LANG_PROGRAM([
 345     #include <linux/input.h>
 346     #include <linux/joystick.h>
 347   ],[
 348     struct js_event js;
 349     js.type = JS_EVENT_AXIS;
 350   ])
 351 ], [
 352   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 353 ], [
 354   HAVE_LINUX_JOYSTICK_HEADERS="no"
 355 ])
 356 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 357
 358 dnl Check for -Bsymbolic-functions linker flag used to avoid
 359 dnl intra-library PLT jumps, if available.
 360 AC_ARG_ENABLE(Bsymbolic,
 361               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 362               [SAVED_LDFLAGS="${LDFLAGS}"
 363                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 364                LDFLAGS=-Wl,-Bsymbolic-functions
 365                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 366                            AC_MSG_RESULT(yes)
 367                            enable_Bsymbolic=yes],[
 368                            AC_MSG_RESULT(no)
 369                            enable_Bsymbolic=no])
 370                LDFLAGS="${SAVED_LDFLAGS}"])
 371
 372
 373 dnl *** set variables based on configure arguments ***
 374
 375 dnl set license and copyright notice
 376 GST_LICENSE="LGPL"
 377 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 378 AC_SUBST(GST_LICENSE)
 379
 380 dnl set location of plugin directory
 381 AG_GST_SET_PLUGINDIR
 382
 383 dnl set release date/time
 384 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 385   ["${srcdir}/gst-plugins-base.doap"],
 386   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 387
 388 dnl build static plugins or not
 389 AC_MSG_CHECKING([whether to build static plugins or not])
 390 AC_ARG_ENABLE(
 391   static-plugins,
 392   AC_HELP_STRING(
 393     [--enable-static-plugins],
 394     [build static plugins @<:@default=no@:>@]),
 395   [AS_CASE(
 396     [$enableval], [no], [], [yes], [],
 397     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 398   [enable_static_plugins=no])
 399 AC_MSG_RESULT([$enable_static_plugins])
 400 if test "x$enable_static_plugins" = xyes; then
 401   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 402     [Define if static plugins should be built])
 403   GST_PLUGIN_LIBTOOLFLAGS=""
 404 else
 405   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 406 fi
 407 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 408 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 409
 410 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 411 dnl make sure it doesn't complain about unused variables if debugging is disabled
 412 NO_WARNINGS=""
 413 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 414
 415 dnl define an ERROR_CFLAGS Makefile variable
 416 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 417 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 418     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 419     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 420     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 421     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 422
 423 dnl define an ERROR_CXXFLAGS Makefile variable
 424 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 425     -Wmissing-declarations -Wredundant-decls -Wundef
 426     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 427     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 428     -Wno-multichar $NO_WARNINGS])
 429
 430 dnl define correct level for debugging messages
 431 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 432
 433 dnl used in examples
 434 AG_GST_DEFAULT_ELEMENTS
 435
 436 dnl needed for encoding-target
 437 GST_DATADIR="$GST_PREFIX/share"
 438 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 439 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 440
 441 dnl behaviour of speex based audio resampler
 442 AC_MSG_CHECKING(which audio resample format to use for integer)
 443 AC_ARG_WITH([audioresample_format],
 444         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 445         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 446 AC_MSG_RESULT($ac_cv_audioresample_format)
 447 case $ac_cv_audioresample_format in
 448   int)
 449     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 450     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 451   ;;
 452   float)
 453     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 454     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 455   ;;
 456   auto)
 457     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 458     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 459 esac
 460
 461 dnl Check for mmap (needed by allocators library)
 462 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 463
 464 dnl *** plug-ins to include ***
 465
 466 dnl these are all the gst plug-ins, compilable without additional libs
 467 AG_GST_CHECK_PLUGIN(adder)
 468 AG_GST_CHECK_PLUGIN(app)
 469 AG_GST_CHECK_PLUGIN(audioconvert)
 470 AG_GST_CHECK_PLUGIN(audiorate)
 471 AG_GST_CHECK_PLUGIN(audiotestsrc)
 472 AG_GST_CHECK_PLUGIN(encoding)
 473 AG_GST_CHECK_PLUGIN(videoconvert)
 474 AG_GST_CHECK_PLUGIN(gio)
 475 AG_GST_CHECK_PLUGIN(playback)
 476 AG_GST_CHECK_PLUGIN(audioresample)
 477 AG_GST_CHECK_PLUGIN(subparse)
 478 AG_GST_CHECK_PLUGIN(tcp)
 479 AG_GST_CHECK_PLUGIN(typefind)
 480 AG_GST_CHECK_PLUGIN(videotestsrc)
 481 AG_GST_CHECK_PLUGIN(videorate)
 482 AG_GST_CHECK_PLUGIN(videoscale)
 483 AG_GST_CHECK_PLUGIN(volume)
 484
 485 dnl iso-codes is optional, used by libgsttag
 486 AC_ARG_ENABLE(iso-codes,
 487 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 488 [case "${enableval}" in
 489   yes) enable_iso_codes=yes ;;
 490   no)  enable_iso_codes=no ;;
 491   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 492 esac
 493 ],
 494 [enable_iso_codes=yes]) dnl Default value
 495
 496 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 497 if test "x$enable_iso_codes" = "xyes"; then
 498   AC_MSG_RESULT([yes])
 499   have_iso_codes=no
 500   AC_MSG_CHECKING([whether iso-codes are available on this system])
 501   if $PKG_CONFIG iso-codes; then
 502     AC_MSG_RESULT([yes])
 503     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 504     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 505       AC_MSG_RESULT([yes])
 506       AC_MSG_CHECKING([for iso-codes prefix])
 507       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 508       if test -d "$ISO_CODES_PREFIX"; then
 509         AC_MSG_RESULT([yes])
 510         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 511         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 512         ISO_639_DOMAIN="iso_639"
 513         AC_MSG_CHECKING([ISO_639_DOMAIN])
 514         AC_MSG_RESULT([$ISO_639_DOMAIN])
 515         have_iso_codes=yes
 516         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 517         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 518         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 519         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 520       else
 521         AC_MSG_RESULT([no])
 522       fi
 523     else
 524       AC_MSG_RESULT([no])
 525     fi
 526   else
 527     AC_MSG_RESULT([no])
 528   fi
 529   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 530 else
 531   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 532   AM_CONDITIONAL(USE_ISO_CODES, false)
 533 fi
 534
 535 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 536 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 537 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 538   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 539       HAVE_ZLIB="yes"
 540     ], [
 541       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 542         HAVE_ZLIB="yes"
 543         ZLIB_LIBS="-lz"
 544         AC_SUBST(ZLIB_LIBS)
 545       ])
 546     ])
 547 ])
 548
 549 dnl *** sys plug-ins ***
 550
 551 echo
 552 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 553 echo
 554
 555 dnl *** X11 ***
 556 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 557 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 558                   [ximagesink], [
 559   AG_GST_PKG_CHECK_MODULES(X, x11)
 560 ])
 561
 562 dnl Check for Xv extension
 563 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 564 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 565                   [xvimagesink], [
 566   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 567 ])
 568
 569 dnl check for X Shm
 570 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 571 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 572   if test x$HAVE_X = xyes; then
 573     PKG_CHECK_MODULES(XSHM, xext, [
 574       AC_CHECK_LIB(Xext, XShmAttach, [
 575         HAVE_XSHM="yes"
 576       ], [
 577         HAVE_XSHM="no"
 578         XSHM_LIBS=""
 579       ], [ $X_LIBS ])
 580     ], [
 581       HAVE_XSHM="no"
 582     ])
 583   fi
 584 ], , [
 585   AC_SUBST(HAVE_XSHM)
 586   AC_SUBST(XSHM_LIBS)
 587 ])
 588
 589 dnl *** ext plug-ins ***
 590 dnl keep this list sorted alphabetically !
 591
 592 if test "x$BUILD_EXTERNAL" = "xyes"; then
 593
 594 echo
 595 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 596 echo
 597
 598 dnl *** alsa ***
 599 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 600 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 601   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 602     HAVE_ALSA="yes"
 603     AC_SUBST(ALSA_CFLAGS)
 604     AC_SUBST(ALSA_LIBS)
 605   ], [
 606     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 607   ])
 608 ])
 609
 610 dnl *** CDParanoia ***
 611 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 612 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 613 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 614   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 615     HAVE_CDPARANOIA="yes"
 616   ], [
 617     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 618                         cdda_open, -lm,
 619                         cdda_interface.h,
 620                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 621                         HEADER_DIR="no"
 622                         FOUND_CDPARANOIA="yes")
 623     if test "x$FOUND_CDPARANOIA" != "xyes";
 624     then
 625       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 626                           cdda_open, -lm,
 627                           cdda/cdda_interface.h,
 628                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 629                           HEADER_DIR="yes"
 630                           FOUND_CDPARANOIA="yes")
 631     fi
 632     if test "x$HEADER_DIR" = "xyes";
 633     then
 634       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 635                          defined if cdda headers are in a cdda/ directory)
 636     fi
 637     if test "x$FOUND_CDPARANOIA" = "xyes";
 638     then
 639       AC_CHECK_LIB(cdda_paranoia,
 640                    paranoia_cachemodel_size,
 641                    : ,
 642                    HAVE_CDPARANOIA=no,
 643                  [-lcdda_interface])
 644     fi
 645
 646     AC_SUBST(CDPARANOIA_LIBS)
 647   ])
 648 ])
 649 dnl FIXME : add second check somehow if that is necessary
 650 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 651 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 652
 653 dnl *** ivorbis ***
 654 dnl AM_PATH_IVORBIS only takes two options
 655 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 656 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 657   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 658   if test $HAVE_IVORBIS = no
 659   then
 660     IVORBIS_LIBS=
 661     IVORBIS_CFLAGS=
 662     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 663       [IVORBIS_LIBS=-lvorbisidec
 664       HAVE_IVORBIS=yes
 665       case $host in
 666       arm-*-*)
 667         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 668       esac
 669       ],
 670       HAVE_IVORBIS=no)
 671     AC_SUBST(IVORBIS_LIBS)
 672     AC_SUBST(IVORBIS_CFLAGS)
 673   else
 674     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 675       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 676       USE_TREMOLO=no)
 677   fi
 678 ])
 679
 680 dnl *** libvisual ***
 681 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 682 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 683   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 684   if test x$HAVE_LIBVISUAL = xyes; then
 685     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 686   fi
 687   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 688   if test x$LIBVIS_PLUGINSDIR != x; then
 689     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 690         "$LIBVIS_PLUGINSDIR",
 691         [directory in which the detected libvisual's plugins are located])
 692   fi
 693 ])
 694
 695 dnl *** ogg ***
 696 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 697 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 698   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 699 ])
 700
 701 dnl *** pango ***
 702 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 703 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 704   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 705 ])
 706
 707 dnl *** theora ***
 708 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 709 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 710   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 711 ])
 712
 713 dnl *** vorbis ***
 714 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 715 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 716   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 717 ])
 718
 719 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 720 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO_UNIX_2_0, true)
 721 AG_GST_CHECK_FEATURE(GIO_UNIX_2_0, [glib GIO unix], gio-unix-2.0, [
 722   AG_GST_PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24)
 723 ])
 724
 725 if test "x$HAVE_VORBIS" = "xyes"; then
 726   ac_cflags_save="$CFLAGS"
 727   AC_COMPILE_IFELSE([
 728     AC_LANG_PROGRAM([[
 729 #include <vorbis/codec.h>
 730                      ]],[[
 731 vorbis_dsp_state *v;
 732
 733 vorbis_synthesis_restart (v);
 734                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 735   if test "x$HAVE_VSR" = "xyes"; then
 736     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 737                        [defined if vorbis_synthesis_restart is present])
 738   fi
 739   CFLAGS="$ac_cflags_save"
 740 fi
 741
 742 else
 743
 744 dnl not building plugins with external dependencies,
 745 dnl but we still need to set the conditionals
 746 AM_CONDITIONAL(USE_ALSA, false)
 747 AM_CONDITIONAL(USE_CDPARANOIA, false)
 748 AM_CONDITIONAL(USE_IVORBIS, false)
 749 AM_CONDITIONAL(USE_LIBVISUAL, false)
 750 AM_CONDITIONAL(USE_OGG, false)
 751 AM_CONDITIONAL(USE_PANGO, false)
 752 AM_CONDITIONAL(USE_THEORA, false)
 753 AM_CONDITIONAL(USE_VORBIS, false)
 754
 755 fi dnl of EXT plugins
 756
 757 dnl seeking needs freetype, so check for it here
 758 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 759   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 760 ])
 761 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 762 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 763 AC_SUBST(FT2_CFLAGS)
 764 AC_SUBST(FT2_LIBS)
 765
 766 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 767
 768 dnl Overview:
 769 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 770 dnl GST_*:              flags shared by built objects to link against GStreamer
 771 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 772 dnl                          (compare to other modules) or for i18n
 773 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 774 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 775 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 776 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 777
 778 dnl GST_OPTION_CFLAGS
 779 if test "x$USE_DEBUG" = xyes; then
 780    PROFILE_CFLAGS="-g"
 781 fi
 782 AC_SUBST(PROFILE_CFLAGS)
 783
 784 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 785   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 786   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 787 else
 788   DEPRECATED_CFLAGS=""
 789 fi
 790 AC_SUBST(DEPRECATED_CFLAGS)
 791
 792 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 793 dnl at make time with e.g. make ERROR_CFLAGS=""
 794 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 795 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 796 AC_SUBST(GST_OPTION_CFLAGS)
 797 AC_SUBST(GST_OPTION_CXXFLAGS)
 798
 799 dnl our libraries need to be versioned correctly
 800 AC_SUBST(GST_LT_LDFLAGS)
 801
 802 dnl GST_PLUGINS_BASE_CFLAGS
 803 dnl prefer internal headers to already installed ones
 804 dnl also add builddir include for enumtypes and marshal
 805 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 806 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 807
 808 dnl FIXME: do we want to rename to GST_ALL_* ?
 809 dnl add GST_OPTION_CFLAGS, but overridable
 810 GST_CFLAGS="$GST_CFLAGS"
 811 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 812 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 813 AC_SUBST(GST_CFLAGS)
 814 AC_SUBST(GST_CXXFLAGS)
 815 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 816 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 817 AC_SUBST(GST_LIBS)
 818
 819 dnl LDFLAGS really should only contain flags, not libs - they get added before
 820 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 821 GST_ALL_LDFLAGS="-no-undefined"
 822 if test "x${enable_Bsymbolic}" = "xyes"; then
 823   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 824 fi
 825 AC_SUBST(GST_ALL_LDFLAGS)
 826
 827 dnl GST_LIB_LDFLAGS
 828 dnl linker flags shared by all libraries
 829 dnl LDFLAGS modifier defining exported symbols from built libraries
 830 dnl (export _gst_foo but not __gst_foo)
 831 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 832 AC_SUBST(GST_LIB_LDFLAGS)
 833
 834 dnl this really should only contain flags, not libs - they get added before
 835 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 836 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 837 AC_SUBST(GST_PLUGIN_LDFLAGS)
 838
 839 dnl use tbm
 840 PKG_CHECK_MODULES(TBM, libdrm libtbm)
 841 AC_SUBST(TBM_CFLAGS)
 842 AC_SUBST(TBM_LIBS)
 843
 844 dnl use  mm-common
 845 PKG_CHECK_MODULES(MMCOMMON,mm-common)
 846 AC_SUBST(MMCOMMON_CFLAGS)
 847
 848 dnl *** output files ***
 849
 850 $MKDIR_P tests/check/orc
 851
 852 AC_CONFIG_FILES(
 853 Makefile
 854 gst-plugins-base.spec
 855 gst/Makefile
 856 gst/adder/Makefile
 857 gst/app/Makefile
 858 gst/audioconvert/Makefile
 859 gst/audiorate/Makefile
 860 gst/audiotestsrc/Makefile
 861 gst/encoding/Makefile
 862 gst/videoconvert/Makefile
 863 gst/gio/Makefile
 864 gst/playback/Makefile
 865 gst/audioresample/Makefile
 866 gst/subparse/Makefile
 867 gst/tcp/Makefile
 868 gst/typefind/Makefile
 869 gst/videotestsrc/Makefile
 870 gst/videorate/Makefile
 871 gst/videoscale/Makefile
 872 gst/volume/Makefile
 873 sys/Makefile
 874 sys/ximage/Makefile
 875 sys/xvimage/Makefile
 876 ext/Makefile
 877 ext/alsa/Makefile
 878 ext/cdparanoia/Makefile
 879 ext/libvisual/Makefile
 880 ext/ogg/Makefile
 881 ext/pango/Makefile
 882 ext/theora/Makefile
 883 ext/vorbis/Makefile
 884 gst-libs/Makefile
 885 gst-libs/gst/Makefile
 886 gst-libs/gst/allocators/Makefile
 887 gst-libs/gst/audio/Makefile
 888 gst-libs/gst/app/Makefile
 889 gst-libs/gst/fft/Makefile
 890 gst-libs/gst/riff/Makefile
 891 gst-libs/gst/rtp/Makefile
 892 gst-libs/gst/rtsp/Makefile
 893 gst-libs/gst/sdp/Makefile
 894 gst-libs/gst/tag/Makefile
 895 gst-libs/gst/pbutils/Makefile
 896 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 897 gst-libs/gst/video/Makefile
 898 tools/Makefile
 899 pkgconfig/Makefile
 900 pkgconfig/gstreamer-allocators.pc
 901 pkgconfig/gstreamer-allocators-uninstalled.pc
 902 pkgconfig/gstreamer-audio.pc
 903 pkgconfig/gstreamer-audio-uninstalled.pc
 904 pkgconfig/gstreamer-app.pc
 905 pkgconfig/gstreamer-app-uninstalled.pc
 906 pkgconfig/gstreamer-fft.pc
 907 pkgconfig/gstreamer-fft-uninstalled.pc
 908 pkgconfig/gstreamer-pbutils.pc
 909 pkgconfig/gstreamer-pbutils-uninstalled.pc
 910 pkgconfig/gstreamer-riff.pc
 911 pkgconfig/gstreamer-riff-uninstalled.pc
 912 pkgconfig/gstreamer-rtp.pc
 913 pkgconfig/gstreamer-rtp-uninstalled.pc
 914 pkgconfig/gstreamer-rtsp.pc
 915 pkgconfig/gstreamer-rtsp-uninstalled.pc
 916 pkgconfig/gstreamer-sdp.pc
 917 pkgconfig/gstreamer-sdp-uninstalled.pc
 918 pkgconfig/gstreamer-tag.pc
 919 pkgconfig/gstreamer-tag-uninstalled.pc
 920 pkgconfig/gstreamer-video.pc
 921 pkgconfig/gstreamer-video-uninstalled.pc
 922 pkgconfig/gstreamer-plugins-base.pc
 923 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 924 tests/Makefile
 925 tests/check/Makefile
 926 tests/examples/Makefile
 927 tests/examples/app/Makefile
 928 tests/examples/audio/Makefile
 929 tests/examples/dynamic/Makefile
 930 tests/examples/encoding/Makefile
 931 tests/examples/fft/Makefile
 932 tests/examples/gio/Makefile
 933 tests/examples/overlay/Makefile
 934 tests/examples/seek/Makefile
 935 tests/examples/snapshot/Makefile
 936 tests/examples/playback/Makefile
 937 tests/examples/playrec/Makefile
 938 tests/files/Makefile
 939 tests/icles/Makefile
 940 tests/icles/playback/Makefile
 941 docs/Makefile
 942 docs/design/Makefile
 943 docs/libs/Makefile
 944 docs/plugins/Makefile
 945 docs/version.entities
 946 po/Makefile.in
 947 common/Makefile
 948 common/m4/Makefile
 949 m4/Makefile
 950 )
 951
 952 dnl Create the config.h file for Visual Studio builds
 953 dnl Beware of spaces and /'s in some of the shell variable contents.
 954 sed \
 955     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 956     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 957     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 958     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 959     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 960     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 961     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 962     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 963     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 964     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 965     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 966     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 967     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 968     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 969     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 970     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 971     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 972     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 973     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 974     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 975     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 976     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 977     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 978     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 979     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 980     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 981     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 982     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 983     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 984     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 985     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 986     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 987     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 988     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 989     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 990     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 991     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 992     config.h.in >win32/common/config.h-new
 993
 994
 995
 996 AC_OUTPUT
 997
 998 AG_GST_OUTPUT_PLUGINS
 999 ORC_OUTPUT
1000