configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20 #
  21 # Process this file with autoconf to produce a configure script
  22
  23 # Initialize Autoconf
  24 AC_PREREQ([2.60])
  25 AC_INIT([xf86-input-evdev],
  26         [2.7.0],
  27         [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
  28         [xf86-input-evdev])
  29 AC_CONFIG_SRCDIR([Makefile.am])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR(.)
  32
  33 # Initialize Automake
  34 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  35 AM_MAINTAINER_MODE
  36
  37 # Initialize libtool
  38 AC_DISABLE_STATIC
  39 AC_PROG_LIBTOOL
  40
  41 # Initialize X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
  42 m4_ifndef([XORG_MACROS_VERSION],
  43           [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
  44 XORG_MACROS_VERSION(1.8)
  45 XORG_DEFAULT_OPTIONS
  46
  47 # Obtain compiler/linker options from server and required extensions
  48 PKG_CHECK_MODULES(XORG, [xorg-server >= 1.10] xproto inputproto)
  49 PKG_CHECK_MODULES(UDEV, libudev)
  50
  51 PKG_CHECK_MODULES(XI22, [inputproto >= 2.1.99.3] [xorg-server >= 1.11.99.901], HAVE_XI22="yes", HAVE_XI22="no")
  52
  53 if test "x$HAVE_XI22" = xyes; then
  54         # Obtain compiler/linker options for mtdev
  55         PKG_CHECK_MODULES(MTDEV, mtdev, HAVE_MTDEV="yes", HAVE_MTDEV="no")
  56 fi
  57 if test "x$HAVE_XI22" = xyes && test "x$HAVE_MTDEV" = xyes; then
  58         AC_DEFINE(MULTITOUCH, 1, [XI2.2 available])
  59 fi
  60
  61 # Define a configure option for an alternate input module directory
  62 AC_ARG_WITH(xorg-module-dir,
  63             AC_HELP_STRING([--with-xorg-module-dir=DIR],
  64                            [Default xorg module directory [[default=$libdir/xorg/modules]]]),
  65             [moduledir="$withval"],
  66             [moduledir="$libdir/xorg/modules"])
  67 inputdir=${moduledir}/input
  68 AC_SUBST(inputdir)
  69
  70 # X Server SDK location is required to install evdev header files
  71 # This location is also relayed in the xorg-evdev.pc file
  72 sdkdir=`$PKG_CONFIG --variable=sdkdir xorg-server`
  73
  74 # Workaround overriding sdkdir to be able to create a tarball when user has no
  75 # write permission in sdkdir. See DISTCHECK_CONFIGURE_FLAGS in Makefile.am
  76 AC_ARG_WITH([sdkdir], [], [sdkdir="$withval"])
  77 AC_SUBST([sdkdir])
  78
  79 DRIVER_NAME=evdev
  80 AC_SUBST([DRIVER_NAME])
  81
  82 AC_CONFIG_FILES([Makefile
  83                  src/Makefile
  84                  man/Makefile
  85                  include/Makefile
  86                  xorg-evdev.pc])
  87 AC_OUTPUT