configure.ac

   1 dnl  Copyright © 2008 Dan Nicholson
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Keith Packard not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Keith Packard makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  DAN NICHOLSON DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 # Initialize Autoconf
  24 AC_PREREQ([2.62])
  25 AC_INIT([libxkbcommon], [0.4.1],
  26         [https://bugs.freedesktop.org/enter_bug.cgi?product=libxkbcommon],
  27         [libxkbcommon], [http://xkbcommon.org])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_HEADERS([src/config.h])
  30 AC_CONFIG_MACRO_DIR([m4])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 # Initialize Automake
  34 AM_INIT_AUTOMAKE([foreign dist-xz no-dist-gzip subdir-objects color-tests parallel-tests check-news])
  35 AM_MAINTAINER_MODE([enable])
  36
  37 # Get _GNU_SOURCE and friends
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 # Initialize libtool
  41 LT_INIT
  42
  43 # Add xorg-macros stuff
  44 m4_ifndef([XORG_MACROS_VERSION],
  45           [m4_fatal([must install xorg-macros 1.16 or later before running autoconf/autogen])])
  46 XORG_MACROS_VERSION(1.16)
  47 XORG_DEFAULT_OPTIONS
  48 XORG_MEMORY_CHECK_FLAGS
  49 XORG_ENABLE_DOCS
  50 XORG_WITH_DOXYGEN
  51
  52 # Needed in older Automakes for subdir-objects
  53 AM_PROG_CC_C_O
  54
  55 # Check for compiler features
  56 AC_C_INLINE
  57
  58 # Check for programs
  59 AC_PROG_MKDIR_P
  60 PKG_PROG_PKG_CONFIG
  61
  62 # Note: we use some yacc extensions, which work with either GNU bison
  63 # (preferred) or byacc. Other yacc's may or may not work.
  64 AC_PROG_YACC
  65 AC_PATH_PROG([YACC_INST], [$YACC])
  66 AS_IF([test ! -f "src/xkbcomp/parser.c" -a "x$YACC_INST" = x], [
  67     AC_MSG_ERROR([yacc not found - unable to compile src/xkbcomp/parser.y])
  68 ])
  69
  70 # Checks for library functions.
  71 AC_CHECK_FUNCS([strcasecmp strncasecmp])
  72 AS_IF([test "x$ac_cv_func_strcasecmp" = xno -o \
  73             "x$ac_cv_func_strncasecmp" = xno], [
  74     AC_MSG_ERROR([C library does not support strcasecmp/strncasecmp])
  75 ])
  76
  77 AC_CHECK_FUNCS([eaccess euidaccess mmap])
  78
  79 AC_CHECK_FUNCS([secure_getenv __secure_getenv])
  80 AS_IF([test "x$ac_cv_func_secure_getenv" = xno -a \
  81             "x$ac_cv_func___secure_getenv" = xno], [
  82     AC_MSG_WARN([C library does not support secure_getenv, using getenv instead])
  83 ])
  84
  85 AX_GCC_BUILTIN(__builtin_expect)
  86
  87 # Some tests use Linux-specific headers
  88 AC_CHECK_HEADER([linux/input.h])
  89 AM_CONDITIONAL(BUILD_LINUX_TESTS, [test "x$ac_cv_header_linux_input_h" = xyes])
  90
  91 XORG_TESTSET_CFLAG([BASE_CFLAGS], [-fvisibility=hidden])
  92 XORG_TESTSET_CFLAG([BASE_CFLAGS], [-Wextra -Wno-unused-parameter -Wno-missing-field-initializers])
  93
  94 XORG_CHECK_LINKER_FLAGS([-Wl,--no-undefined], [have_no_undefined=yes])
  95 AM_CONDITIONAL([HAVE_NO_UNDEFINED], [test "x$have_no_undefined" = xyes])
  96
  97 # Define a configuration option for the XKB config root
  98 xkb_base=`$PKG_CONFIG --variable=xkb_base xkeyboard-config`
  99 AS_IF([test "x$xkb_base" = x], [
 100     xkb_base="$datadir/X11/xkb"
 101 ])
 102 AC_ARG_WITH([xkb_config_root],
 103     [AS_HELP_STRING([--with-xkb-config-root=<path>],
 104         [Set default XKB config root (default: xkeyboard-config install path)])],
 105     [XKBCONFIGROOT="$withval"],
 106     [XKBCONFIGROOT="$xkb_base"])
 107 AC_SUBST([XKBCONFIGROOT])
 108
 109 AC_ARG_WITH([default_rules],
 110     [AS_HELP_STRING([--with-default-rules=<path>],
 111         [Default XKB ruleset (default: evdev)])],
 112     [DEFAULT_XKB_RULES="$withval"],
 113     [DEFAULT_XKB_RULES="evdev"])
 114 AC_DEFINE_UNQUOTED([DEFAULT_XKB_RULES], ["$DEFAULT_XKB_RULES"],
 115                    [Default XKB ruleset])
 116
 117 AC_ARG_WITH([default_model],
 118     [AS_HELP_STRING([--with-default-model=<path>],
 119         [Default XKB model (default: pc105)])],
 120     [DEFAULT_XKB_MODEL="$withval"],
 121     [DEFAULT_XKB_MODEL="pc105"])
 122 AC_DEFINE_UNQUOTED([DEFAULT_XKB_MODEL], ["$DEFAULT_XKB_MODEL"],
 123                    [Default XKB model])
 124
 125 AC_ARG_WITH([default_layout],
 126     [AS_HELP_STRING([--with-default-layout=<path>],
 127         [Default XKB layout (default: us)])],
 128     [DEFAULT_XKB_LAYOUT="$withval"],
 129     [DEFAULT_XKB_LAYOUT="us"])
 130 AC_DEFINE_UNQUOTED([DEFAULT_XKB_LAYOUT], ["$DEFAULT_XKB_LAYOUT"],
 131                    [Default XKB layout])
 132
 133 AC_ARG_WITH([default_variant],
 134     [AS_HELP_STRING([--with-default-variant=<path>],
 135         [Default XKB variant (default: (none))])],
 136     [DEFAULT_XKB_VARIANT="$withval"],
 137     [DEFAULT_XKB_VARAINT=])
 138 AS_IF([test "x$DEFAULT_XKB_VARIANT" != x], [
 139     AC_DEFINE_UNQUOTED([DEFAULT_XKB_VARIANT], ["$DEFAULT_XKB_VARIANT"],
 140                        [Default XKB variant])
 141 ])
 142
 143 AC_ARG_WITH([default_options],
 144     [AS_HELP_STRING([--with-default-options=<path>],
 145         [Default XKB options (default: (none))])],
 146     [DEFAULT_XKB_OPTIONS="$withval"],
 147     [DEFAULT_XKB_OPTIONS=])
 148 AS_IF([test "x$DEFAULT_XKB_OPTIONS" != x], [
 149     AC_DEFINE_UNQUOTED([DEFAULT_XKB_OPTIONS], ["$DEFAULT_XKB_OPTIONS"],
 150                        [Default XKB options])
 151 ])
 152
 153 AC_ARG_ENABLE([x11],
 154     [AS_HELP_STRING([--disable-x11],
 155         [Disable support for creating keymaps with the X11 protocol (default: enabled)])],
 156     [], [enable_x11=yes])
 157 AS_IF([test "x$enable_x11" = xyes], [
 158     PKG_CHECK_MODULES([XCB_XKB], [xcb xcb-xkb >= 1.10], [],
 159         [AC_MSG_ERROR([xkbcommon-x11 requires xcb-xkb >= 1.10 which was not found. \
 160 You can disable X11 support with --disable-x11.])])
 161 ], [enable_x11=no])
 162 AM_CONDITIONAL([ENABLE_X11], [test "x$enable_x11" = xyes])
 163
 164 AC_CONFIG_FILES([
 165     Makefile
 166     xkbcommon-uninstalled.pc
 167     xkbcommon.pc
 168     xkbcommon-x11.pc
 169     xkbcommon-x11-uninstalled.pc
 170     doc/Doxyfile
 171 ])
 172 AC_OUTPUT
 173
 174 AC_MSG_RESULT([
 175         $PACKAGE_NAME $VERSION
 176
 177         libxkbcommon:            yes
 178         libxkbcommon-x11:        ${enable_x11}
 179         documentation:           ${build_docs}
 180
 181         default XKB rules:       ${DEFAULT_XKB_RULES}
 182         default XKB model:       ${DEFAULT_XKB_MODEL}
 183         default XKB layout:      ${DEFAULT_XKB_LAYOUT}
 184         default XKB variant:     ${DEFAULT_XKB_VARIANT}
 185         default XKB options:     ${DEFAULT_XKB_OPTIONS}
 186
 187         prefix:                  ${prefix}
 188         includedir:              ${includedir}
 189         lib dir:                 ${libdir}
 190         XKB config root:         ${XKBCONFIGROOT}
 191 ])