configure.ac

   1 m4_define([weston_major_version], [4])
   2 m4_define([weston_minor_version], [0])
   3 m4_define([weston_micro_version], [90])
   4 m4_define([weston_version],
   5           [weston_major_version.weston_minor_version.weston_micro_version])
   6 m4_define([libweston_major_version], [5])
   7 m4_define([libweston_minor_version], [0])
   8 m4_define([libweston_patch_version], [0])
   9
  10 AC_PREREQ([2.64])
  11 AC_INIT([weston],
  12         [weston_version],
  13         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=weston&version=weston_version],
  14         [weston],
  15         [http://wayland.freedesktop.org])
  16
  17 WAYLAND_PREREQ_VERSION="1.12.0"
  18
  19 AC_SUBST([WESTON_VERSION_MAJOR], [weston_major_version])
  20 AC_SUBST([WESTON_VERSION_MINOR], [weston_minor_version])
  21 AC_SUBST([WESTON_VERSION_MICRO], [weston_micro_version])
  22 AC_SUBST([WESTON_VERSION], [weston_version])
  23 AC_SUBST([LIBWESTON_MAJOR], [libweston_major_version])
  24 # We use minor as current and age since on ABI/API break/removal we bump major
  25 # so minor will be reset to 0.
  26 m4_define([lt_current], [libweston_minor_version])
  27 m4_define([lt_revision], [libweston_patch_version])
  28 m4_define([lt_age], [libweston_minor_version])
  29 AC_SUBST([LT_VERSION_INFO], [lt_current:lt_revision:lt_age])
  30
  31 AC_CONFIG_AUX_DIR([build-aux])
  32 AC_CONFIG_HEADERS([config.h])
  33 AC_CONFIG_MACRO_DIR([m4])
  34
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_SYS_LARGEFILE
  37
  38 save_CFLAGS="$CFLAGS"
  39 export CFLAGS="$CFLAGS -Werror"
  40 AC_HEADER_MAJOR
  41 CFLAGS="$save_CFLAGS"
  42
  43 AM_INIT_AUTOMAKE([1.11 parallel-tests foreign no-dist-gzip dist-xz color-tests subdir-objects])
  44
  45 AM_SILENT_RULES([yes])
  46
  47 # Check Weston and libweston version consistency
  48 m4_if(m4_cmp(weston_micro_version, [90]), [-1],
  49       [
  50         dnl micro < 90
  51         dnl A final or stable release, not a pre-release:
  52         dnl Weston and libweston versions must match.
  53         m4_if(weston_version, libweston_major_version[.]libweston_minor_version[.]libweston_patch_version,
  54               [],
  55               [AC_MSG_ERROR([Weston and libweston version mismatch for a final release])])
  56       ],
  57       [
  58         dnl A pre-release:
  59         dnl libweston must be equal or greater than weston.
  60         m4_case(m4_list_cmp([weston_major_version, weston_minor_version, weston_micro_version],
  61                              [libweston_major_version, libweston_minor_version, libweston_patch_version]),
  62                  [-1], [
  63                         dnl weston < libweston
  64                         dnl libweston must be weston_major+1.0.0
  65                         m4_if(m4_eval(weston_major_version+1)[.0.0],
  66                               libweston_major_version[.]libweston_minor_version[.]libweston_patch_version,
  67                               [],
  68                               [AC_MSG_ERROR([libweston version is greater but not (weston_major+1).0.0])])
  69                  ],
  70                  [0], [
  71                         dnl weston == libweston, all ok
  72                  ],
  73                  [1], [
  74                         dnl weston > libweston, wrong
  75                         AC_MSG_ERROR([Weston version is greater than libweston.])
  76                  ])
  77        ])
  78
  79 # Check for programs
  80 AC_PROG_CC
  81 AC_PROG_SED
  82
  83 # Initialize libtool
  84 LT_PREREQ([2.2])
  85 LT_INIT([disable-static])
  86
  87 AC_ARG_VAR([WESTON_NATIVE_BACKEND],
  88            [Set the native backend to use, if Weston is not running under Wayland nor X11. @<:@default=drm-backend.so@:>@])
  89 AC_ARG_VAR([WESTON_SHELL_CLIENT],
  90            [Set the default desktop shell client to load if none is specified in weston.ini. @<:@default=weston-desktop-shell@:>@])
  91
  92 PKG_PROG_PKG_CONFIG()
  93
  94 # Check for dlsym instead of dlopen because ASAN hijacks the latter
  95 WESTON_SEARCH_LIBS([DL], [dl], [dlsym])
  96
  97 # In old glibc versions (< 2.17) clock_gettime() and clock_getres() are in librt
  98 WESTON_SEARCH_LIBS([CLOCK_GETTIME], [rt], [clock_gettime])
  99 WESTON_SEARCH_LIBS([CLOCK_GETRES], [rt], [clock_getres])
 100
 101 AC_CHECK_DECL(SFD_CLOEXEC,[],
 102               [AC_MSG_ERROR("SFD_CLOEXEC is needed to compile weston")],
 103               [[#include <sys/signalfd.h>]])
 104 AC_CHECK_DECL(TFD_CLOEXEC,[],
 105               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile weston")],
 106               [[#include <sys/timerfd.h>]])
 107 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
 108               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile weston")],
 109               [[#include <time.h>]])
 110 AC_CHECK_HEADERS([execinfo.h])
 111
 112 AC_CHECK_FUNCS([mkostemp strchrnul initgroups posix_fallocate])
 113
 114 # check for libdrm as a build-time dependency only
 115 # libdrm 2.4.30 introduced drm_fourcc.h.
 116 PKG_CHECK_MODULES(LIBDRM, [libdrm >= 2.4.30], [], [AC_MSG_ERROR([
 117      libdrm is a hard build-time dependency for libweston core,
 118      but a sufficient version was not found. However, libdrm
 119      is not a runtime dependency unless you have features
 120      enabled that require it.])])
 121
 122 COMPOSITOR_MODULES="wayland-server >= $WAYLAND_PREREQ_VERSION pixman-1 >= 0.25.2"
 123
 124 AC_CONFIG_FILES([doc/doxygen/tools.doxygen doc/doxygen/tooldev.doxygen])
 125
 126 AC_ARG_ENABLE(devdocs,
 127               AS_HELP_STRING([--disable-devdocs],
 128                              [do not enable building of developer documentation]),,
 129               enable_devdocs=auto)
 130 if test "x$enable_devdocs" != "xno"; then
 131         AC_CHECK_PROGS([DOXYGEN], [doxygen])
 132         if test "x$DOXYGEN" = "x" -a "x$enable_devdocs" = "xyes"; then
 133                 AC_MSG_ERROR([Developer documentation explicitly requested, but Doxygen couldn't be found])
 134         fi
 135         if test "x$DOXYGEN" != "x"; then
 136                 enable_devdocs=yes
 137         else
 138                 enable_devdocs=no
 139         fi
 140 fi
 141 AM_CONDITIONAL(ENABLE_DEVDOCS, test "x$enable_devdocs" = "xyes")
 142
 143 AC_ARG_ENABLE(egl, [  --disable-egl],,
 144               enable_egl=yes)
 145 AM_CONDITIONAL(ENABLE_EGL, test x$enable_egl = xyes)
 146 if test x$enable_egl = xyes; then
 147         AC_DEFINE([ENABLE_EGL], [1], [Build Weston with EGL support])
 148         PKG_CHECK_MODULES(EGL, [egl glesv2])
 149         PKG_CHECK_MODULES([EGL_TESTS], [egl glesv2 wayland-client wayland-egl])
 150         AC_CHECK_HEADERS([linux/sync_file.h])
 151 fi
 152
 153 COMPOSITOR_MODULES="$COMPOSITOR_MODULES xkbcommon >= 0.3.0"
 154
 155 PKG_CHECK_MODULES(XKBCOMMON_COMPOSE, [xkbcommon >= 0.5.0],
 156                   [AC_DEFINE(HAVE_XKBCOMMON_COMPOSE, 1,
 157                      [Define if xkbcommon is 0.5.0 or newer])],true)
 158
 159 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
 160               enable_setuid_install=yes)
 161 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
 162
 163
 164 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
 165               enable_xwayland=yes)
 166 AC_ARG_ENABLE(xwayland-test, [  --enable-xwayland-test],,
 167               enable_xwayland_test=yes)
 168 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
 169 AM_CONDITIONAL(ENABLE_XWAYLAND_TEST, test x$enable_xwayland = xyes -a x$enable_xwayland_test = xyes)
 170 if test x$enable_xwayland = xyes; then
 171   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcb-composite xcb-shape xcursor cairo-xcb)
 172   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
 173
 174   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
 175               [Path to X server]), [XSERVER_PATH="$withval"],
 176               [XSERVER_PATH="/usr/bin/Xwayland"])
 177   AC_SUBST([XSERVER_PATH])
 178   if test x$enable_xwayland_test = xyes; then
 179     PKG_CHECK_MODULES([XWAYLAND_TEST], x11)
 180   fi
 181 fi
 182
 183 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
 184               enable_x11_compositor=yes)
 185 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
 186 have_xcb_xkb=no
 187 if test x$enable_x11_compositor = xyes; then
 188   PKG_CHECK_MODULES([XCB], xcb >= 1.8)
 189   X11_COMPOSITOR_MODULES="x11 x11-xcb xcb-shm"
 190
 191   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb >= 1.9],
 192                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
 193   if test "x$have_xcb_xkb" = xyes; then
 194         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
 195         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
 196   fi
 197
 198   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
 199   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
 200 fi
 201
 202
 203 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
 204               enable_drm_compositor=yes)
 205 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes)
 206 if test x$enable_drm_compositor = xyes; then
 207   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
 208   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm])
 209   PKG_CHECK_MODULES(DRM_COMPOSITOR_ATOMIC, [libdrm >= 2.4.78],
 210                     [AC_DEFINE([HAVE_DRM_ATOMIC], 1, [libdrm supports atomic API])],
 211                     [AC_MSG_WARN([libdrm does not support atomic modesetting, will omit that capability])])
 212   PKG_CHECK_MODULES(DRM_COMPOSITOR_GBM, [gbm >= 10.2],
 213                     [AC_DEFINE([HAVE_GBM_FD_IMPORT], 1, [gbm supports dmabuf import])],
 214                     [AC_MSG_WARN([gbm does not support dmabuf import, will omit that capability])])
 215 fi
 216
 217
 218 PKG_CHECK_MODULES(LIBINPUT_BACKEND, [libinput >= 0.8.0])
 219 PKG_CHECK_MODULES(COMPOSITOR, [$COMPOSITOR_MODULES])
 220
 221 PKG_CHECK_MODULES(WAYLAND_PROTOCOLS, [wayland-protocols >= 1.13],
 222                   [ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`])
 223 AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
 224
 225 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 226               enable_wayland_compositor=yes)
 227 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 228                test x$enable_wayland_compositor = xyes)
 229 if test x$enable_wayland_compositor = xyes; then
 230   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 231             [Build the Wayland (nested) compositor])
 232   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client >= $WAYLAND_PREREQ_VERSION wayland-cursor])
 233   if test x$enable_egl = xyes; then
 234     PKG_CHECK_MODULES(WAYLAND_COMPOSITOR_EGL, [wayland-egl])
 235   fi
 236 fi
 237
 238
 239 AC_ARG_ENABLE(headless-compositor, [  --enable-headless-compositor],,
 240               enable_headless_compositor=yes)
 241 AM_CONDITIONAL(ENABLE_HEADLESS_COMPOSITOR,
 242                test x$enable_headless_compositor = xyes)
 243 if test x$enable_headless_compositor = xyes; then
 244   AC_DEFINE([BUILD_HEADLESS_COMPOSITOR], [1], [Build the headless compositor])
 245 fi
 246
 247
 248 AC_ARG_ENABLE([fbdev-compositor], [  --enable-fbdev-compositor],,
 249               enable_fbdev_compositor=yes)
 250 AM_CONDITIONAL([ENABLE_FBDEV_COMPOSITOR],
 251                [test x$enable_fbdev_compositor = xyes])
 252 AS_IF([test x$enable_fbdev_compositor = xyes], [
 253   AC_DEFINE([BUILD_FBDEV_COMPOSITOR], [1], [Build the fbdev compositor])
 254   PKG_CHECK_MODULES([FBDEV_COMPOSITOR], [libudev >= 136])
 255 ])
 256
 257 AC_ARG_ENABLE([rdp-compositor], [  --enable-rdp-compositor],,
 258               enable_rdp_compositor=no)
 259 AM_CONDITIONAL([ENABLE_RDP_COMPOSITOR],
 260                [test x$enable_rdp_compositor = xyes])
 261 if test x$enable_rdp_compositor = xyes; then
 262   AC_DEFINE([BUILD_RDP_COMPOSITOR], [1], [Build the RDP compositor])
 263   PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp2 >= 2.0.0],
 264     [],
 265     [PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp >= 1.1.0],[])]
 266   )
 267
 268   SAVED_CPPFLAGS="$CPPFLAGS"
 269   CPPFLAGS="$CPPFLAGS $RDP_COMPOSITOR_CFLAGS"
 270   AC_CHECK_HEADERS([freerdp/version.h])
 271   CPPFLAGS="$SAVED_CPPFLAGS"
 272 fi
 273
 274 AC_ARG_ENABLE([screen-sharing], [  --enable-screen-sharing],,
 275               enable_screen_sharing=no)
 276 AM_CONDITIONAL([ENABLE_SCREEN_SHARING],
 277                [test x$enable_screen_sharing = xyes])
 278 if test x$enable_screen_sharing = xyes; then
 279   PKG_CHECK_MODULES(SCREEN_SHARE, [wayland-client])
 280
 281   if test x$enable_rdp_compositor != xyes; then
 282     AC_MSG_WARN([The screen-share.so module requires the RDP backend.])
 283   fi
 284 fi
 285
 286 AC_ARG_WITH(cairo,
 287             AS_HELP_STRING([--with-cairo=@<:@image|gl|glesv2@:>@]
 288                            [Which Cairo renderer to use for the clients]),
 289                            [],[with_cairo="image"])
 290
 291 if test "x$with_cairo" = "ximage"; then
 292         cairo_modules="cairo"
 293 else
 294 if test "x$with_cairo" = "xgl"; then
 295         cairo_modules="cairo-gl"
 296         AC_MSG_WARN([The --with-cairo=gl option can cause increased resource usage and potential instability, and thus is not recommended.  It is needed only for a few special demo programs.])
 297 else
 298 if test "x$with_cairo" = "xglesv2"; then
 299         cairo_modules="cairo-glesv2"
 300         AC_MSG_WARN([The --with-cairo=gles2 option can cause increased resource usage and potential instability, and thus is not recommended.  It is needed only for a few special demo programs.])
 301 else
 302         AC_ERROR([Unknown cairo renderer requested])
 303 fi
 304 fi
 305 fi
 306
 307 # Included for legacy compat
 308 AC_ARG_WITH(cairo-glesv2,
 309             AS_HELP_STRING([--with-cairo-glesv2],
 310                            [Use GLESv2 cairo]))
 311 if test "x$with_cairo_glesv2" = "xyes"; then
 312   cairo_modules="cairo-glesv2"
 313   with_cairo="glesv2"
 314 fi
 315
 316 if test "x$cairo_modules" = "xcairo-glesv2"; then
 317 AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 318 fi
 319
 320 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 321 PKG_CHECK_MODULES(PNG, [libpng])
 322
 323 AC_ARG_WITH([jpeg],
 324             AS_HELP_STRING([--without-jpeg],
 325                            [Use jpeglib for JPEG decoding support [default=auto]]))
 326 AS_IF([test "x$with_jpeg" != "xno"],
 327       [WESTON_SEARCH_LIBS([JPEG], [jpeg], [jpeg_CreateDecompress], [have_jpeglib=yes], [have_jpeglib=no])],
 328       [have_jpeglib=no])
 329 AS_IF([test "x$have_jpeglib" = "xyes"],
 330       [AC_DEFINE([HAVE_JPEG], [1], [Have jpeglib])],
 331       [AS_IF([test "x$with_jpeg" = "xyes"],
 332              [AC_MSG_ERROR([JPEG support explicitly requested, but jpeglib couldn't be found])])])
 333
 334 AC_ARG_WITH([webp],
 335             AS_HELP_STRING([--without-webp],
 336                            [Use libwebp for WebP decoding support [default=auto]]))
 337 AS_IF([test "x$with_webp" != "xno"],
 338       [PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])],
 339       [have_webp=no])
 340 AS_IF([test "x$have_webp" = "xyes"],
 341       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])],
 342       [AS_IF([test "x$with_webp" = "xyes"],
 343              [AC_MSG_ERROR([WebP support explicitly requested, but libwebp couldn't be found])])])
 344
 345 AC_ARG_ENABLE(vaapi-recorder, [  --enable-vaapi-recorder],,
 346               enable_vaapi_recorder=auto)
 347 have_libva=no
 348 if test x$enable_vaapi_recorder != xno; then
 349   PKG_CHECK_MODULES(LIBVA, [libva >= 0.34.0 libva-drm >= 0.34.0],
 350                     [have_libva=yes], [have_libva=no])
 351   if test "x$have_libva" = "xno" -a "x$enable_vaapi_recorder" = "xyes"; then
 352     AC_MSG_ERROR([vaapi-recorder explicitly enabled, but libva couldn't be found])
 353   fi
 354   AS_IF([test "x$have_libva" = "xyes"],
 355         [AC_DEFINE([BUILD_VAAPI_RECORDER], [1], [Build the vaapi recorder])])
 356 fi
 357 AM_CONDITIONAL(ENABLE_VAAPI_RECORDER, test "x$have_libva" = xyes)
 358
 359 PKG_CHECK_MODULES(CAIRO, [cairo])
 360
 361 PKG_CHECK_MODULES(TEST_CLIENT, [wayland-client >= $WAYLAND_PREREQ_VERSION pixman-1])
 362
 363 AC_ARG_ENABLE(simple-clients,
 364               AS_HELP_STRING([--disable-simple-clients],
 365                              [do not build the simple wl_shm clients]),,
 366               enable_simple_clients=yes)
 367 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 368 if test x$enable_simple_clients = xyes; then
 369   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 370 fi
 371
 372 AC_ARG_ENABLE(simple-egl-clients,
 373               AS_HELP_STRING([--disable-simple-egl-clients],
 374                              [do not build the simple EGL clients]),,
 375               enable_simple_egl_clients="$enable_egl")
 376 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes")
 377 if test x$enable_simple_egl_clients = xyes; then
 378   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 379                     [egl glesv2 wayland-client wayland-egl wayland-cursor])
 380 fi
 381
 382 AC_ARG_ENABLE(simple-dmabuf-drm-client,
 383               AS_HELP_STRING([--disable-simple-dmabuf-drm-client],
 384                              [do not build the simple dmabuf drm client]),,
 385               enable_simple_dmabuf_drm_client="auto")
 386 if ! test "x$enable_simple_dmabuf_drm_client" = "xno"; then
 387   PKG_CHECK_MODULES(SIMPLE_DMABUF_DRM_CLIENT, [wayland-client libdrm egl], [have_simple_dmabuf_libs=yes],
 388                     [have_simple_dmabuf_libs=no])
 389
 390   PKG_CHECK_MODULES(LIBDRM_PLATFORM_FREEDRENO, [libdrm_freedreno],
 391       AC_DEFINE([HAVE_LIBDRM_FREEDRENO], [1], [Build freedreno dmabuf client]) have_simple_dmabuf_drm_client=yes,
 392       [true])
 393   PKG_CHECK_MODULES(LIBDRM_PLATFORM_INTEL, [libdrm_intel],
 394       AC_DEFINE([HAVE_LIBDRM_INTEL], [1], [Build intel dmabuf client]) have_simple_dmabuf_drm_client=yes,
 395       [true])
 396
 397   if test "x$have_simple_dmabuf_drm_client" != "xyes" -o \
 398           "x$have_simple_dmabuf_libs" = "xno" && \
 399      test "x$enable_simple_dmabuf_drm_client" = "xyes"; then
 400     AC_MSG_ERROR([DRM dmabuf client explicitly enabled, but libdrm_intel or libdrm_freedreno not found])
 401   fi
 402
 403   if test "x$have_simple_dmabuf_drm_client" = "xyes" -a "x$have_simple_dmabuf_libs" = "xyes"; then
 404     enable_simple_dmabuf_drm_client="yes"
 405   fi
 406 fi
 407 AM_CONDITIONAL(BUILD_SIMPLE_DMABUF_DRM_CLIENT, test "x$enable_simple_dmabuf_drm_client" = "xyes")
 408
 409 AC_ARG_ENABLE(simple-dmabuf-v4l-client,
 410               AS_HELP_STRING([--disable-simple-dmabuf-v4l-client],
 411                              [do not build the simple dmabuf v4l client]),,
 412               enable_simple_dmabuf_v4l_client="auto")
 413 if ! test "x$enable_simple_dmabuf_v4l_client" = "xno"; then
 414   PKG_CHECK_MODULES(SIMPLE_DMABUF_V4L_CLIENT, [wayland-client libdrm],
 415                     have_simple_dmabuf_v4l_client=yes, have_simple_dmabuf_v4l_client=no)
 416   if test "x$have_simple_dmabuf_v4l_client" = "xno" -a "x$enable_simple_dmabuf_v4l_client" = "xyes"; then
 417     AC_MSG_ERROR([V4L dmabuf client explicitly enabled, but libdrm couldn't be found])
 418   fi
 419   enable_simple_dmabuf_v4l_client="$have_simple_dmabuf_v4l_client"
 420 fi
 421 AM_CONDITIONAL(BUILD_SIMPLE_DMABUF_V4L_CLIENT, test "x$enable_simple_dmabuf_v4l_client" = "xyes")
 422
 423 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 424 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 425 have_cairo_egl=no
 426 if test x$enable_clients = xyes; then
 427   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 428
 429   PKG_CHECK_MODULES(CLIENT, [wayland-client >= $WAYLAND_PREREQ_VERSION cairo >= 1.10.0 xkbcommon wayland-cursor])
 430   PKG_CHECK_MODULES(SERVER, [wayland-server])
 431   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client >= $WAYLAND_PREREQ_VERSION])
 432
 433   # Only check for cairo-egl if a GL or GLES renderer requested
 434   AS_IF([test "x$cairo_modules" = "xcairo-gl" -o "x$cairo_modules" = "xcairo-glesv2"], [
 435     PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl cairo-egl >= 1.11.3 $cairo_modules],
 436                       [have_cairo_egl=yes], [have_cairo_egl=no])
 437     AS_IF([test "x$have_cairo_egl" = "xyes"],
 438           [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 439           [AC_ERROR([cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])],
 440   [have_cairo_egl=no])
 441
 442   PKG_CHECK_MODULES(PANGO, [pangocairo pango glib-2.0 >= 2.36], [have_pango=yes], [have_pango=no])
 443 fi
 444
 445 AC_ARG_ENABLE(resize-optimization,
 446               AS_HELP_STRING([--disable-resize-optimization],
 447                              [disable resize optimization allocating a big buffer in toytoolkit]),,
 448               enable_resize_optimization=yes)
 449 AS_IF([test "x$enable_resize_optimization" = "xyes"],
 450       [AC_DEFINE([USE_RESIZE_POOL], [1], [Use resize memory pool as a performance optimization])])
 451
 452 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 453 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch = xyes)
 454 if test x$enable_weston_launch = xyes; then
 455   WESTON_SEARCH_LIBS([PAM], [pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 456   if test x$have_pam = xno; then
 457     AC_ERROR([weston-launch requires pam])
 458   fi
 459 fi
 460
 461 AM_CONDITIONAL(HAVE_PANGO, test "x$have_pango" = "xyes")
 462 if test "x$have_pango" = "xyes"; then
 463   AC_DEFINE([HAVE_PANGO], [1], [Have pango])
 464 fi
 465
 466 AM_CONDITIONAL(HAVE_CAIRO_GLESV2,
 467                [test "x$have_cairo_egl" = "xyes" -a "x$cairo_modules" = "xcairo-glesv2" -a "x$enable_egl" = "xyes"])
 468
 469 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 470                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes" -a "x$enable_egl" = "xyes")
 471
 472 AM_CONDITIONAL(BUILD_SUBSURFACES_CLIENT,
 473                [test '(' "x$have_cairo_egl" != "xyes" -o "x$cairo_modules" = "xcairo-glesv2" ')' -a "x$enable_simple_egl_clients" = "xyes"])
 474
 475 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 476
 477 AC_ARG_ENABLE(fullscreen-shell,
 478               AS_HELP_STRING([--disable-fullscreen-shell],
 479                              [do not build fullscreen-shell server plugin]),,
 480               enable_fullscreen_shell=yes)
 481 AM_CONDITIONAL(ENABLE_FULLSCREEN_SHELL,
 482                test "x$enable_fullscreen_shell" = "xyes")
 483
 484 # CMS modules
 485 AC_ARG_ENABLE(colord,
 486               AS_HELP_STRING([--disable-colord],
 487                              [do not build colord CMS support]),,
 488               enable_colord=auto)
 489 have_colord=no
 490 if test "x$enable_colord" != "xno"; then
 491         PKG_CHECK_MODULES(COLORD,
 492                           colord >= 0.1.27,
 493                           have_colord=yes,
 494                           have_colord=no)
 495         if test "x$have_colord" = "xno" -a "x$enable_colord" = "xyes"; then
 496           AC_MSG_ERROR([colord support explicitly requested, but colord couldn't be found])
 497         fi
 498         if test "x$have_colord" = "xyes"; then
 499              enable_colord=yes
 500         fi
 501 fi
 502 AM_CONDITIONAL(ENABLE_COLORD, test "x$enable_colord" = "xyes")
 503
 504 # dbus support
 505 AC_ARG_ENABLE(dbus,
 506               AS_HELP_STRING([--disable-dbus],
 507                              [do not build with dbus support]),,
 508               enable_dbus=auto)
 509 have_dbus=no
 510 if test "x$enable_dbus" != "xno"; then
 511         PKG_CHECK_MODULES(DBUS,
 512                           dbus-1 >= 1.6,
 513                           have_dbus=yes,
 514                           have_dbus=no)
 515         if test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"; then
 516                 AC_MSG_ERROR([dbus support explicitly requested, but libdbus couldn't be found])
 517         fi
 518         if test "x$have_dbus" = "xyes"; then
 519                 enable_dbus=yes
 520                 AC_DEFINE([HAVE_DBUS], [1], [Build with dbus support])
 521         else
 522                 enable_dbus=no
 523         fi
 524 fi
 525 AM_CONDITIONAL(ENABLE_DBUS, test "x$enable_dbus" = "xyes")
 526
 527 # systemd-login support
 528 AC_ARG_ENABLE(systemd-login,
 529               AS_HELP_STRING([--enable-systemd-login],
 530                              [Enable logind support]),,
 531               enable_systemd_login=auto)
 532 if test x$enable_systemd_login != xno -a x$have_dbus != xno; then
 533   PKG_CHECK_MODULES(SYSTEMD_LOGIN,
 534                     [libsystemd >= 209],
 535                     [have_systemd_login_209=yes;have_systemd_login=yes],
 536                     [have_systemd_login_209=no;have_systemd_login=no])
 537
 538   # Older versions of systemd package systemd-login separately. Fall back on that
 539   AS_IF([test x$have_systemd_login != xyes],[
 540         PKG_CHECK_MODULES(SYSTEMD_LOGIN,
 541                           [libsystemd-login >= 198],
 542                           [have_systemd_login=yes],
 543                           [have_systemd_login=no])
 544         ])
 545 else
 546   have_systemd_login=no
 547 fi
 548
 549 if test "x$have_systemd_login" = "xno" -a "x$enable_systemd_login" = "xyes"; then
 550   AC_MSG_ERROR([systemd-login support explicitly enabled, but can't find libsystemd>=209, libsystemd-login or dbus])
 551 fi
 552
 553 AS_IF([test "x$have_systemd_login" = "xyes"],
 554       [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 555 AM_CONDITIONAL(HAVE_SYSTEMD_LOGIN, test "x$have_systemd_login" = "xyes")
 556
 557 AS_IF([test "x$have_systemd_login_209" = "xyes"],
 558       [AC_DEFINE([HAVE_SYSTEMD_LOGIN_209], [1], [Have systemd-login >= 209])])
 559
 560
 561 # Note that other features might want libxml2, or this feature might use
 562 # alternative xml libraries at some point. Therefore the feature and
 563 # pre-requisite concepts are split.
 564 AC_ARG_ENABLE(junit_xml,
 565               AS_HELP_STRING([--disable-junit-xml],
 566                              [do not build with JUnit XML output]),,
 567               enable_junit_xml=auto)
 568 if test "x$enable_junit_xml" != "xno"; then
 569         PKG_CHECK_MODULES(LIBXML2,
 570                           [libxml-2.0 >= 2.6],
 571                           have_libxml2=yes,
 572                           have_libxml2=no)
 573         if test "x$have_libxml2" = "xno" -a "x$enable_junit_xml" = "xyes"; then
 574                 AC_MSG_ERROR([JUnit XML support explicitly requested, but libxml2 couldn't be found])
 575         fi
 576         if test "x$have_libxml2" = "xyes"; then
 577                 enable_junit_xml=yes
 578                 AC_DEFINE(ENABLE_JUNIT_XML, [1], [Build Weston with JUnit output support])
 579         else
 580                 enable_junit_xml=no
 581         fi
 582 fi
 583 AM_CONDITIONAL(ENABLE_JUNIT_XML, test "x$enable_junit_xml" = "xyes")
 584
 585 # ivi-shell support
 586 AC_ARG_ENABLE(ivi-shell,
 587               AS_HELP_STRING([--disable-ivi-shell],
 588                              [do not build ivi-shell server plugin and client]),,
 589               enable_ivi_shell=yes)
 590 AM_CONDITIONAL(ENABLE_IVI_SHELL, test "x$enable_ivi_shell" = "xyes")
 591
 592 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 593 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 594 if test x$enable_wcap_tools = xyes; then
 595   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 596   PKG_CHECK_MODULES(WCAP, [cairo])
 597   WCAP_LIBS="$WCAP_LIBS -lm"
 598 fi
 599
 600 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 601 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 602
 603 if test "x$GCC" = "xyes"; then
 604         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter \
 605                 -Wno-shift-negative-value -Wno-missing-field-initializers \
 606                 -g -fvisibility=hidden \
 607                 -Wstrict-prototypes -Wmissing-prototypes -Wsign-compare"
 608 fi
 609 AC_SUBST(GCC_CFLAGS)
 610
 611
 612 if test "x$WESTON_NATIVE_BACKEND" = "x"; then
 613         WESTON_NATIVE_BACKEND="drm-backend.so"
 614 fi
 615 AC_MSG_NOTICE([Weston's native backend: $WESTON_NATIVE_BACKEND])
 616 AC_DEFINE_UNQUOTED([WESTON_NATIVE_BACKEND], ["$WESTON_NATIVE_BACKEND"],
 617                    [The default backend to load, if not wayland nor x11.])
 618
 619 if test "x$WESTON_SHELL_CLIENT" = "x"; then
 620         WESTON_SHELL_CLIENT="weston-desktop-shell"
 621 fi
 622 AC_MSG_NOTICE([Weston's default desktop shell client: $WESTON_SHELL_CLIENT])
 623 AC_DEFINE_UNQUOTED([WESTON_SHELL_CLIENT], ["$WESTON_SHELL_CLIENT"],
 624                    [The default desktop shell client to load.])
 625
 626 AC_ARG_ENABLE(demo-clients-install,
 627               AS_HELP_STRING([--enable-demo-clients-install],
 628                              [Install demo clients built with weston]),,
 629                              enable_demo_clients_install=no)
 630 AM_CONDITIONAL(INSTALL_DEMO_CLIENTS, [test "x$enable_demo_clients_install" = "xyes"])
 631
 632 AC_ARG_ENABLE(lcms,
 633               AS_HELP_STRING([--disable-lcms],
 634                              [Disable lcms support]),,
 635               enable_lcms=auto)
 636 have_lcms=no
 637 if test "x$enable_lcms" != "xno"; then
 638         PKG_CHECK_MODULES(LCMS,
 639                           lcms2,
 640                           have_lcms=yes,
 641                           have_lcms=no)
 642         if test "x$have_lcms" = "xno" -a "x$enable_lcms" = "xyes"; then
 643           AC_MSG_ERROR([lcms support explicitly requested, but lcms couldn't be found])
 644         fi
 645         if test "x$have_lcms" = "xyes"; then
 646                 enable_lcms=yes
 647                 AC_DEFINE(HAVE_LCMS, 1, [Have lcms support])
 648         fi
 649 fi
 650 AM_CONDITIONAL(HAVE_LCMS, [test "x$enable_lcms" = xyes])
 651
 652 AC_PATH_PROG([wayland_scanner], [wayland-scanner])
 653 if test x$wayland_scanner = x; then
 654         PKG_CHECK_MODULES(WAYLAND_SCANNER, [wayland-scanner])
 655         wayland_scanner=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`
 656 fi
 657
 658 AC_ARG_ENABLE(systemd_notify,
 659               AS_HELP_STRING([--enable-systemd-notify],
 660                              [Enables systemd notifications to
 661                               notify systemd about weston state
 662                               and update watchdog.
 663                               Also sockets provided by systemd
 664                               in case of socket-base activation
 665                               are added to wayland display]),,
 666               enable_systemd_notify=no)
 667 AM_CONDITIONAL(SYSTEMD_NOTIFY_SUPPORT, test x$enable_systemd_notify = xyes)
 668 if test "x$enable_systemd_notify" = "xyes"; then
 669   AC_DEFINE([SYSTEMD_NOTIFY_SUPPORT], [1], [Build the systemd sd_notify support])
 670   PKG_CHECK_MODULES(SYSTEMD_DAEMON, [libsystemd])
 671 fi
 672
 673 AC_CONFIG_FILES([Makefile libweston/version.h compositor/weston.pc])
 674
 675 # AC_CONFIG_FILES needs the full name when running autoconf, so we need to use
 676 # libweston_abi_version here, and outside [] because of m4 quoting rules
 677 AC_CONFIG_FILES([libweston/libweston-]libweston_major_version[.pc:libweston/libweston.pc.in])
 678 AC_CONFIG_FILES([libweston/libweston-]libweston_major_version[-uninstalled.pc:libweston/libweston-uninstalled.pc.in])
 679 AC_CONFIG_FILES([libweston-desktop/libweston-desktop-]libweston_major_version[.pc:libweston-desktop/libweston-desktop.pc.in])
 680 AC_CONFIG_FILES([libweston-desktop/libweston-desktop-]libweston_major_version[-uninstalled.pc:libweston-desktop/libweston-desktop-uninstalled.pc.in])
 681
 682 AM_CONDITIONAL([HAVE_GIT_REPO], [test -f $srcdir/.git/logs/HEAD])
 683
 684 AC_OUTPUT
 685
 686 AC_MSG_RESULT([
 687         Native Backend                  ${WESTON_NATIVE_BACKEND}
 688         setuid Install                  ${enable_setuid_install}
 689
 690         Cairo Renderer                  ${with_cairo}
 691         EGL                             ${enable_egl}
 692         xcb_xkb                         ${have_xcb_xkb}
 693         XWayland                        ${enable_xwayland}
 694         dbus                            ${enable_dbus}
 695
 696         ivi-shell                       ${enable_ivi_shell}
 697
 698         Build wcap utility              ${enable_wcap_tools}
 699         Build Fullscreen Shell          ${enable_fullscreen_shell}
 700         Enable developer documentation  ${enable_devdocs}
 701
 702         weston-launch utility           ${enable_weston_launch}
 703         systemd-login support           ${have_systemd_login}
 704         systemd notify support          ${enable_systemd_notify}
 705
 706         DRM Compositor                  ${enable_drm_compositor}
 707         X11 Compositor                  ${enable_x11_compositor}
 708         Wayland Compositor              ${enable_wayland_compositor}
 709         Headless Compositor             ${enable_headless_compositor}
 710         FBDEV Compositor                ${enable_fbdev_compositor}
 711         RDP Compositor                  ${enable_rdp_compositor}
 712         Screen Sharing                  ${enable_screen_sharing}
 713         JUnit XML output                ${enable_junit_xml}
 714
 715         Build Clients                   ${enable_clients}
 716         Build EGL Clients               ${have_cairo_egl}
 717         Build Simple Clients            ${enable_simple_clients}
 718         Build Simple EGL Clients        ${enable_simple_egl_clients}
 719
 720         Install Demo Clients            ${enable_demo_clients_install}
 721
 722         Colord Support                  ${have_colord}
 723         LCMS2 Support                   ${have_lcms}
 724         libjpeg Support                 ${have_jpeglib}
 725         libwebp Support                 ${have_webp}
 726         VA H.264 encoding Support       ${have_libva}
 727 ])