configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.69])
  19 AC_INIT([GNU Automake], [1.12a], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([dist-xz filename-length-max=99 color-tests
  43                   no-define no-dependencies])
  44
  45 ## Keep this on a line of its own, since it must be found and processed
  46 ## by the 'update-copyright' rule in our Makefile.
  47 RELEASE_YEAR=2012
  48 AC_SUBST([RELEASE_YEAR])
  49
  50 # The API version is the base version.  We must guarantee
  51 # compatibility for all releases with the same API version.
  52 # Our current rule is that:
  53 # * All releases, including the prereleases, in an X.Y series
  54 #   are compatible.  So 1.5.1c is compatible with 1.5.
  55 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  56 #   aren't the same.
  57 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  58 AC_SUBST([APIVERSION])
  59
  60 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  61 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  62 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  63 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  64 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  65
  66 # Our build system is bootstrapped with the bleeding-edge versions of
  67 # aclocal and automake, hence the remake rules must use those versions
  68 # as well.  The extra quoting is to cater to cases when the build
  69 # directory contains whitespace or shell metacharacters.
  70 ACLOCAL="\"`pwd`/t/wrap/aclocal-$APIVERSION\""
  71 AUTOMAKE="\"`pwd`/t/wrap/automake-$APIVERSION\""
  72
  73 AC_PATH_PROG([PERL], [perl])
  74 if test -z "$PERL"; then
  75    AC_MSG_ERROR([perl not found])
  76 fi
  77 # Save details about the selected perl interpreter in config.log.
  78 AM_RUN_LOG([$PERL --version])
  79 $PERL -e 'require 5.006;' || {
  80    AC_MSG_ERROR(
  81 [perl 5.6 or better is required; perl 5.8.2 or better
  82 is recommended.  If you have several perl versions
  83 installed, select the one Automake should use using
  84   ./configure PERL=/path/to/perl])
  85 }
  86
  87 # We require ithreads support, and version 5.7.2 for CLONE.
  88 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  89 [if $PERL -e '
  90     require 5.007_002;
  91     use Config;
  92     if ($Config{useithreads})
  93       {
  94         require threads;
  95         import threads;
  96         require Thread::Queue;
  97         import Thread::Queue;
  98         exit 0;
  99       }
 100     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
 101 then
 102   am_cv_prog_PERL_ithreads=yes
 103 else
 104   am_cv_prog_PERL_ithreads=no
 105 fi])
 106 if test $am_cv_prog_PERL_ithreads = yes; then
 107   PERL_THREADS=1;
 108 else
 109   PERL_THREADS=0;
 110 fi
 111 AC_SUBST([PERL_THREADS])
 112
 113 # The test suite will skip some tests if tex is absent.
 114 AC_CHECK_PROG([TEX], [tex], [tex])
 115 # Save details about the selected TeX program in config.log.
 116 # Redirect input from /dev/null, as TeX might otherwise hang waiting
 117 # for input from the terminal.
 118 AM_RUN_LOG([$TEX --version </dev/null])
 119
 120 # The test suite will skip some tests if no lex or yacc program is
 121 # available.
 122 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
 123 #  1. we don't want flex (resp. bison) to be preferred to system lex
 124 #     (resp. system yacc);
 125 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 126 #     by default;
 127 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 128 #     LEXLIB to be calculated and/or AC_SUBST'd;
 129 #  4. we prefer that the YACC and LEX variables are not reported in the
 130 #     configure help screen.
 131 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 132 AC_CHECK_PROGS([LEX], [lex flex], [false])
 133
 134 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 135 # deletion of any files created (such as those added to
 136 # autom4te.cache).  We used to perform only the last of the three
 137 # following tests, but some users were unable to figure out that their
 138 # installation was broken since --version appeared to work.
 139
 140 required_autoconf_version=2.65
 141 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 142 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 143 then
 144   am_cv_autoconf_installed=yes
 145 else
 146   am_cv_autoconf_installed=no
 147 fi])
 148 if test "$am_cv_autoconf_installed" = no; then
 149   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 150     Please make sure it is installed and in your PATH.])
 151 fi
 152
 153 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 154 [mkdir conftest
 155 echo 'AC''_INIT' > conftest/conftest.ac
 156 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 157 then
 158   am_cv_autoconf_works=yes
 159 else
 160   am_cv_autoconf_works=no
 161 fi
 162 rm -rf conftest])
 163 if test "$am_cv_autoconf_works" = no; then
 164   AC_MSG_ERROR([The installed version of autoconf does not work.
 165     Please check config.log for error messages before this one.])
 166 fi
 167
 168 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 169 [mkdir conftest
 170 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 171 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 172 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 173 then
 174   am_cv_autoconf_version=yes
 175 else
 176   am_cv_autoconf_version=no
 177 fi
 178 rm -rf conftest])
 179 if test "$am_cv_autoconf_version" = no; then
 180   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 181 fi
 182
 183 # Test for ln.  We need use it to install the versioned binaries.
 184 AC_MSG_CHECKING([whether ln works])
 185 AC_CACHE_VAL([am_cv_prog_ln], [
 186 rm -f conftest conftest.file
 187 : >conftest.file
 188 if ln conftest.file conftest 2>/dev/null; then
 189   am_cv_prog_ln=ln
 190 else
 191   am_cv_prog_ln='cp -p'
 192 fi
 193 rm -f conftest conftest.file])
 194 AC_SUBST([LN], [$am_cv_prog_ln])
 195 result=no
 196 test "x$am_cv_prog_ln" = xln && result=yes
 197 AC_MSG_RESULT([$result])
 198
 199 # The amount we should wait after modifying files depends on the platform.
 200 # On Windows '95, '98 and ME, files modifications have 2-seconds
 201 # granularity and can be up to 3 seconds in the future w.r.t. the
 202 # system clock.  When it is important to ensure one file is older
 203 # than another we wait at least 5 seconds between creations.
 204 case $build in
 205   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 206   *)               MODIFICATION_DELAY=2;;
 207 esac
 208 AC_SUBST([MODIFICATION_DELAY])
 209
 210 ## ------------------------------------------- ##
 211 ##  Test for things needed by the test suite.  ##
 212 ## ------------------------------------------- ##
 213
 214 AC_PROG_EGREP
 215 AC_PROG_FGREP
 216
 217 dnl FIXME: could we extract this in a simpler way through autoconf
 218 dnl FIXME: idioms or internals?
 219 AC_DEFUN(
 220   [_AM_INIT_BOURNE_COMPATIBLE_VAR],
 221   [am_bourne_compatible="AS_ESCAPE(_m4_expand([AS_BOURNE_COMPATIBLE]))"])
 222
 223 dnl
 224 dnl Arguments to this macro:
 225 dnl
 226 dnl   $1 - shell to test
 227 dnl   $2 - description of the tested feature
 228 dnl   $3 - shell code used to check the feature; to indicate success,
 229 dnl        it can either exit with status 77, or have the last command
 230 dnl        returning with exit status of zero
 231 dnl   $4 - shell code to execute if the check on the shell is successful
 232 dnl        (defaults to nothing)
 233 dnl   $5 - shell code to execute if the check on the shell is not
 234 dnl        successful (defaults to nothing)
 235 dnl
 236 AC_DEFUN([_AM_CHECK_SHELL_FEATURE],
 237   [AC_REQUIRE([_AM_INIT_BOURNE_COMPATIBLE_VAR])
 238   AC_MSG_CHECKING([whether $1 $2])
 239   if { $1 -c "$am_bourne_compatible
 240 AS_ESCAPE([$3])
 241 test \$? -eq 0 || exit 1
 242 # Use 77 to indicate success (rather than 0), in case some shell
 243 # acts like Solaris 10's /bin/sh, exiting successfully on some
 244 # syntax errors.
 245 exit 77" >&AS_MESSAGE_LOG_FD 2>&1; test $? -eq 77; }
 246   then
 247     AC_MSG_RESULT([yes])
 248     $4
 249   else
 250     AC_MSG_RESULT([no])
 251     $5
 252   fi])
 253
 254 # AM_CHECK_CANDIDATE_TEST_SHELL(SHELL-PATH)
 255 # -----------------------------------------
 256 #
 257 # Check if the given shell is good enough to run our test scripts.
 258 # Inspired to gnulib's 'tests/init.sh'.
 259 #
 260 # We require POSIX and XSI features (e.g., '$(...)' for command
 261 # substitutions, '$((...))' for shell arithmetic, and support for
 262 # '${var#...}' and '${var%...}' parameter expansions).
 263 #
 264 # We require that the shell can correctly trap EXIT when 'set -e' is in
 265 # effect (OSF1/Tru64 sh failed to do so, see commit v1.10b-52-g9fe8259).
 266 #
 267 # We want to able to define shell aliases with the same name of shell
 268 # builtins.
 269 #
 270 # We also prefer shells that, when 'set -x' is in effect, do not also
 271 # redirect traces upon stderr redirections.  For example,
 272 #  $ set -x; echo x 2>file
 273 # would emit "+ echo x" into file with older zsh versions.  Similarly,
 274 #   $ set -x; P=1 true 2>file
 275 # would emit "P=1" into file with /usr/xpg4/bin/sh from Solaris 10 and
 276 # /bin/sh from SunOS 5.11 and OpenBSD 4.7.
 277 #
 278 # Finally, we look for weird bugs and portability problems mentioned in
 279 # the Autoconf manual, and reject shells that suffers from them. (TODO)
 280 #
 281 # Use '$am_score' to indicate the degree of acceptability of the shell.
 282 # A score of "10" means that the shell is good enough for our needs;
 283 # a score of "9" means that the shell has some minor bugs or limitation,
 284 # but is still (barely) acceptable for our uses.  Any other score means
 285 # that the shell is broken or unfit.
 286 #
 287 AC_DEFUN([_AM_CHECK_CANDIDATE_SHELL],
 288   [am_score=10
 289   while :; do
 290
 291     _AM_CHECK_SHELL_FEATURE([$1],
 292       [supports \$(cmd)],
 293       [test "$(echo x)" = x],
 294       [], [am_score=1; break])
 295
 296     _AM_CHECK_SHELL_FEATURE([$1],
 297       [supports \$((expr))],
 298       [test $((1 + 2 * 3)) = 7],
 299       [], [am_score=1; break])
 300
 301     _AM_CHECK_SHELL_FEATURE([$1],
 302       [supports \${@%:@var}],
 303       [zero='' one='x' twelve=' foobar baz!' \
 304         && test ${@%:@zero} -eq 0 \
 305         && test ${@%:@one} -eq 1 \
 306         && test ${@%:@twelve} -eq 12],
 307       [], [am_score=1; break])
 308
 309     _AM_CHECK_SHELL_FEATURE([$1],
 310       [supports \${var@%:@glob} and \${var%glob}],
 311       [v=a/b/c \
 312         && test ${v@%:@*/} = b/c \
 313         && test ${v@%:@@%:@*/} = c \
 314         && test ${v%/*} = a/b \
 315         && test ${v%%/*} = a],
 316       [], [am_score=1; break])
 317
 318     _AM_CHECK_SHELL_FEATURE([$1],
 319       [preserves exit traps with "set -e"],
 320       [set -e; trap 'exit $?' 0; (exit 77); exit 77],
 321       [], [am_score=1; break])
 322
 323     _AM_CHECK_SHELL_FEATURE([$1],
 324       [can define exit traps in a shell function],
 325       [fail=0 && foo() { trap 'fail=1' 0; } && foo && test $fail = 0],
 326       [], [am_score=1; break])
 327
 328     _AM_CHECK_SHELL_FEATURE([$1],
 329       [corrupts stderr with "set -x"],
 330       [(set -x; P=1 true 2>&3) 3>&1 2>/dev/null | grep P=1],
 331       [am_score=9], [])
 332
 333     echo 'return 34' > conftest-return.sh
 334     echo 'ok=no' >> conftest-return.sh
 335     _AM_CHECK_SHELL_FEATURE([$1],
 336       [can return early from "dot-sourced" files],
 337       [ok=yes; . ./conftest-return.sh; test $? -eq 34 && test $ok = yes],
 338       [rm -f conftest-return.sh],
 339       [rm -f conftest-return.sh; am_score=1; break])
 340
 341     echo 'alias false=echo' > conftest-alias.sh
 342     echo 'false && test "$(false 97)" = 97' >> conftest-alias.sh
 343     _AM_CHECK_SHELL_FEATURE([$1],
 344       [supports alias named like shell builtins],
 345       [. ./conftest-alias.sh],
 346       [rm -f conftest-alias.sh],
 347       [rm -f conftest-alias.sh; am_score=1; break])
 348
 349     _AM_CHECK_SHELL_FEATURE([$1],
 350       [supports "test -e"],
 351       [test -e config.log && test -e . && test ! -e nonesuch],
 352       [], [am_score=1; break])
 353
 354     break
 355   done])
 356
 357 # These messages only goes to the config.log file.
 358 AC_MSG_NOTICE([will now look for a sturdy POSIX shell, for our testsuite])
 359
 360 AC_CACHE_VAL(
 361   [ac_cv_AM_TEST_RUNNER_SHELL],
 362   [if test "$AM_TEST_RUNNER_SHELL"; then
 363     # Let the user override it.
 364     ac_cv_AM_TEST_RUNNER_SHELL=$AM_TEST_RUNNER_SHELL
 365   else
 366     ac_cv_AM_TEST_RUNNER_SHELL=no
 367     am_candidate_shells=${CONFIG_SHELL-}
 368     # For the benefit of Solaris.
 369     am_PATH=$PATH$PATH_SEPARATOR/usr/xpg6/bin$PATH_SEPARATOR/usr/xpg4/bin
 370     for am_sh in sh sh5 dash ash bash zsh ksh pdksh; do
 371       AC_PATH_PROG([am_candidate_sh], [$am_sh], [], [$am_PATH])
 372       if test -n "$am_candidate_sh"; then
 373         am_candidate_shells="$am_candidate_shells $am_candidate_sh"
 374       fi
 375       AM_SUBST_NOTMAKE([am_candidate_sh])
 376       # Must nullify these in order not to interfere with the checks in
 377       # the next loop.
 378       AS_UNSET([am_candidate_sh])
 379       AS_UNSET([ac_cv_path_am_candidate_sh])
 380     done
 381     AS_UNSET([am_PATH]) # Not required anymore
 382     for am_sh in $am_candidate_shells; do
 383       am_score=0
 384       _AM_CHECK_CANDIDATE_SHELL([$am_sh])
 385       if test $am_score -eq 9; then
 386         # The shell is barely acceptable for our needs.  We might
 387         # still find one that is even better, so continue looking.
 388         AC_MSG_NOTICE([shell $am_sh is acceptable, but we might do better])
 389         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 390       elif test $am_score -eq 10; then
 391         AC_MSG_NOTICE([shell $am_sh is good enough, stop looking])
 392         ac_cv_AM_TEST_RUNNER_SHELL=$am_sh
 393         break
 394       fi
 395     done
 396   fi
 397   AM_TEST_RUNNER_SHELL=$ac_cv_AM_TEST_RUNNER_SHELL])
 398
 399 if test $AM_TEST_RUNNER_SHELL = no; then
 400   AC_MSG_FAILURE([m4_normalize([no POSIX shell found that is good
 401                                 enough to be used in our testsuite])])
 402 else
 403   AC_MSG_NOTICE([will use $AM_TEST_RUNNER_SHELL as the testsuite shell])
 404 fi
 405
 406 AC_ARG_VAR([AM_TEST_RUNNER_SHELL],
 407            [a sturdy POSIX shell for our testsuite])
 408
 409
 410 ###########################################################################
 411
 412 # Look for C, C++ and fortran compilers to be used in the testsuite.
 413
 414 dnl We don't want to abort our configuration script if no C compiler is
 415 dnl available, as such a compiler is only required to run part of the
 416 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 417 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 418 dnl easy way to obtain this behaviour, so we'll need a few hacks.
 419
 420 dnl We want the body of this macro to expand as a single shell statement,
 421 dnl thus we wrap it into { ... } brackets.
 422 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 423   AC_MSG_WARN([$1])
 424   am__failed=yes
 425   break
 426 } ])
 427
 428 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 429   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 430   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 431   am__failed=no
 432   while :; do
 433      $1
 434      break
 435   done
 436   AS_IF([test $am__failed = yes], [$2])
 437   # We have to clear these cache variables, so that future checks on
 438   # compilers for different languages won't be confused.
 439   unset ac_cv_objext ac_cv_exeext
 440   # We also need to meddle with the autoconf internals to ensure that
 441   # checks to find object and executable extensions will be run anew.
 442   # FIXME: In the long run, the better thing to do would be to fix
 443   # FIXME: autoconf instead ...
 444   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 445   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 446   m4_popdef([AC_MSG_FAILURE])
 447   m4_popdef([AC_MSG_ERROR])
 448 ])
 449
 450 AC_DEFUN([_AM_SKIP_COMP_TESTS],
 451   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
 452
 453 # Prefer generic compilers to GNU ones when possible.  This will ensure
 454 # more testsuite coverage "in the wild".
 455 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 456 # deliberate; for more discussion and rationale, see:
 457 # <http://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 458
 459 AC_MSG_NOTICE([will now look for generic compilers])
 460
 461 # C compiler.
 462 _AM_COMPILER_CAN_FAIL(dnl
 463   [AC_PROG_CC([cc gcc])],
 464   [CC=false; _AM_SKIP_COMP_TESTS([C])])
 465
 466 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 467
 468 # On case-insensitive file systems (seen e.g. on Cygwin and Mac OS X)
 469 # we must avoid looking for 'CC', because that would be the same as
 470 # 'cc', and could cause $CXX to point to the C compiler, instead of
 471 # to a C++ compiler as expected.  See automake bugs #11893 and #10766.
 472 if test -f /bIn/rMdIr || test -f /uSr/bIn/rMdIr; then
 473   # Case-insensitive file system, don't look for CC.
 474   am_CC=
 475 else
 476   am_CC=CC
 477 fi
 478
 479 # The list of C++ compilers here has been copied, pasted and edited
 480 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 481 # Keep it in sync, or better again, find out a way to avoid this code
 482 # duplication.
 483 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 484   [aCC $am_CC FCC KCC RCC xlC_r xlC c++ cxx cc++ gpp g++])],
 485   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
 486
 487 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 488
 489 # The lists of Fortran compilers here has been copied, pasted and edited
 490 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
 491 # Keep it in sync, or better again, find out a way to avoid this code
 492 # duplication.
 493
 494 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 495   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 496   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
 497   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
 498
 499 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 500
 501 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 502   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
 503   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
 504
 505 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 506
 507 # Some tests will need the GNU compilers.  Searching for them here would
 508 # be overkill, since our testsuite already handles their search and setup
 509 # pretty well.  But in case the compilers already found are the GNU ones,
 510 # we want to use them in the testsuite where GNU compilers are required.
 511 # Also, in case the compilers detected above (at configure time) are not
 512 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
 513 # FFLAGS detected for them with the GNU compilers too, since it's likely
 514 # they won't be compatible.  So we allow the user to define variants of
 515 # these variables for the GNU compilers separately.
 516
 517 AC_MSG_NOTICE([will now look for GNU compilers])
 518
 519 # GNU C compiler.
 520 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
 521 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 522 if test $am_CC_is_GNU = yes; then
 523   AC_MSG_NOTICE([$CC is already a GNU C compiler])
 524   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 525 else
 526   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
 527 fi
 528 if test "$GNU_CC" != false; then
 529   AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
 530         [AC_MSG_WARN([botched installation for GNU C compiler])
 531          _AM_SKIP_COMP_TESTS([GNU C])])
 532 fi
 533
 534 # GNU C++ compiler.
 535 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
 536 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 537 if test $am_CXX_is_GNU = yes; then
 538   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
 539   GNU_CXX=$CXX
 540   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 541 else
 542   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
 543 fi
 544 if test "$GNU_CXX" != false; then
 545   AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
 546         [AC_MSG_WARN([botched installation for GNU C++ compiler])
 547          _AM_SKIP_COMP_TESTS([GNU C++])])
 548 fi
 549
 550 # GNU Fortran compiler.
 551 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
 552 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 553 if test $am_FC_is_GNU = yes; then
 554   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
 555   GNU_FC=$FC
 556   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 557 else
 558   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
 559 fi
 560 if test "$GNU_FC" != false; then
 561   AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
 562         [AC_MSG_WARN([botched installation for GNU Fortran compiler])
 563          _AM_SKIP_COMP_TESTS([GNU Fortran])])
 564 fi
 565
 566 # GNU Fortran 77 compiler.
 567 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
 568 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 569 if test $am_F77_is_GNU = yes; then
 570   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
 571   GNU_F77=$F77
 572   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 573 else
 574   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
 575 fi
 576 if test "$GNU_F77" != false; then
 577   AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
 578         [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
 579         _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
 580 fi
 581
 582 # GNU Java compiler.
 583 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
 584 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
 585 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
 586 if test "$GNU_GCJ" != false; then
 587   AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
 588         [AC_MSG_WARN([botched installation for GNU Java compiler])
 589         _AM_SKIP_COMP_TESTS([GNU Java])])
 590 fi
 591
 592 # If we have been able to find at least a working compiler above, we
 593 # know what the object and executable extensions for this platform are.
 594 OBJEXT=${ac_cv_objext-UNKNOWN}
 595 EXEEXT=${ac_cv_exeext-UNKNOWN}
 596 AC_SUBST([OBJEXT])
 597 AC_SUBST([EXEEXT])
 598
 599 ###########################################################################
 600
 601 ## ---------------------- ##
 602 ##  Create output files.  ##
 603 ## ---------------------- ##
 604
 605 AC_CONFIG_FILES([Makefile])
 606 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 607
 608 AC_CONFIG_FILES([t/wrap/aclocal-${APIVERSION}:t/wrap/aclocal.in],
 609                 [chmod +x t/wrap/aclocal-${APIVERSION}],
 610                 [APIVERSION=$APIVERSION])
 611 AC_CONFIG_FILES([t/wrap/automake-${APIVERSION}:t/wrap/automake.in],
 612                 [chmod +x t/wrap/automake-${APIVERSION}],
 613                 [APIVERSION=$APIVERSION])
 614
 615 AC_OUTPUT
 616
 617 # Inform the user if this version of automake is a beta release or
 618 # a development snapshot.
 619 # According to HACKING, the version of a development snapshot should
 620 # end with an "odd" letter (a, c, ...), the version of a test release
 621 # should end wit an "even" letter (b, d, ...).
 622
 623 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 624 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 625
 626 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 627   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 628   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 629   { print \"development snapshot\"; }"]`
 630
 631 # '$silent' is set to yes if configure is passed the '--quiet' option.
 632 test "$am_release_type" = stable || test "$silent" = yes || cat <<EOF
 633
 634 WARNING: You are about to use a $am_release_type of automake.
 635 WARNING: It might easily suffer from new bugs or regressions.
 636 WARNING: You are strongly advised not to use it in production code.
 637
 638 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>.
 639 EOF
 640
 641 AS_EXIT([0])