configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [4])
   4 m4_define([gst_vaapi_micro_version], [3])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # glib version number
  13 m4_define([glib_major_version], [2])
  14 m4_define([glib_minor_version], [28])
  15 m4_define([glib_micro_version], [0])
  16 m4_define([glib_major_minor_version],
  17           [glib_major_version.glib_minor_version])
  18 m4_define([glib_version],
  19           [glib_major_version.glib_minor_version.glib_micro_version])
  20
  21 # gst version number
  22 m4_define([gst_major_version], [0])
  23 m4_define([gst_minor_version], [10])
  24 m4_define([gst_micro_version], [36])
  25 m4_define([gst_major_minor_version],
  26           [gst_major_version.gst_minor_version])
  27 m4_define([gst_version],
  28           [gst_major_version.gst_minor_version.gst_micro_version])
  29
  30 # gst plugins-base version number
  31 m4_define([gst_plugins_base_major_version], [0])
  32 m4_define([gst_plugins_base_minor_version], [10])
  33 m4_define([gst_plugins_base_micro_version], [31])
  34 m4_define([gst_plugins_base_version],
  35           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  36
  37 # gst plugins-bad version number
  38 m4_define([gst_plugins_bad_major_version], [0])
  39 m4_define([gst_plugins_bad_minor_version], [10])
  40 m4_define([gst_plugins_bad_micro_version], [22])
  41 m4_define([gst_plugins_bad_version],
  42           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
  43
  44 # Wayland minimum version number
  45 m4_define([wayland_api_version], [1.0.0])
  46
  47 # VA-API minimum version number
  48 m4_define([va_api_version],     [0.30.4])
  49 m4_define([va_api_drm_version], [0.33.0])
  50 m4_define([va_api_x11_version], [0.31.0])
  51 m4_define([va_api_glx_version], [0.32.0])
  52 m4_define([va_api_wld_version], [0.33.0])
  53
  54 # libva package version number
  55 m4_define([libva_drm_package_version], [1.1.0])
  56 m4_define([libva_x11_package_version], [1.0.3])
  57 m4_define([libva_glx_package_version], [1.0.9])
  58 m4_define([libva_wld_package_version], [1.1.0])
  59
  60 # gtk-doc version number
  61 # XXX: introspection annotations require gtk-doc >= 1.12
  62 m4_define([gtkdoc_major_version], [1])
  63 m4_define([gtkdoc_minor_version], [9])
  64 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  65
  66 AC_PREREQ([2.58])
  67 AC_INIT([gst_vaapi], [gst_vaapi_version],
  68     [gwenole.beauchesne@intel.com],
  69     [gstreamer-vaapi])
  70
  71 AC_CONFIG_HEADERS([config.h])
  72 AC_CONFIG_SRCDIR([Makefile.am])
  73 AC_CONFIG_MACRO_DIR([m4])
  74 AC_CONFIG_AUX_DIR([build-aux])
  75
  76 AC_CANONICAL_TARGET
  77
  78 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-bzip2])
  79
  80 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  81 AC_SUBST(TODAY)
  82
  83 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
  84 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  85
  86 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  87 AC_SUBST(LIBVA_PACKAGE_VERSION)
  88
  89 WAYLAND_API_VERSION=wayland_api_version
  90 AC_SUBST(WAYLAND_API_VERSION)
  91
  92 dnl Versions for GStreamer and plugins-base
  93 GST_MAJORMINOR=gst_major_minor_version
  94 GST_VERSION_REQUIRED=gst_version
  95 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
  96 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
  97 AC_SUBST(GST_MAJORMINOR)
  98 AC_SUBST(GST_VERSION_REQUIRED)
  99 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
 100 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
 101
 102 dnl Use pretty build output with automake >= 1.11
 103 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
 104   AM_DEFAULT_VERBOSITY=1
 105   AC_SUBST(AM_DEFAULT_VERBOSITY)
 106 ])
 107
 108 dnl Check for tools
 109 AC_PROG_CC
 110 AM_PROG_CC_C_O
 111
 112 dnl Initialize libtool
 113 LT_PREREQ([2.2])
 114 LT_INIT
 115
 116 AC_ARG_ENABLE(drm,
 117     AS_HELP_STRING([--enable-drm],
 118                    [enable DRM backend @<:@default=yes@:>@]),
 119     [], [enable_drm="yes"])
 120
 121 AC_ARG_ENABLE(x11,
 122     AS_HELP_STRING([--enable-x11],
 123                    [enable X11 output @<:@default=yes@:>@]),
 124     [], [enable_x11="yes"])
 125
 126 AC_ARG_ENABLE(glx,
 127     AS_HELP_STRING([--enable-glx],
 128                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
 129     [], [enable_glx="yes"])
 130
 131 AC_ARG_ENABLE(wayland,
 132     AC_HELP_STRING([--enable-wayland],
 133                    [enable Wayland output @<:@default=yes@:>@]),
 134     [], [enable_wayland="yes"])
 135
 136 AC_ARG_ENABLE(encoders,
 137     AC_HELP_STRING([--enable-encoders],
 138                    [enable encoders @<:@default=no@:>@]),
 139     [], [enable_encoders="no"])
 140
 141 dnl Check for basic libraries
 142 AC_CHECK_LIB(m, tan)
 143
 144 dnl Check for Gtk doc
 145 GTKDOC_VERSION=gtkdoc_version
 146 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 147 m4_ifdef([GTK_DOC_CHECK], [
 148 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 149 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 150 AC_SUBST(GTKDOC_VERSION)
 151
 152 dnl Check for GLib
 153 GLIB_VERSION_REQUIRED=glib_version
 154 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 155 AC_SUBST(GLIB_VERSION_REQUIRED)
 156
 157 dnl ---------------------------------------------------------------------------
 158 dnl -- GStreamer                                                             --
 159 dnl ---------------------------------------------------------------------------
 160
 161 dnl GStreamer Core
 162 PKG_CHECK_MODULES([GST],      [gstreamer-$GST_MAJORMINOR >= gst_version])
 163 PKG_CHECK_MODULES([GST_BASE], [gstreamer-base-$GST_MAJORMINOR >= gst_version])
 164
 165 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 166     saved_CFLAGS="$CFLAGS"
 167     CFLAGS="$CFLAGS $GST_BASE_CFLAGS"
 168     saved_LIBS="$LIBS"
 169     LIBS="$LIBS $GST_BASE_LIBS"
 170     AC_COMPILE_IFELSE(
 171         [AC_LANG_PROGRAM(
 172             [[#include <gst/base/gstbasesink.h>]],
 173             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 174         [ac_cv_have_gst_base_sink_query="yes"],
 175         [ac_cv_have_gst_base_sink_query="no"]
 176     )
 177     CFLAGS="$saved_CFLAGS"
 178     LIBS="$saved_LIBS"
 179 ])
 180 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 181     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 182 fi
 183
 184 dnl GStreamer -base plugins
 185 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 186     [gstreamer-plugins-base-$GST_MAJORMINOR >= gst_plugins_base_version])
 187 PKG_CHECK_MODULES([GST_INTERFACES],
 188     [gstreamer-interfaces-$GST_MAJORMINOR >= gst_plugins_base_version])
 189
 190 dnl ... GstVideoOverlayComposition (gstreamer-video)
 191 PKG_CHECK_MODULES([GST_VIDEO],
 192     [gstreamer-video-$GST_MAJORMINOR >= gst_plugins_base_version])
 193
 194 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 195     ac_cv_have_gst_video_overlay_composition, [
 196     saved_CFLAGS="$CFLAGS"
 197     CFLAGS="$CFLAGS $GST_CFLAGS"
 198     saved_LIBS="$LIBS"
 199     LIBS="$LIBS $GST_LIBS"
 200     AC_COMPILE_IFELSE(
 201         [AC_LANG_PROGRAM(
 202             [[#include <gst/video/video-overlay-composition.h>]],
 203             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
 204         [ac_cv_have_gst_video_overlay_composition="yes"],
 205         [ac_cv_have_gst_video_overlay_composition="no"]
 206     )
 207     CFLAGS="$saved_CFLAGS"
 208     LIBS="$saved_LIBS"
 209 ])
 210 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 211     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 212 fi
 213
 214 dnl GStreamer -bad plugins
 215 PKG_CHECK_MODULES([GST_BASEVIDEO],
 216     [gstreamer-basevideo-$GST_MAJORMINOR >= gst_plugins_bad_version])
 217
 218 dnl ... bitstream parsers
 219 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 220     [gstreamer-codecparsers-$GST_MAJORMINOR >= gst_plugins_bad_version])
 221
 222 dnl ... MPEG-2 parser, with the required extensions
 223 AC_CACHE_CHECK([for MPEG-2 parser],
 224     ac_cv_have_gst_mpeg2_parser, [
 225     saved_CPPFLAGS="$CPPFLAGS"
 226     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 227     saved_LIBS="$LIBS"
 228     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 229     AC_COMPILE_IFELSE(
 230         [AC_LANG_PROGRAM(
 231             [[#include <gst/codecparsers/gstmpegvideoparser.h>]],
 232             [[GstMpegVideoSequenceHdr seq_hdr;
 233               GstMpegVideoSequenceExt seq_ext;
 234               GstMpegVideoSequenceDisplayExt seq_dpy;
 235               gst_mpeg_video_finalise_mpeg2_sequence_header(&seq_hdr,
 236                   &seq_ext, &seq_dpy);]])],
 237         [ac_cv_have_gst_mpeg2_parser="yes"],
 238         [ac_cv_have_gst_mpeg2_parser="no"]
 239     )
 240     CPPFLAGS="$saved_CPPFLAGS"
 241     LIBS="$saved_LIBS"
 242 ])
 243 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_MPEG2],
 244     [test "$ac_cv_have_gst_mpeg2_parser" != "yes"])
 245
 246 dnl ... H.264 parser, with the required extensions
 247 AC_CACHE_CHECK([for H.264 parser],
 248     ac_cv_have_gst_h264_parser, [
 249     saved_CPPFLAGS="$CPPFLAGS"
 250     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 251     saved_LIBS="$LIBS"
 252     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 253     AC_COMPILE_IFELSE(
 254         [AC_LANG_PROGRAM(
 255             [[#include <gst/codecparsers/gsth264parser.h>]],
 256             [[GstH264SliceHdr slice_hdr;
 257               GstH264VUIParams vui_params;
 258               slice_hdr.n_emulation_prevention_bytes = 0;
 259               vui_params.par_n = 0;
 260               vui_params.par_d = 0;]])],
 261         [ac_cv_have_gst_h264_parser="yes"],
 262         [ac_cv_have_gst_h264_parser="no"]
 263     )
 264     CPPFLAGS="$saved_CPPFLAGS"
 265     LIBS="$saved_LIBS"
 266 ])
 267 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_H264],
 268     [test "$ac_cv_have_gst_h264_parser" != "yes"])
 269
 270 dnl ... JPEG parser, not upstream yet
 271 AC_CACHE_CHECK([for JPEG parser],
 272     ac_cv_have_gst_jpeg_parser, [
 273     saved_CPPFLAGS="$CPPFLAGS"
 274     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 275     saved_LIBS="$LIBS"
 276     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 277     AC_COMPILE_IFELSE(
 278         [AC_LANG_PROGRAM(
 279             [[#include <gst/codecparsers/gstjpegparser.h>]],
 280             [[GstJpegImage jpeg_image;]])],
 281         [ac_cv_have_gst_jpeg_parser="yes"],
 282         [ac_cv_have_gst_jpeg_parser="no"]
 283     )
 284     CPPFLAGS="$saved_CPPFLAGS"
 285     LIBS="$saved_LIBS"
 286 ])
 287 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_JPEG],
 288     [test "$ac_cv_have_gst_jpeg_parser" != "yes"])
 289
 290 dnl GST_ALL_LDFLAGS:
 291 dnl LDFLAGS really should only contain flags, not libs - they get added before
 292 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 293 GST_ALL_LDFLAGS="-no-undefined"
 294 AC_SUBST(GST_ALL_LDFLAGS)
 295
 296 dnl GST_PLUGIN_LDFLAGS:
 297 dnl this really should only contain flags, not libs - they get added before
 298 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 299 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 300 AC_SUBST(GST_PLUGIN_LDFLAGS)
 301
 302 dnl Check for the GStreamer plugins directory
 303 AC_ARG_VAR([GST_PLUGIN_PATH], [installation path for gstreamer-vaapi plugin elements])
 304 AC_MSG_CHECKING([for GStreamer plugins directory])
 305 if test -d "$GST_PLUGIN_PATH"; then
 306     GST_PLUGINS_DIR="$GST_PLUGIN_PATH"
 307 else
 308     GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 309     if test -z "$GST_PLUGINS_DIR"; then
 310         GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 311     fi
 312 fi
 313 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 314 plugindir="$GST_PLUGINS_DIR"
 315 AC_SUBST(plugindir)
 316
 317 dnl ---------------------------------------------------------------------------
 318 dnl -- Renderers                                                             --
 319 dnl ---------------------------------------------------------------------------
 320
 321 dnl Check for DRM/libudev
 322 USE_DRM=0
 323 if test "$enable_drm" = "yes"; then
 324     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
 325     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
 326
 327     if test $USE_DRM -eq 1; then
 328         saved_CPPFLAGS="$CPPFLAGS"
 329         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 330         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
 331         CPPFLAGS="$saved_CPPFLAGS"
 332     fi
 333 fi
 334
 335 dnl Check for X11
 336 USE_X11=0
 337 if test "$enable_x11" = "yes"; then
 338     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 339     if test $USE_X11 -eq 1; then
 340         saved_CPPFLAGS="$CPPFLAGS"
 341         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 342         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 343         CPPFLAGS="$saved_CPPFLAGS"
 344     fi
 345 fi
 346
 347 dnl Check for XRandR
 348 HAVE_XRANDR=0
 349 if test $USE_X11 -eq 1; then
 350     HAVE_XRANDR=1
 351     PKG_CHECK_MODULES([XRANDR], [xrandr], [:], [HAVE_XRANDR=0])
 352     if test $HAVE_XRANDR -eq 1; then
 353         saved_CPPFLAGS="$CPPFLAGS"
 354         CPPFLAGS="$CPPFLAGS $XRANDR_CFLAGS"
 355         AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [:], [HAVE_XRANDR=0])
 356         CPPFLAGS="$saved_CPPFLAGS"
 357     fi
 358 fi
 359 if test $HAVE_XRANDR -eq 1; then
 360     AC_DEFINE_UNQUOTED(HAVE_XRANDR, 1,
 361         [Defined to 1 if the XRandR extension exists.])
 362 fi
 363
 364 dnl OpenGL
 365 enable_opengl="no"
 366 if test "$enable_glx" = "yes"; then
 367     enable_opengl="yes"
 368 fi
 369
 370 HAVE_GL=0
 371 if test "$enable_opengl" = "yes"; then
 372     HAVE_GL=1
 373     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 374     saved_CPPFLAGS="$CPPFLAGS"
 375     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 376     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 377 #ifdef HAVE_GL_GL_H
 378 # include <GL/gl.h>
 379 #endif
 380     ])
 381     CPPFLAGS="$saved_CPPFLAGS"
 382 fi
 383
 384 dnl Check for encoders
 385 USE_ENCODERS=0
 386 if test "$enable_encoders" = "yes"; then
 387     USE_ENCODERS=1
 388 fi
 389
 390 AC_DEFINE_UNQUOTED(USE_ENCODERS, $USE_ENCODERS,
 391     [Defined to 1 if GStreamer Vaapi Encoder are used])
 392 AM_CONDITIONAL(USE_ENCODERS, test $USE_ENCODERS -eq 1)
 393
 394 dnl ... GLX
 395 USE_GLX=0
 396 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 397     USE_GLX=1
 398     saved_CPPFLAGS="$CPPFLAGS"
 399     saved_LIBS="$LIBS"
 400     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 401     LIBS="$LIBS $GL_LIBS"
 402     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 403 #ifdef HAVE_GL_GL_H
 404 # include <GL/gl.h>
 405 #endif
 406     ])
 407     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 408     CPPFLAGS="$saved_CPPFLAGS"
 409     LIBS="$saved_LIBS"
 410 fi
 411
 412 dnl Check for Wayland
 413 USE_WAYLAND=0
 414 if test "$enable_wayland" = "yes"; then
 415     PKG_CHECK_MODULES(WAYLAND, [wayland-client >= wayland_api_version],
 416         [USE_WAYLAND=1], [USE_WAYLAND=0])
 417
 418     if test $USE_WAYLAND -eq 1; then
 419         saved_CPPFLAGS="$CPPFLAGS"
 420         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 421         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
 422         CPPFLAGS="$saved_CPPFLAGS"
 423     fi
 424 fi
 425
 426 dnl ---------------------------------------------------------------------------
 427 dnl -- VA-API                                                                --
 428 dnl ---------------------------------------------------------------------------
 429
 430 dnl Core API
 431 LIBVA_PKGNAME="libva"
 432 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 433 AC_SUBST(LIBVA_PKGNAME)
 434
 435 VA_VERSION=`$PKG_CONFIG --modversion libva`
 436 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 437 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 438 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 439 VA_VERSION_STR="$VA_VERSION"
 440
 441 dnl VA/DRM API
 442 HAVE_VA_DRM=0
 443 if test $USE_DRM -eq 1; then
 444     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
 445         [HAVE_VA_DRM=1], [USE_DRM=0])
 446
 447     if test $HAVE_VA_DRM -eq 1; then
 448         saved_CPPFLAGS="$CPPFLAGS"
 449         CPPFLAGS="$LIBVA_DRM_CFLAGS"
 450         AC_CHECK_HEADERS([va/va_drm.h], [:], [HAVE_VA_DRM=0 USE_DRM=0])
 451         CPPFLAGS="$saved_CPPFLAGS"
 452     fi
 453 fi
 454
 455 dnl VA/X11 API
 456 HAVE_VA_X11=0
 457 LIBVA_X11_PKGNAME="libva-x11"
 458 if test $USE_X11 -eq 1; then
 459     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 460         [HAVE_VA_X11=1], [USE_X11=0])
 461 fi
 462 AC_SUBST(LIBVA_X11_PKGNAME)
 463
 464 dnl VA/GLX API
 465 HAVE_VA_GLX=0
 466 LIBVA_GLX_PKGNAME="libva-glx"
 467 if test $USE_GLX -eq 1; then
 468     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
 469         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
 470
 471     if test $HAVE_VA_GLX -eq 1; then
 472         saved_CPPFLAGS="$CPPFLAGS"
 473         CPPFLAGS="$LIBVA_GLX_CFLAGS"
 474         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
 475         CPPFLAGS="$saved_CPPFLAGS"
 476     fi
 477 fi
 478 AC_SUBST(LIBVA_GLX_PKGNAME)
 479
 480 dnl Check for JPEG decoding API (0.32.1+)
 481 USE_JPEG_DECODER=0
 482 AC_CACHE_CHECK([for JPEG decoding API],
 483     ac_cv_have_jpeg_decoding_api, [
 484     saved_CFLAGS="$CFLAGS"
 485     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 486     saved_LIBS="$LIBS"
 487     LIBS="$CFLAGS $LIBVA_LIBS"
 488     AC_COMPILE_IFELSE(
 489         [AC_LANG_PROGRAM(
 490             [[#include <va/va.h>]],
 491             [[VAPictureParameterBufferJPEGBaseline pic_param;
 492               VASliceParameterBufferJPEGBaseline slice_param;
 493               VAHuffmanTableBufferJPEGBaseline huffman_table;
 494               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
 495         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 496         [ac_cv_have_jpeg_decoding_api="no"]
 497     )
 498     CFLAGS="$saved_CFLAGS"
 499     LIBS="$saved_LIBS"
 500 ])
 501
 502 dnl Check libva old H.264 encoder API
 503 HAVE_OLD_H264_ENCODER=0
 504 AC_CACHE_CHECK([for H264 encoder old structures],
 505     ac_cv_have_old_h264_encoder, [
 506         saved_CFLAGS="$CFLAGS"
 507         CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 508         saved_LIBS="$LIBS"
 509         LIBS="$CFLAGS $LIBVA_LIBS"
 510     AC_COMPILE_IFELSE(
 511         [AC_LANG_PROGRAM(
 512             [[#include <va/va_enc_h264.h>]],
 513             [[VAEncSequenceParameterBufferH264 seq;
 514               seq.seq_fields.value = 0;
 515                           seq.vui_fields.value = 0;]])],
 516         [ac_cv_have_old_h264_encoder="no" HAVE_OLD_H264_ENCODER=0],
 517         [ac_cv_have_old_h264_encoder="yes" HAVE_OLD_H264_ENCODER=1]
 518     )
 519     CFLAGS="$saved_CFLAGS"
 520     LIBS="$saved_LIBS"
 521 ])
 522
 523 AC_DEFINE_UNQUOTED(HAVE_OLD_H264_ENCODER, $HAVE_OLD_H264_ENCODER,
 524     [Defined to 1 if old h264 encoder API exists.])
 525
 526 dnl Check for vpp (video post-processing) support
 527 HAVE_VA_VPP=1
 528 saved_CFLAGS="$CFLAGS"
 529 CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 530 AC_CHECK_HEADERS([va/va_vpp.h], [:], [HAVE_VA_VPP=0],
 531                  [[#include <va/va.h>
 532                    #include <va/va_vpp.h>]])
 533 CFLAGS="$saved_CFLAGS"
 534
 535 dnl VA/Wayland API
 536 if test "$enable_wayland" = "yes"; then
 537     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
 538         [:], [USE_WAYLAND=0])
 539 fi
 540
 541 dnl ---------------------------------------------------------------------------
 542 dnl -- Generate files and summary                                            --
 543 dnl ---------------------------------------------------------------------------
 544
 545 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
 546 *:1:*)
 547     ;;
 548 *)
 549     AC_MSG_ERROR([No renderer is enabled])
 550     ;;
 551 esac
 552
 553 AC_DEFINE_UNQUOTED(USE_VA_VPP, $HAVE_VA_VPP,
 554     [Defined to 1 if video post-processing is used])
 555 AM_CONDITIONAL(USE_VA_VPP, test $HAVE_VA_VPP -eq 1)
 556
 557 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 558     [Defined to 1 if JPEG decoder is used])
 559 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 560
 561 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
 562     [Defined to 1 if DRM is enabled])
 563 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
 564
 565 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 566     [Defined to 1 if X11 is enabled])
 567 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 568
 569 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 570     [Defined to 1 if GLX is enabled])
 571 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 572
 573 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
 574     [Defined to 1 if WAYLAND is enabled])
 575 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
 576
 577 pkgconfigdir=${libdir}/pkgconfig
 578 AC_SUBST(pkgconfigdir)
 579
 580 AC_CONFIG_FILES([
 581     Makefile
 582     debian.upstream/Makefile
 583     debian.upstream/changelog
 584     debian.upstream/control
 585     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 586 debian.upstream/gstreamer-vaapi-doc.install.in
 587     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 588 debian.upstream/gstreamer-vaapi.install.in
 589     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 590 debian.upstream/libgstvaapi.install.in
 591     debian.upstream/libgstvaapi-dev.install
 592     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
 593 debian.upstream/libgstvaapi-drm.install.in
 594     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 595 debian.upstream/libgstvaapi-glx.install.in
 596     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
 597 debian.upstream/libgstvaapi-wayland.install.in
 598     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 599 debian.upstream/libgstvaapi-x11.install.in
 600     docs/Makefile
 601     docs/reference/Makefile
 602     docs/reference/libs/Makefile
 603     docs/reference/libs/libs-docs.xml
 604     docs/reference/plugins/Makefile
 605     docs/reference/plugins/plugins-docs.xml
 606     ext/Makefile
 607     gst-libs/Makefile
 608     gst-libs/gst/Makefile
 609     gst-libs/gst/codecparsers/Makefile
 610     gst-libs/gst/vaapi/Makefile
 611     gst/Makefile
 612     gst/vaapi/Makefile
 613     pkgconfig/Makefile
 614     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 615 pkgconfig/gstreamer-vaapi.pc.in
 616     pkgconfig/gstreamer-vaapi-drm-$GST_MAJORMINOR.pc:\
 617 pkgconfig/gstreamer-vaapi-drm.pc.in
 618     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 619 pkgconfig/gstreamer-vaapi-glx.pc.in
 620     pkgconfig/gstreamer-vaapi-wayland-$GST_MAJORMINOR.pc:\
 621 pkgconfig/gstreamer-vaapi-wayland.pc.in
 622     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 623 pkgconfig/gstreamer-vaapi-x11.pc.in
 624     tests/Makefile
 625 ])
 626 AC_OUTPUT
 627
 628 dnl Print summary
 629 yesno() {
 630     test $1 -eq 1 && echo yes || echo no
 631 }
 632
 633 VIDEO_OUTPUTS=""
 634 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
 635 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
 636 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
 637 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
 638
 639 echo
 640 echo $PACKAGE configuration summary:
 641 echo
 642 echo VA-API version ................... : $VA_VERSION_STR
 643 echo Video outputs .................... : $VIDEO_OUTPUTS
 644 echo VaapiEncoder support....... ...... : $(yesno $USE_ENCODERS)
 645 echo