configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([weston],
   3         [1.0.90],
   4         [https://bugs.freedesktop.org/enter_bug.cgi?product=weston],
   5         [weston],
   6         [http://wayland.freedesktop.org/])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz])
  11
  12 AM_SILENT_RULES([yes])
  13
  14 # Check for programs
  15 AC_PROG_CC
  16 AC_PROG_SED
  17
  18 # Initialize libtool
  19 LT_PREREQ([2.2])
  20 LT_INIT([disable-static])
  21
  22 AC_ARG_VAR([WESTON_NATIVE_BACKEND],
  23            [Set the native backend to use, if Weston is not running under Wayland nor X11. @<:@default=drm-backend.so@:>@])
  24
  25 PKG_PROG_PKG_CONFIG()
  26
  27 AC_CHECK_FUNC([dlopen], [],
  28               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  29 AC_SUBST(DLOPEN_LIBS)
  30
  31 AC_CHECK_HEADERS([execinfo.h])
  32
  33 AC_CHECK_FUNCS([mkostemp strchrnul])
  34
  35 COMPOSITOR_MODULES="wayland-server xkbcommon pixman-1"
  36
  37 AC_ARG_ENABLE(egl, [  --disable-egl],,
  38               enable_egl=yes)
  39 AM_CONDITIONAL(ENABLE_EGL, test x$enable_egl = xyes)
  40 if test x$enable_egl = xyes; then
  41         AC_DEFINE([ENABLE_EGL], [1], [Build Weston with EGL support])
  42         COMPOSITOR_MODULES="$COMPOSITOR_MODULES egl >= 7.10 glesv2"
  43 fi
  44
  45 PKG_CHECK_MODULES(COMPOSITOR, [$COMPOSITOR_MODULES])
  46
  47 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
  48               enable_setuid_install=yes)
  49 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
  50
  51
  52 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
  53               enable_xwayland=yes)
  54 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
  55 if test x$enable_xwayland = xyes; then
  56   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcursor cairo-xcb)
  57   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
  58
  59   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
  60               [Path to X server]), [XSERVER_PATH="$withval"],
  61               [XSERVER_PATH="$bindir/Xorg"])
  62   AC_SUBST([XSERVER_PATH])
  63 fi
  64
  65
  66 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
  67               enable_x11_compositor=yes)
  68 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
  69 if test x$enable_x11_compositor = xyes; then
  70   PKG_CHECK_MODULES([XCB], xcb)
  71   xcb_save_LIBS=$LIBS
  72   xcb_save_CFLAGS=$CFLAGS
  73   CFLAGS=$XCB_CFLAGS
  74   LIBS=$XCB_LIBS
  75   AC_CHECK_FUNCS([xcb_poll_for_queued_event])
  76   LIBS=$xcb_save_LIBS
  77   CFLAGS=$xcb_save_CFLAGS
  78
  79   X11_COMPOSITOR_MODULES="x11 x11-xcb"
  80
  81   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb],
  82                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
  83   if test "x$have_xcb_xkb" = xyes; then
  84         # Most versions of XCB have totally broken XKB bindings, where the
  85         # events don't work.  Make sure we can actually use them.
  86         xcb_xkb_save_CFLAGS=$CFLAGS
  87         CFLAGS=$X11_COMPOSITOR_XKB_CFLAGS
  88         AC_CHECK_MEMBER([struct xcb_xkb_state_notify_event_t.xkbType],
  89                         [], [have_xcb_xkb=no], [[#include <xcb/xkb.h>]])
  90         CFLAGS=$xcb_xkb_save_CFLAGS
  91   fi
  92   if test "x$have_xcb_xkb" = xyes; then
  93         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
  94         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
  95   fi
  96
  97   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
  98   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
  99 fi
 100
 101
 102 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
 103               enable_drm_compositor=yes)
 104 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes -a x$enable_egl = xyes)
 105 if test x$enable_drm_compositor = xyes -a x$enable_egl = xyes; then
 106   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
 107   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm mtdev >= 1.1.0])
 108 fi
 109
 110
 111 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 112               enable_wayland_compositor=yes)
 113 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 114                test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes)
 115 if test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes; then
 116   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 117             [Build the Wayland (nested) compositor])
 118   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client wayland-egl])
 119 fi
 120
 121
 122 AC_ARG_ENABLE(headless-compositor, [  --enable-headless-compositor],,
 123               enable_headless_compositor=yes)
 124 AM_CONDITIONAL(ENABLE_HEADLESS_COMPOSITOR,
 125                test x$enable_headless_compositor = xyes)
 126
 127
 128 AC_ARG_ENABLE(rpi-compositor,
 129               AS_HELP_STRING([--disable-rpi-compositor],
 130                              [do not build the Raspberry Pi backend]),,
 131               enable_rpi_compositor=yes)
 132 AM_CONDITIONAL(ENABLE_RPI_COMPOSITOR, test "x$enable_rpi_compositor" = "xyes" -a "x$enable_egl" = "xyes")
 133 have_bcm_host="no"
 134 if test x$enable_rpi_compositor = xyes -a x$enable_egl = xyes; then
 135   AC_DEFINE([BUILD_RPI_COMPOSITOR], [1], [Build the compositor for Raspberry Pi])
 136   PKG_CHECK_MODULES(RPI_COMPOSITOR, [libudev >= 136 mtdev >= 1.1.0])
 137   PKG_CHECK_MODULES(RPI_BCM_HOST, [bcm_host],
 138                     [have_bcm_host="yes"
 139                      AC_DEFINE([HAVE_BCM_HOST], [1], [have Raspberry Pi BCM headers])],
 140                     [AC_MSG_WARN([Raspberry Pi BCM host libraries not found, will use stubs instead.])])
 141 fi
 142 AM_CONDITIONAL(INSTALL_RPI_COMPOSITOR, test "x$have_bcm_host" = "xyes")
 143
 144
 145 AC_ARG_ENABLE([fbdev-compositor], [  --enable-fbdev-compositor],,
 146               enable_fbdev_compositor=yes)
 147 AM_CONDITIONAL([ENABLE_FBDEV_COMPOSITOR],
 148                [test x$enable_fbdev_compositor = xyes])
 149 AS_IF([test x$enable_fbdev_compositor = xyes], [
 150   AC_DEFINE([BUILD_FBDEV_COMPOSITOR], [1], [Build the fbdev compositor])
 151   PKG_CHECK_MODULES([FBDEV_COMPOSITOR], [libudev >= 136 mtdev >= 1.1.0])
 152 ])
 153
 154
 155 AC_ARG_WITH(cairo-glesv2,
 156             AS_HELP_STRING([--with-cairo-glesv2],
 157                            [Use GLESv2 cairo instead of full GL]))
 158 if test "x$with_cairo_glesv2" = "xyes"; then
 159   cairo_modules="cairo-glesv2"
 160   AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 161 else
 162   cairo_modules="cairo-gl"
 163 fi
 164
 165 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 166 PKG_CHECK_MODULES(PNG, [libpng])
 167 PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])
 168 AS_IF([test "x$have_webp" = "xyes"],
 169       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])])
 170
 171 AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], have_jpeglib=yes)
 172 if test x$have_jpeglib = xyes; then
 173   JPEG_LIBS="-ljpeg"
 174 else
 175   AC_ERROR([libjpeg not found])
 176 fi
 177 AC_SUBST(JPEG_LIBS)
 178
 179 PKG_CHECK_MODULES(CAIRO, [cairo])
 180
 181 AC_ARG_ENABLE(simple-clients,
 182               AS_HELP_STRING([--disable-simple-clients],
 183                              [do not build the simple wl_shm clients]),,
 184               enable_simple_clients=yes)
 185 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 186 if test x$enable_simple_clients = xyes; then
 187   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 188 fi
 189
 190 AC_ARG_ENABLE(simple-egl-clients,
 191               AS_HELP_STRING([--disable-simple-egl-clients],
 192                              [do not build the simple EGL clients]),,
 193               enable_simple_egl_clients=yes)
 194 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes" -a "x$enable_egl" = "xyes")
 195 if test x$enable_simple_egl_clients = xyes -a x$enable_egl = xyes; then
 196   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 197                     [egl >= 7.10 glesv2 wayland-client wayland-egl wayland-cursor])
 198 fi
 199
 200 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 201 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 202 if test x$enable_clients = xyes; then
 203   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 204
 205   PKG_CHECK_MODULES(CLIENT, [wayland-client cairo >= 1.10.0 xkbcommon wayland-cursor])
 206   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client])
 207
 208   PKG_CHECK_MODULES(POPPLER, [poppler-glib glib-2.0 gobject-2.0 gio-2.0 ],
 209                              [have_poppler=yes], [have_poppler=no])
 210   PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl >= 7.10 cairo-egl >= 1.11.3 $cairo_modules],
 211                     [have_cairo_egl=yes], [have_cairo_egl=no])
 212   AS_IF([test "x$have_cairo_egl" = "xyes"],
 213         [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 214         [AC_MSG_WARN([clients will use cairo image, cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])
 215 fi
 216
 217 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 218 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch == xyes)
 219 if test x$enable_weston_launch == xyes; then
 220   PKG_CHECK_MODULES(WESTON_LAUNCH, [libdrm])
 221   PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login],
 222                     [have_systemd_login=yes], [have_systemd_login=no])
 223   AS_IF([test "x$have_systemd_login" = "xyes"],
 224         [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 225
 226   AC_CHECK_LIB([pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 227   if test x$have_pam == xno; then
 228     AC_ERROR([weston-launch requires pam])
 229   fi
 230   WESTON_LAUNCH_LIBS="$WESTON_LAUNCH_LIBS -lpam"
 231 fi
 232
 233 if test x$enable_egl = xyes; then
 234   PKG_CHECK_MODULES(GLU, [glu], [have_glu=yes], [have_glu=no])
 235 fi
 236 AM_CONDITIONAL(HAVE_GLU, test "x$have_glu" = "xyes")
 237
 238
 239 AM_CONDITIONAL(HAVE_POPPLER, test "x$have_poppler" = "xyes")
 240
 241 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 242                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes" -a "x$enable_egl" = "xyes")
 243
 244 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 245
 246 AC_ARG_ENABLE(tablet-shell,
 247               AS_HELP_STRING([--disable-tablet-shell],
 248                              [do not build tablet-shell server plugin and client]),,
 249               enable_tablet_shell=yes)
 250 AM_CONDITIONAL(ENABLE_TABLET_SHELL,
 251                test "x$enable_tablet_shell" = "xyes")
 252
 253
 254 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 255 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 256 if test x$enable_wcap_tools = xyes; then
 257   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 258   PKG_CHECK_MODULES(WCAP, [cairo])
 259   WCAP_LIBS="$WCAP_LIBS -lm"
 260 fi
 261
 262 AC_CHECK_PROG(RSVG_CONVERT, rsvg-convert, rsvg-convert)
 263 AM_CONDITIONAL(HAVE_RSVG_CONVERT, test -n "$RSVG_CONVERT")
 264
 265 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 266 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 267
 268 if test "x$GCC" = "xyes"; then
 269         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter \
 270                 -Wno-missing-field-initializers -g -fvisibility=hidden \
 271                 -Wstrict-prototypes -Wmissing-prototypes"
 272 fi
 273 AC_SUBST(GCC_CFLAGS)
 274
 275 if test "x$WESTON_NATIVE_BACKEND" = "x"; then
 276         WESTON_NATIVE_BACKEND="drm-backend.so"
 277 fi
 278 AC_MSG_NOTICE([Weston's native backend: $WESTON_NATIVE_BACKEND])
 279 AC_DEFINE_UNQUOTED([WESTON_NATIVE_BACKEND], ["$WESTON_NATIVE_BACKEND"],
 280                    [The default backend to load, if not wayland nor x11.])
 281
 282 WAYLAND_SCANNER_RULES(['$(top_srcdir)/protocol'])
 283
 284 AC_CONFIG_FILES([Makefile
 285                  shared/Makefile
 286                  src/Makefile
 287                  src/xwayland/Makefile
 288                  clients/Makefile
 289                  wcap/Makefile
 290                  data/Makefile
 291                  protocol/Makefile
 292                  man/Makefile
 293                  tests/Makefile])
 294 AC_OUTPUT