configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 # 2004, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_INIT([GNU Automake], [1.11], [bug-automake@gnu.org])
  20
  21 m4_ifndef([AC_PACKAGE_URL],
  22           [AC_SUBST([PACKAGE_URL], [http://www.gnu.org/software/automake/])])
  23
  24 AC_CONFIG_SRCDIR(automake.in)
  25 AC_CONFIG_AUX_DIR(lib)
  26
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by `missing'.  Likewise for autoheader.
  32 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  33 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  34
  35 AM_INIT_AUTOMAKE([1.10a dist-bzip2 filename-length-max=99 color-tests parallel-tests])
  36
  37 # The API version is the base version.  We must guarantee
  38 # compatibility for all releases with the same API version.
  39 # Our current rule is that:
  40 # * All releases, including the prereleases, in an X.Y series
  41 #   are compatible.  So 1.5.1c is compatible with 1.5.
  42 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  43 #   aren't the same.
  44 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  45 AC_SUBST([APIVERSION])
  46
  47 # A versioned directory, defined here for convenience.
  48 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  49
  50 # $AUTOMAKE and $ACLOCAL are always run after a `cd $top_srcdir',
  51 # hence `.' is really what we want for perllibdir, libdir, and acdir.
  52 ACLOCAL="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" --acdir=m4 -I m4"
  53 AUTOMAKE="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" --libdir=lib"
  54
  55 AC_PATH_PROG(PERL, perl)
  56 if test -z "$PERL"; then
  57    AC_MSG_ERROR([perl not found])
  58 fi
  59 $PERL -e 'require 5.006;' || {
  60    AC_MSG_ERROR(
  61 [perl 5.6 or better is required; perl 5.8.2 or better
  62 is recommended.  If you have several perl versions
  63 installed, select the one Automake should use using
  64   ./configure PERL=/path/to/perl])
  65 }
  66
  67 # We require ithreads support, and version 5.7.2 for CLONE.
  68 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  69 [if $PERL -e '
  70     require 5.007_002;
  71     use Config;
  72     if ($Config{useithreads})
  73       {
  74         require threads;
  75         import threads;
  76         require Thread::Queue;
  77         import Thread::Queue;
  78         exit 0;
  79       }
  80     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
  81 then
  82   am_cv_prog_PERL_ithreads=yes
  83 else
  84   am_cv_prog_PERL_ithreads=no
  85 fi])
  86 if test $am_cv_prog_PERL_ithreads = yes; then
  87   PERL_THREADS=1;
  88 else
  89   PERL_THREADS=0;
  90 fi
  91 AC_SUBST([PERL_THREADS])
  92
  93 # The test suite will skip some tests if tex is absent.
  94 AC_CHECK_PROG([TEX], [tex], [tex])
  95
  96 # Generate man pages.
  97 AM_MISSING_PROG([HELP2MAN], [help2man])
  98
  99 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 100 # deletion of any files created (such as those added to
 101 # autom4te.cache).  We used to perform only the last of the three
 102 # following tests, but some users were unable to figure out that their
 103 # installation was broken since --version appeared to work.
 104
 105 required_autoconf_version=2.62
 106 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 107 [if AM_RUN_LOG([eval $am_AUTOCONF --version]);
 108 then
 109   am_cv_autoconf_installed=yes
 110 else
 111   am_cv_autoconf_installed=no
 112 fi])
 113 if test "$am_cv_autoconf_installed" = no; then
 114   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 115     Please make sure it is installed and in your PATH.])
 116 fi
 117
 118 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 119 [mkdir conftest
 120 echo 'AC''_INIT' > conftest/conftest.ac
 121 if AM_RUN_LOG([cd conftest && eval $am_AUTOCONF -o /dev/null conftest.ac]);
 122 then
 123   am_cv_autoconf_works=yes
 124 else
 125   am_cv_autoconf_works=no
 126 fi
 127 rm -rf conftest])
 128 if test "$am_cv_autoconf_works" = no; then
 129   AC_MSG_ERROR([The installed version of autoconf does not work.
 130     Please check config.log for error messages before this one.])
 131 fi
 132
 133 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 134 [mkdir conftest
 135 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 136 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 137 if AM_RUN_LOG([cd conftest && eval $am_AUTOCONF -o /dev/null conftest.ac]);
 138 then
 139   am_cv_autoconf_version=yes
 140 else
 141   am_cv_autoconf_version=no
 142 fi
 143 rm -rf conftest])
 144 if test "$am_cv_autoconf_version" = no; then
 145   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 146 fi
 147
 148 # Test for ln.  We need use it to install the versioned binaries.
 149 AC_MSG_CHECKING([whether ln works])
 150 AC_CACHE_VAL([am_cv_prog_ln], [
 151 rm -f conftest conftest.file
 152 : >conftest.file
 153 if ln conftest.file conftest 2>/dev/null; then
 154   am_cv_prog_ln=ln
 155 else
 156   am_cv_prog_ln='cp -p'
 157 fi
 158 rm -f conftest conftest.file])
 159 AC_SUBST([LN], [$am_cv_prog_ln])
 160 result=no
 161 test "x$am_cv_prog_ln" = xln && result=yes
 162 AC_MSG_RESULT([$result])
 163
 164 # The amount we should wait after modifying files depends on the platform.
 165 # On Windows '95, '98 and ME, files modifications have 2-seconds
 166 # granularity and can be up to 3 seconds in the future w.r.t. the
 167 # system clock.  When it is important to ensure one file is older
 168 # than another we wait at least 5 seconds between creations.
 169 case $build in
 170   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 171   *)               MODIFICATION_DELAY=2;;
 172 esac
 173 AC_SUBST([MODIFICATION_DELAY])
 174
 175 # Test for things needed by the test suite.
 176 AC_PROG_EGREP
 177 AC_PROG_FGREP
 178
 179 AC_CACHE_CHECK([whether /bin/sh has working 'set -e' with exit trap],
 180 [am_cv_sh_errexit_works],
 181 [if /bin/sh -ec "trap 'exit \$?' 0; (exit 77); exit 77"; test $? = 77
 182 then
 183   am_cv_sh_errexit_works=yes
 184 else
 185   am_cv_sh_errexit_works=no
 186 fi
 187 ])
 188 if test $am_cv_sh_errexit_works = no; then
 189   AC_MSG_WARN([`${MAKE-make} check' will leave leftover directories tests/*.dir])
 190   AC_MSG_WARN([you can clean them up manually using `${MAKE-make} clean' or])
 191   AC_MSG_WARN([`cd tests && ${MAKE-make} clean-local-check'])
 192   dnl restore font-lock: `
 193 fi
 194 AC_SUBST([sh_errexit_works], [$am_cv_sh_errexit_works])
 195
 196 AC_CONFIG_FILES([
 197   Makefile
 198   doc/Makefile
 199   lib/Automake/Makefile
 200   lib/Automake/tests/Makefile
 201   lib/Makefile
 202   lib/am/Makefile
 203   m4/Makefile
 204   tests/Makefile
 205   tests/defs
 206 ])
 207 AC_CONFIG_FILES([tests/aclocal-${APIVERSION}:tests/aclocal.in],
 208                 [chmod +x tests/aclocal-${APIVERSION}],
 209                 [APIVERSION=$APIVERSION])
 210 AC_CONFIG_FILES([tests/automake-${APIVERSION}:tests/automake.in],
 211                 [chmod +x tests/automake-${APIVERSION}])
 212
 213 AC_OUTPUT