configure.ac

   1 AC_PREREQ([2.64])
   2
   3 AC_INIT([wayland-fits],
   4         [0.99.1],
   5         [https://bugs.freedesktop.org/enter_bug.cgi?product=wayland],
   6         [wayland-fits],
   7         [http://wayland.freedesktop.org/])
   8
   9 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz])
  10
  11 AC_CONFIG_HEADERS([config.h])
  12 AC_CONFIG_MACRO_DIR([m4])
  13
  14 # check for compilers
  15 AC_PROG_CXX
  16 AC_PROG_CC
  17
  18 # Initialize libtool
  19 LT_PREREQ([2.2])
  20 LT_INIT
  21
  22 LDFLAGS="-Wl,--no-as-needed"
  23
  24 # Required minimum versions for dependencies
  25 m4_define([check_req_version],          [0.9.8])
  26 # m4_define([pixman1_req_version],      [0.29.3])
  27 m4_define([wayland_req_version],        [1.0.6])
  28 m4_define([weston_req_version],         [1.0.6])
  29 m4_define([efl_req_version],            [1.7.6])
  30
  31 PKG_CHECK_MODULES([CHECK], [check >= check_req_version])
  32 PKG_CHECK_MODULES([WAYLAND],
  33         [
  34                 wayland-client >= wayland_req_version
  35                 wayland-egl >= wayland_req_version
  36                 wayland-cursor >= wayland_req_version
  37         ]
  38 )
  39 PKG_CHECK_MODULES(WAYLAND_SERVER, [wayland-server >= wayland_req_version])
  40
  41 have_weston="no"
  42 want_weston_extensions="auto"
  43 AC_ARG_ENABLE([weston-extensions],
  44         [AC_HELP_STRING([--disable-weston-extensions], [disable Weston extension support. @<:@default=detect@:>@])],
  45         [want_weston_extensions=$enableval], [])
  46
  47 if test "x$want_weston_extensions" != "xno"; then
  48         PKG_CHECK_MODULES([WESTON],
  49                 [
  50                         weston >= weston_req_version
  51                         pixman-1
  52                 ],
  53                 [
  54                         AC_DEFINE(HAVE_WESTON, 1, [Support for Weston extensions])
  55                         have_weston="yes"
  56                         PKG_CHECK_MODULES([WESTON_SDK2],
  57                                 [
  58                                         weston >= 1.0.90
  59                                 ],
  60                                 [
  61                                         AC_DEFINE(HAVE_WESTON_SDK2, 1, [Support for Weston 1.1.0 extensions])
  62                                         have_weston_sdk2="yes"
  63                                 ],
  64                                 [have_weston_sdk2="no"]
  65                         )
  66                 ],
  67                 [have_weston="no"]
  68         )
  69 else
  70         have_weston="no"
  71 fi
  72
  73 if test "x$want_weston_extensions" = "xyes" -a "x$have_weston" = "xno"; then
  74         AC_MSG_ERROR([
  75
  76                 weston extension support requested, but one of the following dependency requirements were not met:
  77
  78                 weston >= weston_req_version
  79                 pixman
  80         ])
  81 fi
  82 AM_CONDITIONAL([BUILD_WESTON_EXTENSIONS], [test x${have_weston} = xyes])
  83
  84 have_efl="no"
  85 want_efl_tests="auto"
  86 AC_ARG_ENABLE([efl-tests],
  87         [AC_HELP_STRING([--disable-efl-tests], [disable EFL Tests. @<:@default=detect@:>@])],
  88         [want_efl_tests=$enableval], [])
  89
  90 if test "x$want_efl_tests" != "xno"; then
  91         PKG_CHECK_MODULES([EFL],
  92                 [
  93                         elementary >= efl_req_version
  94                         ecore-wayland >= efl_req_version
  95                         evas-wayland-egl >= efl_req_version
  96                         evas-wayland-shm >= efl_req_version
  97                 ],
  98                 [
  99                         AC_DEFINE(HAVE_EFL, 1, [Support for EFL Tests])
 100                         have_efl="yes"
 101                 ],
 102                 [have_efl="no"]
 103         )
 104 else
 105         have_efl="no"
 106 fi
 107
 108 if test "x$want_efl_tests" = "xyes" -a "x$have_efl" = "xno"; then
 109         AC_MSG_ERROR([
 110
 111                 EFL tests requested, but one of the following dependency requirements were not met:
 112
 113                 elementary >= efl_req_version
 114                 ecore-wayland >= efl_req_version
 115                 evas-wayland-egl >= efl_req_version
 116                 evas-wayland-shm >= efl_req_version
 117         ])
 118 fi
 119 AM_CONDITIONAL([BUILD_EFL_TESTS], [test x$have_efl = xyes])
 120
 121 WAYLAND_SCANNER_RULES(['$(top_srcdir)/src/extensions/protocol'])
 122
 123 AC_CONFIG_FILES([Makefile
 124                  src/Makefile
 125                  src/common/Makefile
 126                  src/core/Makefile
 127                  src/efl/Makefile
 128                  src/extensions/Makefile
 129                  src/extensions/weston/Makefile
 130                  src/extensions/protocol/Makefile])
 131 AC_OUTPUT